granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl get an EGREP to use in the Makefiles
  63 AC_PROG_EGREP
  64 APACHE_SUBST(EGREP)
  65
  66 dnl ## Run configure for packages Apache uses
  67
  68 dnl shared library support for these packages doesn't currently
  69 dnl work on some platforms
  70
  71 AC_CANONICAL_SYSTEM
  72
  73 orig_prefix="$prefix"
  74
  75 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  76
  77 AC_ARG_WITH(included-apr,
  78 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  79
  80 if test "x$with_included_apr" = "xyes"; then
  81    apr_found=reconfig
  82 else
  83    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  84 fi
  85
  86 if test "$apr_found" = "no"; then
  87   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  88 fi
  89
  90 if test "$apr_found" = "reconfig"; then
  91   APR_SUBDIR_CONFIG(srclib/apr,
  92                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  93                     [--enable-layout=*|\'--enable-layout=*])
  94   dnl We must be the first to build and the last to be cleaned
  95 dnl  AP_BUILD_SRCLIB_DIRS="apr libapreq $AP_BUILD_SRCLIB_DIRS"
  96 dnl  AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS libapreq apr"
  97   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  98   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  99
 100   dnl We have to find apr-N-config when we reconfigure APR.
 101   for majorver in 1 2; do
 102     test_apr_config="./srclib/apr/apr-${majorver}-config"
 103     if test -f "$test_apr_config"; then
 104       apr_config="$test_apr_config"
 105     fi
 106   done
 107 fi
 108
 109 APR_SETIFNULL(CC, `$apr_config --cc`)
 110 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 111 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 112 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 113 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 114 INTERNAL_CPPFLAGS=""
 115 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 116 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 117 APR_BINDIR=`$apr_config --bindir`
 118 APR_INCLUDEDIR=`$apr_config --includedir`
 119 APR_INCLUDES=`$apr_config --includes`
 120 APR_VERSION=`$apr_config --version`
 121 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 122 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 123
 124 dnl echo $ac_n "${nl}Configuring Apache Request Library...${nl}"
 125 dnl APR_SUBDIR_CONFIG(srclib/libapreq, [--with-apr=../apr/apr-2-config --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir])
 126 dnl APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/srclib/libapreq/include])
 127
 128 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 129
 130 if test "x${apr_major_version}" = "x2"; then
 131    apu_found=obsolete
 132 elif test "x$with_included_apr" = "xyes"; then
 133    apu_found=reconfig
 134 else
 135    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 136    dnl isn't supported.
 137    ifdef([APR_FIND_APU], [
 138      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 139                   1, ${apr_major_version})
 140    ], [apu_found=no])
 141 fi
 142
 143 if test "$apu_found" = "no"; then
 144   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 145 fi
 146
 147 # Catch some misconfigurations:
 148 case ${apr_found}.${apu_found} in
 149 reconfig.yes)
 150   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 151   ;;
 152 yes.reconfig)
 153   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 154   ;;
 155 esac
 156
 157 if test "$apu_found" = "reconfig"; then
 158   APR_SUBDIR_CONFIG(srclib/apr-util,
 159                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 160                     [--enable-layout=*|\'--enable-layout=*])
 161   dnl We must be the last to build and the first to be cleaned
 162   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 163   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 164   dnl APR and APR-Util major versions must match
 165   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 166 fi
 167
 168 if test "$apu_found" = "obsolete"; then
 169   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 170 else
 171   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 172   APU_BINDIR=`$apu_config --bindir`
 173   APU_INCLUDEDIR=`$apu_config --includedir`
 174   APU_INCLUDES=`$apu_config --includes`
 175   APU_VERSION=`$apu_config --version`
 176   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 177 fi
 178
 179 dnl In case we picked up CC and CPP from APR, get that info into the
 180 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 181 dnl PCRE and for our config tests will be whatever PCRE determines.
 182 AC_PROG_CC
 183 AC_PROG_CPP
 184
 185 dnl Try to get c99 support for variadic macros
 186 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 187
 188 if test "x${cache_file}" = "x/dev/null"; then
 189   # Likewise, ensure that CC and CPP are passed through to the pcre
 190   # configure script iff caching is disabled (the autoconf 2.5x default).
 191   export CC; export CPP
 192 fi
 193
 194 dnl Absolute source/build directory
 195 abs_srcdir=`(cd $srcdir && pwd)`
 196 abs_builddir=`pwd`
 197
 198 AC_ARG_WITH(pcre,
 199 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 200
 201 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 202 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 203    PCRE_CONFIG=$with_pcre/bin/pcre-config
 204 elif test -x "$with_pcre"; then
 205    PCRE_CONFIG=$with_pcre
 206 fi
 207
 208 if test "$PCRE_CONFIG" != "false"; then
 209   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 210     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 211   fi
 212   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 213   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 214   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 215 else
 216   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 217 fi
 218 APACHE_SUBST(PCRE_LIBS)
 219
 220 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 221
 222 dnl If the source dir is not equal to the build dir,
 223 dnl then we are running in VPATH mode.
 224
 225 APR_ADDTO(INCLUDES, [-I.])
 226
 227 if test "$abs_builddir" != "$abs_srcdir"; then
 228   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 229 fi
 230
 231 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 232
 233 # apr/apr-util --includes may pick up system paths for dependent
 234 # libraries, so ensure these are later in INCLUDES than local source
 235 # directories.
 236 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 237 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 238
 239 dnl Add in path to PCRE includes
 240 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 241
 242 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 243
 244 case $host in
 245   *os2*)
 246       # Use a custom made libtool replacement
 247       echo "using aplibtool"
 248       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 249       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 250       SH_LIBS="\$(ALL_LIBS)"
 251       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 252       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 253       MK_IMPLIB="emximp"
 254       other_targets="$other_targets os2core"
 255       INSTALL_PROG_FLAGS="-e .exe"
 256       SHLTCFLAGS=""
 257       LTCFLAGS=""
 258       ;;
 259   *)
 260       if test "x$LTFLAGS" = "x"; then
 261           LTFLAGS='--silent'
 262       fi
 263       my_libtool=`$apr_config --apr-libtool`
 264       LIBTOOL="$my_libtool \$(LTFLAGS)"
 265       libtoolversion=`$my_libtool --version`
 266       case $libtoolversion in
 267           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 268               SH_LIBTOOL='$(LIBTOOL)'
 269               SHLTCFLAGS="-prefer-pic"
 270               LTCFLAGS="-prefer-non-pic -static"
 271               ;;
 272           *)
 273               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 274               SHLTCFLAGS=""
 275               LTCFLAGS=""
 276               ;;
 277       esac
 278       ;;
 279 esac
 280 APACHE_SUBST(SHLTCFLAGS)
 281 APACHE_SUBST(LTCFLAGS)
 282
 283 case $host in
 284   *-apple-aux3*)
 285       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 286       ;;
 287   *os2-emx*)
 288       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 289       ;;
 290   *-linux-*)
 291       case `uname -r` in
 292         2.[[2-9]]* )
 293             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 294             ;;
 295         * )
 296             ;;
 297       esac
 298       ;;
 299   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 300       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 301       ;;
 302   *-solaris2*)
 303       dnl This is a hack -- we should be using AC_TRY_RUN instead
 304       ap_platform_runtime_link_flag="-R"
 305       dnl solaris 8 and above don't have a thundering herd
 306       dnl not sure about rev's before this one.
 307       case `uname -r` in
 308         5.[567]*)
 309             ;;
 310         * )
 311             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 312             ;;
 313       esac
 314       ;;
 315   *cygwin*)
 316       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 317       ;;
 318   *mingw32*)
 319       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 320       APR_SETIFNULL(ac_cv_func_times, [no])
 321       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 322       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 323       ;;
 324   *aix*)
 325       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 326       if test $aixver -ge 4320; then
 327         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 328       fi
 329       ;;
 330   *os390*)
 331       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 332       ;;
 333 esac
 334
 335 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 336
 337 dnl
 338 dnl Process command line arguments. This is done early in the process so the
 339 dnl user can get feedback quickly in case of an error.
 340 dnl
 341 dnl ### need to move some of the arguments "up here"
 342
 343 dnl ## Check for programs
 344
 345 AC_PATH_PROG(RM, rm)
 346 AC_PATH_PROG(PKGCONFIG, pkg-config)
 347 AC_PATH_PROG(RSYNC, rsync)
 348 AC_PROG_AWK
 349 AC_PROG_LN_S
 350 AC_CHECK_TOOL(RANLIB, ranlib, true)
 351 dnl AC_PATH_PROG(PERL_PATH, perl)
 352 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 353
 354 # Hard-coded install programs
 355 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 356 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 357 APACHE_SUBST(MKINSTALLDIRS)
 358 APACHE_SUBST(INSTALL)
 359
 360 dnl Various OS checks that apparently set required flags
 361 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 362 AC_USE_SYSTEM_EXTENSIONS
 363 ], [
 364 AC_AIX
 365 AC_MINIX
 366 ])
 367
 368 AC_ISC_POSIX
 369
 370 # Ensure that satisfactory versions of apr and apr-util are
 371 # found if external copies are configured.
 372 if test "${apr_found}" = "yes"; then
 373   # Require at least APR 1.3.x otherwise fail
 374   APACHE_CHECK_APxVER([apr], 1, 3)
 375 fi
 376
 377 if test "${apu_found}" = "yes"; then
 378   # Require at least APR-util 1.3.x otherwise fail
 379   if test "${apr_found}" = "yes"; then
 380     # we need to add the APR includes to CPPFLAGS
 381     apu_ckver_CPPFLAGS="$CPPFLAGS"
 382     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 383     APACHE_CHECK_APxVER([apu], 1, 3)
 384     CPPFLAGS="$apu_ckver_CPPFLAGS"
 385   else
 386     APACHE_CHECK_APxVER([apu], 1, 3)
 387   fi
 388 fi
 389
 390 dnl Check for what we can generate dependency files with
 391 APR_CHECK_DEPEND
 392
 393 dnl ## Check for libraries
 394
 395 dnl ## Check for header files
 396
 397 dnl I think these are just used all over the place, so just check for
 398 dnl them at the base of the tree. If some are specific to a single
 399 dnl directory, they should be moved (Comment #Spoon)
 400
 401 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 402 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 403 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 404
 405 AC_HEADER_STDC
 406 AC_CHECK_HEADERS( \
 407 string.h \
 408 limits.h \
 409 unistd.h \
 410 sys/socket.h \
 411 pwd.h \
 412 grp.h \
 413 strings.h \
 414 sys/prctl.h \
 415 sys/processor.h \
 416 sys/sem.h \
 417 sys/sdt.h
 418 )
 419 AC_HEADER_SYS_WAIT
 420
 421 dnl ## Check for typedefs, structures, and compiler characteristics.
 422
 423 AC_C_CONST
 424
 425 dnl ## Check for library functions
 426 dnl ## sqrt() only needed in support/ab.c
 427 saved_LIBS="$LIBS"
 428 LIBS=""
 429 AC_SEARCH_LIBS(sqrt, m)
 430 MATH_LIBS="$LIBS"
 431 APACHE_SUBST(MATH_LIBS)
 432 LIBS="$saved_LIBS"
 433
 434 saved_LIBS="$LIBS"
 435 LIBS=""
 436 AC_SEARCH_LIBS(crypt, crypt)
 437 CRYPT_LIBS="$LIBS"
 438 APACHE_SUBST(CRYPT_LIBS)
 439 LIBS="$saved_LIBS"
 440
 441 dnl See Comment #Spoon
 442
 443 AC_CHECK_FUNCS( \
 444 getpwnam \
 445 getgrnam \
 446 initgroups \
 447 bindprocessor \
 448 prctl \
 449 timegm \
 450 getpgid \
 451 fopen64
 452 )
 453
 454 dnl confirm that a void pointer is large enough to store a long integer
 455 APACHE_CHECK_VOID_PTR_LEN
 456
 457 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 458 [AC_TRY_RUN(#define _GNU_SOURCE
 459 #include <unistd.h>
 460 #include <sys/syscall.h>
 461 #include <sys/types.h>
 462 int main(int argc, char **argv) {
 463 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 464 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 465 if test "$ac_cv_gettid" = "yes"; then
 466     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 467 fi
 468
 469 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 470 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 471 [AC_TRY_COMPILE([#include <sys/types.h>
 472 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 473   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 474 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 475     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 476 fi
 477
 478 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 479
 480 case $host in
 481     *aix*)
 482         # for 32-bit builds, increase MAXDATA to allow lots of threads
 483         if test x$OBJECT_MODE != x64; then
 484             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 485         fi
 486         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 487         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 488         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 489         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 490         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 491         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 492         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 493         ;;
 494     *os390*)
 495         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 496         ;;
 497     *)
 498         OS_SPECIFIC_VARS=""
 499 esac
 500
 501 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 502         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 503         [PORT=80])
 504
 505 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 506         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 507         [SSLPORT=443])
 508
 509 DTRACE=true
 510 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 511 [
 512   enable_dtrace=$enableval
 513   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 514   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 515 ],
 516 [
 517   enable_dtrace=no
 518 ])
 519
 520 dnl Disabled dtrace build for now.
 521 enable_dtrace=no
 522
 523 case $host in
 524   *-solaris2*)
 525     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 526         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 527                   [Enable DTrace probes])
 528         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 529         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 530     fi
 531     ;;
 532 esac
 533
 534 APACHE_SUBST(DTRACE)
 535
 536 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 537 [
 538     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 539         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 540     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 541 ])dnl
 542
 543 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 544 [
 545     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 546               [Allow modules to run hook after a fatal exception])
 547 ])dnl
 548
 549 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 550 [
 551   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 552   if test "$GCC" = "yes"; then
 553     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 554     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 555     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 556     APACHE_ADD_GCC_CFLAG([-Wformat])
 557     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 558     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 559   elif test "$AIX_XLC" = "yes"; then
 560     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 561   fi
 562 ])dnl
 563
 564 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 565 [
 566   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 567   if test "$GCC" = "yes"; then
 568     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 569     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 570     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 571     APACHE_ADD_GCC_CFLAG([-Wformat])
 572     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 573     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 574   elif test "$AIX_XLC" = "yes"; then
 575     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 576   fi
 577 ])dnl
 578
 579 dnl Conditionally enable PIE support for GNU toolchains.
 580 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 581 if test "$enable_pie" = "yes"; then
 582    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 583      save_CFLAGS=$CFLAGS
 584      save_LDFLAGS=$LDFLAGS
 585      CFLAGS="$CFLAGS -fPIE"
 586      LDFLAGS="$LDFLAGS -pie"
 587      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 588       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 589      CFLAGS=$save_CFLAGS
 590      LDFLAGS=$save_LDFLAGS
 591    ])
 592    if test "$ap_cv_cc_pie" = "yes"; then
 593      PICFLAGS="-fPIE"
 594      PILDFLAGS="-pie"
 595    else
 596      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 597    fi
 598 fi
 599 AC_SUBST(PICFLAGS)
 600 AC_SUBST(PILDFLAGS)
 601
 602 prefix="$orig_prefix"
 603 APACHE_ENABLE_MODULES
 604
 605 dnl reading config stubs
 606 esyscmd(./build/config-stubs .)
 607
 608 APACHE_SUBST(progname)
 609 APACHE_SUBST(OS)
 610 APACHE_SUBST(OS_DIR)
 611 APACHE_SUBST(BUILTIN_LIBS)
 612 APACHE_SUBST(SHLIBPATH_VAR)
 613 APACHE_SUBST(OS_SPECIFIC_VARS)
 614
 615 PRE_SHARED_CMDS='echo ""'
 616 POST_SHARED_CMDS='echo ""'
 617
 618 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 619
 620 if test "$apache_need_shared" = "yes"; then
 621   if test -f $ac_aux_dir/ltconfig; then
 622     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 623   fi
 624   shared_build="shared-build"
 625 fi
 626
 627 dnl enable_so tells us if *any* modules can be built as DSOs
 628
 629 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 630   case $host in
 631     *-ibm-aix*)
 632       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 633       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 634       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 635       ;;
 636     *os390)
 637       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 638       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 639   esac
 640   MOD_SO_ENABLED=yes
 641 fi
 642 AC_SUBST(MOD_SO_ENABLED)
 643
 644 APACHE_SUBST(PRE_SHARED_CMDS)
 645 APACHE_SUBST(POST_SHARED_CMDS)
 646 APACHE_SUBST(shared_build)
 647
 648 AC_ARG_WITH(program-name,
 649 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 650   progname="$withval" ], [
 651   progname="httpd"] )
 652
 653 # SuExec parameters
 654 AC_ARG_WITH(suexec-bin,
 655 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 656   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 657 ] )
 658
 659 AC_ARG_WITH(suexec-caller,
 660 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 661   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 662
 663 AC_ARG_WITH(suexec-userdir,
 664 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 665   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 666
 667 AC_ARG_WITH(suexec-docroot,
 668 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 669   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 670
 671 AC_ARG_WITH(suexec-uidmin,
 672 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 673   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 674
 675 AC_ARG_WITH(suexec-gidmin,
 676 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 677   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 678
 679 AC_ARG_WITH(suexec-logfile,
 680 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 681   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 682
 683 AC_ARG_WITH(suexec-safepath,
 684 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 685   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 686
 687 AC_ARG_WITH(suexec-umask,
 688 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 689   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 690
 691 dnl APR should go after the other libs, so the right symbols can be picked up
 692 if test x${apu_found} != xobsolete; then
 693   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 694 fi
 695 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 696 APACHE_SUBST(AP_LIBS)
 697 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 698 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 699
 700 AC_DEFINE(AP_USING_AUTOCONF, 1,
 701                 [Using autoconf to configure Apache])
 702
 703 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 704     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 705               [This platform doesn't suffer from the thundering herd problem])
 706 fi
 707
 708 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 709     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 710               [Listening sockets are non-blocking when there are more than 1])
 711 fi
 712
 713 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 714
 715 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 716 [
 717   v4mapped=$enableval
 718 ],
 719 [
 720     case $host in
 721     *freebsd5*|*netbsd*|*openbsd*)
 722         v4mapped=no
 723         ;;
 724     *)
 725         v4mapped=yes
 726         ;;
 727     esac
 728     if ap_mpm_is_enabled winnt; then
 729         dnl WinNT MPM doesn't support this.
 730         v4mapped=no
 731     fi
 732 ])
 733
 734 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 735     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 736               [Allow IPv4 connections on IPv6 listening sockets])
 737 fi
 738
 739 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 740 [
 741   LOAD_ALL_MODULES=$enableval
 742 ],
 743 [
 744   LOAD_ALL_MODULES="no"
 745 ])
 746
 747 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 748 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 749 APACHE_FAST_OUTPUT(support/Makefile)
 750
 751 if test -d ./test; then
 752     APACHE_FAST_OUTPUT(test/Makefile)
 753 fi
 754
 755 dnl ## Finalize the variables
 756 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 757
 758 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 759 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 760 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 761 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 762 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 763 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 764
 765 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 766
 767 APACHE_GEN_CONFIG_VARS
 768
 769 dnl ## Build modules.c
 770 rm -f modules.c
 771 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 772
 773 APR_EXPAND_VAR(ap_prefix, $prefix)
 774 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 775         [Root directory of the Apache install area])
 776 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 777         [Location of the config file, relative to the Apache root directory])
 778 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 779         [Location of the MIME types config file, relative to the Apache root directory])
 780
 781 perlbin=`$ac_aux_dir/PrintPath perl`
 782 if test "x$perlbin" = "x"; then
 783     perlbin="/replace/with/path/to/perl/interpreter"
 784 fi
 785 AC_SUBST(perlbin)
 786
 787 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 788
 789 BSD_MAKEFILE=no
 790 ap_make_include=include
 791 ap_make_delimiter=' '
 792 case $host in
 793 *bsdi*)
 794     # Check whether they've installed GNU make
 795     if make --version > /dev/null 2>&1; then
 796         true
 797     else
 798         BSD_MAKEFILE=yes
 799         ap_make_include=.include
 800         ap_make_delimiter='"'
 801     fi
 802     ;;
 803 esac
 804 AC_SUBST(ap_make_include)
 805 AC_SUBST(ap_make_delimiter)
 806
 807 dnl Ensure that docs/conf is created.
 808 test -d docs/conf||$mkdir_p docs/conf
 809
 810 dnl Ensure that the httpd version is included
 811 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 812 AC_SUBST(HTTPD_VERSION)
 813
 814 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 815   APACHE_GEN_MAKEFILES
 816 ])