granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.461 2006/04/27 14:27:04 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2006, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # C compiler
 210 #
 211
 212 # For historical reasons you can also use --with-CC to specify the C compiler
 213 # to use, although the standard way to do this is to set the CC environment
 214 # variable.
 215 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 216
 217 case $template in
 218   aix) pgac_cc_list="gcc xlc";;
 219  irix) pgac_cc_list="cc";; # no gcc
 220     *) pgac_cc_list="gcc cc";;
 221 esac
 222
 223 AC_PROG_CC([$pgac_cc_list])
 224
 225 unset CFLAGS
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # CFLAGS are selected so:
 233 # If the user specifies something in the environment, that is used.
 234 # else:  If the template file set something, that is used.
 235 # else:  If the compiler is GCC, then we use -O2.
 236 # else:  If the compiler is something else, then we use -0.
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 elif test "${CFLAGS+set}" = set; then
 241   : # (keep what template set)
 242 elif test "$GCC" = yes; then
 243   CFLAGS="-O2"
 244 else
 245   # if the user selected debug mode, don't use -O
 246   if test "$enable_debug" != yes; then
 247     CFLAGS="-O"
 248   fi
 249 fi
 250
 251 # The Intel compiler on Linux supports most gcc options, but not
 252 # all of them, so only add these options if we are really using
 253 # gcc.
 254
 255 if test "$GCC" = yes; then
 256 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 257 choke me
 258 @%:@endif], [ICC=[yes]], [ICC=[no]])
 259   if test "$ICC" = no; then
 260     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 261
 262     # Some versions of GCC support some additional useful warning flags.
 263     # Check whether they are supported, and add them to CFLAGS if so.
 264     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 265     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 266   fi
 267
 268   # Disable strict-aliasing rules; needed for gcc 3.3+
 269   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 270 elif test ${CC} = "xlc"; then
 271   # AIX xlc has to have strict aliasing turned off too
 272   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 273 fi
 274
 275 # supply -g if --enable-debug
 276 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 277   CFLAGS="$CFLAGS -g"
 278 fi
 279
 280 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 281
 282 # We already have this in Makefile.win32, but configure needs it too
 283 if test "$PORTNAME" = "win32"; then
 284   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 285 fi
 286
 287 # Check if the compiler still works with the template settings
 288 AC_MSG_CHECKING([whether the C compiler still works])
 289 AC_TRY_LINK([], [return 0;],
 290   [AC_MSG_RESULT(yes)],
 291   [AC_MSG_RESULT(no)
 292    AC_MSG_ERROR([cannot proceed])])
 293
 294 # Defend against gcc -ffast-math
 295 if test "$GCC" = yes; then
 296 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 297 choke me
 298 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 299 fi
 300
 301 AC_PROG_CPP
 302 AC_SUBST(GCC)
 303
 304 # Create compiler version string
 305 if test x"$GCC" = x"yes" ; then
 306   cc_string="GCC `${CC} --version | sed q`"
 307 else
 308   cc_string=$CC
 309 fi
 310 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 311                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 312                    [A string containing the version number, platform, and C compiler])
 313
 314
 315 #
 316 # Set up TAS assembly code if needed; the template file has now had its
 317 # chance to request this.
 318 #
 319 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 320
 321 if test "$need_tas" = yes ; then
 322   TAS=tas.o
 323 else
 324   TAS=""
 325 fi
 326 AC_SUBST(TAS)
 327
 328
 329 #
 330 # Automatic dependency tracking
 331 #
 332 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 333               [autodepend=yes])
 334 AC_SUBST(autodepend)
 335
 336
 337 #
 338 # Enable assert checks
 339 #
 340 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 341               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 342                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 343
 344
 345 #
 346 # Include directories
 347 #
 348 ac_save_IFS=$IFS
 349 IFS="${IFS}${PATH_SEPARATOR}"
 350 # SRCH_INC comes from the template file
 351 for dir in $with_includes $SRCH_INC; do
 352   if test -d "$dir"; then
 353     INCLUDES="$INCLUDES -I$dir"
 354   else
 355     AC_MSG_WARN([*** Include directory $dir does not exist.])
 356   fi
 357 done
 358 IFS=$ac_save_IFS
 359 AC_SUBST(INCLUDES)
 360
 361
 362 #
 363 # Library directories
 364 #
 365 ac_save_IFS=$IFS
 366 IFS="${IFS}${PATH_SEPARATOR}"
 367 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 368 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 369   if test -d "$dir"; then
 370     LIBDIRS="$LIBDIRS -L$dir"
 371   else
 372     AC_MSG_WARN([*** Library directory $dir does not exist.])
 373   fi
 374 done
 375 IFS=$ac_save_IFS
 376
 377 #
 378 # Enable thread-safe client libraries
 379 #
 380 AC_MSG_CHECKING([allow thread-safe client libraries])
 381 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 382 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 383 if test "$enable_thread_safety" = yes -o \
 384         "$enable_thread_safety_force" = yes; then
 385   enable_thread_safety="yes"    # for 'force'
 386   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 387           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 388 fi
 389 AC_MSG_RESULT([$enable_thread_safety])
 390 AC_SUBST(enable_thread_safety)
 391
 392 #
 393 # Optionally build Tcl modules (PL/Tcl)
 394 #
 395 AC_MSG_CHECKING([whether to build with Tcl])
 396 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 397 AC_MSG_RESULT([$with_tcl])
 398 AC_SUBST([with_tcl])
 399
 400 # We see if the path to the Tcl/Tk configuration scripts is specified.
 401 # This will override the use of tclsh to find the paths to search.
 402
 403 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 404
 405 #
 406 # Optionally build Perl modules (PL/Perl)
 407 #
 408 AC_MSG_CHECKING([whether to build Perl modules])
 409 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 410 AC_MSG_RESULT([$with_perl])
 411 AC_SUBST(with_perl)
 412
 413 #
 414 # Optionally build Python modules (PL/Python)
 415 #
 416 AC_MSG_CHECKING([whether to build Python modules])
 417 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 418 AC_MSG_RESULT([$with_python])
 419 AC_SUBST(with_python)
 420
 421 #
 422 # Kerberos 5
 423 #
 424 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 425 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 426 [
 427   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 428   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 429 ])
 430 AC_MSG_RESULT([$with_krb5])
 431 AC_SUBST(with_krb5)
 432
 433
 434 AC_SUBST(krb_srvtab)
 435
 436
 437 #
 438 # Kerberos configuration parameters
 439 #
 440 PGAC_ARG_REQ(with, krb-srvnam,
 441              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 442              [],
 443              [with_krb_srvnam="postgres"])
 444 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 445                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 446
 447
 448 #
 449 # PAM
 450 #
 451 AC_MSG_CHECKING([whether to build with PAM support])
 452 PGAC_ARG_BOOL(with, pam, no,
 453               [  --with-pam              build with PAM support],
 454               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 455 AC_MSG_RESULT([$with_pam])
 456 AC_SUBST(with_pam)
 457
 458
 459 #
 460 # LDAP
 461 #
 462 AC_MSG_CHECKING([whether to build with LDAP support])
 463 PGAC_ARG_BOOL(with, ldap, no,
 464               [  --with-ldap             build with LDAP support],
 465               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 466 AC_MSG_RESULT([$with_ldap])
 467 AC_SUBST(with_ldap)
 468
 469
 470 #
 471 # Bonjour
 472 #
 473 AC_MSG_CHECKING([whether to build with Bonjour support])
 474 PGAC_ARG_BOOL(with, bonjour, no,
 475               [  --with-bonjour          build with Bonjour support],
 476               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 477 AC_MSG_RESULT([$with_bonjour])
 478 AC_SUBST(with_bonjour)
 479
 480
 481 #
 482 # OpenSSL
 483 #
 484 AC_MSG_CHECKING([whether to build with OpenSSL support])
 485 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 486               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 487 AC_MSG_RESULT([$with_openssl])
 488 AC_SUBST(with_openssl)
 489
 490
 491 #
 492 # Prefer libedit
 493 #
 494 PGAC_ARG_BOOL(with, libedit-preferred, no,
 495               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 496
 497
 498 #
 499 # Readline
 500 #
 501 PGAC_ARG_BOOL(with, readline, yes,
 502               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 503 # readline on MinGW has problems with backslashes in psql and other bugs.
 504 # This is particularly a problem with non-US code pages.
 505 # Therefore disable its use until we understand the cause. 2004-07-20
 506 if test "$PORTNAME" = "win32"; then
 507   if test "$with_readline" = yes; then
 508     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 509     with_readline=no
 510   fi
 511 fi
 512
 513
 514 #
 515 # Zlib
 516 #
 517 PGAC_ARG_BOOL(with, zlib, yes,
 518               [  --without-zlib          do not use Zlib])
 519 AC_SUBST(with_zlib)
 520
 521 #
 522 # Elf
 523 #
 524
 525 # Assume system is ELF if it predefines __ELF__ as 1,
 526 # otherwise believe host_os based default.
 527 case $host_os in
 528     freebsd1*|freebsd2*) elf=no;;
 529     freebsd3*|freebsd4*) elf=yes;;
 530 esac
 531
 532 AC_EGREP_CPP(yes,
 533 [#if __ELF__
 534   yes
 535 #endif
 536 ],
 537 [ELF_SYS=true],
 538 [if test "X$elf" = "Xyes" ; then
 539   ELF_SYS=true
 540 else
 541   ELF_SYS=
 542 fi])
 543 AC_SUBST(ELF_SYS)
 544
 545 #
 546 # Assignments
 547 #
 548
 549 CPPFLAGS="$CPPFLAGS $INCLUDES"
 550 LDFLAGS="$LDFLAGS $LIBDIRS"
 551
 552 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 553 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 554
 555 AC_ARG_VAR(LDFLAGS_SL)
 556
 557 AC_PROG_AWK
 558 PGAC_PATH_FLEX
 559 AC_PROG_LN_S
 560 PGAC_PROG_LD
 561 AC_SUBST(LD)
 562 AC_SUBST(with_gnu_ld)
 563 case $host_os in sysv5*)
 564   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 565   [
 566     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 567     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 568     LDFLAGS=$pgac_save_LDFLAGS
 569   ])
 570   ld_R_works=$pgac_cv_prog_ld_R
 571   AC_SUBST(ld_R_works)
 572 esac
 573 AC_PROG_RANLIB
 574 AC_PATH_PROG(TAR, tar)
 575 PGAC_CHECK_STRIP
 576
 577 AC_CHECK_PROGS(YACC, ['bison -y'])
 578
 579 if test "$YACC"; then
 580   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 581     AC_MSG_WARN([
 582 *** If you are going to modify the grammar files or build from CVS, the installed
 583 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 584   fi
 585 fi
 586
 587 if test -z "$YACC"; then
 588   AC_MSG_WARN([
 589 *** Without Bison you will not be able to build PostgreSQL from CVS or
 590 *** change any of the parser definition files.  You can obtain Bison from
 591 *** a GNU mirror site.  (If you are using the official distribution of
 592 *** PostgreSQL then you do not need to worry about this because the Bison
 593 *** output is pre-generated.)  To use a different yacc program (possible,
 594 *** but not recommended), set the environment variable YACC before running
 595 *** 'configure'.])
 596 fi
 597 AC_SUBST(YFLAGS)
 598
 599 PGAC_PATH_PERL
 600 if test "$with_perl" = yes; then
 601   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 602   PGAC_CHECK_PERL_EMBED_LDFLAGS
 603 fi
 604
 605 if test "$with_python" = yes; then
 606   PGAC_PATH_PYTHON
 607   PGAC_CHECK_PYTHON_EMBED_SETUP
 608 fi
 609
 610 # Supply a numeric version string for use by 3rd party add-ons
 611 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 612 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 613 tr '.' '        ' |
 614 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 615 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 616
 617 ##
 618 ## Libraries
 619 ##
 620
 621 AC_SEARCH_LIBS(setproctitle, util)
 622 AC_SEARCH_LIBS(pow, m)
 623 AC_SEARCH_LIBS(dlopen, dl)
 624 AC_SEARCH_LIBS(socket, [socket wsock32])
 625 AC_SEARCH_LIBS(shl_load, dld)
 626 # We only use libld in port/dynloader/aix.c
 627 case $host_os in
 628      aix*)
 629         AC_SEARCH_LIBS(ldopen, ld)
 630         ;;
 631 esac
 632 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 633 AC_SEARCH_LIBS(crypt, crypt)
 634 # Solaris:
 635 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 636 # Cygwin:
 637 AC_SEARCH_LIBS(shmget, cygipc)
 638
 639 if test "$with_readline" = yes; then
 640   PGAC_CHECK_READLINE
 641   if test x"$pgac_cv_check_readline" = x"no"; then
 642     AC_MSG_ERROR([readline library not found
 643 If you have readline already installed, see config.log for details on the
 644 failure.  It is possible the compiler isn't looking in the proper directory.
 645 Use --without-readline to disable readline support.])
 646   fi
 647 fi
 648
 649 if test "$with_zlib" = yes; then
 650   AC_CHECK_LIB(z, inflate, [],
 651                [AC_MSG_ERROR([zlib library not found
 652 If you have zlib already installed, see config.log for details on the
 653 failure.  It is possible the compiler isn't looking in the proper directory.
 654 Use --without-zlib to disable zlib support.])])
 655 fi
 656
 657 if test "$enable_spinlocks" = yes; then
 658   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 659 else
 660   AC_MSG_WARN([
 661 *** Not using spinlocks will cause poor performance.])
 662 fi
 663
 664 if test "$with_krb5" = yes ; then
 665   if test "$PORTNAME" != "win32"; then
 666      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 667                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 668      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 669                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 670      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 671                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 672   else
 673      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 674                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 675   fi
 676 fi
 677
 678 if test "$with_openssl" = yes ; then
 679   dnl Order matters!
 680   if test "$PORTNAME" != "win32"; then
 681      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 682      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 683   else
 684      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 685      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 686   fi
 687 fi
 688
 689 if test "$with_pam" = yes ; then
 690   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 691 fi
 692
 693
 694 if test "$with_ldap" = yes ; then
 695   if test "$PORTNAME" != "win32"; then
 696      AC_CHECK_LIB(ldap,    ldap_bind, [], [AC_MSG_ERROR([library 'ldap' is required for LDAP])])
 697   else
 698      AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
 699   fi
 700 fi
 701
 702 ##
 703 ## Header files
 704 ##
 705
 706 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 707 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 708
 709 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 710 # netinet/in.h is included first.
 711 AC_CHECK_HEADERS(netinet/in.h)
 712 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 713 [AC_INCLUDES_DEFAULT
 714 #ifdef HAVE_NETINET_IN_H
 715 #include <netinet/in.h>
 716 #endif
 717 ])
 718
 719 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 720   AC_CHECK_HEADERS(readline/readline.h, [],
 721         [AC_CHECK_HEADERS(readline.h, [],
 722                 [AC_MSG_ERROR([readline header not found
 723 If you have readline already installed, see config.log for details on the
 724 failure.  It is possible the compiler isn't looking in the proper directory.
 725 Use --without-readline to disable readline support.])])])
 726   AC_CHECK_HEADERS(readline/history.h, [],
 727         [AC_CHECK_HEADERS(history.h, [],
 728                 [AC_MSG_ERROR([history header not found
 729 If you have readline already installed, see config.log for details on the
 730 failure.  It is possible the compiler isn't looking in the proper directory.
 731 Use --without-readline to disable readline support.])])])
 732 fi
 733
 734 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 735 # Some installations of libedit usurp /usr/include/readline/, which seems
 736 # bad practice, since in combined installations readline will have its headers
 737 # there.  We might have to resort to AC_EGREP checks to make sure we found
 738 # the proper header...
 739   AC_CHECK_HEADERS(editline/readline.h, [],
 740         [AC_CHECK_HEADERS(readline.h, [],
 741                 [AC_CHECK_HEADERS(readline/readline.h, [],
 742                         [AC_MSG_ERROR([readline header not found
 743 If you have libedit already installed, see config.log for details on the
 744 failure.  It is possible the compiler isn't looking in the proper directory.
 745 Use --without-readline to disable libedit support.])])])])
 746   AC_CHECK_HEADERS(editline/history.h, [],
 747         [AC_CHECK_HEADERS(history.h, [],
 748                 [AC_CHECK_HEADERS(readline/history.h, [],
 749                         [AC_MSG_ERROR([history header not found
 750 If you have libedit already installed, see config.log for details on the
 751 failure.  It is possible the compiler isn't looking in the proper directory.
 752 Use --without-readline to disable libedit support.])])])])
 753 fi
 754
 755 if test "$with_zlib" = yes; then
 756   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 757 If you have zlib already installed, see config.log for details on the
 758 failure.  It is possible the compiler isn't looking in the proper directory.
 759 Use --without-zlib to disable zlib support.])])
 760 fi
 761
 762 if test "$with_krb5" = yes ; then
 763   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 764 fi
 765
 766 if test "$with_openssl" = yes ; then
 767   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 768   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 769 fi
 770
 771 if test "$with_pam" = yes ; then
 772   AC_CHECK_HEADERS(security/pam_appl.h, [],
 773                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 774                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 775 fi
 776
 777 if test "$with_ldap" = yes ; then
 778   if test "$PORTNAME" != "win32"; then
 779      AC_CHECK_HEADERS(ldap.h, [],
 780                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 781   else
 782      AC_CHECK_HEADERS(winldap.h, [],
 783                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 784                       [AC_INCLUDES_DEFAULT
 785 #include <windows.h>
 786                       ])
 787   fi
 788 fi
 789
 790 if test "$with_bonjour" = yes ; then
 791   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 792 fi
 793
 794
 795 ##
 796 ## Types, structures, compiler characteristics
 797 ##
 798
 799 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 800 AC_C_CONST
 801 AC_C_INLINE
 802 AC_C_STRINGIZE
 803 PGAC_C_SIGNED
 804 AC_C_VOLATILE
 805 PGAC_C_FUNCNAME_SUPPORT
 806 PGAC_STRUCT_TIMEZONE
 807 PGAC_UNION_SEMUN
 808 PGAC_STRUCT_SOCKADDR_UN
 809 PGAC_STRUCT_SOCKADDR_STORAGE
 810 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 811 PGAC_STRUCT_ADDRINFO
 812
 813 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 814 [#include <sys/param.h>
 815 #include <sys/types.h>
 816 #include <sys/socket.h>
 817 #include <sys/ucred.h>])
 818
 819 AC_CHECK_TYPES([struct option], [], [],
 820 [#ifdef HAVE_GETOPT_H
 821 #include <getopt.h>
 822 #endif])
 823
 824 if test "$with_zlib" = yes; then
 825   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 826   # did not).  While we could work around the lack of z_streamp, it
 827   # seems unwise to encourage people to use such old zlib versions...
 828   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 829 Use --without-zlib to disable zlib support.])],
 830                 [#include <zlib.h>])
 831 fi
 832
 833 if test "$with_krb5" = yes; then
 834 # Check for differences between MIT and Heimdal (KTH) releases
 835   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 836                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 837                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 838                                      [#include <krb5.h>])],
 839                    [#include <krb5.h>])
 840   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 841                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 842                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 843                                      [#include <krb5.h>])],
 844                    [#include <krb5.h>])
 845 fi
 846
 847 # This is probably only present on Darwin, but may as well check always
 848 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 849
 850 ##
 851 ## Functions, global variables
 852 ##
 853
 854 PGAC_VAR_INT_TIMEZONE
 855 AC_FUNC_ACCEPT_ARGTYPES
 856 PGAC_FUNC_GETTIMEOFDAY_1ARG
 857
 858 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 859
 860 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 861
 862 HAVE_IPV6=no
 863 AC_CHECK_TYPE([struct sockaddr_in6],
 864         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 865          HAVE_IPV6=yes],
 866         [],
 867 [$ac_includes_default
 868 #include <netinet/in.h>])
 869 AC_SUBST(HAVE_IPV6)
 870
 871 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 872 [AC_TRY_LINK(
 873 [#include <machine/vmparam.h>
 874 #include <sys/exec.h>
 875 ],
 876 [PS_STRINGS->ps_nargvstr = 1;
 877 PS_STRINGS->ps_argvstr = "foo";],
 878 [pgac_cv_var_PS_STRINGS=yes],
 879 [pgac_cv_var_PS_STRINGS=no])])
 880 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 881   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 882 fi
 883
 884
 885 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 886 # is missing.  Yes, there are machines that have only one.  We may
 887 # also decide to use snprintf.c if snprintf() is present but does not
 888 # have all the features we need --- see below.
 889
 890 if test "$PORTNAME" = "win32"; then
 891   # Win32 gets snprintf.c built unconditionally.
 892   #
 893   # To properly translate all NLS languages strings, we must support the
 894   # *printf() %$ format, which allows *printf() arguments to be selected
 895   # by position in the translated string.
 896   #
 897   # libintl versions < 0.13 use the native *printf() functions, and Win32
 898   # *printf() doesn't understand %$, so we must use our /port versions,
 899   # which do understand %$. libintl versions >= 0.13 include their own
 900   # *printf versions on Win32.  The libintl 0.13 release note text is:
 901   #
 902   #   C format strings with positions, as they arise when a translator
 903   #   needs to reorder a sentence, are now supported on all platforms.
 904   #   On those few platforms (NetBSD and Woe32) for which the native
 905   #   printf()/fprintf()/... functions don't support such format
 906   #   strings, replacements are provided through <libintl.h>.
 907   #
 908   # We could use libintl >= 0.13's *printf() if we were sure that we had
 909   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 910   # to guarantee that, it is best to just use our own, so we are sure to
 911   # get %$ support. In include/port.h we disable the *printf() macros
 912   # that might have been defined by libintl.
 913   #
 914   # We do this unconditionally whether NLS is used or not so we are sure
 915   # that all Win32 libraries and binaries behave the same.
 916   pgac_need_repl_snprintf=yes
 917 else
 918   pgac_need_repl_snprintf=no
 919   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 920   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 921 fi
 922
 923
 924 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 925 # include/c.h will provide declarations.  Note this is a separate test
 926 # from whether the functions exist in the C library --- there are
 927 # systems that have the functions but don't bother to declare them :-(
 928
 929 AC_CHECK_DECLS([snprintf, vsnprintf])
 930
 931
 932 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 933 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 934 [AC_TRY_LINK([
 935 #include <math.h>
 936 double glob_double;
 937 ],
 938 [return isinf(glob_double) ? 0 : 1;],
 939 [ac_cv_func_isinf=yes],
 940 [ac_cv_func_isinf=no])])
 941
 942 if test $ac_cv_func_isinf = yes ; then
 943   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 944 else
 945   AC_LIBOBJ(isinf)
 946   # Look for a way to implement a substitute for isinf()
 947   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 948 fi
 949
 950 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 951
 952 # System's version of getaddrinfo(), if any, may be used only if we found
 953 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 954 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 955 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 956 # because we want to use our own getaddrinfo.c on Windows anyway.)
 957 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 958   AC_REPLACE_FUNCS([getaddrinfo])
 959 else
 960   AC_LIBOBJ(getaddrinfo)
 961 fi
 962
 963 # similarly, use system's getopt_long() only if system provides struct option.
 964 if test x"$ac_cv_type_struct_option" = xyes ; then
 965   AC_REPLACE_FUNCS([getopt_long])
 966 else
 967   AC_LIBOBJ(getopt_long)
 968 fi
 969
 970 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 971 # We override the previous test that said fseeko/ftello didn't exist
 972 # OS tests are also done in include/c.h and port/fseeko.c
 973 case $host_os in bsdi*|netbsd*)
 974 ac_cv_func_fseeko=yes
 975 esac
 976
 977 # Solaris has a very slow qsort in certain cases, so we replace it:
 978 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 979 # Supposedly it is fixed in Solaris, but not sure which version, and
 980 # no confirmed testing.  2005-12-16
 981 if test "$PORTNAME" = "solaris"; then
 982 AC_LIBOBJ(qsort)
 983 fi
 984
 985 # Win32 support
 986 if test "$PORTNAME" = "win32"; then
 987 AC_LIBOBJ(gettimeofday)
 988 AC_LIBOBJ(kill)
 989 AC_LIBOBJ(open)
 990 AC_LIBOBJ(rand)
 991 AC_DEFINE([HAVE_SYMLINK], 1,
 992           [Define to 1 if you have the `symlink' function.])
 993 fi
 994
 995 if test "$with_readline" = yes; then
 996   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 997   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 998   AC_CHECK_FUNCS([replace_history_entry])
 999 fi
1000
1001
1002 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
1003 AC_MSG_CHECKING(for finite)
1004 AC_TRY_LINK([
1005 #include <math.h>
1006 double glob_double;
1007 ],
1008             [return finite(glob_double) ? 0 : 1;],
1009             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
1010 AC_MSG_RESULT(yes)],
1011             [AC_MSG_RESULT(no)])
1012
1013 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1014 dnl (especially on GNU libc)
1015 dnl See also comments in c.h.
1016 AC_MSG_CHECKING(for sigsetjmp)
1017 AC_TRY_LINK([#include <setjmp.h>],
1018             [sigjmp_buf x; sigsetjmp(x, 1);],
1019             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1020 AC_MSG_RESULT(yes)],
1021             [AC_MSG_RESULT(no)])
1022
1023 AC_CHECK_FUNC(syslog,
1024               [AC_CHECK_HEADER(syslog.h,
1025                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1026
1027 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1028 [AC_TRY_LINK([#include <unistd.h>],
1029   [extern int optreset; optreset = 1;],
1030   [pgac_cv_var_int_optreset=yes],
1031   [pgac_cv_var_int_optreset=no])])
1032 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1033   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1034 fi
1035
1036 AC_CHECK_FUNCS([strtoll strtoq], [break])
1037 AC_CHECK_FUNCS([strtoull strtouq], [break])
1038
1039 # Check for one of atexit() or on_exit()
1040 AC_CHECK_FUNCS(atexit, [],
1041                [AC_CHECK_FUNCS(on_exit, [],
1042                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1043
1044 AC_FUNC_FSEEKO
1045
1046 #
1047 # Pthreads
1048 #
1049 # For each platform, we need to know about any special compile and link
1050 # libraries, and whether the normal C function names are thread-safe.
1051 # See the comment at the top of src/port/thread.c for more information.
1052 #
1053 if test "$enable_thread_safety" = yes; then
1054 ACX_PTHREAD     # set thread flags
1055
1056 # Some platforms use these, so just defineed them.  They can't hurt if they
1057 # are not supported.
1058 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1059
1060
1061 # At this point, we don't want to muck with the compiler name for threading.
1062 # Let's see who fails, perhaps AIX.  2004-04-23
1063 if test "$PTHREAD_CC" != "$CC"; then
1064 AC_MSG_ERROR([
1065 PostgreSQL does not support platforms that require a special
1066 compiler binary for thread-safety.
1067 ])
1068 fi
1069
1070 if test "$THREAD_SUPPORT" = no; then
1071 AC_MSG_ERROR([
1072 Cannot enable threads on your platform.
1073 Your platform is known to not support thread-safe programs.
1074 For details, compile and run src/bin/pg_thread_test.
1075 ])
1076 fi
1077
1078 # Check for *_r functions
1079 _CFLAGS="$CFLAGS"
1080 _LIBS="$LIBS"
1081 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1082 LIBS="$LIBS $PTHREAD_LIBS"
1083
1084 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1085
1086 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1087
1088 # Do test here with the proper thread flags
1089 PGAC_FUNC_GETPWUID_R_5ARG
1090 PGAC_FUNC_STRERROR_R_INT
1091
1092 CFLAGS="$_CFLAGS"
1093 LIBS="$_LIBS"
1094
1095 else
1096 # do not use values from template file
1097 PTHREAD_CFLAGS=
1098 PTHREAD_LIBS=
1099 fi
1100
1101 AC_SUBST(PTHREAD_CFLAGS)
1102 AC_SUBST(PTHREAD_LIBS)
1103
1104
1105 # This test makes sure that run tests work at all.  Sometimes a shared
1106 # library is found by the linker, but the runtime linker can't find it.
1107 # This check should come after all modifications of compiler or linker
1108 # variables, and before any other run tests.
1109 AC_MSG_CHECKING([test program])
1110 AC_TRY_RUN([int main() { return 0; }],
1111 [AC_MSG_RESULT(ok)],
1112 [AC_MSG_RESULT(failed)
1113 AC_MSG_ERROR([[
1114 *** Could not execute a simple test program.  This may be a problem
1115 *** related to locating shared libraries.  Check the file 'config.log'
1116 *** for the exact reason.]])],
1117 [AC_MSG_RESULT([cross-compiling])])
1118
1119 # --------------------
1120 # Run tests below here
1121 # --------------------
1122
1123 # Force use of our snprintf if system's doesn't do arg control
1124 # See comment above at snprintf test for details.
1125 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1126   PGAC_FUNC_PRINTF_ARG_CONTROL
1127   if test $pgac_cv_printf_arg_control != yes ; then
1128     pgac_need_repl_snprintf=yes
1129   fi
1130 fi
1131
1132
1133 dnl Check to see if we have a working 64-bit integer type.
1134 dnl This breaks down into two steps:
1135 dnl (1) figure out if the compiler has a 64-bit int type with working
1136 dnl arithmetic, and if so
1137 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1138 dnl snprintf is the only library routine we really need for int8 support.)
1139 dnl It's entirely possible to have a compiler that handles a 64-bit type
1140 dnl when the C library doesn't; this is fairly likely when using gcc on
1141 dnl an older platform, for example.
1142 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1143 dnl we force our own version of snprintf() to be used instead.
1144 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1145
1146 PGAC_TYPE_64BIT_INT([long int])
1147
1148 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1149   PGAC_TYPE_64BIT_INT([long long int])
1150 fi
1151
1152
1153 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1154
1155 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1156   AC_TRY_COMPILE([
1157 #define INT64CONST(x)  x##LL
1158 long long int foo = INT64CONST(0x1234567890123456);
1159 ],
1160         [],
1161         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1162         [])
1163 fi
1164
1165
1166 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1167 # we found we need to use "long long int", better check.  We cope with
1168 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1169 # work, fall back to our own snprintf emulation (which we know uses %lld).
1170
1171 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1172   if test $pgac_need_repl_snprintf = no; then
1173     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1174     if test "$LONG_LONG_INT_FORMAT" = ""; then
1175       # Force usage of our own snprintf, since system snprintf is broken
1176       pgac_need_repl_snprintf=yes
1177       LONG_LONG_INT_FORMAT='%lld'
1178     fi
1179   else
1180     # Here if we previously decided we needed to use our own snprintf
1181     LONG_LONG_INT_FORMAT='%lld'
1182   fi
1183   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1184   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1185   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1186 else
1187   # Here if we are not using 'long long int' at all
1188   INT64_FORMAT='"%ld"'
1189   UINT64_FORMAT='"%lu"'
1190 fi
1191
1192 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1193                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1194
1195 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1196                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1197
1198 # Now we have checked all the reasons to replace snprintf
1199 if test $pgac_need_repl_snprintf = yes; then
1200   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1201   AC_LIBOBJ(snprintf)
1202 fi
1203
1204 # Need a #define for the size of Datum (unsigned long)
1205 AC_CHECK_SIZEOF([unsigned long])
1206
1207 # And one for the size of size_t (enables tweaks for > 32bit address space)
1208 AC_CHECK_SIZEOF([size_t])
1209
1210 # Determine memory alignment requirements for the basic C data types.
1211
1212 PGAC_CHECK_ALIGNOF(short)
1213 PGAC_CHECK_ALIGNOF(int)
1214 PGAC_CHECK_ALIGNOF(long)
1215 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1216   PGAC_CHECK_ALIGNOF(long long int)
1217 fi
1218 PGAC_CHECK_ALIGNOF(double)
1219
1220 # Compute maximum alignment of any basic type.
1221 # We assume long's alignment is at least as strong as char, short, or int;
1222 # but we must check long long (if it exists) and double.
1223
1224 MAX_ALIGNOF=$pgac_cv_alignof_long
1225 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1226   MAX_ALIGNOF=$pgac_cv_alignof_double
1227 fi
1228 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1229   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1230 fi
1231 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1232
1233
1234 # Some platforms predefine the types int8, int16, etc.  Only check
1235 # a (hopefully) representative subset.
1236 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1237 [#include <stdio.h>
1238 #ifdef HAVE_SUPPORTDEFS_H
1239 #include <SupportDefs.h>
1240 #endif])
1241
1242 # We also check for sig_atomic_t, which *should* be defined per ANSI
1243 # C, but is missing on some old platforms.
1244 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1245
1246
1247 if test x"$template" != x"win32"
1248 then
1249 PGAC_FUNC_POSIX_SIGNALS
1250 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1251   AC_MSG_ERROR([
1252 *** Thread-safety requires POSIX signals, which are not supported by your
1253 *** operating system.
1254 ])
1255 fi
1256 fi
1257
1258 if test $ac_cv_func_fseeko = yes; then
1259 AC_SYS_LARGEFILE
1260 fi
1261
1262 # SunOS doesn't handle negative byte comparisons properly with +/- return
1263 AC_FUNC_MEMCMP
1264
1265
1266 # Select semaphore implementation type.
1267 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1268   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1269   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1270 else
1271   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1272     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1273     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1274   else
1275     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1276     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1277   fi
1278 fi
1279
1280
1281 # Select shared-memory implementation type.
1282 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1283 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1284
1285
1286 # If not set in template file, set bytes to use libc memset()
1287 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1288   MEMSET_LOOP_LIMIT=1024
1289 fi
1290 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1291
1292
1293 if test "$enable_nls" = yes ; then
1294   PGAC_CHECK_GETTEXT
1295 fi
1296
1297 # Check for Tcl configuration script tclConfig.sh
1298 if test "$with_tcl" = yes; then
1299     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1300     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1301                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1302     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1303     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1304     ac_save_CPPFLAGS=$CPPFLAGS
1305     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1306     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1307     CPPFLAGS=$ac_save_CPPFLAGS
1308 fi
1309
1310 #
1311 # Check for DocBook and tools
1312 #
1313 PGAC_PROG_NSGMLS
1314 PGAC_PROG_JADE
1315 PGAC_CHECK_DOCBOOK(4.2)
1316 PGAC_PATH_DOCBOOK_STYLESHEETS
1317 PGAC_PATH_COLLATEINDEX
1318 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1319
1320 # Thread testing
1321
1322 # We have to run the thread test near the end so we have all our symbols
1323 # defined.  Cross compiling throws a warning.
1324 #
1325 if test "$enable_thread_safety_force" = yes; then
1326 if test x"$template" != x"win32"
1327 then
1328   AC_MSG_WARN([
1329 *** Skipping thread test program.  --enable-thread-safety-force was used.
1330 *** Run the program in src/test/thread on the your machine and add
1331 proper locking function calls to your applications to guarantee thread
1332 safety.
1333 ])
1334 else
1335 AC_MSG_WARN([*** Skipping thread test on Win32])
1336 fi
1337 elif test "$enable_thread_safety" = yes; then
1338 if test x"$template" != x"win32"
1339 then
1340 AC_MSG_CHECKING([thread safety of required library functions])
1341
1342 _CFLAGS="$CFLAGS"
1343 _LIBS="$LIBS"
1344 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1345 LIBS="$LIBS $PTHREAD_LIBS"
1346 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1347   [AC_MSG_RESULT(yes)],
1348   [AC_MSG_RESULT(no)
1349   AC_MSG_ERROR([
1350 *** Thread test program failed.  Your platform is not thread-safe.
1351 *** Check the file 'config.log'for the exact reason.
1352 ***
1353 *** You can use the configure option --enable-thread-safety-force
1354 *** to force threads to be enabled.  However, you must then run
1355 *** the program in src/test/thread and add locking function calls
1356 *** to your applications to guarantee thread safety.
1357 ])],
1358   [AC_MSG_RESULT(maybe)
1359   AC_MSG_WARN([
1360 *** Skipping thread test program because of cross-compile build.
1361 *** Run the program in src/test/thread on the target machine.
1362 ])])
1363 CFLAGS="$_CFLAGS"
1364 LIBS="$_LIBS"
1365 else
1366 AC_MSG_WARN([*** Skipping thread test on Win32])
1367 fi
1368 fi
1369
1370 # prepare build tree if outside source tree
1371 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1372 # Note 2: /bin/pwd might be better than shell's built-in at getting
1373 #         a symlink-free name.
1374 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1375   vpath_build=no
1376 else
1377   vpath_build=yes
1378   if test "$no_create" != yes; then
1379     _AS_ECHO_N([preparing build tree... ])
1380     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1381     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1382       || AC_MSG_ERROR(failed)
1383     AC_MSG_RESULT(done)
1384   fi
1385 fi
1386 AC_SUBST(vpath_build)
1387
1388
1389 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1390
1391 AC_CONFIG_LINKS([
1392   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1393   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1394   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1395   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1396   src/include/pg_config_os.h:src/include/port/${template}.h
1397   src/Makefile.port:src/makefiles/Makefile.${template}
1398 ])
1399
1400 if test "$PORTNAME" = "win32"; then
1401 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1402 # Links sometimes fail undetected on Mingw -
1403 # so here we detect it and warn the user
1404 for FILE in $CONFIG_LINKS
1405  do
1406         # test -e works for symlinks in the MinGW console
1407         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1408  done
1409 ])
1410 fi
1411
1412 AC_CONFIG_HEADERS([src/include/pg_config.h],
1413 [
1414 # Update timestamp for pg_config.h (see Makefile.global)
1415 echo >src/include/stamp-h
1416 ])
1417
1418 AC_OUTPUT
1419