granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Save user-defined environment settings for later restoration
  22 dnl
  23 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  24 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  25 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  26 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  27 APR_SAVE_THE_ENVIRONMENT(LIBS)
  28 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  29
  30 dnl Generate ./config.nice for reproducing runs of configure
  31 dnl
  32 APR_CONFIG_NICE(config.nice)
  33
  34 nl='
  35 '
  36 dnl ## Run configure for packages Apache uses
  37
  38 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  39
  40 APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --disable-shared")
  41
  42 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  43
  44 APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --disable-shared")
  45
  46 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
  47
  48 APR_SUBDIR_CONFIG(srclib/pcre)
  49
  50 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
  51
  52 echo $ac_n "obtaining flag settings from the sub-configures...${nl}"
  53 . ./srclib/apr/APRVARS
  54
  55 dnl Now that we have APR's EXTRA_flags in our environment, move them over
  56 dnl to the normal variables to avoid duplications and use them for testing.
  57 dnl We ignore EXTRA_INCLUDES because our own includes will encompass them.
  58 dnl
  59 APR_ADDTO(CFLAGS, $EXTRA_CFLAGS)
  60 APR_ADDTO(CPPFLAGS, $EXTRA_CPPFLAGS)
  61 APR_ADDTO(LDFLAGS, $EXTRA_LDFLAGS)
  62 APR_ADDTO(LIBS, $EXTRA_LIBS)
  63 EXTRA_CFLAGS=
  64 EXTRA_CPPFLAGS=
  65 EXTRA_LDFLAGS=
  66 EXTRA_LIBS=
  67 EXTRA_INCLUDES=
  68
  69 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  70 dnl by configure until it is too late.  Is that how it should be or not?
  71 dnl Something seems broken here.
  72 AC_PREFIX_DEFAULT(/usr/local/apache2)
  73 test "$prefix" = "NONE" && prefix='/usr/local/apache2'
  74 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
  75
  76 dnl Absolute source/build directory
  77 abs_srcdir=`(cd $srcdir && pwd)`
  78 abs_builddir=`pwd`
  79
  80 dnl If the source dir is not equal to the build dir,
  81 dnl then we are running in VPATH mode.
  82
  83 if test "$abs_builddir" != "$abs_srcdir"; then
  84   USE_VPATH=1
  85   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/srclib/apr/include -I\$(top_srcdir)/srclib/apr/include -I\$(top_builddir)/srclib/apr-util/include -I\$(top_srcdir)/srclib/apr-util/include])
  86 else
  87   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/include -I\$(top_srcdir)/srclib/apr/include -I\$(top_srcdir)/srclib/apr-util/include])
  88 fi
  89
  90 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
  91
  92 AC_CANONICAL_SYSTEM
  93
  94 case "$host_alias" in
  95   *os2*)
  96       # Use a custom made libtool replacement
  97       echo "using aplibtool"
  98       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
  99       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 100       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 101       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 102       MK_IMPLIB="emximp"
 103       other_targets="$other_targets os2core"
 104       ;;
 105   *)
 106       if test "x$LTFLAGS" = "x"; then
 107           LTFLAGS='--silent'
 108       fi
 109       LIBTOOL='$(SHELL) $(top_builddir)/srclib/apr/libtool $(LTFLAGS)'
 110       SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 111       ;;
 112 esac
 113
 114 case "$host" in
 115   *-apple-aux3*)
 116       APR_SETVAR(APACHE_MPM, [prefork])
 117       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 118       ;;
 119   *-beos*)
 120       APR_SETVAR(APACHE_MPM, [beos])
 121       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 122       ;;
 123   *os2_emx*)
 124       APR_SETVAR(APACHE_MPM, [spmt_os2])
 125       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 126       ;;
 127   *-linux-*)
 128       case `uname -r` in
 129         2.2* ) APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 130             ;;
 131         * )
 132             ;;
 133       esac
 134       ;;
 135   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 136       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 137       ;;
 138   *-solaris2*)
 139       dnl  This is a hack -- we should be using AC_TRY_RUN instead
 140       ap_platform_runtime_link_flag="-R"
 141       ;;
 142 esac
 143
 144 dnl
 145 dnl Process command line arguments. This is done early in the process so the
 146 dnl user can get feedback quickly in case of an error.
 147 dnl
 148 dnl ### need to move some of the arguments "up here"
 149
 150 dnl ## Check for programs
 151
 152 AC_PATH_PROG(RM, rm)
 153 AC_PROG_AWK
 154 AC_PROG_CC
 155 AC_PROG_CPP
 156 AC_PROG_INSTALL
 157 AC_PROG_LN_S
 158 AC_CHECK_TOOL(RANLIB, ranlib, true)
 159 dnl AC_PATH_PROG(PERL_PATH, perl)
 160
 161 dnl various OS checks that apparently set required flags
 162 AC_AIX
 163 AC_ISC_POSIX
 164 AC_MINIX
 165
 166 dnl ## Check for libraries
 167
 168 dnl ## Check for header files
 169
 170 dnl I think these are just used all over the place, so just check for
 171 dnl them at the base of the tree. If some are specific to a single
 172 dnl directory, they should be moved (Comment #Spoon)
 173
 174 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 175 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 176 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 177
 178 AC_HEADER_STDC
 179 AC_CHECK_HEADERS( \
 180 string.h \
 181 limits.h \
 182 unistd.h \
 183 sys/socket.h \
 184 pwd.h \
 185 grp.h \
 186 strings.h
 187 )
 188 AC_HEADER_SYS_WAIT
 189
 190 dnl ## Check for typedefs, structures, and compiler characteristics.
 191
 192 AC_C_CONST
 193 if test "$ac_cv_prog_gcc" = "yes"; then
 194   APR_ADDTO(CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 195 fi
 196
 197 dnl ## Check for library functions
 198
 199 dnl See Comment #Spoon
 200
 201 AC_CHECK_FUNCS( \
 202 initgroups \
 203 )
 204
 205 AC_CHECK_LIB(nsl, gethostbyname)
 206 AC_CHECK_LIB(nsl, gethostname)
 207 AC_CHECK_LIB(socket, socket)
 208
 209 AC_ARG_WITH(port,[  --with-port=PORT        Port on which to listen (default is 80)],
 210         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 211         [PORT=80])
 212
 213 AC_ARG_ENABLE(maintainer-mode,[  --enable-maintainer-mode  Turn on debugging and compile time warnings],
 214 [
 215   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 216 ])dnl
 217
 218 APACHE_ENABLE_LAYOUT
 219 APACHE_ENABLE_MODULES
 220
 221 dnl reading config stubs
 222 esyscmd(./build/config-stubs .)
 223
 224 APACHE_SUBST(progname)
 225 APACHE_SUBST(MPM_LIB)
 226 APACHE_SUBST(OS)
 227 APACHE_SUBST(OS_DIR)
 228 APACHE_SUBST(BUILTIN_LIBS)
 229
 230 PRE_SHARED_CMDS='echo ""'
 231 POST_SHARED_CMDS='echo ""'
 232
 233 if test "$apache_need_shared" = "yes"; then
 234   $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 235   case "$host" in
 236     *-ibm-aix*)
 237       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-bE:$abs_srcdir/support/httpd.exp"
 238       SH_LDFLAGS="$SH_LDFLAGS -Wl,-bI:$abs_srcdir/support/httpd.exp"
 239       ;;
 240     *beos)
 241       SH_LDFLAGS='$(top_builddir)/_APP_'
 242       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 243       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 244       ;;
 245     *os390)
 246       APR_ADDTO(CFLAGS, [-Wc,DLL,EXPORTALL])
 247       ;;
 248   esac
 249   shared_build="shared-modules"
 250 fi
 251
 252 APACHE_SUBST(PRE_SHARED_CMDS)
 253 APACHE_SUBST(POST_SHARED_CMDS)
 254 APACHE_SUBST(shared_build)
 255
 256 AC_ARG_WITH(program-name,
 257 [  --with-program-name     alternate executable name],[
 258   progname="$withval" ], [
 259   progname="httpd"] )
 260
 261 # SuExec parameters
 262 AC_ARG_WITH(suexec-caller,
 263 [  --with-suexec-caller    User allowed to call SuExec],[
 264   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 265
 266 AC_ARG_WITH(suexec-userdir,
 267 [  --with-suexec-userdir   User subdirectory],[
 268   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 269
 270 AC_ARG_WITH(suexec-docroot,
 271 [  --with-suexec-docroot   SuExec root directory],[
 272   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 273
 274 AC_ARG_WITH(suexec-uidmin,
 275 [  --with-suexec-uidmin    Minimal allowed UID],[
 276   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 277
 278 AC_ARG_WITH(suexec-gidmin,
 279 [  --with-suexec-gidmin    Minimal allowed GID],[
 280   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 281
 282 AC_ARG_WITH(suexec-logfile,
 283 [  --with-suexec-logfile   Set the logfile],[
 284   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 285
 286 AC_ARG_WITH(suexec-safepath,
 287 [  --with-suexec-safepath  Set the safepath],[
 288   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 289
 290 AC_ARG_WITH(suexec-umask,
 291 [  --with-suexec-umask     umask for suexec'd process],[
 292   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 293
 294 dnl AP_LIB_DIRS specifies the additional libs from srclib/ that we need
 295 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 296 AP_LIBS="$abs_srcdir/srclib/pcre/libpcre.la $abs_srcdir/srclib/apr-util/libaprutil.la $AP_LIBS"
 297
 298 dnl APR should go after the other libs, so the right symbols can be picked up
 299 AP_LIBS="$AP_LIBS $abs_srcdir/srclib/apr/libapr.la"
 300 APACHE_SUBST(AP_LIB_DIRS)
 301 APACHE_SUBST(AP_LIBS)
 302
 303 AC_DEFINE(AP_USING_AUTOCONF, 1,
 304                 [Using autoconf to configure Apache])
 305
 306 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 307     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 308               [This platform doesn't suffer from the thundering herd problem])
 309 fi
 310
 311 dnl check for endianness
 312 if test "$cross_compiling" = "no"; then
 313   AC_C_BIGENDIAN
 314 else
 315   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 316                 [byte order is unknown due to cross-compilation])
 317 fi
 318
 319 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 320 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 321 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 322 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 323 for i in $AP_LIB_DIRS; do
 324   APACHE_FAST_OUTPUT(srclib/$i/Makefile)
 325 done
 326
 327 if test -d ./test; then
 328     APACHE_FAST_OUTPUT(test/Makefile)
 329 fi
 330
 331 dnl get the exported vars from APRUTIL
 332 . ./srclib/apr-util/export_vars.sh
 333 APR_ADDTO(LIBS, $APRUTIL_EXPORT_LIBS)
 334 AP_LIBS="$AP_LIBS $LIBTOOL_LIBS"
 335
 336 dnl ## Finalize the variables
 337 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 338
 339 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 340 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 341 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 342 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 343 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 344 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 345
 346 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 347
 348 APACHE_GEN_CONFIG_VARS
 349
 350 dnl ## Build modules.c
 351 rm -f modules.c
 352 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 353
 354 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "$prefix",
 355         [Root directory of the Apache install area])
 356 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "conf/$progname.conf",
 357         [Location of the config file, relative to the Apache root directory])
 358 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 359         [Location of the source for the current MPM])
 360
 361 perlbin=`$ac_aux_dir/PrintPath perl`
 362 if test "x$perlbin" = "x"; then
 363     perlbin="/replace/with/path/to/perl/interpreter"
 364 fi
 365 AC_SUBST(perlbin)
 366
 367 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 368
 369 BSD_MAKEFILE=no
 370 case "$host_alias" in
 371 *bsdi*)
 372     # Check whether they've installed GNU make
 373     if make --version > /dev/null 2>&1; then
 374         true
 375     else
 376         BSD_MAKEFILE=yes
 377     fi
 378     ;;
 379 esac
 380
 381 AC_OUTPUT($APACHE_OUTPUT_FILES support/apxs support/apachectl support/dbmmanage support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile,,[
 382   APACHE_GEN_MAKEFILES
 383 ])
 384