granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.247 2003/05/09 16:26:28 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 # Character set recode (--enable-recode)
 157 #
 158 AC_MSG_CHECKING([whether to build with recode support])
 159 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable single-byte recode support],
 160               [AC_DEFINE([CYR_RECODE], 1,
 161                          [Define to 1 if you want single-byte recode support. (--enable-recode)])])
 162 AC_MSG_RESULT([$enable_recode])
 163
 164
 165 #
 166 # NLS
 167 #
 168 AC_MSG_CHECKING([whether NLS is wanted])
 169 PGAC_ARG_OPTARG(enable, nls,
 170                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 171                 [],
 172                 [WANTED_LANGUAGES=$enableval],
 173                 [AC_DEFINE(ENABLE_NLS, 1,
 174                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 175 AC_MSG_RESULT([$enable_nls])
 176 AC_SUBST(enable_nls)
 177 AC_SUBST(WANTED_LANGUAGES)
 178
 179 #
 180 # Default port number (--with-pgport), default 5432
 181 #
 182 AC_MSG_CHECKING([for default port number])
 183 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 184              [default_port=$withval],
 185              [default_port=5432])
 186 AC_MSG_RESULT([$default_port])
 187 # Need both of these because some places want an integer and some a string
 188 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 189 [Define to the default TCP port number on which the server listens and
 190 to which clients will try to connect to.  This can be overridden at
 191 run-time, but it's convenient if your clients have the right default
 192 compiled in.  (--with-pgport=PORTNUM)])
 193 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 194                    [Define to the default TCP port number as string constant.])
 195 AC_SUBST(default_port)
 196
 197 #
 198 # Option to disable shared libraries
 199 #
 200 PGAC_ARG_BOOL(enable, shared, yes,
 201               [  --disable-shared        do not build shared libraries])
 202 AC_SUBST(enable_shared)
 203
 204 #
 205 # '-rpath'-like feature can be disabled
 206 #
 207 PGAC_ARG_BOOL(enable, rpath, yes,
 208               [  --disable-rpath         do not embed shared library search path in executables])
 209 AC_SUBST(enable_rpath)
 210
 211
 212 #
 213 # --enable-debug adds -g to compiler flags
 214 #
 215 PGAC_ARG_BOOL(enable, debug, no,
 216               [  --enable-debug          build with debugging symbols (-g)])
 217 AC_SUBST(enable_debug)
 218
 219 #
 220 # C compiler
 221 #
 222
 223 # For historical reasons you can also use --with-CC to specify the C compiler
 224 # to use, although the standard way to do this is to set the CC environment
 225 # variable.
 226 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 227
 228 case $template in
 229   aix) pgac_cc_list="gcc xlc";;
 230  irix) pgac_cc_list="cc";; # no gcc
 231     *) pgac_cc_list="gcc cc";;
 232 esac
 233
 234 AC_PROG_CC([$pgac_cc_list])
 235 # Read the template
 236 . "$srcdir/src/template/$template" || exit
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 fi
 241 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 242   CFLAGS="$CFLAGS -g"
 243 fi
 244 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 245
 246 # Check if the compiler still works with the template settings
 247 AC_MSG_CHECKING([whether the C compiler still works])
 248 AC_TRY_LINK([], [return 0;],
 249   [AC_MSG_RESULT(yes)],
 250   [AC_MSG_RESULT(no)
 251    AC_MSG_ERROR([cannot proceed])])
 252
 253 # Defend against gcc -ffastmath
 254 if test "$GCC" = yes; then
 255 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 256 choke me
 257 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 258 fi
 259
 260 AC_PROG_CPP
 261 AC_SUBST(GCC)
 262
 263 # Create compiler version string
 264 if test x"$GCC" = x"yes" ; then
 265   cc_string="GCC `${CC} --version | sed q`"
 266 else
 267   cc_string=$CC
 268 fi
 269 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 270                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 271                    [A string containing the version number, platform, and C compiler])
 272
 273
 274 #
 275 # Automatic dependency tracking
 276 #
 277 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 278               [autodepend=yes])
 279 AC_SUBST(autodepend)
 280
 281
 282 #
 283 # Enable assert checks
 284 #
 285 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 286               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 287                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 288
 289
 290 #
 291 # Include directories
 292 #
 293 ac_save_IFS=$IFS
 294 IFS="${IFS}:"
 295 # SRCH_INC comes from the template file
 296 for dir in $with_includes $SRCH_INC; do
 297   if test -d "$dir"; then
 298     INCLUDES="$INCLUDES -I$dir"
 299   else
 300     AC_MSG_WARN([*** Include directory $dir does not exist.])
 301   fi
 302 done
 303 IFS=$ac_save_IFS
 304 AC_SUBST(INCLUDES)
 305
 306
 307 #
 308 # Library directories
 309 #
 310 ac_save_IFS=$IFS
 311 IFS="${IFS}:"
 312 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 313 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 314   if test -d "$dir"; then
 315     LIBDIRS="$LIBDIRS -L$dir"
 316   else
 317     AC_MSG_WARN([*** Library directory $dir does not exist.])
 318   fi
 319 done
 320 IFS=$ac_save_IFS
 321
 322
 323 #
 324 # Tcl/Tk
 325 #
 326 AC_MSG_CHECKING([whether to build with Tcl])
 327 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 328 AC_MSG_RESULT([$with_tcl])
 329 AC_SUBST([with_tcl])
 330
 331 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 332 AC_MSG_CHECKING([whether to build with Tk])
 333 if test "$with_tcl" = yes; then
 334   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 335 else
 336   with_tk=no
 337 fi
 338 AC_MSG_RESULT([$with_tk])
 339 AC_SUBST([with_tk])
 340
 341
 342 # We see if the path to the Tcl/Tk configuration scripts is specified.
 343 # This will override the use of tclsh to find the paths to search.
 344
 345 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 346
 347 # We see if the path to the Tk configuration scripts is specified.
 348 # This will override the use of tclsh to find the paths to search.
 349
 350 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 351
 352 #
 353 # Optionally build Perl modules (PL/Perl)
 354 #
 355 AC_MSG_CHECKING([whether to build Perl modules])
 356 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 357 AC_MSG_RESULT([$with_perl])
 358 AC_SUBST(with_perl)
 359
 360 #
 361 # Optionally build Python interface module
 362 #
 363 AC_MSG_CHECKING([whether to build Python modules])
 364 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 365 AC_MSG_RESULT([$with_python])
 366 AC_SUBST(with_python)
 367
 368 #
 369 # Optionally build the Java/JDBC tools
 370 #
 371 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 372 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 373 [AC_MSG_RESULT(yes)
 374 PGAC_PATH_ANT
 375 if test -z "$ANT"; then
 376   AC_MSG_ERROR([Ant is required to build Java components
 377 If you have Ant already installed, see config.log for details on the failure.])
 378 fi
 379 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 380   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 381 fi],
 382 [AC_MSG_RESULT(no)])
 383 AC_SUBST(with_java)
 384
 385 dnl A note on the Kerberos and OpenSSL options:
 386 dnl
 387 dnl The user can give an argument to the option in order the specify
 388 dnl the base path of the respective installation (what he specified
 389 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 390 dnl then we take the path where the package installs by default. This
 391 dnl way the user doesn't have to use redundant --with-includes and
 392 dnl --with-libraries options, but he can still use them if the layout
 393 dnl is non-standard.
 394
 395 #
 396 # Kerberos 4
 397 #
 398 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 399 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 400                 [krb4_prefix=/usr/athena],
 401                 [krb4_prefix=$withval],
 402 [
 403   AC_MSG_RESULT(yes)
 404   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 405
 406   if test -d "$krb4_prefix/include"; then
 407     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 408   fi
 409   if test -d "$krb4_prefix/lib"; then
 410     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 411   fi
 412
 413   krb_srvtab="/etc/srvtab"
 414 ],
 415 [AC_MSG_RESULT(no)])
 416
 417 AC_SUBST(with_krb4)
 418
 419
 420 #
 421 # Kerberos 5
 422 #
 423 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 424 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 425               [krb5_prefix=/usr/athena],
 426               [krb5_prefix=$withval],
 427 [
 428   AC_MSG_RESULT([yes])
 429   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 430
 431   if test -d "$krb5_prefix/include"; then
 432     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 433   fi
 434   if test -d "$krb5_prefix/lib"; then
 435     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 436   fi
 437
 438   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 439 ],
 440 [AC_MSG_RESULT(no)])
 441
 442 AC_SUBST(with_krb5)
 443
 444
 445 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 446 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 447   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 448 fi
 449
 450 AC_SUBST(krb_srvtab)
 451
 452
 453 #
 454 # Kerberos configuration parameters
 455 #
 456 PGAC_ARG_REQ(with, krb-srvnam,
 457              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 458              [],
 459              [with_krb_srvnam="postgres"])
 460 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 461                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 462
 463
 464 #
 465 # PAM
 466 #
 467 AC_MSG_CHECKING([whether to build with PAM support])
 468 PGAC_ARG_BOOL(with, pam, no,
 469               [  --with-pam              build with PAM support],
 470               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 471 AC_MSG_RESULT([$with_pam])
 472 AC_SUBST(with_pam)
 473
 474
 475 #
 476 # OpenSSL
 477 #
 478 PGAC_ARG_OPTARG(with, openssl,
 479                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 480                 [openssl_prefix=/usr/local/ssl],
 481                 [openssl_prefix=$withval],
 482 [
 483   AC_MSG_RESULT([building with OpenSSL support])
 484   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 485
 486   if test -d "${openssl_prefix}/include" ; then
 487     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 488   fi
 489   if test -d "${openssl_prefix}/lib" ; then
 490     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 491   fi
 492 ])
 493
 494 AC_SUBST(with_openssl)
 495
 496
 497 #
 498 # Readline
 499 #
 500 PGAC_ARG_BOOL(with, readline, yes,
 501               [  --without-readline      do not use Readline])
 502
 503 #
 504 # Zlib
 505 #
 506 PGAC_ARG_BOOL(with, zlib, yes,
 507               [  --without-zlib          do not use Zlib])
 508
 509
 510
 511 # Assume system is ELF if it predefines __ELF__ as 1,
 512 # otherwise believe host_os based default.
 513 case $host_os in
 514     freebsd1*|freebsd2*) elf=no;;
 515     freebsd3*|freebsd4*) elf=yes;;
 516 esac
 517
 518 AC_EGREP_CPP(yes,
 519 [#if __ELF__
 520   yes
 521 #endif
 522 ],
 523 [ELF_SYS=true],
 524 [if test "X$elf" = "Xyes" ; then
 525   ELF_SYS=true
 526 else
 527   ELF_SYS=
 528 fi])
 529 AC_SUBST(ELF_SYS)
 530
 531
 532
 533 CPPFLAGS="$CPPFLAGS $INCLUDES"
 534 LDFLAGS="$LDFLAGS $LIBDIRS"
 535
 536 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 537 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 538
 539
 540 AC_PROG_AWK
 541 PGAC_PATH_FLEX
 542 AC_PROG_LN_S
 543 AC_PROG_LD
 544 AC_SUBST(LD)
 545 AC_SUBST(with_gnu_ld)
 546 case $host_os in sysv5*)
 547   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 548   [
 549     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 550     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 551     LDFLAGS=$pgac_save_LDFLAGS
 552   ])
 553   ld_R_works=$pgac_cv_prog_ld_R
 554   AC_SUBST(ld_R_works)
 555 esac
 556 AC_PROG_RANLIB
 557 AC_CHECK_PROGS(LORDER, lorder)
 558 AC_PATH_PROG(TAR, tar)
 559 PGAC_CHECK_STRIP
 560
 561 AC_CHECK_PROGS(YACC, ['bison -y'])
 562 if test -z "$YACC"; then
 563   AC_MSG_WARN([
 564 *** Without Bison you will not be able to build PostgreSQL from CVS or
 565 *** change any of the parser definition files.  You can obtain Bison from
 566 *** a GNU mirror site.  (If you are using the official distribution of
 567 *** PostgreSQL then you do not need to worry about this because the Bison
 568 *** output is pre-generated.)  To use a different yacc program (possible,
 569 *** but not recommended), set the environment variable YACC before running
 570 *** 'configure'.])
 571 fi
 572 AC_SUBST(YFLAGS)
 573
 574 PGAC_PATH_PERL
 575 if test "$with_perl" = yes; then
 576   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 577   PGAC_CHECK_PERL_EMBED_LDFLAGS
 578 fi
 579
 580 if test "$with_python" = yes; then
 581   PGAC_PATH_PYTHON
 582   PGAC_CHECK_PYTHON_MODULE_SETUP
 583   PGAC_CHECK_PYTHON_EMBED_SETUP
 584 fi
 585
 586
 587 ##
 588 ## Libraries
 589 ##
 590
 591 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 592 then
 593         AC_CHECK_LIB(bsd,      main)
 594 fi
 595 AC_CHECK_LIB(util,     setproctitle)
 596 AC_CHECK_LIB(m,        main)
 597 AC_CHECK_LIB(dl,       main)
 598 AC_CHECK_LIB(nsl,      main)
 599 AC_CHECK_LIB(socket,   main)
 600 AC_CHECK_LIB(ipc,      main)
 601 AC_CHECK_LIB(IPC,      main)
 602 AC_CHECK_LIB(lc,       main)
 603 AC_CHECK_LIB(dld,      main)
 604 AC_CHECK_LIB(ld,       main)
 605 AC_CHECK_LIB(compat,   main)
 606 AC_CHECK_LIB(BSD,      main)
 607 AC_CHECK_LIB(gen,      main)
 608 AC_CHECK_LIB(PW,       main)
 609 AC_CHECK_LIB(resolv,   main)
 610 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 611 # QNX:
 612 AC_CHECK_LIB(unix, main)
 613 AC_SEARCH_LIBS(crypt,  crypt)
 614 # BeOS:
 615 AC_CHECK_LIB(bind, __inet_ntoa)
 616 # Solaris:
 617 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 618 # Cygwin:
 619 AC_CHECK_LIB(cygipc, shmget)
 620
 621 if test "$with_readline" = yes; then
 622   PGAC_CHECK_READLINE
 623   if test x"$pgac_cv_check_readline" = x"no"; then
 624     AC_MSG_ERROR([readline library not found
 625 If you have readline already installed, see config.log for details on the
 626 failure.  It is possible the compiler isn't looking in the proper directory.
 627 Use --without-readline to disable readline support.])
 628   fi
 629 fi
 630
 631 if test "$with_zlib" = yes; then
 632   AC_CHECK_LIB(z, inflate, [],
 633                [AC_MSG_ERROR([zlib library not found
 634 If you have zlib already installed, see config.log for details on the
 635 failure.  It is possible the compiler isn't looking in the proper directory.
 636 Use --without-zlib to disable zlib support.])])
 637 fi
 638
 639 if test "$with_krb4" = yes ; then
 640   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 641   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 642 fi
 643
 644 if test "$with_krb5" = yes ; then
 645   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 646                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 647   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 648                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 649   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 650                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 651 fi
 652
 653 if test "$with_openssl" = yes ; then
 654   dnl Order matters!
 655   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 656   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 657 fi
 658
 659 if test "$with_pam" = yes ; then
 660   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 661 fi
 662
 663
 664 ##
 665 ## Header files
 666 ##
 667
 668 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 669 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 670
 671 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 672 # netinet/in.h is included first.
 673 AC_CHECK_HEADERS(netinet/in.h)
 674 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 675 [AC_INCLUDES_DEFAULT
 676 #ifdef HAVE_NETINET_IN_H
 677 #include <netinet/in.h>
 678 #endif
 679 ])
 680
 681 if test "$with_readline" = yes; then
 682   AC_CHECK_HEADERS(readline/readline.h, [],
 683                    [AC_CHECK_HEADERS(editline/readline.h, [],
 684                          [AC_CHECK_HEADERS(readline.h, [],
 685                                      [AC_MSG_ERROR([readline header not found
 686 If you have readline already installed, see config.log for details on the
 687 failure.  It is possible the compiler isn't looking in the proper directory.
 688 Use --without-readline to disable readline support.])])])])
 689   AC_CHECK_HEADERS(readline/history.h, [],
 690                    [AC_CHECK_HEADERS(editline/history.h, [],
 691                          [AC_CHECK_HEADERS(history.h, [],
 692                                      [AC_MSG_ERROR([history header not found
 693 If you have readline already installed, see config.log for details on the
 694 failure.  It is possible the compiler isn't looking in the proper directory.
 695 Use --without-readline to disable readline support.])])])])
 696 fi
 697
 698 if test "$with_zlib" = yes; then
 699   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 700 If you have zlib already installed, see config.log for details on the
 701 failure.  It is possible the compiler isn't looking in the proper directory.
 702 Use --without-zlib to disable zlib support.])])
 703 fi
 704
 705 if test "$with_krb4" = yes ; then
 706   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 707 fi
 708
 709 if test "$with_krb5" = yes ; then
 710   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 711   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 712 fi
 713
 714 if test "$with_openssl" = yes ; then
 715   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 716   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 717 fi
 718
 719 if test "$with_pam" = yes ; then
 720   AC_CHECK_HEADERS(security/pam_appl.h, [],
 721                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 722                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 723 fi
 724
 725
 726 ##
 727 ## Types, structures, compiler characteristics
 728 ##
 729
 730 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 731 AC_C_CONST
 732 AC_C_INLINE
 733 AC_C_STRINGIZE
 734 PGAC_C_SIGNED
 735 AC_C_VOLATILE
 736 PGAC_C_FUNCNAME_SUPPORT
 737 AC_STRUCT_TIMEZONE
 738 PGAC_UNION_SEMUN
 739 PGAC_STRUCT_SOCKADDR_UN
 740 PGAC_STRUCT_ADDRINFO
 741
 742 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 743 [#include <sys/param.h>
 744 #include <sys/socket.h>
 745 #include <sys/ucred.h>])
 746
 747 if test "$with_zlib" = yes; then
 748   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 749   # did not).  While we could work around the lack of z_streamp, it
 750   # seems unwise to encourage people to use such old zlib versions...
 751   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 752 Use --without-zlib to disable zlib support.])],
 753                 [#include <zlib.h>])
 754 fi
 755
 756 if test "$with_krb5" = yes; then
 757 # Check for differences between MIT and Heimdal (KTH) releases
 758   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 759                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 760                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 761                                      [#include <krb5.h>])],
 762                    [#include <krb5.h>])
 763   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 764                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 765                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 766                                      [#include <krb5.h>])],
 767                    [#include <krb5.h>])
 768 fi
 769
 770
 771 ##
 772 ## Functions, global variables
 773 ##
 774
 775 PGAC_VAR_INT_TIMEZONE
 776 AC_FUNC_ACCEPT_ARGTYPES
 777 PGAC_FUNC_GETTIMEOFDAY_1ARG
 778
 779 # SunOS doesn't handle negative byte comparisons properly with +/- return
 780 AC_FUNC_MEMCMP
 781
 782 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 783
 784 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 785
 786 AC_CHECK_TYPE([struct sockaddr_in6],
 787               [AC_CHECK_FUNC(inet_ntop,
 788                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])])],
 789               [],
 790 [$ac_includes_default
 791 #include <netinet/in.h>])
 792
 793 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 794 [AC_TRY_LINK(
 795 [#include <machine/vmparam.h>
 796 #include <sys/exec.h>
 797 ],
 798 [PS_STRINGS->ps_nargvstr = 1;
 799 PS_STRINGS->ps_argvstr = "foo";],
 800 [pgac_cv_var_PS_STRINGS=yes],
 801 [pgac_cv_var_PS_STRINGS=no])])
 802 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 803   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 804 fi
 805
 806
 807 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 808 # is missing.  Yes, there are machines that have only one.  We may
 809 # also decide to use snprintf.c if snprintf() is present but does not
 810 # have working "long long int" support -- see below.
 811
 812 pgac_need_repl_snprintf=no
 813 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 814 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 815
 816
 817 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 818 # include/c.h will provide declarations.  Note this is a separate test
 819 # from whether the functions exist in the C library --- there are
 820 # systems that have the functions but don't bother to declare them :-(
 821
 822 AC_CHECK_DECLS([snprintf, vsnprintf])
 823
 824
 825 # do this one the hard way in case isinf() is a macro
 826 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 827 [AC_TRY_LINK(
 828 [#include <math.h>
 829 ],
 830 [double x = 0.0; int res = isinf(x);],
 831 [ac_cv_func_isinf=yes],
 832 [ac_cv_func_isinf=no])])
 833
 834 if test $ac_cv_func_isinf = yes ; then
 835   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 836 else
 837   AC_LIBOBJ(isinf)
 838   # Look for a way to implement a substitute for isinf()
 839   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 840 fi
 841
 842 AC_REPLACE_FUNCS([fseeko gethostname getopt_long getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 843
 844 # system's version of getaddrinfo(), if any, may be used only if we found
 845 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 846 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 847   AC_REPLACE_FUNCS([getaddrinfo])
 848 else
 849   AC_LIBOBJ(getaddrinfo)
 850 fi
 851
 852 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 853 # We override the previous test that said fseeko/ftello didn't exist
 854 # OS tests are also done in include/c.h and port/fseeko.c
 855 case $host_os in bsdi*|netbsd*)
 856 ac_cv_func_fseeko=yes
 857 esac
 858
 859 # Solaris has a very slow qsort in certain cases, so we replace it.
 860 case $host_os in solaris*)
 861 AC_LIBOBJ(qsort) ;;
 862 esac
 863
 864 # Win32 can't to rename or unlink on an open file
 865 case $host_os in win32*)
 866 AC_LIBOBJ(dirmod)
 867 AC_LIBOBJ(opendir) ;;
 868 esac
 869
 870 # Now that rint() is /port, I am not sure this still works, bjm 2003-05-09
 871 # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
 872 # this hackery with HPUXMATHLIB allows us to cope.
 873 HPUXMATHLIB=""
 874 case $host_cpu in
 875   hppa1.1)
 876         if test -r /lib/pa1.1/libm.a ; then
 877             HPUXMATHLIB="-L /lib/pa1.1 -lm"
 878         fi ;;
 879 esac
 880 AC_SUBST(HPUXMATHLIB)
 881
 882 AC_CHECK_FUNCS(rint, [],
 883                [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
 884
 885
 886 if test "$with_readline" = yes; then
 887   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 888   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 889   AC_CHECK_FUNCS([replace_history_entry])
 890 fi
 891
 892
 893 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 894 AC_MSG_CHECKING(for finite)
 895 AC_TRY_LINK([#include <math.h>],
 896             [int dummy=finite(1.0);],
 897             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 898 AC_MSG_RESULT(yes)],
 899             [AC_MSG_RESULT(no)])
 900
 901 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 902 dnl (especially on GNU libc)
 903 dnl See also comments in c.h.
 904 AC_MSG_CHECKING(for sigsetjmp)
 905 AC_TRY_LINK([#include <setjmp.h>],
 906             [sigjmp_buf x; sigsetjmp(x, 1);],
 907             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 908 AC_MSG_RESULT(yes)],
 909             [AC_MSG_RESULT(no)])
 910
 911 AC_CHECK_FUNC(syslog,
 912               [AC_CHECK_HEADER(syslog.h,
 913                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 914
 915 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 916 [AC_TRY_LINK([#include <unistd.h>],
 917   [extern int optreset; optreset = 1;],
 918   [pgac_cv_var_int_optreset=yes],
 919   [pgac_cv_var_int_optreset=no])])
 920 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 921   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 922 fi
 923
 924 AC_CHECK_FUNCS([strtoll strtoq], [break])
 925 AC_CHECK_FUNCS([strtoull strtouq], [break])
 926
 927 # Check for one of atexit() or on_exit()
 928 AC_CHECK_FUNCS(atexit, [],
 929                [AC_CHECK_FUNCS(on_exit, [],
 930                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 931
 932 AC_FUNC_FSEEKO
 933
 934
 935 # This test makes sure that run tests work at all.  Sometimes a shared
 936 # library is found by the linker, but the runtime linker can't find it.
 937 # This check should come after all modifications of compiler or linker
 938 # variables, and before any other run tests.
 939 AC_MSG_CHECKING([test program])
 940 AC_TRY_RUN([int main() { return 0; }],
 941 [AC_MSG_RESULT(ok)],
 942 [AC_MSG_RESULT(failed)
 943 AC_MSG_ERROR([[
 944 *** Could not execute a simple test program.  This may be a problem
 945 *** related to locating shared libraries.  Check the file 'config.log'
 946 *** for the exact reason.]])],
 947 [AC_MSG_RESULT([cross-compiling])])
 948
 949
 950 dnl Check to see if we have a working 64-bit integer type.
 951 dnl This breaks down into two steps:
 952 dnl (1) figure out if the compiler has a 64-bit int type with working
 953 dnl arithmetic, and if so
 954 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
 955 dnl snprintf is the only library routine we really need for int8 support.)
 956 dnl It's entirely possible to have a compiler that handles a 64-bit type
 957 dnl when the C library doesn't; this is fairly likely when using gcc on
 958 dnl an older platform, for example.
 959 dnl If there is no native snprintf() or it does not handle the 64-bit type,
 960 dnl we force our own version of snprintf() to be used instead.
 961 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
 962
 963 PGAC_TYPE_64BIT_INT([long int])
 964
 965 if test x"$HAVE_LONG_INT_64" = x"no" ; then
 966   PGAC_TYPE_64BIT_INT([long long int])
 967 fi
 968
 969
 970 dnl If we need to use "long long int", figure out whether nnnLL notation works.
 971
 972 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
 973   AC_TRY_COMPILE([
 974 #define INT64CONST(x)  x##LL
 975 long long int foo = INT64CONST(0x1234567890123456);
 976 ],
 977         [],
 978         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
 979         [])
 980 fi
 981
 982
 983 # If we found "long int" is 64 bits, assume snprintf handles it.  If
 984 # we found we need to use "long long int", better check.  We cope with
 985 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
 986 # neither works, fall back to our own snprintf emulation (which we
 987 # know uses %lld).
 988
 989 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
 990   if test $pgac_need_repl_snprintf = no; then
 991     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
 992     if test "$LONG_LONG_INT_FORMAT" = ""; then
 993       # Force usage of our own snprintf, since system snprintf is broken
 994       pgac_need_repl_snprintf=yes
 995       LONG_LONG_INT_FORMAT='%lld'
 996     fi
 997   else
 998     # Here if we previously decided we needed to use our own snprintf
 999     LONG_LONG_INT_FORMAT='%lld'
1000   fi
1001   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1002 else
1003   # Here if we are not using 'long long int' at all
1004   INT64_FORMAT='"%ld"'
1005 fi
1006
1007 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1008                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1009
1010 if test $pgac_need_repl_snprintf = yes; then
1011   AC_LIBOBJ(snprintf)
1012 fi
1013
1014 # Need a #define for the size of Datum (unsigned long)
1015 AC_CHECK_SIZEOF([unsigned long])
1016
1017 # Determine memory alignment requirements for the basic C data types.
1018
1019 PGAC_CHECK_ALIGNOF(short)
1020 PGAC_CHECK_ALIGNOF(int)
1021 PGAC_CHECK_ALIGNOF(long)
1022 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1023   PGAC_CHECK_ALIGNOF(long long int)
1024 fi
1025 PGAC_CHECK_ALIGNOF(double)
1026
1027 # Compute maximum alignment of any basic type.
1028 # We assume long's alignment is at least as strong as char, short, or int;
1029 # but we must check long long (if it exists) and double.
1030
1031 MAX_ALIGNOF=$pgac_cv_alignof_long
1032 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1033   MAX_ALIGNOF=$pgac_cv_alignof_double
1034 fi
1035 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1036   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1037 fi
1038 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1039
1040
1041 # Some platforms predefine the types int8, int16, etc.  Only check
1042 # a (hopefully) representative subset.
1043 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1044 [#include <stdio.h>
1045 #ifdef HAVE_SUPPORTDEFS_H
1046 #include <SupportDefs.h>
1047 #endif])
1048
1049 # We also check for sig_atomic_t, which *should* be defined per ANSI
1050 # C, but is missing on some old platforms.
1051 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1052
1053
1054 PGAC_FUNC_POSIX_SIGNALS
1055 if test $ac_cv_func_fseeko = yes; then
1056 AC_SYS_LARGEFILE
1057 fi
1058
1059
1060 # Select semaphore implementation type.
1061 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1062   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1063   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1064 else
1065   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1066     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1067     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1068   else
1069     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1070     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1071   fi
1072 fi
1073
1074
1075 # Select shared-memory implementation type.
1076 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1077 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1078
1079
1080 if test "$enable_nls" = yes ; then
1081   PGAC_CHECK_GETTEXT
1082 fi
1083
1084 # Check for Tcl configuration script tclConfig.sh
1085 if test "$with_tcl" = yes; then
1086     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1087     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1088                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1089     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1090 fi
1091
1092 # Check for Tk configuration script tkConfig.sh
1093 if test "$with_tk" = yes; then
1094     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1095     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1096 fi
1097
1098
1099 #
1100 # Check for DocBook and tools
1101 #
1102 PGAC_PROG_NSGMLS
1103 PGAC_PROG_JADE
1104 PGAC_CHECK_DOCBOOK(3.1)
1105 PGAC_PATH_DOCBOOK_STYLESHEETS
1106 PGAC_PATH_COLLATEINDEX
1107 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1108
1109
1110 # prepare build tree if outside source tree
1111 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1112 # Note 2: /bin/pwd might be better than shell's built-in at getting
1113 #         a symlink-free name.
1114 if test "$no_create" != yes; then
1115   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1116     :
1117   else
1118     AC_SUBST(vpath_build, yes)
1119     _AS_ECHO_N([preparing build tree... ])
1120     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1121     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1122       || AC_MSG_ERROR(failed)
1123     AC_MSG_RESULT(done)
1124   fi
1125 fi
1126
1127
1128 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1129
1130 AC_CONFIG_LINKS([
1131   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1132   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1133   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1134   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1135   src/include/pg_config_os.h:src/include/port/${template}.h
1136   src/Makefile.port:src/makefiles/Makefile.${template}
1137 ])
1138
1139 AC_CONFIG_HEADERS([src/include/pg_config.h],
1140 [
1141 # Update timestamp for pg_config.h (see Makefile.global)
1142 echo >src/include/stamp-h
1143 ])
1144
1145 AC_OUTPUT