granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="./srclib/apr/apr-${majorver}-config"
  97     if test -f "$test_apr_config"; then
  98       apr_config="$test_apr_config"
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x${apr_major_version}" = "x2"; then
 119    apu_found=obsolete
 120 elif test "x$with_included_apr" = "xyes"; then
 121    apu_found=reconfig
 122 else
 123    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 124    dnl isn't supported.
 125    ifdef([APR_FIND_APU], [
 126      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 127                   1, ${apr_major_version})
 128    ], [apu_found=no])
 129 fi
 130
 131 if test "$apu_found" = "no"; then
 132   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 133 fi
 134
 135 # Catch some misconfigurations:
 136 case ${apr_found}.${apu_found} in
 137 reconfig.yes)
 138   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 139   ;;
 140 yes.reconfig)
 141   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 142   ;;
 143 esac
 144
 145 if test "$apu_found" = "reconfig"; then
 146   APR_SUBDIR_CONFIG(srclib/apr-util,
 147                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 148                     [--enable-layout=*|\'--enable-layout=*])
 149   dnl We must be the last to build and the first to be cleaned
 150   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 151   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 152   dnl APR and APR-Util major versions must match
 153   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 154 fi
 155
 156 if test "$apu_found" = "obsolete"; then
 157   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 158 else
 159   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 160   APU_BINDIR=`$apu_config --bindir`
 161   APU_INCLUDEDIR=`$apu_config --includedir`
 162   APU_INCLUDES=`$apu_config --includes`
 163   APU_VERSION=`$apu_config --version`
 164   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 165 fi
 166
 167 dnl In case we picked up CC and CPP from APR, get that info into the
 168 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 169 dnl PCRE and for our config tests will be whatever PCRE determines.
 170 AC_PROG_CC
 171 AC_PROG_CPP
 172
 173 dnl Try to get c99 support for variadic macros
 174 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 175
 176 if test "x${cache_file}" = "x/dev/null"; then
 177   # Likewise, ensure that CC and CPP are passed through to the pcre
 178   # configure script iff caching is disabled (the autoconf 2.5x default).
 179   export CC; export CPP
 180 fi
 181
 182 dnl Absolute source/build directory
 183 abs_srcdir=`(cd $srcdir && pwd)`
 184 abs_builddir=`pwd`
 185
 186 AC_ARG_WITH(pcre,
 187 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 188
 189 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 190 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 191    PCRE_CONFIG=$with_pcre/bin/pcre-config
 192 elif test -x "$with_pcre"; then
 193    PCRE_CONFIG=$with_pcre
 194 fi
 195
 196 if test "$PCRE_CONFIG" != "false"; then
 197   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 198     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 199   fi
 200   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 201   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 202   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 203 else
 204   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 205 fi
 206 APACHE_SUBST(PCRE_LIBS)
 207
 208 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 209 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 210
 211 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 212
 213 dnl If the source dir is not equal to the build dir,
 214 dnl then we are running in VPATH mode.
 215
 216 APR_ADDTO(INCLUDES, [-I.])
 217
 218 if test "$abs_builddir" != "$abs_srcdir"; then
 219   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 220 fi
 221
 222 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 223
 224 # apr/apr-util --includes may pick up system paths for dependent
 225 # libraries, so ensure these are later in INCLUDES than local source
 226 # directories.
 227 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 228 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 229
 230 dnl Add in path to PCRE includes
 231 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 232
 233 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 234
 235 case $host in
 236   *os2*)
 237       # Use a custom made libtool replacement
 238       echo "using aplibtool"
 239       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 240       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 241       SH_LIBS="\$(ALL_LIBS)"
 242       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 243       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 244       MK_IMPLIB="emximp"
 245       other_targets="$other_targets os2core"
 246       INSTALL_PROG_FLAGS="-e .exe"
 247       SHLTCFLAGS=""
 248       LTCFLAGS=""
 249       ;;
 250   *)
 251       if test "x$LTFLAGS" = "x"; then
 252           LTFLAGS='--silent'
 253       fi
 254       my_libtool=`$apr_config --apr-libtool`
 255       LIBTOOL="$my_libtool \$(LTFLAGS)"
 256       libtoolversion=`$my_libtool --version`
 257       case $libtoolversion in
 258           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 259               SH_LIBTOOL='$(LIBTOOL)'
 260               SHLTCFLAGS="-prefer-pic"
 261               LTCFLAGS="-prefer-non-pic -static"
 262               ;;
 263           *)
 264               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 265               SHLTCFLAGS=""
 266               LTCFLAGS=""
 267               ;;
 268       esac
 269       ;;
 270 esac
 271 APACHE_SUBST(SHLTCFLAGS)
 272 APACHE_SUBST(LTCFLAGS)
 273
 274 case $host in
 275   *-apple-aux3*)
 276       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 277       ;;
 278   *os2-emx*)
 279       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 280       ;;
 281   *-linux-*)
 282       case `uname -r` in
 283         2.[[2-9]]* )
 284             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 285             ;;
 286         * )
 287             ;;
 288       esac
 289       ;;
 290   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 291       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 292       ;;
 293   *-solaris2*)
 294       dnl This is a hack -- we should be using AC_TRY_RUN instead
 295       ap_platform_runtime_link_flag="-R"
 296       dnl solaris 8 and above don't have a thundering herd
 297       dnl not sure about rev's before this one.
 298       case `uname -r` in
 299         5.[567]*)
 300             ;;
 301         * )
 302             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 303             ;;
 304       esac
 305       ;;
 306   *cygwin*)
 307       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 308       ;;
 309   *mingw32*)
 310       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 311       APR_SETIFNULL(ac_cv_func_times, [no])
 312       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 313       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 314       ;;
 315   *aix*)
 316       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 317       if test $aixver -ge 4320; then
 318         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 319       fi
 320       ;;
 321   *os390*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324 esac
 325
 326 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 327
 328 dnl
 329 dnl Process command line arguments. This is done early in the process so the
 330 dnl user can get feedback quickly in case of an error.
 331 dnl
 332 dnl ### need to move some of the arguments "up here"
 333
 334 dnl ## Check for programs
 335
 336 AC_PATH_PROG(RM, rm)
 337 AC_PATH_PROG(PKGCONFIG, pkg-config)
 338 AC_PATH_PROG(RSYNC, rsync)
 339 AC_PROG_AWK
 340 AC_PROG_LN_S
 341 AC_CHECK_TOOL(RANLIB, ranlib, true)
 342 dnl AC_PATH_PROG(PERL_PATH, perl)
 343 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 344
 345 # Hard-coded install programs
 346 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 347 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 348 APACHE_SUBST(MKINSTALLDIRS)
 349 APACHE_SUBST(INSTALL)
 350
 351 dnl Various OS checks that apparently set required flags
 352 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 353 AC_USE_SYSTEM_EXTENSIONS
 354 ], [
 355 AC_AIX
 356 AC_MINIX
 357 ])
 358
 359 AC_ISC_POSIX
 360
 361 # Ensure that satisfactory versions of apr and apr-util are
 362 # found if external copies are configured.
 363 if test "${apr_found}" = "yes"; then
 364   # Require at least APR 1.3.x otherwise fail
 365   APACHE_CHECK_APxVER([apr], 1, 3)
 366 fi
 367
 368 if test "${apu_found}" = "yes"; then
 369   # Require at least APR-util 1.3.x otherwise fail
 370   if test "${apr_found}" = "yes"; then
 371     # we need to add the APR includes to CPPFLAGS
 372     apu_ckver_CPPFLAGS="$CPPFLAGS"
 373     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 374     APACHE_CHECK_APxVER([apu], 1, 3)
 375     CPPFLAGS="$apu_ckver_CPPFLAGS"
 376   else
 377     APACHE_CHECK_APxVER([apu], 1, 3)
 378   fi
 379 fi
 380
 381 dnl Check for what we can generate dependency files with
 382 APR_CHECK_DEPEND
 383
 384 dnl ## Check for libraries
 385
 386 dnl ## Check for header files
 387
 388 dnl I think these are just used all over the place, so just check for
 389 dnl them at the base of the tree. If some are specific to a single
 390 dnl directory, they should be moved (Comment #Spoon)
 391
 392 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 393 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 394 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 395
 396 AC_HEADER_STDC
 397 AC_CHECK_HEADERS( \
 398 string.h \
 399 limits.h \
 400 unistd.h \
 401 sys/socket.h \
 402 pwd.h \
 403 grp.h \
 404 strings.h \
 405 sys/prctl.h \
 406 sys/processor.h \
 407 sys/sem.h \
 408 sys/sdt.h
 409 )
 410 AC_HEADER_SYS_WAIT
 411
 412 dnl ## Check for typedefs, structures, and compiler characteristics.
 413
 414 AC_C_CONST
 415
 416 dnl ## Check for library functions
 417 dnl ## sqrt() only needed in support/ab.c
 418 saved_LIBS="$LIBS"
 419 LIBS=""
 420 AC_SEARCH_LIBS(sqrt, m)
 421 MATH_LIBS="$LIBS"
 422 APACHE_SUBST(MATH_LIBS)
 423 LIBS="$saved_LIBS"
 424
 425 saved_LIBS="$LIBS"
 426 LIBS=""
 427 AC_SEARCH_LIBS(crypt, crypt)
 428 CRYPT_LIBS="$LIBS"
 429 APACHE_SUBST(CRYPT_LIBS)
 430 LIBS="$saved_LIBS"
 431
 432 dnl See Comment #Spoon
 433
 434 AC_CHECK_FUNCS( \
 435 getpwnam \
 436 getgrnam \
 437 initgroups \
 438 bindprocessor \
 439 prctl \
 440 timegm \
 441 getpgid \
 442 fopen64
 443 )
 444
 445 dnl confirm that a void pointer is large enough to store a long integer
 446 APACHE_CHECK_VOID_PTR_LEN
 447
 448 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 449 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 450 [AC_TRY_COMPILE([#include <sys/types.h>
 451 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 452   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 453 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 454     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 455 fi
 456
 457 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 458
 459 case $host in
 460     *aix*)
 461         # for 32-bit builds, increase MAXDATA to allow lots of threads
 462         if test x$OBJECT_MODE != x64; then
 463             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 464         fi
 465         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 466         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 467         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 468         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 469         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 470         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 471         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 472         ;;
 473     *os390*)
 474         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 475         ;;
 476     *)
 477         OS_SPECIFIC_VARS=""
 478 esac
 479
 480 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 481         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 482         [PORT=80])
 483
 484 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 485         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 486         [SSLPORT=443])
 487
 488 DTRACE=true
 489 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 490 [
 491   enable_dtrace=$enableval
 492   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 493   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 494 ],
 495 [
 496   enable_dtrace=no
 497 ])
 498
 499 dnl Disabled dtrace build for now.
 500 enable_dtrace=no
 501
 502 case $host in
 503   *-solaris2*)
 504     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 505         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 506                   [Enable DTrace probes])
 507         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 508         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 509     fi
 510     ;;
 511 esac
 512
 513 APACHE_SUBST(DTRACE)
 514
 515 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 516 [
 517     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 518               [Allow modules to run hook after a fatal exception])
 519 ])dnl
 520
 521 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 522 [
 523   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 524   if test "$GCC" = "yes"; then
 525     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 526     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 527       save_CFLAGS=$CFLAGS
 528       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 529       AC_COMPILE_IFELSE([int foo() { return 0; }],
 530         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 531       CFLAGS=$save_CFLAGS
 532     ])
 533     if test "$ap_cv_cc_Wdas" = "yes"; then
 534       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 535     fi
 536   elif test "$AIX_XLC" = "yes"; then
 537     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 538   fi
 539 ])dnl
 540
 541 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 542 [
 543   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 544   if test "$GCC" = "yes"; then
 545     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 546     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 547       save_CFLAGS=$CFLAGS
 548       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 549       AC_COMPILE_IFELSE([int foo() { return 0; }],
 550         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 551       CFLAGS=$save_CFLAGS
 552     ])
 553     if test "$ap_cv_cc_Wdas" = "yes"; then
 554       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 555     fi
 556   elif test "$AIX_XLC" = "yes"; then
 557     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 558   fi
 559 ])dnl
 560
 561 dnl Conditionally enable PIE support for GNU toolchains.
 562 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 563 if test "$enable_pie" = "yes"; then
 564    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 565      save_CFLAGS=$CFLAGS
 566      save_LDFLAGS=$LDFLAGS
 567      CFLAGS="$CFLAGS -fPIE"
 568      LDFLAGS="$LDFLAGS -pie"
 569      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 570       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 571      CFLAGS=$save_CFLAGS
 572      LDFLAGS=$save_LDFLAGS
 573    ])
 574    if test "$ap_cv_cc_pie" = "yes"; then
 575      PICFLAGS="-fPIE"
 576      PILDFLAGS="-pie"
 577    else
 578      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 579    fi
 580 fi
 581 AC_SUBST(PICFLAGS)
 582 AC_SUBST(PILDFLAGS)
 583
 584 prefix="$orig_prefix"
 585 APACHE_ENABLE_MODULES
 586
 587 dnl reading config stubs
 588 esyscmd(./build/config-stubs .)
 589
 590 APACHE_SUBST(progname)
 591 APACHE_SUBST(OS)
 592 APACHE_SUBST(OS_DIR)
 593 APACHE_SUBST(BUILTIN_LIBS)
 594 APACHE_SUBST(SHLIBPATH_VAR)
 595 APACHE_SUBST(OS_SPECIFIC_VARS)
 596
 597 PRE_SHARED_CMDS='echo ""'
 598 POST_SHARED_CMDS='echo ""'
 599
 600 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 601
 602 if test "$apache_need_shared" = "yes"; then
 603   if test -f $ac_aux_dir/ltconfig; then
 604     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 605   fi
 606   shared_build="shared-build"
 607 fi
 608
 609 dnl enable_so tells us if *any* modules can be built as DSOs
 610
 611 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 612   case $host in
 613     *-ibm-aix*)
 614       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 615       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 616       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 617       ;;
 618     *os390)
 619       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 620       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 621   esac
 622   MOD_SO_ENABLED=yes
 623 fi
 624 AC_SUBST(MOD_SO_ENABLED)
 625
 626 APACHE_SUBST(PRE_SHARED_CMDS)
 627 APACHE_SUBST(POST_SHARED_CMDS)
 628 APACHE_SUBST(shared_build)
 629
 630 AC_ARG_WITH(program-name,
 631 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 632   progname="$withval" ], [
 633   progname="httpd"] )
 634
 635 # SuExec parameters
 636 AC_ARG_WITH(suexec-bin,
 637 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 638   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 639 ] )
 640
 641 AC_ARG_WITH(suexec-caller,
 642 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 643   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 644
 645 AC_ARG_WITH(suexec-userdir,
 646 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 647   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 648
 649 AC_ARG_WITH(suexec-docroot,
 650 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 651   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 652
 653 AC_ARG_WITH(suexec-uidmin,
 654 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 655   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 656
 657 AC_ARG_WITH(suexec-gidmin,
 658 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 659   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 660
 661 AC_ARG_WITH(suexec-logfile,
 662 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 663   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 664
 665 AC_ARG_WITH(suexec-safepath,
 666 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 667   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 668
 669 AC_ARG_WITH(suexec-umask,
 670 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 671   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 672
 673 dnl APR should go after the other libs, so the right symbols can be picked up
 674 if test x${apu_found} != xobsolete; then
 675   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 676 fi
 677 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 678 APACHE_SUBST(AP_LIBS)
 679 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 680 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 681
 682 AC_DEFINE(AP_USING_AUTOCONF, 1,
 683                 [Using autoconf to configure Apache])
 684
 685 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 686     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 687               [This platform doesn't suffer from the thundering herd problem])
 688 fi
 689
 690 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 691     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 692               [Listening sockets are non-blocking when there are more than 1])
 693 fi
 694
 695 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 696
 697 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 698 [
 699   v4mapped=$enableval
 700 ],
 701 [
 702     case $host in
 703     *freebsd5*|*netbsd*|*openbsd*)
 704         v4mapped=no
 705         ;;
 706     *)
 707         v4mapped=yes
 708         ;;
 709     esac
 710     if ap_mpm_is_enabled winnt; then
 711         dnl WinNT MPM doesn't support this.
 712         v4mapped=no
 713     fi
 714 ])
 715
 716 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 717     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 718               [Allow IPv4 connections on IPv6 listening sockets])
 719 fi
 720
 721 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 722 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 723 APACHE_FAST_OUTPUT(support/Makefile)
 724
 725 if test -d ./test; then
 726     APACHE_FAST_OUTPUT(test/Makefile)
 727 fi
 728
 729 dnl ## Finalize the variables
 730 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 731
 732 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 733 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 734 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 735 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 736 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 737 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 738
 739 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 740
 741 APACHE_GEN_CONFIG_VARS
 742
 743 dnl ## Build modules.c
 744 rm -f modules.c
 745 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 746
 747 APR_EXPAND_VAR(ap_prefix, $prefix)
 748 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 749         [Root directory of the Apache install area])
 750 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 751         [Location of the config file, relative to the Apache root directory])
 752 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 753         [Location of the MIME types config file, relative to the Apache root directory])
 754
 755 perlbin=`$ac_aux_dir/PrintPath perl`
 756 if test "x$perlbin" = "x"; then
 757     perlbin="/replace/with/path/to/perl/interpreter"
 758 fi
 759 AC_SUBST(perlbin)
 760
 761 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 762
 763 BSD_MAKEFILE=no
 764 ap_make_include=include
 765 ap_make_delimiter=' '
 766 case $host in
 767 *bsdi*)
 768     # Check whether they've installed GNU make
 769     if make --version > /dev/null 2>&1; then
 770         true
 771     else
 772         BSD_MAKEFILE=yes
 773         ap_make_include=.include
 774         ap_make_delimiter='"'
 775     fi
 776     ;;
 777 esac
 778 AC_SUBST(ap_make_include)
 779 AC_SUBST(ap_make_delimiter)
 780
 781 dnl Ensure that docs/conf is created.
 782 test -d docs/conf||$mkdir_p docs/conf
 783
 784 dnl Ensure that the httpd version is included
 785 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 786 AC_SUBST(HTTPD_VERSION)
 787
 788 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 789   APACHE_GEN_MAKEFILES
 790 ])