granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [11devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc";;
 357     *) pgac_cc_list="gcc cc";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361
 362 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 363 # but has idiosyncrasies of its own.  We assume icc will define
 364 # __INTEL_COMPILER regardless of CFLAGS.
 365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 366 choke me
 367 @%:@endif])], [ICC=yes], [ICC=no])
 368
 369 # Check if it's Sun Studio compiler. We assume that
 370 # __SUNPRO_C will be defined for Sun Studio compilers
 371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 372 choke me
 373 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 374
 375 AC_SUBST(SUN_STUDIO_CC)
 376
 377 unset CFLAGS
 378
 379 #
 380 # Read the template
 381 #
 382 . "$srcdir/src/template/$template" || exit
 383
 384 # CFLAGS are selected so:
 385 # If the user specifies something in the environment, that is used.
 386 # else:  If the template file set something, that is used.
 387 # else:  If coverage was enabled, don't set anything.
 388 # else:  If the compiler is GCC, then we use -O2.
 389 # else:  If the compiler is something else, then we use -O, unless debugging.
 390
 391 if test "$ac_env_CFLAGS_set" = set; then
 392   CFLAGS=$ac_env_CFLAGS_value
 393 elif test "${CFLAGS+set}" = set; then
 394   : # (keep what template set)
 395 elif test "$enable_coverage" = yes; then
 396   : # no optimization by default
 397 elif test "$GCC" = yes; then
 398   CFLAGS="-O2"
 399 else
 400   # if the user selected debug mode, don't use -O
 401   if test "$enable_debug" != yes; then
 402     CFLAGS="-O"
 403   fi
 404 fi
 405
 406 # CFLAGS we determined above will be added back at the end
 407 user_CFLAGS=$CFLAGS
 408 CFLAGS=""
 409
 410 # set CFLAGS_VECTOR from the environment, if available
 411 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 412   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 413 fi
 414
 415 # Some versions of GCC support some additional useful warning flags.
 416 # Check whether they are supported, and add them to CFLAGS if so.
 417 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 418 # but has its own.  Also check other compiler-specific flags here.
 419
 420 if test "$GCC" = yes -a "$ICC" = no; then
 421   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 422   # These work in some but not all gcc versions
 423   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 424   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 425   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 426   # This was included in -Wall/-Wformat in older GCC versions
 427   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 428   # Disable strict-aliasing rules; needed for gcc 3.3+
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 431   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 432   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 434   # Optimization flags for specific files that benefit from vectorization
 435   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 436   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 437   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 438   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 439   # test for the positive form and if that works, add the negative form
 440   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 441   if test -n "$NOT_THE_CFLAGS"; then
 442     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 443   fi
 444 elif test "$ICC" = yes; then
 445   # Intel's compiler has a bug/misoptimization in checking for
 446   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 447   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 448   # Make sure strict aliasing is off (though this is said to be the default)
 449   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 450 elif test "$PORTNAME" = "aix"; then
 451   # AIX's xlc has to have strict aliasing turned off too
 452   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 453   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 454 elif test "$PORTNAME" = "hpux"; then
 455   # On some versions of HP-UX, libm functions do not set errno by default.
 456   # Fix that by using +Olibmerrno if the compiler recognizes it.
 457   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 458 fi
 459
 460 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 461
 462 # supply -g if --enable-debug
 463 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 464   CFLAGS="$CFLAGS -g"
 465 fi
 466
 467 # enable code coverage if --enable-coverage
 468 if test "$enable_coverage" = yes; then
 469   if test "$GCC" = yes; then
 470     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 471   else
 472     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 473   fi
 474 fi
 475
 476 # enable profiling if --enable-profiling
 477 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 478   if test "$GCC" = yes; then
 479     AC_DEFINE([PROFILE_PID_DIR], 1,
 480            [Define to 1 to allow profiling output to be saved separately for each process.])
 481     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 482   else
 483     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 484   fi
 485 fi
 486
 487 # We already have this in Makefile.win32, but configure needs it too
 488 if test "$PORTNAME" = "win32"; then
 489   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 490 fi
 491
 492 # Now that we're done automatically adding stuff to CFLAGS, put back the
 493 # user-specified flags (if any) at the end.  This lets users override
 494 # the automatic additions.
 495 CFLAGS="$CFLAGS $user_CFLAGS"
 496
 497 # Check if the compiler still works with the final flag settings
 498 AC_MSG_CHECKING([whether the C compiler still works])
 499 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 500   [AC_MSG_RESULT(yes)],
 501   [AC_MSG_RESULT(no)
 502    AC_MSG_ERROR([cannot proceed])])
 503
 504 # Defend against gcc -ffast-math
 505 if test "$GCC" = yes; then
 506 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 507 choke me
 508 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 509 fi
 510
 511 AC_PROG_CPP
 512 AC_SUBST(GCC)
 513
 514
 515 #
 516 # Set up TAS assembly code if needed; the template file has now had its
 517 # chance to request this.
 518 #
 519 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 520
 521 if test "$need_tas" = yes ; then
 522   TAS=tas.o
 523 else
 524   TAS=""
 525 fi
 526 AC_SUBST(TAS)
 527
 528
 529 #
 530 # Automatic dependency tracking
 531 #
 532 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 533               [autodepend=yes])
 534 AC_SUBST(autodepend)
 535
 536
 537 #
 538 # Enable assert checks
 539 #
 540 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 541               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 542                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 543
 544
 545 #
 546 # Include directories
 547 #
 548 ac_save_IFS=$IFS
 549 IFS="${IFS}${PATH_SEPARATOR}"
 550 # SRCH_INC comes from the template file
 551 for dir in $with_includes $SRCH_INC; do
 552   if test -d "$dir"; then
 553     INCLUDES="$INCLUDES -I$dir"
 554   else
 555     AC_MSG_WARN([*** Include directory $dir does not exist.])
 556   fi
 557 done
 558 IFS=$ac_save_IFS
 559 AC_SUBST(INCLUDES)
 560
 561
 562 #
 563 # Library directories
 564 #
 565 ac_save_IFS=$IFS
 566 IFS="${IFS}${PATH_SEPARATOR}"
 567 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 568 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 569   if test -d "$dir"; then
 570     LIBDIRS="$LIBDIRS -L$dir"
 571   else
 572     AC_MSG_WARN([*** Library directory $dir does not exist.])
 573   fi
 574 done
 575 IFS=$ac_save_IFS
 576
 577 #
 578 # Enable thread-safe client libraries
 579 #
 580 AC_MSG_CHECKING([allow thread-safe client libraries])
 581 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 582 if test "$enable_thread_safety" = yes; then
 583   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 584           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 585 fi
 586 AC_MSG_RESULT([$enable_thread_safety])
 587 AC_SUBST(enable_thread_safety)
 588
 589 #
 590 # ICU
 591 #
 592 AC_MSG_CHECKING([whether to build with ICU support])
 593 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 594               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 595 AC_MSG_RESULT([$with_icu])
 596 AC_SUBST(with_icu)
 597
 598 if test "$with_icu" = yes; then
 599   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 600 fi
 601
 602 #
 603 # Optionally build Tcl modules (PL/Tcl)
 604 #
 605 AC_MSG_CHECKING([whether to build with Tcl])
 606 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 607 AC_MSG_RESULT([$with_tcl])
 608 AC_SUBST([with_tcl])
 609
 610 # We see if the path to the Tcl/Tk configuration scripts is specified.
 611 # This will override the use of tclsh to find the paths to search.
 612
 613 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 614
 615 #
 616 # Optionally build Perl modules (PL/Perl)
 617 #
 618 AC_MSG_CHECKING([whether to build Perl modules])
 619 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 620 AC_MSG_RESULT([$with_perl])
 621 AC_SUBST(with_perl)
 622
 623 #
 624 # Optionally build Python modules (PL/Python)
 625 #
 626 AC_MSG_CHECKING([whether to build Python modules])
 627 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 628 AC_MSG_RESULT([$with_python])
 629 AC_SUBST(with_python)
 630
 631 #
 632 # GSSAPI
 633 #
 634 AC_MSG_CHECKING([whether to build with GSSAPI support])
 635 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 636 [
 637   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 638   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 639 ])
 640 AC_MSG_RESULT([$with_gssapi])
 641 AC_SUBST(with_gssapi)
 642
 643
 644 AC_SUBST(krb_srvtab)
 645
 646
 647 #
 648 # Kerberos configuration parameters
 649 #
 650 PGAC_ARG_REQ(with, krb-srvnam,
 651              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 652              [],
 653              [with_krb_srvnam="postgres"])
 654 AC_SUBST(with_krb_srvnam)
 655 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 656                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 657
 658
 659 #
 660 # PAM
 661 #
 662 AC_MSG_CHECKING([whether to build with PAM support])
 663 PGAC_ARG_BOOL(with, pam, no,
 664               [build with PAM support],
 665               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 666 AC_MSG_RESULT([$with_pam])
 667
 668
 669 #
 670 # BSD AUTH
 671 #
 672 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 673 PGAC_ARG_BOOL(with, bsd-auth, no,
 674               [build with BSD Authentication support],
 675               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 676 AC_MSG_RESULT([$with_bsd_auth])
 677
 678
 679 #
 680 # LDAP
 681 #
 682 AC_MSG_CHECKING([whether to build with LDAP support])
 683 PGAC_ARG_BOOL(with, ldap, no,
 684               [build with LDAP support],
 685               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 686 AC_MSG_RESULT([$with_ldap])
 687 AC_SUBST(with_ldap)
 688
 689
 690 #
 691 # Bonjour
 692 #
 693 AC_MSG_CHECKING([whether to build with Bonjour support])
 694 PGAC_ARG_BOOL(with, bonjour, no,
 695               [build with Bonjour support],
 696               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 697 AC_MSG_RESULT([$with_bonjour])
 698
 699
 700 #
 701 # OpenSSL
 702 #
 703 AC_MSG_CHECKING([whether to build with OpenSSL support])
 704 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 705               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 706 AC_MSG_RESULT([$with_openssl])
 707 AC_SUBST(with_openssl)
 708
 709 #
 710 # SELinux
 711 #
 712 AC_MSG_CHECKING([whether to build with SELinux support])
 713 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 714 AC_SUBST(with_selinux)
 715 AC_MSG_RESULT([$with_selinux])
 716
 717 #
 718 # Systemd
 719 #
 720 AC_MSG_CHECKING([whether to build with systemd support])
 721 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 722               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 723 AC_SUBST(with_systemd)
 724 AC_MSG_RESULT([$with_systemd])
 725
 726 #
 727 # Readline
 728 #
 729 PGAC_ARG_BOOL(with, readline, yes,
 730               [do not use GNU Readline nor BSD Libedit for editing])
 731 # readline on MinGW has problems with backslashes in psql and other bugs.
 732 # This is particularly a problem with non-US code pages.
 733 # Therefore disable its use until we understand the cause. 2004-07-20
 734 if test "$PORTNAME" = "win32"; then
 735   if test "$with_readline" = yes; then
 736     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 737     with_readline=no
 738   fi
 739 fi
 740
 741
 742 #
 743 # Prefer libedit
 744 #
 745 PGAC_ARG_BOOL(with, libedit-preferred, no,
 746               [prefer BSD Libedit over GNU Readline])
 747
 748
 749 #
 750 # UUID library
 751 #
 752 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 753 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 754 # UUID library.  More than one of these might be present on a given platform,
 755 # so we make the user say which one she wants.
 756 #
 757 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 758 if test x"$with_uuid" = x"" ; then
 759   with_uuid=no
 760 fi
 761 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 762 if test "$with_ossp_uuid" = yes ; then
 763   with_uuid=ossp
 764 fi
 765
 766 if test "$with_uuid" = bsd ; then
 767   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 768   UUID_EXTRA_OBJS="md5.o sha1.o"
 769 elif test "$with_uuid" = e2fs ; then
 770   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 771   UUID_EXTRA_OBJS="md5.o sha1.o"
 772 elif test "$with_uuid" = ossp ; then
 773   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 774   UUID_EXTRA_OBJS=""
 775 elif test "$with_uuid" = no ; then
 776   UUID_EXTRA_OBJS=""
 777 else
 778   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 779 fi
 780 AC_SUBST(with_uuid)
 781 AC_SUBST(UUID_EXTRA_OBJS)
 782
 783
 784 #
 785 # XML
 786 #
 787 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 788               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 789
 790 if test "$with_libxml" = yes ; then
 791   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 792   if test -n "$XML2_CONFIG"; then
 793     for pgac_option in `$XML2_CONFIG --cflags`; do
 794       case $pgac_option in
 795         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 796       esac
 797     done
 798     for pgac_option in `$XML2_CONFIG --libs`; do
 799       case $pgac_option in
 800         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 801       esac
 802     done
 803   fi
 804 fi
 805
 806 AC_SUBST(with_libxml)
 807
 808 #
 809 # XSLT
 810 #
 811 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 812               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 813
 814
 815 AC_SUBST(with_libxslt)
 816
 817 #
 818 # tzdata
 819 #
 820 PGAC_ARG_REQ(with, system-tzdata,
 821              [DIR], [use system time zone data in DIR])
 822 AC_SUBST(with_system_tzdata)
 823
 824 #
 825 # Zlib
 826 #
 827 PGAC_ARG_BOOL(with, zlib, yes,
 828               [do not use Zlib])
 829 AC_SUBST(with_zlib)
 830
 831 #
 832 # Elf
 833 #
 834
 835 # Assume system is ELF if it predefines __ELF__ as 1,
 836 # otherwise believe host_os based default.
 837 case $host_os in
 838     freebsd1*|freebsd2*) elf=no;;
 839     freebsd3*|freebsd4*) elf=yes;;
 840 esac
 841
 842 AC_EGREP_CPP(yes,
 843 [#if __ELF__
 844   yes
 845 #endif
 846 ],
 847 [ELF_SYS=true],
 848 [if test "X$elf" = "Xyes" ; then
 849   ELF_SYS=true
 850 else
 851   ELF_SYS=
 852 fi])
 853 AC_SUBST(ELF_SYS)
 854
 855 #
 856 # Assignments
 857 #
 858
 859 CPPFLAGS="$CPPFLAGS $INCLUDES"
 860 LDFLAGS="$LDFLAGS $LIBDIRS"
 861
 862 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 863 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 864
 865 PGAC_PROG_LD
 866 AC_SUBST(LD)
 867 AC_SUBST(with_gnu_ld)
 868 AC_PROG_RANLIB
 869 PGAC_CHECK_STRIP
 870 AC_CHECK_TOOL(AR, ar, ar)
 871 if test "$PORTNAME" = "win32"; then
 872   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 873   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 874   AC_CHECK_TOOL(WINDRES, windres, windres)
 875 fi
 876
 877 AC_PROG_INSTALL
 878 # When Autoconf chooses install-sh as install program it tries to generate
 879 # a relative path to it in each makefile where it substitutes it. This clashes
 880 # with our Makefile.global concept. This workaround helps.
 881 case $INSTALL in
 882   *install-sh*) install_bin='';;
 883   *) install_bin=$INSTALL;;
 884 esac
 885 AC_SUBST(install_bin)
 886
 887 PGAC_PATH_PROGS(TAR, tar)
 888 AC_PROG_LN_S
 889 AC_PROG_AWK
 890 AC_PROG_MKDIR_P
 891 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 892 # a relative path to it in each makefile where it substitutes it. This clashes
 893 # with our Makefile.global concept. This workaround helps.
 894 case $MKDIR_P in
 895   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 896 esac
 897
 898 PGAC_PATH_BISON
 899 PGAC_PATH_FLEX
 900
 901 PGAC_PATH_PERL
 902 if test "$with_perl" = yes; then
 903   if test -z "$PERL"; then
 904     AC_MSG_ERROR([Perl not found])
 905   fi
 906   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 907   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 908     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 909 You might have to rebuild your Perl installation.  Refer to the
 910 documentation for details.  Use --without-perl to disable building
 911 PL/Perl.])
 912   fi
 913   PGAC_CHECK_PERL_EMBED_CCFLAGS
 914   PGAC_CHECK_PERL_EMBED_LDFLAGS
 915 fi
 916
 917 if test "$with_python" = yes; then
 918   PGAC_PATH_PYTHON
 919   PGAC_CHECK_PYTHON_EMBED_SETUP
 920 fi
 921
 922 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 923   PGAC_PATH_PROGS(ZIC, zic)
 924   if test -z "$ZIC"; then
 925     AC_MSG_ERROR([
 926 When cross-compiling, either use the option --with-system-tzdata to use
 927 existing time-zone data, or set the environment variable ZIC to a zic
 928 program to use during the build.])
 929   fi
 930 fi
 931
 932 #
 933 # Pthreads
 934 #
 935 # For each platform, we need to know about any special compile and link
 936 # libraries, and whether the normal C function names are thread-safe.
 937 # See the comment at the top of src/port/thread.c for more information.
 938 # WIN32 doesn't need the pthread tests;  it always uses threads
 939 #
 940 # These tests are run before the library-tests, because linking with the
 941 # other libraries can pull in the pthread functions as a side-effect.  We
 942 # want to use the -pthread or similar flags directly, and not rely on
 943 # the side-effects of linking with some other library.
 944 #
 945 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 946 # invocation below is the first one in the script, and autoconf generates
 947 # additional code for that, which must not be inside the if-block. AS_IF
 948 # knows how to do that.
 949 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 950 [ # then
 951 AX_PTHREAD      # set thread flags
 952
 953 # Some platforms use these, so just define them.  They can't hurt if they
 954 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 955 # enables 5-arg getpwuid_r, among other things.
 956 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 957
 958 # Check for *_r functions
 959 _CFLAGS="$CFLAGS"
 960 _LIBS="$LIBS"
 961 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 962 LIBS="$LIBS $PTHREAD_LIBS"
 963
 964 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 965 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 966
 967 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 968
 969 # Do test here with the proper thread flags
 970 PGAC_FUNC_STRERROR_R_INT
 971
 972 CFLAGS="$_CFLAGS"
 973 LIBS="$_LIBS"
 974
 975 ], [ # else
 976 # do not use values from template file
 977 PTHREAD_CFLAGS=
 978 PTHREAD_LIBS=
 979 ]) # fi
 980
 981 AC_SUBST(PTHREAD_CFLAGS)
 982 AC_SUBST(PTHREAD_LIBS)
 983
 984
 985 ##
 986 ## Libraries
 987 ##
 988 ## Most libraries are included only if they demonstrably provide a function
 989 ## we need, but libm is an exception: always include it, because there are
 990 ## too many compilers that play cute optimization games that will break
 991 ## probes for standard functions such as pow().
 992 ##
 993
 994 AC_CHECK_LIB(m, main)
 995 AC_SEARCH_LIBS(setproctitle, util)
 996 AC_SEARCH_LIBS(dlopen, dl)
 997 AC_SEARCH_LIBS(socket, [socket ws2_32])
 998 AC_SEARCH_LIBS(shl_load, dld)
 999 # We only use libld in port/dynloader/aix.c
