granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.285 2003/09/07 03:43:52 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4beta2], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55 # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 #
 157 # NLS
 158 #
 159 AC_MSG_CHECKING([whether NLS is wanted])
 160 PGAC_ARG_OPTARG(enable, nls,
 161                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 162                 [],
 163                 [WANTED_LANGUAGES=$enableval],
 164                 [AC_DEFINE(ENABLE_NLS, 1,
 165                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 166 AC_MSG_RESULT([$enable_nls])
 167 AC_SUBST(enable_nls)
 168 AC_SUBST(WANTED_LANGUAGES)
 169
 170 #
 171 # Default port number (--with-pgport), default 5432
 172 #
 173 AC_MSG_CHECKING([for default port number])
 174 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 175              [default_port=$withval],
 176              [default_port=5432])
 177 AC_MSG_RESULT([$default_port])
 178 # Need both of these because some places want an integer and some a string
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 180 [Define to the default TCP port number on which the server listens and
 181 to which clients will try to connect.  This can be overridden at run-time,
 182 but it's convenient if your clients have the right default compiled in.
 183 (--with-pgport=PORTNUM)])
 184 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 185                    [Define to the default TCP port number as a string constant.])
 186 AC_SUBST(default_port)
 187
 188 #
 189 # Option to disable shared libraries
 190 #
 191 PGAC_ARG_BOOL(enable, shared, yes,
 192               [  --disable-shared        do not build shared libraries])
 193 AC_SUBST(enable_shared)
 194
 195 #
 196 # '-rpath'-like feature can be disabled
 197 #
 198 PGAC_ARG_BOOL(enable, rpath, yes,
 199               [  --disable-rpath         do not embed shared library search path in executables])
 200 AC_SUBST(enable_rpath)
 201
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # adjust CFLAGS per template
 233 if test "$ac_env_CFLAGS_set" = set; then
 234   CFLAGS=$ac_env_CFLAGS_value
 235 fi
 236 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 237   CFLAGS="$CFLAGS -g"
 238 fi
 239 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 240
 241 # We already have this in Makefile.win32, but configure needs it too
 242 if test "$PORTNAME" = "win32"
 243 then
 244         CPPFLAGS="$CPPFLAGS -Isrc/include/port/win32"
 245 fi
 246
 247 # Check if the compiler still works with the template settings
 248 AC_MSG_CHECKING([whether the C compiler still works])
 249 AC_TRY_LINK([], [return 0;],
 250   [AC_MSG_RESULT(yes)],
 251   [AC_MSG_RESULT(no)
 252    AC_MSG_ERROR([cannot proceed])])
 253
 254 # Defend against gcc -ffastmath
 255 if test "$GCC" = yes; then
 256 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 257 choke me
 258 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 259 fi
 260
 261 AC_PROG_CPP
 262 AC_SUBST(GCC)
 263
 264 # Create compiler version string
 265 if test x"$GCC" = x"yes" ; then
 266   cc_string="GCC `${CC} --version | sed q`"
 267 else
 268   cc_string=$CC
 269 fi
 270 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 271                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 272                    [A string containing the version number, platform, and C compiler])
 273
 274
 275 #
 276 # Automatic dependency tracking
 277 #
 278 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 279               [autodepend=yes])
 280 AC_SUBST(autodepend)
 281
 282
 283 #
 284 # Enable assert checks
 285 #
 286 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 287               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 288                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 289
 290
 291 #
 292 # Include directories
 293 #
 294 ac_save_IFS=$IFS
 295 IFS="${IFS}:"
 296 # SRCH_INC comes from the template file
 297 for dir in $with_includes $SRCH_INC; do
 298   if test -d "$dir"; then
 299     INCLUDES="$INCLUDES -I$dir"
 300   else
 301     AC_MSG_WARN([*** Include directory $dir does not exist.])
 302   fi
 303 done
 304 IFS=$ac_save_IFS
 305 AC_SUBST(INCLUDES)
 306
 307
 308 #
 309 # Library directories
 310 #
 311 ac_save_IFS=$IFS
 312 IFS="${IFS}:"
 313 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 314 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 315   if test -d "$dir"; then
 316     LIBDIRS="$LIBDIRS -L$dir"
 317   else
 318     AC_MSG_WARN([*** Library directory $dir does not exist.])
 319   fi
 320 done
 321 IFS=$ac_save_IFS
 322
 323 #
 324 # Enable thread-safe client libraries
 325 #
 326 AC_MSG_CHECKING([allow thread-safe client libraries])
 327 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 328               [AC_DEFINE([USE_THREADS], 1,
 329                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 330 AC_MSG_RESULT([$enable_thread_safety])
 331 AC_SUBST(enable_thread_safety)
 332
 333 #
 334 # Tcl/Tk
 335 #
 336 AC_MSG_CHECKING([whether to build with Tcl])
 337 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 338 AC_MSG_RESULT([$with_tcl])
 339 AC_SUBST([with_tcl])
 340
 341 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 342 AC_MSG_CHECKING([whether to build with Tk])
 343 if test "$with_tcl" = yes; then
 344   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 345 else
 346   with_tk=no
 347 fi
 348 AC_MSG_RESULT([$with_tk])
 349 AC_SUBST([with_tk])
 350
 351
 352 # We see if the path to the Tcl/Tk configuration scripts is specified.
 353 # This will override the use of tclsh to find the paths to search.
 354
 355 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 356
 357 # We see if the path to the Tk configuration scripts is specified.
 358 # This will override the use of tclsh to find the paths to search.
 359
 360 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 361
 362 #
 363 # Optionally build Perl modules (PL/Perl)
 364 #
 365 AC_MSG_CHECKING([whether to build Perl modules])
 366 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 367 AC_MSG_RESULT([$with_perl])
 368 AC_SUBST(with_perl)
 369
 370 #
 371 # Optionally build Python modules (PL/Python)
 372 #
 373 AC_MSG_CHECKING([whether to build Python modules])
 374 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 375 AC_MSG_RESULT([$with_python])
 376 AC_SUBST(with_python)
 377
 378 #
 379 # Optionally build the Java/JDBC tools
 380 #
 381 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 382 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 383 [AC_MSG_RESULT(yes)
 384 PGAC_PATH_ANT
 385 if test -z "$ANT"; then
 386   AC_MSG_ERROR([Ant is required to build Java components
 387 If you have Ant already installed, see config.log for details on the failure.])
 388 fi
 389 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 390   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 391 fi],
 392 [AC_MSG_RESULT(no)])
 393 AC_SUBST(with_java)
 394
 395 dnl A note on the Kerberos and OpenSSL options:
 396 dnl
 397 dnl The user can give an argument to the option in order the specify
 398 dnl the base path of the respective installation (what he specified
 399 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 400 dnl then we take the path where the package installs by default. This
 401 dnl way the user doesn't have to use redundant --with-includes and
 402 dnl --with-libraries options, but he can still use them if the layout
 403 dnl is non-standard.
 404
 405 #
 406 # Kerberos 4
 407 #
 408 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 409 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 410                 [krb4_prefix=/usr/athena],
 411                 [krb4_prefix=$withval],
 412 [
 413   AC_MSG_RESULT(yes)
 414   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 415
 416   if test -d "$krb4_prefix/include"; then
 417     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 418   fi
 419   if test -d "$krb4_prefix/lib"; then
 420     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 421   fi
 422
 423   krb_srvtab="/etc/srvtab"
 424 ],
 425 [AC_MSG_RESULT(no)])
 426
 427 AC_SUBST(with_krb4)
 428
 429
 430 #
 431 # Kerberos 5
 432 #
 433 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 434 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 435               [krb5_prefix=/usr/athena],
 436               [krb5_prefix=$withval],
 437 [
 438   AC_MSG_RESULT([yes])
 439   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 440
 441   if test -d "$krb5_prefix/include"; then
 442     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 443   fi
 444   if test -d "$krb5_prefix/lib"; then
 445     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 446   fi
 447
 448   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 449 ],
 450 [AC_MSG_RESULT(no)])
 451
 452 AC_SUBST(with_krb5)
 453
 454
 455 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 456 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 457   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 458 fi
 459
 460 AC_SUBST(krb_srvtab)
 461
 462
 463 #
 464 # Kerberos configuration parameters
 465 #
 466 PGAC_ARG_REQ(with, krb-srvnam,
 467              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 468              [],
 469              [with_krb_srvnam="postgres"])
 470 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 471                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 472
 473
 474 #
 475 # PAM
 476 #
 477 AC_MSG_CHECKING([whether to build with PAM support])
 478 PGAC_ARG_BOOL(with, pam, no,
 479               [  --with-pam              build with PAM support],
 480               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 481 AC_MSG_RESULT([$with_pam])
 482 AC_SUBST(with_pam)
 483
 484
 485 #
 486 # Rendezvous
 487 #
 488 AC_MSG_CHECKING([whether to build with Rendezvous support])
 489 PGAC_ARG_BOOL(with, rendezvous, no,
 490               [  --with-rendezvous       build with Rendezvous support],
 491               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 492 AC_MSG_RESULT([$with_rendezvous])
 493 AC_SUBST(with_rendezvous)
 494
 495
 496 #
 497 # OpenSSL
 498 #
 499 PGAC_ARG_OPTARG(with, openssl,
 500                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 501                 [openssl_prefix=/usr/local/ssl],
 502                 [openssl_prefix=$withval],
 503 [
 504   AC_MSG_RESULT([building with OpenSSL support])
 505   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 506
 507   if test -d "${openssl_prefix}/include" ; then
 508     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 509   fi
 510   if test -d "${openssl_prefix}/lib" ; then
 511     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 512   fi
 513 ])
 514
 515 AC_SUBST(with_openssl)
 516
 517
 518 #
 519 # Readline
 520 #
 521 PGAC_ARG_BOOL(with, readline, yes,
 522               [  --without-readline      do not use Readline])
 523
 524 #
 525 # Zlib
 526 #
 527 PGAC_ARG_BOOL(with, zlib, yes,
 528               [  --without-zlib          do not use Zlib])
 529
 530
 531 #
 532 # Elf
 533 #
 534
 535 # Assume system is ELF if it predefines __ELF__ as 1,
 536 # otherwise believe host_os based default.
 537 case $host_os in
 538     freebsd1*|freebsd2*) elf=no;;
 539     freebsd3*|freebsd4*) elf=yes;;
 540 esac
 541
 542 AC_EGREP_CPP(yes,
 543 [#if __ELF__
 544   yes
 545 #endif
 546 ],
 547 [ELF_SYS=true],
 548 [if test "X$elf" = "Xyes" ; then
 549   ELF_SYS=true
 550 else
 551   ELF_SYS=
 552 fi])
 553 AC_SUBST(ELF_SYS)
 554
 555 #
 556 # Assignments
 557 #
 558
 559 CPPFLAGS="$CPPFLAGS $INCLUDES"
 560 LDFLAGS="$LDFLAGS $LIBDIRS"
 561
 562 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 563 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 564
 565
 566 AC_PROG_AWK
 567 PGAC_PATH_FLEX
 568 AC_PROG_LN_S
 569 AC_PROG_LD
 570 AC_SUBST(LD)
 571 AC_SUBST(with_gnu_ld)
 572 case $host_os in sysv5*)
 573   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 574   [
 575     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 576     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 577     LDFLAGS=$pgac_save_LDFLAGS
 578   ])
 579   ld_R_works=$pgac_cv_prog_ld_R
 580   AC_SUBST(ld_R_works)
 581 esac
 582 AC_PROG_RANLIB
 583 AC_CHECK_PROGS(LORDER, lorder)
 584 AC_PATH_PROG(TAR, tar)
 585 PGAC_CHECK_STRIP
 586
 587 AC_CHECK_PROGS(YACC, ['bison -y'])
 588
 589 if test "$YACC"; then
 590   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 591     AC_MSG_WARN([
 592 *** The installed version of Bison is too old.  PostgreSQL needs
 593 *** Bison version 1.875 or later.])
 594   fi
 595 fi
 596
 597 if test -z "$YACC"; then
 598   AC_MSG_WARN([
 599 *** Without Bison you will not be able to build PostgreSQL from CVS or
 600 *** change any of the parser definition files.  You can obtain Bison from
 601 *** a GNU mirror site.  (If you are using the official distribution of
 602 *** PostgreSQL then you do not need to worry about this because the Bison
 603 *** output is pre-generated.)  To use a different yacc program (possible,
 604 *** but not recommended), set the environment variable YACC before running
 605 *** 'configure'.])
 606 fi
 607 AC_SUBST(YFLAGS)
 608
 609 PGAC_PATH_PERL
 610 if test "$with_perl" = yes; then
 611   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 612   PGAC_CHECK_PERL_EMBED_LDFLAGS
 613 fi
 614
 615 if test "$with_python" = yes; then
 616   PGAC_PATH_PYTHON
 617   PGAC_CHECK_PYTHON_EMBED_SETUP
 618 fi
 619
 620
 621 ##
 622 ## Libraries
 623 ##
 624
 625 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 626 then
 627         AC_CHECK_LIB(bsd,      main)
 628 fi
 629 AC_CHECK_LIB(util,     setproctitle)
 630 AC_CHECK_LIB(m,        main)
 631 AC_CHECK_LIB(dl,       main)
 632 AC_CHECK_LIB(nsl,      main)
 633 AC_CHECK_LIB(socket,   main)
 634 AC_CHECK_LIB(ipc,      main)
 635 AC_CHECK_LIB(IPC,      main)
 636 AC_CHECK_LIB(lc,       main)
 637 AC_CHECK_LIB(dld,      main)
 638 AC_CHECK_LIB(ld,       main)
 639 AC_CHECK_LIB(compat,   main)
 640 AC_CHECK_LIB(BSD,      main)
 641 AC_CHECK_LIB(gen,      main)
 642 AC_CHECK_LIB(PW,       main)
 643 AC_CHECK_LIB(resolv,   main)
 644 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 645 # QNX:
 646 AC_CHECK_LIB(unix, main)
 647 AC_SEARCH_LIBS(crypt,  crypt)
 648 # BeOS:
 649 if test "$PORTNAME" = "beos"
 650 then
 651         AC_CHECK_LIB(bind, __inet_ntoa)
 652 fi
 653 # Solaris:
 654 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 655 # Cygwin:
 656 AC_CHECK_LIB(cygipc, shmget)
 657 # WIN32:
 658 if test "$PORTNAME" = "win32"
 659 then
 660         AC_CHECK_LIB(wsock32, main)
 661 fi
 662
 663 if test "$with_readline" = yes; then
 664   PGAC_CHECK_READLINE
 665   if test x"$pgac_cv_check_readline" = x"no"; then
 666     AC_MSG_ERROR([readline library not found
 667 If you have readline already installed, see config.log for details on the
 668 failure.  It is possible the compiler isn't looking in the proper directory.
 669 Use --without-readline to disable readline support.])
 670   fi
 671 fi
 672
 673 if test "$with_zlib" = yes; then
 674   AC_CHECK_LIB(z, inflate, [],
 675                [AC_MSG_ERROR([zlib library not found
 676 If you have zlib already installed, see config.log for details on the
 677 failure.  It is possible the compiler isn't looking in the proper directory.
 678 Use --without-zlib to disable zlib support.])])
 679 fi
 680
 681 if test "$with_krb4" = yes ; then
 682   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 683   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 684   AC_REPLACE_FUNCS([gethostname])
 685 fi
 686
 687 if test "$with_krb5" = yes ; then
 688   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 689                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 690   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 691                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 692   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 693                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 694 fi
 695
 696 if test "$with_openssl" = yes ; then
 697   dnl Order matters!
 698   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 699   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 700 fi
 701
 702 if test "$with_pam" = yes ; then
 703   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 704 fi
 705
 706
 707 ##
 708 ## Header files
 709 ##
 710
 711 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 712 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 713
 714 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 715 # netinet/in.h is included first.
 716 AC_CHECK_HEADERS(netinet/in.h)
 717 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 718 [AC_INCLUDES_DEFAULT
 719 #ifdef HAVE_NETINET_IN_H
 720 #include <netinet/in.h>
 721 #endif
 722 ])
 723
 724 if test "$with_readline" = yes; then
 725   AC_CHECK_HEADERS(readline/readline.h, [],
 726                    [AC_CHECK_HEADERS(editline/readline.h, [],
 727                          [AC_CHECK_HEADERS(readline.h, [],
 728                                      [AC_MSG_ERROR([readline header not found
 729 If you have readline already installed, see config.log for details on the
 730 failure.  It is possible the compiler isn't looking in the proper directory.
 731 Use --without-readline to disable readline support.])])])])
 732   AC_CHECK_HEADERS(readline/history.h, [],
 733                    [AC_CHECK_HEADERS(editline/history.h, [],
 734                          [AC_CHECK_HEADERS(history.h, [],
 735                                      [AC_MSG_ERROR([history header not found
 736 If you have readline already installed, see config.log for details on the
 737 failure.  It is possible the compiler isn't looking in the proper directory.
 738 Use --without-readline to disable readline support.])])])])
 739 fi
 740
 741 if test "$with_zlib" = yes; then
 742   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 743 If you have zlib already installed, see config.log for details on the
 744 failure.  It is possible the compiler isn't looking in the proper directory.
 745 Use --without-zlib to disable zlib support.])])
 746 fi
 747
 748 if test "$with_krb4" = yes ; then
 749   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 750 fi
 751
 752 if test "$with_krb5" = yes ; then
 753   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 754   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 755 fi
 756
 757 if test "$with_openssl" = yes ; then
 758   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 759   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 760 fi
 761
 762 if test "$with_pam" = yes ; then
 763   AC_CHECK_HEADERS(security/pam_appl.h, [],
 764                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 765                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 766 fi
 767
 768 if test "$with_rendezvous" = yes ; then
 769   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 770 fi
 771
 772
 773 ##
 774 ## Types, structures, compiler characteristics
 775 ##
 776
 777 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 778 AC_C_CONST
 779 AC_C_INLINE
 780 AC_C_STRINGIZE
 781 PGAC_C_SIGNED
 782 AC_C_VOLATILE
 783 PGAC_C_FUNCNAME_SUPPORT
 784 PGAC_STRUCT_TIMEZONE
 785 PGAC_UNION_SEMUN
 786 PGAC_STRUCT_SOCKADDR_UN
 787 PGAC_STRUCT_SOCKADDR_STORAGE
 788 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 789 PGAC_STRUCT_ADDRINFO
 790
 791 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 792 [#include <sys/param.h>
 793 #include <sys/types.h>
 794 #include <sys/socket.h>
 795 #include <sys/ucred.h>])
 796
 797 AC_CHECK_TYPES([struct option], [], [],
 798 [#ifdef HAVE_GETOPT_H
 799 #include <getopt.h>
 800 #endif])
 801
 802 if test "$with_zlib" = yes; then
 803   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 804   # did not).  While we could work around the lack of z_streamp, it
 805   # seems unwise to encourage people to use such old zlib versions...
 806   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 807 Use --without-zlib to disable zlib support.])],
 808                 [#include <zlib.h>])
 809 fi
 810
 811 if test "$with_krb5" = yes; then
 812 # Check for differences between MIT and Heimdal (KTH) releases
 813   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 814                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 815                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 816                                      [#include <krb5.h>])],
 817                    [#include <krb5.h>])
 818   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 819                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 820                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 821                                      [#include <krb5.h>])],
 822                    [#include <krb5.h>])
 823 fi
 824
 825
 826 ##
 827 ## Functions, global variables
 828 ##
 829
 830 PGAC_VAR_INT_TIMEZONE
 831 AC_FUNC_ACCEPT_ARGTYPES
 832 PGAC_FUNC_GETTIMEOFDAY_1ARG
 833
 834 # SunOS doesn't handle negative byte comparisons properly with +/- return
 835 AC_FUNC_MEMCMP
 836
 837 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 838
 839 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 840
 841 HAVE_IPV6=no
 842 AC_CHECK_TYPE([struct sockaddr_in6],
 843               [AC_CHECK_FUNC(inet_ntop,
 844                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 845                                                           HAVE_IPV6=yes])],
 846               [],
 847 [$ac_includes_default
 848 #include <netinet/in.h>])
 849 AC_SUBST(HAVE_IPV6)
 850
 851 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 852 [AC_TRY_LINK(
 853 [#include <machine/vmparam.h>
 854 #include <sys/exec.h>
 855 ],
 856 [PS_STRINGS->ps_nargvstr = 1;
 857 PS_STRINGS->ps_argvstr = "foo";],
 858 [pgac_cv_var_PS_STRINGS=yes],
 859 [pgac_cv_var_PS_STRINGS=no])])
 860 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 861   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 862 fi
 863
 864
 865 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 866 # is missing.  Yes, there are machines that have only one.  We may
 867 # also decide to use snprintf.c if snprintf() is present but does not
 868 # have working "long long int" support -- see below.
 869
 870 pgac_need_repl_snprintf=no
 871 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 872 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 873
 874
 875 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 876 # include/c.h will provide declarations.  Note this is a separate test
 877 # from whether the functions exist in the C library --- there are
 878 # systems that have the functions but don't bother to declare them :-(
 879
 880 AC_CHECK_DECLS([snprintf, vsnprintf])
 881
 882
 883 # do this one the hard way in case isinf() is a macro
 884 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 885 [AC_TRY_LINK(
 886 [#include <math.h>
 887 ],
 888 [double x = 0.0; int res = isinf(x);],
 889 [ac_cv_func_isinf=yes],
 890 [ac_cv_func_isinf=no])])
 891
 892 if test $ac_cv_func_isinf = yes ; then
 893   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 894 else
 895   AC_LIBOBJ(isinf)
 896   # Look for a way to implement a substitute for isinf()
 897   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 898 fi
 899
 900 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 901
 902 # system's version of getaddrinfo(), if any, may be used only if we found
 903 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 904 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 905   AC_REPLACE_FUNCS([getaddrinfo])
 906 else
 907   AC_LIBOBJ(getaddrinfo)
 908 fi
 909
 910 # similarly, use system's getopt_long() only if system provides struct option.
 911 if test x"$ac_cv_type_struct_option" = xyes ; then
 912   AC_REPLACE_FUNCS([getopt_long])
 913 else
 914   AC_LIBOBJ(getopt_long)
 915 fi
 916
 917 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 918 # We override the previous test that said fseeko/ftello didn't exist
 919 # OS tests are also done in include/c.h and port/fseeko.c
 920 case $host_os in bsdi*|netbsd*)
 921 ac_cv_func_fseeko=yes
 922 esac
 923
 924 # Solaris has a very slow qsort in certain cases, so we replace it.
 925 case $host_os in solaris*)
 926 AC_LIBOBJ(qsort) ;;
 927 esac
 928
 929 # Win32 can't to rename or unlink on an open file
 930 case $host_os in mingw*)
 931 AC_LIBOBJ(dirmod)
 932 AC_LIBOBJ(copydir)
 933 AC_LIBOBJ(gettimeofday) ;;
 934 esac
 935
 936 if test "$with_readline" = yes; then
 937   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 938   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 939   AC_CHECK_FUNCS([replace_history_entry])
 940 fi
 941
 942
 943 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 944 AC_MSG_CHECKING(for finite)
 945 AC_TRY_LINK([#include <math.h>],
 946             [int dummy=finite(1.0);],
 947             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 948 AC_MSG_RESULT(yes)],
 949             [AC_MSG_RESULT(no)])
 950
 951 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 952 dnl (especially on GNU libc)
 953 dnl See also comments in c.h.
 954 AC_MSG_CHECKING(for sigsetjmp)
 955 AC_TRY_LINK([#include <setjmp.h>],
 956             [sigjmp_buf x; sigsetjmp(x, 1);],
 957             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 958 AC_MSG_RESULT(yes)],
 959             [AC_MSG_RESULT(no)])
 960
 961 AC_CHECK_FUNC(syslog,
 962               [AC_CHECK_HEADER(syslog.h,
 963                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 964
 965 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 966 [AC_TRY_LINK([#include <unistd.h>],
 967   [extern int optreset; optreset = 1;],
 968   [pgac_cv_var_int_optreset=yes],
 969   [pgac_cv_var_int_optreset=no])])
 970 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 971   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 972 fi
 973
 974 AC_CHECK_FUNCS([strtoll strtoq], [break])
 975 AC_CHECK_FUNCS([strtoull strtouq], [break])
 976
 977 # Check for one of atexit() or on_exit()
 978 AC_CHECK_FUNCS(atexit, [],
 979                [AC_CHECK_FUNCS(on_exit, [],
 980                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 981
 982 AC_FUNC_FSEEKO
 983
 984 #
 985 # Pthreads
 986 #
 987 # For each platform, we need to know about any special compile and link
 988 # libraries, and whether the normal C function names are thread-safe.
 989 # See the comment at the top of src/port/thread.c for more information.
 990 #
 991 if test "$enable_thread_safety" = yes; then
 992 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
 993
 994 if test "$SUPPORTS_THREADS" != yes; then
 995 AC_MSG_ERROR([
 996 Cannot enable threads on your platform.
 997 Please report your platform threading info to the PostgreSQL mailing lists
 998 so it can be added to the next release.  Report all compile flags, link flags,
 999 functions, or libraries required for threading support.
1000 See the comment at the top of src/port/thread.c for more information.
1001 ])
1002 fi
1003 else
1004 # do not use values from template file
1005 THREAD_CFLAGS=
1006 THREAD_LIBS=
1007 fi
1008 AC_SUBST(THREAD_CFLAGS)
1009 AC_SUBST(THREAD_LIBS)
1010
1011
1012 #
1013 # Check for re-entrant versions of certain functions
1014 #
1015 # Include special flags if threads are enabled _and_ if required for
1016 # threading on this platform.  Some platforms have *_r functions but
1017 # their natively named funcs are threadsafe, and should be used instead.
1018 #
1019 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1020 # functions are marked "not found", which is perfect.
1021 #
1022 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNC_NAMES" = yes ; then
1023 _CFLAGS="$CFLAGS"
1024 _LIBS="$LIBS"
1025 CFLAGS="$CFLAGS $THREAD_CFLAGS"
1026 LIBS="$LIBS $THREAD_LIBS"
1027 AC_CHECK_FUNC(strerror_r,
1028         [], [AC_MSG_ERROR([strerror_r not found, required on this platform for --enable-thread-safety])])
1029 AC_CHECK_FUNC(getpwuid_r,
1030         [], [AC_MSG_ERROR([getpwuid_r not found, required on this platform for --enable-thread-safety])])
1031 AC_CHECK_FUNC(gethostbyname_r,
1032         [], [AC_MSG_ERROR([gethostbyname_r not found, required on this platform for --enable-thread-safety])])
1033 CFLAGS="$_CFLAGS"
1034 LIBS="$_LIBS"
1035 fi
1036
1037
1038 # This test makes sure that run tests work at all.  Sometimes a shared
1039 # library is found by the linker, but the runtime linker can't find it.
1040 # This check should come after all modifications of compiler or linker
1041 # variables, and before any other run tests.
1042 AC_MSG_CHECKING([test program])
1043 AC_TRY_RUN([int main() { return 0; }],
1044 [AC_MSG_RESULT(ok)],
1045 [AC_MSG_RESULT(failed)
1046 AC_MSG_ERROR([[
1047 *** Could not execute a simple test program.  This may be a problem
1048 *** related to locating shared libraries.  Check the file 'config.log'
1049 *** for the exact reason.]])],
1050 [AC_MSG_RESULT([cross-compiling])])
1051
1052
1053 dnl Check to see if we have a working 64-bit integer type.
1054 dnl This breaks down into two steps:
1055 dnl (1) figure out if the compiler has a 64-bit int type with working
1056 dnl arithmetic, and if so
1057 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1058 dnl snprintf is the only library routine we really need for int8 support.)
1059 dnl It's entirely possible to have a compiler that handles a 64-bit type
1060 dnl when the C library doesn't; this is fairly likely when using gcc on
1061 dnl an older platform, for example.
1062 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1063 dnl we force our own version of snprintf() to be used instead.
1064 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1065
1066 PGAC_TYPE_64BIT_INT([long int])
1067
1068 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1069   PGAC_TYPE_64BIT_INT([long long int])
1070 fi
1071
1072
1073 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1074
1075 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1076   AC_TRY_COMPILE([
1077 #define INT64CONST(x)  x##LL
1078 long long int foo = INT64CONST(0x1234567890123456);
1079 ],
1080         [],
1081         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1082         [])
1083 fi
1084
1085
1086 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1087 # we found we need to use "long long int", better check.  We cope with
1088 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1089 # neither works, fall back to our own snprintf emulation (which we
1090 # know uses %lld).
1091
1092 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1093   if test $pgac_need_repl_snprintf = no; then
1094     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1095     if test "$LONG_LONG_INT_FORMAT" = ""; then
1096       # Force usage of our own snprintf, since system snprintf is broken
1097       pgac_need_repl_snprintf=yes
1098       LONG_LONG_INT_FORMAT='%lld'
1099     fi
1100   else
1101     # Here if we previously decided we needed to use our own snprintf
1102     LONG_LONG_INT_FORMAT='%lld'
1103   fi
1104   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1105 else
1106   # Here if we are not using 'long long int' at all
1107   INT64_FORMAT='"%ld"'
1108 fi
1109
1110 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1111                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1112
1113 if test $pgac_need_repl_snprintf = yes; then
1114   AC_LIBOBJ(snprintf)
1115 fi
1116
1117 # Need a #define for the size of Datum (unsigned long)
1118 AC_CHECK_SIZEOF([unsigned long])
1119
1120 # Determine memory alignment requirements for the basic C data types.
1121
1122 PGAC_CHECK_ALIGNOF(short)
1123 PGAC_CHECK_ALIGNOF(int)
1124 PGAC_CHECK_ALIGNOF(long)
1125 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1126   PGAC_CHECK_ALIGNOF(long long int)
1127 fi
1128 PGAC_CHECK_ALIGNOF(double)
1129
1130 # Compute maximum alignment of any basic type.
1131 # We assume long's alignment is at least as strong as char, short, or int;
1132 # but we must check long long (if it exists) and double.
1133
1134 MAX_ALIGNOF=$pgac_cv_alignof_long
1135 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1136   MAX_ALIGNOF=$pgac_cv_alignof_double
1137 fi
1138 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1139   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1140 fi
1141 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1142
1143
1144 # Some platforms predefine the types int8, int16, etc.  Only check
1145 # a (hopefully) representative subset.
1146 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1147 [#include <stdio.h>
1148 #ifdef HAVE_SUPPORTDEFS_H
1149 #include <SupportDefs.h>
1150 #endif])
1151
1152 # We also check for sig_atomic_t, which *should* be defined per ANSI
1153 # C, but is missing on some old platforms.
1154 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1155
1156
1157 PGAC_FUNC_POSIX_SIGNALS
1158 if test $ac_cv_func_fseeko = yes; then
1159 AC_SYS_LARGEFILE
1160 fi
1161
1162
1163 # Select semaphore implementation type.
1164 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1165   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1166   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1167 else
1168   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1169     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1170     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1171   else
1172     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1173     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1174   fi
1175 fi
1176
1177
1178 # Select shared-memory implementation type.
1179 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1180 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1181
1182
1183 if test "$enable_nls" = yes ; then
1184   PGAC_CHECK_GETTEXT
1185 fi
1186
1187 # Check for Tcl configuration script tclConfig.sh
1188 if test "$with_tcl" = yes; then
1189     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1190     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1191                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1192     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1193 fi
1194
1195 # Check for Tk configuration script tkConfig.sh
1196 if test "$with_tk" = yes; then
1197     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1198     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1199 fi
1200
1201
1202 #
1203 # Check for DocBook and tools
1204 #
1205 PGAC_PROG_NSGMLS
1206 PGAC_PROG_JADE
1207 PGAC_CHECK_DOCBOOK(3.1)
1208 PGAC_PATH_DOCBOOK_STYLESHEETS
1209 PGAC_PATH_COLLATEINDEX
1210 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1211
1212
1213 # prepare build tree if outside source tree
1214 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1215 # Note 2: /bin/pwd might be better than shell's built-in at getting
1216 #         a symlink-free name.
1217 if test "$no_create" != yes; then
1218   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1219     :
1220   else
1221     AC_SUBST(vpath_build, yes)
1222     _AS_ECHO_N([preparing build tree... ])
1223     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1224     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1225       || AC_MSG_ERROR(failed)
1226     AC_MSG_RESULT(done)
1227   fi
1228 fi
1229
1230
1231 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1232
1233 AC_CONFIG_LINKS([
1234   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1235   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1236   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1237   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1238   src/include/pg_config_os.h:src/include/port/${template}.h
1239   src/Makefile.port:src/makefiles/Makefile.${template}
1240 ])
1241
1242 AC_CONFIG_HEADERS([src/include/pg_config.h],
1243 [
1244 # Update timestamp for pg_config.h (see Makefile.global)
1245 echo >src/include/stamp-h
1246 ])
1247
1248 AC_OUTPUT