granicus.if.org Git - sysstat/blob - configure.in

   1 # configure.in
   2 #
   3 # (C) 2007 - Ivana Varekova <varekova@redhat.com>
   4 # Modified by Sebastien Godard (sysstat <at> orange.fr)
   5
   6 # Initialization of $PACKAGE_VERSION and $PACKAGE_NAME variables
   7 AC_INIT(sysstat, 11.4.0)
   8
   9 # Ensure that a recent enough version of Autoconf is being used
  10 AC_PREREQ(2.53)
  11
  12 # Check whether the configure script is in the right dir
  13 AC_CONFIG_SRCDIR(ioconf.h)
  14
  15 # Check programs
  16 echo .
  17 echo Check programs:
  18 echo .
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_PROG_LN_S
  23
  24 DFLAGS=""
  25
  26 AC_CHECK_PROG(CHMOD, chmod, chmod)
  27 AC_CHECK_PROG(CHOWN, chown, chown)
  28 AC_CHECK_PROG(AR, ar, ar)
  29 AC_CHECK_PROG(INSTALL, install, install)
  30 AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
  31 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
  32 AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
  33 AC_CHECK_PROGS(ZIP, xz bzip2 gzip, gzip)
  34 INSTALL_DATA="\${INSTALL} -m 644"
  35 AC_SUBST(INSTALL_DATA)
  36 INSTALL_BIN="\${INSTALL} -m 755"
  37 AC_SUBST(INSTALL_BIN)
  38
  39 AC_PATH_PROG(PATH_CP, cp)
  40 AC_PATH_PROG(PATH_CHKCONFIG, chkconfig)
  41
  42 # Check for systemd
  43 AC_CHECK_PROG(PKG_CONFIG, pkg-config, pkg-config)
  44 AC_PATH_PROG(SYSTEMCTL, systemctl)
  45 AC_ARG_WITH([systemdsystemunitdir],
  46     AS_HELP_STRING([--with-systemdsystemunitdir=DIR],[Directory for systemd service files]),
  47     [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  48 if test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ; then
  49     AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
  50 fi
  51
  52 # Check libraries
  53
  54 # Check header files
  55 echo .
  56 echo Check header files:
  57 echo .
  58 HAVE_LIBINTL_H=
  59 HAVE_LOCALE_H=
  60 HAVE_SYS_SYSMACROS_H=
  61 AC_HEADER_STDC
  62 AC_HEADER_DIRENT
  63 AC_CHECK_HEADERS(ctype.h)
  64 AC_CHECK_HEADERS(errno.h)
  65 AC_CHECK_HEADERS(libintl.h, HAVE_LIBINTL_H=1)
  66 AC_CHECK_HEADERS(locale.h, HAVE_LOCALE_H=1)
  67 AC_CHECK_HEADERS(net/if.h)
  68 AC_CHECK_HEADERS(regex.h)
  69 AC_CHECK_HEADERS(signal.h)
  70 AC_CHECK_HEADERS(stdio.h)
  71 AC_CHECK_HEADERS(sys/file.h)
  72 AC_CHECK_HEADERS(sys/ioctl.h)
  73 AC_CHECK_HEADERS(sys/stat.h)
  74 AC_CHECK_HEADERS(sys/sysmacros.h, HAVE_SYS_SYSMACROS_H=1)
  75
  76 echo .
  77 echo Check typedefs, structures and compiler characteristics:
  78 echo .
  79 AC_TYPE_SIGNAL
  80 AC_TYPE_SIZE_T
  81 AC_TYPE_OFF_T
  82
  83 echo .
  84 echo Check library functions:
  85 echo .
  86 AC_CHECK_FUNCS(strchr)
  87 AC_CHECK_FUNCS(strcspn)
  88 AC_CHECK_FUNCS(strspn)
  89 AC_CHECK_FUNCS(strstr)
  90
  91 # Should we check for lm_sensors?
  92 AC_MSG_CHECKING(for sensors support)
  93 AC_ARG_ENABLE(sensors,
  94               AC_HELP_STRING([--disable-sensors],
  95                              [disable sensors support]),
  96                              SENSORS=$enableval,SENSORS=yes)
  97 if test $SENSORS != "yes"; then
  98    HAVE_SENSORS="n"
  99 else
 100    HAVE_SENSORS="y"
 101 fi
 102 AC_MSG_RESULT($SENSORS)
 103
 104 # Check for lm_sensors
 105 SENSORS=no
 106 LFSENSORS=""
 107 DFSENSORS=""
 108 AC_CHECK_LIB(sensors, sensors_get_detected_chips, LFSENSORS="-lsensors", HAVE_SENSORS="n")
 109 AC_MSG_CHECKING(for sensors lib)
 110 AC_TRY_COMPILE(#include <sensors/sensors.h>
 111 #include <sensors/error.h>
 112                 , sensors_cleanup();,SENSORS=yes; DFSENSORS="-DHAVE_SENSORS", HAVE_SENSORS="n"; SENSORS=no)
 113 AC_MSG_RESULT($SENSORS)
 114 AC_SUBST(HAVE_SENSORS)
 115 AC_SUBST(LFSENSORS)
 116 AC_SUBST(DFSENSORS)
 117
 118 echo .
 119 echo Check system services:
 120 echo .
 121 AC_SYS_LARGEFILE
 122
 123 echo .
 124 echo Check configuration:
 125 echo .
 126 # Check arguments used
 127 #
 128 # Optional Features:
 129 #  --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
 130 #  --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
 131 #  --disable-largefile     omit support for large files
 132 #  --disable-nls           disable National Language Support
 133 #  --disable-file-attr     don't set attributes on files being installed
 134 #  --enable-install-cron   tell sysstat to install cron scripts
 135 #  --collect-all           tell sadc to collect all possible data
 136 #  --enable-clean-sa-dir   clean system activity directory
 137 #  --enable-compress-manpg compress manual pages
 138 #  --enable-install-isag   install isag script
 139 #  --enable-debuginfo      enable debug output (--debuginfo option)
 140 #  --disable-documentation do not install documentation (man pages...)
 141 #  --disable-sensors       do not link against libsensors even if available
 142 #  --disable-stripping     do not strip object files
 143 #  --enablle-copy-only     only copy files when installing sysstat
 144 #
 145 # Some influential environment variables:
 146 #  rcdir         directory where startup scripts are installed
 147 #  sa_lib_dir    sadc, sa1 and sa2 directory
 148 #  sa_dir        system activity daily datafiles directory
 149 #  conf_dir      sysstat configuration directory (default is /etc/sysconfig)
 150 #  history       number of daily datafiles to keep (default value is 7)
 151 #  compressafter number of days after which datafiles are compressed
 152 #  man_group     group for man pages
 153 #  cron_owner    crontab owner
 154 #  cron_interval crontab sampling interval
 155 #  sadc_options  options to be passed to sadc
 156 #
 157 # Fine tuning the installation directories:
 158 #  --mandir=DIR           man documentation directory [PREFIX/man]
 159 #  --docdir=DIR           other documentation directory [PREFIX/share/doc]
 160 #
 161 # Installation directories:
 162 #  --prefix=PREFIX         install architecture-independent files in PREFIX
 163 #                            [/usr/local]
 164 #  --exec-prefix=EPREFIX   install architecture-dependent files in EPREFIX
 165 #                            [PREFIX]
 166
 167 # Set directories
 168 if test -d /etc/init.d && test ! -L /etc/init.d; then
 169    if test -d /etc/init.d/rc2.d; then
 170       RC_DIR=/etc/init.d
 171       INITD_DIR=.
 172    else
 173       RC_DIR=/etc
 174       INITD_DIR=init.d
 175    fi
 176    INIT_DIR=/etc/init.d
 177 elif test -d /sbin/init.d; then
 178    RC_DIR=/sbin/init.d
 179    INIT_DIR=/sbin/init.d
 180    INITD_DIR=.
 181 else
 182    RC_DIR=/etc/rc.d
 183    INIT_DIR=/etc/rc.d/init.d
 184    INITD_DIR=init.d
 185 fi
 186
 187 AC_MSG_CHECKING(run-commands directory)
 188 AC_ARG_VAR([rcdir],[run-commands directory])
 189 if test x$rcdir != x""; then
 190         # Override previous rc directories values
 191         RC_DIR=$rcdir
 192         INIT_DIR=$rcdir/init.d
 193         INITD_DIR=init.d
 194 fi
 195 AC_MSG_RESULT($RC_DIR)
 196 if test ! -d $RC_DIR; then
 197         echo "INFO: Directory ${RC_DIR} doesn't exist."
 198         echo "INFO: Startup scripts won't be installed."
 199 fi
 200
 201 AC_SUBST(RC_DIR)
 202 AC_SUBST(INIT_DIR)
 203 AC_SUBST(INITD_DIR)
 204
 205 if test $HAVE_SYS_SYSMACROS_H; then
 206    SYSMACROS="y"
 207 else
 208    SYSMACROS="n"
 209 fi
 210 AC_SUBST(SYSMACROS)
 211
 212 # Set sadc directory
 213 if test $prefix != "NONE"; then
 214    AuxPrefix=$prefix
 215 else
 216    AuxPrefix=/usr/local
 217 fi
 218
 219 SADC_DIR=$AuxPrefix/lib
 220 if test -d $AuxPrefix/lib64; then
 221     # Verify that this OS is really 64 bit
 222     BITS=$(getconf LONG_BIT 2>/dev/null)
 223     if test $? = 0; then
 224         if test $BITS = 64; then
 225             SADC_DIR=$AuxPrefix/lib64
 226         fi
 227     else
 228         # Fallback: look for lm (long mode) flag to know if CPU is 64 bit
 229         grep " lm " /proc/cpuinfo >/dev/null 2>&1
 230         if test $? = 0; then
 231             SADC_DIR=$AuxPrefix/lib64
 232         fi
 233     fi
 234 fi
 235
 236 AC_MSG_CHECKING(sadc directory)
 237 AC_ARG_VAR([sa_lib_dir],[sadc directory])
 238 if test x$sa_lib_dir != x""; then
 239    SA_LIB_DIR=$sa_lib_dir
 240 else
 241    SA_LIB_DIR=$SADC_DIR/sa
 242 fi
 243 AC_MSG_RESULT($SA_LIB_DIR)
 244 if test ! -d $SA_LIB_DIR; then
 245    echo "INFO: Directory ${SA_LIB_DIR} will be created during installation stage."
 246 fi
 247 AC_SUBST(SA_LIB_DIR)
 248
 249 # Set system activity directory
 250 AC_MSG_CHECKING(system activity directory)
 251 AC_ARG_VAR([sa_dir],[system activity directory])
 252 if test x$sa_dir != x""; then
 253    SA_DIR=$sa_dir
 254 else
 255    SA_DIR=/var/log/sa
 256 fi
 257 AC_MSG_RESULT($SA_DIR)
 258 if test ! -d $SA_DIR; then
 259    echo "INFO: Directory ${SA_DIR} will be created during installation stage."
 260 fi
 261 AC_SUBST(SA_DIR)
 262
 263 # Set configuration directory
 264 AC_MSG_CHECKING(sysstat configuration directory)
 265 AC_ARG_VAR([conf_dir],[sysstat configuration directory])
 266 if test x$conf_dir != x""; then
 267    SYSCONFIG_DIR=$conf_dir
 268 else
 269    SYSCONFIG_DIR=/etc/sysconfig
 270 fi
 271 AC_MSG_RESULT($SYSCONFIG_DIR)
 272 if test ! -d $SYSCONFIG_DIR; then
 273    echo "INFO: Directory ${SYSCONFIG_DIR} will be created during installation stage."
 274 fi
 275 AC_SUBST(SYSCONFIG_DIR)
 276
 277 # National Language Support
 278 AC_MSG_CHECKING(National Language Support)
 279 AC_ARG_ENABLE(nls,
 280               AC_HELP_STRING([--disable-nls],
 281                              [disable National Language Support]),
 282                              AUX_NLS=$enableval,AUX_NLS=yes)
 283 if test $AUX_NLS != "no" && test $HAVE_LIBINTL_H && test $HAVE_LOCALE_H; then
 284    AUX_NLS="yes"
 285    NLS="y"
 286 else
 287    AUX_NLS="no"
 288    NLS="n"
 289 fi
 290 AC_MSG_RESULT($AUX_NLS)
 291 LACKING_GETTEXT="n"
 292 if test $AUX_NLS = "yes" &&  test x$MSGFMT != x"msgfmt"; then
 293    echo "WARNING: msgfmt command not found!"
 294    LACKING_GETTEXT="y"
 295 fi
 296 if test $AUX_NLS = "yes" &&  test x$XGETTEXT != x"xgettext"; then
 297    echo "WARNING: xgettext command not found!"
 298    LACKING_GETTEXT="y"
 299 fi
 300 if test $AUX_NLS = "yes" &&  test x$MSGMERGE != x"msgmerge"; then
 301    echo "WARNING: msgmerge command not found!"
 302    LACKING_GETTEXT="y"
 303 fi
 304 if test $NLS = "y" && test $LACKING_GETTEXT = "y"; then
 305    echo "WARNING: Disabling NLS"
 306    NLS="n"
 307 fi
 308 AC_SUBST(NLS)
 309
 310 # Data history to keep by sa2
 311 AC_MSG_CHECKING(number of daily data files to keep)
 312 AC_ARG_VAR([history],[number of daily data files to keep (default value is 7)])
 313 if test x$history = x""; then
 314    HISTORY=7
 315 else
 316    HISTORY=$history
 317 fi
 318 AC_MSG_RESULT($HISTORY)
 319 AC_SUBST(HISTORY)
 320
 321 # Number of days after which datafiles are compressed
 322 AC_MSG_CHECKING(number of days after which data files are compressed)
 323 AC_ARG_VAR([compressafter],[number of days after which data files are compressed (default value is 10)])
 324 if test x$compressafter = x""; then
 325    COMPRESSAFTER=10
 326 else
 327    COMPRESSAFTER=$compressafter
 328 fi
 329 AC_MSG_RESULT($COMPRESSAFTER)
 330 AC_SUBST(COMPRESSAFTER)
 331
 332 # Preallocation factor
 333 AC_MSG_CHECKING(preallocation factor value)
 334 AC_ARG_VAR([prealloc],[preallocation factor that will determine data files size (default value is 1)])
 335 if test x$prealloc = x""; then
 336    PREALLOC_FACTOR=1
 337 else
 338    PREALLOC_FACTOR=$prealloc
 339 fi
 340 AC_MSG_RESULT($PREALLOC_FACTOR)
 341 AC_SUBST(PREALLOC_FACTOR)
 342
 343 # Manual page group
 344 grep ^man: /etc/group >/dev/null 2>&1
 345 if test $? = 0; then
 346    GRP=man
 347 else
 348    GRP=root
 349 fi
 350
 351 AC_MSG_CHECKING(group for manual pages)
 352 AC_ARG_VAR([man_group],[group for manual pages])
 353 if test x$man_group = x""; then
 354    MAN_GROUP=$GRP
 355    AC_MSG_RESULT($MAN_GROUP)
 356 else
 357    grep ^$man_group: /etc/group >/dev/null 2>&1
 358    if test $? = 1; then
 359       MAN_GROUP=$GRP
 360       AC_MSG_RESULT($MAN_GROUP)
 361       echo "WARNING: Group ${man_group} not found: Using ${GRP} instead"
 362    else
 363       MAN_GROUP=$man_group
 364       AC_MSG_RESULT($MAN_GROUP)
 365    fi
 366 fi
 367 AC_SUBST(MAN_GROUP)
 368
 369 # Don't set attributes on files being installed?
 370 AC_MSG_CHECKING(whether attributes should not be set on files being installed)
 371 AC_ARG_ENABLE(file-attr,
 372               AC_HELP_STRING([--disable-file-attr],
 373                              [do not set attributes on files being installed]),
 374                              AUX_IMG=$enableval,AUX_IMG=yes)
 375 if test $AUX_IMG != "no"; then
 376    IGNORE_FILE_ATTRIBUTES=n
 377    AUX_IMG=no
 378 else
 379    IGNORE_FILE_ATTRIBUTES=y
 380    AUX_IMG=yes
 381 fi
 382 AC_MSG_RESULT($AUX_IMG)
 383 AC_SUBST(IGNORE_FILE_ATTRIBUTES)
 384
 385 # Compress manual pages?
 386 AC_MSG_CHECKING(whether manual pages should be compressed)
 387 AC_ARG_ENABLE(compress-manpg,
 388               AC_HELP_STRING([--enable-compress-manpg],
 389                              [compress sysstat manual pages]),
 390                              AUX_MPG=$enableval,AUX_MPG=no)
 391 if test $AUX_MPG != "yes"; then
 392    COMPRESS_MANPG=n
 393    AUX_MPG=no
 394 else
 395    COMPRESS_MANPG=y
 396 fi
 397 AC_MSG_RESULT($AUX_MPG)
 398 AC_SUBST(COMPRESS_MANPG)
 399
 400 # Check whether isag should be installed
 401 AC_MSG_CHECKING(whether isag script should be installed)
 402 AC_ARG_ENABLE(install-isag,
 403               AC_HELP_STRING([--enable-install-isag],
 404                              [install isag script]),
 405                              AUX_IIS=$enableval,AUX_IIS=no)
 406 if test $AUX_IIS != "yes"; then
 407    INSTALL_ISAG=n
 408    AUX_IIS=no
 409 else
 410    INSTALL_ISAG=y
 411 fi
 412 AC_MSG_RESULT($AUX_IIS)
 413 AC_SUBST(INSTALL_ISAG)
 414
 415 # Check whether sa directory should be cleaned
 416 AC_MSG_CHECKING(whether system activity directory should be cleaned)
 417 AC_ARG_ENABLE(clean-sa-dir,
 418               AC_HELP_STRING([--enable-clean-sa-dir],
 419                              [clean system activity directory]),
 420                             AUX_CSD=$enableval,AUX_CSD=no)
 421 if test $AUX_CSD != "yes"; then
 422    CLEAN_SA_DIR=n
 423    AUX_CSD=no
 424 else
 425    CLEAN_SA_DIR=y
 426 fi
 427 AC_MSG_RESULT($AUX_CSD)
 428 AC_SUBST(CLEAN_SA_DIR)
 429
 430 # Start crontab
 431 AC_MSG_CHECKING(whether cron should start sar automatically)
 432 AC_ARG_ENABLE(install-cron,
 433               AC_HELP_STRING([--enable-install-cron],
 434                              [install a crontab to start sar]),
 435                              INSTALL_CRON=$enableval,INSTALL_CRON=n)
 436 if test $INSTALL_CRON != "yes"; then
 437    INSTALL_CRON=n
 438    AUX_CRON=no
 439 else
 440    INSTALL_CRON=y
 441    AUX_CRON=yes
 442 fi
 443 AC_MSG_RESULT($AUX_CRON)
 444 AC_SUBST(INSTALL_CRON)
 445
 446 # Crontab owner
 447 CUSR="root"
 448 if test $INSTALL_CRON = "y"; then
 449    AC_MSG_CHECKING(crontab owner)
 450    AC_ARG_VAR([cron_owner],[crontab owner])
 451    if test x$cron_owner = x""; then
 452       CRON_OWNER=$CUSR
 453       AC_MSG_RESULT($CRON_OWNER)
 454    else
 455       grep ^$cron_owner: /etc/passwd >/dev/null 2>&1
 456       if test $? = 1; then
 457          CRON_OWNER=$CUSR;
 458          AC_MSG_RESULT($CRON_OWNER)
 459          echo "WARNING: User ${cron_owner} not found: Using ${CUSR} instead."
 460       else
 461          CRON_OWNER=$cron_owner
 462          AC_MSG_RESULT($CRON_OWNER)
 463       fi
 464    fi
 465    echo "INFO: Crontab for ${CRON_OWNER} will be saved in current directory if necessary"
 466    if test $CRON_OWNER = "root"; then
 467       SU_C_OWNER=""
 468       QUOTE=""
 469       REM_CHOWN="# REM_CHOWN"
 470    else
 471       SU_C_OWNER="su $CRON_OWNER -c "
 472       QUOTE=\"
 473       # " (ignore this line)
 474       REM_CHOWN=$CHOWN
 475    fi
 476
 477 #  Crontab interval
 478    AC_MSG_CHECKING(crontab interval)
 479    AC_ARG_VAR([cron_interval],[crontab interval])
 480    if test x$cron_interval = x""; then
 481       CRON_INTERVAL=10
 482    else
 483       CRON_INTERVAL=$cron_interval
 484    fi
 485    AC_MSG_RESULT($CRON_INTERVAL)
 486    CRON_INTERVAL_SEC=`expr ${CRON_INTERVAL} \* 60`
 487    CRON_COUNT=`expr 60 / ${CRON_INTERVAL}`
 488
 489 #  Check whether sadc should collect all possible activities
 490    AC_MSG_CHECKING(whether sadc should collect all possible activities)
 491    AC_ARG_ENABLE(collect-all,
 492                  AC_HELP_STRING([--enable-collect-all],
 493                                 [collect all possible activities]),
 494                                 COLLECT_ALL=$enableval,COLLECT_ALL=n)
 495    if test $COLLECT_ALL != "yes"; then
 496       COLLECT_ALL=""
 497       AUX_COLL=no
 498    else
 499       COLLECT_ALL="-S XALL"
 500       AUX_COLL=yes
 501    fi
 502    AC_MSG_RESULT($AUX_COLL)
 503
 504    AC_MSG_CHECKING(options to be passed to sadc)
 505    AC_ARG_VAR([sadc_options],[options to be passed to sadc])
 506    if test x"$sadc_options" != x""; then
 507         SADC_OPT="$sadc_options"
 508    else
 509         SADC_OPT=
 510    fi
 511    AC_MSG_RESULT($SADC_OPT)
 512    AC_SUBST(SADC_OPT)
 513
 514 #  Check whether files should only be copied
 515    AC_MSG_CHECKING(whether files should only be copied)
 516    AC_ARG_ENABLE(copy-only,
 517                  AC_HELP_STRING([--enable-copy-only],
 518                                 [only copy files when installing]),
 519                                 OCOPY=$enableval,OCOPY=no)
 520    if test $OCOPY != "yes"; then
 521       COPY_ONLY=n
 522       OCOPY=no
 523    else
 524       COPY_ONLY=y
 525    fi
 526    AC_MSG_RESULT($OCOPY)
 527    AC_SUBST(COPY_ONLY)
 528
 529 else
 530    CRON_OWNER="root"
 531    SU_C_OWNER=""
 532    QUOTE=""
 533    REM_CHOWN="# REM_CHOWN"
 534    CRON_INTERVAL=10
 535    CRON_INTERVAL_SEC=600
 536    CRON_COUNT=6
 537    COLLECT_ALL=""
 538 fi
 539 AC_SUBST(CRON_OWNER)
 540 AC_SUBST(SU_C_OWNER)
 541 AC_SUBST(CRON_INTERVAL)
 542 AC_SUBST(CRON_INTERVAL_SEC)
 543 AC_SUBST(CRON_COUNT)
 544 AC_SUBST(QUOTE)
 545 AC_SUBST(REM_CHOWN)
 546 AC_SUBST(COLLECT_ALL)
 547
 548 # Check whether documentation should be installed
 549 AC_MSG_CHECKING(whether documentation should be installed)
 550 AC_ARG_ENABLE(documentation,
 551               AC_HELP_STRING([--disable-documentation],
 552                              [do not install documentation]),
 553                              AUX_DOC=$enableval,AUX_DOC=yes)
 554 if  test  $AUX_DOC !=  "no"; then
 555    AUX_DOC="yes"
 556    INSTALL_DOC="y"
 557 else
 558    AUX_DOC="no"
 559    INSTALL_DOC="n"
 560 fi
 561 AC_MSG_RESULT($AUX_DOC)
 562 AC_SUBST(INSTALL_DOC)
 563
 564 # Set directory for installing manual pages (see comment in Makefile)
 565 AC_SUBST(mandir)
 566
 567 # Check whether --debuginfo options should be allowed
 568 AC_ARG_ENABLE(debuginfo,
 569               AC_HELP_STRING([--enable-debuginfo],
 570                              [enable debug output (--debuginfo option)]),
 571                              WITH_DEBUG=yes ; DFLAGS="$DFLAGS -DDEBUG" , WITH_DEBUG=no)
 572 AC_SUBST(WITH_DEBUG)
 573 AC_SUBST(DFLAGS)
 574
 575 # Check whether object files should be stripped
 576 AC_MSG_CHECKING(whether object files should be stripped)
 577 AC_ARG_ENABLE(stripping,
 578               AC_HELP_STRING([--disable-stripping],
 579                              [do not strip object files]),
 580                              AUX_STRIP=$enableval,AUX_STRIP=yes)
 581 if test $AUX_STRIP != "no"; then
 582    AUX_STRIP="yes"
 583    STRIP="-s"
 584 else
 585    AUX_STRIP="no"
 586    STRIP=
 587 fi
 588 AC_MSG_RESULT($AUX_STRIP)
 589 AC_SUBST(STRIP)
 590
 591 # Create files
 592 echo .
 593 echo Now create files:
 594 echo .
 595 AC_CONFIG_FILES([sa1], [chmod +x sa1])          # Permissions must be changed
 596 AC_CONFIG_FILES([sa2], [chmod +x sa2])          # Permissions must be changed
 597 AC_CONFIG_FILES([cron/crontab:cron/crontab.sample])     # File must be renamed
 598 AC_CONFIG_FILES([sysstat.sysconfig])
 599 AC_CONFIG_FILES([version.h:version.in])         # File must be renamed
 600 AC_CONFIG_FILES([sysconfig.h:sysconfig.in])     # File must be renamed
 601 AC_CONFIG_FILES([prealloc.h:prealloc.in])       # File must be renamed
 602 AC_CONFIG_FILES([cron/sysstat.cron.daily])
 603 AC_CONFIG_FILES([cron/sysstat.cron.hourly])
 604 AC_CONFIG_FILES([cron/sysstat.crond])
 605 AC_CONFIG_FILES([cron/sysstat.crond.sample.in:cron/sysstat.crond.in], [sed s/^/#/ cron/sysstat.crond.sample.in > cron/sysstat.crond.sample])
 606 AC_CONFIG_FILES([sysstat], [chmod +x sysstat])  # Permissions must be changed
 607 AC_CONFIG_FILES([sysstat.service])
 608 AC_CONFIG_FILES([cron/sysstat-collect.service])
 609 AC_CONFIG_FILES([cron/sysstat-collect.timer])
 610 AC_CONFIG_FILES([cron/sysstat-summary.service])
 611 AC_CONFIG_FILES([cron/sysstat-summary.timer])
 612 AC_CONFIG_FILES([man/sa1.8:man/sa1.in])         # File must be renamed
 613 AC_CONFIG_FILES([man/sa2.8:man/sa2.in])         # File must be renamed
 614 AC_CONFIG_FILES([man/sadc.8:man/sadc.in])       # File must be renamed
 615 AC_CONFIG_FILES([man/sadf.1:man/sadf.in])       # File must be renamed
 616 AC_CONFIG_FILES([man/sar.1:man/sar.in])         # File must be renamed
 617 AC_CONFIG_FILES([man/sysstat.5:man/sysstat.in]) # File must be renamed
 618 AC_CONFIG_FILES([man/iostat.1:man/iostat.in])   # File must be renamed
 619 AC_CONFIG_FILES([man/cifsiostat.1:man/cifsiostat.in])   # File must be renamed
 620 AC_CONFIG_FILES([contrib/isag/isag], [chmod +x contrib/isag/isag]) # Permissions must be changed
 621
 622 AC_OUTPUT(Makefile)
 623
 624 echo "
 625    Sysstat version:             $PACKAGE_VERSION
 626    Installation prefix:         $prefix
 627    rc directory:                ${RC_DIR}
 628    Init directory:              ${INIT_DIR}
 629    Systemd unit dir:            ${with_systemdsystemunitdir}
 630    Configuration directory:     ${SYSCONFIG_DIR}
 631    Man pages directory:         $mandir
 632    Compiler:                    $CC
 633    Compiler flags:              $CFLAGS
 634 "
 635