granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1)
  65
  66 if test "$apr_found" = "no"; then
  67   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  68 fi
  69
  70 if test "$apr_found" = "reconfig"; then
  71   APR_SUBDIR_CONFIG(srclib/apr,
  72                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  73                     [--enable-layout=*|\'--enable-layout=*])
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_SETIFNULL(CC, `$apr_config --cc`)
  80 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  81 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  82 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  83 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  84 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  85 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  86 APR_BINDIR=`$apr_config --bindir`
  87 APR_INCLUDEDIR=`$apr_config --includedir`
  88
  89 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  90
  91 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1)
  92
  93 if test "$apu_found" = "no"; then
  94   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  95 fi
  96
  97 if test "$apu_found" = "reconfig"; then
  98   APR_SUBDIR_CONFIG(srclib/apr-util,
  99                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 100                     [--enable-layout=*|\'--enable-layout=*])
 101   dnl We must be the last to build and the first to be cleaned
 102   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 103   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 104 fi
 105
 106 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 107 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 108 APU_BINDIR=`$apu_config --bindir`
 109 APU_INCLUDEDIR=`$apu_config --includedir`
 110
 111 dnl In case we picked up CC and CPP from APR, get that info into the
 112 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 113 dnl PCRE and for our config tests will be whatever PCRE determines.
 114 AC_PROG_CC
 115 AC_PROG_CPP
 116
 117 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 118
 119 APR_SUBDIR_CONFIG(srclib/pcre,
 120                   [--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir])
 121
 122 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 123
 124 dnl Absolute source/build directory
 125 abs_srcdir=`(cd $srcdir && pwd)`
 126 abs_builddir=`pwd`
 127
 128 dnl If the source dir is not equal to the build dir,
 129 dnl then we are running in VPATH mode.
 130
 131 APR_ADDTO(INCLUDES, [-I.])
 132
 133 if test "$abs_builddir" != "$abs_srcdir"; then
 134   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 135 fi
 136
 137 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators])
 138
 139 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 140
 141 case $host in
 142   *os2*)
 143       # Use a custom made libtool replacement
 144       echo "using aplibtool"
 145       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 146       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 147       SH_LIBS="\$(ALL_LIBS)"
 148       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 149       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 150       MK_IMPLIB="emximp"
 151       other_targets="$other_targets os2core"
 152       INSTALL_PROG_FLAGS="-e .exe"
 153       SHLTCFLAGS=""
 154       LTCFLAGS=""
 155       ;;
 156   *)
 157       if test "x$LTFLAGS" = "x"; then
 158           LTFLAGS='--silent'
 159       fi
 160       my_libtool=`$apr_config --apr-libtool`
 161       LIBTOOL="$my_libtool \$(LTFLAGS)"
 162       libtoolversion=`$my_libtool --version`
 163       case $libtoolversion in
 164           *1.[[45]]*)
 165               SH_LIBTOOL='$(LIBTOOL)'
 166               SHLTCFLAGS="-prefer-pic"
 167               LTCFLAGS="-prefer-non-pic -static"
 168               ;;
 169           *)
 170               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 171               SHLTCFLAGS=""
 172               LTCFLAGS=""
 173               ;;
 174       esac
 175       ;;
 176 esac
 177 APACHE_SUBST(SHLTCFLAGS)
 178 APACHE_SUBST(LTCFLAGS)
 179
 180 AP_SIG_GRACEFUL=USR1
 181
 182 case $host in
 183   *-apple-aux3*)
 184       APR_SETVAR(APACHE_MPM, [prefork])
 185       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 186       ;;
 187   *-beos*)
 188       APR_SETVAR(APACHE_MPM, [beos])
 189       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 190       ;;
 191   *os2_emx*)
 192       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 193       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 194       ;;
 195   *-linux-*)
 196       case `uname -r` in
 197         2.0* )
 198             AP_SIG_GRACEFUL=WINCH
 199             ;;
 200         2.[[2-9]]* )
 201             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 202             ;;
 203         * )
 204             ;;
 205       esac
 206       ;;
 207   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 208       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 209       ;;
 210   *-solaris2*)
 211       dnl This is a hack -- we should be using AC_TRY_RUN instead
 212       ap_platform_runtime_link_flag="-R"
 213       dnl solaris 8 and above don't have a thundering herd
 214       dnl not sure about rev's before this one.
 215       case `uname -r` in
 216         5.[567]*)
 217             ;;
 218         * )
 219             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 220             ;;
 221       esac
 222       ;;
 223   *cygwin*)
 224       APR_SETVAR(APACHE_MPM, [prefork])
 225       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 226       ;;
 227   *aix*)
 228       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 229       if test $aixver -ge 4320; then
 230         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 231       fi
 232       ;;
 233   *os390*)
 234       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 235       ;;
 236 esac
 237
 238 dnl
 239 dnl Process command line arguments. This is done early in the process so the
 240 dnl user can get feedback quickly in case of an error.
 241 dnl
 242 dnl ### need to move some of the arguments "up here"
 243
 244 dnl ## Check for programs
 245
 246 AC_PATH_PROG(RM, rm)
 247 AC_PROG_AWK
 248 AC_PROG_INSTALL
 249 AC_PROG_LN_S
 250 AC_CHECK_TOOL(RANLIB, ranlib, true)
 251 dnl AC_PATH_PROG(PERL_PATH, perl)
 252 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 253
 254 dnl various OS checks that apparently set required flags
 255 AC_AIX
 256 AC_ISC_POSIX
 257 AC_MINIX
 258
 259 dnl Check for what we can generate dependency files with
 260 APR_CHECK_DEPEND
 261
 262 dnl ## Check for libraries
 263
 264 dnl ## Check for header files
 265
 266 dnl I think these are just used all over the place, so just check for
 267 dnl them at the base of the tree. If some are specific to a single
 268 dnl directory, they should be moved (Comment #Spoon)
 269
 270 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 271 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 272 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 273
 274 AC_HEADER_STDC
 275 AC_CHECK_HEADERS( \
 276 string.h \
 277 limits.h \
 278 unistd.h \
 279 sys/socket.h \
 280 pwd.h \
 281 grp.h \
 282 strings.h \
 283 sys/prctl.h \
 284 sys/processor.h \
 285 sys/sem.h
 286 )
 287 AC_HEADER_SYS_WAIT
 288
 289 dnl ## Check for typedefs, structures, and compiler characteristics.
 290
 291 AC_C_CONST
 292 if test "$ac_cv_prog_gcc" = "yes"; then
 293   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 294 fi
 295
 296 dnl ## Check for library functions
 297 AC_SEARCH_LIBS(sqrt, m)
 298
 299 dnl See Comment #Spoon
 300
 301 AC_CHECK_FUNCS( \
 302 getpwnam \
 303 getgrnam \
 304 initgroups \
 305 bindprocessor \
 306 prctl \
 307 timegm \
 308 )
 309
 310 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 311 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 312 [AC_TRY_COMPILE([#include <sys/types.h>
 313 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 314   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 315 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 316     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 317 fi
 318
 319 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 320
 321 case $host in
 322     *aix*)
 323         # for 32-bit builds, increase MAXDATA to allow lots of threads
 324         if test x$OBJECT_MODE != x64; then
 325             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 326         fi
 327         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 328         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 329         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 330         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 331         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 332         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 333         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 334         ;;
 335     *os390*)
 336         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 337         ;;
 338     *)
 339         OS_SPECIFIC_VARS=""
 340 esac
 341
 342 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 343         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 344         [PORT=80])
 345
 346 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 347
 348 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 349 [
 350   v4mapped=$enableval
 351 ],
 352 [
 353     case $host in
 354     *freebsd5*|*netbsd*|*openbsd*)
 355         v4mapped=no
 356         ;;
 357     *)
 358         v4mapped=yes
 359         ;;
 360 esac
 361 ])
 362
 363 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 364     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 365               [Allow IPv4 connections on IPv6 listening sockets])
 366 fi
 367
 368 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 369 [
 370     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 371               [Allow modules to run hook after a fatal exception])
 372 ])dnl
 373
 374 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 375 [
 376   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 377 ])dnl
 378
 379 prefix="$orig_prefix"
 380 APACHE_ENABLE_MODULES
 381
 382 dnl reading config stubs
 383 esyscmd(./build/config-stubs .)
 384
 385 APACHE_SUBST(progname)
 386 APACHE_SUBST(MPM_LIB)
 387 APACHE_SUBST(OS)
 388 APACHE_SUBST(OS_DIR)
 389 APACHE_SUBST(BUILTIN_LIBS)
 390 APACHE_SUBST(SHLIBPATH_VAR)
 391 APACHE_SUBST(OS_SPECIFIC_VARS)
 392
 393 PRE_SHARED_CMDS='echo ""'
 394 POST_SHARED_CMDS='echo ""'
 395
 396 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 397
 398 if test "$apache_need_shared" = "yes"; then
 399   if test -f $ac_aux_dir/ltconfig; then
 400     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 401   fi
 402   shared_build="shared-build"
 403 fi
 404
 405 dnl enable_so tells us if *any* modules can be built as DSOs
 406
 407 if test "$enable_so" = "yes"; then
 408   case $host in
 409     *-ibm-aix*)
 410       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 411       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 412       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 413       ;;
 414     *beos)
 415       SH_LDFLAGS='$(top_builddir)/_APP_'
 416       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 417       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 418       ;;
 419     *os390)
 420       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 421       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 422   esac
 423 fi
 424
 425 APACHE_SUBST(PRE_SHARED_CMDS)
 426 APACHE_SUBST(POST_SHARED_CMDS)
 427 APACHE_SUBST(shared_build)
 428
 429 AC_ARG_WITH(program-name,
 430 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 431   progname="$withval" ], [
 432   progname="httpd"] )
 433
 434 # SuExec parameters
 435 AC_ARG_WITH(suexec-bin,
 436 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 437   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 438 ] )
 439
 440 AC_ARG_WITH(suexec-caller,
 441 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 442   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 443
 444 AC_ARG_WITH(suexec-userdir,
 445 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 446   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 447
 448 AC_ARG_WITH(suexec-docroot,
 449 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 450   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 451
 452 AC_ARG_WITH(suexec-uidmin,
 453 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 454   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 455
 456 AC_ARG_WITH(suexec-gidmin,
 457 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 458   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 459
 460 AC_ARG_WITH(suexec-logfile,
 461 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 462   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 463
 464 AC_ARG_WITH(suexec-safepath,
 465 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 466   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 467
 468 AC_ARG_WITH(suexec-umask,
 469 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 470   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 471
 472 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 473 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 474
 475 dnl APR should go after the other libs, so the right symbols can be picked up
 476 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 477 APACHE_SUBST(AP_LIBS)
 478 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 479 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 480
 481 AC_DEFINE(AP_USING_AUTOCONF, 1,
 482                 [Using autoconf to configure Apache])
 483
 484 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 485     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 486               [This platform doesn't suffer from the thundering herd problem])
 487 fi
 488
 489 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 490 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 491 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 492 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 493 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 494 AC_SUBST(AP_SIG_GRACEFUL)
 495 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 496 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 497
 498 dnl check for endianness
 499 if test "$cross_compiling" = "no"; then
 500   AC_C_BIGENDIAN
 501 else
 502   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 503                 [byte order is unknown due to cross-compilation])
 504 fi
 505
 506 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 507 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 508 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 509
 510 if test -d ./test; then
 511     APACHE_FAST_OUTPUT(test/Makefile)
 512 fi
 513
 514 dnl ## Finalize the variables
 515 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 516
 517 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 518 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 519 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 520 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 521 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 522 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 523
 524 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 525
 526 APACHE_GEN_CONFIG_VARS
 527
 528 dnl ## Build modules.c
 529 rm -f modules.c
 530 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 531
 532 APR_EXPAND_VAR(ap_prefix, $prefix)
 533 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 534         [Root directory of the Apache install area])
 535 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 536         [Location of the config file, relative to the Apache root directory])
 537 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 538         [Location of the MIME types config file, relative to the Apache root directory])
 539 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 540         [Location of the source for the current MPM])
 541
 542 perlbin=`$ac_aux_dir/PrintPath perl`
 543 if test "x$perlbin" = "x"; then
 544     perlbin="/replace/with/path/to/perl/interpreter"
 545 fi
 546 AC_SUBST(perlbin)
 547
 548 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 549
 550 BSD_MAKEFILE=no
 551 ap_make_include=include
 552 ap_make_delimiter=' '
 553 case $host in
 554 *bsdi*)
 555     # Check whether they've installed GNU make
 556     if make --version > /dev/null 2>&1; then
 557         true
 558     else
 559         BSD_MAKEFILE=yes
 560         ap_make_include=.include
 561         ap_make_delimiter='"'
 562     fi
 563     ;;
 564 esac
 565 AC_SUBST(ap_make_include)
 566 AC_SUBST(ap_make_delimiter)
 567
 568 dnl Ensure that docs/conf is created.
 569 test -d docs/conf||$mkdir_p docs/conf
 570
 571 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf docs/conf/ssl-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 572   APACHE_GEN_MAKEFILES
 573 ])
 574