granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [11devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2017, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc";;
 357     *) pgac_cc_list="gcc cc";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361
 362 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 363 # but has idiosyncrasies of its own.  We assume icc will define
 364 # __INTEL_COMPILER regardless of CFLAGS.
 365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 366 choke me
 367 @%:@endif])], [ICC=yes], [ICC=no])
 368
 369 # Check if it's Sun Studio compiler. We assume that
 370 # __SUNPRO_C will be defined for Sun Studio compilers
 371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 372 choke me
 373 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 374
 375 AC_SUBST(SUN_STUDIO_CC)
 376
 377 unset CFLAGS
 378
 379 #
 380 # Read the template
 381 #
 382 . "$srcdir/src/template/$template" || exit
 383
 384 # CFLAGS are selected so:
 385 # If the user specifies something in the environment, that is used.
 386 # else:  If the template file set something, that is used.
 387 # else:  If coverage was enabled, don't set anything.
 388 # else:  If the compiler is GCC, then we use -O2.
 389 # else:  If the compiler is something else, then we use -O, unless debugging.
 390
 391 if test "$ac_env_CFLAGS_set" = set; then
 392   CFLAGS=$ac_env_CFLAGS_value
 393 elif test "${CFLAGS+set}" = set; then
 394   : # (keep what template set)
 395 elif test "$enable_coverage" = yes; then
 396   : # no optimization by default
 397 elif test "$GCC" = yes; then
 398   CFLAGS="-O2"
 399 else
 400   # if the user selected debug mode, don't use -O
 401   if test "$enable_debug" != yes; then
 402     CFLAGS="-O"
 403   fi
 404 fi
 405
 406 # CFLAGS we determined above will be added back at the end
 407 user_CFLAGS=$CFLAGS
 408 CFLAGS=""
 409
 410 # set CFLAGS_VECTOR from the environment, if available
 411 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 412   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 413 fi
 414
 415 # Some versions of GCC support some additional useful warning flags.
 416 # Check whether they are supported, and add them to CFLAGS if so.
 417 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 418 # but has its own.  Also check other compiler-specific flags here.
 419
 420 if test "$GCC" = yes -a "$ICC" = no; then
 421   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 422   # These work in some but not all gcc versions
 423   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 424   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 425   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 426   # This was included in -Wall/-Wformat in older GCC versions
 427   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 428   # Disable strict-aliasing rules; needed for gcc 3.3+
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 431   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 432   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 434   # Optimization flags for specific files that benefit from vectorization
 435   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 436   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 437   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 438   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 439   # test for the positive form and if that works, add the negative form
 440   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 441   if test -n "$NOT_THE_CFLAGS"; then
 442     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 443   fi
 444 elif test "$ICC" = yes; then
 445   # Intel's compiler has a bug/misoptimization in checking for
 446   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 447   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 448   # Make sure strict aliasing is off (though this is said to be the default)
 449   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 450 elif test "$PORTNAME" = "aix"; then
 451   # AIX's xlc has to have strict aliasing turned off too
 452   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 453   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 454 elif test "$PORTNAME" = "hpux"; then
 455   # On some versions of HP-UX, libm functions do not set errno by default.
 456   # Fix that by using +Olibmerrno if the compiler recognizes it.
 457   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 458 fi
 459
 460 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 461
 462 # supply -g if --enable-debug
 463 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 464   CFLAGS="$CFLAGS -g"
 465 fi
 466
 467 # enable code coverage if --enable-coverage
 468 if test "$enable_coverage" = yes; then
 469   if test "$GCC" = yes; then
 470     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 471   else
 472     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 473   fi
 474 fi
 475
 476 # enable profiling if --enable-profiling
 477 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 478   if test "$GCC" = yes; then
 479     AC_DEFINE([PROFILE_PID_DIR], 1,
 480            [Define to 1 to allow profiling output to be saved separately for each process.])
 481     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 482   else
 483     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 484   fi
 485 fi
 486
 487 # We already have this in Makefile.win32, but configure needs it too
 488 if test "$PORTNAME" = "win32"; then
 489   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 490 fi
 491
 492 # Now that we're done automatically adding stuff to CFLAGS, put back the
 493 # user-specified flags (if any) at the end.  This lets users override
 494 # the automatic additions.
 495 CFLAGS="$CFLAGS $user_CFLAGS"
 496
 497 # Check if the compiler still works with the final flag settings
 498 AC_MSG_CHECKING([whether the C compiler still works])
 499 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 500   [AC_MSG_RESULT(yes)],
 501   [AC_MSG_RESULT(no)
 502    AC_MSG_ERROR([cannot proceed])])
 503
 504 # Defend against gcc -ffast-math
 505 if test "$GCC" = yes; then
 506 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 507 choke me
 508 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 509 fi
 510
 511 AC_PROG_CPP
 512 AC_SUBST(GCC)
 513
 514
 515 #
 516 # Set up TAS assembly code if needed; the template file has now had its
 517 # chance to request this.
 518 #
 519 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 520
 521 if test "$need_tas" = yes ; then
 522   TAS=tas.o
 523 else
 524   TAS=""
 525 fi
 526 AC_SUBST(TAS)
 527
 528
 529 #
 530 # Automatic dependency tracking
 531 #
 532 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 533               [autodepend=yes])
 534 AC_SUBST(autodepend)
 535
 536
 537 #
 538 # Enable assert checks
 539 #
 540 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 541               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 542                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 543
 544
 545 #
 546 # Include directories
 547 #
 548 ac_save_IFS=$IFS
 549 IFS="${IFS}${PATH_SEPARATOR}"
 550 # SRCH_INC comes from the template file
 551 for dir in $with_includes $SRCH_INC; do
 552   if test -d "$dir"; then
 553     INCLUDES="$INCLUDES -I$dir"
 554   else
 555     AC_MSG_WARN([*** Include directory $dir does not exist.])
 556   fi
 557 done
 558 IFS=$ac_save_IFS
 559 AC_SUBST(INCLUDES)
 560
 561
 562 #
 563 # Library directories
 564 #
 565 ac_save_IFS=$IFS
 566 IFS="${IFS}${PATH_SEPARATOR}"
 567 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 568 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 569   if test -d "$dir"; then
 570     LIBDIRS="$LIBDIRS -L$dir"
 571   else
 572     AC_MSG_WARN([*** Library directory $dir does not exist.])
 573   fi
 574 done
 575 IFS=$ac_save_IFS
 576
 577 #
 578 # Enable thread-safe client libraries
 579 #
 580 AC_MSG_CHECKING([allow thread-safe client libraries])
 581 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 582 if test "$enable_thread_safety" = yes; then
 583   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 584           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 585 fi
 586 AC_MSG_RESULT([$enable_thread_safety])
 587 AC_SUBST(enable_thread_safety)
 588
 589 #
 590 # ICU
 591 #
 592 AC_MSG_CHECKING([whether to build with ICU support])
 593 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 594               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 595 AC_MSG_RESULT([$with_icu])
 596 AC_SUBST(with_icu)
 597
 598 if test "$with_icu" = yes; then
 599   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 600 fi
 601
 602 #
 603 # Optionally build Tcl modules (PL/Tcl)
 604 #
 605 AC_MSG_CHECKING([whether to build with Tcl])
 606 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 607 AC_MSG_RESULT([$with_tcl])
 608 AC_SUBST([with_tcl])
 609
 610 # We see if the path to the Tcl/Tk configuration scripts is specified.
 611 # This will override the use of tclsh to find the paths to search.
 612
 613 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 614
 615 #
 616 # Optionally build Perl modules (PL/Perl)
 617 #
 618 AC_MSG_CHECKING([whether to build Perl modules])
 619 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 620 AC_MSG_RESULT([$with_perl])
 621 AC_SUBST(with_perl)
 622
 623 #
 624 # Optionally build Python modules (PL/Python)
 625 #
 626 AC_MSG_CHECKING([whether to build Python modules])
 627 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 628 AC_MSG_RESULT([$with_python])
 629 AC_SUBST(with_python)
 630
 631 #
 632 # GSSAPI
 633 #
 634 AC_MSG_CHECKING([whether to build with GSSAPI support])
 635 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 636 [
 637   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 638   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 639 ])
 640 AC_MSG_RESULT([$with_gssapi])
 641
 642
 643 AC_SUBST(krb_srvtab)
 644
 645
 646 #
 647 # Kerberos configuration parameters
 648 #
 649 PGAC_ARG_REQ(with, krb-srvnam,
 650              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 651              [],
 652              [with_krb_srvnam="postgres"])
 653 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 654                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 655
 656
 657 #
 658 # PAM
 659 #
 660 AC_MSG_CHECKING([whether to build with PAM support])
 661 PGAC_ARG_BOOL(with, pam, no,
 662               [build with PAM support],
 663               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 664 AC_MSG_RESULT([$with_pam])
 665
 666
 667 #
 668 # BSD AUTH
 669 #
 670 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 671 PGAC_ARG_BOOL(with, bsd-auth, no,
 672               [build with BSD Authentication support],
 673               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 674 AC_MSG_RESULT([$with_bsd_auth])
 675
 676
 677 #
 678 # LDAP
 679 #
 680 AC_MSG_CHECKING([whether to build with LDAP support])
 681 PGAC_ARG_BOOL(with, ldap, no,
 682               [build with LDAP support],
 683               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 684 AC_MSG_RESULT([$with_ldap])
 685
 686
 687 #
 688 # Bonjour
 689 #
 690 AC_MSG_CHECKING([whether to build with Bonjour support])
 691 PGAC_ARG_BOOL(with, bonjour, no,
 692               [build with Bonjour support],
 693               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 694 AC_MSG_RESULT([$with_bonjour])
 695
 696
 697 #
 698 # OpenSSL
 699 #
 700 AC_MSG_CHECKING([whether to build with OpenSSL support])
 701 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 702               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 703 AC_MSG_RESULT([$with_openssl])
 704 AC_SUBST(with_openssl)
 705
 706 #
 707 # SELinux
 708 #
 709 AC_MSG_CHECKING([whether to build with SELinux support])
 710 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 711 AC_SUBST(with_selinux)
 712 AC_MSG_RESULT([$with_selinux])
 713
 714 #
 715 # Systemd
 716 #
 717 AC_MSG_CHECKING([whether to build with systemd support])
 718 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 719               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 720 AC_SUBST(with_systemd)
 721 AC_MSG_RESULT([$with_systemd])
 722
 723 #
 724 # Readline
 725 #
 726 PGAC_ARG_BOOL(with, readline, yes,
 727               [do not use GNU Readline nor BSD Libedit for editing])
 728 # readline on MinGW has problems with backslashes in psql and other bugs.
 729 # This is particularly a problem with non-US code pages.
 730 # Therefore disable its use until we understand the cause. 2004-07-20
 731 if test "$PORTNAME" = "win32"; then
 732   if test "$with_readline" = yes; then
 733     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 734     with_readline=no
 735   fi
 736 fi
 737
 738
 739 #
 740 # Prefer libedit
 741 #
 742 PGAC_ARG_BOOL(with, libedit-preferred, no,
 743               [prefer BSD Libedit over GNU Readline])
 744
 745
 746 #
 747 # UUID library
 748 #
 749 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 750 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 751 # UUID library.  More than one of these might be present on a given platform,
 752 # so we make the user say which one she wants.
 753 #
 754 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 755 if test x"$with_uuid" = x"" ; then
 756   with_uuid=no
 757 fi
 758 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 759 if test "$with_ossp_uuid" = yes ; then
 760   with_uuid=ossp
 761 fi
 762
 763 if test "$with_uuid" = bsd ; then
 764   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 765   UUID_EXTRA_OBJS="md5.o sha1.o"
 766 elif test "$with_uuid" = e2fs ; then
 767   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 768   UUID_EXTRA_OBJS="md5.o sha1.o"
 769 elif test "$with_uuid" = ossp ; then
 770   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 771   UUID_EXTRA_OBJS=""
 772 elif test "$with_uuid" = no ; then
 773   UUID_EXTRA_OBJS=""
 774 else
 775   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 776 fi
 777 AC_SUBST(with_uuid)
 778 AC_SUBST(UUID_EXTRA_OBJS)
 779
 780
 781 #
 782 # XML
 783 #
 784 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 785               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 786
 787 if test "$with_libxml" = yes ; then
 788   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 789   if test -n "$XML2_CONFIG"; then
 790     for pgac_option in `$XML2_CONFIG --cflags`; do
 791       case $pgac_option in
 792         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 793       esac
 794     done
 795     for pgac_option in `$XML2_CONFIG --libs`; do
 796       case $pgac_option in
 797         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 798       esac
 799     done
 800   fi
 801 fi
 802
 803 AC_SUBST(with_libxml)
 804
 805 #
 806 # XSLT
 807 #
 808 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 809               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 810
 811
 812 AC_SUBST(with_libxslt)
 813
 814 #
 815 # tzdata
 816 #
 817 PGAC_ARG_REQ(with, system-tzdata,
 818              [DIR], [use system time zone data in DIR])
 819 AC_SUBST(with_system_tzdata)
 820
 821 #
 822 # Zlib
 823 #
 824 PGAC_ARG_BOOL(with, zlib, yes,
 825               [do not use Zlib])
 826 AC_SUBST(with_zlib)
 827
 828 #
 829 # Elf
 830 #
 831
 832 # Assume system is ELF if it predefines __ELF__ as 1,
 833 # otherwise believe host_os based default.
 834 case $host_os in
 835     freebsd1*|freebsd2*) elf=no;;
 836     freebsd3*|freebsd4*) elf=yes;;
 837 esac
 838
 839 AC_EGREP_CPP(yes,
 840 [#if __ELF__
 841   yes
 842 #endif
 843 ],
 844 [ELF_SYS=true],
 845 [if test "X$elf" = "Xyes" ; then
 846   ELF_SYS=true
 847 else
 848   ELF_SYS=
 849 fi])
 850 AC_SUBST(ELF_SYS)
 851
 852 #
 853 # Assignments
 854 #
 855
 856 CPPFLAGS="$CPPFLAGS $INCLUDES"
 857 LDFLAGS="$LDFLAGS $LIBDIRS"
 858
 859 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 860 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 861
 862 PGAC_PROG_LD
 863 AC_SUBST(LD)
 864 AC_SUBST(with_gnu_ld)
 865 AC_PROG_RANLIB
 866 PGAC_CHECK_STRIP
 867 AC_CHECK_TOOL(AR, ar, ar)
 868 if test "$PORTNAME" = "win32"; then
 869   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 870   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 871   AC_CHECK_TOOL(WINDRES, windres, windres)
 872 fi
 873
 874 AC_PROG_INSTALL
 875 # When Autoconf chooses install-sh as install program it tries to generate
 876 # a relative path to it in each makefile where it substitutes it. This clashes
 877 # with our Makefile.global concept. This workaround helps.
 878 case $INSTALL in
 879   *install-sh*) install_bin='';;
 880   *) install_bin=$INSTALL;;
 881 esac
 882 AC_SUBST(install_bin)
 883
 884 PGAC_PATH_PROGS(TAR, tar)
 885 AC_PROG_LN_S
 886 AC_PROG_AWK
 887 AC_PROG_MKDIR_P
 888 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 889 # a relative path to it in each makefile where it substitutes it. This clashes
 890 # with our Makefile.global concept. This workaround helps.
 891 case $MKDIR_P in
 892   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 893 esac
 894
 895 PGAC_PATH_BISON
 896 PGAC_PATH_FLEX
 897
 898 PGAC_PATH_PERL
 899 if test "$with_perl" = yes; then
 900   if test -z "$PERL"; then
 901     AC_MSG_ERROR([Perl not found])
 902   fi
 903   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 904   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 905     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 906 You might have to rebuild your Perl installation.  Refer to the
 907 documentation for details.  Use --without-perl to disable building
 908 PL/Perl.])
 909   fi
 910   PGAC_CHECK_PERL_EMBED_CCFLAGS
 911   PGAC_CHECK_PERL_EMBED_LDFLAGS
 912 fi
 913
 914 if test "$with_python" = yes; then
 915   PGAC_PATH_PYTHON
 916   PGAC_CHECK_PYTHON_EMBED_SETUP
 917 fi
 918
 919 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 920   PGAC_PATH_PROGS(ZIC, zic)
 921   if test -z "$ZIC"; then
 922     AC_MSG_ERROR([
 923 When cross-compiling, either use the option --with-system-tzdata to use
 924 existing time-zone data, or set the environment variable ZIC to a zic
 925 program to use during the build.])
 926   fi
 927 fi
 928
 929 #
 930 # Pthreads
 931 #
 932 # For each platform, we need to know about any special compile and link
 933 # libraries, and whether the normal C function names are thread-safe.
 934 # See the comment at the top of src/port/thread.c for more information.
 935 # WIN32 doesn't need the pthread tests;  it always uses threads
 936 #
 937 # These tests are run before the library-tests, because linking with the
 938 # other libraries can pull in the pthread functions as a side-effect.  We
 939 # want to use the -pthread or similar flags directly, and not rely on
 940 # the side-effects of linking with some other library.
 941 #
 942 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 943 # invocation below is the first one in the script, and autoconf generates
 944 # additional code for that, which must not be inside the if-block. AS_IF
 945 # knows how to do that.
 946 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 947 [ # then
 948 AX_PTHREAD      # set thread flags
 949
 950 # Some platforms use these, so just define them.  They can't hurt if they
 951 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 952 # enables 5-arg getpwuid_r, among other things.
 953 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 954
 955 # Check for *_r functions
 956 _CFLAGS="$CFLAGS"
 957 _LIBS="$LIBS"
 958 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 959 LIBS="$LIBS $PTHREAD_LIBS"
 960
 961 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 962 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 963
 964 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 965
 966 # Do test here with the proper thread flags
 967 PGAC_FUNC_STRERROR_R_INT
 968
 969 CFLAGS="$_CFLAGS"
 970 LIBS="$_LIBS"
 971
 972 ], [ # else
 973 # do not use values from template file
 974 PTHREAD_CFLAGS=
 975 PTHREAD_LIBS=
 976 ]) # fi
 977
 978 AC_SUBST(PTHREAD_CFLAGS)
 979 AC_SUBST(PTHREAD_LIBS)
 980
 981
 982 ##
 983 ## Libraries
 984 ##
 985 ## Most libraries are included only if they demonstrably provide a function
 986 ## we need, but libm is an exception: always include it, because there are
 987 ## too many compilers that play cute optimization games that will break
 988 ## probes for standard functions such as pow().
 989 ##
 990
 991 AC_CHECK_LIB(m, main)
 992 AC_SEARCH_LIBS(setproctitle, util)
 993 AC_SEARCH_LIBS(dlopen, dl)
 994 AC_SEARCH_LIBS(socket, [socket ws2_32])
 995 AC_SEARCH_LIBS(shl_load, dld)
 996 # We only use libld in port/dynloader/aix.c
 997 case $host_os in
 998      aix*)
 999         AC_SEARCH_LIBS(ldopen, ld)
