granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.193 2002/07/19 17:35:09 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.3devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=win ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      qnx*) template=qnx4 ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sunos*) template=sunos4 ;;
  76  sysv4.2*)
  77         case $host_vendor in
  78           univel) template=univel ;;
  79         esac ;;
  80    sysv4*) template=svr4 ;;
  81    sysv5*) template=unixware ;;
  82   ultrix*) template=ultrix4 ;;
  83 esac
  84
  85   if test x"$template" = x"" ; then
  86     AC_MSG_ERROR([[
  87 *******************************************************************
  88 PostgreSQL has apparently not been ported to your platform yet.
  89 To try a manual configuration, look into the src/template directory
  90 for a similar platform and use the '--with-template=' option.
  91
  92 Please also contact <pgsql-ports@postgresql.org> to see about
  93 rectifying this.  Include the above 'checking host system type...'
  94 line.
  95 *******************************************************************
  96 ]])
  97   fi
  98
  99 ])
 100
 101 AC_MSG_RESULT([$template])
 102
 103 PORTNAME=$template
 104 AC_SUBST(PORTNAME)
 105
 106 # Pick right test-and-set (TAS) code.  Most platforms have inline
 107 # assembler code in src/include/storage/s_lock.h, so we just use
 108 # a dummy file here.
 109 case $host in
 110   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 111   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 112   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 113   *)                need_tas=no;  tas_file=dummy.s ;;
 114 esac
 115 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 116
 117 if test "$need_tas" = yes ; then
 118   TAS=tas.o
 119 fi
 120 AC_SUBST(TAS)
 121
 122
 123
 124 ##
 125 ## Command line options
 126 ##
 127
 128
 129 #
 130 # Add non-standard directories to the include path
 131 #
 132 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 133
 134
 135 #
 136 # Add non-standard directories to the library search path
 137 #
 138 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 139              [LIBRARY_DIRS=$withval])
 140
 141 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 142              [LIBRARY_DIRS=$withval])
 143
 144
 145 #
 146 # 64-bit integer date/time storage (--enable-integer-datetimes)
 147 #
 148 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 149 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 150               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 151                          [Set to 1 if you want integer date/time support (--enable-integer-datetimes)])])
 152 AC_MSG_RESULT([$enable_integer_datetimes])
 153
 154
 155 # Character set recode (--enable-recode)
 156 #
 157 AC_MSG_CHECKING([whether to build with recode support])
 158 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable character set recode support],
 159               [AC_DEFINE([CYR_RECODE], 1,
 160                          [Set to 1 if you want cyrillic recode support (--enable-recode)])])
 161 AC_MSG_RESULT([$enable_recode])
 162
 163
 164 #
 165 # Multibyte support
 166 #
 167 MULTIBYTE=SQL_ASCII
 168 AC_DEFINE(MULTIBYTE, 1, [Set to 1 if you want to use multibyte characters (--enable-multibyte)])
 169 AC_SUBST(MULTIBYTE)
 170
 171 #
 172 # NLS
 173 #
 174 AC_MSG_CHECKING([whether NLS is wanted])
 175 PGAC_ARG_OPTARG(enable, nls,
 176                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 177                 [],
 178                 [WANTED_LANGUAGES=$enableval],
 179                 [AC_DEFINE(ENABLE_NLS, 1,
 180                            [Define to 1 if you want National Language Support (--enable-nls)])])
 181 AC_MSG_RESULT([$enable_nls])
 182 AC_SUBST(enable_nls)
 183 AC_SUBST(WANTED_LANGUAGES)
 184
 185 #
 186 # Default port number (--with-pgport), default 5432
 187 #
 188 AC_MSG_CHECKING([for default port number])
 189 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 190              [default_port=$withval],
 191              [default_port=5432])
 192 AC_MSG_RESULT([$default_port])
 193 # Need both of these because some places want an integer and some a string
 194 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 195 [The default TCP port number on which the server listens and to which
 196 clients will try to connect to.  This can be overridden at run-time,
 197 but it's convenient if your clients have the right default compiled in.
 198 (--with-pgport=PORTNUM)])
 199 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 200                    [Default TCP port number as string constant])
 201 AC_SUBST(default_port)
 202
 203 #
 204 # Maximum number of allowed connections (--with-maxbackends), default 32
 205 #
 206 AC_MSG_CHECKING([for default soft limit on number of connections])
 207 PGAC_ARG_REQ(with, maxbackends, [  --with-maxbackends=N    set default maximum number of connections [32]],
 208              [],
 209              [with_maxbackends=32])
 210 AC_MSG_RESULT([$with_maxbackends])
 211 AC_DEFINE_UNQUOTED([DEF_MAXBACKENDS], [$with_maxbackends],
 212                    [The default soft limit on the number of concurrent connections, i.e., the default for the postmaster -N switch (--with-maxbackends)])
 213
 214
 215 #
 216 # Option to disable shared libraries
 217 #
 218 PGAC_ARG_BOOL(enable, shared, yes,
 219               [  --disable-shared        do not build shared libraries])
 220 AC_SUBST(enable_shared)
 221
 222 #
 223 # '-rpath'-like feature can be disabled
 224 #
 225 PGAC_ARG_BOOL(enable, rpath, yes,
 226               [  --disable-rpath         do not embed shared library search path in executables])
 227 AC_SUBST(enable_rpath)
 228
 229
 230 #
 231 # --enable-debug adds -g to compiler flags
 232 #
 233 PGAC_ARG_BOOL(enable, debug, no,
 234               [  --enable-debug          build with debugging symbols (-g)])
 235 AC_SUBST(enable_debug)
 236
 237 #
 238 # C compiler
 239 #
 240
 241 # For historical reasons you can also use --with-CC to specify the C compiler
 242 # to use, although the standard way to do this is to set the CC environment
 243 # variable.
 244 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 245
 246 # Set here so it can be over-ridden in the template file
 247 GCC_CXXFLAGS="-O2"
 248 VENDOR_CXXFLAGS=""
 249
 250 case $template in
 251   aix) pgac_cc_list="gcc xlc";;
 252  irix) pgac_cc_list="cc";; # no gcc
 253     *) pgac_cc_list="gcc cc";;
 254 esac
 255
 256 AC_PROG_CC([$pgac_cc_list])
 257 # Read the template
 258 . "$srcdir/src/template/$template" || exit
 259
 260 if test "$ac_env_CFLAGS_set" = set; then
 261   CFLAGS=$ac_env_CFLAGS_value
 262 fi
 263 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 264   CFLAGS="$CFLAGS -g"
 265 fi
 266 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 267 # Check if the compiler still works with the template settings
 268 AC_MSG_CHECKING([whether the C compiler still works])
 269 AC_TRY_LINK([], [return 0;],
 270   [AC_MSG_RESULT(yes)],
 271   [AC_MSG_RESULT(no)
 272    AC_MSG_ERROR([cannot proceed])])
 273 AC_PROG_CPP
 274 AC_SUBST(GCC)
 275
 276 # Create compiler version string
 277 if test x"$GCC" = x"yes" ; then
 278   cc_string="GCC `${CC} --version | sed q`"
 279 else
 280   cc_string=$CC
 281 fi
 282 AC_DEFINE_UNQUOTED(PG_VERSION_STR, ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"], [A canonical string containing the version number, platform, and C compiler])
 283
 284
 285 #
 286 # Automatic dependency tracking
 287 #
 288 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 289               [autodepend=yes])
 290 AC_SUBST(autodepend)
 291
 292
 293 #
 294 # Enable assert checks
 295 #
 296 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 297               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 298                          [Define to 1 to build with assertion checks])])
 299
 300
 301 #
 302 # Include directories
 303 #
 304 ac_save_IFS=$IFS
 305 IFS="${IFS}:"
 306 # SRCH_INC comes from the template file
 307 for dir in $with_includes $SRCH_INC; do
 308   if test -d "$dir"; then
 309     INCLUDES="$INCLUDES -I$dir"
 310   else
 311     AC_MSG_WARN([*** Include directory $dir does not exist.])
 312   fi
 313 done
 314 IFS=$ac_save_IFS
 315 AC_SUBST(INCLUDES)
 316
 317
 318 #
 319 # Library directories
 320 #
 321 ac_save_IFS=$IFS
 322 IFS="${IFS}:"
 323 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 324 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 325   if test -d "$dir"; then
 326     LIBDIRS="$LIBDIRS -L$dir"
 327   else
 328     AC_MSG_WARN([*** Library directory $dir does not exist.])
 329   fi
 330 done
 331 IFS=$ac_save_IFS
 332
 333
 334 #
 335 # Tcl/Tk
 336 #
 337 AC_MSG_CHECKING([whether to build with Tcl])
 338 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 339 AC_MSG_RESULT([$with_tcl])
 340 AC_SUBST([with_tcl])
 341
 342 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 343 AC_MSG_CHECKING([whether to build with Tk])
 344 if test "$with_tcl" = yes; then
 345   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 346 else
 347   with_tk=no
 348 fi
 349 AC_MSG_RESULT([$with_tk])
 350 AC_SUBST([with_tk])
 351
 352
 353 # We see if the path to the Tcl/Tk configuration scripts is specified.
 354 # This will override the use of tclsh to find the paths to search.
 355
 356 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 357
 358 # We see if the path to the Tk configuration scripts is specified.
 359 # This will override the use of tclsh to find the paths to search.
 360
 361 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 362
 363 #
 364 # Optionally build Perl modules (Pg.pm and PL/Perl)
 365 #
 366 AC_MSG_CHECKING([whether to build Perl modules])
 367 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl interface and PL/Perl])
 368 AC_MSG_RESULT([$with_perl])
 369 AC_SUBST(with_perl)
 370
 371 #
 372 # Optionally build Python interface module
 373 #
 374 AC_MSG_CHECKING([whether to build Python modules])
 375 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 376 AC_MSG_RESULT([$with_python])
 377 AC_SUBST(with_python)
 378
 379 #
 380 # Optionally build the Java/JDBC tools
 381 #
 382 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 383 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 384 [AC_MSG_RESULT(yes)
 385 PGAC_PATH_ANT
 386 if test -z "$ANT"; then
 387   AC_MSG_ERROR([Ant is required to build Java components])
 388 fi],
 389 [AC_MSG_RESULT(no)])
 390 AC_SUBST(with_java)
 391
 392 dnl A note on the Kerberos and OpenSSL options:
 393 dnl
 394 dnl The user can give an argument to the option in order the specify
 395 dnl the base path of the respective installation (what he specified
 396 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 397 dnl then we take the path where the package installs by default. This
 398 dnl way the user doesn't have to use redundant --with-includes and
 399 dnl --with-libraries options, but he can still use them if the layout
 400 dnl is non-standard.
 401
 402 #
 403 # Kerberos 4
 404 #
 405 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 406 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 407                 [krb4_prefix=/usr/athena],
 408                 [krb4_prefix=$withval],
 409 [
 410   AC_MSG_RESULT(yes)
 411   AC_DEFINE(KRB4, 1, [Define if you are building with Kerberos 4 support.])
 412
 413   if test -d "$krb4_prefix/include"; then
 414     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 415   fi
 416   if test -d "$krb4_prefix/lib"; then
 417     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 418   fi
 419
 420   krb_srvtab="/etc/srvtab"
 421 ],
 422 [AC_MSG_RESULT(no)])
 423
 424 AC_SUBST(with_krb4)
 425
 426
 427 #
 428 # Kerberos 5
 429 #
 430 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 431 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 432               [krb5_prefix=/usr/athena],
 433               [krb5_prefix=$withval],
 434 [
 435   AC_MSG_RESULT([yes])
 436   AC_DEFINE(KRB5, 1, [Define if you are building with Kerberos 5 support.])
 437
 438   if test -d "$krb5_prefix/include"; then
 439     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 440   fi
 441   if test -d "$krb5_prefix/lib"; then
 442     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 443   fi
 444
 445   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 446 ],
 447 [AC_MSG_RESULT(no)])
 448
 449 AC_SUBST(with_krb5)
 450
 451
 452 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 453 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 454   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 455 fi
 456
 457 AC_SUBST(krb_srvtab)
 458
 459
 460 #
 461 # Kerberos configuration parameters
 462 #
 463 PGAC_ARG_REQ(with, krb-srvnam,
 464              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 465              [],
 466              [with_krb_srvnam="postgres"])
 467 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 468                    [The name of the PostgreSQL service principal in Kerberos])
 469
 470
 471 #
 472 # PAM
 473 #
 474 AC_MSG_CHECKING([whether to build with PAM support])
 475 PGAC_ARG_BOOL(with, pam, no,
 476               [  --with-pam              build with PAM support],
 477               [AC_DEFINE([USE_PAM], 1, [Define to build with PAM support])])
 478 AC_MSG_RESULT([$with_pam])
 479 AC_SUBST(with_pam)
 480
 481
 482 #
 483 # OpenSSL
 484 #
 485 PGAC_ARG_OPTARG(with, openssl,
 486                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 487                 [openssl_prefix=/usr/local/ssl],
 488                 [openssl_prefix=$withval],
 489 [
 490   AC_MSG_RESULT([building with OpenSSL support])
 491   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support])
 492
 493   if test -d "${openssl_prefix}/include" ; then
 494     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 495   fi
 496   if test -d "${openssl_prefix}/lib" ; then
 497     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 498   fi
 499 ])
 500
 501 AC_SUBST(with_openssl)
 502
 503
 504 #
 505 # Readline
 506 #
 507 PGAC_ARG_BOOL(with, readline, yes,
 508               [  --without-readline      do not use Readline])
 509
 510 #
 511 # Zlib
 512 #
 513 PGAC_ARG_BOOL(with, zlib, yes,
 514               [  --without-zlib          do not use Zlib])
 515
 516
 517
 518 #
 519 # Optionally enable the building of the ODBC driver
 520 #
 521
 522 # Old option name
 523 if test "${with_odbc+set}" = set && test "${enable_odbc+set}" != set; then
 524   enable_odbc=$with_odbc
 525 fi
 526
 527 AC_MSG_CHECKING([whether to build the ODBC driver])
 528 PGAC_ARG_BOOL(enable, odbc, no, [  --enable-odbc           build the ODBC driver package])
 529 PGAC_ARG_BOOL(with, unixodbc, no, [  --with-unixodbc         build ODBC driver for unixODBC])
 530 PGAC_ARG_BOOL(with, iodbc, no, [  --with-iodbc            build ODBC driver for iODBC])
 531 if test "$with_unixodbc" = yes && test "$with_iodbc" = yes; then
 532   AC_MSG_ERROR([ODBC driver cannot be built for both unixODBC and iODBC])
 533 fi
 534 if test "$with_unixodbc" = yes || test "$with_iodbc" = yes; then
 535   enable_odbc=yes
 536 fi
 537 case $enable_odbc:$with_unixodbc:$with_iodbc in
 538   yes:no:no)    AC_MSG_RESULT([yes (stand-alone)]);;
 539   yes:yes:no)   AC_MSG_RESULT([yes (unixODBC)])
 540                 AC_DEFINE(WITH_UNIXODBC, 1, [Define to 1 to build with unixODBC support (--with-unixodbc)])
 541                 ;;
 542   yes:no:yes)   AC_MSG_RESULT([yes (iODBC)])
 543                 AC_DEFINE(WITH_IODBC, 1, [Define to 1 to build with iODBC support (--with-iodbc)])
 544                 ;;
 545   no:*)         AC_MSG_RESULT(no);;
 546 esac
 547 AC_SUBST([enable_odbc])
 548 AC_SUBST([with_unixodbc])
 549 AC_SUBST([with_iodbc])
 550
 551
 552 # Allow for overriding the default location of the odbcinst.ini
 553 # file which is normally ${sysconfdir} (i.e., ${prefix}/etc).
 554 PGAC_ARG_REQ(with, odbcinst,
 555              [  --with-odbcinst=DIR     default directory for odbcinst.ini [sysconfdir]],
 556              [odbcinst_ini_dir=$withval],
 557              [odbcinst_ini_dir="\${sysconfdir}"])
 558 AC_SUBST([odbcinst_ini_dir])
 559
 560
 561
 562 # Assume system is ELF if it predefines __ELF__ as 1,
 563 # otherwise believe host_os based default.
 564 case $host_os in
 565     freebsd1*|freebsd2*) elf=no;;
 566     freebsd3*|freebsd4*) elf=yes;;
 567 esac
 568
 569 AC_EGREP_CPP(yes,
 570 [#if __ELF__
 571   yes
 572 #endif
 573 ],
 574 [ELF_SYS=true],
 575 [if test "X$elf" = "Xyes" ; then
 576   ELF_SYS=true
 577 else
 578   ELF_SYS=
 579 fi])
 580 AC_SUBST(ELF_SYS)
 581
 582
 583
 584 #
 585 # Optionally build C++ code (i.e., libpq++)
 586 #
 587 AC_MSG_CHECKING([whether to build C++ modules])
 588 PGAC_ARG_OPTARG(with, CXX, [  --with-CXX              build C++ modules (libpq++)],
 589                 [],
 590                 [CXX=$withval],
 591 [
 592   AC_MSG_RESULT(yes)
 593
 594   # If the user has specified CXXFLAGS in the environment, leave it
 595   # alone, else use a default.
 596
 597   AC_PROG_CXX
 598   if test "$ac_env_CXXFLAGS" != set; then
 599     if test "$GXX" = yes; then
 600       CXXFLAGS="$GCC_CXXFLAGS"
 601     else
 602       CXXFLAGS="$VENDOR_CXXFLAGS"
 603     fi
 604   fi
 605   if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 606     CXXFLAGS="$CXXFLAGS -g"
 607   fi
 608   AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
 609
 610   AC_PROG_CXXCPP
 611 ],
 612 [AC_MSG_RESULT(no)])
 613 AC_SUBST(with_CXX)
 614 AC_SUBST(GXX)
 615
 616 CPPFLAGS="$CPPFLAGS $INCLUDES"
 617 LDFLAGS="$LDFLAGS $LIBDIRS"
 618
 619 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 620 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 621
 622
 623 AC_PROG_AWK
 624 PGAC_PATH_FLEX
 625 AC_PROG_LN_S
 626 AC_PROG_LD
 627 AC_SUBST(LD)
 628 AC_SUBST(with_gnu_ld)
 629 case $host_os in sysv5*)
 630   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 631   [
 632     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 633     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 634     LDFLAGS=$pgac_save_LDFLAGS
 635   ])
 636   ld_R_works=$pgac_cv_prog_ld_R
 637   AC_SUBST(ld_R_works)
 638 esac
 639 AC_PROG_RANLIB
 640 AC_CHECK_PROGS(LORDER, lorder)
 641 AC_PATH_PROG(TAR, tar)
 642 PGAC_CHECK_STRIP
 643
 644 AC_CHECK_PROGS(YACC, ['bison -y'])
 645 if test -z "$YACC"; then
 646   AC_MSG_WARN([
 647 *** Without Bison you will not be able to build PostgreSQL from CVS or
 648 *** change any of the parser definition files.  You can obtain Bison from
 649 *** a GNU mirror site.  (If you are using the official distribution of
 650 *** PostgreSQL then you do not need to worry about this because the Bison
 651 *** output is pre-generated.)  To use a different yacc program (possible,
 652 *** but not recommended), set the environment variable YACC before running
 653 *** 'configure'.])
 654 fi
 655 AC_SUBST(YFLAGS)
 656
 657 if test "$with_tk" = yes; then
 658     AC_PATH_PROG(WISH, wish)
 659     test -z "$WISH" && AC_MSG_ERROR(['wish' is required for Tk support])
 660 fi
 661
 662 PGAC_PATH_PERL
 663 if test "$with_perl" = yes; then
 664   PGAC_CHECK_PERL_CONFIGS([installsitearch,installman3dir,
 665                            archlibexp,privlibexp,useshrplib,man3ext])
 666   PGAC_CHECK_PERL_EMBED_LDFLAGS
 667 fi
 668
 669 if test "$with_python" = yes; then
 670   PGAC_PATH_PYTHON
 671   PGAC_CHECK_PYTHON_MODULE_SETUP
 672   PGAC_CHECK_PYTHON_EMBED_SETUP
 673 fi
 674
 675
 676 ##
 677 ## Libraries
 678 ##
 679
 680 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 681 then
 682         AC_CHECK_LIB(bsd,      main)
 683 fi
 684 AC_CHECK_LIB(util,     setproctitle)
 685 AC_CHECK_LIB(m,        main)
 686 AC_CHECK_LIB(dl,       main)
 687 AC_CHECK_LIB(nsl,      main)
 688 AC_CHECK_LIB(socket,   main)
 689 AC_CHECK_LIB(ipc,      main)
 690 AC_CHECK_LIB(IPC,      main)
 691 AC_CHECK_LIB(lc,       main)
 692 AC_CHECK_LIB(dld,      main)
 693 AC_CHECK_LIB(ld,       main)
 694 AC_CHECK_LIB(compat,   main)
 695 AC_CHECK_LIB(BSD,      main)
 696 AC_CHECK_LIB(gen,      main)
 697 AC_CHECK_LIB(PW,       main)
 698 AC_CHECK_LIB(resolv,   main)
 699 AC_SEARCH_LIBS(getopt_long, [getopt])
 700 # QNX:
 701 AC_CHECK_LIB([[unix]], main)
 702 AC_SEARCH_LIBS(crypt,  crypt)
 703 # BeOS:
 704 AC_CHECK_LIB(bind,     __inet_ntoa)
 705 # Solaris:
 706 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 707
 708 if test "$with_readline" = yes; then
 709   PGAC_CHECK_READLINE
 710   if test x"$pgac_cv_check_readline" = x"no"; then
 711     AC_MSG_ERROR([readline library not found
 712 Use --without-readline to disable readline support.])
 713   fi
 714 fi
 715
 716 if test "$with_zlib" = yes; then
 717   AC_CHECK_LIB(z, inflate, [],
 718                [AC_MSG_ERROR([zlib library not found
 719 Use --without-zlib to disable zlib support.])])
 720 fi
 721
 722 if test "$with_krb4" = yes ; then
 723   AC_CHECK_LIB(des, [des_encrypt], [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 724   AC_CHECK_LIB(krb, [krb_sendauth], [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 725 fi
 726
 727 if test "$with_krb5" = yes ; then
 728   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 729                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 730   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 731                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 732   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 733                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 734 fi
 735
 736 if test "$with_openssl" = yes ; then
 737   dnl Order matters!
 738   AC_CHECK_LIB(crypto, [CRYPTO_new_ex_data], [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 739   AC_CHECK_LIB(ssl,    [SSL_library_init], [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 740 fi
 741
 742 if test "$with_pam" = yes ; then
 743   AC_CHECK_LIB(pam,    [pam_start], [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 744 fi
 745
 746
 747 ##
 748 ## Header files
 749 ##
 750 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 751 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h pwd.h sys/ipc.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h kernel/OS.h kernel/image.h SupportDefs.h])
 752
 753 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 754 # netinet/in.h is included first.
 755 AC_CHECK_HEADERS([netinet/in.h])
 756 AC_CHECK_HEADERS([netinet/tcp.h], [], [],
 757 [AC_INCLUDES_DEFAULT
 758 #ifdef HAVE_NETINET_IN_H
 759 #include <netinet/in.h>
 760 #endif
 761 ])
 762
 763 if test "$with_readline" = yes; then
 764   AC_CHECK_HEADERS([readline/readline.h], [],
 765                    [AC_CHECK_HEADERS([readline.h], [],
 766                                      [AC_MSG_ERROR([readline header not found
 767 Use --without-readline to disable readline support.])])])
 768   AC_CHECK_HEADERS([readline/history.h], [],
 769                    [AC_CHECK_HEADERS([history.h], [],
 770                                      [AC_MSG_ERROR([history header not found
 771 Use --without-readline to disable readline support.])])])
 772 fi
 773
 774 if test "$with_zlib" = yes; then
 775   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 776 Use --without-zlib to disable zlib support.])])
 777 fi
 778
 779 if test "$with_krb4" = yes ; then
 780   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 781 fi
 782
 783 if test "$with_krb5" = yes ; then
 784   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 785   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 786 fi
 787
 788 if test "$with_openssl" = yes ; then
 789   AC_CHECK_HEADER([openssl/ssl.h], [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 790   AC_CHECK_HEADER([openssl/err.h], [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 791 fi
 792
 793 if test "$with_pam" = yes ; then
 794   AC_CHECK_HEADER([security/pam_appl.h], [], [AC_MSG_ERROR([header file <security/pam_appl.h> is required for PAM])])
 795 fi
 796
 797
 798 ##
 799 ## Types, structures, compiler characteristics
 800 ##
 801 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 802 AC_C_CONST
 803 AC_C_INLINE
 804 AC_C_STRINGIZE
 805 PGAC_C_SIGNED
 806 AC_C_VOLATILE
 807 AC_STRUCT_TIMEZONE
 808 PGAC_UNION_SEMUN
 809 PGAC_STRUCT_SOCKADDR_UN
 810
 811 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 812 [#include <sys/param.h>
 813 #include <sys/socket.h>
 814 #include <sys/ucred.h>])
 815
 816 if test "$with_zlib" = yes; then
 817   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 818   # did not).  While we could work around the lack of z_streamp, it
 819   # seems unwise to encourage people to use such old zlib versions...
 820   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 821 Use --without-zlib to disable zlib support.])],
 822                 [#include <zlib.h>])
 823 fi
 824
 825 if test "$with_krb5" = yes; then
 826 # Check for differences between MIT and Heimdal (KTH) releases
 827   AC_CHECK_MEMBERS([krb5_ticket.enc_part2], [],
 828                    [AC_CHECK_MEMBERS([krb5_ticket.client], [],
 829                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 830                                      [#include <krb5.h>])],
 831                    [#include <krb5.h>])
 832   AC_CHECK_MEMBERS([krb5_error.text.data], [],
 833                    [AC_CHECK_MEMBER([krb5_error.e_data], [],
 834                                     [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 835                                     [#include <krb5.h>])],
 836                    [#include <krb5.h>])
 837 fi
 838
 839
 840 ##
 841 ## Functions, global variables
 842 ##
 843 PGAC_VAR_INT_TIMEZONE
 844 AC_FUNC_ACCEPT_ARGTYPES
 845 PGAC_FUNC_GETTIMEOFDAY_1ARG
 846
 847 # SunOS doesn't handle negative byte comparisons properly with +/- return
 848 PGAC_FUNC_MEMCMP
 849
 850 AC_CHECK_FUNCS([cbrt fcvt getopt_long memmove pstat setproctitle setsid sigprocmask sysconf waitpid dlopen fdatasync])
 851
 852 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 853
 854 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 855 [AC_TRY_LINK(
 856 [#include <machine/vmparam.h>
 857 #include <sys/exec.h>
 858 ],
 859 [PS_STRINGS->ps_nargvstr = 1;
 860 PS_STRINGS->ps_argvstr = "foo";],
 861 [pgac_cv_var_PS_STRINGS=yes],
 862 [pgac_cv_var_PS_STRINGS=no])])
 863 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 864   AC_DEFINE([HAVE_PS_STRINGS], [], [Define if the PS_STRINGS thing exists.])
 865 fi
 866
 867
 868 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 869 # is missing.  Yes, there are machines that have only one.  We may
 870 # also decide to use snprintf.c if snprintf() is present but does not
 871 # have working "long long int" support -- see below.
 872
 873 SNPRINTF=''
 874 AC_CHECK_FUNCS(snprintf, [], SNPRINTF='$(top_builddir)/src/port/snprintf.o')
 875 AC_CHECK_FUNCS(vsnprintf, [], SNPRINTF='$(top_builddir)/src/port/snprintf.o')
 876 AC_SUBST(SNPRINTF)
 877
 878
 879 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 880 # include/c.h will provide declarations.  Note this is a separate test
 881 # from whether the functions exist in the C library --- there are
 882 # systems that have the functions but don't bother to declare them :-(
 883
 884 AC_CHECK_DECLS([snprintf, vsnprintf])
 885
 886
 887 # do this one the hard way in case isinf() is a macro
 888 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 889 [AC_TRY_LINK(
 890 [#include <math.h>
 891 ],
 892 [double x = 0.0; int res = isinf(x);],
 893 [ac_cv_func_isinf=yes],
 894 [ac_cv_func_isinf=no])])
 895
 896 if test $ac_cv_func_isinf = yes ; then
 897   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf()])
 898   ISINF=
 899 else
 900   ISINF='isinf.o'
 901   # Look for a way to implement a substitute for isinf()
 902   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 903 fi
 904 AC_SUBST(ISINF)
 905
 906
 907 AC_CHECK_FUNCS(getrusage, [], GETRUSAGE='$(top_builddir)/src/port/getrusage.o')
 908 AC_SUBST(GETRUSAGE)
 909 AC_CHECK_FUNCS(srandom, [], SRANDOM='$(top_builddir)/src/port/srandom.o')
 910 AC_SUBST(SRANDOM)
 911 AC_CHECK_FUNCS(gethostname, [], GETHOSTNAME='$(top_builddir)/src/port/gethostname.o')
 912 AC_SUBST(GETHOSTNAME)
 913 AC_CHECK_FUNCS(random, [], MISSING_RANDOM='$(top_builddir)/src/port/random.o')
 914 AC_SUBST(MISSING_RANDOM)
 915 AC_CHECK_FUNCS(inet_aton, [], INET_ATON='$(top_builddir)/src/port/inet_aton.o')
 916 AC_SUBST(INET_ATON)
 917 AC_CHECK_FUNCS(strerror, [], STRERROR='$(top_builddir)/src/port/strerror.o')
 918 AC_SUBST(STRERROR)
 919 AC_CHECK_FUNCS(strdup, [], STRDUP='$(top_builddir)/src/port/strdup.o')
 920 AC_SUBST(STRDUP)
 921 AC_CHECK_FUNCS(strtol, [], STRTOL='$(top_builddir)/src/port/strtol.o')
 922 AC_SUBST(STRTOL)
 923 AC_CHECK_FUNCS(strtoul, [], STRTOUL='$(top_builddir)/src/port/strtoul.o')
 924 AC_SUBST(STRTOUL)
 925 AC_CHECK_FUNCS(strcasecmp, [], STRCASECMP='$(top_builddir)/src/port/strcasecmp.o')
 926 AC_SUBST(STRCASECMP)
 927
 928 # Set path of dllinit.c for cygwin
 929 DLLINIT=""
 930 case $host_os in
 931   cygwin*) DLLINIT='$(top_builddir)/src/backend/port/dllinit.o' ;;
 932 esac
 933 AC_SUBST(DLLINIT)
 934
 935 # Set path of qsort for solaris, which has a very slow qsort in certain cases.
 936 QSORT=""
 937 case $host_os in
 938   solaris*) DLLINIT='$(top_builddir)/src/backend/port/qsort.o' ;;
 939 esac
 940 AC_SUBST(QSORT)
 941
 942 # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
 943 # this hackery with HPUXMATHLIB allows us to cope.
 944 HPUXMATHLIB=""
 945 case $host_cpu in
 946   hppa1.1)
 947         if [[ -r /lib/pa1.1/libm.a ]] ; then
 948             HPUXMATHLIB="-L /lib/pa1.1 -lm"
 949         fi ;;
 950 esac
 951 AC_SUBST(HPUXMATHLIB)
 952
 953 AC_CHECK_FUNCS(rint, [],
 954                [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
 955
 956
 957 if test "$with_readline" = yes; then
 958   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 959   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 960 fi
 961
 962
 963 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 964 AC_MSG_CHECKING(for finite)
 965 AC_TRY_LINK([#include <math.h>],
 966             [int dummy=finite(1.0);],
 967             [AC_DEFINE(HAVE_FINITE, 1, [Set to 1 if you have finite()])
 968 AC_MSG_RESULT(yes)],
 969             [AC_MSG_RESULT(no)])
 970
 971 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 972 dnl (especially on GNU libc)
 973 dnl See also comments in pg_config.h.
 974 AC_MSG_CHECKING(for sigsetjmp)
 975 AC_TRY_LINK([#include <setjmp.h>],
 976             [sigjmp_buf x; sigsetjmp(x, 1);],
 977             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Set to 1 if you have sigsetjmp()])
 978 AC_MSG_RESULT(yes)],
 979             [AC_MSG_RESULT(no)])
 980
 981 AC_CHECK_FUNC(syslog,
 982              [AC_CHECK_HEADER(syslog.h,
 983              [AC_DEFINE(HAVE_SYSLOG, 1, [])],
 984              [])])
 985
 986 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 987 [AC_TRY_LINK([#include <unistd.h>],
 988   [extern int optreset; optreset = 1;],
 989   [pgac_cv_var_int_optreset=yes],
 990   [pgac_cv_var_int_optreset=no])])
 991 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 992   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'])
 993 fi
 994
 995
 996 # This test makes sure that run tests work at all.  Sometimes a shared
 997 # library is found by the linker, but the runtime linker can't find it.
 998 # This check should come after all modifications of compiler or linker
 999 # variables, and before any other run tests.
1000 AC_MSG_CHECKING([test program])
1001 AC_TRY_RUN([int main() { return 0; }],
1002 [AC_MSG_RESULT(ok)],
1003 [AC_MSG_RESULT(failed)
1004 AC_MSG_ERROR([[
1005 *** Could not execute a simple test program.  This may be a problem
1006 *** related to locating shared libraries.  Check the file 'config.log'
1007 *** for the exact reason.]])],
1008 [AC_MSG_RESULT([cross-compiling])])
1009
1010
1011 dnl Check to see if we have a working 64-bit integer type.
1012 dnl This breaks down into two steps:
1013 dnl (1) figure out if the compiler has a 64-bit int type with working
1014 dnl arithmetic, and if so
1015 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1016 dnl snprintf is the only library routine we really need for int8 support.)
1017 dnl It's entirely possible to have a compiler that handles a 64-bit type
1018 dnl when the C library doesn't; this is fairly likely when using gcc on
1019 dnl an older platform, for example.
1020 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1021 dnl we force our own version of snprintf() to be used instead.
1022 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1023
1024 PGAC_TYPE_64BIT_INT([long int])
1025
1026 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1027   PGAC_TYPE_64BIT_INT([long long int])
1028 fi
1029
1030
1031 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1032
1033 if [[ x"$HAVE_LONG_LONG_INT_64" = xyes ]] ; then
1034   AC_TRY_COMPILE([
1035 #define INT64CONST(x)  x##LL
1036 long long int foo = INT64CONST(0x1234567890123456);
1037 ],
1038         [],
1039         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define if you have LL constants])],
1040         [])
1041 fi
1042
1043
1044 dnl If we found "long int" is 64 bits, assume snprintf handles it.
1045 dnl If we found we need to use "long long int", better check.
1046 dnl We cope with snprintfs that use either %lld or %qd as the format.
1047 dnl If neither works, fall back to our own snprintf emulation (which we
1048 dnl know uses %lld).
1049
1050 if [[ x"$HAVE_LONG_LONG_INT_64" = xyes ]] ; then
1051   if [[ x$SNPRINTF = x ]] ; then
1052     AC_MSG_CHECKING(whether snprintf handles 'long long int' as %lld)
1053     AC_TRY_RUN([#include <stdio.h>
1054 typedef long long int int64;
1055 #define INT64_FORMAT "%lld"
1056
1057 int64 a = 20000001;
1058 int64 b = 40000005;
1059
1060 int does_int64_snprintf_work()
1061 {
1062   int64 c;
1063   char buf[100];
1064
1065   if (sizeof(int64) != 8)
1066     return 0;                   /* doesn't look like the right size */
1067
1068   c = a * b;
1069   snprintf(buf, 100, INT64_FORMAT, c);
1070   if (strcmp(buf, "800000140000005") != 0)
1071     return 0;                   /* either multiply or snprintf is busted */
1072   return 1;
1073 }
1074 main() {
1075   exit(! does_int64_snprintf_work());
1076 }],
1077         [ AC_MSG_RESULT(yes)
1078           INT64_FORMAT='"%lld"'
1079         ],
1080   [ AC_MSG_RESULT(no)
1081     AC_MSG_CHECKING(whether snprintf handles 'long long int' as %qd)
1082     AC_TRY_RUN([#include <stdio.h>
1083 typedef long long int int64;
1084 #define INT64_FORMAT "%qd"
1085
1086 int64 a = 20000001;
1087 int64 b = 40000005;
1088
1089 int does_int64_snprintf_work()
1090 {
1091   int64 c;
1092   char buf[100];
1093
1094   if (sizeof(int64) != 8)
1095     return 0;     /* doesn't look like the right size */
1096
1097   c = a * b;
1098   snprintf(buf, 100, INT64_FORMAT, c);
1099   if (strcmp(buf, "800000140000005") != 0)
1100     return 0;     /* either multiply or snprintf is busted */
1101   return 1;
1102 }
1103 main() {
1104   exit(! does_int64_snprintf_work());
1105 }],
1106   [ AC_MSG_RESULT(yes)
1107     INT64_FORMAT='"%qd"'
1108   ],
1109   [ AC_MSG_RESULT(no)
1110         # Force usage of our own snprintf, since system snprintf is broken
1111         SNPRINTF='$(top_builddir)/src/port/snprintf.o'
1112         INT64_FORMAT='"%lld"'
1113   ],
1114   [ AC_MSG_RESULT(assuming not on target machine)
1115         # Force usage of our own snprintf, since we cannot test foreign snprintf
1116         SNPRINTF='$(top_builddir)/src/port/snprintf.o'
1117         INT64_FORMAT='"%lld"'
1118   ]) ],
1119   [ AC_MSG_RESULT(assuming not on target machine)
1120         # Force usage of our own snprintf, since we cannot test foreign snprintf
1121         SNPRINTF='$(top_builddir)/src/port/snprintf.o'
1122         INT64_FORMAT='"%lld"'
1123   ])
1124   else
1125     # here if we previously decided we needed to use our own snprintf
1126     INT64_FORMAT='"%lld"'
1127   fi
1128 else
1129   # Here if we are not using 'long long int' at all
1130   INT64_FORMAT='"%ld"'
1131 fi
1132
1133 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1134                    [Define this as the appropriate snprintf format for 64-bit ints, if any])
1135
1136
1137 AC_CHECK_FUNCS([strtoll strtoq], [break])
1138 AC_CHECK_FUNCS([strtoull strtouq], [break])
1139
1140 # Check for one of atexit() or on_exit()
1141 AC_CHECK_FUNCS(atexit, [],
1142                [AC_CHECK_FUNCS(on_exit, [],
1143                                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1144
1145 dnl Need a #define for the size of Datum (unsigned long)
1146
1147 AC_CHECK_SIZEOF([unsigned long])
1148 AC_DEFINE_UNQUOTED(SIZEOF_DATUM, $ac_cv_sizeof_unsigned_long, [sizeof(Datum) -- don't change])
1149
1150 # Determine memory alignment requirements for the basic C data types.
1151
1152 PGAC_CHECK_ALIGNOF(short)
1153 PGAC_CHECK_ALIGNOF(int)
1154 PGAC_CHECK_ALIGNOF(long)
1155 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1156   PGAC_CHECK_ALIGNOF(long long int)
1157 fi
1158 PGAC_CHECK_ALIGNOF(double)
1159
1160 # Compute maximum alignment of any basic type.
1161 # We assume long's alignment is at least as strong as char, short, or int;
1162 # but we must check long long (if it exists) and double.
1163
1164 MAX_ALIGNOF=$pgac_cv_alignof_long
1165 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1166   MAX_ALIGNOF=$pgac_cv_alignof_double
1167 fi
1168 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1169   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1170 fi
1171 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any type])
1172
1173
1174 # Some platforms predefine the types int8, int16, etc.  Only check
1175 # a (hopefully) representative subset.
1176 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1177 [#include <stdio.h>
1178 #ifdef HAVE_SUPPORTDEFS_H
1179 #include <SupportDefs.h>
1180 #endif])
1181
1182 # We also check for sig_atomic_t, which *should* be defined per ANSI
1183 # C, but is missing on some old platforms.
1184 AC_CHECK_TYPES([sig_atomic_t], [], [], [#include <signal.h>])
1185
1186
1187 PGAC_FUNC_POSIX_SIGNALS
1188
1189
1190 # Select semaphore implementation type.
1191 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1192   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores])
1193   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1194 else
1195   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1196     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores])
1197     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1198   else
1199     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores])
1200     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1201   fi
1202 fi
1203
1204
1205 # Select shared-memory implementation type.
1206 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory])
1207 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1208
1209
1210 if test "$enable_nls" = yes ; then
1211   PGAC_CHECK_GETTEXT
1212 fi
1213
1214 if test "$with_CXX" = yes; then
1215   PGAC_CLASS_STRING
1216   PGAC_CXX_NAMESPACE_STD
1217 fi
1218
1219
1220 # Check for Tcl configuration script tclConfig.sh
1221 if test "$with_tcl" = yes; then
1222     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1223     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1224                           [TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1225     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1226 fi
1227
1228 # Check for Tk configuration script tkConfig.sh
1229 if test "$with_tk" = yes; then
1230     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1231     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1232 fi
1233
1234
1235 #
1236 # Check for DocBook and tools
1237 #
1238 PGAC_PROG_NSGMLS
1239 PGAC_PROG_JADE
1240 PGAC_CHECK_DOCBOOK([3.1])
1241 PGAC_PATH_DOCBOOK_STYLESHEETS
1242 PGAC_PATH_COLLATEINDEX
1243 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1244
1245
1246 # prepare build tree if outside source tree
1247 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1248 # Note 2: /bin/pwd might be better than shell's built-in at getting
1249 #         a symlink-free name.
1250 if test "$no_create" != yes; then
1251   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1252     :
1253   else
1254     AC_SUBST(vpath_build, yes)
1255     _AS_ECHO_N([preparing build tree... ])
1256     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1257     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1258       || AC_MSG_ERROR(failed)
1259     AC_MSG_RESULT(done)
1260   fi
1261 fi
1262
1263
1264 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1265
1266 AC_CONFIG_LINKS([
1267   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1268   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1269   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1270   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1271   src/include/pg_config_os.h:src/include/port/${template}.h
1272   src/Makefile.port:src/makefiles/Makefile.${template}
1273 ])
1274
1275 AC_CONFIG_HEADERS([src/include/pg_config.h],
1276 [
1277 # Update timestamp for pg_config.h (see Makefile.global)
1278 echo >src/include/stamp-h
1279 ])
1280
1281 AC_OUTPUT