granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.431 2005/11/05 04:01:41 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.1.0], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2005, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60  linux*|gnu*|k*bsd*-gnu)
  61            template=linux ;;
  62    mingw*) template=win32 ;;
  63   netbsd*) template=netbsd ;;
  64 nextstep*) template=nextstep ;;
  65  openbsd*) template=openbsd ;;
  66      osf*) template=osf ;;
  67      qnx*) template=qnx4 ;;
  68      sco*) template=sco ;;
  69  solaris*) template=solaris ;;
  70    sunos*) template=sunos4 ;;
  71  sysv4.2*)
  72         case $host_vendor in
  73           univel) template=univel ;;
  74         esac ;;
  75    sysv4*) template=svr4 ;;
  76    sysv5*) template=unixware ;;
  77   ultrix*) template=ultrix4 ;;
  78 esac
  79
  80   if test x"$template" = x"" ; then
  81     AC_MSG_ERROR([[
  82 *******************************************************************
  83 PostgreSQL has apparently not been ported to your platform yet.
  84 To try a manual configuration, look into the src/template directory
  85 for a similar platform and use the '--with-template=' option.
  86
  87 Please also contact <pgsql-ports@postgresql.org> to see about
  88 rectifying this.  Include the above 'checking host system type...'
  89 line.
  90 *******************************************************************
  91 ]])
  92   fi
  93
  94 ])
  95
  96 AC_MSG_RESULT([$template])
  97
  98 PORTNAME=$template
  99 AC_SUBST(PORTNAME)
 100
 101 # Initialize default assumption that we do not need separate assembly code
 102 # for TAS (test-and-set).  This can be overridden by the template file
 103 # when it's executed.
 104 need_tas=no
 105 tas_file=dummy.s
 106
 107
 108
 109 ##
 110 ## Command line options
 111 ##
 112
 113 #
 114 # Installation directory for documentation
 115 #
 116 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 117   --without-docdir        do not install the documentation],
 118          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 119          [docdir=],
 120          [docdir=$withval],
 121          [docdir='${prefix}/doc'])
 122 AC_SUBST(docdir)
 123
 124
 125 #
 126 # Add non-standard directories to the include path
 127 #
 128 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 129
 130
 131 #
 132 # Add non-standard directories to the library search path
 133 #
 134 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 135              [LIBRARY_DIRS=$withval])
 136
 137 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 138              [LIBRARY_DIRS=$withval])
 139
 140
 141 #
 142 # 64-bit integer date/time storage (--enable-integer-datetimes)
 143 #
 144 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 145 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 146               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 147                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 148 AC_MSG_RESULT([$enable_integer_datetimes])
 149
 150
 151 #
 152 # NLS
 153 #
 154 AC_MSG_CHECKING([whether NLS is wanted])
 155 PGAC_ARG_OPTARG(enable, nls,
 156                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 157                 [],
 158                 [WANTED_LANGUAGES=$enableval],
 159                 [AC_DEFINE(ENABLE_NLS, 1,
 160                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 161 AC_MSG_RESULT([$enable_nls])
 162 AC_SUBST(enable_nls)
 163 AC_SUBST(WANTED_LANGUAGES)
 164
 165 #
 166 # Default port number (--with-pgport), default 5432
 167 #
 168 AC_MSG_CHECKING([for default port number])
 169 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 170              [default_port=$withval],
 171              [default_port=5432])
 172 AC_MSG_RESULT([$default_port])
 173 # Need both of these because some places want an integer and some a string
 174 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 175 [Define to the default TCP port number on which the server listens and
 176 to which clients will try to connect.  This can be overridden at run-time,
 177 but it's convenient if your clients have the right default compiled in.
 178 (--with-pgport=PORTNUM)])
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 180                    [Define to the default TCP port number as a string constant.])
 181 AC_SUBST(default_port)
 182
 183 #
 184 # Option to disable shared libraries
 185 #
 186 PGAC_ARG_BOOL(enable, shared, yes,
 187               [  --disable-shared        do not build shared libraries])
 188 AC_SUBST(enable_shared)
 189
 190 #
 191 # '-rpath'-like feature can be disabled
 192 #
 193 PGAC_ARG_BOOL(enable, rpath, yes,
 194               [  --disable-rpath         do not embed shared library search path in executables])
 195 AC_SUBST(enable_rpath)
 196
 197 #
 198 # Spinlocks
 199 #
 200 PGAC_ARG_BOOL(enable, spinlocks, yes,
 201               [  --disable-spinlocks     do not use spinlocks])
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 unset CFLAGS
 228
 229 #
 230 # Read the template
 231 #
 232 . "$srcdir/src/template/$template" || exit
 233
 234 # CFLAGS are selected so:
 235 # If the user specifies something in the environment, that is used.
 236 # else:  If the template file set something, that is used.
 237 # else:  If the compiler is GCC, then we use -O2.
 238 # else:  If the compiler is something else, then we use -0.
 239
 240 if test "$ac_env_CFLAGS_set" = set; then
 241   CFLAGS=$ac_env_CFLAGS_value
 242 elif test "${CFLAGS+set}" = set; then
 243   : # (keep what template set)
 244 elif test "$GCC" = yes; then
 245   CFLAGS="-O2"
 246 else
 247   # if the user selected debug mode, don't use -O
 248   if test "$enable_debug" != yes; then
 249     CFLAGS="-O"
 250   fi
 251 fi
 252
 253 if test "$GCC" = yes; then
 254   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 255
 256   # Some versions of GCC support some additional useful warning flags.
 257   # Check whether they are supported, and add them to CFLAGS if so.
 258   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 259   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 260
 261   # Disable strict-aliasing rules; needed for gcc 3.3+
 262   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 263 fi
 264
 265 # supply -g if --enable-debug
 266 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 267   CFLAGS="$CFLAGS -g"
 268 fi
 269
 270 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 271
 272 # We already have this in Makefile.win32, but configure needs it too
 273 if test "$PORTNAME" = "win32"; then
 274   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 275 fi
 276
 277 # Check if the compiler still works with the template settings
 278 AC_MSG_CHECKING([whether the C compiler still works])
 279 AC_TRY_LINK([], [return 0;],
 280   [AC_MSG_RESULT(yes)],
 281   [AC_MSG_RESULT(no)
 282    AC_MSG_ERROR([cannot proceed])])
 283
 284 # Defend against gcc -ffast-math
 285 if test "$GCC" = yes; then
 286 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 287 choke me
 288 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 289 fi
 290
 291 AC_PROG_CPP
 292 AC_SUBST(GCC)
 293
 294 # Create compiler version string
 295 if test x"$GCC" = x"yes" ; then
 296   cc_string="GCC `${CC} --version | sed q`"
 297 else
 298   cc_string=$CC
 299 fi
 300 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 301                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 302                    [A string containing the version number, platform, and C compiler])
 303
 304
 305 #
 306 # Set up TAS assembly code if needed; the template file has now had its
 307 # chance to request this.
 308 #
 309 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 310
 311 if test "$need_tas" = yes ; then
 312   TAS=tas.o
 313 else
 314   TAS=""
 315 fi
 316 AC_SUBST(TAS)
 317
 318
 319 #
 320 # Automatic dependency tracking
 321 #
 322 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 323               [autodepend=yes])
 324 AC_SUBST(autodepend)
 325
 326
 327 #
 328 # Enable assert checks
 329 #
 330 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 331               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 332                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 333
 334
 335 #
 336 # Include directories
 337 #
 338 ac_save_IFS=$IFS
 339 IFS="${IFS}${PATH_SEPARATOR}"
 340 # SRCH_INC comes from the template file
 341 for dir in $with_includes $SRCH_INC; do
 342   if test -d "$dir"; then
 343     INCLUDES="$INCLUDES -I$dir"
 344   else
 345     AC_MSG_WARN([*** Include directory $dir does not exist.])
 346   fi
 347 done
 348 IFS=$ac_save_IFS
 349 AC_SUBST(INCLUDES)
 350
 351
 352 #
 353 # Library directories
 354 #
 355 ac_save_IFS=$IFS
 356 IFS="${IFS}${PATH_SEPARATOR}"
 357 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 358 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 359   if test -d "$dir"; then
 360     LIBDIRS="$LIBDIRS -L$dir"
 361   else
 362     AC_MSG_WARN([*** Library directory $dir does not exist.])
 363   fi
 364 done
 365 IFS=$ac_save_IFS
 366
 367 #
 368 # Enable thread-safe client libraries
 369 #
 370 AC_MSG_CHECKING([allow thread-safe client libraries])
 371 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 372 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 373 if test "$enable_thread_safety" = yes -o \
 374         "$enable_thread_safety_force" = yes; then
 375   enable_thread_safety="yes"    # for 'force'
 376   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 377           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 378 fi
 379 AC_MSG_RESULT([$enable_thread_safety])
 380 AC_SUBST(enable_thread_safety)
 381
 382 #
 383 # Optionally build Tcl modules (PL/Tcl)
 384 #
 385 AC_MSG_CHECKING([whether to build with Tcl])
 386 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 387 AC_MSG_RESULT([$with_tcl])
 388 AC_SUBST([with_tcl])
 389
 390 # We see if the path to the Tcl/Tk configuration scripts is specified.
 391 # This will override the use of tclsh to find the paths to search.
 392
 393 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 394
 395 #
 396 # Optionally build Perl modules (PL/Perl)
 397 #
 398 AC_MSG_CHECKING([whether to build Perl modules])
 399 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 400 AC_MSG_RESULT([$with_perl])
 401 AC_SUBST(with_perl)
 402
 403 #
 404 # Optionally build Python modules (PL/Python)
 405 #
 406 AC_MSG_CHECKING([whether to build Python modules])
 407 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 408 AC_MSG_RESULT([$with_python])
 409 AC_SUBST(with_python)
 410
 411 #
 412 # Kerberos 5
 413 #
 414 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 415 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 416 [
 417   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 418   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 419 ])
 420 AC_MSG_RESULT([$with_krb5])
 421 AC_SUBST(with_krb5)
 422
 423
 424 AC_SUBST(krb_srvtab)
 425
 426
 427 #
 428 # Kerberos configuration parameters
 429 #
 430 PGAC_ARG_REQ(with, krb-srvnam,
 431              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 432              [],
 433              [with_krb_srvnam="postgres"])
 434 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 435                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 436
 437
 438 #
 439 # PAM
 440 #
 441 AC_MSG_CHECKING([whether to build with PAM support])
 442 PGAC_ARG_BOOL(with, pam, no,
 443               [  --with-pam              build with PAM support],
 444               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 445 AC_MSG_RESULT([$with_pam])
 446 AC_SUBST(with_pam)
 447
 448
 449 #
 450 # Bonjour
 451 #
 452 AC_MSG_CHECKING([whether to build with Bonjour support])
 453 PGAC_ARG_BOOL(with, bonjour, no,
 454               [  --with-bonjour          build with Bonjour support],
 455               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 456 AC_MSG_RESULT([$with_bonjour])
 457 AC_SUBST(with_bonjour)
 458
 459
 460 #
 461 # OpenSSL
 462 #
 463 AC_MSG_CHECKING([whether to build with OpenSSL support])
 464 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 465               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 466 AC_MSG_RESULT([$with_openssl])
 467 AC_SUBST(with_openssl)
 468
 469
 470 #
 471 # Readline
 472 #
 473 PGAC_ARG_BOOL(with, readline, yes,
 474               [  --without-readline      do not use Readline])
 475 # readline on MinGW has problems with backslashes in psql and other bugs.
 476 # This is particularly a problem with non-US code pages.
 477 # Therefore disable its use until we understand the cause. 2004-07-20
 478 if test "$PORTNAME" = "win32"; then
 479   if test "$with_readline" = yes; then
 480     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 481     with_readline=no
 482   fi
 483 fi
 484
 485
 486 #
 487 # Zlib
 488 #
 489 PGAC_ARG_BOOL(with, zlib, yes,
 490               [  --without-zlib          do not use Zlib])
 491 AC_SUBST(with_zlib)
 492
 493 #
 494 # Elf
 495 #
 496
 497 # Assume system is ELF if it predefines __ELF__ as 1,
 498 # otherwise believe host_os based default.
 499 case $host_os in
 500     freebsd1*|freebsd2*) elf=no;;
 501     freebsd3*|freebsd4*) elf=yes;;
 502 esac
 503
 504 AC_EGREP_CPP(yes,
 505 [#if __ELF__
 506   yes
 507 #endif
 508 ],
 509 [ELF_SYS=true],
 510 [if test "X$elf" = "Xyes" ; then
 511   ELF_SYS=true
 512 else
 513   ELF_SYS=
 514 fi])
 515 AC_SUBST(ELF_SYS)
 516
 517 #
 518 # Assignments
 519 #
 520
 521 CPPFLAGS="$CPPFLAGS $INCLUDES"
 522 LDFLAGS="$LDFLAGS $LIBDIRS"
 523
 524 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 525 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 526
 527 AC_ARG_VAR(LDFLAGS_SL)
 528
 529 AC_PROG_AWK
 530 PGAC_PATH_FLEX
 531 AC_PROG_LN_S
 532 PGAC_PROG_LD
 533 AC_SUBST(LD)
 534 AC_SUBST(with_gnu_ld)
 535 case $host_os in sysv5*)
 536   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 537   [
 538     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 539     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 540     LDFLAGS=$pgac_save_LDFLAGS
 541   ])
 542   ld_R_works=$pgac_cv_prog_ld_R
 543   AC_SUBST(ld_R_works)
 544 esac
 545 AC_PROG_RANLIB
 546 AC_CHECK_PROGS(LORDER, lorder)
 547 AC_PATH_PROG(TAR, tar)
 548 PGAC_CHECK_STRIP
 549
 550 AC_CHECK_PROGS(YACC, ['bison -y'])
 551
 552 if test "$YACC"; then
 553   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 554     AC_MSG_WARN([
 555 *** If you are going to modify the grammar files or build from CVS, the installed
 556 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 557   fi
 558 fi
 559
 560 if test -z "$YACC"; then
 561   AC_MSG_WARN([
 562 *** Without Bison you will not be able to build PostgreSQL from CVS or
 563 *** change any of the parser definition files.  You can obtain Bison from
 564 *** a GNU mirror site.  (If you are using the official distribution of
 565 *** PostgreSQL then you do not need to worry about this because the Bison
 566 *** output is pre-generated.)  To use a different yacc program (possible,
 567 *** but not recommended), set the environment variable YACC before running
 568 *** 'configure'.])
 569 fi
 570 AC_SUBST(YFLAGS)
 571
 572 PGAC_PATH_PERL
 573 if test "$with_perl" = yes; then
 574   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 575   PGAC_CHECK_PERL_EMBED_LDFLAGS
 576 fi
 577
 578 if test "$with_python" = yes; then
 579   PGAC_PATH_PYTHON
 580   PGAC_CHECK_PYTHON_EMBED_SETUP
 581 fi
 582
 583
 584 ##
 585 ## Libraries
 586 ##
 587
 588 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 589 then
 590         AC_CHECK_LIB(bsd,      main)
 591 fi
 592 AC_CHECK_LIB(util,     setproctitle)
 593 AC_CHECK_LIB(m,        main)
 594 AC_CHECK_LIB(dl,       main)
 595 AC_CHECK_LIB(nsl,      main)
 596 AC_CHECK_LIB(socket,   main)
 597 AC_CHECK_LIB(ipc,      main)
 598 AC_CHECK_LIB(IPC,      main)
 599 AC_CHECK_LIB(lc,       main)
 600 AC_CHECK_LIB(dld,      main)
 601 AC_CHECK_LIB(ld,       main)
 602 AC_CHECK_LIB(compat,   main)
 603 AC_CHECK_LIB(BSD,      main)
 604 AC_CHECK_LIB(gen,      main)
 605 AC_CHECK_LIB(PW,       main)
 606 AC_CHECK_LIB(resolv,   main)
 607 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 608 # QNX:
 609 AC_CHECK_LIB(unix, main)
 610 AC_SEARCH_LIBS(crypt,  crypt)
 611 # BeOS:
 612 if test "$PORTNAME" = "beos"
 613 then
 614         AC_CHECK_LIB(bind, __inet_ntoa)
 615 fi
 616 # Solaris:
 617 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 618 # Cygwin:
 619 AC_CHECK_LIB(cygipc, shmget)
 620 # WIN32:
 621 if test "$PORTNAME" = "win32"
 622 then
 623         AC_CHECK_LIB(wsock32, main)
 624 fi
 625
 626 if test "$with_readline" = yes; then
 627   PGAC_CHECK_READLINE
 628   if test x"$pgac_cv_check_readline" = x"no"; then
 629     AC_MSG_ERROR([readline library not found
 630 If you have readline already installed, see config.log for details on the
 631 failure.  It is possible the compiler isn't looking in the proper directory.
 632 Use --without-readline to disable readline support.])
 633   fi
 634 fi
 635
 636 if test "$with_zlib" = yes; then
 637   AC_CHECK_LIB(z, inflate, [],
 638                [AC_MSG_ERROR([zlib library not found
 639 If you have zlib already installed, see config.log for details on the
 640 failure.  It is possible the compiler isn't looking in the proper directory.
 641 Use --without-zlib to disable zlib support.])])
 642 fi
 643
 644 if test "$enable_spinlocks" = yes; then
 645   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 646 else
 647   AC_MSG_WARN([
 648 *** Not using spinlocks will cause poor performance.])
 649 fi
 650
 651 if test "$with_krb5" = yes ; then
 652   if test "$PORTNAME" != "win32"; then
 653      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 654                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 655      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 656                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 657      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 658                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 659   else
 660      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 661                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 662   fi
 663 fi
 664
 665 if test "$with_openssl" = yes ; then
 666   dnl Order matters!
 667   if test "$PORTNAME" != "win32"; then
 668      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 669      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 670   else
 671      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 672      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 673   fi
 674 fi
 675
 676 if test "$with_pam" = yes ; then
 677   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 678 fi
 679
 680
 681 ##
 682 ## Header files
 683 ##
 684
 685 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 686 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 687
 688 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 689 # netinet/in.h is included first.
 690 AC_CHECK_HEADERS(netinet/in.h)
 691 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 692 [AC_INCLUDES_DEFAULT
 693 #ifdef HAVE_NETINET_IN_H
 694 #include <netinet/in.h>
 695 #endif
 696 ])
 697
 698 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 699   AC_CHECK_HEADERS(readline/readline.h, [],
 700         [AC_CHECK_HEADERS(readline.h, [],
 701                 [AC_MSG_ERROR([readline header not found
 702 If you have readline already installed, see config.log for details on the
 703 failure.  It is possible the compiler isn't looking in the proper directory.
 704 Use --without-readline to disable readline support.])])])
 705   AC_CHECK_HEADERS(readline/history.h, [],
 706         [AC_CHECK_HEADERS(history.h, [],
 707                 [AC_MSG_ERROR([history header not found
 708 If you have readline already installed, see config.log for details on the
 709 failure.  It is possible the compiler isn't looking in the proper directory.
 710 Use --without-readline to disable readline support.])])])
 711 fi
 712
 713 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 714 # Some installations of libedit usurp /usr/include/readline/, which seems
 715 # bad practice, since in combined installations readline will have its headers
 716 # there.  We might have to resort to AC_EGREP checks to make sure we found
 717 # the proper header...
 718   AC_CHECK_HEADERS(editline/readline.h, [],
 719         [AC_CHECK_HEADERS(readline.h, [],
 720                 [AC_CHECK_HEADERS(readline/readline.h, [],
 721                         [AC_MSG_ERROR([readline header not found
 722 If you have libedit already installed, see config.log for details on the
 723 failure.  It is possible the compiler isn't looking in the proper directory.
 724 Use --without-readline to disable libedit support.])])])])
 725   AC_CHECK_HEADERS(editline/history.h, [],
 726         [AC_CHECK_HEADERS(history.h, [],
 727                 [AC_CHECK_HEADERS(readline/history.h, [],
 728                         [AC_MSG_ERROR([history header not found
 729 If you have libedit already installed, see config.log for details on the
 730 failure.  It is possible the compiler isn't looking in the proper directory.
 731 Use --without-readline to disable libedit support.])])])])
 732 fi
 733
 734 if test "$with_zlib" = yes; then
 735   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 736 If you have zlib already installed, see config.log for details on the
 737 failure.  It is possible the compiler isn't looking in the proper directory.
 738 Use --without-zlib to disable zlib support.])])
 739 fi
 740
 741 if test "$with_krb5" = yes ; then
 742   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 743 fi
 744
 745 if test "$with_openssl" = yes ; then
 746   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 747   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 748 fi
 749
 750 if test "$with_pam" = yes ; then
 751   AC_CHECK_HEADERS(security/pam_appl.h, [],
 752                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 753                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 754 fi
 755
 756 if test "$with_bonjour" = yes ; then
 757   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 758 fi
 759
 760
 761 ##
 762 ## Types, structures, compiler characteristics
 763 ##
 764
 765 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 766 AC_C_CONST
 767 AC_C_INLINE
 768 AC_C_STRINGIZE
 769 PGAC_C_SIGNED
 770 AC_C_VOLATILE
 771 PGAC_C_FUNCNAME_SUPPORT
 772 PGAC_STRUCT_TIMEZONE
 773 PGAC_UNION_SEMUN
 774 PGAC_STRUCT_SOCKADDR_UN
 775 PGAC_STRUCT_SOCKADDR_STORAGE
 776 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 777 PGAC_STRUCT_ADDRINFO
 778
 779 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 780 [#include <sys/param.h>
 781 #include <sys/types.h>
 782 #include <sys/socket.h>
 783 #include <sys/ucred.h>])
 784
 785 AC_CHECK_TYPES([struct option], [], [],
 786 [#ifdef HAVE_GETOPT_H
 787 #include <getopt.h>
 788 #endif])
 789
 790 if test "$with_zlib" = yes; then
 791   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 792   # did not).  While we could work around the lack of z_streamp, it
 793   # seems unwise to encourage people to use such old zlib versions...
 794   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 795 Use --without-zlib to disable zlib support.])],
 796                 [#include <zlib.h>])
 797 fi
 798
 799 if test "$with_krb5" = yes; then
 800 # Check for differences between MIT and Heimdal (KTH) releases
 801   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 802                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 803                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 804                                      [#include <krb5.h>])],
 805                    [#include <krb5.h>])
 806   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 807                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 808                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 809                                      [#include <krb5.h>])],
 810                    [#include <krb5.h>])
 811 fi
 812
 813 ##
 814 ## Functions, global variables
 815 ##
 816
 817 PGAC_VAR_INT_TIMEZONE
 818 AC_FUNC_ACCEPT_ARGTYPES
 819 PGAC_FUNC_GETTIMEOFDAY_1ARG
 820
 821 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 822
 823 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 824
 825 HAVE_IPV6=no
 826 AC_CHECK_TYPE([struct sockaddr_in6],
 827         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 828          HAVE_IPV6=yes],
 829         [],
 830 [$ac_includes_default
 831 #include <netinet/in.h>])
 832 AC_SUBST(HAVE_IPV6)
 833
 834 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 835 [AC_TRY_LINK(
 836 [#include <machine/vmparam.h>
 837 #include <sys/exec.h>
 838 ],
 839 [PS_STRINGS->ps_nargvstr = 1;
 840 PS_STRINGS->ps_argvstr = "foo";],
 841 [pgac_cv_var_PS_STRINGS=yes],
 842 [pgac_cv_var_PS_STRINGS=no])])
 843 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 844   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 845 fi
 846
 847
 848 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 849 # is missing.  Yes, there are machines that have only one.  We may
 850 # also decide to use snprintf.c if snprintf() is present but does not
 851 # have all the features we need --- see below.
 852
 853 pgac_need_repl_snprintf=no
 854 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 855 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 856
 857
 858 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 859 # include/c.h will provide declarations.  Note this is a separate test
 860 # from whether the functions exist in the C library --- there are
 861 # systems that have the functions but don't bother to declare them :-(
 862
 863 AC_CHECK_DECLS([snprintf, vsnprintf])
 864
 865
 866 # do this one the hard way in case isinf() is a macro
 867 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 868 [AC_TRY_LINK(
 869 [#include <math.h>
 870 ],
 871 [double x = 0.0; int res = isinf(x);],
 872 [ac_cv_func_isinf=yes],
 873 [ac_cv_func_isinf=no])])
 874
 875 if test $ac_cv_func_isinf = yes ; then
 876   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 877 else
 878   AC_LIBOBJ(isinf)
 879   # Look for a way to implement a substitute for isinf()
 880   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 881 fi
 882
 883 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 884
 885 # System's version of getaddrinfo(), if any, may be used only if we found
 886 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 887 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 888 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 889 # because we want to use our own getaddrinfo.c on Windows anyway.)
 890 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 891   AC_REPLACE_FUNCS([getaddrinfo])
 892 else
 893   AC_LIBOBJ(getaddrinfo)
 894 fi
 895
 896 # similarly, use system's getopt_long() only if system provides struct option.
 897 if test x"$ac_cv_type_struct_option" = xyes ; then
 898   AC_REPLACE_FUNCS([getopt_long])
 899 else
 900   AC_LIBOBJ(getopt_long)
 901 fi
 902
 903 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 904 # We override the previous test that said fseeko/ftello didn't exist
 905 # OS tests are also done in include/c.h and port/fseeko.c
 906 case $host_os in bsdi*|netbsd*)
 907 ac_cv_func_fseeko=yes
 908 esac
 909
 910 # Solaris has a very slow qsort in certain cases, so we replace it.
 911 if test "$PORTNAME" = "solaris"; then
 912 AC_LIBOBJ(qsort)
 913 fi
 914
 915 # Win32 support
 916 if test "$PORTNAME" = "win32"; then
 917 AC_LIBOBJ(gettimeofday)
 918 AC_LIBOBJ(kill)
 919 AC_LIBOBJ(open)
 920 AC_LIBOBJ(rand)
 921 AC_DEFINE([HAVE_SYMLINK], 1,
 922           [Define to 1 if you have the `symlink' function.])
 923 fi
 924
 925 if test "$with_readline" = yes; then
 926   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 927   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 928   AC_CHECK_FUNCS([replace_history_entry])
 929 fi
 930
 931
 932 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 933 AC_MSG_CHECKING(for finite)
 934 AC_TRY_LINK([#include <math.h>],
 935             [int dummy=finite(1.0);],
 936             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 937 AC_MSG_RESULT(yes)],
 938             [AC_MSG_RESULT(no)])
 939
 940 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 941 dnl (especially on GNU libc)
 942 dnl See also comments in c.h.
 943 AC_MSG_CHECKING(for sigsetjmp)
 944 AC_TRY_LINK([#include <setjmp.h>],
 945             [sigjmp_buf x; sigsetjmp(x, 1);],
 946             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 947 AC_MSG_RESULT(yes)],
 948             [AC_MSG_RESULT(no)])
 949
 950 AC_CHECK_FUNC(syslog,
 951               [AC_CHECK_HEADER(syslog.h,
 952                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 953
 954 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 955 [AC_TRY_LINK([#include <unistd.h>],
 956   [extern int optreset; optreset = 1;],
 957   [pgac_cv_var_int_optreset=yes],
 958   [pgac_cv_var_int_optreset=no])])
 959 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 960   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 961 fi
 962
 963 AC_CHECK_FUNCS([strtoll strtoq], [break])
 964 AC_CHECK_FUNCS([strtoull strtouq], [break])
 965
 966 # Check for one of atexit() or on_exit()
 967 AC_CHECK_FUNCS(atexit, [],
 968                [AC_CHECK_FUNCS(on_exit, [],
 969                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 970
 971 AC_FUNC_FSEEKO
 972
 973 #
 974 # Pthreads
 975 #
 976 # For each platform, we need to know about any special compile and link
 977 # libraries, and whether the normal C function names are thread-safe.
 978 # See the comment at the top of src/port/thread.c for more information.
 979 #
 980 if test "$enable_thread_safety" = yes; then
 981 ACX_PTHREAD     # set thread flags
 982
 983 # Some platforms use these, so just defineed them.  They can't hurt if they
 984 # are not supported.
 985 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 986
 987
 988 # At this point, we don't want to muck with the compiler name for threading.
 989 # Let's see who fails, perhaps AIX.  2004-04-23
 990 if test "$PTHREAD_CC" != "$CC"; then
 991 AC_MSG_ERROR([
 992 PostgreSQL does not support platforms that require a special
 993 compiler binary for thread-safety.
 994 ])
 995 fi
 996
 997 if test "$THREAD_SUPPORT" = no; then
 998 AC_MSG_ERROR([
 999 Cannot enable threads on your platform.
1000 Your platform is known to not support thread-safe programs.
1001 For details, compile and run src/bin/pg_thread_test.
1002 ])
1003 fi
1004
1005 # Check for *_r functions
1006 _CFLAGS="$CFLAGS"
1007 _LIBS="$LIBS"
1008 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1009 LIBS="$LIBS $PTHREAD_LIBS"
1010
1011 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1012
1013 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1014
1015 # Do test here with the proper thread flags
1016 PGAC_FUNC_GETPWUID_R_5ARG
1017 PGAC_FUNC_STRERROR_R_INT
1018
1019 CFLAGS="$_CFLAGS"
1020 LIBS="$_LIBS"
1021
1022 else
1023 # do not use values from template file
1024 PTHREAD_CFLAGS=
1025 PTHREAD_LIBS=
1026 fi
1027
1028 AC_SUBST(PTHREAD_CFLAGS)
1029 AC_SUBST(PTHREAD_LIBS)
1030
1031
1032 # This test makes sure that run tests work at all.  Sometimes a shared
1033 # library is found by the linker, but the runtime linker can't find it.
1034 # This check should come after all modifications of compiler or linker
1035 # variables, and before any other run tests.
1036 AC_MSG_CHECKING([test program])
1037 AC_TRY_RUN([int main() { return 0; }],
1038 [AC_MSG_RESULT(ok)],
1039 [AC_MSG_RESULT(failed)
1040 AC_MSG_ERROR([[
1041 *** Could not execute a simple test program.  This may be a problem
1042 *** related to locating shared libraries.  Check the file 'config.log'
1043 *** for the exact reason.]])],
1044 [AC_MSG_RESULT([cross-compiling])])
1045
1046
1047 # Force use of our snprintf if system's doesn't do arg control
1048 # This feature is used by NLS
1049 if test "$enable_nls" = yes &&
1050    test $pgac_need_repl_snprintf = no &&
1051 # On Win32, libintl replaces snprintf() with its own version that
1052 # understands arg control, so we don't need our own.  In fact, it
1053 # also uses macros that conflict with ours, so we _can't_ use
1054 # our own.
1055    test "$PORTNAME" != "win32"; then
1056   PGAC_FUNC_PRINTF_ARG_CONTROL
1057   if test $pgac_cv_printf_arg_control != yes ; then
1058     pgac_need_repl_snprintf=yes
1059   fi
1060 fi
1061
1062
1063 dnl Check to see if we have a working 64-bit integer type.
1064 dnl This breaks down into two steps:
1065 dnl (1) figure out if the compiler has a 64-bit int type with working
1066 dnl arithmetic, and if so
1067 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1068 dnl snprintf is the only library routine we really need for int8 support.)
1069 dnl It's entirely possible to have a compiler that handles a 64-bit type
1070 dnl when the C library doesn't; this is fairly likely when using gcc on
1071 dnl an older platform, for example.
1072 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1073 dnl we force our own version of snprintf() to be used instead.
1074 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1075
1076 PGAC_TYPE_64BIT_INT([long int])
1077
1078 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1079   PGAC_TYPE_64BIT_INT([long long int])
1080 fi
1081
1082
1083 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1084
1085 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1086   AC_TRY_COMPILE([
1087 #define INT64CONST(x)  x##LL
1088 long long int foo = INT64CONST(0x1234567890123456);
1089 ],
1090         [],
1091         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1092         [])
1093 fi
1094
1095
1096 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1097 # we found we need to use "long long int", better check.  We cope with
1098 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1099 # work, fall back to our own snprintf emulation (which we know uses %lld).
1100
1101 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1102   if test $pgac_need_repl_snprintf = no; then
1103     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1104     if test "$LONG_LONG_INT_FORMAT" = ""; then
1105       # Force usage of our own snprintf, since system snprintf is broken
1106       pgac_need_repl_snprintf=yes
1107       LONG_LONG_INT_FORMAT='%lld'
1108     fi
1109   else
1110     # Here if we previously decided we needed to use our own snprintf
1111     LONG_LONG_INT_FORMAT='%lld'
1112   fi
1113   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1114   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1115   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1116 else
1117   # Here if we are not using 'long long int' at all
1118   INT64_FORMAT='"%ld"'
1119   UINT64_FORMAT='"%lu"'
1120 fi
1121
1122 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1123                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1124
1125 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1126                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1127
1128 # Now we have checked all the reasons to replace snprintf
1129 if test $pgac_need_repl_snprintf = yes; then
1130   AC_DEFINE(USE_SNPRINTF, 1, [Use replacement snprintf() functions.])
1131   AC_LIBOBJ(snprintf)
1132 fi
1133
1134 # Need a #define for the size of Datum (unsigned long)
1135 AC_CHECK_SIZEOF([unsigned long])
1136
1137 # And one for the size of size_t (enables tweaks for > 32bit address space)
1138 AC_CHECK_SIZEOF([size_t])
1139
1140 # Determine memory alignment requirements for the basic C data types.
1141
1142 PGAC_CHECK_ALIGNOF(short)
1143 PGAC_CHECK_ALIGNOF(int)
1144 PGAC_CHECK_ALIGNOF(long)
1145 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1146   PGAC_CHECK_ALIGNOF(long long int)
1147 fi
1148 PGAC_CHECK_ALIGNOF(double)
1149
1150 # Compute maximum alignment of any basic type.
1151 # We assume long's alignment is at least as strong as char, short, or int;
1152 # but we must check long long (if it exists) and double.
1153
1154 MAX_ALIGNOF=$pgac_cv_alignof_long
1155 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1156   MAX_ALIGNOF=$pgac_cv_alignof_double
1157 fi
1158 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1159   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1160 fi
1161 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1162
1163
1164 # Some platforms predefine the types int8, int16, etc.  Only check
1165 # a (hopefully) representative subset.
1166 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1167 [#include <stdio.h>
1168 #ifdef HAVE_SUPPORTDEFS_H
1169 #include <SupportDefs.h>
1170 #endif])
1171
1172 # We also check for sig_atomic_t, which *should* be defined per ANSI
1173 # C, but is missing on some old platforms.
1174 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1175
1176
1177 if test x"$template" != x"win32"
1178 then
1179 PGAC_FUNC_POSIX_SIGNALS
1180 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1181   AC_MSG_ERROR([
1182 *** Thread-safety requires POSIX signals, which are not supported by your
1183 *** operating system.
1184 ])
1185 fi
1186 fi
1187
1188 if test $ac_cv_func_fseeko = yes; then
1189 AC_SYS_LARGEFILE
1190 fi
1191
1192 # SunOS doesn't handle negative byte comparisons properly with +/- return
1193 AC_FUNC_MEMCMP
1194
1195
1196 # Select semaphore implementation type.
1197 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1198   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1199   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1200 else
1201   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1202     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1203     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1204   else
1205     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1206     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1207   fi
1208 fi
1209
1210
1211 # Select shared-memory implementation type.
1212 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1213 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1214
1215
1216 if test "$enable_nls" = yes ; then
1217   PGAC_CHECK_GETTEXT
1218 fi
1219
1220 # Check for Tcl configuration script tclConfig.sh
1221 if test "$with_tcl" = yes; then
1222     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1223     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1224                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1225     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1226     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1227     ac_save_CPPFLAGS=$CPPFLAGS
1228     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1229     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1230     CPPFLAGS=$ac_save_CPPFLAGS
1231 fi
1232
1233 #
1234 # Check for DocBook and tools
1235 #
1236 PGAC_PROG_NSGMLS
1237 PGAC_PROG_JADE
1238 PGAC_CHECK_DOCBOOK(4.2)
1239 PGAC_PATH_DOCBOOK_STYLESHEETS
1240 PGAC_PATH_COLLATEINDEX
1241 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1242
1243 # Thread testing
1244
1245 # We have to run the thread test near the end so we have all our symbols
1246 # defined.  Cross compiling throws a warning.
1247 #
1248 if test "$enable_thread_safety_force" = yes; then
1249 if test x"$template" != x"win32"
1250 then
1251   AC_MSG_WARN([
1252 *** Skipping thread test program.  --enable-thread-safety-force was used.
1253 *** Run the program in src/tools/thread on the your machine and add
1254 proper locking function calls to your applications to guarantee thread
1255 safety.
1256 ])
1257 else
1258 AC_MSG_WARN([*** Skipping thread test on Win32])
1259 fi
1260 elif test "$enable_thread_safety" = yes; then
1261 if test x"$template" != x"win32"
1262 then
1263 AC_MSG_CHECKING([thread safety of required library functions])
1264
1265 _CFLAGS="$CFLAGS"
1266 _LIBS="$LIBS"
1267 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1268 LIBS="$LIBS $PTHREAD_LIBS"
1269 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1270   [AC_MSG_RESULT(yes)],
1271   [AC_MSG_RESULT(no)
1272   AC_MSG_ERROR([
1273 *** Thread test program failed.  Your platform is not thread-safe.
1274 *** Check the file 'config.log'for the exact reason.
1275 ***
1276 *** You can use the configure option --enable-thread-safety-force
1277 *** to force threads to be enabled.  However, you must then run
1278 *** the program in src/tools/thread and add locking function calls
1279 *** to your applications to guarantee thread safety.
1280 ])],
1281   [AC_MSG_RESULT(maybe)
1282   AC_MSG_WARN([
1283 *** Skipping thread test program because of cross-compile build.
1284 *** Run the program in src/tools/thread on the target machine.
1285 ])])
1286 CFLAGS="$_CFLAGS"
1287 LIBS="$_LIBS"
1288 else
1289 AC_MSG_WARN([*** Skipping thread test on Win32])
1290 fi
1291 fi
1292
1293 # prepare build tree if outside source tree
1294 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1295 # Note 2: /bin/pwd might be better than shell's built-in at getting
1296 #         a symlink-free name.
1297 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1298   vpath_build=no
1299 else
1300   vpath_build=yes
1301   if test "$no_create" != yes; then
1302     _AS_ECHO_N([preparing build tree... ])
1303     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1304     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1305       || AC_MSG_ERROR(failed)
1306     AC_MSG_RESULT(done)
1307   fi
1308 fi
1309 AC_SUBST(vpath_build)
1310
1311
1312 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1313
1314 AC_CONFIG_LINKS([
1315   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1316   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1317   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1318   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1319   src/include/pg_config_os.h:src/include/port/${template}.h
1320   src/Makefile.port:src/makefiles/Makefile.${template}
1321 ])
1322
1323 if test "$PORTNAME" = "win32"; then
1324 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1325 # Links sometimes fail undetected on Mingw -
1326 # so here we detect it and warn the user
1327 for FILE in $CONFIG_LINKS
1328  do
1329         # test -e works for symlinks in the MinGW console
1330         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1331  done
1332 ])
1333 fi
1334
1335 AC_CONFIG_HEADERS([src/include/pg_config.h],
1336 [
1337 # Update timestamp for pg_config.h (see Makefile.global)
1338 echo >src/include/stamp-h
1339 ])
1340
1341 AC_OUTPUT
1342