granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2013, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58   cygwin*) template=cygwin ;;
  59   darwin*) template=darwin ;;
  60 dragonfly*) template=netbsd ;;
  61  freebsd*) template=freebsd ;;
  62     hpux*) template=hpux ;;
  63     irix*) template=irix ;;
  64  linux*|gnu*|k*bsd*-gnu)
  65            template=linux ;;
  66    mingw*) template=win32 ;;
  67   netbsd*) template=netbsd ;;
  68  openbsd*) template=openbsd ;;
  69      osf*) template=osf ;;
  70      sco*) template=sco ;;
  71  solaris*) template=solaris ;;
  72    sysv5*) template=unixware ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage: enabled by default.
 126 #
 127 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 128 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 129               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 130                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 131 AC_MSG_RESULT([$enable_integer_datetimes])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 #
 167 # '-rpath'-like feature can be disabled
 168 #
 169 PGAC_ARG_BOOL(enable, rpath, yes,
 170               [do not embed shared library search path in executables])
 171 AC_SUBST(enable_rpath)
 172
 173 #
 174 # Spinlocks
 175 #
 176 PGAC_ARG_BOOL(enable, spinlocks, yes,
 177               [do not use spinlocks])
 178
 179 #
 180 # --enable-debug adds -g to compiler flags
 181 #
 182 PGAC_ARG_BOOL(enable, debug, no,
 183               [build with debugging symbols (-g)])
 184 AC_SUBST(enable_debug)
 185
 186 #
 187 # --enable-profiling enables gcc profiling
 188 #
 189 PGAC_ARG_BOOL(enable, profiling, no,
 190               [build with profiling enabled ])
 191
 192 #
 193 # --enable-coverage enables generation of code coverage metrics with gcov
 194 #
 195 PGAC_ARG_BOOL(enable, coverage, no,
 196               [build with coverage testing instrumentation],
 197 [AC_CHECK_PROGS(GCOV, gcov)
 198 if test -z "$GCOV"; then
 199   AC_MSG_ERROR([gcov not found])
 200 fi
 201 AC_CHECK_PROGS(LCOV, lcov)
 202 if test -z "$LCOV"; then
 203   AC_MSG_ERROR([lcov not found])
 204 fi
 205 AC_CHECK_PROGS(GENHTML, genhtml)
 206 if test -z "$GENHTML"; then
 207   AC_MSG_ERROR([genhtml not found])
 208 fi])
 209 AC_SUBST(enable_coverage)
 210
 211 #
 212 # DTrace
 213 #
 214 PGAC_ARG_BOOL(enable, dtrace, no,
 215               [build with DTrace support],
 216 [AC_CHECK_PROGS(DTRACE, dtrace)
 217 if test -z "$DTRACE"; then
 218   AC_MSG_ERROR([dtrace not found])
 219 fi
 220 AC_SUBST(DTRACEFLAGS)])
 221 AC_SUBST(enable_dtrace)
 222
 223 #
 224 # Block size
 225 #
 226 AC_MSG_CHECKING([for block size])
 227 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 228              [blocksize=$withval],
 229              [blocksize=8])
 230 case ${blocksize} in
 231   1) BLCKSZ=1024;;
 232   2) BLCKSZ=2048;;
 233   4) BLCKSZ=4096;;
 234   8) BLCKSZ=8192;;
 235  16) BLCKSZ=16384;;
 236  32) BLCKSZ=32768;;
 237   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 238 esac
 239 AC_MSG_RESULT([${blocksize}kB])
 240
 241 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 242  Size of a disk block --- this also limits the size of a tuple.  You
 243  can set it bigger if you need bigger tuples (although TOAST should
 244  reduce the need to have large tuples, since fields can be spread
 245  across multiple tuples).
 246
 247  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 248  is currently 2^15 (32768).  This is determined by the 15-bit widths
 249  of the lp_off and lp_len fields in ItemIdData (see
 250  include/storage/itemid.h).
 251
 252  Changing BLCKSZ requires an initdb.
 253 ])
 254
 255 #
 256 # Relation segment size
 257 #
 258 AC_MSG_CHECKING([for segment size])
 259 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 260              [segsize=$withval],
 261              [segsize=1])
 262 # this expression is set up to avoid unnecessary integer overflow
 263 # blocksize is already guaranteed to be a factor of 1024
 264 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 265 test $? -eq 0 || exit 1
 266 AC_MSG_RESULT([${segsize}GB])
 267
 268 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 269  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 270  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 271  relations bigger than that are divided into multiple files.
 272
 273  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 274  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 275  have large file support enabled.  By default, we make the limit 1 GB
 276  to avoid any possible integer-overflow problems within the OS.
 277  A limit smaller than necessary only means we divide a large
 278  relation into more chunks than necessary, so it seems best to err
 279  in the direction of a small limit.
 280
 281  A power-of-2 value is recommended to save a few cycles in md.c,
 282  but is not absolutely required.
 283
 284  Changing RELSEG_SIZE requires an initdb.
 285 ])
 286
 287 #
 288 # WAL block size
 289 #
 290 AC_MSG_CHECKING([for WAL block size])
 291 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 292              [wal_blocksize=$withval],
 293              [wal_blocksize=8])
 294 case ${wal_blocksize} in
 295   1) XLOG_BLCKSZ=1024;;
 296   2) XLOG_BLCKSZ=2048;;
 297   4) XLOG_BLCKSZ=4096;;
 298   8) XLOG_BLCKSZ=8192;;
 299  16) XLOG_BLCKSZ=16384;;
 300  32) XLOG_BLCKSZ=32768;;
 301  64) XLOG_BLCKSZ=65536;;
 302   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 303 esac
 304 AC_MSG_RESULT([${wal_blocksize}kB])
 305
 306 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 307  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 308  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 309  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 310  buffers, else direct I/O may fail.
 311
 312  Changing XLOG_BLCKSZ requires an initdb.
 313 ])
 314
 315 #
 316 # WAL segment size
 317 #
 318 AC_MSG_CHECKING([for WAL segment size])
 319 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 320              [wal_segsize=$withval],
 321              [wal_segsize=16])
 322 case ${wal_segsize} in
 323   1) ;;
 324   2) ;;
 325   4) ;;
 326   8) ;;
 327  16) ;;
 328  32) ;;
 329  64) ;;
 330   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 331 esac
 332 AC_MSG_RESULT([${wal_segsize}MB])
 333
 334 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 335  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 336  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 337  XLOG_BLCKSZ).
 338
 339  Changing XLOG_SEG_SIZE requires an initdb.
 340 ])
 341
 342 #
 343 # C compiler
 344 #
 345
 346 # For historical reasons you can also use --with-CC to specify the C compiler
 347 # to use, although the standard way to do this is to set the CC environment
 348 # variable.
 349 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 350
 351 case $template in
 352   aix) pgac_cc_list="gcc xlc";;
 353  irix) pgac_cc_list="cc";; # no gcc
 354     *) pgac_cc_list="gcc cc";;
 355 esac
 356
 357 AC_PROG_CC([$pgac_cc_list])
 358
 359 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 360 # but has idiosyncrasies of its own.  We assume icc will define
 361 # __INTEL_COMPILER regardless of CFLAGS.
 362 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 363 choke me
 364 @%:@endif], [ICC=[yes]], [ICC=[no]])
 365
 366 # Check if it's Sun Studio compiler. We assume that
 367 # __SUNPRO_C will be defined for Sun Studio compilers
 368 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 369 choke me
 370 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 371
 372 AC_SUBST(SUN_STUDIO_CC)
 373
 374 unset CFLAGS
 375
 376 #
 377 # Read the template
 378 #
 379 . "$srcdir/src/template/$template" || exit
 380
 381 # CFLAGS are selected so:
 382 # If the user specifies something in the environment, that is used.
 383 # else:  If the template file set something, that is used.
 384 # else:  If coverage was enabled, don't set anything.
 385 # else:  If the compiler is GCC, then we use -O2.
 386 # else:  If the compiler is something else, then we use -O, unless debugging.
 387
 388 if test "$ac_env_CFLAGS_set" = set; then
 389   CFLAGS=$ac_env_CFLAGS_value
 390 elif test "${CFLAGS+set}" = set; then
 391   : # (keep what template set)
 392 elif test "$enable_coverage" = yes; then
 393   : # no optimization by default
 394 elif test "$GCC" = yes; then
 395   CFLAGS="-O2"
 396 else
 397   # if the user selected debug mode, don't use -O
 398   if test "$enable_debug" != yes; then
 399     CFLAGS="-O"
 400   fi
 401 fi
 402
 403 # set CFLAGS_VECTOR from the environment, if available
 404 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 405   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 406 fi
 407
 408 # Some versions of GCC support some additional useful warning flags.
 409 # Check whether they are supported, and add them to CFLAGS if so.
 410 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 411 # but has its own.  Also check other compiler-specific flags here.
 412
 413 if test "$GCC" = yes -a "$ICC" = no; then
 414   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 415   # These work in some but not all gcc versions
 416   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 417   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 418   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 419   # This was included in -Wall/-Wformat in older GCC versions
 420   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 421   # Disable strict-aliasing rules; needed for gcc 3.3+
 422   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 423   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 424   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 425   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 426   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 427   # Optimization flags for specific files that benefit from vectorization
 428   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 429   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 430 elif test "$ICC" = yes; then
 431   # Intel's compiler has a bug/misoptimization in checking for
 432   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 433   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 434   # Make sure strict aliasing is off (though this is said to be the default)
 435   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 436 elif test "$PORTNAME" = "aix"; then
 437   # AIX's xlc has to have strict aliasing turned off too
 438   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 439 elif test "$PORTNAME" = "hpux"; then
 440   # On some versions of HP-UX, libm functions do not set errno by default.
 441   # Fix that by using +Olibmerrno if the compiler recognizes it.
 442   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 443 fi
 444
 445 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 446
 447 # supply -g if --enable-debug
 448 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 449   CFLAGS="$CFLAGS -g"
 450 fi
 451
 452 # enable code coverage if --enable-coverage
 453 if test "$enable_coverage" = yes; then
 454   if test "$GCC" = yes; then
 455     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 456   else
 457     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 458   fi
 459 fi
 460
 461 # enable profiling if --enable-profiling
 462 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 463   if test "$GCC" = yes; then
 464     AC_DEFINE([PROFILE_PID_DIR], 1,
 465            [Define to 1 to allow profiling output to be saved separately for each process.])
 466     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 467   else
 468     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 469   fi
 470 fi
 471
 472 # We already have this in Makefile.win32, but configure needs it too
 473 if test "$PORTNAME" = "win32"; then
 474   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 475 fi
 476
 477 # Check if the compiler still works with the template settings
 478 AC_MSG_CHECKING([whether the C compiler still works])
 479 AC_TRY_LINK([], [return 0;],
 480   [AC_MSG_RESULT(yes)],
 481   [AC_MSG_RESULT(no)
 482    AC_MSG_ERROR([cannot proceed])])
 483
 484 # Defend against gcc -ffast-math
 485 if test "$GCC" = yes; then
 486 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 487 choke me
 488 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 489 fi
 490
 491 AC_PROG_CPP
 492 AC_SUBST(GCC)
 493
 494
 495 #
 496 # Set up TAS assembly code if needed; the template file has now had its
 497 # chance to request this.
 498 #
 499 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 500
 501 if test "$need_tas" = yes ; then
 502   TAS=tas.o
 503 else
 504   TAS=""
 505 fi
 506 AC_SUBST(TAS)
 507
 508
 509 #
 510 # Automatic dependency tracking
 511 #
 512 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 513               [autodepend=yes])
 514 AC_SUBST(autodepend)
 515
 516
 517 #
 518 # Enable assert checks
 519 #
 520 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 521               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 522                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 523
 524
 525 #
 526 # Include directories
 527 #
 528 ac_save_IFS=$IFS
 529 IFS="${IFS}${PATH_SEPARATOR}"
 530 # SRCH_INC comes from the template file
 531 for dir in $with_includes $SRCH_INC; do
 532   if test -d "$dir"; then
 533     INCLUDES="$INCLUDES -I$dir"
 534   else
 535     AC_MSG_WARN([*** Include directory $dir does not exist.])
 536   fi
 537 done
 538 IFS=$ac_save_IFS
 539 AC_SUBST(INCLUDES)
 540
 541
 542 #
 543 # Library directories
 544 #
 545 ac_save_IFS=$IFS
 546 IFS="${IFS}${PATH_SEPARATOR}"
 547 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 548 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 549   if test -d "$dir"; then
 550     LIBDIRS="$LIBDIRS -L$dir"
 551   else
 552     AC_MSG_WARN([*** Library directory $dir does not exist.])
 553   fi
 554 done
 555 IFS=$ac_save_IFS
 556
 557 #
 558 # Enable thread-safe client libraries
 559 #
 560 AC_MSG_CHECKING([allow thread-safe client libraries])
 561 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 562 if test "$enable_thread_safety" = yes; then
 563   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 564           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 565 fi
 566 AC_MSG_RESULT([$enable_thread_safety])
 567 AC_SUBST(enable_thread_safety)
 568
 569 #
 570 # Optionally build Tcl modules (PL/Tcl)
 571 #
 572 AC_MSG_CHECKING([whether to build with Tcl])
 573 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 574 AC_MSG_RESULT([$with_tcl])
 575 AC_SUBST([with_tcl])
 576
 577 # We see if the path to the Tcl/Tk configuration scripts is specified.
 578 # This will override the use of tclsh to find the paths to search.
 579
 580 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 581
 582 #
 583 # Optionally build Perl modules (PL/Perl)
 584 #
 585 AC_MSG_CHECKING([whether to build Perl modules])
 586 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 587 AC_MSG_RESULT([$with_perl])
 588 AC_SUBST(with_perl)
 589
 590 #
 591 # Optionally build Python modules (PL/Python)
 592 #
 593 AC_MSG_CHECKING([whether to build Python modules])
 594 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 595 AC_MSG_RESULT([$with_python])
 596 AC_SUBST(with_python)
 597
 598 #
 599 # GSSAPI
 600 #
 601 AC_MSG_CHECKING([whether to build with GSSAPI support])
 602 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 603 [
 604   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 605   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 606 ])
 607 AC_MSG_RESULT([$with_gssapi])
 608
 609 #
 610 # Kerberos 5
 611 #
 612 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 613 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 614 [
 615   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 616   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 617 ])
 618 AC_MSG_RESULT([$with_krb5])
 619
 620
 621 AC_SUBST(krb_srvtab)
 622
 623
 624 #
 625 # Kerberos configuration parameters
 626 #
 627 PGAC_ARG_REQ(with, krb-srvnam,
 628              [NAME], [default service principal name in Kerberos [postgres]],
 629              [],
 630              [with_krb_srvnam="postgres"])
 631 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 632                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 633
 634
 635 #
 636 # PAM
 637 #
 638 AC_MSG_CHECKING([whether to build with PAM support])
 639 PGAC_ARG_BOOL(with, pam, no,
 640               [build with PAM support],
 641               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 642 AC_MSG_RESULT([$with_pam])
 643
 644
 645 #
 646 # LDAP
 647 #
 648 AC_MSG_CHECKING([whether to build with LDAP support])
 649 PGAC_ARG_BOOL(with, ldap, no,
 650               [build with LDAP support],
 651               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 652 AC_MSG_RESULT([$with_ldap])
 653
 654
 655 #
 656 # Bonjour
 657 #
 658 AC_MSG_CHECKING([whether to build with Bonjour support])
 659 PGAC_ARG_BOOL(with, bonjour, no,
 660               [build with Bonjour support],
 661               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 662 AC_MSG_RESULT([$with_bonjour])
 663
 664
 665 #
 666 # OpenSSL
 667 #
 668 AC_MSG_CHECKING([whether to build with OpenSSL support])
 669 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 670               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 671 AC_MSG_RESULT([$with_openssl])
 672 AC_SUBST(with_openssl)
 673
 674 #
 675 # SELinux
 676 #
 677 AC_MSG_CHECKING([whether to build with SELinux support])
 678 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 679 AC_SUBST(with_selinux)
 680 AC_MSG_RESULT([$with_selinux])
 681
 682 #
 683 # Readline
 684 #
 685 PGAC_ARG_BOOL(with, readline, yes,
 686               [do not use GNU Readline nor BSD Libedit for editing])
 687 # readline on MinGW has problems with backslashes in psql and other bugs.
 688 # This is particularly a problem with non-US code pages.
 689 # Therefore disable its use until we understand the cause. 2004-07-20
 690 if test "$PORTNAME" = "win32"; then
 691   if test "$with_readline" = yes; then
 692     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 693     with_readline=no
 694   fi
 695 fi
 696
 697
 698 #
 699 # Prefer libedit
 700 #
 701 PGAC_ARG_BOOL(with, libedit-preferred, no,
 702               [prefer BSD Libedit over GNU Readline])
 703
 704
 705 #
 706 # OSSP UUID library
 707 #
 708 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 709 AC_SUBST(with_ossp_uuid)
 710
 711
 712 #
 713 # XML
 714 #
 715 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 716               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 717
 718 if test "$with_libxml" = yes ; then
 719   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 720   if test -n "$XML2_CONFIG"; then
 721     for pgac_option in `$XML2_CONFIG --cflags`; do
 722       case $pgac_option in
 723         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 724       esac
 725     done
 726     for pgac_option in `$XML2_CONFIG --libs`; do
 727       case $pgac_option in
 728         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 729       esac
 730     done
 731   fi
 732 fi
 733
 734 AC_SUBST(with_libxml)
 735
 736 #
 737 # XSLT
 738 #
 739 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 740               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 741
 742
 743 AC_SUBST(with_libxslt)
 744
 745 #
 746 # tzdata
 747 #
 748 PGAC_ARG_REQ(with, system-tzdata,
 749              [DIR], [use system time zone data in DIR])
 750 AC_SUBST(with_system_tzdata)
 751
 752 #
 753 # Zlib
 754 #
 755 PGAC_ARG_BOOL(with, zlib, yes,
 756               [do not use Zlib])
 757 AC_SUBST(with_zlib)
 758
 759 #
 760 # Elf
 761 #
 762
 763 # Assume system is ELF if it predefines __ELF__ as 1,
 764 # otherwise believe host_os based default.
 765 case $host_os in
 766     freebsd1*|freebsd2*) elf=no;;
 767     freebsd3*|freebsd4*) elf=yes;;
 768 esac
 769
 770 AC_EGREP_CPP(yes,
 771 [#if __ELF__
 772   yes
 773 #endif
 774 ],
 775 [ELF_SYS=true],
 776 [if test "X$elf" = "Xyes" ; then
 777   ELF_SYS=true
 778 else
 779   ELF_SYS=
 780 fi])
 781 AC_SUBST(ELF_SYS)
 782
 783 #
 784 # Assignments
 785 #
 786
 787 CPPFLAGS="$CPPFLAGS $INCLUDES"
 788 LDFLAGS="$LDFLAGS $LIBDIRS"
 789
 790 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 791 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 792
 793 PGAC_PROG_LD
 794 AC_SUBST(LD)
 795 AC_SUBST(with_gnu_ld)
 796 case $host_os in sysv5*)
 797   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 798   [
 799     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 800     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 801     LDFLAGS=$pgac_save_LDFLAGS
 802   ])
 803   ld_R_works=$pgac_cv_prog_ld_R
 804   AC_SUBST(ld_R_works)
 805 esac
 806 AC_PROG_RANLIB
 807 PGAC_CHECK_STRIP
 808 AC_CHECK_TOOL(AR, ar, ar)
 809 if test "$PORTNAME" = "win32"; then
 810   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 811   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 812   AC_CHECK_TOOL(WINDRES, windres, windres)
 813 fi
 814
 815 AC_PROG_INSTALL
 816 # When Autoconf chooses install-sh as install program it tries to generate
 817 # a relative path to it in each makefile where it subsitutes it. This clashes
 818 # with our Makefile.global concept. This workaround helps.
 819 case $INSTALL in
 820   *install-sh*) install_bin='';;
 821   *) install_bin=$INSTALL;;
 822 esac
 823 AC_SUBST(install_bin)
 824
 825 AC_PATH_PROG(TAR, tar)
 826 AC_PROG_LN_S
 827 AC_PROG_AWK
 828 AC_PROG_MKDIR_P
 829 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 830 # a relative path to it in each makefile where it subsitutes it. This clashes
 831 # with our Makefile.global concept. This workaround helps.
 832 case $MKDIR_P in
 833   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 834 esac
 835
 836 PGAC_PATH_BISON
 837 PGAC_PATH_FLEX
 838
 839 PGAC_PATH_PERL
 840 if test "$with_perl" = yes; then
 841   if test -z "$PERL"; then
 842     AC_MSG_ERROR([Perl not found])
 843   fi
 844   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 845   PGAC_CHECK_PERL_EMBED_LDFLAGS
 846 fi
 847
 848 if test "$with_python" = yes; then
 849   PGAC_PATH_PYTHON
 850   PGAC_CHECK_PYTHON_EMBED_SETUP
 851 fi
 852
 853 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 854   AC_PATH_PROG(ZIC, zic)
 855   if test -z "$ZIC"; then
 856     AC_MSG_ERROR([
 857 When cross-compiling, either use the option --with-system-tzdata to use
 858 existing time-zone data, or set the environment variable ZIC to a zic
 859 program to use during the build.])
 860   fi
 861 fi
 862
 863
 864 ##
 865 ## Libraries
 866 ##
 867 ## Most libraries are included only if they demonstrably provide a function
 868 ## we need, but libm is an exception: always include it, because there are
 869 ## too many compilers that play cute optimization games that will break
 870 ## probes for standard functions such as pow().
 871 ##
 872
 873 AC_CHECK_LIB(m, main)
 874 AC_SEARCH_LIBS(setproctitle, util)
 875 AC_SEARCH_LIBS(dlopen, dl)
 876 AC_SEARCH_LIBS(socket, [socket wsock32])
 877 AC_SEARCH_LIBS(shl_load, dld)
 878 # We only use libld in port/dynloader/aix.c
 879 case $host_os in
 880      aix*)
 881         AC_SEARCH_LIBS(ldopen, ld)
 882         ;;
 883 esac
 884 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 885 AC_SEARCH_LIBS(crypt, crypt)
 886 AC_SEARCH_LIBS(shm_open, rt)
 887 AC_SEARCH_LIBS(shm_unlink, rt)
 888 # Solaris:
 889 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 890 # Required for thread_test.c on Solaris 2.5:
 891 # Other ports use it too (HP-UX) so test unconditionally
 892 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 893 # Cygwin:
 894 AC_SEARCH_LIBS(shmget, cygipc)
 895
 896 if test "$with_readline" = yes; then
 897   PGAC_CHECK_READLINE
 898   if test x"$pgac_cv_check_readline" = x"no"; then
 899     AC_MSG_ERROR([readline library not found
 900 If you have readline already installed, see config.log for details on the
 901 failure.  It is possible the compiler isn't looking in the proper directory.
 902 Use --without-readline to disable readline support.])
 903   fi
 904 fi
 905
 906 if test "$with_zlib" = yes; then
 907   AC_CHECK_LIB(z, inflate, [],
 908                [AC_MSG_ERROR([zlib library not found
 909 If you have zlib already installed, see config.log for details on the
 910 failure.  It is possible the compiler isn't looking in the proper directory.
 911 Use --without-zlib to disable zlib support.])])
 912 fi
 913
 914 if test "$enable_spinlocks" = yes; then
 915   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 916 else
 917   AC_MSG_WARN([
 918 *** Not using spinlocks will cause poor performance.])
 919 fi
 920
 921 if test "$with_gssapi" = yes ; then
 922   if test "$PORTNAME" != "win32"; then
 923     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 924                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 925   else
 926     LIBS="$LIBS -lgssapi32"
 927   fi
 928 fi
 929
 930 if test "$with_krb5" = yes ; then
 931   if test "$PORTNAME" != "win32"; then
 932      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 933                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 934      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 935                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 936   else
 937      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 938                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 939   fi
 940 fi
 941
 942 if test "$with_openssl" = yes ; then
 943   dnl Order matters!
 944   if test "$PORTNAME" != "win32"; then
 945      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 946      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 947   else
 948      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 949      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 950   fi
 951 fi
 952
 953 if test "$with_pam" = yes ; then
 954   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 955 fi
 956
 957 if test "$with_libxml" = yes ; then
 958   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 959 fi
 960
 961 if test "$with_libxslt" = yes ; then
 962   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 963 fi
 964
 965 # for contrib/sepgsql
 966 if test "$with_selinux" = yes; then
 967   AC_CHECK_LIB(selinux, security_compute_create_name, [],
 968                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
 969 fi
 970
 971 # for contrib/uuid-ossp
 972 if test "$with_ossp_uuid" = yes ; then
 973   AC_CHECK_LIB(ossp-uuid, uuid_export,
 974     [OSSP_UUID_LIBS="-lossp-uuid"],
 975     [AC_CHECK_LIB(uuid, uuid_export,
 976       [OSSP_UUID_LIBS="-luuid"],
 977       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 978 fi
 979 AC_SUBST(OSSP_UUID_LIBS)
 980
 981
 982 ##
 983 ## Header files
 984 ##
 985
 986 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 987 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
 988
 989 # On BSD, test for net/if.h will fail unless sys/socket.h
 990 # is included first.
 991 AC_CHECK_HEADERS(net/if.h, [], [],
 992 [AC_INCLUDES_DEFAULT
 993 #ifdef HAVE_SYS_SOCKET_H
 994 #include <sys/socket.h>
 995 #endif
 996 ])
 997
 998 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
 999 # is included first.
1000 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1001 [AC_INCLUDES_DEFAULT
1002 #include <sys/param.h>
1003 ])
1004
1005 # At least on IRIX, test for netinet/tcp.h will fail unless
1006 # netinet/in.h is included first.
1007 AC_CHECK_HEADERS(netinet/in.h)
1008 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1009 [AC_INCLUDES_DEFAULT
1010 #ifdef HAVE_NETINET_IN_H
1011 #include <netinet/in.h>
1012 #endif
1013 ])
1014
1015 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1016   AC_CHECK_HEADERS(readline/readline.h, [],
1017         [AC_CHECK_HEADERS(readline.h, [],
1018                 [AC_MSG_ERROR([readline header not found
1019 If you have readline already installed, see config.log for details on the
1020 failure.  It is possible the compiler isn't looking in the proper directory.
1021 Use --without-readline to disable readline support.])])])
1022   AC_CHECK_HEADERS(readline/history.h, [],
1023         [AC_CHECK_HEADERS(history.h, [],
1024                 [AC_MSG_ERROR([history header not found
1025 If you have readline already installed, see config.log for details on the
1026 failure.  It is possible the compiler isn't looking in the proper directory.
1027 Use --without-readline to disable readline support.])])])
1028 fi
1029
1030 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1031 # Some installations of libedit usurp /usr/include/readline/, which seems
1032 # bad practice, since in combined installations readline will have its headers
1033 # there.  We might have to resort to AC_EGREP checks to make sure we found
1034 # the proper header...
1035   AC_CHECK_HEADERS(editline/readline.h, [],
1036         [AC_CHECK_HEADERS(readline.h, [],
1037                 [AC_CHECK_HEADERS(readline/readline.h, [],
1038                         [AC_MSG_ERROR([readline header not found
1039 If you have libedit already installed, see config.log for details on the
1040 failure.  It is possible the compiler isn't looking in the proper directory.
1041 Use --without-readline to disable libedit support.])])])])
1042 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1043 # not be there at all.  Hence, don't complain if not found.  We must check
1044 # though, since in yet other versions it is an independent header.
1045   AC_CHECK_HEADERS(editline/history.h, [],
1046         [AC_CHECK_HEADERS(history.h, [],
1047                 [AC_CHECK_HEADERS(readline/history.h)])])
1048 fi
1049
1050 if test "$with_zlib" = yes; then
1051   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1052 If you have zlib already installed, see config.log for details on the
1053 failure.  It is possible the compiler isn't looking in the proper directory.
1054 Use --without-zlib to disable zlib support.])])
1055 fi
1056
1057 if test "$with_gssapi" = yes ; then
1058   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1059         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1060 fi
1061
1062 if test "$with_krb5" = yes ; then
1063   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1064 fi
1065
1066 if test "$with_openssl" = yes ; then
1067   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1068   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1069 fi
1070
1071 if test "$with_pam" = yes ; then
1072   AC_CHECK_HEADERS(security/pam_appl.h, [],
1073                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1074                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1075 fi
1076
1077 if test "$with_libxml" = yes ; then
1078   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1079 fi
1080
1081 if test "$with_libxslt" = yes ; then
1082   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1083 fi
1084
1085 if test "$with_ldap" = yes ; then
1086   if test "$PORTNAME" != "win32"; then
1087      AC_CHECK_HEADERS(ldap.h, [],
1088                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1089   else
1090      AC_CHECK_HEADERS(winldap.h, [],
1091                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1092                       [AC_INCLUDES_DEFAULT
1093 #include <windows.h>
1094                       ])
1095   fi
1096 fi
1097
1098 if test "$with_bonjour" = yes ; then
1099   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1100 fi
1101
1102 # for contrib/uuid-ossp
1103 if test "$with_ossp_uuid" = yes ; then
1104   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1105     AC_CHECK_HEADERS(uuid.h, [],
1106       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1107 fi
1108
1109 if test "$PORTNAME" = "win32" ; then
1110    AC_CHECK_HEADERS(crtdefs.h)
1111 fi
1112
1113 ##
1114 ## Types, structures, compiler characteristics
1115 ##
1116
1117 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1118 AC_C_BIGENDIAN
1119 AC_C_CONST
1120 PGAC_C_INLINE
1121 AC_C_STRINGIZE
1122 AC_C_FLEXIBLE_ARRAY_MEMBER
1123 PGAC_C_SIGNED
1124 AC_C_VOLATILE
1125 PGAC_C_FUNCNAME_SUPPORT
1126 PGAC_C_STATIC_ASSERT
1127 PGAC_C_TYPES_COMPATIBLE
1128 PGAC_C_BUILTIN_CONSTANT_P
1129 PGAC_C_BUILTIN_UNREACHABLE
1130 PGAC_C_VA_ARGS
1131 PGAC_STRUCT_TIMEZONE
1132 PGAC_UNION_SEMUN
1133 PGAC_STRUCT_SOCKADDR_UN
1134 PGAC_STRUCT_SOCKADDR_STORAGE
1135 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1136 PGAC_STRUCT_ADDRINFO
1137 AC_TYPE_INTPTR_T
1138 AC_TYPE_UINTPTR_T
1139 AC_TYPE_LONG_LONG_INT
1140
1141 PGAC_TYPE_LOCALE_T
1142
1143 AC_CHECK_TYPES([struct cmsgcred], [], [],
1144 [#include <sys/socket.h>
1145 #include <sys/param.h>
1146 #ifdef HAVE_SYS_UCRED_H
1147 #include <sys/ucred.h>
1148 #endif])
1149
1150 AC_CHECK_TYPES([struct option], [], [],
1151 [#ifdef HAVE_GETOPT_H
1152 #include <getopt.h>
1153 #endif])
1154
1155 if test "$with_zlib" = yes; then
1156   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1157   # did not).  While we could work around the lack of z_streamp, it
1158   # seems unwise to encourage people to use such old zlib versions...
1159   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1160 Use --without-zlib to disable zlib support.])],
1161                 [#include <zlib.h>])
1162 fi
1163
1164 if test "$with_krb5" = yes; then
1165 # Check for differences between MIT and Heimdal (KTH) releases
1166   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1167                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1168                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1169                                      [#include <krb5.h>])],
1170                    [#include <krb5.h>])
1171   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1172                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1173                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1174                                      [#include <krb5.h>])],
1175                    [#include <krb5.h>])
1176
1177 # Win32 requires headers to be loaded for __stdcall, so can't use
1178 # AC_CHECK_FUNCS here.
1179   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1180   AC_TRY_LINK([#include <krb5.h>],
1181               [krb5_free_unparsed_name(NULL,NULL);],
1182               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name.])
1183 AC_MSG_RESULT(yes)],
1184               [AC_MSG_RESULT(no)])
1185 fi
1186
1187 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1188 case $host_cpu in
1189   ppc*|powerpc*)
1190     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1191     AC_TRY_COMPILE([],
1192         [int a = 0; int *p = &a; int r;
1193          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1194         [pgac_cv_have_ppc_mutex_hint=yes],
1195         [pgac_cv_have_ppc_mutex_hint=no])
1196     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1197     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1198         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1199     fi
1200   ;;
1201 esac
1202
1203 # Check largefile support.  You might think this is a system service not a
1204 # compiler characteristic, but you'd be wrong.  We must check this before
1205 # probing existence of related functions such as fseeko, since the largefile
1206 # defines can affect what is generated for that.
1207 if test "$PORTNAME" != "win32"; then
1208    AC_SYS_LARGEFILE
1209 fi
1210
1211 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1212 AC_CHECK_SIZEOF([off_t])
1213
1214 # If we don't have largefile support, can't handle segsize >= 2GB.
1215 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1216    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1217 fi
1218
1219
1220 ##
1221 ## Functions, global variables
1222 ##
1223
1224 PGAC_VAR_INT_TIMEZONE
1225 AC_FUNC_ACCEPT_ARGTYPES
1226 PGAC_FUNC_GETTIMEOFDAY_1ARG
1227
1228 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1229 # symbols that that library has no business exposing to the world.  Pending
1230 # acquisition of a clue by those developers, ignore libedit (including its
1231 # possible alias of libreadline) while checking for everything else.
1232 LIBS_including_readline="$LIBS"
1233 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1234
1235 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1236
1237 AC_REPLACE_FUNCS(fseeko)
1238 case $host_os in
1239         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1240         # Mingw uses macros to access Win32 API calls
1241         netbsd*|mingw*)
1242                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1243                 ac_cv_func_fseeko=yes;;
1244         *)
1245                 AC_FUNC_FSEEKO;;
1246 esac
1247
1248 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1249 # by calling it, 2009-04-02
1250 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1251 if test "$PORTNAME" != "solaris"; then
1252 AC_CHECK_FUNCS(posix_fadvise)
1253 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1254 fi
1255
1256 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1257 AC_CHECK_DECLS([strlcat, strlcpy])
1258 # This is probably only present on Darwin, but may as well check always
1259 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1260
1261 HAVE_IPV6=no
1262 AC_CHECK_TYPE([struct sockaddr_in6],
1263         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1264          HAVE_IPV6=yes],
1265         [],
1266 [$ac_includes_default
1267 #include <netinet/in.h>])
1268 AC_SUBST(HAVE_IPV6)
1269
1270 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1271 [AC_TRY_LINK(
1272 [#include <machine/vmparam.h>
1273 #include <sys/exec.h>
1274 ],
1275 [PS_STRINGS->ps_nargvstr = 1;
1276 PS_STRINGS->ps_argvstr = "foo";],
1277 [pgac_cv_var_PS_STRINGS=yes],
1278 [pgac_cv_var_PS_STRINGS=no])])
1279 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1280   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1281 fi
1282
1283
1284 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1285 # is missing.  Yes, there are machines that have only one.  We may
1286 # also decide to use snprintf.c if snprintf() is present but does not
1287 # have all the features we need --- see below.
1288
1289 if test "$PORTNAME" = "win32"; then
1290   # Win32 gets snprintf.c built unconditionally.
1291   #
1292   # To properly translate all NLS languages strings, we must support the
1293   # *printf() %$ format, which allows *printf() arguments to be selected
1294   # by position in the translated string.
1295   #
1296   # libintl versions < 0.13 use the native *printf() functions, and Win32
1297   # *printf() doesn't understand %$, so we must use our /port versions,
1298   # which do understand %$. libintl versions >= 0.13 include their own
1299   # *printf versions on Win32.  The libintl 0.13 release note text is:
1300   #
1301   #   C format strings with positions, as they arise when a translator
1302   #   needs to reorder a sentence, are now supported on all platforms.
1303   #   On those few platforms (NetBSD and Woe32) for which the native
1304   #   printf()/fprintf()/... functions don't support such format
1305   #   strings, replacements are provided through <libintl.h>.
1306   #
1307   # We could use libintl >= 0.13's *printf() if we were sure that we had
1308   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1309   # to guarantee that, it is best to just use our own, so we are sure to
1310   # get %$ support. In include/port.h we disable the *printf() macros
1311   # that might have been defined by libintl.
1312   #
1313   # We do this unconditionally whether NLS is used or not so we are sure
1314   # that all Win32 libraries and binaries behave the same.
1315   pgac_need_repl_snprintf=yes
1316 else
1317   pgac_need_repl_snprintf=no
1318   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1319   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1320 fi
1321
1322
1323 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1324 # include/c.h will provide declarations.  Note this is a separate test
1325 # from whether the functions exist in the C library --- there are
1326 # systems that have the functions but don't bother to declare them :-(
1327
1328 AC_CHECK_DECLS([snprintf, vsnprintf])
1329
1330
1331 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1332 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1333 [AC_TRY_LINK([
1334 #include <math.h>
1335 double glob_double;
1336 ],
1337 [return isinf(glob_double) ? 0 : 1;],
1338 [ac_cv_func_isinf=yes],
1339 [ac_cv_func_isinf=no])])
1340
1341 if test $ac_cv_func_isinf = yes ; then
1342   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1343 else
1344   AC_LIBOBJ(isinf)
1345   # Look for a way to implement a substitute for isinf()
1346   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1347 fi
1348
1349 AC_REPLACE_FUNCS([asprintf crypt fls getopt getrusage inet_aton random rint srandom strerror strlcat strlcpy])
1350
1351 case $host_os in
1352
1353         # Windows uses a specialised env handler
1354         # and doesn't need a replacement getpeereid because it doesn't use
1355         # Unix sockets.
1356         mingw*)
1357                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1358                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1359                 ac_cv_func_unsetenv=yes
1360                 ac_cv_func_getpeereid=yes;;
1361         *)
1362                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1363                 ;;
1364 esac
1365
1366 # System's version of getaddrinfo(), if any, may be used only if we found
1367 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1368 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1369 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1370 # because we want to use our own getaddrinfo.c on Windows anyway.)
1371 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1372   AC_REPLACE_FUNCS([getaddrinfo])
1373 else
1374   AC_LIBOBJ(getaddrinfo)
1375 fi
1376
1377 # Similarly, use system's getopt_long() only if system provides struct option.
1378 if test x"$ac_cv_type_struct_option" = xyes ; then
1379   AC_REPLACE_FUNCS([getopt_long])
1380 else
1381   AC_LIBOBJ(getopt_long)
1382 fi
1383
1384 # Solaris' getopt() doesn't do what we want for long options, so always use
1385 # our version on that platform.
1386 if test "$PORTNAME" = "solaris"; then
1387   AC_LIBOBJ(getopt)
1388 fi
1389
1390 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1391 # so always use our version on Windows.
1392 if test "$PORTNAME" = "win32"; then
1393   AC_LIBOBJ(getopt)
1394   AC_LIBOBJ(getopt_long)
1395 fi
1396
1397 # Win32 support
1398 if test "$PORTNAME" = "win32"; then
1399   AC_REPLACE_FUNCS(gettimeofday)
1400   AC_LIBOBJ(kill)
1401   AC_LIBOBJ(open)
1402   AC_LIBOBJ(win32env)
1403   AC_LIBOBJ(win32error)
1404   AC_LIBOBJ(win32setlocale)
1405   AC_DEFINE([HAVE_SYMLINK], 1,
1406             [Define to 1 if you have the `symlink' function.])
1407   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1408 #define WIN32_LEAN_AND_MEAN
1409 #include <windows.h>
1410 #include <string.h>
1411 #include <dbghelp.h>])
1412 fi
1413 if test x"$pgac_minidump_type" = x"yes" ; then
1414   AC_SUBST(have_win32_dbghelp,yes)
1415 else
1416   AC_SUBST(have_win32_dbghelp,no)
1417 fi
1418
1419 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1420 dnl (especially on GNU libc)
1421 dnl See also comments in c.h.
1422 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1423 [AC_TRY_LINK([#include <setjmp.h>],
1424             [sigjmp_buf x; sigsetjmp(x, 1);],
1425             [pgac_cv_func_sigsetjmp=yes],
1426             [pgac_cv_func_sigsetjmp=no])])
1427 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1428   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1429 fi
1430
1431 AC_DECL_SYS_SIGLIST
1432
1433 AC_CHECK_FUNC(syslog,
1434               [AC_CHECK_HEADER(syslog.h,
1435                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1436
1437 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1438 [AC_TRY_LINK([#include <unistd.h>],
1439   [extern int opterr; opterr = 1;],
1440   [pgac_cv_var_int_opterr=yes],
1441   [pgac_cv_var_int_opterr=no])])
1442 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1443   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1444 fi
1445
1446 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1447 [AC_TRY_LINK([#include <unistd.h>],
1448   [extern int optreset; optreset = 1;],
1449   [pgac_cv_var_int_optreset=yes],
1450   [pgac_cv_var_int_optreset=no])])
1451 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1452   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1453 fi
1454
1455 AC_CHECK_FUNCS([strtoll strtoq], [break])
1456 AC_CHECK_FUNCS([strtoull strtouq], [break])
1457
1458 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1459 [AC_TRY_LINK([],
1460   [int lock = 0;
1461    __sync_lock_test_and_set(&lock, 1);
1462    __sync_lock_release(&lock);],
1463   [pgac_cv_gcc_int_atomics="yes"],
1464   [pgac_cv_gcc_int_atomics="no"])])
1465 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1466   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1467 fi
1468
1469 # Lastly, restore full LIBS list and check for readline/libedit symbols
1470 LIBS="$LIBS_including_readline"
1471
1472 if test "$with_readline" = yes; then
1473   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1474   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1475   AC_CHECK_FUNCS([append_history history_truncate_file])
1476 fi
1477
1478
1479 #
1480 # Pthreads
1481 #
1482 # For each platform, we need to know about any special compile and link
1483 # libraries, and whether the normal C function names are thread-safe.
1484 # See the comment at the top of src/port/thread.c for more information.
1485 # WIN32 doesn't need the pthread tests;  it always uses threads
1486 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1487 ACX_PTHREAD     # set thread flags
1488
1489 # Some platforms use these, so just define them.  They can't hurt if they
1490 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1491 # enables 5-arg getpwuid_r, among other things.
1492 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1493
1494
1495 # At this point, we don't want to muck with the compiler name for threading.
1496 # Let's see who fails, perhaps AIX.  2004-04-23
1497 if test "$PTHREAD_CC" != "$CC"; then
1498 AC_MSG_ERROR([
1499 PostgreSQL does not support platforms that require a special compiler
1500 for thread safety;  use --disable-thread-safety to disable thread safety.])
1501 fi
1502
1503 # Check for *_r functions
1504 _CFLAGS="$CFLAGS"
1505 _LIBS="$LIBS"
1506 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1507 LIBS="$LIBS $PTHREAD_LIBS"
1508
1509 if test "$PORTNAME" != "win32"; then
1510 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1511 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1512 fi
1513
1514 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1515
1516 # Do test here with the proper thread flags
1517 PGAC_FUNC_GETPWUID_R_5ARG
1518 PGAC_FUNC_STRERROR_R_INT
1519
1520 CFLAGS="$_CFLAGS"
1521 LIBS="$_LIBS"
1522
1523 else
1524 # do not use values from template file
1525 PTHREAD_CFLAGS=
1526 PTHREAD_LIBS=
1527 fi
1528
1529 AC_SUBST(PTHREAD_CFLAGS)
1530 AC_SUBST(PTHREAD_LIBS)
1531
1532
1533 # We can test for libldap_r only after we know PTHREAD_LIBS
1534 if test "$with_ldap" = yes ; then
1535   _LIBS="$LIBS"
1536   if test "$PORTNAME" != "win32"; then
1537     AC_CHECK_LIB(ldap, ldap_bind, [],
1538                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1539                  [$EXTRA_LDAP_LIBS])
1540     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1541     if test "$enable_thread_safety" = yes; then
1542       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1543       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1544                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1545                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1546       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1547     else
1548       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1549     fi
1550   else
1551     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1552     LDAP_LIBS_FE="-lwldap32"
1553     LDAP_LIBS_BE="-lwldap32"
1554   fi
1555   LIBS="$_LIBS"
1556 fi
1557 AC_SUBST(LDAP_LIBS_FE)
1558 AC_SUBST(LDAP_LIBS_BE)
1559
1560
1561 # This test makes sure that run tests work at all.  Sometimes a shared
1562 # library is found by the linker, but the runtime linker can't find it.
1563 # This check should come after all modifications of compiler or linker
1564 # variables, and before any other run tests.
1565 AC_MSG_CHECKING([test program])
1566 AC_TRY_RUN([int main() { return 0; }],
1567 [AC_MSG_RESULT(ok)],
1568 [AC_MSG_RESULT(failed)
1569 AC_MSG_ERROR([[
1570 Could not execute a simple test program.  This may be a problem
1571 related to locating shared libraries.  Check the file 'config.log'
1572 for the exact reason.]])],
1573 [AC_MSG_RESULT([cross-compiling])])
1574
1575 # --------------------
1576 # Run tests below here
1577 # --------------------
1578
1579 # Force use of our snprintf if system's doesn't do arg control
1580 # See comment above at snprintf test for details.
1581 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1582   PGAC_FUNC_PRINTF_ARG_CONTROL
1583   if test $pgac_cv_printf_arg_control != yes ; then
1584     pgac_need_repl_snprintf=yes
1585   fi
1586 fi
1587
1588
1589 dnl Check to see if we have a working 64-bit integer type.
1590 dnl This breaks down into two steps:
1591 dnl (1) figure out if the compiler has a 64-bit int type with working
1592 dnl arithmetic, and if so
1593 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1594 dnl snprintf is the only library routine we really need for int8 support.)
1595 dnl It's entirely possible to have a compiler that handles a 64-bit type
1596 dnl when the C library doesn't; this is fairly likely when using gcc on
1597 dnl an older platform, for example.
1598 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1599 dnl we force our own version of snprintf() to be used instead.
1600 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1601
1602 dnl As of Postgres 8.4, we no longer support compilers without a working
1603 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1604
1605 PGAC_TYPE_64BIT_INT([long int])
1606
1607 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1608   pg_int64_type="long int"
1609 else
1610   PGAC_TYPE_64BIT_INT([long long int])
1611   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1612     pg_int64_type="long long int"
1613   else
1614     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1615   fi
1616 fi
1617
1618 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1619   [Define to the name of a signed 64-bit integer type.])
1620
1621 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1622
1623 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1624   AC_TRY_COMPILE([
1625 #define INT64CONST(x)  x##LL
1626 long long int foo = INT64CONST(0x1234567890123456);
1627 ],
1628         [],
1629         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1630         [])
1631 fi
1632
1633
1634 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1635 # we found we need to use "long long int", better check.  We cope with
1636 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1637 # work, fall back to our own snprintf emulation (which we know uses %lld).
1638
1639 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1640   if test $pgac_need_repl_snprintf = no; then
1641     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1642     if test "$LONG_LONG_INT_FORMAT" = ""; then
1643       # Force usage of our own snprintf, since system snprintf is broken
1644       pgac_need_repl_snprintf=yes
1645       LONG_LONG_INT_FORMAT='%lld'
1646     fi
1647   else
1648     # Here if we previously decided we needed to use our own snprintf
1649     LONG_LONG_INT_FORMAT='%lld'
1650   fi
1651   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1652   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1653   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1654 else
1655   # Here if we are not using 'long long int' at all
1656   INT64_FORMAT='"%ld"'
1657   UINT64_FORMAT='"%lu"'
1658 fi
1659
1660 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1661                    [Define to the appropriate snprintf format for 64-bit ints.])
1662
1663 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1664                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1665
1666 # Now we have checked all the reasons to replace snprintf
1667 if test $pgac_need_repl_snprintf = yes; then
1668   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1669   AC_LIBOBJ(snprintf)
1670 fi
1671
1672 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1673 AC_CHECK_SIZEOF([void *])
1674 AC_CHECK_SIZEOF([size_t])
1675 AC_CHECK_SIZEOF([long])
1676
1677 # Decide whether float4 is passed by value: user-selectable, enabled by default
1678 AC_MSG_CHECKING([whether to build with float4 passed by value])
1679 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1680               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1681                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1682                float4passbyval=true],
1683               [float4passbyval=false])
1684 AC_MSG_RESULT([$enable_float4_byval])
1685 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1686
1687 # Decide whether float8 is passed by value.
1688 # Note: this setting also controls int8 and related types such as timestamp.
1689 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1690 # If not, trying to select it is an error.
1691 AC_MSG_CHECKING([whether to build with float8 passed by value])
1692 if test $ac_cv_sizeof_void_p -ge 8 ; then
1693   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1694 else
1695   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1696   if test "$enable_float8_byval" = yes ; then
1697     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1698   fi
1699 fi
1700 if test "$enable_float8_byval" = yes ; then
1701   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1702             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1703   float8passbyval=true
1704 else
1705   float8passbyval=false
1706 fi
1707 AC_MSG_RESULT([$enable_float8_byval])
1708 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1709
1710 # Determine memory alignment requirements for the basic C data types.
1711
1712 AC_CHECK_ALIGNOF(short)
1713 AC_CHECK_ALIGNOF(int)
1714 AC_CHECK_ALIGNOF(long)
1715 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1716   AC_CHECK_ALIGNOF(long long int)
1717 fi
1718 AC_CHECK_ALIGNOF(double)
1719
1720 # Compute maximum alignment of any basic type.
1721 # We assume long's alignment is at least as strong as char, short, or int;
1722 # but we must check long long (if it exists) and double.
1723
1724 MAX_ALIGNOF=$ac_cv_alignof_long
1725 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1726   MAX_ALIGNOF=$ac_cv_alignof_double
1727 fi
1728 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1729   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1730 fi
1731 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1732
1733
1734 # Some platforms predefine the types int8, int16, etc.  Only check
1735 # a (hopefully) representative subset.
1736 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1737 [#include <stdio.h>])
1738
1739 # We also check for sig_atomic_t, which *should* be defined per ANSI
1740 # C, but is missing on some old platforms.
1741 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1742
1743
1744 if test "$PORTNAME" != "win32"
1745 then
1746 PGAC_FUNC_POSIX_SIGNALS
1747 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1748   AC_MSG_ERROR([
1749 Thread-safety requires POSIX signals, which are not supported by this
1750 operating system;  use --disable-thread-safety to disable thread safety.])
1751 fi
1752 fi
1753
1754 # SunOS doesn't handle negative byte comparisons properly with +/- return
1755 AC_FUNC_MEMCMP
1756
1757
1758 # Select semaphore implementation type.
1759 if test "$PORTNAME" != "win32"; then
1760   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1761     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1762     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1763   else
1764     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1765       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1766       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1767     else
1768       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1769       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1770     fi
1771   fi
1772 else
1773   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1774   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1775 fi
1776
1777
1778 # Select shared-memory implementation type.
1779 if test "$PORTNAME" != "win32"; then
1780   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1781   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1782 else
1783   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1784   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1785 fi
1786
1787 # Select latch implementation type.
1788 if test "$PORTNAME" != "win32"; then
1789   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1790 else
1791   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1792 fi
1793
1794 # If not set in template file, set bytes to use libc memset()
1795 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1796   MEMSET_LOOP_LIMIT=1024
1797 fi
1798 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1799
1800
1801 if test "$enable_nls" = yes ; then
1802   PGAC_CHECK_GETTEXT
1803 fi
1804
1805 # Check for Tcl configuration script tclConfig.sh
1806 if test "$with_tcl" = yes; then
1807     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1808     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1809                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1810     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1811     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1812     ac_save_CPPFLAGS=$CPPFLAGS
1813     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1814     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1815     CPPFLAGS=$ac_save_CPPFLAGS
1816 fi
1817
1818 # check for <perl.h>
1819 if test "$with_perl" = yes; then
1820   ac_save_CPPFLAGS=$CPPFLAGS
1821   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1822   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1823                   [#include <EXTERN.h>])
1824   # While we're at it, check that we can link to libperl.
1825   # On most platforms, if perl.h is there then libperl.so will be too, but at
1826   # this writing Debian packages them separately.  There is no known reason to
1827   # waste cycles on separate probes for the Tcl or Python libraries, though.
1828   pgac_save_LIBS=$LIBS
1829   LIBS="$perl_embed_ldflags"
1830   AC_MSG_CHECKING([for libperl])
1831   AC_TRY_LINK([
1832 #include <EXTERN.h>
1833 #include <perl.h>
1834 ],  [perl_alloc();],
1835     [AC_MSG_RESULT(yes)],
1836     [AC_MSG_RESULT(no)
1837      AC_MSG_ERROR([libperl library is required for Perl])])
1838   LIBS=$pgac_save_LIBS
1839   CPPFLAGS=$ac_save_CPPFLAGS
1840 fi
1841
1842 # check for <Python.h>
1843 if test "$with_python" = yes; then
1844   ac_save_CPPFLAGS=$CPPFLAGS
1845   CPPFLAGS="$python_includespec $CPPFLAGS"
1846   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1847   CPPFLAGS=$ac_save_CPPFLAGS
1848 fi
1849
1850 #
1851 # Check for DocBook and tools
1852 #
1853 PGAC_PROG_NSGMLS
1854 PGAC_PROG_JADE
1855 PGAC_CHECK_DOCBOOK(4.2)
1856 PGAC_PATH_DOCBOOK_STYLESHEETS
1857 PGAC_PATH_COLLATEINDEX
1858 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1859 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1860
1861 # Thread testing
1862
1863 # We have to run the thread test near the end so we have all our symbols
1864 # defined.  Cross compiling throws a warning.
1865 #
1866 if test "$enable_thread_safety" = yes; then
1867 if test "$PORTNAME" != "win32"
1868 then
1869 AC_MSG_CHECKING([thread safety of required library functions])
1870
1871 _CFLAGS="$CFLAGS"
1872 _LIBS="$LIBS"
1873 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1874 LIBS="$LIBS $PTHREAD_LIBS"
1875 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1876   [AC_MSG_RESULT(yes)],
1877   [AC_MSG_RESULT(no)
1878   AC_MSG_ERROR([thread test program failed
1879 This platform is not thread-safe.  Check the file 'config.log' or compile
1880 and run src/test/thread/thread_test for the exact reason.
1881 Use --disable-thread-safety to disable thread safety.])],
1882   [AC_MSG_RESULT(maybe)
1883   AC_MSG_WARN([
1884 *** Skipping thread test program because of cross-compile build.
1885 *** Run the program in src/test/thread on the target machine.
1886 ])])
1887 CFLAGS="$_CFLAGS"
1888 LIBS="$_LIBS"
1889 else
1890 AC_MSG_WARN([*** skipping thread test on Win32])
1891 fi
1892 fi
1893
1894 # If compiler will take -Wl,--as-needed (or various platform-specific
1895 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1896 # trying to filter LIBS to the minimum for each executable.
1897 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1898 # libreadline; therefore we postpone testing it until we know what library
1899 # dependencies readline has.  The test code will try to link with $LIBS.
1900 if test "$with_readline" = yes; then
1901   link_test_func=readline
1902 else
1903   link_test_func=exit
1904 fi
1905
1906 if test "$PORTNAME" = "darwin"; then
1907   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1908 elif test "$PORTNAME" = "openbsd"; then
1909   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1910 else
1911   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1912 fi
1913
1914 # Create compiler version string
1915 if test x"$GCC" = x"yes" ; then
1916   cc_string=`${CC} --version | sed q`
1917   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1918 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1919   cc_string=`${CC} -V 2>&1 | sed q`
1920 else
1921   cc_string=$CC
1922 fi
1923
1924 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1925                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1926                    [A string containing the version number, platform, and C compiler])
1927
1928 # Supply a numeric version string for use by 3rd party add-ons
1929 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1930 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1931 tr '.' '        ' |
1932 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1933 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1934
1935
1936 # Begin output steps
1937
1938 AC_MSG_NOTICE([using compiler=$cc_string])
1939 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1940 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1941 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1942
1943 # prepare build tree if outside source tree
1944 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1945 # Note 2: /bin/pwd might be better than shell's built-in at getting
1946 #         a symlink-free name.
1947 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1948   vpath_build=no
1949 else
1950   vpath_build=yes
1951   if test "$no_create" != yes; then
1952     _AS_ECHO_N([preparing build tree... ])
1953     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1954     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1955       || AC_MSG_ERROR(failed)
1956     AC_MSG_RESULT(done)
1957   fi
1958 fi
1959 AC_SUBST(vpath_build)
1960
1961
1962 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1963
1964 AC_CONFIG_LINKS([
1965   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1966   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1967   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1968   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1969   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1970   src/include/pg_config_os.h:src/include/port/${template}.h
1971   src/Makefile.port:src/makefiles/Makefile.${template}
1972 ])
1973
1974 if test "$PORTNAME" = "win32"; then
1975 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1976 # Links sometimes fail undetected on Mingw -
1977 # so here we detect it and warn the user
1978 for FILE in $CONFIG_LINKS
1979  do
1980         # test -e works for symlinks in the MinGW console
1981         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1982  done
1983 ])
1984 fi
1985
1986 AC_CONFIG_HEADERS([src/include/pg_config.h],
1987 [
1988 # Update timestamp for pg_config.h (see Makefile.global)
1989 echo >src/include/stamp-h
1990 ])
1991
1992 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
1993 [
1994 # Update timestamp for pg_config_ext.h (see Makefile.global)
1995 echo >src/include/stamp-ext-h
1996 ])
1997
1998 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1999                   [echo >src/interfaces/ecpg/include/stamp-h])
2000
2001 AC_OUTPUT