granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.6devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2015, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sysv5*) template=unixware ;;
  75 esac
  76
  77   if test x"$template" = x"" ; then
  78     AC_MSG_ERROR([[
  79 *******************************************************************
  80 PostgreSQL has apparently not been ported to your platform yet.
  81 To try a manual configuration, look into the src/template directory
  82 for a similar platform and use the '--with-template=' option.
  83
  84 Please also contact <pgsql-bugs@postgresql.org> to see about
  85 rectifying this.  Include the above 'checking host system type...'
  86 line.
  87 *******************************************************************
  88 ]])
  89   fi
  90
  91 ])
  92
  93 AC_MSG_RESULT([$template])
  94
  95 PORTNAME=$template
  96 AC_SUBST(PORTNAME)
  97
  98 # Initialize default assumption that we do not need separate assembly code
  99 # for TAS (test-and-set).  This can be overridden by the template file
 100 # when it's executed.
 101 need_tas=no
 102 tas_file=dummy.s
 103
 104
 105
 106 ##
 107 ## Command line options
 108 ##
 109
 110 #
 111 # Add non-standard directories to the include path
 112 #
 113 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 114
 115
 116 #
 117 # Add non-standard directories to the library search path
 118 #
 119 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 120              [LIBRARY_DIRS=$withval])
 121
 122 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 123              [LIBRARY_DIRS=$withval])
 124
 125
 126 #
 127 # 64-bit integer date/time storage: enabled by default.
 128 #
 129 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 130 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 131               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 132                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 133 AC_MSG_RESULT([$enable_integer_datetimes])
 134
 135
 136 #
 137 # NLS
 138 #
 139 AC_MSG_CHECKING([whether NLS is wanted])
 140 PGAC_ARG_OPTARG(enable, nls,
 141                 [LANGUAGES], [enable Native Language Support],
 142                 [],
 143                 [WANTED_LANGUAGES=$enableval],
 144                 [AC_DEFINE(ENABLE_NLS, 1,
 145                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 146 AC_MSG_RESULT([$enable_nls])
 147 AC_SUBST(enable_nls)
 148 AC_SUBST(WANTED_LANGUAGES)
 149
 150 #
 151 # Default port number (--with-pgport), default 5432
 152 #
 153 AC_MSG_CHECKING([for default port number])
 154 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 155              [default_port=$withval],
 156              [default_port=5432])
 157 AC_MSG_RESULT([$default_port])
 158 # Need both of these because some places want an integer and some a string
 159 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 160 [Define to the default TCP port number on which the server listens and
 161 to which clients will try to connect.  This can be overridden at run-time,
 162 but it's convenient if your clients have the right default compiled in.
 163 (--with-pgport=PORTNUM)])
 164 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 165                    [Define to the default TCP port number as a string constant.])
 166 AC_SUBST(default_port)
 167
 168 #
 169 # '-rpath'-like feature can be disabled
 170 #
 171 PGAC_ARG_BOOL(enable, rpath, yes,
 172               [do not embed shared library search path in executables])
 173 AC_SUBST(enable_rpath)
 174
 175 #
 176 # Spinlocks
 177 #
 178 PGAC_ARG_BOOL(enable, spinlocks, yes,
 179               [do not use spinlocks])
 180
 181 #
 182 # Atomic operations
 183 #
 184 PGAC_ARG_BOOL(enable, atomics, yes,
 185               [do not use atomic operations])
 186
 187 #
 188 # --enable-debug adds -g to compiler flags
 189 #
 190 PGAC_ARG_BOOL(enable, debug, no,
 191               [build with debugging symbols (-g)])
 192 AC_SUBST(enable_debug)
 193
 194 #
 195 # --enable-profiling enables gcc profiling
 196 #
 197 PGAC_ARG_BOOL(enable, profiling, no,
 198               [build with profiling enabled ])
 199
 200 #
 201 # --enable-coverage enables generation of code coverage metrics with gcov
 202 #
 203 PGAC_ARG_BOOL(enable, coverage, no,
 204               [build with coverage testing instrumentation],
 205 [AC_CHECK_PROGS(GCOV, gcov)
 206 if test -z "$GCOV"; then
 207   AC_MSG_ERROR([gcov not found])
 208 fi
 209 AC_CHECK_PROGS(LCOV, lcov)
 210 if test -z "$LCOV"; then
 211   AC_MSG_ERROR([lcov not found])
 212 fi
 213 AC_CHECK_PROGS(GENHTML, genhtml)
 214 if test -z "$GENHTML"; then
 215   AC_MSG_ERROR([genhtml not found])
 216 fi])
 217 AC_SUBST(enable_coverage)
 218
 219 #
 220 # DTrace
 221 #
 222 PGAC_ARG_BOOL(enable, dtrace, no,
 223               [build with DTrace support],
 224 [AC_CHECK_PROGS(DTRACE, dtrace)
 225 if test -z "$DTRACE"; then
 226   AC_MSG_ERROR([dtrace not found])
 227 fi
 228 AC_SUBST(DTRACEFLAGS)])
 229 AC_SUBST(enable_dtrace)
 230
 231 #
 232 # TAP tests
 233 #
 234 PGAC_ARG_BOOL(enable, tap-tests, no,
 235               [enable TAP tests (requires Perl and IPC::Run)])
 236 AC_SUBST(enable_tap_tests)
 237
 238 #
 239 # Block size
 240 #
 241 AC_MSG_CHECKING([for block size])
 242 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 243              [blocksize=$withval],
 244              [blocksize=8])
 245 case ${blocksize} in
 246   1) BLCKSZ=1024;;
 247   2) BLCKSZ=2048;;
 248   4) BLCKSZ=4096;;
 249   8) BLCKSZ=8192;;
 250  16) BLCKSZ=16384;;
 251  32) BLCKSZ=32768;;
 252   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 253 esac
 254 AC_MSG_RESULT([${blocksize}kB])
 255
 256 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 257  Size of a disk block --- this also limits the size of a tuple.  You
 258  can set it bigger if you need bigger tuples (although TOAST should
 259  reduce the need to have large tuples, since fields can be spread
 260  across multiple tuples).
 261
 262  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 263  is currently 2^15 (32768).  This is determined by the 15-bit widths
 264  of the lp_off and lp_len fields in ItemIdData (see
 265  include/storage/itemid.h).
 266
 267  Changing BLCKSZ requires an initdb.
 268 ])
 269
 270 #
 271 # Relation segment size
 272 #
 273 AC_MSG_CHECKING([for segment size])
 274 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 275              [segsize=$withval],
 276              [segsize=1])
 277 # this expression is set up to avoid unnecessary integer overflow
 278 # blocksize is already guaranteed to be a factor of 1024
 279 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 280 test $? -eq 0 || exit 1
 281 AC_MSG_RESULT([${segsize}GB])
 282
 283 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 284  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 285  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 286  relations bigger than that are divided into multiple files.
 287
 288  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 289  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 290  have large file support enabled.  By default, we make the limit 1 GB
 291  to avoid any possible integer-overflow problems within the OS.
 292  A limit smaller than necessary only means we divide a large
 293  relation into more chunks than necessary, so it seems best to err
 294  in the direction of a small limit.
 295
 296  A power-of-2 value is recommended to save a few cycles in md.c,
 297  but is not absolutely required.
 298
 299  Changing RELSEG_SIZE requires an initdb.
 300 ])
 301
 302 #
 303 # WAL block size
 304 #
 305 AC_MSG_CHECKING([for WAL block size])
 306 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 307              [wal_blocksize=$withval],
 308              [wal_blocksize=8])
 309 case ${wal_blocksize} in
 310   1) XLOG_BLCKSZ=1024;;
 311   2) XLOG_BLCKSZ=2048;;
 312   4) XLOG_BLCKSZ=4096;;
 313   8) XLOG_BLCKSZ=8192;;
 314  16) XLOG_BLCKSZ=16384;;
 315  32) XLOG_BLCKSZ=32768;;
 316  64) XLOG_BLCKSZ=65536;;
 317   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 318 esac
 319 AC_MSG_RESULT([${wal_blocksize}kB])
 320
 321 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 322  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 323  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 324  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 325  buffers, else direct I/O may fail.
 326
 327  Changing XLOG_BLCKSZ requires an initdb.
 328 ])
 329
 330 #
 331 # WAL segment size
 332 #
 333 AC_MSG_CHECKING([for WAL segment size])
 334 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 335              [wal_segsize=$withval],
 336              [wal_segsize=16])
 337 case ${wal_segsize} in
 338   1) ;;
 339   2) ;;
 340   4) ;;
 341   8) ;;
 342  16) ;;
 343  32) ;;
 344  64) ;;
 345   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 346 esac
 347 AC_MSG_RESULT([${wal_segsize}MB])
 348
 349 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 350  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 351  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 352  XLOG_BLCKSZ).
 353
 354  Changing XLOG_SEG_SIZE requires an initdb.
 355 ])
 356
 357 #
 358 # C compiler
 359 #
 360
 361 # For historical reasons you can also use --with-CC to specify the C compiler
 362 # to use, although the standard way to do this is to set the CC environment
 363 # variable.
 364 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 365
 366 case $template in
 367   aix) pgac_cc_list="gcc xlc";;
 368     *) pgac_cc_list="gcc cc";;
 369 esac
 370
 371 AC_PROG_CC([$pgac_cc_list])
 372
 373 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 374 # but has idiosyncrasies of its own.  We assume icc will define
 375 # __INTEL_COMPILER regardless of CFLAGS.
 376 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 377 choke me
 378 @%:@endif])], [ICC=yes], [ICC=no])
 379
 380 # Check if it's Sun Studio compiler. We assume that
 381 # __SUNPRO_C will be defined for Sun Studio compilers
 382 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 383 choke me
 384 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 385
 386 AC_SUBST(SUN_STUDIO_CC)
 387
 388 unset CFLAGS
 389
 390 #
 391 # Read the template
 392 #
 393 . "$srcdir/src/template/$template" || exit
 394
 395 # CFLAGS are selected so:
 396 # If the user specifies something in the environment, that is used.
 397 # else:  If the template file set something, that is used.
 398 # else:  If coverage was enabled, don't set anything.
 399 # else:  If the compiler is GCC, then we use -O2.
 400 # else:  If the compiler is something else, then we use -O, unless debugging.
 401
 402 if test "$ac_env_CFLAGS_set" = set; then
 403   CFLAGS=$ac_env_CFLAGS_value
 404 elif test "${CFLAGS+set}" = set; then
 405   : # (keep what template set)
 406 elif test "$enable_coverage" = yes; then
 407   : # no optimization by default
 408 elif test "$GCC" = yes; then
 409   CFLAGS="-O2"
 410 else
 411   # if the user selected debug mode, don't use -O
 412   if test "$enable_debug" != yes; then
 413     CFLAGS="-O"
 414   fi
 415 fi
 416
 417 # CFLAGS we determined above will be added back at the end
 418 user_CFLAGS=$CFLAGS
 419 CFLAGS=""
 420
 421 # set CFLAGS_VECTOR from the environment, if available
 422 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 423   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 424 fi
 425
 426 # Some versions of GCC support some additional useful warning flags.
 427 # Check whether they are supported, and add them to CFLAGS if so.
 428 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 429 # but has its own.  Also check other compiler-specific flags here.
 430
 431 if test "$GCC" = yes -a "$ICC" = no; then
 432   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 433   # These work in some but not all gcc versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 435   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 436   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 437   # This was included in -Wall/-Wformat in older GCC versions
 438   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 439   # Disable strict-aliasing rules; needed for gcc 3.3+
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 442   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 443   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 444   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 445   # Optimization flags for specific files that benefit from vectorization
 446   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 447   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 448   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 449   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 450   # test for the positive form and if that works, add the negative form
 451   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 452   if test -n "$NOT_THE_CFLAGS"; then
 453     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 454   fi
 455 elif test "$ICC" = yes; then
 456   # Intel's compiler has a bug/misoptimization in checking for
 457   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 458   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 459   # Make sure strict aliasing is off (though this is said to be the default)
 460   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 461 elif test "$PORTNAME" = "aix"; then
 462   # AIX's xlc has to have strict aliasing turned off too
 463   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 464   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 465 elif test "$PORTNAME" = "hpux"; then
 466   # On some versions of HP-UX, libm functions do not set errno by default.
 467   # Fix that by using +Olibmerrno if the compiler recognizes it.
 468   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 469 fi
 470
 471 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 472
 473 # supply -g if --enable-debug
 474 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 475   CFLAGS="$CFLAGS -g"
 476 fi
 477
 478 # enable code coverage if --enable-coverage
 479 if test "$enable_coverage" = yes; then
 480   if test "$GCC" = yes; then
 481     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 482   else
 483     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 484   fi
 485 fi
 486
 487 # enable profiling if --enable-profiling
 488 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 489   if test "$GCC" = yes; then
 490     AC_DEFINE([PROFILE_PID_DIR], 1,
 491            [Define to 1 to allow profiling output to be saved separately for each process.])
 492     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 493   else
 494     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 495   fi
 496 fi
 497
 498 # We already have this in Makefile.win32, but configure needs it too
 499 if test "$PORTNAME" = "win32"; then
 500   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 501 fi
 502
 503 # Now that we're done automatically adding stuff to CFLAGS, put back the
 504 # user-specified flags (if any) at the end.  This lets users override
 505 # the automatic additions.
 506 CFLAGS="$CFLAGS $user_CFLAGS"
 507
 508 # Check if the compiler still works with the final flag settings
 509 AC_MSG_CHECKING([whether the C compiler still works])
 510 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 511   [AC_MSG_RESULT(yes)],
 512   [AC_MSG_RESULT(no)
 513    AC_MSG_ERROR([cannot proceed])])
 514
 515 # Defend against gcc -ffast-math
 516 if test "$GCC" = yes; then
 517 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 518 choke me
 519 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 520 fi
 521
 522 AC_PROG_CPP
 523 AC_SUBST(GCC)
 524
 525
 526 #
 527 # Set up TAS assembly code if needed; the template file has now had its
 528 # chance to request this.
 529 #
 530 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 531
 532 if test "$need_tas" = yes ; then
 533   TAS=tas.o
 534 else
 535   TAS=""
 536 fi
 537 AC_SUBST(TAS)
 538
 539
 540 #
 541 # Automatic dependency tracking
 542 #
 543 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 544               [autodepend=yes])
 545 AC_SUBST(autodepend)
 546
 547
 548 #
 549 # Enable assert checks
 550 #
 551 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 552               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 553                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 554
 555
 556 #
 557 # Include directories
 558 #
 559 ac_save_IFS=$IFS
 560 IFS="${IFS}${PATH_SEPARATOR}"
 561 # SRCH_INC comes from the template file
 562 for dir in $with_includes $SRCH_INC; do
 563   if test -d "$dir"; then
 564     INCLUDES="$INCLUDES -I$dir"
 565   else
 566     AC_MSG_WARN([*** Include directory $dir does not exist.])
 567   fi
 568 done
 569 IFS=$ac_save_IFS
 570 AC_SUBST(INCLUDES)
 571
 572
 573 #
 574 # Library directories
 575 #
 576 ac_save_IFS=$IFS
 577 IFS="${IFS}${PATH_SEPARATOR}"
 578 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 579 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 580   if test -d "$dir"; then
 581     LIBDIRS="$LIBDIRS -L$dir"
 582   else
 583     AC_MSG_WARN([*** Library directory $dir does not exist.])
 584   fi
 585 done
 586 IFS=$ac_save_IFS
 587
 588 #
 589 # Enable thread-safe client libraries
 590 #
 591 AC_MSG_CHECKING([allow thread-safe client libraries])
 592 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 593 if test "$enable_thread_safety" = yes; then
 594   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 595           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 596 fi
 597 AC_MSG_RESULT([$enable_thread_safety])
 598 AC_SUBST(enable_thread_safety)
 599
 600 #
 601 # Optionally build Tcl modules (PL/Tcl)
 602 #
 603 AC_MSG_CHECKING([whether to build with Tcl])
 604 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 605 AC_MSG_RESULT([$with_tcl])
 606 AC_SUBST([with_tcl])
 607
 608 # We see if the path to the Tcl/Tk configuration scripts is specified.
 609 # This will override the use of tclsh to find the paths to search.
 610
 611 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 612
 613 #
 614 # Optionally build Perl modules (PL/Perl)
 615 #
 616 AC_MSG_CHECKING([whether to build Perl modules])
 617 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 618 AC_MSG_RESULT([$with_perl])
 619 AC_SUBST(with_perl)
 620
 621 #
 622 # Optionally build Python modules (PL/Python)
 623 #
 624 AC_MSG_CHECKING([whether to build Python modules])
 625 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 626 AC_MSG_RESULT([$with_python])
 627 AC_SUBST(with_python)
 628
 629 #
 630 # GSSAPI
 631 #
 632 AC_MSG_CHECKING([whether to build with GSSAPI support])
 633 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 634 [
 635   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 636   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 637 ])
 638 AC_MSG_RESULT([$with_gssapi])
 639
 640
 641 AC_SUBST(krb_srvtab)
 642
 643
 644 #
 645 # Kerberos configuration parameters
 646 #
 647 PGAC_ARG_REQ(with, krb-srvnam,
 648              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 649              [],
 650              [with_krb_srvnam="postgres"])
 651 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 652                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 653
 654
 655 #
 656 # PAM
 657 #
 658 AC_MSG_CHECKING([whether to build with PAM support])
 659 PGAC_ARG_BOOL(with, pam, no,
 660               [build with PAM support],
 661               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 662 AC_MSG_RESULT([$with_pam])
 663
 664
 665 #
 666 # LDAP
 667 #
 668 AC_MSG_CHECKING([whether to build with LDAP support])
 669 PGAC_ARG_BOOL(with, ldap, no,
 670               [build with LDAP support],
 671               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 672 AC_MSG_RESULT([$with_ldap])
 673
 674
 675 #
 676 # Bonjour
 677 #
 678 AC_MSG_CHECKING([whether to build with Bonjour support])
 679 PGAC_ARG_BOOL(with, bonjour, no,
 680               [build with Bonjour support],
 681               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 682 AC_MSG_RESULT([$with_bonjour])
 683
 684
 685 #
 686 # OpenSSL
 687 #
 688 AC_MSG_CHECKING([whether to build with OpenSSL support])
 689 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 690               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 691 AC_MSG_RESULT([$with_openssl])
 692 AC_SUBST(with_openssl)
 693
 694 #
 695 # SELinux
 696 #
 697 AC_MSG_CHECKING([whether to build with SELinux support])
 698 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 699 AC_SUBST(with_selinux)
 700 AC_MSG_RESULT([$with_selinux])
 701
 702 #
 703 # Readline
 704 #
 705 PGAC_ARG_BOOL(with, readline, yes,
 706               [do not use GNU Readline nor BSD Libedit for editing])
 707 # readline on MinGW has problems with backslashes in psql and other bugs.
 708 # This is particularly a problem with non-US code pages.
 709 # Therefore disable its use until we understand the cause. 2004-07-20
 710 if test "$PORTNAME" = "win32"; then
 711   if test "$with_readline" = yes; then
 712     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 713     with_readline=no
 714   fi
 715 fi
 716
 717
 718 #
 719 # Prefer libedit
 720 #
 721 PGAC_ARG_BOOL(with, libedit-preferred, no,
 722               [prefer BSD Libedit over GNU Readline])
 723
 724
 725 #
 726 # UUID library
 727 #
 728 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 729 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 730 # UUID library.  More than one of these might be present on a given platform,
 731 # so we make the user say which one she wants.
 732 #
 733 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 734 if test x"$with_uuid" = x"" ; then
 735   with_uuid=no
 736 fi
 737 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 738 if test "$with_ossp_uuid" = yes ; then
 739   with_uuid=ossp
 740 fi
 741
 742 if test "$with_uuid" = bsd ; then
 743   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 744   UUID_EXTRA_OBJS="md5.o sha1.o"
 745 elif test "$with_uuid" = e2fs ; then
 746   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 747   UUID_EXTRA_OBJS="md5.o sha1.o"
 748 elif test "$with_uuid" = ossp ; then
 749   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 750   UUID_EXTRA_OBJS=""
 751 elif test "$with_uuid" = no ; then
 752   UUID_EXTRA_OBJS=""
 753 else
 754   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 755 fi
 756 AC_SUBST(with_uuid)
 757 AC_SUBST(UUID_EXTRA_OBJS)
 758
 759
 760 #
 761 # XML
 762 #
 763 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 764               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 765
 766 if test "$with_libxml" = yes ; then
 767   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 768   if test -n "$XML2_CONFIG"; then
 769     for pgac_option in `$XML2_CONFIG --cflags`; do
 770       case $pgac_option in
 771         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 772       esac
 773     done
 774     for pgac_option in `$XML2_CONFIG --libs`; do
 775       case $pgac_option in
 776         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 777       esac
 778     done
 779   fi
 780 fi
 781
 782 AC_SUBST(with_libxml)
 783
 784 #
 785 # XSLT
 786 #
 787 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 788               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 789
 790
 791 AC_SUBST(with_libxslt)
 792
 793 #
 794 # tzdata
 795 #
 796 PGAC_ARG_REQ(with, system-tzdata,
 797              [DIR], [use system time zone data in DIR])
 798 AC_SUBST(with_system_tzdata)
 799
 800 #
 801 # Zlib
 802 #
 803 PGAC_ARG_BOOL(with, zlib, yes,
 804               [do not use Zlib])
 805 AC_SUBST(with_zlib)
 806
 807 #
 808 # Elf
 809 #
 810
 811 # Assume system is ELF if it predefines __ELF__ as 1,
 812 # otherwise believe host_os based default.
 813 case $host_os in
 814     freebsd1*|freebsd2*) elf=no;;
 815     freebsd3*|freebsd4*) elf=yes;;
 816 esac
 817
 818 AC_EGREP_CPP(yes,
 819 [#if __ELF__
 820   yes
 821 #endif
 822 ],
 823 [ELF_SYS=true],
 824 [if test "X$elf" = "Xyes" ; then
 825   ELF_SYS=true
 826 else
 827   ELF_SYS=
 828 fi])
 829 AC_SUBST(ELF_SYS)
 830
 831 #
 832 # Assignments
 833 #
 834
 835 CPPFLAGS="$CPPFLAGS $INCLUDES"
 836 LDFLAGS="$LDFLAGS $LIBDIRS"
 837
 838 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 839 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 840
 841 PGAC_PROG_LD
 842 AC_SUBST(LD)
 843 AC_SUBST(with_gnu_ld)
 844 case $host_os in sysv5*)
 845   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 846   [
 847     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 848     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 849       [pgac_cv_prog_ld_R=yes],
 850       [pgac_cv_prog_ld_R=no])
 851     LDFLAGS=$pgac_save_LDFLAGS
 852   ])
 853   ld_R_works=$pgac_cv_prog_ld_R
 854   AC_SUBST(ld_R_works)
 855 esac
 856 AC_PROG_RANLIB
 857 PGAC_CHECK_STRIP
 858 AC_CHECK_TOOL(AR, ar, ar)
 859 if test "$PORTNAME" = "win32"; then
 860   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 861   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 862   AC_CHECK_TOOL(WINDRES, windres, windres)
 863 fi
 864
 865 AC_PROG_INSTALL
 866 # When Autoconf chooses install-sh as install program it tries to generate
 867 # a relative path to it in each makefile where it subsitutes it. This clashes
 868 # with our Makefile.global concept. This workaround helps.
 869 case $INSTALL in
 870   *install-sh*) install_bin='';;
 871   *) install_bin=$INSTALL;;
 872 esac
 873 AC_SUBST(install_bin)
 874
 875 AC_PATH_PROG(TAR, tar)
 876 AC_PROG_LN_S
 877 AC_PROG_AWK
 878 AC_PROG_MKDIR_P
 879 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 880 # a relative path to it in each makefile where it subsitutes it. This clashes
 881 # with our Makefile.global concept. This workaround helps.
 882 case $MKDIR_P in
 883   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 884 esac
 885
 886 PGAC_PATH_BISON
 887 PGAC_PATH_FLEX
 888
 889 PGAC_PATH_PERL
 890 if test "$with_perl" = yes; then
 891   if test -z "$PERL"; then
 892     AC_MSG_ERROR([Perl not found])
 893   fi
 894   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 895   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 896     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 897 You might have to rebuild your Perl installation.  Refer to the
 898 documentation for details.  Use --without-perl to disable building
 899 PL/Perl.])
 900   fi
 901   PGAC_CHECK_PERL_EMBED_LDFLAGS
 902 fi
 903
 904 if test "$with_python" = yes; then
 905   PGAC_PATH_PYTHON
 906   PGAC_CHECK_PYTHON_EMBED_SETUP
 907
 908   # We need libpython as a shared library.  With Python >=2.5, we
 909   # check the Py_ENABLE_SHARED setting.  On Debian, the setting is not
 910   # correct before the jessie release (http://bugs.debian.org/695979).
 911   # We also want to support older Python versions.  So as a fallback
 912   # we see if there is a file that is named like a shared library.
 913
 914   if test "$python_enable_shared" != 1; then
 915     if test "$PORTNAME" = darwin; then
 916       # OS X does supply a .dylib even though Py_ENABLE_SHARED does
 917       # not get set.  The file detection logic below doesn't succeed
 918       # on older OS X versions, so make it explicit.
 919       python_enable_shared=1
 920     elif test "$PORTNAME" = win32; then
 921       # Windows also needs an explicit override.
 922       python_enable_shared=1
 923     else
 924       # We don't know the platform shared library extension here yet,
 925       # so we try some candidates.
 926       for dlsuffix in .so .sl; do
 927         if ls "$python_libdir"/libpython*${dlsuffix}* >/dev/null 2>&1; then
 928           python_enable_shared=1
 929           break
 930         fi
 931       done
 932     fi
 933   fi
 934
 935   if test "$python_enable_shared" != 1; then
 936     AC_MSG_ERROR([cannot build PL/Python because libpython is not a shared library
 937 You might have to rebuild your Python installation.  Refer to the
 938 documentation for details.  Use --without-python to disable building
 939 PL/Python.])
 940   fi
 941 fi
 942
 943 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 944   AC_PATH_PROG(ZIC, zic)
 945   if test -z "$ZIC"; then
 946     AC_MSG_ERROR([
 947 When cross-compiling, either use the option --with-system-tzdata to use
 948 existing time-zone data, or set the environment variable ZIC to a zic
 949 program to use during the build.])
 950   fi
 951 fi
 952
 953 #
 954 # Pthreads
 955 #
 956 # For each platform, we need to know about any special compile and link
 957 # libraries, and whether the normal C function names are thread-safe.
 958 # See the comment at the top of src/port/thread.c for more information.
 959 # WIN32 doesn't need the pthread tests;  it always uses threads
 960 #
 961 # These tests are run before the library-tests, because linking with the
 962 # other libraries can pull in the pthread functions as a side-effect.  We
 963 # want to use the -pthread or similar flags directly, and not rely on
 964 # the side-effects of linking with some other library.
 965 #
 966 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 967 # invocation below is the first one in the script, and autoconf generates
 968 # additional code for that, which must not be inside the if-block. AS_IF
 969 # knows how to do that.
 970 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 971 [ # then
 972 AX_PTHREAD      # set thread flags
 973
 974 # Some platforms use these, so just define them.  They can't hurt if they
 975 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 976 # enables 5-arg getpwuid_r, among other things.
 977 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 978
 979 # Check for *_r functions
 980 _CFLAGS="$CFLAGS"
 981 _LIBS="$LIBS"
 982 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 983 LIBS="$LIBS $PTHREAD_LIBS"
 984
 985 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 986 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 987
 988 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 989
 990 # Do test here with the proper thread flags
 991 PGAC_FUNC_STRERROR_R_INT
 992
 993 CFLAGS="$_CFLAGS"
 994 LIBS="$_LIBS"
 995
 996 ], [ # else
 997 # do not use values from template file
 998 PTHREAD_CFLAGS=
 999 PTHREAD_LIBS=
1000 ]) # fi
1001
1002 AC_SUBST(PTHREAD_CFLAGS)
1003 AC_SUBST(PTHREAD_LIBS)
1004
1005
1006 ##
1007 ## Libraries
1008 ##
1009 ## Most libraries are included only if they demonstrably provide a function
1010 ## we need, but libm is an exception: always include it, because there are
1011 ## too many compilers that play cute optimization games that will break
1012 ## probes for standard functions such as pow().
1013 ##
1014
1015 AC_CHECK_LIB(m, main)
1016 AC_SEARCH_LIBS(setproctitle, util)
1017 AC_SEARCH_LIBS(dlopen, dl)
1018 AC_SEARCH_LIBS(socket, [socket ws2_32])
1019 AC_SEARCH_LIBS(shl_load, dld)
1020 # We only use libld in port/dynloader/aix.c
1021 case $host_os in
1022      aix*)
1023         AC_SEARCH_LIBS(ldopen, ld)
1024         ;;
1025 esac
1026 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1027 AC_SEARCH_LIBS(crypt, crypt)
1028 AC_SEARCH_LIBS(shm_open, rt)
1029 AC_SEARCH_LIBS(shm_unlink, rt)
1030 # Solaris:
1031 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1032 # Required for thread_test.c on Solaris
1033 AC_SEARCH_LIBS(sched_yield, rt)
1034 # Required for thread_test.c on Solaris 2.5:
1035 # Other ports use it too (HP-UX) so test unconditionally
1036 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1037 # Cygwin:
1038 AC_SEARCH_LIBS(shmget, cygipc)
1039
1040 if test "$with_readline" = yes; then
1041   PGAC_CHECK_READLINE
1042   if test x"$pgac_cv_check_readline" = x"no"; then
1043     AC_MSG_ERROR([readline library not found
1044 If you have readline already installed, see config.log for details on the
1045 failure.  It is possible the compiler isn't looking in the proper directory.
1046 Use --without-readline to disable readline support.])
1047   fi
1048 fi
1049
1050 if test "$with_zlib" = yes; then
1051   AC_CHECK_LIB(z, inflate, [],
1052                [AC_MSG_ERROR([zlib library not found
1053 If you have zlib already installed, see config.log for details on the
1054 failure.  It is possible the compiler isn't looking in the proper directory.
1055 Use --without-zlib to disable zlib support.])])
1056 fi
1057
1058 if test "$enable_spinlocks" = yes; then
1059   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1060 else
1061   AC_MSG_WARN([
1062 *** Not using spinlocks will cause poor performance.])
1063 fi
1064
1065 if test "$enable_atomics" = yes; then
1066   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1067 else
1068   AC_MSG_WARN([
1069 *** Not using atomic operations will cause poor performance.])
1070 fi
1071
1072 if test "$with_gssapi" = yes ; then
1073   if test "$PORTNAME" != "win32"; then
1074     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1075                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1076   else
1077     LIBS="$LIBS -lgssapi32"
1078   fi
1079 fi
1080
1081 if test "$with_openssl" = yes ; then
1082   dnl Order matters!
1083   if test "$PORTNAME" != "win32"; then
1084      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1085      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1086   else
1087      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1088      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1089   fi
1090   AC_CHECK_FUNCS([SSL_get_current_compression])
1091 fi
1092
1093 if test "$with_pam" = yes ; then
1094   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1095 fi
1096
1097 if test "$with_libxml" = yes ; then
1098   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1099 fi
1100
1101 if test "$with_libxslt" = yes ; then
1102   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1103 fi
1104
1105 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1106 if test "$with_ldap" = yes ; then
1107   _LIBS="$LIBS"
1108   if test "$PORTNAME" != "win32"; then
1109     AC_CHECK_LIB(ldap, ldap_bind, [],
1110                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1111                  [$EXTRA_LDAP_LIBS])
1112     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1113     if test "$enable_thread_safety" = yes; then
1114       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1115       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1116                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1117                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1118       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1119     else
1120       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1121     fi
1122   else
1123     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1124     LDAP_LIBS_FE="-lwldap32"
1125     LDAP_LIBS_BE="-lwldap32"
1126   fi
1127   LIBS="$_LIBS"
1128 fi
1129 AC_SUBST(LDAP_LIBS_FE)
1130 AC_SUBST(LDAP_LIBS_BE)
1131
1132 # for contrib/sepgsql
1133 if test "$with_selinux" = yes; then
1134   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1135                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1136 fi
1137
1138 # for contrib/uuid-ossp
1139 if test "$with_uuid" = bsd ; then
1140   # On BSD, the UUID functions are in libc
1141   AC_CHECK_FUNC(uuid_to_string,
1142     [UUID_LIBS=""],
1143     [AC_MSG_ERROR([BSD UUID functions are not present])])
1144 elif test "$with_uuid" = e2fs ; then
1145   # On OS X, the UUID functions are in libc
1146   AC_CHECK_FUNC(uuid_generate,
1147     [UUID_LIBS=""],
1148     [AC_CHECK_LIB(uuid, uuid_generate,
1149       [UUID_LIBS="-luuid"],
1150       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1151 elif test "$with_uuid" = ossp ; then
1152   AC_CHECK_LIB(ossp-uuid, uuid_export,
1153     [UUID_LIBS="-lossp-uuid"],
1154     [AC_CHECK_LIB(uuid, uuid_export,
1155       [UUID_LIBS="-luuid"],
1156       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1157 fi
1158 AC_SUBST(UUID_LIBS)
1159
1160
1161 ##
1162 ## Header files
1163 ##
1164
1165 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1166 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1167
1168 # On BSD, test for net/if.h will fail unless sys/socket.h
1169 # is included first.
1170 AC_CHECK_HEADERS(net/if.h, [], [],
1171 [AC_INCLUDES_DEFAULT
1172 #ifdef HAVE_SYS_SOCKET_H
1173 #include <sys/socket.h>
1174 #endif
1175 ])
1176
1177 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1178 # is included first.
1179 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1180 [AC_INCLUDES_DEFAULT
1181 #include <sys/param.h>
1182 ])
1183
1184 # At least on IRIX, test for netinet/tcp.h will fail unless
1185 # netinet/in.h is included first.
1186 AC_CHECK_HEADERS(netinet/in.h)
1187 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1188 [AC_INCLUDES_DEFAULT
1189 #ifdef HAVE_NETINET_IN_H
1190 #include <netinet/in.h>
1191 #endif
1192 ])
1193
1194 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1195   AC_CHECK_HEADERS(readline/readline.h, [],
1196         [AC_CHECK_HEADERS(readline.h, [],
1197                 [AC_MSG_ERROR([readline header not found
1198 If you have readline already installed, see config.log for details on the
1199 failure.  It is possible the compiler isn't looking in the proper directory.
1200 Use --without-readline to disable readline support.])])])
1201   AC_CHECK_HEADERS(readline/history.h, [],
1202         [AC_CHECK_HEADERS(history.h, [],
1203                 [AC_MSG_ERROR([history header not found
1204 If you have readline already installed, see config.log for details on the
1205 failure.  It is possible the compiler isn't looking in the proper directory.
1206 Use --without-readline to disable readline support.])])])
1207 fi
1208
1209 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1210 # Some installations of libedit usurp /usr/include/readline/, which seems
1211 # bad practice, since in combined installations readline will have its headers
1212 # there.  We might have to resort to AC_EGREP checks to make sure we found
1213 # the proper header...
1214   AC_CHECK_HEADERS(editline/readline.h, [],
1215         [AC_CHECK_HEADERS(readline.h, [],
1216                 [AC_CHECK_HEADERS(readline/readline.h, [],
1217                         [AC_MSG_ERROR([readline header not found
1218 If you have libedit already installed, see config.log for details on the
1219 failure.  It is possible the compiler isn't looking in the proper directory.
1220 Use --without-readline to disable libedit support.])])])])
1221 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1222 # not be there at all.  Hence, don't complain if not found.  We must check
1223 # though, since in yet other versions it is an independent header.
1224   AC_CHECK_HEADERS(editline/history.h, [],
1225         [AC_CHECK_HEADERS(history.h, [],
1226                 [AC_CHECK_HEADERS(readline/history.h)])])
1227 fi
1228
1229 if test "$with_zlib" = yes; then
1230   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1231 If you have zlib already installed, see config.log for details on the
1232 failure.  It is possible the compiler isn't looking in the proper directory.
1233 Use --without-zlib to disable zlib support.])])
1234 fi
1235
1236 if test "$with_gssapi" = yes ; then
1237   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1238         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1239 fi
1240
1241 if test "$with_openssl" = yes ; then
1242   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1243   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1244 fi
1245
1246 if test "$with_pam" = yes ; then
1247   AC_CHECK_HEADERS(security/pam_appl.h, [],
1248                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1249                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1250 fi
1251
1252 if test "$with_libxml" = yes ; then
1253   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1254 fi
1255
1256 if test "$with_libxslt" = yes ; then
1257   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1258 fi
1259
1260 if test "$with_ldap" = yes ; then
1261   if test "$PORTNAME" != "win32"; then
1262      AC_CHECK_HEADERS(ldap.h, [],
1263                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1264      PGAC_LDAP_SAFE
1265   else
1266      AC_CHECK_HEADERS(winldap.h, [],
1267                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1268                       [AC_INCLUDES_DEFAULT
1269 #include <windows.h>
1270                       ])
1271   fi
1272 fi
1273
1274 if test "$with_bonjour" = yes ; then
1275   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1276 fi
1277
1278 # for contrib/uuid-ossp
1279 if test "$with_uuid" = bsd ; then
1280   AC_CHECK_HEADERS(uuid.h,
1281     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1282       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1283     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1284 elif test "$with_uuid" = e2fs ; then
1285   AC_CHECK_HEADERS(uuid/uuid.h,
1286     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1287       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1288     [AC_CHECK_HEADERS(uuid.h,
1289       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1290         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1291       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1292 elif test "$with_uuid" = ossp ; then
1293   AC_CHECK_HEADERS(ossp/uuid.h,
1294     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1295       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1296     [AC_CHECK_HEADERS(uuid.h,
1297       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1298         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1299       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1300 fi
1301
1302 if test "$PORTNAME" = "win32" ; then
1303    AC_CHECK_HEADERS(crtdefs.h)
1304 fi
1305
1306 ##
1307 ## Types, structures, compiler characteristics
1308 ##
1309
1310 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1311 AC_C_BIGENDIAN
1312 AC_C_INLINE
1313 PGAC_PRINTF_ARCHETYPE
1314 AC_C_FLEXIBLE_ARRAY_MEMBER
1315 PGAC_C_SIGNED
1316 PGAC_C_FUNCNAME_SUPPORT
1317 PGAC_C_STATIC_ASSERT
1318 PGAC_C_TYPES_COMPATIBLE
1319 PGAC_C_BUILTIN_BSWAP32
1320 PGAC_C_BUILTIN_CONSTANT_P
1321 PGAC_C_BUILTIN_UNREACHABLE
1322 PGAC_C_VA_ARGS
1323 PGAC_STRUCT_TIMEZONE
1324 PGAC_UNION_SEMUN
1325 PGAC_STRUCT_SOCKADDR_UN
1326 PGAC_STRUCT_SOCKADDR_STORAGE
1327 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1328 PGAC_STRUCT_ADDRINFO
1329 AC_TYPE_INTPTR_T
1330 AC_TYPE_UINTPTR_T
1331 AC_TYPE_LONG_LONG_INT
1332
1333 PGAC_TYPE_LOCALE_T
1334
1335 AC_CHECK_TYPES([struct cmsgcred], [], [],
1336 [#include <sys/socket.h>
1337 #include <sys/param.h>
1338 #ifdef HAVE_SYS_UCRED_H
1339 #include <sys/ucred.h>
1340 #endif])
1341
1342 AC_CHECK_TYPES([struct option], [], [],
1343 [#ifdef HAVE_GETOPT_H
1344 #include <getopt.h>
1345 #endif])
1346
1347 if test "$with_zlib" = yes; then
1348   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1349   # did not).  While we could work around the lack of z_streamp, it
1350   # seems unwise to encourage people to use such old zlib versions...
1351   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1352 Use --without-zlib to disable zlib support.])],
1353                 [#include <zlib.h>])
1354 fi
1355
1356 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1357 case $host_cpu in
1358   ppc*|powerpc*)
1359     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1360     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1361         [int a = 0; int *p = &a; int r;
1362          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1363         [pgac_cv_have_ppc_mutex_hint=yes],
1364         [pgac_cv_have_ppc_mutex_hint=no])
1365     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1366     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1367         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1368     fi
1369   ;;
1370 esac
1371
1372 # Check largefile support.  You might think this is a system service not a
1373 # compiler characteristic, but you'd be wrong.  We must check this before
1374 # probing existence of related functions such as fseeko, since the largefile
1375 # defines can affect what is generated for that.
1376 if test "$PORTNAME" != "win32"; then
1377    AC_SYS_LARGEFILE
1378    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1379    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1380    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1381    dnl versions where the feature actually works, it's on by default anyway.
1382    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1383 fi
1384
1385 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1386 AC_CHECK_SIZEOF([off_t])
1387
1388 # If we don't have largefile support, can't handle segsize >= 2GB.
1389 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1390    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1391 fi
1392
1393
1394 ##
1395 ## Functions, global variables
1396 ##
1397
1398 PGAC_VAR_INT_TIMEZONE
1399 AC_FUNC_ACCEPT_ARGTYPES
1400 PGAC_FUNC_GETTIMEOFDAY_1ARG
1401
1402 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1403 # symbols that that library has no business exposing to the world.  Pending
1404 # acquisition of a clue by those developers, ignore libedit (including its
1405 # possible alias of libreadline) while checking for everything else.
1406 LIBS_including_readline="$LIBS"
1407 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1408
1409 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1410
1411 AC_REPLACE_FUNCS(fseeko)
1412 case $host_os in
1413         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1414         # Mingw uses macros to access Win32 API calls
1415         netbsd*|mingw*)
1416                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1417                 ac_cv_func_fseeko=yes;;
1418         *)
1419                 AC_FUNC_FSEEKO;;
1420 esac
1421
1422 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1423 # by calling it, 2009-04-02
1424 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1425 if test "$PORTNAME" != "solaris"; then
1426 AC_CHECK_FUNCS(posix_fadvise)
1427 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1428 fi
1429
1430 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1431 AC_CHECK_DECLS([strlcat, strlcpy])
1432 # This is probably only present on Darwin, but may as well check always
1433 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1434
1435 HAVE_IPV6=no
1436 AC_CHECK_TYPE([struct sockaddr_in6],
1437         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1438          HAVE_IPV6=yes],
1439         [],
1440 [$ac_includes_default
1441 #include <netinet/in.h>])
1442 AC_SUBST(HAVE_IPV6)
1443
1444 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1445 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1446 [#include <machine/vmparam.h>
1447 #include <sys/exec.h>
1448 ],
1449 [PS_STRINGS->ps_nargvstr = 1;
1450 PS_STRINGS->ps_argvstr = "foo";])],
1451 [pgac_cv_var_PS_STRINGS=yes],
1452 [pgac_cv_var_PS_STRINGS=no])])
1453 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1454   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1455 fi
1456
1457
1458 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1459 # is missing.  Yes, there are machines that have only one.  We may
1460 # also decide to use snprintf.c if snprintf() is present but does not
1461 # have all the features we need --- see below.
1462
1463 if test "$PORTNAME" = "win32"; then
1464   # Win32 gets snprintf.c built unconditionally.
1465   #
1466   # To properly translate all NLS languages strings, we must support the
1467   # *printf() %$ format, which allows *printf() arguments to be selected
1468   # by position in the translated string.
1469   #
1470   # libintl versions < 0.13 use the native *printf() functions, and Win32
1471   # *printf() doesn't understand %$, so we must use our /port versions,
1472   # which do understand %$. libintl versions >= 0.13 include their own
1473   # *printf versions on Win32.  The libintl 0.13 release note text is:
1474   #
1475   #   C format strings with positions, as they arise when a translator
1476   #   needs to reorder a sentence, are now supported on all platforms.
1477   #   On those few platforms (NetBSD and Woe32) for which the native
1478   #   printf()/fprintf()/... functions don't support such format
1479   #   strings, replacements are provided through <libintl.h>.
1480   #
1481   # We could use libintl >= 0.13's *printf() if we were sure that we had
1482   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1483   # to guarantee that, it is best to just use our own, so we are sure to
1484   # get %$ support. In include/port.h we disable the *printf() macros
1485   # that might have been defined by libintl.
1486   #
1487   # We do this unconditionally whether NLS is used or not so we are sure
1488   # that all Win32 libraries and binaries behave the same.
1489   pgac_need_repl_snprintf=yes
1490 else
1491   pgac_need_repl_snprintf=no
1492   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1493   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1494 fi
1495
1496
1497 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1498 # include/c.h will provide declarations.  Note this is a separate test
1499 # from whether the functions exist in the C library --- there are
1500 # systems that have the functions but don't bother to declare them :-(
1501
1502 AC_CHECK_DECLS([snprintf, vsnprintf])
1503
1504
1505 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1506 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1507 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1508 #include <math.h>
1509 double glob_double;
1510 ],
1511 [return isinf(glob_double) ? 0 : 1;])],
1512 [ac_cv_func_isinf=yes],
1513 [ac_cv_func_isinf=no])])
1514
1515 if test $ac_cv_func_isinf = yes ; then
1516   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1517 else
1518   AC_LIBOBJ(isinf)
1519   # Look for a way to implement a substitute for isinf()
1520   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1521 fi
1522
1523 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1524
1525 case $host_os in
1526
1527         # Windows uses a specialised env handler
1528         # and doesn't need a replacement getpeereid because it doesn't use
1529         # Unix sockets.
1530         mingw*)
1531                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1532                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1533                 ac_cv_func_unsetenv=yes
1534                 ac_cv_func_getpeereid=yes;;
1535         *)
1536                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1537                 ;;
1538 esac
1539
1540 # System's version of getaddrinfo(), if any, may be used only if we found
1541 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1542 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1543 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1544    test "$PORTNAME" != "win32"; then
1545   AC_REPLACE_FUNCS([getaddrinfo])
1546 else
1547   AC_LIBOBJ(getaddrinfo)
1548 fi
1549
1550 # Similarly, use system's getopt_long() only if system provides struct option.
1551 if test x"$ac_cv_type_struct_option" = xyes ; then
1552   AC_REPLACE_FUNCS([getopt_long])
1553 else
1554   AC_LIBOBJ(getopt_long)
1555 fi
1556
1557 # Solaris' getopt() doesn't do what we want for long options, so always use
1558 # our version on that platform.
1559 if test "$PORTNAME" = "solaris"; then
1560   AC_LIBOBJ(getopt)
1561 fi
1562
1563 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1564 # so always use our version on Windows.
1565 if test "$PORTNAME" = "win32"; then
1566   AC_LIBOBJ(getopt)
1567   AC_LIBOBJ(getopt_long)
1568 fi
1569
1570 # Win32 (really MinGW) support
1571 if test "$PORTNAME" = "win32"; then
1572   AC_REPLACE_FUNCS(gettimeofday)
1573   AC_LIBOBJ(dirmod)
1574   AC_LIBOBJ(kill)
1575   AC_LIBOBJ(open)
1576   AC_LIBOBJ(system)
1577   AC_LIBOBJ(win32env)
1578   AC_LIBOBJ(win32error)
1579   AC_LIBOBJ(win32setlocale)
1580   AC_DEFINE([HAVE_SYMLINK], 1,
1581             [Define to 1 if you have the `symlink' function.])
1582   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1583 #define WIN32_LEAN_AND_MEAN
1584 #include <windows.h>
1585 #include <string.h>
1586 #include <dbghelp.h>])
1587 fi
1588 if test x"$pgac_minidump_type" = x"yes" ; then
1589   AC_SUBST(have_win32_dbghelp,yes)
1590 else
1591   AC_SUBST(have_win32_dbghelp,no)
1592 fi
1593
1594 # Cygwin needs only a bit of that
1595 if test "$PORTNAME" = "cygwin"; then
1596   AC_LIBOBJ(dirmod)
1597 fi
1598
1599 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1600 dnl (especially on GNU libc)
1601 dnl See also comments in c.h.
1602 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1603 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <setjmp.h>],
1604             [sigjmp_buf x; sigsetjmp(x, 1);])],
1605             [pgac_cv_func_sigsetjmp=yes],
1606             [pgac_cv_func_sigsetjmp=no])])
1607 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1608   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1609 fi
1610
1611 AC_CHECK_DECLS([sys_siglist], [], [],
1612 [#include <signal.h>
1613 /* NetBSD declares sys_siglist in unistd.h.  */
1614 #ifdef HAVE_UNISTD_H
1615 # include <unistd.h>
1616 #endif
1617 ])
1618
1619 AC_CHECK_FUNC(syslog,
1620               [AC_CHECK_HEADER(syslog.h,
1621                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1622
1623 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1624 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1625   [extern int opterr; opterr = 1;])],
1626   [pgac_cv_var_int_opterr=yes],
1627   [pgac_cv_var_int_opterr=no])])
1628 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1629   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1630 fi
1631
1632 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1633 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1634   [extern int optreset; optreset = 1;])],
1635   [pgac_cv_var_int_optreset=yes],
1636   [pgac_cv_var_int_optreset=no])])
1637 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1638   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1639 fi
1640
1641 AC_CHECK_FUNCS([strtoll strtoq], [break])
1642 AC_CHECK_FUNCS([strtoull strtouq], [break])
1643
1644 # Lastly, restore full LIBS list and check for readline/libedit symbols
1645 LIBS="$LIBS_including_readline"
1646
1647 if test "$with_readline" = yes; then
1648   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1649   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1650   AC_CHECK_FUNCS([append_history history_truncate_file])
1651 fi
1652
1653
1654 # This test makes sure that run tests work at all.  Sometimes a shared
1655 # library is found by the linker, but the runtime linker can't find it.
1656 # This check should come after all modifications of compiler or linker
1657 # variables, and before any other run tests.
1658 AC_MSG_CHECKING([test program])
1659 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1660 [AC_MSG_RESULT(ok)],
1661 [AC_MSG_RESULT(failed)
1662 AC_MSG_ERROR([[
1663 Could not execute a simple test program.  This may be a problem
1664 related to locating shared libraries.  Check the file 'config.log'
1665 for the exact reason.]])],
1666 [AC_MSG_RESULT([cross-compiling])])
1667
1668 # --------------------
1669 # Run tests below here
1670 # --------------------
1671
1672 # Force use of our snprintf if system's doesn't do arg control
1673 # See comment above at snprintf test for details.
1674 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1675   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1676   if test $pgac_cv_snprintf_arg_control != yes ; then
1677     pgac_need_repl_snprintf=yes
1678   fi
1679 fi
1680
1681
1682 dnl Check to see if we have a working 64-bit integer type.
1683 dnl This breaks down into two steps:
1684 dnl (1) figure out if the compiler has a 64-bit int type with working
1685 dnl arithmetic, and if so
1686 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1687 dnl snprintf is the only library routine we really need for int8 support.)
1688 dnl It's entirely possible to have a compiler that handles a 64-bit type
1689 dnl when the C library doesn't; this is fairly likely when using gcc on
1690 dnl an older platform, for example.
1691 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1692 dnl we force our own version of snprintf() to be used instead.
1693 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1694
1695 dnl As of Postgres 8.4, we no longer support compilers without a working
1696 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1697
1698 PGAC_TYPE_64BIT_INT([long int])
1699
1700 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1701   pg_int64_type="long int"
1702 else
1703   PGAC_TYPE_64BIT_INT([long long int])
1704   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1705     pg_int64_type="long long int"
1706   else
1707     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1708   fi
1709 fi
1710
1711 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1712   [Define to the name of a signed 64-bit integer type.])
1713
1714 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1715
1716 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1717   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1718 #define INT64CONST(x)  x##LL
1719 long long int foo = INT64CONST(0x1234567890123456);
1720 ])],
1721         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1722         [])
1723 fi
1724
1725
1726 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1727 # we found we need to use "long long int", better check.  We cope with
1728 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1729 # work, fall back to our own snprintf emulation (which we know uses %lld).
1730
1731 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1732   if test $pgac_need_repl_snprintf = no; then
1733     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1734     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1735       # Force usage of our own snprintf, since system snprintf is broken
1736       pgac_need_repl_snprintf=yes
1737       LONG_LONG_INT_MODIFIER='ll'
1738     fi
1739   else
1740     # Here if we previously decided we needed to use our own snprintf
1741     LONG_LONG_INT_MODIFIER='ll'
1742   fi
1743 else
1744   # Here if we are not using 'long long int' at all
1745   LONG_LONG_INT_MODIFIER='l'
1746 fi
1747
1748 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1749
1750 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1751                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1752
1753 # Also force use of our snprintf if the system's doesn't support the %z flag.
1754 if test "$pgac_need_repl_snprintf" = no; then
1755   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1756   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1757     pgac_need_repl_snprintf=yes
1758   fi
1759 fi
1760
1761 # Now we have checked all the reasons to replace snprintf
1762 if test $pgac_need_repl_snprintf = yes; then
1763   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1764   AC_LIBOBJ(snprintf)
1765 fi
1766
1767 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1768 AC_CHECK_SIZEOF([void *])
1769 AC_CHECK_SIZEOF([size_t])
1770 AC_CHECK_SIZEOF([long])
1771
1772 # Decide whether float4 is passed by value: user-selectable, enabled by default
1773 AC_MSG_CHECKING([whether to build with float4 passed by value])
1774 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1775               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1776                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1777                float4passbyval=true],
1778               [float4passbyval=false])
1779 AC_MSG_RESULT([$enable_float4_byval])
1780 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1781
1782 # Decide whether float8 is passed by value.
1783 # Note: this setting also controls int8 and related types such as timestamp.
1784 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1785 # If not, trying to select it is an error.
1786 AC_MSG_CHECKING([whether to build with float8 passed by value])
1787 if test $ac_cv_sizeof_void_p -ge 8 ; then
1788   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1789 else
1790   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1791   if test "$enable_float8_byval" = yes ; then
1792     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1793   fi
1794 fi
1795 if test "$enable_float8_byval" = yes ; then
1796   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1797             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1798   float8passbyval=true
1799 else
1800   float8passbyval=false
1801 fi
1802 AC_MSG_RESULT([$enable_float8_byval])
1803 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1804
1805 # Determine memory alignment requirements for the basic C data types.
1806
1807 AC_CHECK_ALIGNOF(short)
1808 AC_CHECK_ALIGNOF(int)
1809 AC_CHECK_ALIGNOF(long)
1810 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1811   AC_CHECK_ALIGNOF(long long int)
1812 fi
1813 AC_CHECK_ALIGNOF(double)
1814
1815 # Compute maximum alignment of any basic type.
1816 # We assume long's alignment is at least as strong as char, short, or int;
1817 # but we must check long long (if it exists) and double.
1818
1819 MAX_ALIGNOF=$ac_cv_alignof_long
1820 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1821   MAX_ALIGNOF=$ac_cv_alignof_double
1822 fi
1823 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1824   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1825 fi
1826 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1827
1828
1829 # Some platforms predefine the types int8, int16, etc.  Only check
1830 # a (hopefully) representative subset.
1831 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1832 [#include <stdio.h>])
1833
1834 # Check for extensions offering the integer scalar type __int128.
1835 PGAC_TYPE_128BIT_INT
1836
1837 # Check for various atomic operations now that we have checked how to declare
1838 # 64bit integers.
1839 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1840 PGAC_HAVE_GCC__SYNC_INT32_TAS
1841 PGAC_HAVE_GCC__SYNC_INT32_CAS
1842 PGAC_HAVE_GCC__SYNC_INT64_CAS
1843 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1844 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1845
1846
1847 # Check for x86 cpuid instruction
1848 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1849 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1850   [[unsigned int exx[4] = {0, 0, 0, 0};
1851   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1852   ]])],
1853   [pgac_cv__get_cpuid="yes"],
1854   [pgac_cv__get_cpuid="no"])])
1855 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1856   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1857 fi
1858
1859 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1860 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1861   [[unsigned int exx[4] = {0, 0, 0, 0};
1862   __get_cpuid(exx[0], 1);
1863   ]])],
1864   [pgac_cv__cpuid="yes"],
1865   [pgac_cv__cpuid="no"])])
1866 if test x"$pgac_cv__cpuid" = x"yes"; then
1867   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1868 fi
1869
1870 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1871 #
1872 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1873 # with the default compiler flags. If not, check if adding the -msse4.2
1874 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1875 PGAC_SSE42_CRC32_INTRINSICS([])
1876 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1877   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1878 fi
1879 AC_SUBST(CFLAGS_SSE42)
1880
1881 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1882 # define __SSE4_2__ in that case.
1883 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1884 #ifndef __SSE4_2__
1885 #error __SSE4_2__ not defined
1886 #endif
1887 ])], [SSE4_2_TARGETED=1])
1888
1889 # Select CRC-32C implementation.
1890 #
1891 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1892 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1893 # a processor, but we can nevertheless produce code that uses the SSE
1894 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1895 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1896 # by the processor we're running on.
1897 #
1898 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1899 # in the template or configure command line.
1900 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1901   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1902     USE_SSE42_CRC32C=1
1903   else
1904     # the CPUID instruction is needed for the runtime check.
1905     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1906       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1907     else
1908       # fall back to slicing-by-8 algorithm which doesn't require any special
1909       # CPU support.
1910       USE_SLICING_BY_8_CRC32C=1
1911     fi
1912   fi
1913 fi
1914
1915 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1916 AC_MSG_CHECKING([which CRC-32C implementation to use])
1917 if test x"$USE_SSE42_CRC32C" = x"1"; then
1918   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1919   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1920   AC_MSG_RESULT(SSE 4.2)
1921 else
1922   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1923     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1924     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1925     AC_MSG_RESULT(SSE 4.2 with runtime check)
1926   else
1927     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1928     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1929     AC_MSG_RESULT(slicing-by-8)
1930   fi
1931 fi
1932 AC_SUBST(PG_CRC32C_OBJS)
1933
1934
1935 # Check that POSIX signals are available if thread safety is enabled.
1936 if test "$PORTNAME" != "win32"
1937 then
1938 PGAC_FUNC_POSIX_SIGNALS
1939 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1940   AC_MSG_ERROR([
1941 Thread-safety requires POSIX signals, which are not supported by this
1942 operating system;  use --disable-thread-safety to disable thread safety.])
1943 fi
1944 fi
1945
1946
1947 # Select semaphore implementation type.
1948 if test "$PORTNAME" != "win32"; then
1949   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1950     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1951     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1952   else
1953     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1954       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1955       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1956     else
1957       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1958       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1959     fi
1960   fi
1961 else
1962   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1963   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1964 fi
1965
1966
1967 # Select shared-memory implementation type.
1968 if test "$PORTNAME" != "win32"; then
1969   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1970   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1971 else
1972   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1973   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1974 fi
1975
1976 # Select latch implementation type.
1977 if test "$PORTNAME" != "win32"; then
1978   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1979 else
1980   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1981 fi
1982
1983 # If not set in template file, set bytes to use libc memset()
1984 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1985   MEMSET_LOOP_LIMIT=1024
1986 fi
1987 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1988
1989
1990 if test "$enable_nls" = yes ; then
1991   PGAC_CHECK_GETTEXT
1992 fi
1993
1994 # Check for Tcl configuration script tclConfig.sh
1995 if test "$with_tcl" = yes; then
1996     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1997     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1998                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1999     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2000     if test "$TCL_SHARED_BUILD" != 1; then
2001       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2002 Use --without-tcl to disable building PL/Tcl.])
2003     fi
2004     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2005     ac_save_CPPFLAGS=$CPPFLAGS
2006     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2007     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2008     CPPFLAGS=$ac_save_CPPFLAGS
2009 fi
2010
2011 # check for <perl.h>
2012 if test "$with_perl" = yes; then
2013   ac_save_CPPFLAGS=$CPPFLAGS
2014   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2015   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2016                   [#include <EXTERN.h>])
2017   # While we're at it, check that we can link to libperl.
2018   # On most platforms, if perl.h is there then libperl.so will be too, but at
2019   # this writing Debian packages them separately.  There is no known reason to
2020   # waste cycles on separate probes for the Tcl or Python libraries, though.
2021   pgac_save_LIBS=$LIBS
2022   LIBS="$perl_embed_ldflags"
2023   AC_MSG_CHECKING([for libperl])
2024   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2025 #include <EXTERN.h>
2026 #include <perl.h>
2027 ],  [perl_alloc();])],
2028     [AC_MSG_RESULT(yes)],
2029     [AC_MSG_RESULT(no)
2030      AC_MSG_ERROR([libperl library is required for Perl])])
2031   LIBS=$pgac_save_LIBS
2032   CPPFLAGS=$ac_save_CPPFLAGS
2033 fi
2034
2035 # check for <Python.h>
2036 if test "$with_python" = yes; then
2037   ac_save_CPPFLAGS=$CPPFLAGS
2038   CPPFLAGS="$python_includespec $CPPFLAGS"
2039   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2040   CPPFLAGS=$ac_save_CPPFLAGS
2041 fi
2042
2043 #
2044 # Check for DocBook and tools
2045 #
2046 PGAC_PROG_NSGMLS
2047 PGAC_PROG_JADE
2048 PGAC_CHECK_DOCBOOK(4.2)
2049 PGAC_PATH_DOCBOOK_STYLESHEETS
2050 PGAC_PATH_COLLATEINDEX
2051 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
2052 AC_CHECK_PROGS(XMLLINT, xmllint)
2053 AC_CHECK_PROGS(XSLTPROC, xsltproc)
2054 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
2055
2056 #
2057 # Check for test tools
2058 #
2059 if test "$enable_tap_tests" = yes; then
2060   AC_CHECK_PROGS(PROVE, prove)
2061   if test -z "$PROVE"; then
2062     AC_MSG_ERROR([prove not found])
2063   fi
2064   if test -z "$PERL"; then
2065     AC_MSG_ERROR([Perl not found])
2066   fi
2067 fi
2068
2069 # Thread testing
2070
2071 # We have to run the thread test near the end so we have all our symbols
2072 # defined.  Cross compiling throws a warning.
2073 #
2074 if test "$enable_thread_safety" = yes; then
2075 if test "$PORTNAME" != "win32"
2076 then
2077 AC_MSG_CHECKING([thread safety of required library functions])
2078
2079 _CFLAGS="$CFLAGS"
2080 _LIBS="$LIBS"
2081 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2082 LIBS="$LIBS $PTHREAD_LIBS"
2083 AC_RUN_IFELSE(
2084   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2085   [AC_MSG_RESULT(yes)],
2086   [AC_MSG_RESULT(no)
2087   AC_MSG_ERROR([thread test program failed
2088 This platform is not thread-safe.  Check the file 'config.log' or compile
2089 and run src/test/thread/thread_test for the exact reason.
2090 Use --disable-thread-safety to disable thread safety.])],
2091   [AC_MSG_RESULT(maybe)
2092   AC_MSG_WARN([
2093 *** Skipping thread test program because of cross-compile build.
2094 *** Run the program in src/test/thread on the target machine.
2095 ])])
2096 CFLAGS="$_CFLAGS"
2097 LIBS="$_LIBS"
2098 else
2099 AC_MSG_WARN([*** skipping thread test on Win32])
2100 fi
2101 fi
2102
2103 # If compiler will take -Wl,--as-needed (or various platform-specific
2104 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2105 # trying to filter LIBS to the minimum for each executable.
2106 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2107 # libreadline; therefore we postpone testing it until we know what library
2108 # dependencies readline has.  The test code will try to link with $LIBS.
2109 if test "$with_readline" = yes; then
2110   link_test_func=readline
2111 else
2112   link_test_func=exit
2113 fi
2114
2115 if test "$PORTNAME" = "darwin"; then
2116   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2117 elif test "$PORTNAME" = "openbsd"; then
2118   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2119 else
2120   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2121 fi
2122
2123 # Create compiler version string
2124 if test x"$GCC" = x"yes" ; then
2125   cc_string=`${CC} --version | sed q`
2126   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2127 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2128   cc_string=`${CC} -V 2>&1 | sed q`
2129 else
2130   cc_string=$CC
2131 fi
2132
2133 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2134                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2135                    [A string containing the version number, platform, and C compiler])
2136
2137 # Supply a numeric version string for use by 3rd party add-ons
2138 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2139 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2140 tr '.' '        ' |
2141 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2142 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2143 AC_SUBST(PG_VERSION_NUM)
2144
2145
2146 # Begin output steps
2147
2148 AC_MSG_NOTICE([using compiler=$cc_string])
2149 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2150 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2151 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2152
2153 # prepare build tree if outside source tree
2154 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2155 # Note 2: /bin/pwd might be better than shell's built-in at getting
2156 #         a symlink-free name.
2157 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2158   vpath_build=no
2159 else
2160   vpath_build=yes
2161   if test "$no_create" != yes; then
2162     _AS_ECHO_N([preparing build tree... ])
2163     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2164     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2165       || AC_MSG_ERROR(failed)
2166     AC_MSG_RESULT(done)
2167   fi
2168 fi
2169 AC_SUBST(vpath_build)
2170
2171
2172 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2173
2174 AC_CONFIG_LINKS([
2175   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2176   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2177   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2178   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
2179   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2180   src/include/pg_config_os.h:src/include/port/${template}.h
2181   src/Makefile.port:src/makefiles/Makefile.${template}
2182 ])
2183
2184 if test "$PORTNAME" = "win32"; then
2185 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2186 # Links sometimes fail undetected on Mingw -
2187 # so here we detect it and warn the user
2188 for FILE in $CONFIG_LINKS
2189  do
2190         # test -e works for symlinks in the MinGW console
2191         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2192  done
2193 ])
2194 fi
2195
2196 AC_CONFIG_HEADERS([src/include/pg_config.h],
2197 [
2198 # Update timestamp for pg_config.h (see Makefile.global)
2199 echo >src/include/stamp-h
2200 ])
2201
2202 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2203 [
2204 # Update timestamp for pg_config_ext.h (see Makefile.global)
2205 echo >src/include/stamp-ext-h
2206 ])
2207
2208 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2209                   [echo >src/interfaces/ecpg/include/stamp-h])
2210
2211 AC_OUTPUT