granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please read the documentation.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 if test "x${cache_file}" = "x/dev/null"; then
 210   # Likewise, ensure that CC and CPP are passed through to the pcre
 211   # configure script iff caching is disabled (the autoconf 2.5x default).
 212   export CC; export CPP
 213 fi
 214
 215 AC_ARG_WITH(pcre,
 216 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 217
 218 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 219 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 220    PCRE_CONFIG=$with_pcre/bin/pcre-config
 221 elif test -x "$with_pcre"; then
 222    PCRE_CONFIG=$with_pcre
 223 fi
 224
 225 if test "$PCRE_CONFIG" != "false"; then
 226   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 227     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 228   fi
 229   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 230   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 231   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 232 else
 233   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 234 fi
 235 APACHE_SUBST(PCRE_LIBS)
 236
 237 AC_MSG_NOTICE([])
 238 AC_MSG_NOTICE([Configuring Apache httpd...])
 239 AC_MSG_NOTICE([])
 240
 241 dnl If the source dir is not equal to the build dir,
 242 dnl then we are running in VPATH mode.
 243
 244 APR_ADDTO(INCLUDES, [-I.])
 245
 246 if test "$abs_builddir" != "$abs_srcdir"; then
 247   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 248 fi
 249
 250 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 251
 252 # apr/apr-util --includes may pick up system paths for dependent
 253 # libraries, so ensure these are later in INCLUDES than local source
 254 # directories.
 255 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 256 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 257
 258 dnl Add in path to PCRE includes
 259 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 260
 261 AC_MSG_NOTICE([])
 262 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 263 AC_MSG_NOTICE([])
 264
 265 case $host in
 266   *os2*)
 267       # Use a custom made libtool replacement
 268       echo "using aplibtool"
 269       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 270       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 271       SH_LIBS="\$(ALL_LIBS)"
 272       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 273       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 274       MK_IMPLIB="emximp"
 275       other_targets="$other_targets os2core"
 276       INSTALL_PROG_FLAGS="-e .exe"
 277       SHLTCFLAGS=""
 278       LTCFLAGS=""
 279       ;;
 280   *)
 281       if test "x$LTFLAGS" = "x"; then
 282           LTFLAGS='--silent'
 283       fi
 284       my_libtool=`$apr_config --apr-libtool`
 285       LIBTOOL="$my_libtool \$(LTFLAGS)"
 286       libtoolversion=`$my_libtool --version`
 287       case $libtoolversion in
 288           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 289               SH_LIBTOOL='$(LIBTOOL)'
 290               SHLTCFLAGS="-prefer-pic"
 291               LTCFLAGS="-prefer-non-pic -static"
 292               ;;
 293           *)
 294               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 295               SHLTCFLAGS=""
 296               LTCFLAGS=""
 297               ;;
 298       esac
 299       ;;
 300 esac
 301 APACHE_SUBST(SHLTCFLAGS)
 302 APACHE_SUBST(LTCFLAGS)
 303
 304 case $host in
 305   *-apple-aux3*)
 306       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 307       ;;
 308   *os2-emx*)
 309       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 310       ;;
 311   *-linux-*)
 312       case `uname -r` in
 313         2.[[2-9]]* )
 314             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 315             ;;
 316         * )
 317             ;;
 318       esac
 319       ;;
 320   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 321       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 322       ;;
 323   *-solaris2*)
 324       dnl This is a hack -- we should be using AC_TRY_RUN instead
 325       ap_platform_runtime_link_flag="-R"
 326       dnl solaris 8 and above don't have a thundering herd
 327       dnl not sure about rev's before this one.
 328       case `uname -r` in
 329         5.[567]*)
 330             ;;
 331         * )
 332             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 333             ;;
 334       esac
 335       ;;
 336   *cygwin*)
 337       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 338       ;;
 339   *mingw32*)
 340       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 341       APR_SETIFNULL(ac_cv_func_times, [no])
 342       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 343       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 344       ;;
 345   *aix*)
 346       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 347       if test $aixver -ge 4320; then
 348         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 349       fi
 350       ;;
 351   *os390*)
 352       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 353       ;;
 354 esac
 355
 356 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 357
 358 dnl
 359 dnl Process command line arguments. This is done early in the process so the
 360 dnl user can get feedback quickly in case of an error.
 361 dnl
 362 dnl ### need to move some of the arguments "up here"
 363
 364 dnl ## Check for programs
 365
 366 AC_PATH_PROG(RM, rm)
 367 AC_PATH_PROG(PKGCONFIG, pkg-config)
 368 AC_PATH_PROG(RSYNC, rsync)
 369 AC_PROG_AWK
 370 AC_PROG_LN_S
 371 AC_CHECK_TOOL(RANLIB, ranlib, true)
 372 dnl AC_PATH_PROG(PERL_PATH, perl)
 373 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 374
 375 # Hard-coded install programs
 376 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 377 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 378 APACHE_SUBST(MKINSTALLDIRS)
 379 APACHE_SUBST(INSTALL)
 380
 381 dnl Various OS checks that apparently set required flags
 382 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 383 AC_USE_SYSTEM_EXTENSIONS
 384 ], [
 385 AC_AIX
 386 AC_MINIX
 387 ])
 388
 389 AC_ISC_POSIX
 390
 391 # Ensure that satisfactory versions of apr and apr-util are
 392 # found if external copies are configured.
 393 if test "${apr_found}" = "yes"; then
 394   # Require at least APR 1.3.x otherwise fail
 395   APACHE_CHECK_APxVER([apr], 1, 3)
 396 fi
 397
 398 if test "${apu_found}" = "yes"; then
 399   # Require at least APR-util 1.3.x otherwise fail
 400   if test "${apr_found}" = "yes"; then
 401     # we need to add the APR includes to CPPFLAGS
 402     apu_ckver_CPPFLAGS="$CPPFLAGS"
 403     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 404     APACHE_CHECK_APxVER([apu], 1, 3)
 405     CPPFLAGS="$apu_ckver_CPPFLAGS"
 406   else
 407     APACHE_CHECK_APxVER([apu], 1, 3)
 408   fi
 409 fi
 410
 411 dnl Check for what we can generate dependency files with
 412 APR_CHECK_DEPEND
 413
 414 dnl ## Check for libraries
 415
 416 dnl ## Check for header files
 417
 418 dnl I think these are just used all over the place, so just check for
 419 dnl them at the base of the tree. If some are specific to a single
 420 dnl directory, they should be moved (Comment #Spoon)
 421
 422 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 423 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 424 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 425
 426 AC_HEADER_STDC
 427 AC_CHECK_HEADERS( \
 428 string.h \
 429 limits.h \
 430 unistd.h \
 431 sys/socket.h \
 432 pwd.h \
 433 grp.h \
 434 strings.h \
 435 sys/prctl.h \
 436 sys/processor.h \
 437 sys/sem.h \
 438 sys/sdt.h
 439 )
 440 AC_HEADER_SYS_WAIT
 441
 442 dnl ## Check for typedefs, structures, and compiler characteristics.
 443
 444 AC_C_CONST
 445
 446 dnl ## Check for library functions
 447 dnl ## sqrt() only needed in support/ab.c
 448 saved_LIBS="$LIBS"
 449 LIBS=""
 450 AC_SEARCH_LIBS(sqrt, m)
 451 MATH_LIBS="$LIBS"
 452 APACHE_SUBST(MATH_LIBS)
 453 LIBS="$saved_LIBS"
 454
 455 saved_LIBS="$LIBS"
 456 LIBS=""
 457 AC_SEARCH_LIBS(crypt, crypt)
 458 CRYPT_LIBS="$LIBS"
 459 APACHE_SUBST(CRYPT_LIBS)
 460 LIBS="$saved_LIBS"
 461
 462 dnl See Comment #Spoon
 463
 464 AC_CHECK_FUNCS( \
 465 getpwnam \
 466 getgrnam \
 467 initgroups \
 468 bindprocessor \
 469 prctl \
 470 timegm \
 471 getpgid \
 472 fopen64
 473 )
 474
 475 dnl confirm that a void pointer is large enough to store a long integer
 476 APACHE_CHECK_VOID_PTR_LEN
 477
 478 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 479 [AC_TRY_RUN(#define _GNU_SOURCE
 480 #include <unistd.h>
 481 #include <sys/syscall.h>
 482 #include <sys/types.h>
 483 int main(int argc, char **argv) {
 484 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 485 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 486 if test "$ac_cv_gettid" = "yes"; then
 487     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 488 fi
 489
 490 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 491 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 492 [AC_TRY_COMPILE([#include <sys/types.h>
 493 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 494   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 495 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 496     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 497 fi
 498
 499 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 500
 501 case $host in
 502     *aix*)
 503         # for 32-bit builds, increase MAXDATA to allow lots of threads
 504         if test x$OBJECT_MODE != x64; then
 505             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 506         fi
 507         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 508         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 509         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 510         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 511         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 512         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 513         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 514         ;;
 515     *os390*)
 516         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 517         ;;
 518     *)
 519         OS_SPECIFIC_VARS=""
 520 esac
 521
 522 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 523         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 524         [PORT=80])
 525
 526 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 527         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 528         [SSLPORT=443])
 529
 530 DTRACE=true
 531 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 532 [
 533   enable_dtrace=$enableval
 534   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 535   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 536 ],
 537 [
 538   enable_dtrace=no
 539 ])
 540
 541 dnl Disabled dtrace build for now.
 542 enable_dtrace=no
 543
 544 case $host in
 545   *-solaris2*)
 546     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 547         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 548                   [Enable DTrace probes])
 549         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 550         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 551     fi
 552     ;;
 553 esac
 554
 555 APACHE_SUBST(DTRACE)
 556
 557 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 558 [
 559     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 560         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 561     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 562 ])dnl
 563
 564 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 565 [
 566     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 567               [Allow modules to run hook after a fatal exception])
 568 ])dnl
 569
 570 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 571 [
 572   LOAD_ALL_MODULES=$enableval
 573   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 574 ],
 575 [
 576   LOAD_ALL_MODULES="no"
 577 ])
 578
 579 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 580 [
 581   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 582   if test "$GCC" = "yes"; then
 583     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 584     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 585     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 586     APACHE_ADD_GCC_CFLAG([-Wformat])
 587     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 588     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 589   elif test "$AIX_XLC" = "yes"; then
 590     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 591   fi
 592   if test "x$enable_load_all_modules" = "x"; then
 593     LOAD_ALL_MODULES=yes
 594     AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 595   fi
 596 ])dnl
 597
 598 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 599 [
 600   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 601   if test "$GCC" = "yes"; then
 602     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 603     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 604     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 605     APACHE_ADD_GCC_CFLAG([-Wformat])
 606     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 607     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 608   elif test "$AIX_XLC" = "yes"; then
 609     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 610   fi
 611 ])dnl
 612
 613 dnl Conditionally enable PIE support for GNU toolchains.
 614 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 615 if test "$enable_pie" = "yes"; then
 616    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 617      save_CFLAGS=$CFLAGS
 618      save_LDFLAGS=$LDFLAGS
 619      CFLAGS="$CFLAGS -fPIE"
 620      LDFLAGS="$LDFLAGS -pie"
 621      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 622       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 623      CFLAGS=$save_CFLAGS
 624      LDFLAGS=$save_LDFLAGS
 625    ])
 626    if test "$ap_cv_cc_pie" = "yes"; then
 627      PICFLAGS="-fPIE"
 628      PILDFLAGS="-pie"
 629    else
 630      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 631    fi
 632 fi
 633 APACHE_SUBST(PICFLAGS)
 634 APACHE_SUBST(PILDFLAGS)
 635
 636 prefix="$orig_prefix"
 637 APACHE_ENABLE_MODULES
 638
 639 dnl reading config stubs
 640 esyscmd(./build/config-stubs .)
 641
 642 APACHE_SUBST(progname)
 643 APACHE_SUBST(OS)
 644 APACHE_SUBST(OS_DIR)
 645 APACHE_SUBST(BUILTIN_LIBS)
 646 APACHE_SUBST(SHLIBPATH_VAR)
 647 APACHE_SUBST(OS_SPECIFIC_VARS)
 648
 649 PRE_SHARED_CMDS='echo ""'
 650 POST_SHARED_CMDS='echo ""'
 651
 652 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 653
 654 if test "$apache_need_shared" = "yes"; then
 655   if test -f $ac_aux_dir/ltconfig; then
 656     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 657   fi
 658   shared_build="shared-build"
 659 fi
 660
 661 dnl enable_so tells us if *any* modules can be built as DSOs
 662
 663 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 664   case $host in
 665     *-ibm-aix*)
 666       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 667       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 668       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 669       ;;
 670     *os390)
 671       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 672       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 673   esac
 674   MOD_SO_ENABLED=yes
 675 fi
 676 AC_SUBST(MOD_SO_ENABLED)
 677
 678 APACHE_SUBST(PRE_SHARED_CMDS)
 679 APACHE_SUBST(POST_SHARED_CMDS)
 680 APACHE_SUBST(shared_build)
 681
 682 AC_ARG_WITH(program-name,
 683 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 684   progname="$withval" ], [
 685   progname="httpd"] )
 686
 687 # SuExec parameters
 688 AC_ARG_WITH(suexec-bin,
 689 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 690   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 691 ] )
 692
 693 AC_ARG_WITH(suexec-caller,
 694 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 695   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 696
 697 AC_ARG_WITH(suexec-userdir,
 698 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 699   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 700
 701 AC_ARG_WITH(suexec-docroot,
 702 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 703   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 704
 705 AC_ARG_WITH(suexec-uidmin,
 706 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 707   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 708
 709 AC_ARG_WITH(suexec-gidmin,
 710 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 711   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 712
 713 AC_ARG_WITH(suexec-logfile,
 714 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 715   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 716
 717 AC_ARG_WITH(suexec-safepath,
 718 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 719   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 720
 721 AC_ARG_WITH(suexec-umask,
 722 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 723   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 724
 725 dnl APR should go after the other libs, so the right symbols can be picked up
 726 if test x${apu_found} != xobsolete; then
 727   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 728 fi
 729 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 730 APACHE_SUBST(AP_LIBS)
 731 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 732 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 733
 734 AC_DEFINE(AP_USING_AUTOCONF, 1,
 735                 [Using autoconf to configure Apache])
 736
 737 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 738     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 739               [This platform doesn't suffer from the thundering herd problem])
 740 fi
 741
 742 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 743     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 744               [Listening sockets are non-blocking when there are more than 1])
 745 fi
 746
 747 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 748
 749 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 750 [
 751   v4mapped=$enableval
 752 ],
 753 [
 754     case $host in
 755     *freebsd5*|*netbsd*|*openbsd*)
 756         v4mapped=no
 757         ;;
 758     *)
 759         v4mapped=yes
 760         ;;
 761     esac
 762     if ap_mpm_is_enabled winnt; then
 763         dnl WinNT MPM doesn't support this.
 764         v4mapped=no
 765     fi
 766 ])
 767
 768 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 769     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 770               [Allow IPv4 connections on IPv6 listening sockets])
 771 fi
 772
 773 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 774 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 775 APACHE_FAST_OUTPUT(support/Makefile)
 776
 777 if test -d ./test; then
 778     APACHE_FAST_OUTPUT(test/Makefile)
 779 fi
 780
 781 dnl ## Finalize the variables
 782 AC_MSG_NOTICE([])
 783 AC_MSG_NOTICE([Restore user-defined environment settings...])
 784 AC_MSG_NOTICE([])
 785
 786 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 787 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 788 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 789 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 790 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 791 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 792
 793 AC_MSG_NOTICE([])
 794 AC_MSG_NOTICE([Construct makefiles and header files...])
 795 AC_MSG_NOTICE([])
 796
 797 APACHE_GEN_CONFIG_VARS
 798
 799 dnl ## Build modules.c
 800 rm -f modules.c
 801 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 802
 803 APR_EXPAND_VAR(ap_prefix, $prefix)
 804 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 805         [Root directory of the Apache install area])
 806 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 807         [Location of the config file, relative to the Apache root directory])
 808 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 809         [Location of the MIME types config file, relative to the Apache root directory])
 810
 811 perlbin=`$ac_aux_dir/PrintPath perl`
 812 if test "x$perlbin" = "x"; then
 813     perlbin="/replace/with/path/to/perl/interpreter"
 814 fi
 815 AC_SUBST(perlbin)
 816
 817 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 818
 819 BSD_MAKEFILE=no
 820 ap_make_include=include
 821 ap_make_delimiter=' '
 822 case $host in
 823 *bsdi*)
 824     # Check whether they've installed GNU make
 825     if make --version > /dev/null 2>&1; then
 826         true
 827     else
 828         BSD_MAKEFILE=yes
 829         ap_make_include=.include
 830         ap_make_delimiter='"'
 831     fi
 832     ;;
 833 esac
 834 AC_SUBST(ap_make_include)
 835 AC_SUBST(ap_make_delimiter)
 836
 837 dnl Ensure that docs/conf is created.
 838 test -d docs/conf||$mkdir_p docs/conf
 839
 840 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 841   APACHE_GEN_MAKEFILES
 842 ])