1000 case $host_os in
1001      aix*)
1002         AC_SEARCH_LIBS(ldopen, ld)
1003         ;;
1004 esac
1005 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1006 AC_SEARCH_LIBS(crypt, crypt)
1007 AC_SEARCH_LIBS(shm_open, rt)
1008 AC_SEARCH_LIBS(shm_unlink, rt)
1009 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1010 # Solaris:
1011 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1012 # Required for thread_test.c on Solaris
1013 AC_SEARCH_LIBS(sched_yield, rt)
1014 # Required for thread_test.c on Solaris 2.5:
1015 # Other ports use it too (HP-UX) so test unconditionally
1016 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1017 # Cygwin:
1018 AC_SEARCH_LIBS(shmget, cygipc)
1019
1020 if test "$with_readline" = yes; then
1021   PGAC_CHECK_READLINE
1022   if test x"$pgac_cv_check_readline" = x"no"; then
1023     AC_MSG_ERROR([readline library not found
1024 If you have readline already installed, see config.log for details on the
1025 failure.  It is possible the compiler isn't looking in the proper directory.
1026 Use --without-readline to disable readline support.])
1027   fi
1028 fi
1029
1030 if test "$with_zlib" = yes; then
1031   AC_CHECK_LIB(z, inflate, [],
1032                [AC_MSG_ERROR([zlib library not found
1033 If you have zlib already installed, see config.log for details on the
1034 failure.  It is possible the compiler isn't looking in the proper directory.
1035 Use --without-zlib to disable zlib support.])])
1036 fi
1037
1038 if test "$enable_spinlocks" = yes; then
1039   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1040 else
1041   AC_MSG_WARN([
1042 *** Not using spinlocks will cause poor performance.])
1043 fi
1044
1045 if test "$enable_atomics" = yes; then
1046   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1047 else
1048   AC_MSG_WARN([
1049 *** Not using atomic operations will cause poor performance.])
1050 fi
1051
1052 if test "$with_gssapi" = yes ; then
1053   if test "$PORTNAME" != "win32"; then
1054     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1055                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1056   else
1057     LIBS="$LIBS -lgssapi32"
1058   fi
1059 fi
1060
1061 if test "$with_openssl" = yes ; then
1062   dnl Order matters!
1063   if test "$PORTNAME" != "win32"; then
1064      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1065      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1066   else
1067      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1068      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1069   fi
1070   AC_CHECK_FUNCS([SSL_get_current_compression X509_get_signature_nid])
1071   # Functions introduced in OpenSSL 1.1.0. We used to check for
1072   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1073   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1074   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1075   # functions.
1076   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1077   # OpenSSL versions before 1.1.0 required setting callback functions, for
1078   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1079   # function was removed.
1080   AC_CHECK_FUNCS([CRYPTO_lock])
1081 fi
1082
1083 if test "$with_pam" = yes ; then
1084   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1085 fi
1086
1087 if test "$with_libxml" = yes ; then
1088   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1089 fi
1090
1091 if test "$with_libxslt" = yes ; then
1092   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1093 fi
1094
1095 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1096 if test "$with_ldap" = yes ; then
1097   _LIBS="$LIBS"
1098   if test "$PORTNAME" != "win32"; then
1099     AC_CHECK_LIB(ldap, ldap_bind, [],
1100                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1101                  [$EXTRA_LDAP_LIBS])
1102     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1103     if test "$enable_thread_safety" = yes; then
1104       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1105       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1106                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1107                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1108       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1109     else
1110       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1111     fi
1112     AC_CHECK_FUNCS([ldap_initialize])
1113   else
1114     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1115     LDAP_LIBS_FE="-lwldap32"
1116     LDAP_LIBS_BE="-lwldap32"
1117   fi
1118   LIBS="$_LIBS"
1119 fi
1120 AC_SUBST(LDAP_LIBS_FE)
1121 AC_SUBST(LDAP_LIBS_BE)
1122
1123 # for contrib/sepgsql
1124 if test "$with_selinux" = yes; then
1125   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1126                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1127 fi
1128
1129 # for contrib/uuid-ossp
1130 if test "$with_uuid" = bsd ; then
1131   # On BSD, the UUID functions are in libc
1132   AC_CHECK_FUNC(uuid_to_string,
1133     [UUID_LIBS=""],
1134     [AC_MSG_ERROR([BSD UUID functions are not present])])
1135 elif test "$with_uuid" = e2fs ; then
1136   # On macOS, the UUID functions are in libc
1137   AC_CHECK_FUNC(uuid_generate,
1138     [UUID_LIBS=""],
1139     [AC_CHECK_LIB(uuid, uuid_generate,
1140       [UUID_LIBS="-luuid"],
1141       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1142 elif test "$with_uuid" = ossp ; then
1143   AC_CHECK_LIB(ossp-uuid, uuid_export,
1144     [UUID_LIBS="-lossp-uuid"],
1145     [AC_CHECK_LIB(uuid, uuid_export,
1146       [UUID_LIBS="-luuid"],
1147       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1148 fi
1149 AC_SUBST(UUID_LIBS)
1150
1151
1152 ##
1153 ## Header files
1154 ##
1155
1156 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1157
1158 # On BSD, test for net/if.h will fail unless sys/socket.h
1159 # is included first.
1160 AC_CHECK_HEADERS(net/if.h, [], [],
1161 [AC_INCLUDES_DEFAULT
1162 #include <sys/socket.h>
1163 ])
1164
1165 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1166 # is included first.
1167 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1168 [AC_INCLUDES_DEFAULT
1169 #include <sys/param.h>
1170 ])
1171
1172 # At least on IRIX, test for netinet/tcp.h will fail unless
1173 # netinet/in.h is included first.
1174 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1175 [AC_INCLUDES_DEFAULT
1176 #include <netinet/in.h>
1177 ])
1178
1179 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1180   AC_CHECK_HEADERS(readline/readline.h, [],
1181         [AC_CHECK_HEADERS(readline.h, [],
1182                 [AC_MSG_ERROR([readline header not found
1183 If you have readline already installed, see config.log for details on the
1184 failure.  It is possible the compiler isn't looking in the proper directory.
1185 Use --without-readline to disable readline support.])])])
1186   AC_CHECK_HEADERS(readline/history.h, [],
1187         [AC_CHECK_HEADERS(history.h, [],
1188                 [AC_MSG_ERROR([history header not found
1189 If you have readline already installed, see config.log for details on the
1190 failure.  It is possible the compiler isn't looking in the proper directory.
1191 Use --without-readline to disable readline support.])])])
1192 fi
1193
1194 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1195 # Some installations of libedit usurp /usr/include/readline/, which seems
1196 # bad practice, since in combined installations readline will have its headers
1197 # there.  We might have to resort to AC_EGREP checks to make sure we found
1198 # the proper header...
1199   AC_CHECK_HEADERS(editline/readline.h, [],
1200         [AC_CHECK_HEADERS(readline.h, [],
1201                 [AC_CHECK_HEADERS(readline/readline.h, [],
1202                         [AC_MSG_ERROR([readline header not found
1203 If you have libedit already installed, see config.log for details on the
1204 failure.  It is possible the compiler isn't looking in the proper directory.
1205 Use --without-readline to disable libedit support.])])])])
1206 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1207 # not be there at all.  Hence, don't complain if not found.  We must check
1208 # though, since in yet other versions it is an independent header.
1209   AC_CHECK_HEADERS(editline/history.h, [],
1210         [AC_CHECK_HEADERS(history.h, [],
1211                 [AC_CHECK_HEADERS(readline/history.h)])])
1212 fi
1213
1214 if test "$with_zlib" = yes; then
1215   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1216 If you have zlib already installed, see config.log for details on the
1217 failure.  It is possible the compiler isn't looking in the proper directory.
1218 Use --without-zlib to disable zlib support.])])
1219 fi
1220
1221 if test "$with_gssapi" = yes ; then
1222   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1223         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1224 fi
1225
1226 if test "$with_openssl" = yes ; then
1227   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1228   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1229 fi
1230
1231 if test "$with_pam" = yes ; then
1232   AC_CHECK_HEADERS(security/pam_appl.h, [],
1233                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1234                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1235 fi
1236
1237 if test "$with_bsd_auth" = yes ; then
1238   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1239 fi
1240
1241 if test "$with_systemd" = yes ; then
1242   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1243 fi
1244
1245 if test "$with_libxml" = yes ; then
1246   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1247 fi
1248
1249 if test "$with_libxslt" = yes ; then
1250   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1251 fi
1252
1253 if test "$with_ldap" = yes ; then
1254   if test "$PORTNAME" != "win32"; then
1255      AC_CHECK_HEADERS(ldap.h, [],
1256                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1257      PGAC_LDAP_SAFE
1258   else
1259      AC_CHECK_HEADERS(winldap.h, [],
1260                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1261                       [AC_INCLUDES_DEFAULT
1262 #include <windows.h>
1263                       ])
1264   fi
1265 fi
1266
1267 if test "$with_bonjour" = yes ; then
1268   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1269 dnl At some point we might add something like
1270 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1271 dnl but right now, what that would mainly accomplish is to encourage
1272 dnl people to try to use the avahi implementation, which does not work.
1273 dnl If you want to use Apple's own Bonjour code on another platform,
1274 dnl just add -ldns_sd to LIBS manually.
1275 fi
1276
1277 # for contrib/uuid-ossp
1278 if test "$with_uuid" = bsd ; then
1279   AC_CHECK_HEADERS(uuid.h,
1280     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1281       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1282     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1283 elif test "$with_uuid" = e2fs ; then
1284   AC_CHECK_HEADERS(uuid/uuid.h,
1285     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1286       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1287     [AC_CHECK_HEADERS(uuid.h,
1288       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1289         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1290       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1291 elif test "$with_uuid" = ossp ; then
1292   AC_CHECK_HEADERS(ossp/uuid.h,
1293     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1294       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1295     [AC_CHECK_HEADERS(uuid.h,
1296       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1297         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1298       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1299 fi
1300
1301 if test "$PORTNAME" = "win32" ; then
1302    AC_CHECK_HEADERS(crtdefs.h)
1303 fi
1304
1305 ##
1306 ## Types, structures, compiler characteristics
1307 ##
1308
1309 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1310 AC_C_BIGENDIAN
1311 AC_C_INLINE
1312 PGAC_PRINTF_ARCHETYPE
1313 AC_C_FLEXIBLE_ARRAY_MEMBER
1314 PGAC_C_SIGNED
1315 PGAC_C_FUNCNAME_SUPPORT
1316 PGAC_C_STATIC_ASSERT
1317 PGAC_C_TYPEOF
1318 PGAC_C_TYPES_COMPATIBLE
1319 PGAC_C_BUILTIN_BSWAP16
1320 PGAC_C_BUILTIN_BSWAP32
1321 PGAC_C_BUILTIN_BSWAP64
1322 PGAC_C_BUILTIN_CONSTANT_P
1323 PGAC_C_BUILTIN_UNREACHABLE
1324 PGAC_C_COMPUTED_GOTO
1325 PGAC_C_VA_ARGS
1326 PGAC_STRUCT_TIMEZONE
1327 PGAC_UNION_SEMUN
1328 PGAC_STRUCT_SOCKADDR_UN
1329 PGAC_STRUCT_SOCKADDR_STORAGE
1330 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1331 PGAC_STRUCT_ADDRINFO
1332 AC_TYPE_INTPTR_T
1333 AC_TYPE_UINTPTR_T
1334 AC_TYPE_LONG_LONG_INT
1335
1336 PGAC_TYPE_LOCALE_T
1337
1338 # MSVC doesn't cope well with defining restrict to __restrict, the
1339 # spelling it understands, because it conflicts with
1340 # __declspec(restrict). Therefore we define pg_restrict to the
1341 # appropriate definition, which presumably won't conflict.
1342 #
1343 # Allow platforms with buggy compilers to force restrict to not be
1344 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1345 # template.
1346 AC_C_RESTRICT
1347 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1348   pg_restrict=""
1349 else
1350   pg_restrict="$ac_cv_c_restrict"
1351 fi
1352 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1353 [Define to keyword to use for C99 restrict support, or to nothing if not
1354 supported])
1355
1356 AC_CHECK_TYPES([struct cmsgcred], [], [],
1357 [#include <sys/socket.h>
1358 #include <sys/param.h>
1359 #ifdef HAVE_SYS_UCRED_H
1360 #include <sys/ucred.h>
1361 #endif])
1362
1363 AC_CHECK_TYPES([struct option], [], [],
1364 [#ifdef HAVE_GETOPT_H
1365 #include <getopt.h>
1366 #endif])
1367
1368 if test "$with_zlib" = yes; then
1369   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1370   # did not).  While we could work around the lack of z_streamp, it
1371   # seems unwise to encourage people to use such old zlib versions...
1372   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1373 Use --without-zlib to disable zlib support.])],
1374                 [#include <zlib.h>])
1375 fi
1376
1377 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1378 case $host_cpu in
1379   ppc*|powerpc*)
1380     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1381     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1382         [int a = 0; int *p = &a; int r;
1383          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1384         [pgac_cv_have_ppc_mutex_hint=yes],
1385         [pgac_cv_have_ppc_mutex_hint=no])
1386     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1387     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1388         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1389     fi
1390   ;;
1391 esac
1392
1393 # Check largefile support.  You might think this is a system service not a
1394 # compiler characteristic, but you'd be wrong.  We must check this before
1395 # probing existence of related functions such as fseeko, since the largefile
1396 # defines can affect what is generated for that.
1397 if test "$PORTNAME" != "win32"; then
1398    AC_SYS_LARGEFILE
1399    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1400    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1401    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1402    dnl versions where the feature actually works, it's on by default anyway.
1403    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1404 fi
1405
1406 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1407 AC_CHECK_SIZEOF([off_t])
1408
1409 # If we don't have largefile support, can't handle segsize >= 2GB.
1410 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1411    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1412 fi
1413
1414
1415 ##
1416 ## Functions, global variables
1417 ##
1418
1419 PGAC_VAR_INT_TIMEZONE
1420 AC_FUNC_ACCEPT_ARGTYPES
1421 PGAC_FUNC_GETTIMEOFDAY_1ARG
1422 PGAC_FUNC_WCSTOMBS_L
1423
1424 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1425 # symbols that that library has no business exposing to the world.  Pending
1426 # acquisition of a clue by those developers, ignore libedit (including its
1427 # possible alias of libreadline) while checking for everything else.
1428 LIBS_including_readline="$LIBS"
1429 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1430
1431 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1432
1433 AC_REPLACE_FUNCS(fseeko)
1434 case $host_os in
1435         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1436         # Mingw uses macros to access Win32 API calls
1437         netbsd*|mingw*)
1438                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1439                 ac_cv_func_fseeko=yes;;
1440         *)
1441                 AC_FUNC_FSEEKO;;
1442 esac
1443
1444 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1445 # by calling it, 2009-04-02
1446 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1447 if test "$PORTNAME" != "solaris"; then
1448 AC_CHECK_FUNCS(posix_fadvise)
1449 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1450 fi
1451
1452 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1453 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1454 # This is probably only present on macOS, but may as well check always
1455 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1456
1457 HAVE_IPV6=no
1458 AC_CHECK_TYPE([struct sockaddr_in6],
1459         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1460          HAVE_IPV6=yes],
1461         [],
1462 [$ac_includes_default
1463 #include <netinet/in.h>])
1464 AC_SUBST(HAVE_IPV6)
1465
1466 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1467 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1468 [#include <machine/vmparam.h>
1469 #include <sys/exec.h>
1470 ],
1471 [PS_STRINGS->ps_nargvstr = 1;
1472 PS_STRINGS->ps_argvstr = "foo";])],
1473 [pgac_cv_var_PS_STRINGS=yes],
1474 [pgac_cv_var_PS_STRINGS=no])])
1475 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1476   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1477 fi
1478
1479
1480 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1481 # is missing.  Yes, there are machines that have only one.  We may
1482 # also decide to use snprintf.c if snprintf() is present but does not
1483 # have all the features we need --- see below.
1484
1485 if test "$PORTNAME" = "win32"; then
1486   # Win32 gets snprintf.c built unconditionally.
1487   #
1488   # To properly translate all NLS languages strings, we must support the
1489   # *printf() %$ format, which allows *printf() arguments to be selected
1490   # by position in the translated string.
1491   #
1492   # libintl versions < 0.13 use the native *printf() functions, and Win32
1493   # *printf() doesn't understand %$, so we must use our /port versions,
1494   # which do understand %$. libintl versions >= 0.13 include their own
1495   # *printf versions on Win32.  The libintl 0.13 release note text is:
1496   #
1497   #   C format strings with positions, as they arise when a translator
1498   #   needs to reorder a sentence, are now supported on all platforms.
1499   #   On those few platforms (NetBSD and Woe32) for which the native
1500   #   printf()/fprintf()/... functions don't support such format
1501   #   strings, replacements are provided through <libintl.h>.
1502   #
1503   # We could use libintl >= 0.13's *printf() if we were sure that we had
1504   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1505   # to guarantee that, it is best to just use our own, so we are sure to
1506   # get %$ support. In include/port.h we disable the *printf() macros
1507   # that might have been defined by libintl.
1508   #
1509   # We do this unconditionally whether NLS is used or not so we are sure
1510   # that all Win32 libraries and binaries behave the same.
1511   pgac_need_repl_snprintf=yes
1512 else
1513   pgac_need_repl_snprintf=no
1514   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1515   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1516 fi
1517
1518
1519 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1520 # include/c.h will provide declarations.  Note this is a separate test
1521 # from whether the functions exist in the C library --- there are
1522 # systems that have the functions but don't bother to declare them :-(
1523
1524 AC_CHECK_DECLS([snprintf, vsnprintf])
1525
1526
1527 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1528 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1529 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1530 #include <math.h>
1531 double glob_double;
1532 ],
1533 [return isinf(glob_double) ? 0 : 1;])],
1534 [ac_cv_func_isinf=yes],
1535 [ac_cv_func_isinf=no])])
1536
1537 if test $ac_cv_func_isinf = yes ; then
1538   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1539 else
1540   AC_LIBOBJ(isinf)
1541   # Look for a way to implement a substitute for isinf()
1542   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1543 fi
1544
1545 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1546
1547 case $host_os in
1548
1549         # Windows uses a specialised env handler
1550         # and doesn't need a replacement getpeereid because it doesn't use
1551         # Unix sockets.
1552         mingw*)
1553                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1554                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1555                 ac_cv_func_unsetenv=yes
1556                 ac_cv_func_getpeereid=yes;;
1557         *)
1558                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1559                 ;;
1560 esac
1561
1562 # System's version of getaddrinfo(), if any, may be used only if we found
1563 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1564 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1565 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1566    test "$PORTNAME" != "win32"; then
1567   AC_REPLACE_FUNCS([getaddrinfo])
1568 else
1569   AC_LIBOBJ(getaddrinfo)
1570 fi
1571
1572 # Similarly, use system's getopt_long() only if system provides struct option.
1573 if test x"$ac_cv_type_struct_option" = xyes ; then
1574   AC_REPLACE_FUNCS([getopt_long])
1575 else
1576   AC_LIBOBJ(getopt_long)
1577 fi
1578
1579 # Solaris' getopt() doesn't do what we want for long options, so always use
1580 # our version on that platform.
1581 if test "$PORTNAME" = "solaris"; then
1582   AC_LIBOBJ(getopt)
1583 fi
1584
1585 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1586 # so always use our version on Windows.
1587 if test "$PORTNAME" = "win32"; then
1588   AC_LIBOBJ(getopt)
1589   AC_LIBOBJ(getopt_long)
1590 fi
1591
1592 # Win32 (really MinGW) support
1593 if test "$PORTNAME" = "win32"; then
1594   AC_REPLACE_FUNCS(gettimeofday)
1595   AC_LIBOBJ(dirmod)
1596   AC_LIBOBJ(kill)
1597   AC_LIBOBJ(open)
1598   AC_LIBOBJ(system)
1599   AC_LIBOBJ(win32env)
1600   AC_LIBOBJ(win32error)
1601   AC_LIBOBJ(win32security)
1602   AC_LIBOBJ(win32setlocale)
1603   AC_DEFINE([HAVE_SYMLINK], 1,
1604             [Define to 1 if you have the `symlink' function.])
1605   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1606 #define WIN32_LEAN_AND_MEAN
1607 #include <windows.h>
1608 #include <string.h>
1609 #include <dbghelp.h>])
1610 fi
1611 if test x"$pgac_minidump_type" = x"yes" ; then
1612   AC_SUBST(have_win32_dbghelp,yes)
1613 else
1614   AC_SUBST(have_win32_dbghelp,no)
1615 fi
1616
1617 # Cygwin needs only a bit of that
1618 if test "$PORTNAME" = "cygwin"; then
1619   AC_LIBOBJ(dirmod)
1620 fi
1621
1622 AC_CHECK_DECLS([sys_siglist], [], [],
1623 [#include <signal.h>
1624 /* NetBSD declares sys_siglist in unistd.h.  */
1625 #ifdef HAVE_UNISTD_H
1626 # include <unistd.h>
1627 #endif
1628 ])
1629
1630 AC_CHECK_FUNC(syslog,
1631               [AC_CHECK_HEADER(syslog.h,
1632                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1633
1634 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1635 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1636   [extern int opterr; opterr = 1;])],
1637   [pgac_cv_var_int_opterr=yes],
1638   [pgac_cv_var_int_opterr=no])])
1639 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1640   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1641 fi
1642
1643 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1644 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1645   [extern int optreset; optreset = 1;])],
1646   [pgac_cv_var_int_optreset=yes],
1647   [pgac_cv_var_int_optreset=no])])
1648 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1649   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1650 fi
1651
1652 AC_CHECK_FUNCS([strtoll strtoq], [break])
1653 AC_CHECK_FUNCS([strtoull strtouq], [break])
1654
1655 if test "$with_icu" = yes; then
1656   ac_save_CPPFLAGS=$CPPFLAGS
1657   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1658
1659   # Verify we have ICU's header files
1660   AC_CHECK_HEADER(unicode/ucol.h, [],
1661         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1662
1663   CPPFLAGS=$ac_save_CPPFLAGS
1664 fi
1665
1666 # Lastly, restore full LIBS list and check for readline/libedit symbols
1667 LIBS="$LIBS_including_readline"
1668
1669 if test "$with_readline" = yes; then
1670   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1671   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1672   AC_CHECK_FUNCS([append_history history_truncate_file])
1673 fi
1674
1675
1676 # This test makes sure that run tests work at all.  Sometimes a shared
1677 # library is found by the linker, but the runtime linker can't find it.
1678 # This check should come after all modifications of compiler or linker
1679 # variables, and before any other run tests.
1680 AC_MSG_CHECKING([test program])
1681 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1682 [AC_MSG_RESULT(ok)],
1683 [AC_MSG_RESULT(failed)
1684 AC_MSG_ERROR([[
1685 Could not execute a simple test program.  This may be a problem
1686 related to locating shared libraries.  Check the file 'config.log'
1687 for the exact reason.]])],
1688 [AC_MSG_RESULT([cross-compiling])])
1689
1690 # --------------------
1691 # Run tests below here
1692 # --------------------
1693
1694 # Force use of our snprintf if system's doesn't do arg control
1695 # See comment above at snprintf test for details.
1696 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1697   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1698   if test $pgac_cv_snprintf_arg_control != yes ; then
1699     pgac_need_repl_snprintf=yes
1700   fi
1701 fi
1702
1703
1704 dnl Check to see if we have a working 64-bit integer type.
1705 dnl This breaks down into two steps:
1706 dnl (1) figure out if the compiler has a 64-bit int type with working
1707 dnl arithmetic, and if so
1708 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1709 dnl snprintf is the only library routine we really need for int8 support.)
1710 dnl It's entirely possible to have a compiler that handles a 64-bit type
1711 dnl when the C library doesn't; this is fairly likely when using gcc on
1712 dnl an older platform, for example.
1713 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1714 dnl we force our own version of snprintf() to be used instead.
1715 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1716
1717 dnl As of Postgres 8.4, we no longer support compilers without a working
1718 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1719
1720 PGAC_TYPE_64BIT_INT([long int])
1721
1722 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1723   pg_int64_type="long int"
1724 else
1725   PGAC_TYPE_64BIT_INT([long long int])
1726   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1727     pg_int64_type="long long int"
1728   else
1729     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1730   fi
1731 fi
1732
1733 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1734   [Define to the name of a signed 64-bit integer type.])
1735
1736 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1737 # we found we need to use "long long int", better check.  We cope with
1738 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1739 # work, fall back to our own snprintf emulation (which we know uses %lld).
1740
1741 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1742   if test $pgac_need_repl_snprintf = no; then
1743     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1744     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1745       # Force usage of our own snprintf, since system snprintf is broken
1746       pgac_need_repl_snprintf=yes
1747       LONG_LONG_INT_MODIFIER='ll'
1748     fi
1749   else
1750     # Here if we previously decided we needed to use our own snprintf
1751     LONG_LONG_INT_MODIFIER='ll'
1752   fi
1753 else
1754   # Here if we are not using 'long long int' at all
1755   LONG_LONG_INT_MODIFIER='l'
1756 fi
1757
1758 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1759
1760 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1761                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1762
1763 # Also force use of our snprintf if the system's doesn't support the %z flag.
1764 if test "$pgac_need_repl_snprintf" = no; then
1765   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1766   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1767     pgac_need_repl_snprintf=yes
1768   fi
1769 fi
1770
1771 # Now we have checked all the reasons to replace snprintf
1772 if test $pgac_need_repl_snprintf = yes; then
1773   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1774   AC_LIBOBJ(snprintf)
1775 fi
1776
1777 # has to be down here, rather than with the other builtins, because
1778 # the test uses PG_INT64_TYPE.
1779 PGAC_C_BUILTIN_OP_OVERFLOW
1780
1781 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1782 AC_CHECK_SIZEOF([void *])
1783 AC_CHECK_SIZEOF([size_t])
1784 AC_CHECK_SIZEOF([long])
1785
1786 # Decide whether float4 is passed by value: user-selectable, enabled by default
1787 AC_MSG_CHECKING([whether to build with float4 passed by value])
1788 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1789               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1790                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1791                float4passbyval=true],
1792               [float4passbyval=false])
1793 AC_MSG_RESULT([$enable_float4_byval])
1794 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1795
1796 # Decide whether float8 is passed by value.
1797 # Note: this setting also controls int8 and related types such as timestamp.
1798 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1799 # If not, trying to select it is an error.
1800 AC_MSG_CHECKING([whether to build with float8 passed by value])
1801 if test $ac_cv_sizeof_void_p -ge 8 ; then
1802   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1803 else
1804   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1805   if test "$enable_float8_byval" = yes ; then
1806     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1807   fi
1808 fi
1809 if test "$enable_float8_byval" = yes ; then
1810   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1811             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1812   float8passbyval=true
1813 else
1814   float8passbyval=false
1815 fi
1816 AC_MSG_RESULT([$enable_float8_byval])
1817 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1818
1819 # Determine memory alignment requirements for the basic C data types.
1820
1821 AC_CHECK_ALIGNOF(short)
1822 AC_CHECK_ALIGNOF(int)
1823 AC_CHECK_ALIGNOF(long)
1824 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1825   AC_CHECK_ALIGNOF(long long int)
1826 fi
1827 AC_CHECK_ALIGNOF(double)
1828
1829 # Compute maximum alignment of any basic type.
1830 # We assume long's alignment is at least as strong as char, short, or int;
1831 # but we must check long long (if it is being used for int64) and double.
1832 # Note that we intentionally do not consider any types wider than 64 bits,
1833 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1834 # for disk and memory space.
1835
1836 MAX_ALIGNOF=$ac_cv_alignof_long
1837 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1838   MAX_ALIGNOF=$ac_cv_alignof_double
1839 fi
1840 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1841   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1842 fi
1843 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1844
1845
1846 # Some platforms predefine the types int8, int16, etc.  Only check
1847 # a (hopefully) representative subset.
1848 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1849 [#include <stdio.h>])
1850
1851 # Some compilers offer a 128-bit integer scalar type.
1852 PGAC_TYPE_128BIT_INT
1853
1854 # Check for various atomic operations now that we have checked how to declare
1855 # 64bit integers.
1856 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1857 PGAC_HAVE_GCC__SYNC_INT32_TAS
1858 PGAC_HAVE_GCC__SYNC_INT32_CAS
1859 PGAC_HAVE_GCC__SYNC_INT64_CAS
1860 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1861 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1862
1863
1864 # Check for x86 cpuid instruction
1865 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1866 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1867   [[unsigned int exx[4] = {0, 0, 0, 0};
1868   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1869   ]])],
1870   [pgac_cv__get_cpuid="yes"],
1871   [pgac_cv__get_cpuid="no"])])
1872 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1873   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1874 fi
1875
1876 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1877 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1878   [[unsigned int exx[4] = {0, 0, 0, 0};
1879   __get_cpuid(exx[0], 1);
1880   ]])],
1881   [pgac_cv__cpuid="yes"],
1882   [pgac_cv__cpuid="no"])])
1883 if test x"$pgac_cv__cpuid" = x"yes"; then
1884   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1885 fi
1886
1887 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1888 #
1889 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1890 # with the default compiler flags. If not, check if adding the -msse4.2
1891 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1892 PGAC_SSE42_CRC32_INTRINSICS([])
1893 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1894   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1895 fi
1896 AC_SUBST(CFLAGS_SSE42)
1897
1898 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1899 # define __SSE4_2__ in that case.
1900 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1901 #ifndef __SSE4_2__
1902 #error __SSE4_2__ not defined
1903 #endif
1904 ])], [SSE4_2_TARGETED=1])
1905
1906 # Select CRC-32C implementation.
1907 #
1908 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1909 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1910 # a processor, but we can nevertheless produce code that uses the SSE
1911 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1912 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1913 # by the processor we're running on.
1914 #
1915 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1916 # in the template or configure command line.
1917 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1918   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1919     USE_SSE42_CRC32C=1
1920   else
1921     # the CPUID instruction is needed for the runtime check.
1922     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1923       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1924     else
1925       # fall back to slicing-by-8 algorithm which doesn't require any special
1926       # CPU support.
1927       USE_SLICING_BY_8_CRC32C=1
1928     fi
1929   fi
1930 fi
1931
1932 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1933 AC_MSG_CHECKING([which CRC-32C implementation to use])
1934 if test x"$USE_SSE42_CRC32C" = x"1"; then
1935   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1936   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1937   AC_MSG_RESULT(SSE 4.2)
1938 else
1939   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1940     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1941     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1942     AC_MSG_RESULT(SSE 4.2 with runtime check)
1943   else
1944     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1945     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1946     AC_MSG_RESULT(slicing-by-8)
1947   fi
1948 fi
1949 AC_SUBST(PG_CRC32C_OBJS)
1950
1951
1952 # Select semaphore implementation type.
1953 if test "$PORTNAME" != "win32"; then
1954   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1955     # Need sem_open for this
1956     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1957   fi
1958   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1959     # Need sem_init for this
1960     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1961   fi
1962   AC_MSG_CHECKING([which semaphore API to use])
1963   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1964     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1965     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1966     sematype="named POSIX"
1967   else
1968     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1969       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1970       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1971       sematype="unnamed POSIX"
1972     else
1973       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1974       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1975       sematype="System V"
1976     fi
1977   fi
1978   AC_MSG_RESULT([$sematype])
1979 else
1980   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1981   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1982 fi
1983
1984
1985 # Select shared-memory implementation type.
1986 if test "$PORTNAME" != "win32"; then
1987   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1988   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1989 else
1990   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1991   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1992 fi
1993
1994 # Select random number source
1995 #
1996 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
1997 # in the template or configure command line.
1998
1999 # If not selected manually, try to select a source automatically.
2000 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2001   if test x"$with_openssl" = x"yes" ; then
2002     USE_OPENSSL_RANDOM=1
2003   elif test "$PORTNAME" = "win32" ; then
2004     USE_WIN32_RANDOM=1
2005   else
2006     AC_CHECK_FILE([/dev/urandom], [], [])
2007
2008     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2009       USE_DEV_URANDOM=1
2010     fi
2011   fi
2012 fi
2013
2014 AC_MSG_CHECKING([which random number source to use])
2015 if test "$enable_strong_random" = yes ; then
2016   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2017     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2018     AC_MSG_RESULT([OpenSSL])
2019   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2020     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2021     AC_MSG_RESULT([Windows native])
2022   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2023     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2024     AC_MSG_RESULT([/dev/urandom])
2025   else
2026     AC_MSG_ERROR([
2027 no source of strong random numbers was found
2028 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2029 for authentication protocols. You can use --disable-strong-random to use a
2030 built-in pseudo random number generator, but that may be insecure.])
2031   fi
2032   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2033 else
2034     AC_MSG_RESULT([weak builtin PRNG])
2035     AC_MSG_WARN([
2036 *** Not using a strong random number source may be insecure.])
2037 fi
2038
2039 # If not set in template file, set bytes to use libc memset()
2040 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2041   MEMSET_LOOP_LIMIT=1024
2042 fi
2043 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2044
2045
2046 if test "$enable_nls" = yes ; then
2047   PGAC_CHECK_GETTEXT
2048 fi
2049
2050 # Check for Tcl configuration script tclConfig.sh
2051 if test "$with_tcl" = yes; then
2052     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2053     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2054                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2055     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2056     if test "$TCL_SHARED_BUILD" != 1; then
2057       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2058 Use --without-tcl to disable building PL/Tcl.])
2059     fi
2060     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2061     ac_save_CPPFLAGS=$CPPFLAGS
2062     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2063     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2064     CPPFLAGS=$ac_save_CPPFLAGS
2065 fi
2066
2067 # check for <perl.h>
2068 if test "$with_perl" = yes; then
2069   ac_save_CPPFLAGS=$CPPFLAGS
2070   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2071   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2072                   [#include <EXTERN.h>])
2073   # While we're at it, check that we can link to libperl.
2074   # On most platforms, if perl.h is there then libperl.so will be too, but at
2075   # this writing Debian packages them separately.  There is no known reason to
2076   # waste cycles on separate probes for the Tcl or Python libraries, though.
2077   pgac_save_LIBS=$LIBS
2078   LIBS="$perl_embed_ldflags"
2079   AC_MSG_CHECKING([for libperl])
2080   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2081 #include <EXTERN.h>
2082 #include <perl.h>
2083 ],  [perl_alloc();])],
2084     [AC_MSG_RESULT(yes)],
2085     [AC_MSG_RESULT(no)
2086      AC_MSG_ERROR([libperl library is required for Perl])])
2087   LIBS=$pgac_save_LIBS
2088   CPPFLAGS=$ac_save_CPPFLAGS
2089 fi
2090
2091 # check for <Python.h>
2092 if test "$with_python" = yes; then
2093   ac_save_CPPFLAGS=$CPPFLAGS
2094   CPPFLAGS="$python_includespec $CPPFLAGS"
2095   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2096   CPPFLAGS=$ac_save_CPPFLAGS
2097 fi
2098
2099 #
2100 # Check for DocBook and tools
2101 #
2102 PGAC_PATH_XMLLINT
2103 PGAC_CHECK_DOCBOOK(4.2)
2104 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2105 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2106 PGAC_PATH_PROGS(FOP, fop)
2107
2108 #
2109 # Check for test tools
2110 #
2111 if test "$enable_tap_tests" = yes; then
2112   # Check for necessary modules, unless user has specified the "prove" to use;
2113   # in that case it's her responsibility to have a working configuration.
2114   # (prove might be part of a different Perl installation than perl, eg on
2115   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2116   if test -z "$PROVE"; then
2117     AX_PROG_PERL_MODULES(IPC::Run, ,
2118       AC_MSG_ERROR([Perl module IPC::Run is required to run TAP tests]))
2119   fi
2120   # Now make sure we know where prove is
2121   PGAC_PATH_PROGS(PROVE, prove)
2122   if test -z "$PROVE"; then
2123     AC_MSG_ERROR([prove not found])
2124   fi
2125 fi
2126
2127 # Thread testing
2128
2129 # We have to run the thread test near the end so we have all our symbols
2130 # defined.  Cross compiling throws a warning.
2131 #
2132 if test "$enable_thread_safety" = yes; then
2133 if test "$PORTNAME" != "win32"
2134 then
2135 AC_MSG_CHECKING([thread safety of required library functions])
2136
2137 _CFLAGS="$CFLAGS"
2138 _LIBS="$LIBS"
2139 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2140 LIBS="$LIBS $PTHREAD_LIBS"
2141 AC_RUN_IFELSE(
2142   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2143   [AC_MSG_RESULT(yes)],
2144   [AC_MSG_RESULT(no)
2145   AC_MSG_ERROR([thread test program failed
2146 This platform is not thread-safe.  Check the file 'config.log' or compile
2147 and run src/test/thread/thread_test for the exact reason.
2148 Use --disable-thread-safety to disable thread safety.])],
2149   [AC_MSG_RESULT(maybe)
2150   AC_MSG_WARN([
2151 *** Skipping thread test program because of cross-compile build.
2152 *** Run the program in src/test/thread on the target machine.
2153 ])])
2154 CFLAGS="$_CFLAGS"
2155 LIBS="$_LIBS"
2156 else
2157 AC_MSG_WARN([*** skipping thread test on Win32])
2158 fi
2159 fi
2160
2161 # If compiler will take -Wl,--as-needed (or various platform-specific
2162 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2163 # trying to filter LIBS to the minimum for each executable.
2164 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2165 # libreadline; therefore we postpone testing it until we know what library
2166 # dependencies readline has.  The test code will try to link with $LIBS.
2167 if test "$with_readline" = yes; then
2168   link_test_func=readline
2169 else
2170   link_test_func=exit
2171 fi
2172
2173 if test "$PORTNAME" = "darwin"; then
2174   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2175 elif test "$PORTNAME" = "openbsd"; then
2176   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2177 else
2178   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2179 fi
2180
2181 # Create compiler version string
2182 if test x"$GCC" = x"yes" ; then
2183   cc_string=`${CC} --version | sed q`
2184   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2185 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2186   cc_string=`${CC} -V 2>&1 | sed q`
2187 else
2188   cc_string=$CC
2189 fi
2190
2191 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2192                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2193                    [A string containing the version number, platform, and C compiler])
2194
2195 # Supply a numeric version string for use by 3rd party add-ons
2196 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2197 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2198 tr '.' '        ' |
2199 $AWK '{printf "%d%04d", $1, $2}'`"]
2200 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2201 AC_SUBST(PG_VERSION_NUM)
2202
2203
2204 # Begin output steps
2205
2206 AC_MSG_NOTICE([using compiler=$cc_string])
2207 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2208 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2209 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2210
2211 # prepare build tree if outside source tree
2212 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2213 # Note 2: /bin/pwd might be better than shell's built-in at getting
2214 #         a symlink-free name.
2215 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2216   vpath_build=no
2217 else
2218   vpath_build=yes
2219   if test "$no_create" != yes; then
2220     _AS_ECHO_N([preparing build tree... ])
2221     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2222     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2223       || AC_MSG_ERROR(failed)
2224     AC_MSG_RESULT(done)
2225   fi
2226 fi
2227 AC_SUBST(vpath_build)
2228
2229
2230 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2231
2232 AC_CONFIG_LINKS([
2233   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2234   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2235   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2236   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2237   src/include/pg_config_os.h:src/include/port/${template}.h
2238   src/Makefile.port:src/makefiles/Makefile.${template}
2239 ])
2240
2241 if test "$PORTNAME" = "win32"; then
2242 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2243 # Links sometimes fail undetected on Mingw -
2244 # so here we detect it and warn the user
2245 for FILE in $CONFIG_LINKS
2246  do
2247         # test -e works for symlinks in the MinGW console
2248         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2249  done
2250 ])
2251 fi
2252
2253 AC_CONFIG_HEADERS([src/include/pg_config.h],
2254 [
2255 # Update timestamp for pg_config.h (see Makefile.global)
2256 echo >src/include/stamp-h
2257 ])
2258
2259 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2260 [
2261 # Update timestamp for pg_config_ext.h (see Makefile.global)
2262 echo >src/include/stamp-ext-h
2263 ])
2264
2265 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2266                   [echo >src/interfaces/ecpg/include/stamp-h])
2267
2268 AC_OUTPUT