granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.302 2003/11/03 14:42:08 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.5devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55 # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 #
 157 # NLS
 158 #
 159 AC_MSG_CHECKING([whether NLS is wanted])
 160 PGAC_ARG_OPTARG(enable, nls,
 161                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 162                 [],
 163                 [WANTED_LANGUAGES=$enableval],
 164                 [AC_DEFINE(ENABLE_NLS, 1,
 165                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 166 AC_MSG_RESULT([$enable_nls])
 167 AC_SUBST(enable_nls)
 168 AC_SUBST(WANTED_LANGUAGES)
 169
 170 #
 171 # Default port number (--with-pgport), default 5432
 172 #
 173 AC_MSG_CHECKING([for default port number])
 174 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 175              [default_port=$withval],
 176              [default_port=5432])
 177 AC_MSG_RESULT([$default_port])
 178 # Need both of these because some places want an integer and some a string
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 180 [Define to the default TCP port number on which the server listens and
 181 to which clients will try to connect.  This can be overridden at run-time,
 182 but it's convenient if your clients have the right default compiled in.
 183 (--with-pgport=PORTNUM)])
 184 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 185                    [Define to the default TCP port number as a string constant.])
 186 AC_SUBST(default_port)
 187
 188 #
 189 # Option to disable shared libraries
 190 #
 191 PGAC_ARG_BOOL(enable, shared, yes,
 192               [  --disable-shared        do not build shared libraries])
 193 AC_SUBST(enable_shared)
 194
 195 #
 196 # '-rpath'-like feature can be disabled
 197 #
 198 PGAC_ARG_BOOL(enable, rpath, yes,
 199               [  --disable-rpath         do not embed shared library search path in executables])
 200 AC_SUBST(enable_rpath)
 201
 202 #
 203 # Spinlocks
 204 #
 205 PGAC_ARG_BOOL(enable, spinlocks, yes,
 206               [  --disable-spinlocks     do not use spinlocks])
 207
 208 #
 209 # --enable-debug adds -g to compiler flags
 210 #
 211 PGAC_ARG_BOOL(enable, debug, no,
 212               [  --enable-debug          build with debugging symbols (-g)])
 213 AC_SUBST(enable_debug)
 214
 215 #
 216 # C compiler
 217 #
 218
 219 # For historical reasons you can also use --with-CC to specify the C compiler
 220 # to use, although the standard way to do this is to set the CC environment
 221 # variable.
 222 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 223
 224 case $template in
 225   aix) pgac_cc_list="gcc xlc";;
 226  irix) pgac_cc_list="cc";; # no gcc
 227     *) pgac_cc_list="gcc cc";;
 228 esac
 229
 230 AC_PROG_CC([$pgac_cc_list])
 231
 232 unset CFLAGS
 233
 234 #
 235 # Read the template
 236 #
 237 . "$srcdir/src/template/$template" || exit
 238
 239 # CFLAGS are selected so:
 240 # If the user specifies something in the environment, that is used.
 241 # else:  If the template file set something, that is used.
 242 # else:  If the compiler is GCC, then we use -O2.
 243 # else:  If the compiler is something else, then we use -0.
 244
 245 if test "$ac_env_CFLAGS_set" = set; then
 246   CFLAGS=$ac_env_CFLAGS_value
 247 elif test "${CFLAGS+set}" = set; then
 248   : # (keep what template set)
 249 elif test "$GCC" = yes; then
 250   CFLAGS="-O2"
 251 else
 252   # if the user selected debug mode, don't use -O
 253   if test "$enable_debug" != yes; then
 254     CFLAGS="-O"
 255   fi
 256 fi
 257
 258 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 259 PGAC_PROG_CC_NO_STRICT_ALIASING
 260
 261 # supply -g if --enable-debug
 262 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 263   CFLAGS="$CFLAGS -g"
 264 fi
 265
 266 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 267
 268 # We already have this in Makefile.win32, but configure needs it too
 269 if test "$PORTNAME" = "win32"; then
 270   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32"
 271 fi
 272
 273 # Check if the compiler still works with the template settings
 274 AC_MSG_CHECKING([whether the C compiler still works])
 275 AC_TRY_LINK([], [return 0;],
 276   [AC_MSG_RESULT(yes)],
 277   [AC_MSG_RESULT(no)
 278    AC_MSG_ERROR([cannot proceed])])
 279
 280 # Defend against gcc -ffast-math
 281 if test "$GCC" = yes; then
 282 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 283 choke me
 284 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 285 fi
 286
 287 AC_PROG_CPP
 288 AC_SUBST(GCC)
 289
 290 # Create compiler version string
 291 if test x"$GCC" = x"yes" ; then
 292   cc_string="GCC `${CC} --version | sed q`"
 293 else
 294   cc_string=$CC
 295 fi
 296 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 297                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 298                    [A string containing the version number, platform, and C compiler])
 299
 300
 301 #
 302 # Automatic dependency tracking
 303 #
 304 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 305               [autodepend=yes])
 306 AC_SUBST(autodepend)
 307
 308
 309 #
 310 # Enable assert checks
 311 #
 312 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 313               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 314                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 315
 316
 317 #
 318 # Include directories
 319 #
 320 ac_save_IFS=$IFS
 321 IFS="${IFS}:"
 322 # SRCH_INC comes from the template file
 323 for dir in $with_includes $SRCH_INC; do
 324   if test -d "$dir"; then
 325     INCLUDES="$INCLUDES -I$dir"
 326   else
 327     AC_MSG_WARN([*** Include directory $dir does not exist.])
 328   fi
 329 done
 330 IFS=$ac_save_IFS
 331 AC_SUBST(INCLUDES)
 332
 333
 334 #
 335 # Library directories
 336 #
 337 ac_save_IFS=$IFS
 338 IFS="${IFS}:"
 339 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 340 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 341   if test -d "$dir"; then
 342     LIBDIRS="$LIBDIRS -L$dir"
 343   else
 344     AC_MSG_WARN([*** Library directory $dir does not exist.])
 345   fi
 346 done
 347 IFS=$ac_save_IFS
 348
 349 #
 350 # Enable thread-safe client libraries
 351 #
 352 AC_MSG_CHECKING([allow thread-safe client libraries])
 353 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 354               [AC_DEFINE([USE_THREADS], 1,
 355                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 356 AC_MSG_RESULT([$enable_thread_safety])
 357 AC_SUBST(enable_thread_safety)
 358
 359 #
 360 # Tcl/Tk
 361 #
 362 AC_MSG_CHECKING([whether to build with Tcl])
 363 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 364 AC_MSG_RESULT([$with_tcl])
 365 AC_SUBST([with_tcl])
 366
 367 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 368 AC_MSG_CHECKING([whether to build with Tk])
 369 if test "$with_tcl" = yes; then
 370   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 371 else
 372   with_tk=no
 373 fi
 374 AC_MSG_RESULT([$with_tk])
 375 AC_SUBST([with_tk])
 376
 377
 378 # We see if the path to the Tcl/Tk configuration scripts is specified.
 379 # This will override the use of tclsh to find the paths to search.
 380
 381 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 382
 383 # We see if the path to the Tk configuration scripts is specified.
 384 # This will override the use of tclsh to find the paths to search.
 385
 386 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 387
 388 #
 389 # Optionally build Perl modules (PL/Perl)
 390 #
 391 AC_MSG_CHECKING([whether to build Perl modules])
 392 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 393 AC_MSG_RESULT([$with_perl])
 394 AC_SUBST(with_perl)
 395
 396 #
 397 # Optionally build Python modules (PL/Python)
 398 #
 399 AC_MSG_CHECKING([whether to build Python modules])
 400 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 401 AC_MSG_RESULT([$with_python])
 402 AC_SUBST(with_python)
 403
 404 #
 405 # Optionally build the Java/JDBC tools
 406 #
 407 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 408 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 409 [AC_MSG_RESULT(yes)
 410 PGAC_PATH_ANT
 411 if test -z "$ANT"; then
 412   AC_MSG_ERROR([Ant is required to build Java components
 413 If you have Ant already installed, see config.log for details on the failure.])
 414 fi
 415 if "$ANT" -version | egrep -i 'ant version' | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 416   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 417 fi],
 418 [AC_MSG_RESULT(no)])
 419 AC_SUBST(with_java)
 420
 421 dnl A note on the Kerberos and OpenSSL options:
 422 dnl
 423 dnl The user can give an argument to the option in order the specify
 424 dnl the base path of the respective installation (what he specified
 425 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 426 dnl then we take the path where the package installs by default. This
 427 dnl way the user doesn't have to use redundant --with-includes and
 428 dnl --with-libraries options, but he can still use them if the layout
 429 dnl is non-standard.
 430
 431 #
 432 # Kerberos 4
 433 #
 434 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 435 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 436                 [krb4_prefix=/usr/athena],
 437                 [krb4_prefix=$withval],
 438 [
 439   AC_MSG_RESULT(yes)
 440   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 441
 442   if test -d "$krb4_prefix/include"; then
 443     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 444   fi
 445   if test -d "$krb4_prefix/lib"; then
 446     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 447   fi
 448
 449   krb_srvtab="/etc/srvtab"
 450 ],
 451 [AC_MSG_RESULT(no)])
 452
 453 AC_SUBST(with_krb4)
 454
 455
 456 #
 457 # Kerberos 5
 458 #
 459 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 460 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 461               [krb5_prefix=/usr/athena],
 462               [krb5_prefix=$withval],
 463 [
 464   AC_MSG_RESULT([yes])
 465   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 466
 467   if test -d "$krb5_prefix/include"; then
 468     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 469   fi
 470   if test -d "$krb5_prefix/lib"; then
 471     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 472   fi
 473
 474   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 475 ],
 476 [AC_MSG_RESULT(no)])
 477
 478 AC_SUBST(with_krb5)
 479
 480
 481 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 482 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 483   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 484 fi
 485
 486 AC_SUBST(krb_srvtab)
 487
 488
 489 #
 490 # Kerberos configuration parameters
 491 #
 492 PGAC_ARG_REQ(with, krb-srvnam,
 493              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 494              [],
 495              [with_krb_srvnam="postgres"])
 496 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 497                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 498
 499
 500 #
 501 # PAM
 502 #
 503 AC_MSG_CHECKING([whether to build with PAM support])
 504 PGAC_ARG_BOOL(with, pam, no,
 505               [  --with-pam              build with PAM support],
 506               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 507 AC_MSG_RESULT([$with_pam])
 508 AC_SUBST(with_pam)
 509
 510
 511 #
 512 # Rendezvous
 513 #
 514 AC_MSG_CHECKING([whether to build with Rendezvous support])
 515 PGAC_ARG_BOOL(with, rendezvous, no,
 516               [  --with-rendezvous       build with Rendezvous support],
 517               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 518 AC_MSG_RESULT([$with_rendezvous])
 519 AC_SUBST(with_rendezvous)
 520
 521
 522 #
 523 # OpenSSL
 524 #
 525 PGAC_ARG_OPTARG(with, openssl,
 526                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 527                 [openssl_prefix=/usr/local/ssl],
 528                 [openssl_prefix=$withval],
 529 [
 530   AC_MSG_RESULT([building with OpenSSL support])
 531   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 532
 533   if test -d "${openssl_prefix}/include" ; then
 534     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 535   fi
 536   if test -d "${openssl_prefix}/lib" ; then
 537     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 538   fi
 539 ])
 540
 541 AC_SUBST(with_openssl)
 542
 543
 544 #
 545 # Readline
 546 #
 547 PGAC_ARG_BOOL(with, readline, yes,
 548               [  --without-readline      do not use Readline])
 549
 550 #
 551 # Zlib
 552 #
 553 PGAC_ARG_BOOL(with, zlib, yes,
 554               [  --without-zlib          do not use Zlib])
 555
 556 #
 557 # Elf
 558 #
 559
 560 # Assume system is ELF if it predefines __ELF__ as 1,
 561 # otherwise believe host_os based default.
 562 case $host_os in
 563     freebsd1*|freebsd2*) elf=no;;
 564     freebsd3*|freebsd4*) elf=yes;;
 565 esac
 566
 567 AC_EGREP_CPP(yes,
 568 [#if __ELF__
 569   yes
 570 #endif
 571 ],
 572 [ELF_SYS=true],
 573 [if test "X$elf" = "Xyes" ; then
 574   ELF_SYS=true
 575 else
 576   ELF_SYS=
 577 fi])
 578 AC_SUBST(ELF_SYS)
 579
 580 #
 581 # Assignments
 582 #
 583
 584 CPPFLAGS="$CPPFLAGS $INCLUDES"
 585 LDFLAGS="$LDFLAGS $LIBDIRS"
 586
 587 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 588 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 589
 590
 591 AC_PROG_AWK
 592 PGAC_PATH_FLEX
 593 AC_PROG_LN_S
 594 AC_PROG_LD
 595 AC_SUBST(LD)
 596 AC_SUBST(with_gnu_ld)
 597 case $host_os in sysv5*)
 598   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 599   [
 600     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 601     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 602     LDFLAGS=$pgac_save_LDFLAGS
 603   ])
 604   ld_R_works=$pgac_cv_prog_ld_R
 605   AC_SUBST(ld_R_works)
 606 esac
 607 AC_PROG_RANLIB
 608 AC_CHECK_PROGS(LORDER, lorder)
 609 AC_PATH_PROG(TAR, tar)
 610 PGAC_CHECK_STRIP
 611
 612 AC_CHECK_PROGS(YACC, ['bison -y'])
 613
 614 if test "$YACC"; then
 615   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 616     AC_MSG_WARN([
 617 *** The installed version of Bison is too old.  PostgreSQL needs
 618 *** Bison version 1.875 or later.])
 619   fi
 620 fi
 621
 622 if test -z "$YACC"; then
 623   AC_MSG_WARN([
 624 *** Without Bison you will not be able to build PostgreSQL from CVS or
 625 *** change any of the parser definition files.  You can obtain Bison from
 626 *** a GNU mirror site.  (If you are using the official distribution of
 627 *** PostgreSQL then you do not need to worry about this because the Bison
 628 *** output is pre-generated.)  To use a different yacc program (possible,
 629 *** but not recommended), set the environment variable YACC before running
 630 *** 'configure'.])
 631 fi
 632 AC_SUBST(YFLAGS)
 633
 634 PGAC_PATH_PERL
 635 if test "$with_perl" = yes; then
 636   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 637   PGAC_CHECK_PERL_EMBED_LDFLAGS
 638 fi
 639
 640 if test "$with_python" = yes; then
 641   PGAC_PATH_PYTHON
 642   PGAC_CHECK_PYTHON_EMBED_SETUP
 643 fi
 644
 645
 646 ##
 647 ## Libraries
 648 ##
 649
 650 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 651 then
 652         AC_CHECK_LIB(bsd,      main)
 653 fi
 654 AC_CHECK_LIB(util,     setproctitle)
 655 AC_CHECK_LIB(m,        main)
 656 AC_CHECK_LIB(dl,       main)
 657 AC_CHECK_LIB(nsl,      main)
 658 AC_CHECK_LIB(socket,   main)
 659 AC_CHECK_LIB(ipc,      main)
 660 AC_CHECK_LIB(IPC,      main)
 661 AC_CHECK_LIB(lc,       main)
 662 AC_CHECK_LIB(dld,      main)
 663 AC_CHECK_LIB(ld,       main)
 664 AC_CHECK_LIB(compat,   main)
 665 AC_CHECK_LIB(BSD,      main)
 666 AC_CHECK_LIB(gen,      main)
 667 AC_CHECK_LIB(PW,       main)
 668 AC_CHECK_LIB(resolv,   main)
 669 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 670 # QNX:
 671 AC_CHECK_LIB(unix, main)
 672 AC_SEARCH_LIBS(crypt,  crypt)
 673 # BeOS:
 674 if test "$PORTNAME" = "beos"
 675 then
 676         AC_CHECK_LIB(bind, __inet_ntoa)
 677 fi
 678 # Solaris:
 679 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 680 # Cygwin:
 681 AC_CHECK_LIB(cygipc, shmget)
 682 # WIN32:
 683 if test "$PORTNAME" = "win32"
 684 then
 685         AC_CHECK_LIB(wsock32, main)
 686 fi
 687
 688 if test "$with_readline" = yes; then
 689   PGAC_CHECK_READLINE
 690   if test x"$pgac_cv_check_readline" = x"no"; then
 691     AC_MSG_ERROR([readline library not found
 692 If you have readline already installed, see config.log for details on the
 693 failure.  It is possible the compiler isn't looking in the proper directory.
 694 Use --without-readline to disable readline support.])
 695   fi
 696 fi
 697
 698 if test "$with_zlib" = yes; then
 699   AC_CHECK_LIB(z, inflate, [],
 700                [AC_MSG_ERROR([zlib library not found
 701 If you have zlib already installed, see config.log for details on the
 702 failure.  It is possible the compiler isn't looking in the proper directory.
 703 Use --without-zlib to disable zlib support.])])
 704 fi
 705
 706 if test "$enable_spinlocks" = yes; then
 707   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 708 else
 709   AC_MSG_WARN([
 710 *** Not using spinlocks will cause poor performance.])
 711 fi
 712
 713 if test "$with_krb4" = yes ; then
 714   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 715   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 716   AC_REPLACE_FUNCS([gethostname])
 717 fi
 718
 719 if test "$with_krb5" = yes ; then
 720   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 721                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 722   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 723                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 724   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 725                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 726 fi
 727
 728 if test "$with_openssl" = yes ; then
 729   dnl Order matters!
 730   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 731   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 732 fi
 733
 734 if test "$with_pam" = yes ; then
 735   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 736 fi
 737
 738
 739 ##
 740 ## Header files
 741 ##
 742
 743 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 744 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 745
 746 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 747 # netinet/in.h is included first.
 748 AC_CHECK_HEADERS(netinet/in.h)
 749 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 750 [AC_INCLUDES_DEFAULT
 751 #ifdef HAVE_NETINET_IN_H
 752 #include <netinet/in.h>
 753 #endif
 754 ])
 755
 756 if test "$with_readline" = yes; then
 757   AC_CHECK_HEADERS(readline/readline.h, [],
 758                    [AC_CHECK_HEADERS(editline/readline.h, [],
 759                          [AC_CHECK_HEADERS(readline.h, [],
 760                                      [AC_MSG_ERROR([readline header not found
 761 If you have readline already installed, see config.log for details on the
 762 failure.  It is possible the compiler isn't looking in the proper directory.
 763 Use --without-readline to disable readline support.])])])])
 764   AC_CHECK_HEADERS(readline/history.h, [],
 765                    [AC_CHECK_HEADERS(editline/history.h, [],
 766                          [AC_CHECK_HEADERS(history.h, [],
 767                                      [AC_MSG_ERROR([history header not found
 768 If you have readline already installed, see config.log for details on the
 769 failure.  It is possible the compiler isn't looking in the proper directory.
 770 Use --without-readline to disable readline support.])])])])
 771 fi
 772
 773 if test "$with_zlib" = yes; then
 774   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 775 If you have zlib already installed, see config.log for details on the
 776 failure.  It is possible the compiler isn't looking in the proper directory.
 777 Use --without-zlib to disable zlib support.])])
 778 fi
 779
 780 if test "$with_krb4" = yes ; then
 781   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 782 fi
 783
 784 if test "$with_krb5" = yes ; then
 785   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 786   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 787 fi
 788
 789 if test "$with_openssl" = yes ; then
 790   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 791   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 792 fi
 793
 794 if test "$with_pam" = yes ; then
 795   AC_CHECK_HEADERS(security/pam_appl.h, [],
 796                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 797                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 798 fi
 799
 800 if test "$with_rendezvous" = yes ; then
 801   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 802 fi
 803
 804
 805 ##
 806 ## Types, structures, compiler characteristics
 807 ##
 808
 809 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 810 AC_C_CONST
 811 AC_C_INLINE
 812 AC_C_STRINGIZE
 813 PGAC_C_SIGNED
 814 AC_C_VOLATILE
 815 PGAC_C_FUNCNAME_SUPPORT
 816 PGAC_STRUCT_TIMEZONE
 817 PGAC_UNION_SEMUN
 818 PGAC_STRUCT_SOCKADDR_UN
 819 PGAC_STRUCT_SOCKADDR_STORAGE
 820 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 821 PGAC_STRUCT_ADDRINFO
 822
 823 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 824 [#include <sys/param.h>
 825 #include <sys/types.h>
 826 #include <sys/socket.h>
 827 #include <sys/ucred.h>])
 828
 829 AC_CHECK_TYPES([struct option], [], [],
 830 [#ifdef HAVE_GETOPT_H
 831 #include <getopt.h>
 832 #endif])
 833
 834 if test "$with_zlib" = yes; then
 835   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 836   # did not).  While we could work around the lack of z_streamp, it
 837   # seems unwise to encourage people to use such old zlib versions...
 838   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 839 Use --without-zlib to disable zlib support.])],
 840                 [#include <zlib.h>])
 841 fi
 842
 843 if test "$with_krb5" = yes; then
 844 # Check for differences between MIT and Heimdal (KTH) releases
 845   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 846                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 847                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 848                                      [#include <krb5.h>])],
 849                    [#include <krb5.h>])
 850   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 851                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 852                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 853                                      [#include <krb5.h>])],
 854                    [#include <krb5.h>])
 855 fi
 856
 857
 858 ##
 859 ## Functions, global variables
 860 ##
 861
 862 PGAC_VAR_INT_TIMEZONE
 863 AC_FUNC_ACCEPT_ARGTYPES
 864 PGAC_FUNC_GETTIMEOFDAY_1ARG
 865
 866 # SunOS doesn't handle negative byte comparisons properly with +/- return
 867 AC_FUNC_MEMCMP
 868
 869 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 870
 871 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 872
 873 HAVE_IPV6=no
 874 AC_CHECK_TYPE([struct sockaddr_in6],
 875               [AC_CHECK_FUNC(inet_ntop,
 876                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 877                                                           HAVE_IPV6=yes])],
 878               [],
 879 [$ac_includes_default
 880 #include <netinet/in.h>])
 881 AC_SUBST(HAVE_IPV6)
 882
 883 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 884 [AC_TRY_LINK(
 885 [#include <machine/vmparam.h>
 886 #include <sys/exec.h>
 887 ],
 888 [PS_STRINGS->ps_nargvstr = 1;
 889 PS_STRINGS->ps_argvstr = "foo";],
 890 [pgac_cv_var_PS_STRINGS=yes],
 891 [pgac_cv_var_PS_STRINGS=no])])
 892 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 893   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 894 fi
 895
 896
 897 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 898 # is missing.  Yes, there are machines that have only one.  We may
 899 # also decide to use snprintf.c if snprintf() is present but does not
 900 # have working "long long int" support -- see below.
 901
 902 pgac_need_repl_snprintf=no
 903 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 904 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 905
 906
 907 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 908 # include/c.h will provide declarations.  Note this is a separate test
 909 # from whether the functions exist in the C library --- there are
 910 # systems that have the functions but don't bother to declare them :-(
 911
 912 AC_CHECK_DECLS([snprintf, vsnprintf])
 913
 914
 915 # do this one the hard way in case isinf() is a macro
 916 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 917 [AC_TRY_LINK(
 918 [#include <math.h>
 919 ],
 920 [double x = 0.0; int res = isinf(x);],
 921 [ac_cv_func_isinf=yes],
 922 [ac_cv_func_isinf=no])])
 923
 924 if test $ac_cv_func_isinf = yes ; then
 925   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 926 else
 927   AC_LIBOBJ(isinf)
 928   # Look for a way to implement a substitute for isinf()
 929   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 930 fi
 931
 932 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 933
 934 # system's version of getaddrinfo(), if any, may be used only if we found
 935 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 936 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 937   AC_REPLACE_FUNCS([getaddrinfo])
 938 else
 939   AC_LIBOBJ(getaddrinfo)
 940 fi
 941
 942 # similarly, use system's getopt_long() only if system provides struct option.
 943 if test x"$ac_cv_type_struct_option" = xyes ; then
 944   AC_REPLACE_FUNCS([getopt_long])
 945 else
 946   AC_LIBOBJ(getopt_long)
 947 fi
 948
 949 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 950 # We override the previous test that said fseeko/ftello didn't exist
 951 # OS tests are also done in include/c.h and port/fseeko.c
 952 case $host_os in bsdi*|netbsd*)
 953 ac_cv_func_fseeko=yes
 954 esac
 955
 956 # Solaris has a very slow qsort in certain cases, so we replace it.
 957 case $host_os in solaris*)
 958 AC_LIBOBJ(qsort) ;;
 959 esac
 960
 961 # Win32 can't to rename or unlink on an open file
 962 case $host_os in mingw*)
 963 AC_LIBOBJ(dirmod)
 964 AC_LIBOBJ(copydir)
 965 AC_LIBOBJ(gettimeofday) ;;
 966 esac
 967
 968 if test "$with_readline" = yes; then
 969   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 970   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 971   AC_CHECK_FUNCS([replace_history_entry])
 972 fi
 973
 974
 975 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 976 AC_MSG_CHECKING(for finite)
 977 AC_TRY_LINK([#include <math.h>],
 978             [int dummy=finite(1.0);],
 979             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 980 AC_MSG_RESULT(yes)],
 981             [AC_MSG_RESULT(no)])
 982
 983 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 984 dnl (especially on GNU libc)
 985 dnl See also comments in c.h.
 986 AC_MSG_CHECKING(for sigsetjmp)
 987 AC_TRY_LINK([#include <setjmp.h>],
 988             [sigjmp_buf x; sigsetjmp(x, 1);],
 989             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 990 AC_MSG_RESULT(yes)],
 991             [AC_MSG_RESULT(no)])
 992
 993 AC_CHECK_FUNC(syslog,
 994               [AC_CHECK_HEADER(syslog.h,
 995                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 996
 997 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 998 [AC_TRY_LINK([#include <unistd.h>],
 999   [extern int optreset; optreset = 1;],
1000   [pgac_cv_var_int_optreset=yes],
1001   [pgac_cv_var_int_optreset=no])])
1002 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1003   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1004 fi
1005
1006 AC_CHECK_FUNCS([strtoll strtoq], [break])
1007 AC_CHECK_FUNCS([strtoull strtouq], [break])
1008
1009 # Check for one of atexit() or on_exit()
1010 AC_CHECK_FUNCS(atexit, [],
1011                [AC_CHECK_FUNCS(on_exit, [],
1012                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1013
1014 AC_FUNC_FSEEKO
1015
1016 #
1017 # Pthreads
1018 #
1019 # For each platform, we need to know about any special compile and link
1020 # libraries, and whether the normal C function names are thread-safe.
1021 # See the comment at the top of src/port/thread.c for more information.
1022 #
1023 if test "$enable_thread_safety" = yes; then
1024 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
1025
1026 if test "$THREAD_SUPPORT" != yes; then
1027 AC_MSG_ERROR([
1028 Cannot enable threads on your platform.
1029 Please report your platform threading info to the PostgreSQL mailing lists
1030 so it can be added to the next release.  Report all compile flags, link flags,
1031 functions, or libraries required for threading support.
1032 See the comment at the top of src/port/thread.c for more information.
1033 ])
1034 fi
1035 else
1036 # do not use values from template file
1037 THREAD_CPPFLAGS=
1038 THREAD_LIBS=
1039 fi
1040 AC_SUBST(THREAD_SUPPORT)
1041 AC_SUBST(THREAD_CPPFLAGS)
1042 AC_SUBST(THREAD_LIBS)
1043
1044
1045 #
1046 # Check for re-entrant versions of certain functions
1047 #
1048 # Include special flags if threads are enabled _and_ if required for
1049 # threading on this platform.  Some platforms have *_r functions but
1050 # their natively named funcs are threadsafe, and should be used instead.
1051 #
1052 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1053 # functions are marked "not found", which is perfect.
1054 #
1055 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNCS" = yes ; then
1056 _CFLAGS="$CFLAGS"
1057 _LIBS="$LIBS"
1058 CFLAGS="$CFLAGS $THREAD_CPPFLAGS"
1059 LIBS="$LIBS $THREAD_LIBS"
1060 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1061 CFLAGS="$_CFLAGS"
1062 LIBS="$_LIBS"
1063 fi
1064
1065
1066 # This test makes sure that run tests work at all.  Sometimes a shared
1067 # library is found by the linker, but the runtime linker can't find it.
1068 # This check should come after all modifications of compiler or linker
1069 # variables, and before any other run tests.
1070 AC_MSG_CHECKING([test program])
1071 AC_TRY_RUN([int main() { return 0; }],
1072 [AC_MSG_RESULT(ok)],
1073 [AC_MSG_RESULT(failed)
1074 AC_MSG_ERROR([[
1075 *** Could not execute a simple test program.  This may be a problem
1076 *** related to locating shared libraries.  Check the file 'config.log'
1077 *** for the exact reason.]])],
1078 [AC_MSG_RESULT([cross-compiling])])
1079
1080
1081 dnl Check to see if we have a working 64-bit integer type.
1082 dnl This breaks down into two steps:
1083 dnl (1) figure out if the compiler has a 64-bit int type with working
1084 dnl arithmetic, and if so
1085 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1086 dnl snprintf is the only library routine we really need for int8 support.)
1087 dnl It's entirely possible to have a compiler that handles a 64-bit type
1088 dnl when the C library doesn't; this is fairly likely when using gcc on
1089 dnl an older platform, for example.
1090 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1091 dnl we force our own version of snprintf() to be used instead.
1092 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1093
1094 PGAC_TYPE_64BIT_INT([long int])
1095
1096 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1097   PGAC_TYPE_64BIT_INT([long long int])
1098 fi
1099
1100
1101 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1102
1103 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1104   AC_TRY_COMPILE([
1105 #define INT64CONST(x)  x##LL
1106 long long int foo = INT64CONST(0x1234567890123456);
1107 ],
1108         [],
1109         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1110         [])
1111 fi
1112
1113
1114 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1115 # we found we need to use "long long int", better check.  We cope with
1116 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1117 # neither works, fall back to our own snprintf emulation (which we
1118 # know uses %lld).
1119
1120 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1121   if test $pgac_need_repl_snprintf = no; then
1122     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1123     if test "$LONG_LONG_INT_FORMAT" = ""; then
1124       # Force usage of our own snprintf, since system snprintf is broken
1125       pgac_need_repl_snprintf=yes
1126       LONG_LONG_INT_FORMAT='%lld'
1127     fi
1128   else
1129     # Here if we previously decided we needed to use our own snprintf
1130     LONG_LONG_INT_FORMAT='%lld'
1131   fi
1132   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1133 else
1134   # Here if we are not using 'long long int' at all
1135   INT64_FORMAT='"%ld"'
1136 fi
1137
1138 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1139                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1140
1141 if test $pgac_need_repl_snprintf = yes; then
1142   AC_LIBOBJ(snprintf)
1143 fi
1144
1145 # Need a #define for the size of Datum (unsigned long)
1146 AC_CHECK_SIZEOF([unsigned long])
1147
1148 # Determine memory alignment requirements for the basic C data types.
1149
1150 PGAC_CHECK_ALIGNOF(short)
1151 PGAC_CHECK_ALIGNOF(int)
1152 PGAC_CHECK_ALIGNOF(long)
1153 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1154   PGAC_CHECK_ALIGNOF(long long int)
1155 fi
1156 PGAC_CHECK_ALIGNOF(double)
1157
1158 # Compute maximum alignment of any basic type.
1159 # We assume long's alignment is at least as strong as char, short, or int;
1160 # but we must check long long (if it exists) and double.
1161
1162 MAX_ALIGNOF=$pgac_cv_alignof_long
1163 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1164   MAX_ALIGNOF=$pgac_cv_alignof_double
1165 fi
1166 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1167   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1168 fi
1169 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1170
1171
1172 # Some platforms predefine the types int8, int16, etc.  Only check
1173 # a (hopefully) representative subset.
1174 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1175 [#include <stdio.h>
1176 #ifdef HAVE_SUPPORTDEFS_H
1177 #include <SupportDefs.h>
1178 #endif])
1179
1180 # We also check for sig_atomic_t, which *should* be defined per ANSI
1181 # C, but is missing on some old platforms.
1182 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1183
1184
1185 PGAC_FUNC_POSIX_SIGNALS
1186 if test $ac_cv_func_fseeko = yes; then
1187 AC_SYS_LARGEFILE
1188 fi
1189
1190
1191 # Select semaphore implementation type.
1192 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1193   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1194   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1195 else
1196   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1197     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1198     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1199   else
1200     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1201     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1202   fi
1203 fi
1204
1205
1206 # Select shared-memory implementation type.
1207 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1208 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1209
1210
1211 if test "$enable_nls" = yes ; then
1212   PGAC_CHECK_GETTEXT
1213 fi
1214
1215 # Check for Tcl configuration script tclConfig.sh
1216 if test "$with_tcl" = yes; then
1217     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1218     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1219                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1220     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1221 fi
1222
1223 # Check for Tk configuration script tkConfig.sh
1224 if test "$with_tk" = yes; then
1225     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1226     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1227 fi
1228
1229
1230 #
1231 # Check for DocBook and tools
1232 #
1233 PGAC_PROG_NSGMLS
1234 PGAC_PROG_JADE
1235 PGAC_CHECK_DOCBOOK(3.1)
1236 PGAC_PATH_DOCBOOK_STYLESHEETS
1237 PGAC_PATH_COLLATEINDEX
1238 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1239
1240
1241 # prepare build tree if outside source tree
1242 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1243 # Note 2: /bin/pwd might be better than shell's built-in at getting
1244 #         a symlink-free name.
1245 if test "$no_create" != yes; then
1246   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1247     :
1248   else
1249     AC_SUBST(vpath_build, yes)
1250     _AS_ECHO_N([preparing build tree... ])
1251     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1252     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1253       || AC_MSG_ERROR(failed)
1254     AC_MSG_RESULT(done)
1255   fi
1256 fi
1257
1258
1259 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1260
1261 AC_CONFIG_LINKS([
1262   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1263   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1264   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1265   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1266   src/include/pg_config_os.h:src/include/port/${template}.h
1267   src/Makefile.port:src/makefiles/Makefile.${template}
1268 ])
1269
1270 AC_CONFIG_HEADERS([src/include/pg_config.h],
1271 [
1272 # Update timestamp for pg_config.h (see Makefile.global)
1273 echo >src/include/stamp-h
1274 ])
1275
1276 AC_OUTPUT