granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [12devel], [pgsql-bugs@lists.postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2019, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@lists.postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # --enable-debug adds -g to compiler flags
 198 #
 199 PGAC_ARG_BOOL(enable, debug, no,
 200               [build with debugging symbols (-g)])
 201 AC_SUBST(enable_debug)
 202
 203 #
 204 # --enable-profiling enables gcc profiling
 205 #
 206 PGAC_ARG_BOOL(enable, profiling, no,
 207               [build with profiling enabled ])
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [PGAC_PATH_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 PGAC_PATH_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 PGAC_PATH_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [PGAC_PATH_PROGS(DTRACE, dtrace)
 234 if test -z "$DTRACE"; then
 235   AC_MSG_ERROR([dtrace not found])
 236 fi
 237 AC_SUBST(DTRACEFLAGS)])
 238 AC_SUBST(enable_dtrace)
 239
 240 #
 241 # TAP tests
 242 #
 243 PGAC_ARG_BOOL(enable, tap-tests, no,
 244               [enable TAP tests (requires Perl and IPC::Run)])
 245 AC_SUBST(enable_tap_tests)
 246
 247 #
 248 # Block size
 249 #
 250 AC_MSG_CHECKING([for block size])
 251 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 252              [blocksize=$withval],
 253              [blocksize=8])
 254 case ${blocksize} in
 255   1) BLCKSZ=1024;;
 256   2) BLCKSZ=2048;;
 257   4) BLCKSZ=4096;;
 258   8) BLCKSZ=8192;;
 259  16) BLCKSZ=16384;;
 260  32) BLCKSZ=32768;;
 261   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 262 esac
 263 AC_MSG_RESULT([${blocksize}kB])
 264
 265 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 266  Size of a disk block --- this also limits the size of a tuple.  You
 267  can set it bigger if you need bigger tuples (although TOAST should
 268  reduce the need to have large tuples, since fields can be spread
 269  across multiple tuples).
 270
 271  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 272  is currently 2^15 (32768).  This is determined by the 15-bit widths
 273  of the lp_off and lp_len fields in ItemIdData (see
 274  include/storage/itemid.h).
 275
 276  Changing BLCKSZ requires an initdb.
 277 ])
 278
 279 #
 280 # Relation segment size
 281 #
 282 AC_MSG_CHECKING([for segment size])
 283 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 284              [segsize=$withval],
 285              [segsize=1])
 286 # this expression is set up to avoid unnecessary integer overflow
 287 # blocksize is already guaranteed to be a factor of 1024
 288 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 289 test $? -eq 0 || exit 1
 290 AC_MSG_RESULT([${segsize}GB])
 291
 292 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 293  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 294  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 295  relations bigger than that are divided into multiple files.
 296
 297  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 298  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 299  have large file support enabled.  By default, we make the limit 1 GB
 300  to avoid any possible integer-overflow problems within the OS.
 301  A limit smaller than necessary only means we divide a large
 302  relation into more chunks than necessary, so it seems best to err
 303  in the direction of a small limit.
 304
 305  A power-of-2 value is recommended to save a few cycles in md.c,
 306  but is not absolutely required.
 307
 308  Changing RELSEG_SIZE requires an initdb.
 309 ])
 310
 311 #
 312 # WAL block size
 313 #
 314 AC_MSG_CHECKING([for WAL block size])
 315 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 316              [wal_blocksize=$withval],
 317              [wal_blocksize=8])
 318 case ${wal_blocksize} in
 319   1) XLOG_BLCKSZ=1024;;
 320   2) XLOG_BLCKSZ=2048;;
 321   4) XLOG_BLCKSZ=4096;;
 322   8) XLOG_BLCKSZ=8192;;
 323  16) XLOG_BLCKSZ=16384;;
 324  32) XLOG_BLCKSZ=32768;;
 325  64) XLOG_BLCKSZ=65536;;
 326   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 327 esac
 328 AC_MSG_RESULT([${wal_blocksize}kB])
 329
 330 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 331  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 332  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 333  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 334  buffers, else direct I/O may fail.
 335
 336  Changing XLOG_BLCKSZ requires an initdb.
 337 ])
 338
 339 #
 340 # C compiler
 341 #
 342
 343 # For historical reasons you can also use --with-CC to specify the C compiler
 344 # to use, although the standard way to do this is to set the CC environment
 345 # variable.
 346 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 347
 348 case $template in
 349   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 350     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 351 esac
 352
 353 AC_PROG_CC([$pgac_cc_list])
 354 AC_PROG_CC_C99()
 355
 356 # Error out if the compiler does not support C99, as the codebase
 357 # relies on that.
 358 if test "$ac_cv_prog_cc_c99" = no; then
 359     AC_MSG_ERROR([C compiler "$CC" does not support C99])
 360 fi
 361
 362 AC_PROG_CXX([$pgac_cxx_list])
 363
 364 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 365 # but has idiosyncrasies of its own.  We assume icc will define
 366 # __INTEL_COMPILER regardless of CFLAGS.
 367 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 368 choke me
 369 @%:@endif])], [ICC=yes], [ICC=no])
 370
 371 # Check if it's Sun Studio compiler. We assume that
 372 # __SUNPRO_C will be defined for Sun Studio compilers
 373 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 374 choke me
 375 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 376
 377 AC_SUBST(SUN_STUDIO_CC)
 378
 379
 380 #
 381 # LLVM
 382 #
 383 # Checked early because subsequent tests depend on it.
 384 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 385               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 386 AC_SUBST(with_llvm)
 387 dnl must use AS_IF here, else AC_REQUIRES inside PGAC_LLVM_SUPPORT malfunctions
 388 AS_IF([test "$with_llvm" = yes], [
 389   PGAC_LLVM_SUPPORT()
 390 ]) # fi
 391
 392
 393 unset CFLAGS
 394 unset CXXFLAGS
 395
 396 #
 397 # Read the template
 398 #
 399 . "$srcdir/src/template/$template" || exit
 400
 401 # C[XX]FLAGS are selected so:
 402 # If the user specifies something in the environment, that is used.
 403 # else:  If the template file set something, that is used.
 404 # else:  If coverage was enabled, don't set anything.
 405 # else:  If the compiler is GCC, then we use -O2.
 406 # else:  If the compiler is something else, then we use -O, unless debugging.
 407
 408 if test "$ac_env_CFLAGS_set" = set; then
 409   CFLAGS=$ac_env_CFLAGS_value
 410 elif test "${CFLAGS+set}" = set; then
 411   : # (keep what template set)
 412 elif test "$enable_coverage" = yes; then
 413   : # no optimization by default
 414 elif test "$GCC" = yes; then
 415   CFLAGS="-O2"
 416 else
 417   # if the user selected debug mode, don't use -O
 418   if test "$enable_debug" != yes; then
 419     CFLAGS="-O"
 420   fi
 421 fi
 422
 423 if test "$ac_env_CXXFLAGS_set" = set; then
 424   CXXFLAGS=$ac_env_CXXFLAGS_value
 425 elif test "${CXXFLAGS+set}" = set; then
 426   : # (keep what template set)
 427 elif test "$enable_coverage" = yes; then
 428   : # no optimization by default
 429 elif test "$GCC" = yes; then
 430   CXXFLAGS="-O2"
 431 else
 432   # if the user selected debug mode, don't use -O
 433   if test "$enable_debug" != yes; then
 434     CXXFLAGS="-O"
 435   fi
 436 fi
 437
 438 # When generating bitcode (for inlining) we always want to use -O2
 439 # even when --enable-debug is specified. The bitcode it's not going to
 440 # be used for line-by-line debugging, and JIT inlining doesn't work
 441 # without at least -O1 (otherwise clang will emit 'noinline'
 442 # attributes everywhere), which is bad for testing.  Still allow the
 443 # environment to override if done explicitly.
 444 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 445   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 446 else
 447   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 448 fi
 449 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 450   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 451 else
 452   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 453 fi
 454
 455 # C[XX]FLAGS we determined above will be added back at the end
 456 user_CFLAGS=$CFLAGS
 457 CFLAGS=""
 458 user_CXXFLAGS=$CXXFLAGS
 459 CXXFLAGS=""
 460 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 461 BITCODE_CFLAGS=""
 462 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 463 BITCODE_CXXFLAGS=""
 464
 465 # set CFLAGS_VECTOR from the environment, if available
 466 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 467   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 468 fi
 469
 470 # Some versions of GCC support some additional useful warning flags.
 471 # Check whether they are supported, and add them to CFLAGS if so.
 472 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 473 # but has its own.  Also check other compiler-specific flags here.
 474
 475 if test "$GCC" = yes -a "$ICC" = no; then
 476   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 477   CXXFLAGS="-Wall -Wpointer-arith"
 478   # These work in some but not all gcc versions
 479   save_CFLAGS=$CFLAGS
 480   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 481   # -Wdeclaration-after-statement isn't applicable for C++.  Specific C files
 482   # disable it, so AC_SUBST the negative form.
 483   PERMIT_DECLARATION_AFTER_STATEMENT=
 484   if test x"save_$CFLAGS" != x"$CFLAGS"; then
 485     PERMIT_DECLARATION_AFTER_STATEMENT=-Wno-declaration-after-statement
 486   fi
 487   AC_SUBST(PERMIT_DECLARATION_AFTER_STATEMENT)
 488   # Really don't want VLAs to be used in our dialect of C
 489   PGAC_PROG_CC_CFLAGS_OPT([-Werror=vla])
 490   # -Wvla is not applicable for C++
 491   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 492   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 493   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 494   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 495   # This was included in -Wall/-Wformat in older GCC versions
 496   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 497   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 498   # Disable strict-aliasing rules; needed for gcc 3.3+
 499   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 500   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 501   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 502   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 503   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 504   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 505   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 506   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 507   # Optimization flags for specific files that benefit from vectorization
 508   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 509   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 510   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 511   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 512   # test for the positive form and if that works, add the negative form
 513   NOT_THE_CFLAGS=""
 514   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 515   if test -n "$NOT_THE_CFLAGS"; then
 516     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 517   fi
 518   # Similarly disable useless truncation warnings from gcc 8+
 519   NOT_THE_CFLAGS=""
 520   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 521   if test -n "$NOT_THE_CFLAGS"; then
 522     CFLAGS="$CFLAGS -Wno-format-truncation"
 523   fi
 524   NOT_THE_CFLAGS=""
 525   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 526   if test -n "$NOT_THE_CFLAGS"; then
 527     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 528   fi
 529 elif test "$ICC" = yes; then
 530   # Intel's compiler has a bug/misoptimization in checking for
 531   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 532   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 533   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 534   # Make sure strict aliasing is off (though this is said to be the default)
 535   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 536   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 537 elif test "$PORTNAME" = "aix"; then
 538   # AIX's xlc has to have strict aliasing turned off too
 539   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 540   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 541   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 542   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 543 elif test "$PORTNAME" = "hpux"; then
 544   # On some versions of HP-UX, libm functions do not set errno by default.
 545   # Fix that by using +Olibmerrno if the compiler recognizes it.
 546   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 547   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 548 fi
 549
 550 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 551
 552 # Determine flags used to emit bitcode for JIT inlining. Need to test
 553 # for behaviour changing compiler flags, to keep compatibility with
 554 # compiler used for normal postgres code.
 555 if test "$with_llvm" = yes ; then
 556   CLANGXX="$CLANG -xc++"
 557
 558   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 559   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 560   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 561   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 562   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 563   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 564 fi
 565
 566 # supply -g if --enable-debug
 567 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 568   CFLAGS="$CFLAGS -g"
 569 fi
 570
 571 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 572   CXXFLAGS="$CXXFLAGS -g"
 573 fi
 574
 575 # enable code coverage if --enable-coverage
 576 if test "$enable_coverage" = yes; then
 577   if test "$GCC" = yes; then
 578     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 579     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 580   else
 581     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 582   fi
 583 fi
 584
 585 # enable profiling if --enable-profiling
 586 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 587   if test "$GCC" = yes; then
 588     AC_DEFINE([PROFILE_PID_DIR], 1,
 589            [Define to 1 to allow profiling output to be saved separately for each process.])
 590     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 591     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 592   else
 593     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 594   fi
 595 fi
 596
 597 # We already have this in Makefile.win32, but configure needs it too
 598 if test "$PORTNAME" = "win32"; then
 599   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 600 fi
 601
 602 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 603 # user-specified flags (if any) at the end.  This lets users override
 604 # the automatic additions.
 605 CFLAGS="$CFLAGS $user_CFLAGS"
 606 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 607 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 608 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 609
 610 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 611 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 612
 613 # Check if the compiler still works with the final flag settings
 614 # (note, we're not checking that for CXX, which is optional)
 615 AC_MSG_CHECKING([whether the C compiler still works])
 616 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 617   [AC_MSG_RESULT(yes)],
 618   [AC_MSG_RESULT(no)
 619    AC_MSG_ERROR([cannot proceed])])
 620
 621 # Defend against gcc -ffast-math
 622 if test "$GCC" = yes; then
 623 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 624 choke me
 625 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 626 fi
 627
 628 # Defend against clang being used on x86-32 without SSE2 enabled.  As current
 629 # versions of clang do not understand -fexcess-precision=standard, the use of
 630 # x87 floating point operations leads to problems like isinf possibly returning
 631 # false for a value that is infinite when converted from the 80bit register to
 632 # the 8byte memory representation.
 633 #
 634 # Only perform the test if the compiler doesn't understand
 635 # -fexcess-precision=standard, that way a potentially fixed compiler will work
 636 # automatically.
 637 if test "$pgac_cv_prog_CC_cflags__fexcess_precision_standard" = no; then
 638 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 639 @%:@if defined(__clang__) && defined(__i386__) && !defined(__SSE2_MATH__)
 640 choke me
 641 @%:@endif
 642 ])], [],
 643 [AC_MSG_ERROR([Compiling PostgreSQL with clang, on 32bit x86, requires SSE2 support. Use -msse2 or use gcc.])])
 644 fi
 645
 646 AC_PROG_CPP
 647 AC_SUBST(GCC)
 648
 649
 650 #
 651 # Set up TAS assembly code if needed; the template file has now had its
 652 # chance to request this.
 653 #
 654 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 655
 656 if test "$need_tas" = yes ; then
 657   TAS=tas.o
 658 else
 659   TAS=""
 660 fi
 661 AC_SUBST(TAS)
 662
 663
 664 #
 665 # Automatic dependency tracking
 666 #
 667 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 668               [autodepend=yes])
 669 AC_SUBST(autodepend)
 670
 671
 672 #
 673 # Enable assert checks
 674 #
 675 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 676               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 677                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 678
 679
 680 #
 681 # Include directories
 682 #
 683 ac_save_IFS=$IFS
 684 IFS="${IFS}${PATH_SEPARATOR}"
 685 # SRCH_INC comes from the template file
 686 for dir in $with_includes $SRCH_INC; do
 687   if test -d "$dir"; then
 688     INCLUDES="$INCLUDES -I$dir"
 689   else
 690     AC_MSG_WARN([*** Include directory $dir does not exist.])
 691   fi
 692 done
 693 IFS=$ac_save_IFS
 694 AC_SUBST(INCLUDES)
 695
 696
 697 #
 698 # Library directories
 699 #
 700 ac_save_IFS=$IFS
 701 IFS="${IFS}${PATH_SEPARATOR}"
 702 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 703 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 704   if test -d "$dir"; then
 705     LIBDIRS="$LIBDIRS -L$dir"
 706   else
 707     AC_MSG_WARN([*** Library directory $dir does not exist.])
 708   fi
 709 done
 710 IFS=$ac_save_IFS
 711
 712 #
 713 # Enable thread-safe client libraries
 714 #
 715 AC_MSG_CHECKING([allow thread-safe client libraries])
 716 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 717 if test "$enable_thread_safety" = yes; then
 718   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 719           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 720 fi
 721 AC_MSG_RESULT([$enable_thread_safety])
 722 AC_SUBST(enable_thread_safety)
 723
 724 #
 725 # ICU
 726 #
 727 AC_MSG_CHECKING([whether to build with ICU support])
 728 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 729               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 730 AC_MSG_RESULT([$with_icu])
 731 AC_SUBST(with_icu)
 732
 733 if test "$with_icu" = yes; then
 734   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 735 fi
 736
 737 #
 738 # Optionally build Tcl modules (PL/Tcl)
 739 #
 740 AC_MSG_CHECKING([whether to build with Tcl])
 741 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 742 AC_MSG_RESULT([$with_tcl])
 743 AC_SUBST([with_tcl])
 744
 745 # We see if the path to the Tcl/Tk configuration scripts is specified.
 746 # This will override the use of tclsh to find the paths to search.
 747
 748 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 749
 750 #
 751 # Optionally build Perl modules (PL/Perl)
 752 #
 753 AC_MSG_CHECKING([whether to build Perl modules])
 754 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 755 AC_MSG_RESULT([$with_perl])
 756 AC_SUBST(with_perl)
 757
 758 #
 759 # Optionally build Python modules (PL/Python)
 760 #
 761 AC_MSG_CHECKING([whether to build Python modules])
 762 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 763 AC_MSG_RESULT([$with_python])
 764 AC_SUBST(with_python)
 765
 766 #
 767 # GSSAPI
 768 #
 769 AC_MSG_CHECKING([whether to build with GSSAPI support])
 770 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 771 [
 772   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 773   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 774 ])
 775 AC_MSG_RESULT([$with_gssapi])
 776 AC_SUBST(with_gssapi)
 777
 778
 779 AC_SUBST(krb_srvtab)
 780
 781
 782 #
 783 # Kerberos configuration parameters
 784 #
 785 PGAC_ARG_REQ(with, krb-srvnam,
 786              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 787              [],
 788              [with_krb_srvnam="postgres"])
 789 AC_SUBST(with_krb_srvnam)
 790 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 791                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 792
 793
 794 #
 795 # PAM
 796 #
 797 AC_MSG_CHECKING([whether to build with PAM support])
 798 PGAC_ARG_BOOL(with, pam, no,
 799               [build with PAM support],
 800               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 801 AC_MSG_RESULT([$with_pam])
 802
 803
 804 #
 805 # BSD AUTH
 806 #
 807 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 808 PGAC_ARG_BOOL(with, bsd-auth, no,
 809               [build with BSD Authentication support],
 810               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 811 AC_MSG_RESULT([$with_bsd_auth])
 812
 813
 814 #
 815 # LDAP
 816 #
 817 AC_MSG_CHECKING([whether to build with LDAP support])
 818 PGAC_ARG_BOOL(with, ldap, no,
 819               [build with LDAP support],
 820               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 821 AC_MSG_RESULT([$with_ldap])
 822 AC_SUBST(with_ldap)
 823
 824
 825 #
 826 # Bonjour
 827 #
 828 AC_MSG_CHECKING([whether to build with Bonjour support])
 829 PGAC_ARG_BOOL(with, bonjour, no,
 830               [build with Bonjour support],
 831               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 832 AC_MSG_RESULT([$with_bonjour])
 833
 834
 835 #
 836 # OpenSSL
 837 #
 838 AC_MSG_CHECKING([whether to build with OpenSSL support])
 839 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 840               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 841 AC_MSG_RESULT([$with_openssl])
 842 AC_SUBST(with_openssl)
 843
 844 #
 845 # SELinux
 846 #
 847 AC_MSG_CHECKING([whether to build with SELinux support])
 848 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 849 AC_SUBST(with_selinux)
 850 AC_MSG_RESULT([$with_selinux])
 851
 852 #
 853 # Systemd
 854 #
 855 AC_MSG_CHECKING([whether to build with systemd support])
 856 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 857               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 858 AC_SUBST(with_systemd)
 859 AC_MSG_RESULT([$with_systemd])
 860
 861 #
 862 # Readline
 863 #
 864 PGAC_ARG_BOOL(with, readline, yes,
 865               [do not use GNU Readline nor BSD Libedit for editing])
 866 # readline on MinGW has problems with backslashes in psql and other bugs.
 867 # This is particularly a problem with non-US code pages.
 868 # Therefore disable its use until we understand the cause. 2004-07-20
 869 if test "$PORTNAME" = "win32"; then
 870   if test "$with_readline" = yes; then
 871     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 872     with_readline=no
 873   fi
 874 fi
 875
 876
 877 #
 878 # Prefer libedit
 879 #
 880 PGAC_ARG_BOOL(with, libedit-preferred, no,
 881               [prefer BSD Libedit over GNU Readline])
 882
 883
 884 #
 885 # UUID library
 886 #
 887 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 888 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 889 # UUID library.  More than one of these might be present on a given platform,
 890 # so we make the user say which one she wants.
 891 #
 892 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 893 if test x"$with_uuid" = x"" ; then
 894   with_uuid=no
 895 fi
 896 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 897 if test "$with_ossp_uuid" = yes ; then
 898   with_uuid=ossp
 899 fi
 900
 901 if test "$with_uuid" = bsd ; then
 902   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 903   UUID_EXTRA_OBJS="md5.o sha1.o"
 904 elif test "$with_uuid" = e2fs ; then
 905   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 906   UUID_EXTRA_OBJS="md5.o sha1.o"
 907 elif test "$with_uuid" = ossp ; then
 908   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 909   UUID_EXTRA_OBJS=""
 910 elif test "$with_uuid" = no ; then
 911   UUID_EXTRA_OBJS=""
 912 else
 913   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 914 fi
 915 AC_SUBST(with_uuid)
 916 AC_SUBST(UUID_EXTRA_OBJS)
 917
 918
 919 #
 920 # XML
 921 #
 922 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 923               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 924
 925 if test "$with_libxml" = yes ; then
 926   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 927   AC_ARG_VAR(XML2_CONFIG, [path to xml2-config utility])dnl
 928   if test -n "$XML2_CONFIG"; then
 929     for pgac_option in `$XML2_CONFIG --cflags`; do
 930       case $pgac_option in
 931         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 932       esac
 933     done
 934     for pgac_option in `$XML2_CONFIG --libs`; do
 935       case $pgac_option in
 936         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 937       esac
 938     done
 939   fi
 940 fi
 941
 942 AC_SUBST(with_libxml)
 943
 944 #
 945 # XSLT
 946 #
 947 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 948               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 949
 950
 951 AC_SUBST(with_libxslt)
 952
 953 #
 954 # tzdata
 955 #
 956 PGAC_ARG_REQ(with, system-tzdata,
 957              [DIR], [use system time zone data in DIR])
 958 AC_SUBST(with_system_tzdata)
 959
 960 #
 961 # Zlib
 962 #
 963 PGAC_ARG_BOOL(with, zlib, yes,
 964               [do not use Zlib])
 965 AC_SUBST(with_zlib)
 966
 967 #
 968 # Elf
 969 #
 970
 971 # Assume system is ELF if it predefines __ELF__ as 1,
 972 # otherwise believe host_os based default.
 973 case $host_os in
 974     freebsd1*|freebsd2*) elf=no;;
 975     freebsd3*|freebsd4*) elf=yes;;
 976 esac
 977
 978 AC_EGREP_CPP(yes,
 979 [#if __ELF__
 980   yes
 981 #endif
 982 ],
 983 [ELF_SYS=true],
 984 [if test "X$elf" = "Xyes" ; then
 985   ELF_SYS=true
 986 else
 987   ELF_SYS=
 988 fi])
 989 AC_SUBST(ELF_SYS)
 990
 991 #
 992 # Assignments
 993 #
 994
 995 CPPFLAGS="$CPPFLAGS $INCLUDES"
 996 LDFLAGS="$LDFLAGS $LIBDIRS"
 997
 998 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 999 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
1000
1001 PGAC_PROG_LD
1002 AC_SUBST(LD)
1003 AC_SUBST(with_gnu_ld)
1004 AC_PROG_RANLIB
1005 PGAC_CHECK_STRIP
1006 AC_CHECK_TOOL(AR, ar, ar)
1007 if test "$PORTNAME" = "win32"; then
1008   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
1009   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
1010   AC_CHECK_TOOL(WINDRES, windres, windres)
1011 fi
1012
1013 AC_PROG_INSTALL
1014 # When Autoconf chooses install-sh as install program it tries to generate
1015 # a relative path to it in each makefile where it substitutes it. This clashes
1016 # with our Makefile.global concept. This workaround helps.
1017 case $INSTALL in
1018   *install-sh*) install_bin='';;
1019   *) install_bin=$INSTALL;;
1020 esac
1021 AC_SUBST(install_bin)
1022
1023 PGAC_PATH_PROGS(TAR, tar)
1024 AC_PROG_LN_S
1025 AC_PROG_MKDIR_P
1026 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
1027 # a relative path to it in each makefile where it substitutes it. This clashes
1028 # with our Makefile.global concept. This workaround helps.
1029 case $MKDIR_P in
1030   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1031 esac
1032
1033 PGAC_PATH_BISON
1034 PGAC_PATH_FLEX
1035
1036 PGAC_PATH_PERL
1037 if test "$with_perl" = yes; then
1038   if test -z "$PERL"; then
1039     AC_MSG_ERROR([Perl not found])
1040   fi
1041   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1042   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1043     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1044 You might have to rebuild your Perl installation.  Refer to the
1045 documentation for details.  Use --without-perl to disable building
1046 PL/Perl.])
1047   fi
1048   # On most platforms, archlibexp is also where the Perl include files live ...
1049   perl_includespec="-I$perl_archlibexp/CORE"
1050   # ... but on newer macOS versions, we must use -iwithsysroot to look
1051   # under $PG_SYSROOT
1052   if test \! -f "$perl_archlibexp/CORE/perl.h" ; then
1053     if test -f "$PG_SYSROOT$perl_archlibexp/CORE/perl.h" ; then
1054       perl_includespec="-iwithsysroot $perl_archlibexp/CORE"
1055     fi
1056   fi
1057   AC_SUBST(perl_includespec)dnl
1058   PGAC_CHECK_PERL_EMBED_CCFLAGS
1059   PGAC_CHECK_PERL_EMBED_LDFLAGS
1060 fi
1061
1062 if test "$with_python" = yes; then
1063   PGAC_PATH_PYTHON
1064   PGAC_CHECK_PYTHON_EMBED_SETUP
1065 fi
1066
1067 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1068   PGAC_PATH_PROGS(ZIC, zic)
1069   if test -z "$ZIC"; then
1070     AC_MSG_ERROR([
1071 When cross-compiling, either use the option --with-system-tzdata to use
1072 existing time-zone data, or set the environment variable ZIC to a zic
1073 program to use during the build.])
1074   fi
1075 fi
1076
1077 #
1078 # Pthreads
1079 #
1080 # For each platform, we need to know about any special compile and link
1081 # libraries, and whether the normal C function names are thread-safe.
1082 # See the comment at the top of src/port/thread.c for more information.
1083 # WIN32 doesn't need the pthread tests;  it always uses threads
1084 #
1085 # These tests are run before the library-tests, because linking with the
1086 # other libraries can pull in the pthread functions as a side-effect.  We
1087 # want to use the -pthread or similar flags directly, and not rely on
1088 # the side-effects of linking with some other library.
1089
1090 dnl note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1091 dnl invocation below is the first one in the script, and autoconf generates
1092 dnl additional code for that, which must not be inside the if-block. AS_IF
1093 dnl knows how to do that.
1094 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1095 [ # then
1096 AX_PTHREAD      # set thread flags
1097
1098 # Some platforms use these, so just define them.  They can't hurt if they
1099 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1100 # enables 5-arg getpwuid_r, among other things.
1101 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1102
1103 # Check for *_r functions
1104 _CFLAGS="$CFLAGS"
1105 _LIBS="$LIBS"
1106 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1107 LIBS="$LIBS $PTHREAD_LIBS"
1108
1109 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1110 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1111
1112 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1113
1114 # Do test here with the proper thread flags
1115 PGAC_FUNC_STRERROR_R_INT
1116
1117 CFLAGS="$_CFLAGS"
1118 LIBS="$_LIBS"
1119
1120 ], [ # else
1121 # do not use values from template file
1122 PTHREAD_CFLAGS=
1123 PTHREAD_LIBS=
1124 ]) # fi
1125
1126 AC_SUBST(PTHREAD_CFLAGS)
1127 AC_SUBST(PTHREAD_LIBS)
1128
1129
1130 ##
1131 ## Libraries
1132 ##
1133 ## Most libraries are included only if they demonstrably provide a function
1134 ## we need, but libm is an exception: always include it, because there are
1135 ## too many compilers that play cute optimization games that will break
1136 ## probes for standard functions such as pow().
1137 ##
1138
1139 AC_CHECK_LIB(m, main)
1140 AC_SEARCH_LIBS(setproctitle, util)
1141 AC_SEARCH_LIBS(dlopen, dl)
1142 AC_SEARCH_LIBS(socket, [socket ws2_32])
1143 AC_SEARCH_LIBS(shl_load, dld)
1144 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1145 AC_SEARCH_LIBS(crypt, crypt)
1146 AC_SEARCH_LIBS(shm_open, rt)
1147 AC_SEARCH_LIBS(shm_unlink, rt)
1148 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1149 # Solaris:
1150 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1151 # Required for thread_test.c on Solaris
1152 AC_SEARCH_LIBS(sched_yield, rt)
1153 # Required for thread_test.c on Solaris 2.5:
1154 # Other ports use it too (HP-UX) so test unconditionally
1155 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1156 # Cygwin:
1157 AC_SEARCH_LIBS(shmget, cygipc)
1158
1159 if test "$with_readline" = yes; then
1160   PGAC_CHECK_READLINE
1161   if test x"$pgac_cv_check_readline" = x"no"; then
1162     AC_MSG_ERROR([readline library not found
1163 If you have readline already installed, see config.log for details on the
1164 failure.  It is possible the compiler isn't looking in the proper directory.
1165 Use --without-readline to disable readline support.])
1166   fi
1167 fi
1168
1169 if test "$with_zlib" = yes; then
1170   AC_CHECK_LIB(z, inflate, [],
1171                [AC_MSG_ERROR([zlib library not found
1172 If you have zlib already installed, see config.log for details on the
1173 failure.  It is possible the compiler isn't looking in the proper directory.
1174 Use --without-zlib to disable zlib support.])])
1175 fi
1176
1177 if test "$enable_spinlocks" = yes; then
1178   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1179 else
1180   AC_MSG_WARN([
1181 *** Not using spinlocks will cause poor performance.])
1182 fi
1183
1184 if test "$enable_atomics" = yes; then
1185   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1186 else
1187   AC_MSG_WARN([
1188 *** Not using atomic operations will cause poor performance.])
1189 fi
1190
1191 if test "$with_gssapi" = yes ; then
1192   if test "$PORTNAME" != "win32"; then
1193     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1194                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1195   else
1196     LIBS="$LIBS -lgssapi32"
1197   fi
1198 fi
1199
1200 if test "$with_openssl" = yes ; then
1201   dnl Order matters!
1202   if test "$PORTNAME" != "win32"; then
1203      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1204      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1205   else
1206      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1207      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1208   fi
1209   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1210   # Functions introduced in OpenSSL 1.1.0. We used to check for
1211   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1212   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1213   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1214   # functions.
1215   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1216   # OpenSSL versions before 1.1.0 required setting callback functions, for
1217   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1218   # function was removed.
1219   AC_CHECK_FUNCS([CRYPTO_lock])
1220 fi
1221
1222 if test "$with_pam" = yes ; then
1223   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1224 fi
1225
1226 if test "$with_libxml" = yes ; then
1227   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1228 fi
1229
1230 if test "$with_libxslt" = yes ; then
1231   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1232 fi
1233
1234 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1235 if test "$with_ldap" = yes ; then
1236   _LIBS="$LIBS"
1237   if test "$PORTNAME" != "win32"; then
1238     AC_CHECK_LIB(ldap, ldap_bind, [],
1239                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1240                  [$EXTRA_LDAP_LIBS])
1241     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1242     if test "$enable_thread_safety" = yes; then
1243       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1244       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1245                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1246                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1247       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1248     else
1249       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1250     fi
1251     AC_CHECK_FUNCS([ldap_initialize])
1252   else
1253     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1254     LDAP_LIBS_FE="-lwldap32"
1255     LDAP_LIBS_BE="-lwldap32"
1256   fi
1257   LIBS="$_LIBS"
1258 fi
1259 AC_SUBST(LDAP_LIBS_FE)
1260 AC_SUBST(LDAP_LIBS_BE)
1261
1262 # for contrib/sepgsql
1263 if test "$with_selinux" = yes; then
1264   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1265                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1266 fi
1267
1268 # for contrib/uuid-ossp
1269 if test "$with_uuid" = bsd ; then
1270   # On BSD, the UUID functions are in libc
1271   AC_CHECK_FUNC(uuid_to_string,
1272     [UUID_LIBS=""],
1273     [AC_MSG_ERROR([BSD UUID functions are not present])])
1274 elif test "$with_uuid" = e2fs ; then
1275   # On macOS, the UUID functions are in libc
1276   AC_CHECK_FUNC(uuid_generate,
1277     [UUID_LIBS=""],
1278     [AC_CHECK_LIB(uuid, uuid_generate,
1279       [UUID_LIBS="-luuid"],
1280       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1281 elif test "$with_uuid" = ossp ; then
1282   AC_CHECK_LIB(ossp-uuid, uuid_export,
1283     [UUID_LIBS="-lossp-uuid"],
1284     [AC_CHECK_LIB(uuid, uuid_export,
1285       [UUID_LIBS="-luuid"],
1286       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1287 fi
1288 AC_SUBST(UUID_LIBS)
1289
1290
1291 ##
1292 ## Header files
1293 ##
1294
1295 AC_HEADER_STDBOOL
1296
1297 AC_CHECK_HEADERS(m4_normalize([
1298         atomic.h
1299         copyfile.h
1300         crypt.h
1301         fp_class.h
1302         getopt.h
1303         ieeefp.h
1304         ifaddrs.h
1305         langinfo.h
1306         mbarrier.h
1307         poll.h
1308         sys/epoll.h
1309         sys/ipc.h
1310         sys/prctl.h
1311         sys/procctl.h
1312         sys/pstat.h
1313         sys/resource.h
1314         sys/select.h
1315         sys/sem.h
1316         sys/shm.h
1317         sys/sockio.h
1318         sys/tas.h
1319         sys/un.h
1320         termios.h
1321         ucred.h
1322         utime.h
1323         wchar.h
1324         wctype.h
1325 ]))
1326
1327 # On BSD, test for net/if.h will fail unless sys/socket.h
1328 # is included first.
1329 AC_CHECK_HEADERS(net/if.h, [], [],
1330 [AC_INCLUDES_DEFAULT
1331 #include <sys/socket.h>
1332 ])
1333
1334 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1335 # is included first.
1336 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1337 [AC_INCLUDES_DEFAULT
1338 #include <sys/param.h>
1339 ])
1340
1341 # At least on IRIX, test for netinet/tcp.h will fail unless
1342 # netinet/in.h is included first.
1343 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1344 [AC_INCLUDES_DEFAULT
1345 #include <netinet/in.h>
1346 ])
1347
1348 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1349   AC_CHECK_HEADERS(readline/readline.h, [],
1350         [AC_CHECK_HEADERS(readline.h, [],
1351                 [AC_MSG_ERROR([readline header not found
1352 If you have readline already installed, see config.log for details on the
1353 failure.  It is possible the compiler isn't looking in the proper directory.
1354 Use --without-readline to disable readline support.])])])
1355   AC_CHECK_HEADERS(readline/history.h, [],
1356         [AC_CHECK_HEADERS(history.h, [],
1357                 [AC_MSG_ERROR([history header not found
1358 If you have readline already installed, see config.log for details on the
1359 failure.  It is possible the compiler isn't looking in the proper directory.
1360 Use --without-readline to disable readline support.])])])
1361 fi
1362
1363 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1364 # Some installations of libedit usurp /usr/include/readline/, which seems
1365 # bad practice, since in combined installations readline will have its headers
1366 # there.  We might have to resort to AC_EGREP checks to make sure we found
1367 # the proper header...
1368   AC_CHECK_HEADERS(editline/readline.h, [],
1369         [AC_CHECK_HEADERS(readline.h, [],
1370                 [AC_CHECK_HEADERS(readline/readline.h, [],
1371                         [AC_MSG_ERROR([readline header not found
1372 If you have libedit already installed, see config.log for details on the
1373 failure.  It is possible the compiler isn't looking in the proper directory.
1374 Use --without-readline to disable libedit support.])])])])
1375 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1376 # not be there at all.  Hence, don't complain if not found.  We must check
1377 # though, since in yet other versions it is an independent header.
1378   AC_CHECK_HEADERS(editline/history.h, [],
1379         [AC_CHECK_HEADERS(history.h, [],
1380                 [AC_CHECK_HEADERS(readline/history.h)])])
1381 fi
1382
1383 if test "$with_zlib" = yes; then
1384   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1385 If you have zlib already installed, see config.log for details on the
1386 failure.  It is possible the compiler isn't looking in the proper directory.
1387 Use --without-zlib to disable zlib support.])])
1388 fi
1389
1390 if test "$with_gssapi" = yes ; then
1391   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1392         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1393 fi
1394
1395 if test "$with_openssl" = yes ; then
1396   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1397   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1398 fi
1399
1400 if test "$with_pam" = yes ; then
1401   AC_CHECK_HEADERS(security/pam_appl.h, [],
1402                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1403                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1404 fi
1405
1406 if test "$with_bsd_auth" = yes ; then
1407   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1408 fi
1409
1410 if test "$with_systemd" = yes ; then
1411   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1412 fi
1413
1414 if test "$with_libxml" = yes ; then
1415   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1416 fi
1417
1418 if test "$with_libxslt" = yes ; then
1419   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1420 fi
1421
1422 if test "$with_ldap" = yes ; then
1423   if test "$PORTNAME" != "win32"; then
1424      AC_CHECK_HEADERS(ldap.h, [],
1425                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1426      PGAC_LDAP_SAFE
1427   else
1428      AC_CHECK_HEADERS(winldap.h, [],
1429                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1430                       [AC_INCLUDES_DEFAULT
1431 #include <windows.h>
1432                       ])
1433   fi
1434 fi
1435
1436 if test "$with_bonjour" = yes ; then
1437   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1438 dnl At some point we might add something like
1439 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1440 dnl but right now, what that would mainly accomplish is to encourage
1441 dnl people to try to use the avahi implementation, which does not work.
1442 dnl If you want to use Apple's own Bonjour code on another platform,
1443 dnl just add -ldns_sd to LIBS manually.
1444 fi
1445
1446 # for contrib/uuid-ossp
1447 if test "$with_uuid" = bsd ; then
1448   AC_CHECK_HEADERS(uuid.h,
1449     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1450       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1451     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1452 elif test "$with_uuid" = e2fs ; then
1453   AC_CHECK_HEADERS(uuid/uuid.h,
1454     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1455       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1456     [AC_CHECK_HEADERS(uuid.h,
1457       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1458         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1459       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1460 elif test "$with_uuid" = ossp ; then
1461   AC_CHECK_HEADERS(ossp/uuid.h,
1462     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1463       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1464     [AC_CHECK_HEADERS(uuid.h,
1465       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1466         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1467       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1468 fi
1469
1470 if test "$PORTNAME" = "win32" ; then
1471    AC_CHECK_HEADERS(crtdefs.h)
1472 fi
1473
1474 ##
1475 ## Types, structures, compiler characteristics
1476 ##
1477
1478 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1479 AC_C_BIGENDIAN
1480 AC_C_INLINE
1481 PGAC_PRINTF_ARCHETYPE
1482 AC_C_FLEXIBLE_ARRAY_MEMBER
1483 PGAC_C_SIGNED
1484 PGAC_C_FUNCNAME_SUPPORT
1485 PGAC_C_STATIC_ASSERT
1486 PGAC_C_TYPEOF
1487 PGAC_C_TYPES_COMPATIBLE
1488 PGAC_C_BUILTIN_CONSTANT_P
1489 PGAC_C_BUILTIN_UNREACHABLE
1490 PGAC_C_COMPUTED_GOTO
1491 PGAC_STRUCT_TIMEZONE
1492 PGAC_UNION_SEMUN
1493 PGAC_STRUCT_SOCKADDR_UN
1494 PGAC_STRUCT_SOCKADDR_STORAGE
1495 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1496 PGAC_STRUCT_ADDRINFO
1497 AC_TYPE_INTPTR_T
1498 AC_TYPE_UINTPTR_T
1499 AC_TYPE_LONG_LONG_INT
1500
1501 PGAC_TYPE_LOCALE_T
1502
1503 # MSVC doesn't cope well with defining restrict to __restrict, the
1504 # spelling it understands, because it conflicts with
1505 # __declspec(restrict). Therefore we define pg_restrict to the
1506 # appropriate definition, which presumably won't conflict.
1507 #
1508 # Allow platforms with buggy compilers to force restrict to not be
1509 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1510 # template.
1511 AC_C_RESTRICT
1512 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1513   pg_restrict=""
1514 else
1515   pg_restrict="$ac_cv_c_restrict"
1516 fi
1517 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1518 [Define to keyword to use for C99 restrict support, or to nothing if not
1519 supported])
1520
1521 AC_CHECK_TYPES([struct cmsgcred], [], [],
1522 [#include <sys/socket.h>
1523 #include <sys/param.h>
1524 #ifdef HAVE_SYS_UCRED_H
1525 #include <sys/ucred.h>
1526 #endif])
1527
1528 AC_CHECK_TYPES([struct option], [], [],
1529 [#ifdef HAVE_GETOPT_H
1530 #include <getopt.h>
1531 #endif])
1532
1533 if test "$with_zlib" = yes; then
1534   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1535   # did not).  While we could work around the lack of z_streamp, it
1536   # seems unwise to encourage people to use such old zlib versions...
1537   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1538 Use --without-zlib to disable zlib support.])],
1539                 [#include <zlib.h>])
1540 fi
1541
1542 case $host_cpu in
1543   x86_64)
1544     # On x86_64, check if we can compile a popcntq instruction
1545     AC_CACHE_CHECK([whether assembler supports x86_64 popcntq],
1546                    [pgac_cv_have_x86_64_popcntq],
1547     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1548         [long long x = 1; long long r;
1549          __asm__ __volatile__ (" popcntq %1,%0\n" : "=q"(r) : "rm"(x));])],
1550         [pgac_cv_have_x86_64_popcntq=yes],
1551         [pgac_cv_have_x86_64_popcntq=no])])
1552     if test x"$pgac_cv_have_x86_64_popcntq" = xyes ; then
1553         AC_DEFINE(HAVE_X86_64_POPCNTQ, 1, [Define to 1 if the assembler supports X86_64's POPCNTQ instruction.])
1554     fi
1555   ;;
1556   ppc*|powerpc*)
1557     # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1558     AC_CACHE_CHECK([whether assembler supports lwarx hint bit],
1559                    [pgac_cv_have_ppc_mutex_hint],
1560     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1561         [int a = 0; int *p = &a; int r;
1562          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1563         [pgac_cv_have_ppc_mutex_hint=yes],
1564         [pgac_cv_have_ppc_mutex_hint=no])])
1565     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1566         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1567     fi
1568   ;;
1569 esac
1570
1571 # Check largefile support.  You might think this is a system service not a
1572 # compiler characteristic, but you'd be wrong.  We must check this before
1573 # probing existence of related functions such as fseeko, since the largefile
1574 # defines can affect what is generated for that.
1575 if test "$PORTNAME" != "win32"; then
1576    AC_SYS_LARGEFILE
1577    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1578    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1579    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1580    dnl versions where the feature actually works, it's on by default anyway.
1581    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1582 fi
1583
1584 dnl Check for largefile support (must be after AC_SYS_LARGEFILE)
1585 AC_CHECK_SIZEOF([off_t])
1586
1587 # If we don't have largefile support, can't handle segsize >= 2GB.
1588 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1589    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1590 fi
1591
1592 AC_CHECK_SIZEOF([bool], [],
1593 [#ifdef HAVE_STDBOOL_H
1594 #include <stdbool.h>
1595 #endif])
1596
1597
1598 ##
1599 ## Functions, global variables
1600 ##
1601
1602 PGAC_VAR_INT_TIMEZONE
1603 AC_FUNC_ACCEPT_ARGTYPES
1604 PGAC_FUNC_GETTIMEOFDAY_1ARG
1605 PGAC_FUNC_WCSTOMBS_L
1606
1607 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1608 # symbols that that library has no business exposing to the world.  Pending
1609 # acquisition of a clue by those developers, ignore libedit (including its
1610 # possible alias of libreadline) while checking for everything else.
1611 LIBS_including_readline="$LIBS"
1612 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1613
1614 AC_CHECK_FUNCS(m4_normalize([
1615         cbrt
1616         clock_gettime
1617         copyfile
1618         fdatasync
1619         getifaddrs
1620         getpeerucred
1621         getrlimit
1622         mbstowcs_l
1623         memmove
1624         poll
1625         posix_fallocate
1626         ppoll
1627         pstat
1628         pthread_is_threaded_np
1629         readlink
1630         setproctitle
1631         setproctitle_fast
1632         setsid
1633         shm_open
1634         strchrnul
1635         strsignal
1636         symlink
1637         sync_file_range
1638         uselocale
1639         utime
1640         utimes
1641         wcstombs_l
1642 ]))
1643
1644 # These typically are compiler builtins, for which AC_CHECK_FUNCS fails.
1645 PGAC_CHECK_BUILTIN_FUNC([__builtin_bswap16], [int x])
1646 PGAC_CHECK_BUILTIN_FUNC([__builtin_bswap32], [int x])
1647 PGAC_CHECK_BUILTIN_FUNC([__builtin_bswap64], [long int x])
1648 # We assume that we needn't test all widths of these explicitly:
1649 PGAC_CHECK_BUILTIN_FUNC([__builtin_clz], [unsigned int x])
1650 PGAC_CHECK_BUILTIN_FUNC([__builtin_ctz], [unsigned int x])
1651 PGAC_CHECK_BUILTIN_FUNC([__builtin_popcount], [unsigned int x])
1652
1653 AC_REPLACE_FUNCS(fseeko)
1654 case $host_os in
1655         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1656         # Mingw uses macros to access Win32 API calls
1657         netbsd*|mingw*)
1658                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1659                 ac_cv_func_fseeko=yes;;
1660         *)
1661                 AC_FUNC_FSEEKO;;
1662 esac
1663
1664 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1665 # by calling it, 2009-04-02
1666 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1667 dnl must use AS_IF here, else AC_REQUIRES inside AC_CHECK_DECLS malfunctions
1668 AS_IF([test "$PORTNAME" != "solaris"], [
1669 AC_CHECK_FUNCS(posix_fadvise)
1670 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1671 ]) # fi
1672
1673 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1674 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1675 # This is probably only present on macOS, but may as well check always
1676 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1677
1678 AC_CHECK_DECLS([RTLD_GLOBAL, RTLD_NOW], [], [], [#include <dlfcn.h>])
1679
1680 AC_CHECK_TYPE([struct sockaddr_in6],
1681         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])],
1682         [],
1683 [$ac_includes_default
1684 #include <netinet/in.h>])
1685
1686 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1687 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1688 [#include <machine/vmparam.h>
1689 #include <sys/exec.h>
1690 ],
1691 [PS_STRINGS->ps_nargvstr = 1;
1692 PS_STRINGS->ps_argvstr = "foo";])],
1693 [pgac_cv_var_PS_STRINGS=yes],
1694 [pgac_cv_var_PS_STRINGS=no])])
1695 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1696   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1697 fi
1698
1699
1700 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1701 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1702 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1703 #include <math.h>
1704 double glob_double;
1705 ],
1706 [return isinf(glob_double) ? 0 : 1;])],
1707 [ac_cv_func_isinf=yes],
1708 [ac_cv_func_isinf=no])])
1709
1710 if test $ac_cv_func_isinf = yes ; then
1711   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1712 else
1713   AC_LIBOBJ(isinf)
1714   # Look for a way to implement a substitute for isinf()
1715   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1716 fi
1717
1718 AC_REPLACE_FUNCS(m4_normalize([
1719         crypt
1720         dlopen
1721         fls
1722         getopt
1723         getrusage
1724         inet_aton
1725         mkdtemp
1726         pread
1727         pwrite
1728         random
1729         rint
1730         srandom
1731         strlcat
1732         strlcpy
1733         strnlen
1734         strtof
1735 ]))
1736
1737 case $host_os in
1738         # Cygwin and (apparently, based on test results) Mingw both
1739         # have a broken strtof(), so substitute the same replacement
1740         # code we use with VS2013. That's not a perfect fix, since
1741         # (unlike with VS2013) it doesn't avoid double-rounding, but
1742         # we have no better options. To get that, though, we have to
1743         # force the file to be compiled despite HAVE_STRTOF.
1744         mingw*|cygwin*)
1745                 AC_LIBOBJ([strtof])
1746                 AC_MSG_NOTICE([On $host_os we will use our strtof wrapper.])
1747         ;;
1748 esac
1749
1750 case $host_os in
1751
1752         # Windows uses a specialised env handler
1753         # and doesn't need a replacement getpeereid because it doesn't use
1754         # Unix sockets.
1755         mingw*)
1756                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1757                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1758                 ac_cv_func_unsetenv=yes
1759                 ac_cv_func_getpeereid=yes;;
1760         *)
1761                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1762                 ;;
1763 esac
1764
1765 # System's version of getaddrinfo(), if any, may be used only if we found
1766 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1767 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1768 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1769    test "$PORTNAME" != "win32"; then
1770   AC_REPLACE_FUNCS([getaddrinfo])
1771 else
1772   AC_LIBOBJ(getaddrinfo)
1773 fi
1774
1775 # Similarly, use system's getopt_long() only if system provides struct option.
1776 if test x"$ac_cv_type_struct_option" = xyes ; then
1777   AC_REPLACE_FUNCS([getopt_long])
1778 else
1779   AC_LIBOBJ(getopt_long)
1780 fi
1781
1782 # On OpenBSD and Solaris, getopt() doesn't do what we want for long options
1783 # (i.e., allow '-' as a flag character), so use our version on those platforms.
1784 if test "$PORTNAME" = "openbsd" -o "$PORTNAME" = "solaris"; then
1785   AC_LIBOBJ(getopt)
1786 fi
1787
1788 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1789 # so always use our version on Windows.
1790 if test "$PORTNAME" = "win32"; then
1791   AC_LIBOBJ(getopt)
1792   AC_LIBOBJ(getopt_long)
1793 fi
1794
1795 # Win32 (really MinGW) support
1796 if test "$PORTNAME" = "win32"; then
1797   AC_CHECK_FUNCS(_configthreadlocale)
1798   AC_REPLACE_FUNCS(gettimeofday)
1799   AC_LIBOBJ(dirmod)
1800   AC_LIBOBJ(kill)
1801   AC_LIBOBJ(open)
1802   AC_LIBOBJ(system)
1803   AC_LIBOBJ(win32env)
1804   AC_LIBOBJ(win32error)
1805   AC_LIBOBJ(win32security)
1806   AC_LIBOBJ(win32setlocale)
1807   AC_DEFINE([HAVE_SYMLINK], 1,
1808             [Define to 1 if you have the `symlink' function.])
1809   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1810 #define WIN32_LEAN_AND_MEAN
1811 #include <windows.h>
1812 #include <string.h>
1813 #include <dbghelp.h>])
1814 fi
1815 if test x"$pgac_minidump_type" = x"yes" ; then
1816   AC_SUBST(have_win32_dbghelp,yes)
1817 else
1818   AC_SUBST(have_win32_dbghelp,no)
1819 fi
1820
1821 # Cygwin needs only a bit of that
1822 if test "$PORTNAME" = "cygwin"; then
1823   AC_LIBOBJ(dirmod)
1824 fi
1825
1826 AC_CHECK_FUNC(syslog,
1827               [AC_CHECK_HEADER(syslog.h,
1828                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1829
1830 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1831 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1832   [extern int opterr; opterr = 1;])],
1833   [pgac_cv_var_int_opterr=yes],
1834   [pgac_cv_var_int_opterr=no])])
1835 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1836   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1837 fi
1838
1839 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1840 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1841   [extern int optreset; optreset = 1;])],
1842   [pgac_cv_var_int_optreset=yes],
1843   [pgac_cv_var_int_optreset=no])])
1844 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1845   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1846 fi
1847
1848 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1849 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1850 # strto[u]ll may exist but not be declared
1851 AC_CHECK_DECLS([strtoll, strtoull])
1852
1853 if test "$with_icu" = yes; then
1854   ac_save_CPPFLAGS=$CPPFLAGS
1855   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1856
1857   # Verify we have ICU's header files
1858   AC_CHECK_HEADER(unicode/ucol.h, [],
1859         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1860
1861   CPPFLAGS=$ac_save_CPPFLAGS
1862 fi
1863
1864 if test "$with_llvm" = yes; then
1865   PGAC_CHECK_LLVM_FUNCTIONS()
1866 fi
1867
1868 # Lastly, restore full LIBS list and check for readline/libedit symbols
1869 LIBS="$LIBS_including_readline"
1870
1871 if test "$with_readline" = yes; then
1872   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1873   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1874   AC_CHECK_FUNCS([append_history history_truncate_file])
1875 fi
1876
1877
1878 # This test makes sure that run tests work at all.  Sometimes a shared
1879 # library is found by the linker, but the runtime linker can't find it.
1880 # This check should come after all modifications of compiler or linker
1881 # variables, and before any other run tests.
1882 AC_MSG_CHECKING([test program])
1883 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1884 [AC_MSG_RESULT(ok)],
1885 [AC_MSG_RESULT(failed)
1886 AC_MSG_ERROR([[
1887 Could not execute a simple test program.  This may be a problem
1888 related to locating shared libraries.  Check the file 'config.log'
1889 for the exact reason.]])],
1890 [AC_MSG_RESULT([cross-compiling])])
1891
1892 # --------------------
1893 # Run tests below here
1894 # --------------------
1895
1896 dnl Check to see if we have a working 64-bit integer type.
1897 dnl Since Postgres 8.4, we no longer support compilers without a working
1898 dnl 64-bit type; but we have to determine whether that type is called
1899 dnl "long int" or "long long int".
1900
1901 PGAC_TYPE_64BIT_INT([long int])
1902
1903 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1904   pg_int64_type="long int"
1905 else
1906   PGAC_TYPE_64BIT_INT([long long int])
1907   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1908     pg_int64_type="long long int"
1909   else
1910     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1911   fi
1912 fi
1913
1914 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1915   [Define to the name of a signed 64-bit integer type.])
1916
1917 # Select the printf length modifier that goes with that, too.
1918 if test x"$pg_int64_type" = x"long long int" ; then
1919   INT64_MODIFIER='"ll"'
1920 else
1921   INT64_MODIFIER='"l"'
1922 fi
1923
1924 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1925                    [Define to the appropriate printf length modifier for 64-bit ints.])
1926
1927 # has to be down here, rather than with the other builtins, because
1928 # the test uses PG_INT64_TYPE.
1929 PGAC_C_BUILTIN_OP_OVERFLOW
1930
1931 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1932 AC_CHECK_SIZEOF([void *])
1933 AC_CHECK_SIZEOF([size_t])
1934 AC_CHECK_SIZEOF([long])
1935
1936 # Decide whether float4 is passed by value: user-selectable, enabled by default
1937 AC_MSG_CHECKING([whether to build with float4 passed by value])
1938 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1939               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1940                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1941                float4passbyval=true],
1942               [float4passbyval=false])
1943 AC_MSG_RESULT([$enable_float4_byval])
1944 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1945
1946 # Decide whether float8 is passed by value.
1947 # Note: this setting also controls int8 and related types such as timestamp.
1948 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1949 # If not, trying to select it is an error.
1950 AC_MSG_CHECKING([whether to build with float8 passed by value])
1951 if test $ac_cv_sizeof_void_p -ge 8 ; then
1952   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1953 else
1954   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1955   if test "$enable_float8_byval" = yes ; then
1956     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1957   fi
1958 fi
1959 if test "$enable_float8_byval" = yes ; then
1960   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1961             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1962   float8passbyval=true
1963 else
1964   float8passbyval=false
1965 fi
1966 AC_MSG_RESULT([$enable_float8_byval])
1967 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1968
1969 # Determine memory alignment requirements for the basic C data types.
1970
1971 AC_CHECK_ALIGNOF(short)
1972 AC_CHECK_ALIGNOF(int)
1973 AC_CHECK_ALIGNOF(long)
1974 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1975   AC_CHECK_ALIGNOF(long long int)
1976 fi
1977 AC_CHECK_ALIGNOF(double)
1978
1979 # Compute maximum alignment of any basic type.
1980 # We assume long's alignment is at least as strong as char, short, or int;
1981 # but we must check long long (if it is being used for int64) and double.
1982 # Note that we intentionally do not consider any types wider than 64 bits,
1983 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1984 # for disk and memory space.
1985
1986 MAX_ALIGNOF=$ac_cv_alignof_long
1987 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1988   MAX_ALIGNOF=$ac_cv_alignof_double
1989 fi
1990 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1991   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1992 fi
1993 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1994
1995
1996 # Some platforms predefine the types int8, int16, etc.  Only check
1997 # a (hopefully) representative subset.
1998 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1999 [#include <stdio.h>])
2000
2001 # Some compilers offer a 128-bit integer scalar type.
2002 PGAC_TYPE_128BIT_INT
2003
2004 # Check for various atomic operations now that we have checked how to declare
2005 # 64bit integers.
2006 PGAC_HAVE_GCC__SYNC_CHAR_TAS
2007 PGAC_HAVE_GCC__SYNC_INT32_TAS
2008 PGAC_HAVE_GCC__SYNC_INT32_CAS
2009 PGAC_HAVE_GCC__SYNC_INT64_CAS
2010 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
2011 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
2012
2013
2014 # Check for x86 cpuid instruction
2015 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
2016 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
2017   [[unsigned int exx[4] = {0, 0, 0, 0};
2018   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
2019   ]])],
2020   [pgac_cv__get_cpuid="yes"],
2021   [pgac_cv__get_cpuid="no"])])
2022 if test x"$pgac_cv__get_cpuid" = x"yes"; then
2023   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
2024 fi
2025
2026 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
2027 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
2028   [[unsigned int exx[4] = {0, 0, 0, 0};
2029   __get_cpuid(exx[0], 1);
2030   ]])],
2031   [pgac_cv__cpuid="yes"],
2032   [pgac_cv__cpuid="no"])])
2033 if test x"$pgac_cv__cpuid" = x"yes"; then
2034   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
2035 fi
2036
2037 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
2038 #
2039 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
2040 # with the default compiler flags. If not, check if adding the -msse4.2
2041 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
2042 PGAC_SSE42_CRC32_INTRINSICS([])
2043 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
2044   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
2045 fi
2046 AC_SUBST(CFLAGS_SSE42)
2047
2048 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
2049 # define __SSE4_2__ in that case.
2050 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2051 #ifndef __SSE4_2__
2052 #error __SSE4_2__ not defined
2053 #endif
2054 ])], [SSE4_2_TARGETED=1])
2055
2056 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2057 #
2058 # First check if __crc32c* intrinsics can be used with the default compiler
2059 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2060 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2061 PGAC_ARMV8_CRC32C_INTRINSICS([])
2062 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2063   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2064 fi
2065 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2066
2067 # Select CRC-32C implementation.
2068 #
2069 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2070 # use the special CRC instructions for calculating CRC-32C. If we're not
2071 # targeting such a processor, but we can nevertheless produce code that uses
2072 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2073 # implementations and select which one to use at runtime, depending on whether
2074 # SSE 4.2 is supported by the processor we're running on.
2075 #
2076 # Similarly, if we are targeting an ARM processor that has the CRC
2077 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2078 # we're not targeting such a processor, but can nevertheless produce code that
2079 # uses the CRC instructions, compile both, and select at runtime.
2080 #
2081 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2082 # in the template or configure command line.
2083 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2084   # Use Intel SSE 4.2 if available.
2085   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2086     USE_SSE42_CRC32C=1
2087   else
2088     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2089     # the runtime check.
2090     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2091       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2092     else
2093       # Use ARM CRC Extension if available.
2094       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2095         USE_ARMV8_CRC32C=1
2096       else
2097         # ARM CRC Extension, with runtime check?
2098         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2099           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2100         else
2101           # fall back to slicing-by-8 algorithm, which doesn't require any
2102           # special CPU support.
2103           USE_SLICING_BY_8_CRC32C=1
2104         fi
2105       fi
2106     fi
2107   fi
2108 fi
2109
2110 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2111 AC_MSG_CHECKING([which CRC-32C implementation to use])
2112 if test x"$USE_SSE42_CRC32C" = x"1"; then
2113   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2114   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2115   AC_MSG_RESULT(SSE 4.2)
2116 else
2117   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2118     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2119     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2120     AC_MSG_RESULT(SSE 4.2 with runtime check)
2121   else
2122     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2123       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2124       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2125       AC_MSG_RESULT(ARMv8 CRC instructions)
2126     else
2127       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2128         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2129         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2130         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2131       else
2132         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2133         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2134         AC_MSG_RESULT(slicing-by-8)
2135       fi
2136     fi
2137   fi
2138 fi
2139 AC_SUBST(PG_CRC32C_OBJS)
2140
2141
2142 # Select semaphore implementation type.
2143 if test "$PORTNAME" != "win32"; then
2144   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2145     # Need sem_open for this
2146     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2147   fi
2148   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2149     # Need sem_init for this
2150     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2151   fi
2152   AC_MSG_CHECKING([which semaphore API to use])
2153   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2154     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2155     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2156     sematype="named POSIX"
2157   else
2158     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2159       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2160       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2161       sematype="unnamed POSIX"
2162     else
2163       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2164       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2165       sematype="System V"
2166     fi
2167   fi
2168   AC_MSG_RESULT([$sematype])
2169 else
2170   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2171   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2172 fi
2173
2174
2175 # Select shared-memory implementation type.
2176 if test "$PORTNAME" != "win32"; then
2177   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2178   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2179 else
2180   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2181   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2182 fi
2183
2184 # Select random number source
2185 #
2186 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2187 # in the template or configure command line.
2188
2189 # If not selected manually, try to select a source automatically.
2190 if test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2191   if test x"$with_openssl" = x"yes" ; then
2192     USE_OPENSSL_RANDOM=1
2193   elif test "$PORTNAME" = "win32" ; then
2194     USE_WIN32_RANDOM=1
2195   else
2196     AC_CHECK_FILE([/dev/urandom], [], [])
2197
2198     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2199       USE_DEV_URANDOM=1
2200     fi
2201   fi
2202 fi
2203
2204 AC_MSG_CHECKING([which random number source to use])
2205 if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2206   AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2207   AC_MSG_RESULT([OpenSSL])
2208 elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2209   AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2210   AC_MSG_RESULT([Windows native])
2211 elif test x"$USE_DEV_URANDOM" = x"1" ; then
2212   AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2213   AC_MSG_RESULT([/dev/urandom])
2214 else
2215   AC_MSG_ERROR([
2216 no source of strong random numbers was found
2217 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers.])
2218 fi
2219
2220 # If not set in template file, set bytes to use libc memset()
2221 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2222   MEMSET_LOOP_LIMIT=1024
2223 fi
2224 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2225
2226
2227 if test "$enable_nls" = yes ; then
2228   PGAC_CHECK_GETTEXT
2229 fi
2230
2231 # Check for Tcl configuration script tclConfig.sh
2232 if test "$with_tcl" = yes; then
2233     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2234     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2235                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2236     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2237     if test "$TCL_SHARED_BUILD" != 1; then
2238       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2239 Use --without-tcl to disable building PL/Tcl.])
2240     fi
2241     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2242     ac_save_CPPFLAGS=$CPPFLAGS
2243     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2244     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2245     CPPFLAGS=$ac_save_CPPFLAGS
2246 fi
2247
2248 # check for <perl.h>
2249 if test "$with_perl" = yes; then
2250   ac_save_CPPFLAGS=$CPPFLAGS
2251   CPPFLAGS="$CPPFLAGS $perl_includespec"
2252   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2253                   [#include <EXTERN.h>])
2254   # While we're at it, check that we can link to libperl.
2255   # On most platforms, if perl.h is there then libperl.so will be too, but at
2256   # this writing Debian packages them separately.  There is no known reason to
2257   # waste cycles on separate probes for the Tcl or Python libraries, though.
2258   pgac_save_LIBS=$LIBS
2259   LIBS="$perl_embed_ldflags"
2260   AC_MSG_CHECKING([for libperl])
2261   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2262 #include <EXTERN.h>
2263 #include <perl.h>
2264 ],  [perl_alloc();])],
2265     [AC_MSG_RESULT(yes)],
2266     [AC_MSG_RESULT(no)
2267      AC_MSG_ERROR([libperl library is required for Perl])])
2268   LIBS=$pgac_save_LIBS
2269   CPPFLAGS=$ac_save_CPPFLAGS
2270 fi
2271
2272 # check for <Python.h>
2273 if test "$with_python" = yes; then
2274   ac_save_CPPFLAGS=$CPPFLAGS
2275   CPPFLAGS="$python_includespec $CPPFLAGS"
2276   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2277   CPPFLAGS=$ac_save_CPPFLAGS
2278 fi
2279
2280 #
2281 # Check for DocBook and tools
2282 #
2283 PGAC_PATH_XMLLINT
2284 PGAC_CHECK_DOCBOOK(4.2)
2285 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2286 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2287 PGAC_PATH_PROGS(FOP, fop)
2288
2289 #
2290 # Check for test tools
2291 #
2292 if test "$enable_tap_tests" = yes; then
2293   # Check for necessary modules, unless user has specified the "prove" to use;
2294   # in that case it's her responsibility to have a working configuration.
2295   # (prove might be part of a different Perl installation than perl, eg on
2296   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2297   if test -z "$PROVE"; then
2298     # Test::More and Time::HiRes are supposed to be part of core Perl,
2299     # but some distros omit them in a minimal installation.
2300     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2301       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2302   fi
2303   # Now make sure we know where prove is
2304   PGAC_PATH_PROGS(PROVE, prove)
2305   if test -z "$PROVE"; then
2306     AC_MSG_ERROR([prove not found])
2307   fi
2308 fi
2309
2310 # Thread testing
2311
2312 # We have to run the thread test near the end so we have all our symbols
2313 # defined.  Cross compiling throws a warning.
2314 #
2315 if test "$enable_thread_safety" = yes; then
2316 if test "$PORTNAME" != "win32"
2317 then
2318 AC_MSG_CHECKING([thread safety of required library functions])
2319
2320 _CFLAGS="$CFLAGS"
2321 _LIBS="$LIBS"
2322 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2323 LIBS="$LIBS $PTHREAD_LIBS"
2324 AC_RUN_IFELSE(
2325   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2326   [AC_MSG_RESULT(yes)],
2327   [AC_MSG_RESULT(no)
2328   AC_MSG_ERROR([thread test program failed
2329 This platform is not thread-safe.  Check the file 'config.log' or compile
2330 and run src/test/thread/thread_test for the exact reason.
2331 Use --disable-thread-safety to disable thread safety.])],
2332   [AC_MSG_RESULT(maybe)
2333   AC_MSG_WARN([
2334 *** Skipping thread test program because of cross-compile build.
2335 *** Run the program in src/test/thread on the target machine.
2336 ])])
2337 CFLAGS="$_CFLAGS"
2338 LIBS="$_LIBS"
2339 else
2340 AC_MSG_WARN([*** skipping thread test on Win32])
2341 fi
2342 fi
2343
2344 # If compiler will take -Wl,--as-needed (or various platform-specific
2345 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2346 # trying to filter LIBS to the minimum for each executable.
2347 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2348 # libreadline; therefore we postpone testing it until we know what library
2349 # dependencies readline has.  The test code will try to link with $LIBS.
2350 if test "$with_readline" = yes; then
2351   link_test_func=readline
2352 else
2353   link_test_func=exit
2354 fi
2355
2356 if test "$PORTNAME" = "darwin"; then
2357   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2358 elif test "$PORTNAME" = "openbsd"; then
2359   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2360 else
2361   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2362 fi
2363
2364 # Create compiler version string
2365 if test x"$GCC" = x"yes" ; then
2366   cc_string=`${CC} --version | sed q`
2367   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2368 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2369   cc_string=`${CC} -V 2>&1 | sed q`
2370 else
2371   cc_string=$CC
2372 fi
2373
2374 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2375                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2376                    [A string containing the version number, platform, and C compiler])
2377
2378 # Supply a numeric version string for use by 3rd party add-ons
2379 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2380 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2381 tr '.' '        ' |
2382 $AWK '{printf "%d%04d", $1, $2}'`"]
2383 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2384 AC_SUBST(PG_VERSION_NUM)
2385
2386 # If we are inserting PG_SYSROOT into CPPFLAGS, do so symbolically not
2387 # literally, so that it's possible to override it at build time using
2388 # a command like "make ... PG_SYSROOT=path".  This has to be done after
2389 # we've finished all configure checks that depend on CPPFLAGS.
2390 if test x"$PG_SYSROOT" != x; then
2391   CPPFLAGS=`echo "$CPPFLAGS" | sed -e "s| $PG_SYSROOT | \\\$(PG_SYSROOT) |"`
2392 fi
2393 AC_SUBST(PG_SYSROOT)
2394
2395
2396 # Begin output steps
2397
2398 AC_MSG_NOTICE([using compiler=$cc_string])
2399 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2400 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2401 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2402 # Currently only used when LLVM is used
2403 if test "$with_llvm" = yes ; then
2404    AC_MSG_NOTICE([using CXX=$CXX])
2405    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2406    AC_MSG_NOTICE([using CLANG=$CLANG])
2407    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2408    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2409 fi
2410
2411 # prepare build tree if outside source tree
2412 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2413 # Note 2: /bin/pwd might be better than shell's built-in at getting
2414 #         a symlink-free name.
2415 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2416   vpath_build=no
2417 else
2418   vpath_build=yes
2419   if test "$no_create" != yes; then
2420     _AS_ECHO_N([preparing build tree... ])
2421     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2422     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2423       || AC_MSG_ERROR(failed)
2424     AC_MSG_RESULT(done)
2425   fi
2426 fi
2427 AC_SUBST(vpath_build)
2428
2429
2430 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2431
2432 AC_CONFIG_LINKS([
2433   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2434   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2435   src/include/pg_config_os.h:src/include/port/${template}.h
2436   src/Makefile.port:src/makefiles/Makefile.${template}
2437 ])
2438
2439 if test "$PORTNAME" = "win32"; then
2440 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2441 # Links sometimes fail undetected on Mingw -
2442 # so here we detect it and warn the user
2443 for FILE in $CONFIG_LINKS
2444  do
2445         # test -e works for symlinks in the MinGW console
2446         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2447  done
2448 ])
2449 fi
2450
2451 AC_CONFIG_HEADERS([src/include/pg_config.h],
2452 [
2453 # Update timestamp for pg_config.h (see Makefile.global)
2454 echo >src/include/stamp-h
2455 ])
2456
2457 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2458 [
2459 # Update timestamp for pg_config_ext.h (see Makefile.global)
2460 echo >src/include/stamp-ext-h
2461 ])
2462
2463 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2464                   [echo >src/interfaces/ecpg/include/stamp-h])
2465
2466 AC_OUTPUT