1000         ;;
1001 esac
1002 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1003 AC_SEARCH_LIBS(crypt, crypt)
1004 AC_SEARCH_LIBS(shm_open, rt)
1005 AC_SEARCH_LIBS(shm_unlink, rt)
1006 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1007 # Solaris:
1008 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1009 # Required for thread_test.c on Solaris
1010 AC_SEARCH_LIBS(sched_yield, rt)
1011 # Required for thread_test.c on Solaris 2.5:
1012 # Other ports use it too (HP-UX) so test unconditionally
1013 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1014 # Cygwin:
1015 AC_SEARCH_LIBS(shmget, cygipc)
1016
1017 if test "$with_readline" = yes; then
1018   PGAC_CHECK_READLINE
1019   if test x"$pgac_cv_check_readline" = x"no"; then
1020     AC_MSG_ERROR([readline library not found
1021 If you have readline already installed, see config.log for details on the
1022 failure.  It is possible the compiler isn't looking in the proper directory.
1023 Use --without-readline to disable readline support.])
1024   fi
1025 fi
1026
1027 if test "$with_zlib" = yes; then
1028   AC_CHECK_LIB(z, inflate, [],
1029                [AC_MSG_ERROR([zlib library not found
1030 If you have zlib already installed, see config.log for details on the
1031 failure.  It is possible the compiler isn't looking in the proper directory.
1032 Use --without-zlib to disable zlib support.])])
1033 fi
1034
1035 if test "$enable_spinlocks" = yes; then
1036   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1037 else
1038   AC_MSG_WARN([
1039 *** Not using spinlocks will cause poor performance.])
1040 fi
1041
1042 if test "$enable_atomics" = yes; then
1043   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1044 else
1045   AC_MSG_WARN([
1046 *** Not using atomic operations will cause poor performance.])
1047 fi
1048
1049 if test "$with_gssapi" = yes ; then
1050   if test "$PORTNAME" != "win32"; then
1051     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1052                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1053   else
1054     LIBS="$LIBS -lgssapi32"
1055   fi
1056 fi
1057
1058 if test "$with_openssl" = yes ; then
1059   dnl Order matters!
1060   if test "$PORTNAME" != "win32"; then
1061      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1062      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1063   else
1064      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1065      AC_SEARCH_LIBS(SSL_new, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1066   fi
1067   AC_CHECK_FUNCS([SSL_get_current_compression])
1068   # Functions introduced in OpenSSL 1.1.0. We used to check for
1069   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1070   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1071   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1072   # functions.
1073   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1074   # OpenSSL versions before 1.1.0 required setting callback functions, for
1075   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1076   # function was removed.
1077   AC_CHECK_FUNCS([CRYPTO_lock])
1078 fi
1079
1080 if test "$with_pam" = yes ; then
1081   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1082 fi
1083
1084 if test "$with_libxml" = yes ; then
1085   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1086 fi
1087
1088 if test "$with_libxslt" = yes ; then
1089   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1090 fi
1091
1092 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1093 if test "$with_ldap" = yes ; then
1094   _LIBS="$LIBS"
1095   if test "$PORTNAME" != "win32"; then
1096     AC_CHECK_LIB(ldap, ldap_bind, [],
1097                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1098                  [$EXTRA_LDAP_LIBS])
1099     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1100     if test "$enable_thread_safety" = yes; then
1101       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1102       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1103                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1104                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1105       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1106     else
1107       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1108     fi
1109   else
1110     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1111     LDAP_LIBS_FE="-lwldap32"
1112     LDAP_LIBS_BE="-lwldap32"
1113   fi
1114   LIBS="$_LIBS"
1115 fi
1116 AC_SUBST(LDAP_LIBS_FE)
1117 AC_SUBST(LDAP_LIBS_BE)
1118
1119 # for contrib/sepgsql
1120 if test "$with_selinux" = yes; then
1121   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1122                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1123 fi
1124
1125 # for contrib/uuid-ossp
1126 if test "$with_uuid" = bsd ; then
1127   # On BSD, the UUID functions are in libc
1128   AC_CHECK_FUNC(uuid_to_string,
1129     [UUID_LIBS=""],
1130     [AC_MSG_ERROR([BSD UUID functions are not present])])
1131 elif test "$with_uuid" = e2fs ; then
1132   # On macOS, the UUID functions are in libc
1133   AC_CHECK_FUNC(uuid_generate,
1134     [UUID_LIBS=""],
1135     [AC_CHECK_LIB(uuid, uuid_generate,
1136       [UUID_LIBS="-luuid"],
1137       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1138 elif test "$with_uuid" = ossp ; then
1139   AC_CHECK_LIB(ossp-uuid, uuid_export,
1140     [UUID_LIBS="-lossp-uuid"],
1141     [AC_CHECK_LIB(uuid, uuid_export,
1142       [UUID_LIBS="-luuid"],
1143       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1144 fi
1145 AC_SUBST(UUID_LIBS)
1146
1147
1148 ##
1149 ## Header files
1150 ##
1151
1152 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1153
1154 # On BSD, test for net/if.h will fail unless sys/socket.h
1155 # is included first.
1156 AC_CHECK_HEADERS(net/if.h, [], [],
1157 [AC_INCLUDES_DEFAULT
1158 #include <sys/socket.h>
1159 ])
1160
1161 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1162 # is included first.
1163 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1164 [AC_INCLUDES_DEFAULT
1165 #include <sys/param.h>
1166 ])
1167
1168 # At least on IRIX, test for netinet/tcp.h will fail unless
1169 # netinet/in.h is included first.
1170 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1171 [AC_INCLUDES_DEFAULT
1172 #include <netinet/in.h>
1173 ])
1174
1175 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1176   AC_CHECK_HEADERS(readline/readline.h, [],
1177         [AC_CHECK_HEADERS(readline.h, [],
1178                 [AC_MSG_ERROR([readline header not found
1179 If you have readline already installed, see config.log for details on the
1180 failure.  It is possible the compiler isn't looking in the proper directory.
1181 Use --without-readline to disable readline support.])])])
1182   AC_CHECK_HEADERS(readline/history.h, [],
1183         [AC_CHECK_HEADERS(history.h, [],
1184                 [AC_MSG_ERROR([history header not found
1185 If you have readline already installed, see config.log for details on the
1186 failure.  It is possible the compiler isn't looking in the proper directory.
1187 Use --without-readline to disable readline support.])])])
1188 fi
1189
1190 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1191 # Some installations of libedit usurp /usr/include/readline/, which seems
1192 # bad practice, since in combined installations readline will have its headers
1193 # there.  We might have to resort to AC_EGREP checks to make sure we found
1194 # the proper header...
1195   AC_CHECK_HEADERS(editline/readline.h, [],
1196         [AC_CHECK_HEADERS(readline.h, [],
1197                 [AC_CHECK_HEADERS(readline/readline.h, [],
1198                         [AC_MSG_ERROR([readline header not found
1199 If you have libedit already installed, see config.log for details on the
1200 failure.  It is possible the compiler isn't looking in the proper directory.
1201 Use --without-readline to disable libedit support.])])])])
1202 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1203 # not be there at all.  Hence, don't complain if not found.  We must check
1204 # though, since in yet other versions it is an independent header.
1205   AC_CHECK_HEADERS(editline/history.h, [],
1206         [AC_CHECK_HEADERS(history.h, [],
1207                 [AC_CHECK_HEADERS(readline/history.h)])])
1208 fi
1209
1210 if test "$with_zlib" = yes; then
1211   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1212 If you have zlib already installed, see config.log for details on the
1213 failure.  It is possible the compiler isn't looking in the proper directory.
1214 Use --without-zlib to disable zlib support.])])
1215 fi
1216
1217 if test "$with_gssapi" = yes ; then
1218   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1219         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1220 fi
1221
1222 if test "$with_openssl" = yes ; then
1223   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1224   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1225 fi
1226
1227 if test "$with_pam" = yes ; then
1228   AC_CHECK_HEADERS(security/pam_appl.h, [],
1229                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1230                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1231 fi
1232
1233 if test "$with_bsd_auth" = yes ; then
1234   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1235 fi
1236
1237 if test "$with_systemd" = yes ; then
1238   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1239 fi
1240
1241 if test "$with_libxml" = yes ; then
1242   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1243 fi
1244
1245 if test "$with_libxslt" = yes ; then
1246   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1247 fi
1248
1249 if test "$with_ldap" = yes ; then
1250   if test "$PORTNAME" != "win32"; then
1251      AC_CHECK_HEADERS(ldap.h, [],
1252                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1253      PGAC_LDAP_SAFE
1254   else
1255      AC_CHECK_HEADERS(winldap.h, [],
1256                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1257                       [AC_INCLUDES_DEFAULT
1258 #include <windows.h>
1259                       ])
1260   fi
1261 fi
1262
1263 if test "$with_bonjour" = yes ; then
1264   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1265 fi
1266
1267 # for contrib/uuid-ossp
1268 if test "$with_uuid" = bsd ; then
1269   AC_CHECK_HEADERS(uuid.h,
1270     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1271       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1272     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1273 elif test "$with_uuid" = e2fs ; then
1274   AC_CHECK_HEADERS(uuid/uuid.h,
1275     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1276       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1277     [AC_CHECK_HEADERS(uuid.h,
1278       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1279         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1280       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1281 elif test "$with_uuid" = ossp ; then
1282   AC_CHECK_HEADERS(ossp/uuid.h,
1283     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1284       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1285     [AC_CHECK_HEADERS(uuid.h,
1286       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1287         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1288       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1289 fi
1290
1291 if test "$PORTNAME" = "win32" ; then
1292    AC_CHECK_HEADERS(crtdefs.h)
1293 fi
1294
1295 ##
1296 ## Types, structures, compiler characteristics
1297 ##
1298
1299 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1300 AC_C_BIGENDIAN
1301 AC_C_INLINE
1302 PGAC_PRINTF_ARCHETYPE
1303 AC_C_FLEXIBLE_ARRAY_MEMBER
1304 PGAC_C_SIGNED
1305 PGAC_C_FUNCNAME_SUPPORT
1306 PGAC_C_STATIC_ASSERT
1307 PGAC_C_TYPEOF
1308 PGAC_C_TYPES_COMPATIBLE
1309 PGAC_C_BUILTIN_BSWAP16
1310 PGAC_C_BUILTIN_BSWAP32
1311 PGAC_C_BUILTIN_BSWAP64
1312 PGAC_C_BUILTIN_CONSTANT_P
1313 PGAC_C_BUILTIN_UNREACHABLE
1314 PGAC_C_COMPUTED_GOTO
1315 PGAC_C_VA_ARGS
1316 PGAC_STRUCT_TIMEZONE
1317 PGAC_UNION_SEMUN
1318 PGAC_STRUCT_SOCKADDR_UN
1319 PGAC_STRUCT_SOCKADDR_STORAGE
1320 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1321 PGAC_STRUCT_ADDRINFO
1322 AC_TYPE_INTPTR_T
1323 AC_TYPE_UINTPTR_T
1324 AC_TYPE_LONG_LONG_INT
1325
1326 PGAC_TYPE_LOCALE_T
1327
1328 AC_CHECK_TYPES([struct cmsgcred], [], [],
1329 [#include <sys/socket.h>
1330 #include <sys/param.h>
1331 #ifdef HAVE_SYS_UCRED_H
1332 #include <sys/ucred.h>
1333 #endif])
1334
1335 AC_CHECK_TYPES([struct option], [], [],
1336 [#ifdef HAVE_GETOPT_H
1337 #include <getopt.h>
1338 #endif])
1339
1340 if test "$with_zlib" = yes; then
1341   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1342   # did not).  While we could work around the lack of z_streamp, it
1343   # seems unwise to encourage people to use such old zlib versions...
1344   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1345 Use --without-zlib to disable zlib support.])],
1346                 [#include <zlib.h>])
1347 fi
1348
1349 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1350 case $host_cpu in
1351   ppc*|powerpc*)
1352     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1353     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1354         [int a = 0; int *p = &a; int r;
1355          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1356         [pgac_cv_have_ppc_mutex_hint=yes],
1357         [pgac_cv_have_ppc_mutex_hint=no])
1358     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1359     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1360         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1361     fi
1362   ;;
1363 esac
1364
1365 # Check largefile support.  You might think this is a system service not a
1366 # compiler characteristic, but you'd be wrong.  We must check this before
1367 # probing existence of related functions such as fseeko, since the largefile
1368 # defines can affect what is generated for that.
1369 if test "$PORTNAME" != "win32"; then
1370    AC_SYS_LARGEFILE
1371    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1372    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1373    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1374    dnl versions where the feature actually works, it's on by default anyway.
1375    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1376 fi
1377
1378 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1379 AC_CHECK_SIZEOF([off_t])
1380
1381 # If we don't have largefile support, can't handle segsize >= 2GB.
1382 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1383    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1384 fi
1385
1386
1387 ##
1388 ## Functions, global variables
1389 ##
1390
1391 PGAC_VAR_INT_TIMEZONE
1392 AC_FUNC_ACCEPT_ARGTYPES
1393 PGAC_FUNC_GETTIMEOFDAY_1ARG
1394 PGAC_FUNC_WCSTOMBS_L
1395
1396 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1397 # symbols that that library has no business exposing to the world.  Pending
1398 # acquisition of a clue by those developers, ignore libedit (including its
1399 # possible alias of libreadline) while checking for everything else.
1400 LIBS_including_readline="$LIBS"
1401 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1402
1403 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1404
1405 AC_REPLACE_FUNCS(fseeko)
1406 case $host_os in
1407         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1408         # Mingw uses macros to access Win32 API calls
1409         netbsd*|mingw*)
1410                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1411                 ac_cv_func_fseeko=yes;;
1412         *)
1413                 AC_FUNC_FSEEKO;;
1414 esac
1415
1416 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1417 # by calling it, 2009-04-02
1418 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1419 if test "$PORTNAME" != "solaris"; then
1420 AC_CHECK_FUNCS(posix_fadvise)
1421 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1422 fi
1423
1424 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1425 AC_CHECK_DECLS([strlcat, strlcpy])
1426 # This is probably only present on macOS, but may as well check always
1427 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1428
1429 HAVE_IPV6=no
1430 AC_CHECK_TYPE([struct sockaddr_in6],
1431         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1432          HAVE_IPV6=yes],
1433         [],
1434 [$ac_includes_default
1435 #include <netinet/in.h>])
1436 AC_SUBST(HAVE_IPV6)
1437
1438 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1439 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1440 [#include <machine/vmparam.h>
1441 #include <sys/exec.h>
1442 ],
1443 [PS_STRINGS->ps_nargvstr = 1;
1444 PS_STRINGS->ps_argvstr = "foo";])],
1445 [pgac_cv_var_PS_STRINGS=yes],
1446 [pgac_cv_var_PS_STRINGS=no])])
1447 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1448   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1449 fi
1450
1451
1452 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1453 # is missing.  Yes, there are machines that have only one.  We may
1454 # also decide to use snprintf.c if snprintf() is present but does not
1455 # have all the features we need --- see below.
1456
1457 if test "$PORTNAME" = "win32"; then
1458   # Win32 gets snprintf.c built unconditionally.
1459   #
1460   # To properly translate all NLS languages strings, we must support the
1461   # *printf() %$ format, which allows *printf() arguments to be selected
1462   # by position in the translated string.
1463   #
1464   # libintl versions < 0.13 use the native *printf() functions, and Win32
1465   # *printf() doesn't understand %$, so we must use our /port versions,
1466   # which do understand %$. libintl versions >= 0.13 include their own
1467   # *printf versions on Win32.  The libintl 0.13 release note text is:
1468   #
1469   #   C format strings with positions, as they arise when a translator
1470   #   needs to reorder a sentence, are now supported on all platforms.
1471   #   On those few platforms (NetBSD and Woe32) for which the native
1472   #   printf()/fprintf()/... functions don't support such format
1473   #   strings, replacements are provided through <libintl.h>.
1474   #
1475   # We could use libintl >= 0.13's *printf() if we were sure that we had
1476   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1477   # to guarantee that, it is best to just use our own, so we are sure to
1478   # get %$ support. In include/port.h we disable the *printf() macros
1479   # that might have been defined by libintl.
1480   #
1481   # We do this unconditionally whether NLS is used or not so we are sure
1482   # that all Win32 libraries and binaries behave the same.
1483   pgac_need_repl_snprintf=yes
1484 else
1485   pgac_need_repl_snprintf=no
1486   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1487   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1488 fi
1489
1490
1491 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1492 # include/c.h will provide declarations.  Note this is a separate test
1493 # from whether the functions exist in the C library --- there are
1494 # systems that have the functions but don't bother to declare them :-(
1495
1496 AC_CHECK_DECLS([snprintf, vsnprintf])
1497
1498
1499 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1500 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1501 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1502 #include <math.h>
1503 double glob_double;
1504 ],
1505 [return isinf(glob_double) ? 0 : 1;])],
1506 [ac_cv_func_isinf=yes],
1507 [ac_cv_func_isinf=no])])
1508
1509 if test $ac_cv_func_isinf = yes ; then
1510   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1511 else
1512   AC_LIBOBJ(isinf)
1513   # Look for a way to implement a substitute for isinf()
1514   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1515 fi
1516
1517 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1518
1519 case $host_os in
1520
1521         # Windows uses a specialised env handler
1522         # and doesn't need a replacement getpeereid because it doesn't use
1523         # Unix sockets.
1524         mingw*)
1525                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1526                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1527                 ac_cv_func_unsetenv=yes
1528                 ac_cv_func_getpeereid=yes;;
1529         *)
1530                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1531                 ;;
1532 esac
1533
1534 # System's version of getaddrinfo(), if any, may be used only if we found
1535 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1536 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1537 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1538    test "$PORTNAME" != "win32"; then
1539   AC_REPLACE_FUNCS([getaddrinfo])
1540 else
1541   AC_LIBOBJ(getaddrinfo)
1542 fi
1543
1544 # Similarly, use system's getopt_long() only if system provides struct option.
1545 if test x"$ac_cv_type_struct_option" = xyes ; then
1546   AC_REPLACE_FUNCS([getopt_long])
1547 else
1548   AC_LIBOBJ(getopt_long)
1549 fi
1550
1551 # Solaris' getopt() doesn't do what we want for long options, so always use
1552 # our version on that platform.
1553 if test "$PORTNAME" = "solaris"; then
1554   AC_LIBOBJ(getopt)
1555 fi
1556
1557 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1558 # so always use our version on Windows.
1559 if test "$PORTNAME" = "win32"; then
1560   AC_LIBOBJ(getopt)
1561   AC_LIBOBJ(getopt_long)
1562 fi
1563
1564 # Win32 (really MinGW) support
1565 if test "$PORTNAME" = "win32"; then
1566   AC_REPLACE_FUNCS(gettimeofday)
1567   AC_LIBOBJ(dirmod)
1568   AC_LIBOBJ(kill)
1569   AC_LIBOBJ(open)
1570   AC_LIBOBJ(system)
1571   AC_LIBOBJ(win32env)
1572   AC_LIBOBJ(win32error)
1573   AC_LIBOBJ(win32security)
1574   AC_LIBOBJ(win32setlocale)
1575   AC_DEFINE([HAVE_SYMLINK], 1,
1576             [Define to 1 if you have the `symlink' function.])
1577   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1578 #define WIN32_LEAN_AND_MEAN
1579 #include <windows.h>
1580 #include <string.h>
1581 #include <dbghelp.h>])
1582 fi
1583 if test x"$pgac_minidump_type" = x"yes" ; then
1584   AC_SUBST(have_win32_dbghelp,yes)
1585 else
1586   AC_SUBST(have_win32_dbghelp,no)
1587 fi
1588
1589 # Cygwin needs only a bit of that
1590 if test "$PORTNAME" = "cygwin"; then
1591   AC_LIBOBJ(dirmod)
1592 fi
1593
1594 AC_CHECK_DECLS([sys_siglist], [], [],
1595 [#include <signal.h>
1596 /* NetBSD declares sys_siglist in unistd.h.  */
1597 #ifdef HAVE_UNISTD_H
1598 # include <unistd.h>
1599 #endif
1600 ])
1601
1602 AC_CHECK_FUNC(syslog,
1603               [AC_CHECK_HEADER(syslog.h,
1604                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1605
1606 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1607 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1608   [extern int opterr; opterr = 1;])],
1609   [pgac_cv_var_int_opterr=yes],
1610   [pgac_cv_var_int_opterr=no])])
1611 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1612   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1613 fi
1614
1615 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1616 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1617   [extern int optreset; optreset = 1;])],
1618   [pgac_cv_var_int_optreset=yes],
1619   [pgac_cv_var_int_optreset=no])])
1620 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1621   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1622 fi
1623
1624 AC_CHECK_FUNCS([strtoll strtoq], [break])
1625 AC_CHECK_FUNCS([strtoull strtouq], [break])
1626
1627 if test "$with_icu" = yes; then
1628   ac_save_CPPFLAGS=$CPPFLAGS
1629   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1630
1631   # Verify we have ICU's header files
1632   AC_CHECK_HEADER(unicode/ucol.h, [],
1633         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1634
1635   CPPFLAGS=$ac_save_CPPFLAGS
1636 fi
1637
1638 # Lastly, restore full LIBS list and check for readline/libedit symbols
1639 LIBS="$LIBS_including_readline"
1640
1641 if test "$with_readline" = yes; then
1642   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1643   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1644   AC_CHECK_FUNCS([append_history history_truncate_file])
1645 fi
1646
1647
1648 # This test makes sure that run tests work at all.  Sometimes a shared
1649 # library is found by the linker, but the runtime linker can't find it.
1650 # This check should come after all modifications of compiler or linker
1651 # variables, and before any other run tests.
1652 AC_MSG_CHECKING([test program])
1653 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1654 [AC_MSG_RESULT(ok)],
1655 [AC_MSG_RESULT(failed)
1656 AC_MSG_ERROR([[
1657 Could not execute a simple test program.  This may be a problem
1658 related to locating shared libraries.  Check the file 'config.log'
1659 for the exact reason.]])],
1660 [AC_MSG_RESULT([cross-compiling])])
1661
1662 # --------------------
1663 # Run tests below here
1664 # --------------------
1665
1666 # Force use of our snprintf if system's doesn't do arg control
1667 # See comment above at snprintf test for details.
1668 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1669   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1670   if test $pgac_cv_snprintf_arg_control != yes ; then
1671     pgac_need_repl_snprintf=yes
1672   fi
1673 fi
1674
1675
1676 dnl Check to see if we have a working 64-bit integer type.
1677 dnl This breaks down into two steps:
1678 dnl (1) figure out if the compiler has a 64-bit int type with working
1679 dnl arithmetic, and if so
1680 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1681 dnl snprintf is the only library routine we really need for int8 support.)
1682 dnl It's entirely possible to have a compiler that handles a 64-bit type
1683 dnl when the C library doesn't; this is fairly likely when using gcc on
1684 dnl an older platform, for example.
1685 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1686 dnl we force our own version of snprintf() to be used instead.
1687 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1688
1689 dnl As of Postgres 8.4, we no longer support compilers without a working
1690 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1691
1692 PGAC_TYPE_64BIT_INT([long int])
1693
1694 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1695   pg_int64_type="long int"
1696 else
1697   PGAC_TYPE_64BIT_INT([long long int])
1698   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1699     pg_int64_type="long long int"
1700   else
1701     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1702   fi
1703 fi
1704
1705 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1706   [Define to the name of a signed 64-bit integer type.])
1707
1708 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1709 # we found we need to use "long long int", better check.  We cope with
1710 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1711 # work, fall back to our own snprintf emulation (which we know uses %lld).
1712
1713 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1714   if test $pgac_need_repl_snprintf = no; then
1715     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1716     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1717       # Force usage of our own snprintf, since system snprintf is broken
1718       pgac_need_repl_snprintf=yes
1719       LONG_LONG_INT_MODIFIER='ll'
1720     fi
1721   else
1722     # Here if we previously decided we needed to use our own snprintf
1723     LONG_LONG_INT_MODIFIER='ll'
1724   fi
1725 else
1726   # Here if we are not using 'long long int' at all
1727   LONG_LONG_INT_MODIFIER='l'
1728 fi
1729
1730 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1731
1732 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1733                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1734
1735 # Also force use of our snprintf if the system's doesn't support the %z flag.
1736 if test "$pgac_need_repl_snprintf" = no; then
1737   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1738   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1739     pgac_need_repl_snprintf=yes
1740   fi
1741 fi
1742
1743 # Now we have checked all the reasons to replace snprintf
1744 if test $pgac_need_repl_snprintf = yes; then
1745   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1746   AC_LIBOBJ(snprintf)
1747 fi
1748
1749 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1750 AC_CHECK_SIZEOF([void *])
1751 AC_CHECK_SIZEOF([size_t])
1752 AC_CHECK_SIZEOF([long])
1753
1754 # Decide whether float4 is passed by value: user-selectable, enabled by default
1755 AC_MSG_CHECKING([whether to build with float4 passed by value])
1756 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1757               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1758                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1759                float4passbyval=true],
1760               [float4passbyval=false])
1761 AC_MSG_RESULT([$enable_float4_byval])
1762 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1763
1764 # Decide whether float8 is passed by value.
1765 # Note: this setting also controls int8 and related types such as timestamp.
1766 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1767 # If not, trying to select it is an error.
1768 AC_MSG_CHECKING([whether to build with float8 passed by value])
1769 if test $ac_cv_sizeof_void_p -ge 8 ; then
1770   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1771 else
1772   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1773   if test "$enable_float8_byval" = yes ; then
1774     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1775   fi
1776 fi
1777 if test "$enable_float8_byval" = yes ; then
1778   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1779             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1780   float8passbyval=true
1781 else
1782   float8passbyval=false
1783 fi
1784 AC_MSG_RESULT([$enable_float8_byval])
1785 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1786
1787 # Determine memory alignment requirements for the basic C data types.
1788
1789 AC_CHECK_ALIGNOF(short)
1790 AC_CHECK_ALIGNOF(int)
1791 AC_CHECK_ALIGNOF(long)
1792 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1793   AC_CHECK_ALIGNOF(long long int)
1794 fi
1795 AC_CHECK_ALIGNOF(double)
1796
1797 # Compute maximum alignment of any basic type.
1798 # We assume long's alignment is at least as strong as char, short, or int;
1799 # but we must check long long (if it exists) and double.
1800
1801 MAX_ALIGNOF=$ac_cv_alignof_long
1802 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1803   MAX_ALIGNOF=$ac_cv_alignof_double
1804 fi
1805 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1806   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1807 fi
1808 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1809
1810
1811 # Some platforms predefine the types int8, int16, etc.  Only check
1812 # a (hopefully) representative subset.
1813 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1814 [#include <stdio.h>])
1815
1816 # Check for extensions offering the integer scalar type __int128.
1817 PGAC_TYPE_128BIT_INT
1818
1819 # Check for various atomic operations now that we have checked how to declare
1820 # 64bit integers.
1821 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1822 PGAC_HAVE_GCC__SYNC_INT32_TAS
1823 PGAC_HAVE_GCC__SYNC_INT32_CAS
1824 PGAC_HAVE_GCC__SYNC_INT64_CAS
1825 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1826 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1827
1828
1829 # Check for x86 cpuid instruction
1830 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1831 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1832   [[unsigned int exx[4] = {0, 0, 0, 0};
1833   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1834   ]])],
1835   [pgac_cv__get_cpuid="yes"],
1836   [pgac_cv__get_cpuid="no"])])
1837 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1838   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1839 fi
1840
1841 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1842 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1843   [[unsigned int exx[4] = {0, 0, 0, 0};
1844   __get_cpuid(exx[0], 1);
1845   ]])],
1846   [pgac_cv__cpuid="yes"],
1847   [pgac_cv__cpuid="no"])])
1848 if test x"$pgac_cv__cpuid" = x"yes"; then
1849   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1850 fi
1851
1852 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1853 #
1854 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1855 # with the default compiler flags. If not, check if adding the -msse4.2
1856 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1857 PGAC_SSE42_CRC32_INTRINSICS([])
1858 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1859   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1860 fi
1861 AC_SUBST(CFLAGS_SSE42)
1862
1863 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1864 # define __SSE4_2__ in that case.
1865 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1866 #ifndef __SSE4_2__
1867 #error __SSE4_2__ not defined
1868 #endif
1869 ])], [SSE4_2_TARGETED=1])
1870
1871 # Select CRC-32C implementation.
1872 #
1873 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1874 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1875 # a processor, but we can nevertheless produce code that uses the SSE
1876 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1877 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1878 # by the processor we're running on.
1879 #
1880 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1881 # in the template or configure command line.
1882 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1883   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1884     USE_SSE42_CRC32C=1
1885   else
1886     # the CPUID instruction is needed for the runtime check.
1887     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1888       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1889     else
1890       # fall back to slicing-by-8 algorithm which doesn't require any special
1891       # CPU support.
1892       USE_SLICING_BY_8_CRC32C=1
1893     fi
1894   fi
1895 fi
1896
1897 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1898 AC_MSG_CHECKING([which CRC-32C implementation to use])
1899 if test x"$USE_SSE42_CRC32C" = x"1"; then
1900   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1901   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1902   AC_MSG_RESULT(SSE 4.2)
1903 else
1904   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1905     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1906     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1907     AC_MSG_RESULT(SSE 4.2 with runtime check)
1908   else
1909     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1910     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1911     AC_MSG_RESULT(slicing-by-8)
1912   fi
1913 fi
1914 AC_SUBST(PG_CRC32C_OBJS)
1915
1916
1917 # Select semaphore implementation type.
1918 if test "$PORTNAME" != "win32"; then
1919   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1920     # Need sem_open for this
1921     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1922   fi
1923   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1924     # Need sem_init for this
1925     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1926   fi
1927   AC_MSG_CHECKING([which semaphore API to use])
1928   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1929     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1930     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1931     sematype="named POSIX"
1932   else
1933     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1934       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1935       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1936       sematype="unnamed POSIX"
1937     else
1938       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1939       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1940       sematype="System V"
1941     fi
1942   fi
1943   AC_MSG_RESULT([$sematype])
1944 else
1945   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1946   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1947 fi
1948
1949
1950 # Select shared-memory implementation type.
1951 if test "$PORTNAME" != "win32"; then
1952   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1953   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1954 else
1955   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1956   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1957 fi
1958
1959 # Select random number source
1960 #
1961 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
1962 # in the template or configure command line.
1963
1964 # If not selected manually, try to select a source automatically.
1965 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
1966   if test x"$with_openssl" = x"yes" ; then
1967     USE_OPENSSL_RANDOM=1
1968   elif test "$PORTNAME" = "win32" ; then
1969     USE_WIN32_RANDOM=1
1970   else
1971     AC_CHECK_FILE([/dev/urandom], [], [])
1972
1973     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
1974       USE_DEV_URANDOM=1
1975     fi
1976   fi
1977 fi
1978
1979 AC_MSG_CHECKING([which random number source to use])
1980 if test "$enable_strong_random" = yes ; then
1981   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
1982     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
1983     AC_MSG_RESULT([OpenSSL])
1984   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
1985     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
1986     AC_MSG_RESULT([Windows native])
1987   elif test x"$USE_DEV_URANDOM" = x"1" ; then
1988     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
1989     AC_MSG_RESULT([/dev/urandom])
1990   else
1991     AC_MSG_ERROR([
1992 no source of strong random numbers was found
1993 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
1994 for authentication protocols. You can use --disable-strong-random to use a
1995 built-in pseudo random number generator, but that may be insecure.])
1996   fi
1997   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
1998 else
1999     AC_MSG_RESULT([weak builtin PRNG])
2000     AC_MSG_WARN([
2001 *** Not using a strong random number source may be insecure.])
2002 fi
2003
2004 # If not set in template file, set bytes to use libc memset()
2005 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2006   MEMSET_LOOP_LIMIT=1024
2007 fi
2008 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2009
2010
2011 if test "$enable_nls" = yes ; then
2012   PGAC_CHECK_GETTEXT
2013 fi
2014
2015 # Check for Tcl configuration script tclConfig.sh
2016 if test "$with_tcl" = yes; then
2017     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2018     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2019                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2020     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2021     if test "$TCL_SHARED_BUILD" != 1; then
2022       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2023 Use --without-tcl to disable building PL/Tcl.])
2024     fi
2025     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2026     ac_save_CPPFLAGS=$CPPFLAGS
2027     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2028     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2029     CPPFLAGS=$ac_save_CPPFLAGS
2030 fi
2031
2032 # check for <perl.h>
2033 if test "$with_perl" = yes; then
2034   ac_save_CPPFLAGS=$CPPFLAGS
2035   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2036   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2037                   [#include <EXTERN.h>])
2038   # While we're at it, check that we can link to libperl.
2039   # On most platforms, if perl.h is there then libperl.so will be too, but at
2040   # this writing Debian packages them separately.  There is no known reason to
2041   # waste cycles on separate probes for the Tcl or Python libraries, though.
2042   pgac_save_LIBS=$LIBS
2043   LIBS="$perl_embed_ldflags"
2044   AC_MSG_CHECKING([for libperl])
2045   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2046 #include <EXTERN.h>
2047 #include <perl.h>
2048 ],  [perl_alloc();])],
2049     [AC_MSG_RESULT(yes)],
2050     [AC_MSG_RESULT(no)
2051      AC_MSG_ERROR([libperl library is required for Perl])])
2052   LIBS=$pgac_save_LIBS
2053   CPPFLAGS=$ac_save_CPPFLAGS
2054 fi
2055
2056 # check for <Python.h>
2057 if test "$with_python" = yes; then
2058   ac_save_CPPFLAGS=$CPPFLAGS
2059   CPPFLAGS="$python_includespec $CPPFLAGS"
2060   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2061   CPPFLAGS=$ac_save_CPPFLAGS
2062 fi
2063
2064 #
2065 # Check for DocBook and tools
2066 #
2067 PGAC_PROG_NSGMLS
2068 PGAC_CHECK_DOCBOOK(4.2)
2069 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2070 PGAC_PATH_PROGS(XMLLINT, xmllint)
2071 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2072 PGAC_PATH_PROGS(OSX, [osx sgml2xml sx])
2073 PGAC_PATH_PROGS(FOP, fop)
2074
2075 #
2076 # Check for test tools
2077 #
2078 if test "$enable_tap_tests" = yes; then
2079   # Check for necessary modules, unless user has specified the "prove" to use;
2080   # in that case it's her responsibility to have a working configuration.
2081   # (prove might be part of a different Perl installation than perl, eg on
2082   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2083   if test -z "$PROVE"; then
2084     AX_PROG_PERL_MODULES(IPC::Run, ,
2085       AC_MSG_ERROR([Perl module IPC::Run is required to run TAP tests]))
2086   fi
2087   # Now make sure we know where prove is
2088   PGAC_PATH_PROGS(PROVE, prove)
2089   if test -z "$PROVE"; then
2090     AC_MSG_ERROR([prove not found])
2091   fi
2092 fi
2093
2094 # Thread testing
2095
2096 # We have to run the thread test near the end so we have all our symbols
2097 # defined.  Cross compiling throws a warning.
2098 #
2099 if test "$enable_thread_safety" = yes; then
2100 if test "$PORTNAME" != "win32"
2101 then
2102 AC_MSG_CHECKING([thread safety of required library functions])
2103
2104 _CFLAGS="$CFLAGS"
2105 _LIBS="$LIBS"
2106 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2107 LIBS="$LIBS $PTHREAD_LIBS"
2108 AC_RUN_IFELSE(
2109   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2110   [AC_MSG_RESULT(yes)],
2111   [AC_MSG_RESULT(no)
2112   AC_MSG_ERROR([thread test program failed
2113 This platform is not thread-safe.  Check the file 'config.log' or compile
2114 and run src/test/thread/thread_test for the exact reason.
2115 Use --disable-thread-safety to disable thread safety.])],
2116   [AC_MSG_RESULT(maybe)
2117   AC_MSG_WARN([
2118 *** Skipping thread test program because of cross-compile build.
2119 *** Run the program in src/test/thread on the target machine.
2120 ])])
2121 CFLAGS="$_CFLAGS"
2122 LIBS="$_LIBS"
2123 else
2124 AC_MSG_WARN([*** skipping thread test on Win32])
2125 fi
2126 fi
2127
2128 # If compiler will take -Wl,--as-needed (or various platform-specific
2129 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2130 # trying to filter LIBS to the minimum for each executable.
2131 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2132 # libreadline; therefore we postpone testing it until we know what library
2133 # dependencies readline has.  The test code will try to link with $LIBS.
2134 if test "$with_readline" = yes; then
2135   link_test_func=readline
2136 else
2137   link_test_func=exit
2138 fi
2139
2140 if test "$PORTNAME" = "darwin"; then
2141   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2142 elif test "$PORTNAME" = "openbsd"; then
2143   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2144 else
2145   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2146 fi
2147
2148 # Create compiler version string
2149 if test x"$GCC" = x"yes" ; then
2150   cc_string=`${CC} --version | sed q`
2151   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2152 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2153   cc_string=`${CC} -V 2>&1 | sed q`
2154 else
2155   cc_string=$CC
2156 fi
2157
2158 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2159                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2160                    [A string containing the version number, platform, and C compiler])
2161
2162 # Supply a numeric version string for use by 3rd party add-ons
2163 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2164 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2165 tr '.' '        ' |
2166 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2167 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2168 AC_SUBST(PG_VERSION_NUM)
2169
2170
2171 # Begin output steps
2172
2173 AC_MSG_NOTICE([using compiler=$cc_string])
2174 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2175 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2176 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2177
2178 # prepare build tree if outside source tree
2179 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2180 # Note 2: /bin/pwd might be better than shell's built-in at getting
2181 #         a symlink-free name.
2182 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2183   vpath_build=no
2184 else
2185   vpath_build=yes
2186   if test "$no_create" != yes; then
2187     _AS_ECHO_N([preparing build tree... ])
2188     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2189     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2190       || AC_MSG_ERROR(failed)
2191     AC_MSG_RESULT(done)
2192   fi
2193 fi
2194 AC_SUBST(vpath_build)
2195
2196
2197 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2198
2199 AC_CONFIG_LINKS([
2200   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2201   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2202   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2203   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2204   src/include/pg_config_os.h:src/include/port/${template}.h
2205   src/Makefile.port:src/makefiles/Makefile.${template}
2206 ])
2207
2208 if test "$PORTNAME" = "win32"; then
2209 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2210 # Links sometimes fail undetected on Mingw -
2211 # so here we detect it and warn the user
2212 for FILE in $CONFIG_LINKS
2213  do
2214         # test -e works for symlinks in the MinGW console
2215         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2216  done
2217 ])
2218 fi
2219
2220 AC_CONFIG_HEADERS([src/include/pg_config.h],
2221 [
2222 # Update timestamp for pg_config.h (see Makefile.global)
2223 echo >src/include/stamp-h
2224 ])
2225
2226 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2227 [
2228 # Update timestamp for pg_config_ext.h (see Makefile.global)
2229 echo >src/include/stamp-ext-h
2230 ])
2231
2232 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2233                   [echo >src/interfaces/ecpg/include/stamp-h])
2234
2235 AC_OUTPUT