granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.265 2003/06/15 04:07:58 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 # Character set recode (--enable-recode)
 157 #
 158 AC_MSG_CHECKING([whether to build with recode support])
 159 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable single-byte recode support],
 160               [AC_DEFINE([CYR_RECODE], 1,
 161                          [Define to 1 if you want single-byte recode support. (--enable-recode)])])
 162 AC_MSG_RESULT([$enable_recode])
 163
 164
 165 #
 166 # NLS
 167 #
 168 AC_MSG_CHECKING([whether NLS is wanted])
 169 PGAC_ARG_OPTARG(enable, nls,
 170                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 171                 [],
 172                 [WANTED_LANGUAGES=$enableval],
 173                 [AC_DEFINE(ENABLE_NLS, 1,
 174                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 175 AC_MSG_RESULT([$enable_nls])
 176 AC_SUBST(enable_nls)
 177 AC_SUBST(WANTED_LANGUAGES)
 178
 179 #
 180 # Default port number (--with-pgport), default 5432
 181 #
 182 AC_MSG_CHECKING([for default port number])
 183 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 184              [default_port=$withval],
 185              [default_port=5432])
 186 AC_MSG_RESULT([$default_port])
 187 # Need both of these because some places want an integer and some a string
 188 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 189 [Define to the default TCP port number on which the server listens and
 190 to which clients will try to connect to.  This can be overridden at
 191 run-time, but it's convenient if your clients have the right default
 192 compiled in.  (--with-pgport=PORTNUM)])
 193 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 194                    [Define to the default TCP port number as string constant.])
 195 AC_SUBST(default_port)
 196
 197 #
 198 # Option to disable shared libraries
 199 #
 200 PGAC_ARG_BOOL(enable, shared, yes,
 201               [  --disable-shared        do not build shared libraries])
 202 AC_SUBST(enable_shared)
 203
 204 #
 205 # '-rpath'-like feature can be disabled
 206 #
 207 PGAC_ARG_BOOL(enable, rpath, yes,
 208               [  --disable-rpath         do not embed shared library search path in executables])
 209 AC_SUBST(enable_rpath)
 210
 211
 212 #
 213 # --enable-debug adds -g to compiler flags
 214 #
 215 PGAC_ARG_BOOL(enable, debug, no,
 216               [  --enable-debug          build with debugging symbols (-g)])
 217 AC_SUBST(enable_debug)
 218
 219 #
 220 # C compiler
 221 #
 222
 223 # For historical reasons you can also use --with-CC to specify the C compiler
 224 # to use, although the standard way to do this is to set the CC environment
 225 # variable.
 226 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 227
 228 case $template in
 229   aix) pgac_cc_list="gcc xlc";;
 230  irix) pgac_cc_list="cc";; # no gcc
 231     *) pgac_cc_list="gcc cc";;
 232 esac
 233
 234 AC_PROG_CC([$pgac_cc_list])
 235 # Read the template
 236 . "$srcdir/src/template/$template" || exit
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 fi
 241 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 242   CFLAGS="$CFLAGS -g"
 243 fi
 244 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 245
 246 # Check if the compiler still works with the template settings
 247 AC_MSG_CHECKING([whether the C compiler still works])
 248 AC_TRY_LINK([], [return 0;],
 249   [AC_MSG_RESULT(yes)],
 250   [AC_MSG_RESULT(no)
 251    AC_MSG_ERROR([cannot proceed])])
 252
 253 # Defend against gcc -ffastmath
 254 if test "$GCC" = yes; then
 255 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 256 choke me
 257 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 258 fi
 259
 260 AC_PROG_CPP
 261 AC_SUBST(GCC)
 262
 263 # Create compiler version string
 264 if test x"$GCC" = x"yes" ; then
 265   cc_string="GCC `${CC} --version | sed q`"
 266 else
 267   cc_string=$CC
 268 fi
 269 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 270                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 271                    [A string containing the version number, platform, and C compiler])
 272
 273
 274 #
 275 # Automatic dependency tracking
 276 #
 277 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 278               [autodepend=yes])
 279 AC_SUBST(autodepend)
 280
 281
 282 #
 283 # Enable assert checks
 284 #
 285 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 286               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 287                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 288
 289
 290 #
 291 # Include directories
 292 #
 293 ac_save_IFS=$IFS
 294 IFS="${IFS}:"
 295 # SRCH_INC comes from the template file
 296 for dir in $with_includes $SRCH_INC; do
 297   if test -d "$dir"; then
 298     INCLUDES="$INCLUDES -I$dir"
 299   else
 300     AC_MSG_WARN([*** Include directory $dir does not exist.])
 301   fi
 302 done
 303 IFS=$ac_save_IFS
 304 AC_SUBST(INCLUDES)
 305
 306
 307 #
 308 # Library directories
 309 #
 310 ac_save_IFS=$IFS
 311 IFS="${IFS}:"
 312 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 313 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 314   if test -d "$dir"; then
 315     LIBDIRS="$LIBDIRS -L$dir"
 316   else
 317     AC_MSG_WARN([*** Library directory $dir does not exist.])
 318   fi
 319 done
 320 IFS=$ac_save_IFS
 321
 322 #
 323 # Enable libpq to be thread-safe
 324 #
 325 AC_MSG_CHECKING([allow threaded libpq])
 326 PGAC_ARG_BOOL(with, threads, no, [  --with-threads          allow libpq and ecpg to be thread-safe],
 327               [AC_DEFINE([USE_THREADS], 1, [Define to 1 to build libpq and ecpg to be thread-safe. (--with-threads)])])
 328
 329 AC_MSG_RESULT([$with_threads])
 330 AC_SUBST(with_threads)
 331
 332 #
 333 # Tcl/Tk
 334 #
 335 AC_MSG_CHECKING([whether to build with Tcl])
 336 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 337 AC_MSG_RESULT([$with_tcl])
 338 AC_SUBST([with_tcl])
 339
 340 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 341 AC_MSG_CHECKING([whether to build with Tk])
 342 if test "$with_tcl" = yes; then
 343   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 344 else
 345   with_tk=no
 346 fi
 347 AC_MSG_RESULT([$with_tk])
 348 AC_SUBST([with_tk])
 349
 350
 351 # We see if the path to the Tcl/Tk configuration scripts is specified.
 352 # This will override the use of tclsh to find the paths to search.
 353
 354 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 355
 356 # We see if the path to the Tk configuration scripts is specified.
 357 # This will override the use of tclsh to find the paths to search.
 358
 359 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 360
 361 #
 362 # Optionally build Perl modules (PL/Perl)
 363 #
 364 AC_MSG_CHECKING([whether to build Perl modules])
 365 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 366 AC_MSG_RESULT([$with_perl])
 367 AC_SUBST(with_perl)
 368
 369 #
 370 # Optionally build Python interface module
 371 #
 372 AC_MSG_CHECKING([whether to build Python modules])
 373 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 374 AC_MSG_RESULT([$with_python])
 375 AC_SUBST(with_python)
 376
 377 #
 378 # Optionally build the Java/JDBC tools
 379 #
 380 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 381 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 382 [AC_MSG_RESULT(yes)
 383 PGAC_PATH_ANT
 384 if test -z "$ANT"; then
 385   AC_MSG_ERROR([Ant is required to build Java components
 386 If you have Ant already installed, see config.log for details on the failure.])
 387 fi
 388 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 389   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 390 fi],
 391 [AC_MSG_RESULT(no)])
 392 AC_SUBST(with_java)
 393
 394 dnl A note on the Kerberos and OpenSSL options:
 395 dnl
 396 dnl The user can give an argument to the option in order the specify
 397 dnl the base path of the respective installation (what he specified
 398 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 399 dnl then we take the path where the package installs by default. This
 400 dnl way the user doesn't have to use redundant --with-includes and
 401 dnl --with-libraries options, but he can still use them if the layout
 402 dnl is non-standard.
 403
 404 #
 405 # Kerberos 4
 406 #
 407 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 408 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 409                 [krb4_prefix=/usr/athena],
 410                 [krb4_prefix=$withval],
 411 [
 412   AC_MSG_RESULT(yes)
 413   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 414
 415   if test -d "$krb4_prefix/include"; then
 416     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 417   fi
 418   if test -d "$krb4_prefix/lib"; then
 419     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 420   fi
 421
 422   krb_srvtab="/etc/srvtab"
 423 ],
 424 [AC_MSG_RESULT(no)])
 425
 426 AC_SUBST(with_krb4)
 427
 428
 429 #
 430 # Kerberos 5
 431 #
 432 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 433 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 434               [krb5_prefix=/usr/athena],
 435               [krb5_prefix=$withval],
 436 [
 437   AC_MSG_RESULT([yes])
 438   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 439
 440   if test -d "$krb5_prefix/include"; then
 441     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 442   fi
 443   if test -d "$krb5_prefix/lib"; then
 444     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 445   fi
 446
 447   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 448 ],
 449 [AC_MSG_RESULT(no)])
 450
 451 AC_SUBST(with_krb5)
 452
 453
 454 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 455 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 456   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 457 fi
 458
 459 AC_SUBST(krb_srvtab)
 460
 461
 462 #
 463 # Kerberos configuration parameters
 464 #
 465 PGAC_ARG_REQ(with, krb-srvnam,
 466              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 467              [],
 468              [with_krb_srvnam="postgres"])
 469 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 470                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 471
 472
 473 #
 474 # PAM
 475 #
 476 AC_MSG_CHECKING([whether to build with PAM support])
 477 PGAC_ARG_BOOL(with, pam, no,
 478               [  --with-pam              build with PAM support],
 479               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 480 AC_MSG_RESULT([$with_pam])
 481 AC_SUBST(with_pam)
 482
 483
 484 #
 485 # Rendezvous
 486 #
 487 AC_MSG_CHECKING([whether to build with Rendezvous support])
 488 PGAC_ARG_BOOL(with, rendezvous, no,
 489               [  --with-rendezvous       build with Rendezvous support],
 490               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 491 AC_MSG_RESULT([$with_rendezvous])
 492 AC_SUBST(with_rendezvous)
 493
 494
 495 #
 496 # OpenSSL
 497 #
 498 PGAC_ARG_OPTARG(with, openssl,
 499                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 500                 [openssl_prefix=/usr/local/ssl],
 501                 [openssl_prefix=$withval],
 502 [
 503   AC_MSG_RESULT([building with OpenSSL support])
 504   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 505
 506   if test -d "${openssl_prefix}/include" ; then
 507     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 508   fi
 509   if test -d "${openssl_prefix}/lib" ; then
 510     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 511   fi
 512 ])
 513
 514 AC_SUBST(with_openssl)
 515
 516
 517 #
 518 # Readline
 519 #
 520 PGAC_ARG_BOOL(with, readline, yes,
 521               [  --without-readline      do not use Readline])
 522
 523 #
 524 # Zlib
 525 #
 526 PGAC_ARG_BOOL(with, zlib, yes,
 527               [  --without-zlib          do not use Zlib])
 528
 529
 530 #
 531 # Elf
 532 #
 533
 534 # Assume system is ELF if it predefines __ELF__ as 1,
 535 # otherwise believe host_os based default.
 536 case $host_os in
 537     freebsd1*|freebsd2*) elf=no;;
 538     freebsd3*|freebsd4*) elf=yes;;
 539 esac
 540
 541 AC_EGREP_CPP(yes,
 542 [#if __ELF__
 543   yes
 544 #endif
 545 ],
 546 [ELF_SYS=true],
 547 [if test "X$elf" = "Xyes" ; then
 548   ELF_SYS=true
 549 else
 550   ELF_SYS=
 551 fi])
 552 AC_SUBST(ELF_SYS)
 553
 554 #
 555 # Pthreads
 556 #
 557 # For each platform, we need to know about any special compile and link
 558 # libraries, and whether the normal C function names are thread-safe.
 559 #
 560 NEED_REENTRANT_FUNC_NAMES=no
 561 if test "$with_threads" = yes; then
 562 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --with-threads])])
 563
 564 if test "$SUPPORTS_THREADS" != yes; then
 565 AC_MSG_ERROR([
 566 Cannot enable threads on your platform.
 567 Please report your platform threading info to the PostgreSQL mailing lists
 568 so it can be added to the next release.  Report any compile flags, link flags,
 569 functions, or libraries required for threading support.
 570 ])
 571 fi
 572 fi
 573 AC_SUBST(THREAD_CFLAGS)
 574 AC_SUBST(THREAD_LIBS)
 575
 576
 577 #
 578 # Assignments
 579 #
 580
 581 CPPFLAGS="$CPPFLAGS $INCLUDES"
 582 LDFLAGS="$LDFLAGS $LIBDIRS"
 583
 584 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 585 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 586
 587
 588 AC_PROG_AWK
 589 PGAC_PATH_FLEX
 590 AC_PROG_LN_S
 591 AC_PROG_LD
 592 AC_SUBST(LD)
 593 AC_SUBST(with_gnu_ld)
 594 case $host_os in sysv5*)
 595   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 596   [
 597     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 598     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 599     LDFLAGS=$pgac_save_LDFLAGS
 600   ])
 601   ld_R_works=$pgac_cv_prog_ld_R
 602   AC_SUBST(ld_R_works)
 603 esac
 604 AC_PROG_RANLIB
 605 AC_CHECK_PROGS(LORDER, lorder)
 606 AC_PATH_PROG(TAR, tar)
 607 PGAC_CHECK_STRIP
 608
 609 AC_CHECK_PROGS(YACC, ['bison -y'])
 610
 611 if test "$YACC"; then
 612   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 613     AC_MSG_WARN([
 614 *** The installed version of Bison is too old.  PostgreSQL needs
 615 *** Bison version 1.875 or later.])
 616   fi
 617 fi
 618
 619 if test -z "$YACC"; then
 620   AC_MSG_WARN([
 621 *** Without Bison you will not be able to build PostgreSQL from CVS or
 622 *** change any of the parser definition files.  You can obtain Bison from
 623 *** a GNU mirror site.  (If you are using the official distribution of
 624 *** PostgreSQL then you do not need to worry about this because the Bison
 625 *** output is pre-generated.)  To use a different yacc program (possible,
 626 *** but not recommended), set the environment variable YACC before running
 627 *** 'configure'.])
 628 fi
 629 AC_SUBST(YFLAGS)
 630
 631 PGAC_PATH_PERL
 632 if test "$with_perl" = yes; then
 633   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 634   PGAC_CHECK_PERL_EMBED_LDFLAGS
 635 fi
 636
 637 if test "$with_python" = yes; then
 638   PGAC_PATH_PYTHON
 639   PGAC_CHECK_PYTHON_MODULE_SETUP
 640   PGAC_CHECK_PYTHON_EMBED_SETUP
 641 fi
 642
 643
 644 ##
 645 ## Libraries
 646 ##
 647
 648 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 649 then
 650         AC_CHECK_LIB(bsd,      main)
 651 fi
 652 AC_CHECK_LIB(util,     setproctitle)
 653 AC_CHECK_LIB(m,        main)
 654 AC_CHECK_LIB(dl,       main)
 655 AC_CHECK_LIB(nsl,      main)
 656 AC_CHECK_LIB(socket,   main)
 657 AC_CHECK_LIB(ipc,      main)
 658 AC_CHECK_LIB(IPC,      main)
 659 AC_CHECK_LIB(lc,       main)
 660 AC_CHECK_LIB(dld,      main)
 661 AC_CHECK_LIB(ld,       main)
 662 AC_CHECK_LIB(compat,   main)
 663 AC_CHECK_LIB(BSD,      main)
 664 AC_CHECK_LIB(gen,      main)
 665 AC_CHECK_LIB(PW,       main)
 666 AC_CHECK_LIB(resolv,   main)
 667 AC_CHECK_LIB(wsock32,   main)
 668 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 669 # QNX:
 670 AC_CHECK_LIB(unix, main)
 671 AC_SEARCH_LIBS(crypt,  crypt)
 672 # BeOS:
 673 AC_CHECK_LIB(bind, __inet_ntoa)
 674 # Solaris:
 675 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 676 # Cygwin:
 677 AC_CHECK_LIB(cygipc, shmget)
 678
 679 if test "$with_readline" = yes; then
 680   PGAC_CHECK_READLINE
 681   if test x"$pgac_cv_check_readline" = x"no"; then
 682     AC_MSG_ERROR([readline library not found
 683 If you have readline already installed, see config.log for details on the
 684 failure.  It is possible the compiler isn't looking in the proper directory.
 685 Use --without-readline to disable readline support.])
 686   fi
 687 fi
 688
 689 if test "$with_zlib" = yes; then
 690   AC_CHECK_LIB(z, inflate, [],
 691                [AC_MSG_ERROR([zlib library not found
 692 If you have zlib already installed, see config.log for details on the
 693 failure.  It is possible the compiler isn't looking in the proper directory.
 694 Use --without-zlib to disable zlib support.])])
 695 fi
 696
 697 if test "$with_krb4" = yes ; then
 698   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 699   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 700   AC_REPLACE_FUNCS([gethostname])
 701 fi
 702
 703 if test "$with_krb5" = yes ; then
 704   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 705                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 706   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 707                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 708   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 709                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 710 fi
 711
 712 if test "$with_openssl" = yes ; then
 713   dnl Order matters!
 714   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 715   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 716 fi
 717
 718 if test "$with_pam" = yes ; then
 719   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 720 fi
 721
 722
 723 ##
 724 ## Header files
 725 ##
 726
 727 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 728 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 729
 730 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 731 # netinet/in.h is included first.
 732 AC_CHECK_HEADERS(netinet/in.h)
 733 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 734 [AC_INCLUDES_DEFAULT
 735 #ifdef HAVE_NETINET_IN_H
 736 #include <netinet/in.h>
 737 #endif
 738 ])
 739
 740 if test "$with_readline" = yes; then
 741   AC_CHECK_HEADERS(readline/readline.h, [],
 742                    [AC_CHECK_HEADERS(editline/readline.h, [],
 743                          [AC_CHECK_HEADERS(readline.h, [],
 744                                      [AC_MSG_ERROR([readline header not found
 745 If you have readline already installed, see config.log for details on the
 746 failure.  It is possible the compiler isn't looking in the proper directory.
 747 Use --without-readline to disable readline support.])])])])
 748   AC_CHECK_HEADERS(readline/history.h, [],
 749                    [AC_CHECK_HEADERS(editline/history.h, [],
 750                          [AC_CHECK_HEADERS(history.h, [],
 751                                      [AC_MSG_ERROR([history header not found
 752 If you have readline already installed, see config.log for details on the
 753 failure.  It is possible the compiler isn't looking in the proper directory.
 754 Use --without-readline to disable readline support.])])])])
 755 fi
 756
 757 if test "$with_zlib" = yes; then
 758   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 759 If you have zlib already installed, see config.log for details on the
 760 failure.  It is possible the compiler isn't looking in the proper directory.
 761 Use --without-zlib to disable zlib support.])])
 762 fi
 763
 764 if test "$with_krb4" = yes ; then
 765   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 766 fi
 767
 768 if test "$with_krb5" = yes ; then
 769   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 770   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 771 fi
 772
 773 if test "$with_openssl" = yes ; then
 774   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 775   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 776 fi
 777
 778 if test "$with_pam" = yes ; then
 779   AC_CHECK_HEADERS(security/pam_appl.h, [],
 780                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 781                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 782 fi
 783
 784 if test "$with_rendezvous" = yes ; then
 785   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 786 fi
 787
 788
 789 ##
 790 ## Types, structures, compiler characteristics
 791 ##
 792
 793 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 794 AC_C_CONST
 795 AC_C_INLINE
 796 AC_C_STRINGIZE
 797 PGAC_C_SIGNED
 798 AC_C_VOLATILE
 799 PGAC_C_FUNCNAME_SUPPORT
 800 PGAC_STRUCT_TIMEZONE
 801 PGAC_UNION_SEMUN
 802 PGAC_STRUCT_SOCKADDR_UN
 803 PGAC_STRUCT_SOCKADDR_STORAGE
 804 PGAC_STRUCT_ADDRINFO
 805
 806 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 807 [#include <sys/param.h>
 808 #include <sys/types.h>
 809 #include <sys/socket.h>
 810 #include <sys/ucred.h>])
 811
 812 if test "$with_zlib" = yes; then
 813   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 814   # did not).  While we could work around the lack of z_streamp, it
 815   # seems unwise to encourage people to use such old zlib versions...
 816   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 817 Use --without-zlib to disable zlib support.])],
 818                 [#include <zlib.h>])
 819 fi
 820
 821 if test "$with_krb5" = yes; then
 822 # Check for differences between MIT and Heimdal (KTH) releases
 823   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 824                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 825                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 826                                      [#include <krb5.h>])],
 827                    [#include <krb5.h>])
 828   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 829                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 830                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 831                                      [#include <krb5.h>])],
 832                    [#include <krb5.h>])
 833 fi
 834
 835
 836 ##
 837 ## Functions, global variables
 838 ##
 839
 840 PGAC_VAR_INT_TIMEZONE
 841 AC_FUNC_ACCEPT_ARGTYPES
 842 PGAC_FUNC_GETTIMEOFDAY_1ARG
 843
 844 # SunOS doesn't handle negative byte comparisons properly with +/- return
 845 AC_FUNC_MEMCMP
 846
 847 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 848
 849 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 850
 851 AC_CHECK_TYPE([struct sockaddr_in6],
 852               [AC_CHECK_FUNC(inet_ntop,
 853                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])])],
 854               [],
 855 [$ac_includes_default
 856 #include <netinet/in.h>])
 857
 858 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 859 [AC_TRY_LINK(
 860 [#include <machine/vmparam.h>
 861 #include <sys/exec.h>
 862 ],
 863 [PS_STRINGS->ps_nargvstr = 1;
 864 PS_STRINGS->ps_argvstr = "foo";],
 865 [pgac_cv_var_PS_STRINGS=yes],
 866 [pgac_cv_var_PS_STRINGS=no])])
 867 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 868   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 869 fi
 870
 871
 872 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 873 # is missing.  Yes, there are machines that have only one.  We may
 874 # also decide to use snprintf.c if snprintf() is present but does not
 875 # have working "long long int" support -- see below.
 876
 877 pgac_need_repl_snprintf=no
 878 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 879 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 880
 881
 882 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 883 # include/c.h will provide declarations.  Note this is a separate test
 884 # from whether the functions exist in the C library --- there are
 885 # systems that have the functions but don't bother to declare them :-(
 886
 887 AC_CHECK_DECLS([snprintf, vsnprintf])
 888
 889
 890 # do this one the hard way in case isinf() is a macro
 891 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 892 [AC_TRY_LINK(
 893 [#include <math.h>
 894 ],
 895 [double x = 0.0; int res = isinf(x);],
 896 [ac_cv_func_isinf=yes],
 897 [ac_cv_func_isinf=no])])
 898
 899 if test $ac_cv_func_isinf = yes ; then
 900   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 901 else
 902   AC_LIBOBJ(isinf)
 903   # Look for a way to implement a substitute for isinf()
 904   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 905 fi
 906
 907 AC_REPLACE_FUNCS([crypt fseeko getopt getopt_long getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 908
 909 # system's version of getaddrinfo(), if any, may be used only if we found
 910 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 911 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 912   AC_REPLACE_FUNCS([getaddrinfo])
 913 else
 914   AC_LIBOBJ(getaddrinfo)
 915 fi
 916
 917 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 918 # We override the previous test that said fseeko/ftello didn't exist
 919 # OS tests are also done in include/c.h and port/fseeko.c
 920 case $host_os in bsdi*|netbsd*)
 921 ac_cv_func_fseeko=yes
 922 esac
 923
 924 # Solaris has a very slow qsort in certain cases, so we replace it.
 925 case $host_os in solaris*)
 926 AC_LIBOBJ(qsort) ;;
 927 esac
 928
 929 # Win32 can't to rename or unlink on an open file
 930 case $host_os in mingw*)
 931 AC_LIBOBJ(dirmod)
 932 AC_LIBOBJ(copydir)
 933 AC_LIBOBJ(gettimeofday) ;;
 934 esac
 935
 936 if test "$with_readline" = yes; then
 937   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 938   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 939   AC_CHECK_FUNCS([replace_history_entry])
 940 fi
 941
 942
 943 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 944 AC_MSG_CHECKING(for finite)
 945 AC_TRY_LINK([#include <math.h>],
 946             [int dummy=finite(1.0);],
 947             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 948 AC_MSG_RESULT(yes)],
 949             [AC_MSG_RESULT(no)])
 950
 951 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 952 dnl (especially on GNU libc)
 953 dnl See also comments in c.h.
 954 AC_MSG_CHECKING(for sigsetjmp)
 955 AC_TRY_LINK([#include <setjmp.h>],
 956             [sigjmp_buf x; sigsetjmp(x, 1);],
 957             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 958 AC_MSG_RESULT(yes)],
 959             [AC_MSG_RESULT(no)])
 960
 961 AC_CHECK_FUNC(syslog,
 962               [AC_CHECK_HEADER(syslog.h,
 963                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 964
 965 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 966 [AC_TRY_LINK([#include <unistd.h>],
 967   [extern int optreset; optreset = 1;],
 968   [pgac_cv_var_int_optreset=yes],
 969   [pgac_cv_var_int_optreset=no])])
 970 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 971   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 972 fi
 973
 974 AC_CHECK_FUNCS([strtoll strtoq], [break])
 975 AC_CHECK_FUNCS([strtoull strtouq], [break])
 976
 977 # Check for one of atexit() or on_exit()
 978 AC_CHECK_FUNCS(atexit, [],
 979                [AC_CHECK_FUNCS(on_exit, [],
 980                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 981
 982 AC_FUNC_FSEEKO
 983
 984 #
 985 # Check for re-entrant versions of certain functions
 986 #
 987 # Include special flags if threads are enabled _and_ if required for
 988 # threading on this platform.  Some platforms have *_r functions but
 989 # their natively named funcs are threadsafe, and should be used instead.
 990 #
 991 # One trick here is that if the don't call AC_CHECK_FUNCS, the
 992 # functions are marked "not found", which is perfect.
 993 #
 994 if test "$NEED_REENTRANT_FUNC_NAMES" = yes ; then
 995 _CFLAGS="$CFLAGS"
 996 _LIB="$LIBS"
 997 CFLAGS="$CFLAGS $TREAD_CFLAGS"
 998 LIBS="$LIBS $THREAD_LIBS"
 999 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1000 CFLAGS="$_CFLAGS"
1001 LIB="$_LIBS"
1002 fi
1003
1004
1005 # This test makes sure that run tests work at all.  Sometimes a shared
1006 # library is found by the linker, but the runtime linker can't find it.
1007 # This check should come after all modifications of compiler or linker
1008 # variables, and before any other run tests.
1009 AC_MSG_CHECKING([test program])
1010 AC_TRY_RUN([int main() { return 0; }],
1011 [AC_MSG_RESULT(ok)],
1012 [AC_MSG_RESULT(failed)
1013 AC_MSG_ERROR([[
1014 *** Could not execute a simple test program.  This may be a problem
1015 *** related to locating shared libraries.  Check the file 'config.log'
1016 *** for the exact reason.]])],
1017 [AC_MSG_RESULT([cross-compiling])])
1018
1019
1020 dnl Check to see if we have a working 64-bit integer type.
1021 dnl This breaks down into two steps:
1022 dnl (1) figure out if the compiler has a 64-bit int type with working
1023 dnl arithmetic, and if so
1024 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1025 dnl snprintf is the only library routine we really need for int8 support.)
1026 dnl It's entirely possible to have a compiler that handles a 64-bit type
1027 dnl when the C library doesn't; this is fairly likely when using gcc on
1028 dnl an older platform, for example.
1029 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1030 dnl we force our own version of snprintf() to be used instead.
1031 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1032
1033 PGAC_TYPE_64BIT_INT([long int])
1034
1035 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1036   PGAC_TYPE_64BIT_INT([long long int])
1037 fi
1038
1039
1040 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1041
1042 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1043   AC_TRY_COMPILE([
1044 #define INT64CONST(x)  x##LL
1045 long long int foo = INT64CONST(0x1234567890123456);
1046 ],
1047         [],
1048         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1049         [])
1050 fi
1051
1052
1053 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1054 # we found we need to use "long long int", better check.  We cope with
1055 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1056 # neither works, fall back to our own snprintf emulation (which we
1057 # know uses %lld).
1058
1059 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1060   if test $pgac_need_repl_snprintf = no; then
1061     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1062     if test "$LONG_LONG_INT_FORMAT" = ""; then
1063       # Force usage of our own snprintf, since system snprintf is broken
1064       pgac_need_repl_snprintf=yes
1065       LONG_LONG_INT_FORMAT='%lld'
1066     fi
1067   else
1068     # Here if we previously decided we needed to use our own snprintf
1069     LONG_LONG_INT_FORMAT='%lld'
1070   fi
1071   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1072 else
1073   # Here if we are not using 'long long int' at all
1074   INT64_FORMAT='"%ld"'
1075 fi
1076
1077 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1078                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1079
1080 if test $pgac_need_repl_snprintf = yes; then
1081   AC_LIBOBJ(snprintf)
1082 fi
1083
1084 # Need a #define for the size of Datum (unsigned long)
1085 AC_CHECK_SIZEOF([unsigned long])
1086
1087 # Determine memory alignment requirements for the basic C data types.
1088
1089 PGAC_CHECK_ALIGNOF(short)
1090 PGAC_CHECK_ALIGNOF(int)
1091 PGAC_CHECK_ALIGNOF(long)
1092 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1093   PGAC_CHECK_ALIGNOF(long long int)
1094 fi
1095 PGAC_CHECK_ALIGNOF(double)
1096
1097 # Compute maximum alignment of any basic type.
1098 # We assume long's alignment is at least as strong as char, short, or int;
1099 # but we must check long long (if it exists) and double.
1100
1101 MAX_ALIGNOF=$pgac_cv_alignof_long
1102 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1103   MAX_ALIGNOF=$pgac_cv_alignof_double
1104 fi
1105 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1106   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1107 fi
1108 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1109
1110
1111 # Some platforms predefine the types int8, int16, etc.  Only check
1112 # a (hopefully) representative subset.
1113 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1114 [#include <stdio.h>
1115 #ifdef HAVE_SUPPORTDEFS_H
1116 #include <SupportDefs.h>
1117 #endif])
1118
1119 # We also check for sig_atomic_t, which *should* be defined per ANSI
1120 # C, but is missing on some old platforms.
1121 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1122
1123
1124 PGAC_FUNC_POSIX_SIGNALS
1125 if test $ac_cv_func_fseeko = yes; then
1126 AC_SYS_LARGEFILE
1127 fi
1128
1129
1130 # Select semaphore implementation type.
1131 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1132   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1133   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1134 else
1135   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1136     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1137     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1138   else
1139     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1140     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1141   fi
1142 fi
1143
1144
1145 # Select shared-memory implementation type.
1146 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1147 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1148
1149
1150 if test "$enable_nls" = yes ; then
1151   PGAC_CHECK_GETTEXT
1152 fi
1153
1154 # Check for Tcl configuration script tclConfig.sh
1155 if test "$with_tcl" = yes; then
1156     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1157     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1158                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1159     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1160 fi
1161
1162 # Check for Tk configuration script tkConfig.sh
1163 if test "$with_tk" = yes; then
1164     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1165     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1166 fi
1167
1168
1169 #
1170 # Check for DocBook and tools
1171 #
1172 PGAC_PROG_NSGMLS
1173 PGAC_PROG_JADE
1174 PGAC_CHECK_DOCBOOK(3.1)
1175 PGAC_PATH_DOCBOOK_STYLESHEETS
1176 PGAC_PATH_COLLATEINDEX
1177 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1178
1179
1180 # prepare build tree if outside source tree
1181 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1182 # Note 2: /bin/pwd might be better than shell's built-in at getting
1183 #         a symlink-free name.
1184 if test "$no_create" != yes; then
1185   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1186     :
1187   else
1188     AC_SUBST(vpath_build, yes)
1189     _AS_ECHO_N([preparing build tree... ])
1190     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1191     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1192       || AC_MSG_ERROR(failed)
1193     AC_MSG_RESULT(done)
1194   fi
1195 fi
1196
1197
1198 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1199
1200 AC_CONFIG_LINKS([
1201   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1202   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1203   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1204   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1205   src/include/pg_config_os.h:src/include/port/${template}.h
1206   src/Makefile.port:src/makefiles/Makefile.${template}
1207 ])
1208
1209 AC_CONFIG_HEADERS([src/include/pg_config.h],
1210 [
1211 # Update timestamp for pg_config.h (see Makefile.global)
1212 echo >src/include/stamp-h
1213 ])
1214
1215 AC_OUTPUT