granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  84
  85 AC_ARG_WITH(included-apr,
  86 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  87
  88 if test "x$with_included_apr" = "xyes"; then
  89   apr_found=reconfig
  90   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  91     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
  92   fi
  93 else
  94   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  95 fi
  96
  97 if test "$apr_found" = "no"; then
  98   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  99 fi
 100
 101 if test "$apr_found" = "reconfig"; then
 102   APR_SUBDIR_CONFIG(srclib/apr,
 103                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 104                     [--enable-layout=*|\'--enable-layout=*])
 105   dnl We must be the first to build and the last to be cleaned
 106   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 107   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 108
 109   dnl We have to find apr-N-config when we reconfigure APR.
 110   for majorver in 1 2; do
 111     test_apr_config="./srclib/apr/apr-${majorver}-config"
 112     if test -f "$test_apr_config"; then
 113       apr_config="$test_apr_config"
 114     fi
 115   done
 116 fi
 117
 118 APR_SETIFNULL(CC, `$apr_config --cc`)
 119 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 120 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 121 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 122 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 123 INTERNAL_CPPFLAGS=""
 124 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 125 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 126 APR_BINDIR=`$apr_config --bindir`
 127 APR_INCLUDEDIR=`$apr_config --includedir`
 128 APR_INCLUDES=`$apr_config --includes`
 129 APR_VERSION=`$apr_config --version`
 130 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 131 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 132
 133 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 134
 135 if test "x${apr_major_version}" = "x2"; then
 136   apu_found=obsolete
 137 elif test "x$with_included_apr" = "xyes"; then
 138   apu_found=reconfig
 139   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 140     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
 141   fi
 142 else
 143    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 144    dnl isn't supported.
 145    ifdef([APR_FIND_APU], [
 146      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 147                   1, ${apr_major_version})
 148    ], [apu_found=no])
 149 fi
 150
 151 if test "$apu_found" = "no"; then
 152   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 153 fi
 154
 155 # Catch some misconfigurations:
 156 case ${apr_found}.${apu_found} in
 157 reconfig.yes)
 158   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 159   ;;
 160 yes.reconfig)
 161   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 162   ;;
 163 esac
 164
 165 if test "$apu_found" = "reconfig"; then
 166   APR_SUBDIR_CONFIG(srclib/apr-util,
 167                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 168                     [--enable-layout=*|\'--enable-layout=*])
 169   dnl We must be the last to build and the first to be cleaned
 170   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 171   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 172   dnl APR and APR-Util major versions must match
 173   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 174 fi
 175
 176 if test "$apu_found" = "obsolete"; then
 177   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 178 else
 179   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 180   APU_BINDIR=`$apu_config --bindir`
 181   APU_INCLUDEDIR=`$apu_config --includedir`
 182   APU_INCLUDES=`$apu_config --includes`
 183   APU_VERSION=`$apu_config --version`
 184   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 185 fi
 186
 187 dnl In case we picked up CC and CPP from APR, get that info into the
 188 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 189 dnl PCRE and for our config tests will be whatever PCRE determines.
 190 AC_PROG_CC
 191 AC_PROG_CPP
 192
 193 dnl Try to get c99 support for variadic macros
 194 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 195
 196 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 197 dnl we got already CC_FOR_BUILD from environment.
 198 if test "x${build_alias}" != "x${host_alias}"; then
 199   if test "x${CC_FOR_BUILD}" = "x"; then
 200     CC_FOR_BUILD=cc
 201   fi
 202 fi
 203
 204 if test "x${cache_file}" = "x/dev/null"; then
 205   # Likewise, ensure that CC and CPP are passed through to the pcre
 206   # configure script iff caching is disabled (the autoconf 2.5x default).
 207   export CC; export CPP
 208 fi
 209
 210 AC_ARG_WITH(pcre,
 211 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 212
 213 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 214 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 215    PCRE_CONFIG=$with_pcre/bin/pcre-config
 216 elif test -x "$with_pcre"; then
 217    PCRE_CONFIG=$with_pcre
 218 fi
 219
 220 if test "$PCRE_CONFIG" != "false"; then
 221   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 222     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 223   fi
 224   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 225   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 226   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 227 else
 228   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 229 fi
 230 APACHE_SUBST(PCRE_LIBS)
 231
 232 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 233
 234 dnl If the source dir is not equal to the build dir,
 235 dnl then we are running in VPATH mode.
 236
 237 APR_ADDTO(INCLUDES, [-I.])
 238
 239 if test "$abs_builddir" != "$abs_srcdir"; then
 240   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 241 fi
 242
 243 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 244
 245 # apr/apr-util --includes may pick up system paths for dependent
 246 # libraries, so ensure these are later in INCLUDES than local source
 247 # directories.
 248 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 249 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 250
 251 dnl Add in path to PCRE includes
 252 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 253
 254 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 255
 256 case $host in
 257   *os2*)
 258       # Use a custom made libtool replacement
 259       echo "using aplibtool"
 260       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 261       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 262       SH_LIBS="\$(ALL_LIBS)"
 263       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 264       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 265       MK_IMPLIB="emximp"
 266       other_targets="$other_targets os2core"
 267       INSTALL_PROG_FLAGS="-e .exe"
 268       SHLTCFLAGS=""
 269       LTCFLAGS=""
 270       ;;
 271   *)
 272       if test "x$LTFLAGS" = "x"; then
 273           LTFLAGS='--silent'
 274       fi
 275       my_libtool=`$apr_config --apr-libtool`
 276       LIBTOOL="$my_libtool \$(LTFLAGS)"
 277       libtoolversion=`$my_libtool --version`
 278       case $libtoolversion in
 279           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 280               SH_LIBTOOL='$(LIBTOOL)'
 281               SHLTCFLAGS="-prefer-pic"
 282               LTCFLAGS="-prefer-non-pic -static"
 283               ;;
 284           *)
 285               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 286               SHLTCFLAGS=""
 287               LTCFLAGS=""
 288               ;;
 289       esac
 290       ;;
 291 esac
 292 APACHE_SUBST(SHLTCFLAGS)
 293 APACHE_SUBST(LTCFLAGS)
 294
 295 case $host in
 296   *-apple-aux3*)
 297       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 298       ;;
 299   *os2-emx*)
 300       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 301       ;;
 302   *-linux-*)
 303       case `uname -r` in
 304         2.[[2-9]]* )
 305             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 306             ;;
 307         * )
 308             ;;
 309       esac
 310       ;;
 311   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 312       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 313       ;;
 314   *-solaris2*)
 315       dnl This is a hack -- we should be using AC_TRY_RUN instead
 316       ap_platform_runtime_link_flag="-R"
 317       dnl solaris 8 and above don't have a thundering herd
 318       dnl not sure about rev's before this one.
 319       case `uname -r` in
 320         5.[567]*)
 321             ;;
 322         * )
 323             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 324             ;;
 325       esac
 326       ;;
 327   *cygwin*)
 328       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 329       ;;
 330   *mingw32*)
 331       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 332       APR_SETIFNULL(ac_cv_func_times, [no])
 333       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 334       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 335       ;;
 336   *aix*)
 337       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 338       if test $aixver -ge 4320; then
 339         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 340       fi
 341       ;;
 342   *os390*)
 343       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 344       ;;
 345 esac
 346
 347 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 348
 349 dnl
 350 dnl Process command line arguments. This is done early in the process so the
 351 dnl user can get feedback quickly in case of an error.
 352 dnl
 353 dnl ### need to move some of the arguments "up here"
 354
 355 dnl ## Check for programs
 356
 357 AC_PATH_PROG(RM, rm)
 358 AC_PATH_PROG(PKGCONFIG, pkg-config)
 359 AC_PATH_PROG(RSYNC, rsync)
 360 AC_PROG_AWK
 361 AC_PROG_LN_S
 362 AC_CHECK_TOOL(RANLIB, ranlib, true)
 363 dnl AC_PATH_PROG(PERL_PATH, perl)
 364 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 365
 366 # Hard-coded install programs
 367 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 368 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 369 APACHE_SUBST(MKINSTALLDIRS)
 370 APACHE_SUBST(INSTALL)
 371
 372 dnl Various OS checks that apparently set required flags
 373 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 374 AC_USE_SYSTEM_EXTENSIONS
 375 ], [
 376 AC_AIX
 377 AC_MINIX
 378 ])
 379
 380 AC_ISC_POSIX
 381
 382 # Ensure that satisfactory versions of apr and apr-util are
 383 # found if external copies are configured.
 384 if test "${apr_found}" = "yes"; then
 385   # Require at least APR 1.3.x otherwise fail
 386   APACHE_CHECK_APxVER([apr], 1, 3)
 387 fi
 388
 389 if test "${apu_found}" = "yes"; then
 390   # Require at least APR-util 1.3.x otherwise fail
 391   if test "${apr_found}" = "yes"; then
 392     # we need to add the APR includes to CPPFLAGS
 393     apu_ckver_CPPFLAGS="$CPPFLAGS"
 394     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 395     APACHE_CHECK_APxVER([apu], 1, 3)
 396     CPPFLAGS="$apu_ckver_CPPFLAGS"
 397   else
 398     APACHE_CHECK_APxVER([apu], 1, 3)
 399   fi
 400 fi
 401
 402 dnl Check for what we can generate dependency files with
 403 APR_CHECK_DEPEND
 404
 405 dnl ## Check for libraries
 406
 407 dnl ## Check for header files
 408
 409 dnl I think these are just used all over the place, so just check for
 410 dnl them at the base of the tree. If some are specific to a single
 411 dnl directory, they should be moved (Comment #Spoon)
 412
 413 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 414 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 415 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 416
 417 AC_HEADER_STDC
 418 AC_CHECK_HEADERS( \
 419 string.h \
 420 limits.h \
 421 unistd.h \
 422 sys/socket.h \
 423 pwd.h \
 424 grp.h \
 425 strings.h \
 426 sys/prctl.h \
 427 sys/processor.h \
 428 sys/sem.h \
 429 sys/sdt.h
 430 )
 431 AC_HEADER_SYS_WAIT
 432
 433 dnl ## Check for typedefs, structures, and compiler characteristics.
 434
 435 AC_C_CONST
 436
 437 dnl ## Check for library functions
 438 dnl ## sqrt() only needed in support/ab.c
 439 saved_LIBS="$LIBS"
 440 LIBS=""
 441 AC_SEARCH_LIBS(sqrt, m)
 442 MATH_LIBS="$LIBS"
 443 APACHE_SUBST(MATH_LIBS)
 444 LIBS="$saved_LIBS"
 445
 446 saved_LIBS="$LIBS"
 447 LIBS=""
 448 AC_SEARCH_LIBS(crypt, crypt)
 449 CRYPT_LIBS="$LIBS"
 450 APACHE_SUBST(CRYPT_LIBS)
 451 LIBS="$saved_LIBS"
 452
 453 dnl See Comment #Spoon
 454
 455 AC_CHECK_FUNCS( \
 456 getpwnam \
 457 getgrnam \
 458 initgroups \
 459 bindprocessor \
 460 prctl \
 461 timegm \
 462 getpgid \
 463 fopen64
 464 )
 465
 466 dnl confirm that a void pointer is large enough to store a long integer
 467 APACHE_CHECK_VOID_PTR_LEN
 468
 469 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 470 [AC_TRY_RUN(#define _GNU_SOURCE
 471 #include <unistd.h>
 472 #include <sys/syscall.h>
 473 #include <sys/types.h>
 474 int main(int argc, char **argv) {
 475 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 476 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 477 if test "$ac_cv_gettid" = "yes"; then
 478     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 479 fi
 480
 481 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 482 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 483 [AC_TRY_COMPILE([#include <sys/types.h>
 484 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 485   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 486 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 487     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 488 fi
 489
 490 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 491
 492 case $host in
 493     *aix*)
 494         # for 32-bit builds, increase MAXDATA to allow lots of threads
 495         if test x$OBJECT_MODE != x64; then
 496             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 497         fi
 498         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 499         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 500         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 501         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 502         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 503         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 504         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 505         ;;
 506     *os390*)
 507         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 508         ;;
 509     *)
 510         OS_SPECIFIC_VARS=""
 511 esac
 512
 513 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 514         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 515         [PORT=80])
 516
 517 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 518         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 519         [SSLPORT=443])
 520
 521 DTRACE=true
 522 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 523 [
 524   enable_dtrace=$enableval
 525   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 526   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 527 ],
 528 [
 529   enable_dtrace=no
 530 ])
 531
 532 dnl Disabled dtrace build for now.
 533 enable_dtrace=no
 534
 535 case $host in
 536   *-solaris2*)
 537     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 538         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 539                   [Enable DTrace probes])
 540         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 541         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 542     fi
 543     ;;
 544 esac
 545
 546 APACHE_SUBST(DTRACE)
 547
 548 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 549 [
 550     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 551         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 552     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 553 ])dnl
 554
 555 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 556 [
 557     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 558               [Allow modules to run hook after a fatal exception])
 559 ])dnl
 560
 561 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 562 [
 563   LOAD_ALL_MODULES=$enableval
 564   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 565 ],
 566 [
 567   LOAD_ALL_MODULES="no"
 568 ])
 569
 570 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 571 [
 572   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 573   if test "$GCC" = "yes"; then
 574     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 575     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 576     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 577     APACHE_ADD_GCC_CFLAG([-Wformat])
 578     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 579     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 580   elif test "$AIX_XLC" = "yes"; then
 581     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 582   fi
 583   if test "x$enable_load_all_modules" = "x"; then
 584     LOAD_ALL_MODULES=yes
 585     AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 586   fi
 587 ])dnl
 588
 589 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 590 [
 591   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 592   if test "$GCC" = "yes"; then
 593     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 594     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 595     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 596     APACHE_ADD_GCC_CFLAG([-Wformat])
 597     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 598     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 599   elif test "$AIX_XLC" = "yes"; then
 600     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 601   fi
 602 ])dnl
 603
 604 dnl Conditionally enable PIE support for GNU toolchains.
 605 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 606 if test "$enable_pie" = "yes"; then
 607    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 608      save_CFLAGS=$CFLAGS
 609      save_LDFLAGS=$LDFLAGS
 610      CFLAGS="$CFLAGS -fPIE"
 611      LDFLAGS="$LDFLAGS -pie"
 612      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 613       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 614      CFLAGS=$save_CFLAGS
 615      LDFLAGS=$save_LDFLAGS
 616    ])
 617    if test "$ap_cv_cc_pie" = "yes"; then
 618      PICFLAGS="-fPIE"
 619      PILDFLAGS="-pie"
 620    else
 621      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 622    fi
 623 fi
 624 AC_SUBST(PICFLAGS)
 625 AC_SUBST(PILDFLAGS)
 626
 627 prefix="$orig_prefix"
 628 APACHE_ENABLE_MODULES
 629
 630 dnl reading config stubs
 631 esyscmd(./build/config-stubs .)
 632
 633 APACHE_SUBST(progname)
 634 APACHE_SUBST(OS)
 635 APACHE_SUBST(OS_DIR)
 636 APACHE_SUBST(BUILTIN_LIBS)
 637 APACHE_SUBST(SHLIBPATH_VAR)
 638 APACHE_SUBST(OS_SPECIFIC_VARS)
 639
 640 PRE_SHARED_CMDS='echo ""'
 641 POST_SHARED_CMDS='echo ""'
 642
 643 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 644
 645 if test "$apache_need_shared" = "yes"; then
 646   if test -f $ac_aux_dir/ltconfig; then
 647     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 648   fi
 649   shared_build="shared-build"
 650 fi
 651
 652 dnl enable_so tells us if *any* modules can be built as DSOs
 653
 654 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 655   case $host in
 656     *-ibm-aix*)
 657       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 658       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 659       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 660       ;;
 661     *os390)
 662       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 663       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 664   esac
 665   MOD_SO_ENABLED=yes
 666 fi
 667 AC_SUBST(MOD_SO_ENABLED)
 668
 669 APACHE_SUBST(PRE_SHARED_CMDS)
 670 APACHE_SUBST(POST_SHARED_CMDS)
 671 APACHE_SUBST(shared_build)
 672
 673 AC_ARG_WITH(program-name,
 674 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 675   progname="$withval" ], [
 676   progname="httpd"] )
 677
 678 # SuExec parameters
 679 AC_ARG_WITH(suexec-bin,
 680 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 681   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 682 ] )
 683
 684 AC_ARG_WITH(suexec-caller,
 685 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 686   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 687
 688 AC_ARG_WITH(suexec-userdir,
 689 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 690   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 691
 692 AC_ARG_WITH(suexec-docroot,
 693 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 694   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 695
 696 AC_ARG_WITH(suexec-uidmin,
 697 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 698   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 699
 700 AC_ARG_WITH(suexec-gidmin,
 701 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 702   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 703
 704 AC_ARG_WITH(suexec-logfile,
 705 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 706   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 707
 708 AC_ARG_WITH(suexec-safepath,
 709 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 710   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 711
 712 AC_ARG_WITH(suexec-umask,
 713 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 714   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 715
 716 dnl APR should go after the other libs, so the right symbols can be picked up
 717 if test x${apu_found} != xobsolete; then
 718   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 719 fi
 720 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 721 APACHE_SUBST(AP_LIBS)
 722 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 723 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 724
 725 AC_DEFINE(AP_USING_AUTOCONF, 1,
 726                 [Using autoconf to configure Apache])
 727
 728 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 729     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 730               [This platform doesn't suffer from the thundering herd problem])
 731 fi
 732
 733 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 734     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 735               [Listening sockets are non-blocking when there are more than 1])
 736 fi
 737
 738 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 739
 740 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 741 [
 742   v4mapped=$enableval
 743 ],
 744 [
 745     case $host in
 746     *freebsd5*|*netbsd*|*openbsd*)
 747         v4mapped=no
 748         ;;
 749     *)
 750         v4mapped=yes
 751         ;;
 752     esac
 753     if ap_mpm_is_enabled winnt; then
 754         dnl WinNT MPM doesn't support this.
 755         v4mapped=no
 756     fi
 757 ])
 758
 759 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 760     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 761               [Allow IPv4 connections on IPv6 listening sockets])
 762 fi
 763
 764 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 765 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 766 APACHE_FAST_OUTPUT(support/Makefile)
 767
 768 if test -d ./test; then
 769     APACHE_FAST_OUTPUT(test/Makefile)
 770 fi
 771
 772 dnl ## Finalize the variables
 773 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 774
 775 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 776 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 777 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 778 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 779 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 780 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 781
 782 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 783
 784 APACHE_GEN_CONFIG_VARS
 785
 786 dnl ## Build modules.c
 787 rm -f modules.c
 788 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 789
 790 APR_EXPAND_VAR(ap_prefix, $prefix)
 791 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 792         [Root directory of the Apache install area])
 793 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 794         [Location of the config file, relative to the Apache root directory])
 795 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 796         [Location of the MIME types config file, relative to the Apache root directory])
 797
 798 perlbin=`$ac_aux_dir/PrintPath perl`
 799 if test "x$perlbin" = "x"; then
 800     perlbin="/replace/with/path/to/perl/interpreter"
 801 fi
 802 AC_SUBST(perlbin)
 803
 804 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 805
 806 BSD_MAKEFILE=no
 807 ap_make_include=include
 808 ap_make_delimiter=' '
 809 case $host in
 810 *bsdi*)
 811     # Check whether they've installed GNU make
 812     if make --version > /dev/null 2>&1; then
 813         true
 814     else
 815         BSD_MAKEFILE=yes
 816         ap_make_include=.include
 817         ap_make_delimiter='"'
 818     fi
 819     ;;
 820 esac
 821 AC_SUBST(ap_make_include)
 822 AC_SUBST(ap_make_delimiter)
 823
 824 dnl Ensure that docs/conf is created.
 825 test -d docs/conf||$mkdir_p docs/conf
 826
 827 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 828   APACHE_GEN_MAKEFILES
 829 ])