granicus.if.org Git - sysstat/blob - configure.in

   1 # configure.in
   2 #
   3 # (C) 2007 - Ivana Varekova <varekova@redhat.com>
   4 # Modified by Sebastien Godard (sysstat <at> orange.fr)
   5
   6 # Initialization of $PACKAGE_VERSION and $PACKAGE_NAME variables
   7 AC_INIT(sysstat, 12.5.3)
   8
   9 # Ensure that a recent enough version of Autoconf is being used
  10 AC_PREREQ(2.53)
  11
  12 # Check whether the configure script is in the right dir
  13 AC_CONFIG_SRCDIR(ioconf.h)
  14
  15 # Check programs
  16 echo .
  17 echo Check programs:
  18 echo .
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_PROG_LN_S
  23
  24 DFLAGS=""
  25
  26 AC_CHECK_PROG(CHMOD, chmod, chmod)
  27 AC_CHECK_PROG(CHOWN, chown, chown)
  28 AC_CHECK_PROG(AR, ar, ar)
  29 AC_CHECK_PROG(INSTALL, install, install)
  30 AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
  31 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
  32 AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
  33 AC_CHECK_PROG(VER_XML, xmllint, xmllint)
  34 AC_CHECK_PROGS(VER_JSON, json_verify json_pp, true)
  35 AC_CHECK_PROGS(ZIP, xz bzip2 gzip, gzip)
  36 INSTALL_DATA="\${INSTALL} -m 644"
  37 AC_SUBST(INSTALL_DATA)
  38 INSTALL_BIN="\${INSTALL} -m 755"
  39 AC_SUBST(INSTALL_BIN)
  40
  41 AC_SUBST(VER_JSON)
  42 AC_SUBST(VER_XML)
  43
  44 AC_PATH_PROG(PATH_CP, cp)
  45 AC_PATH_PROG(PATH_CHKCONFIG, chkconfig)
  46
  47 # Check for systemd
  48 AC_CHECK_PROG(PKG_CONFIG, pkg-config, pkg-config)
  49 AC_PATH_PROG(SYSTEMCTL, systemctl)
  50 AC_ARG_WITH([systemdsystemunitdir],
  51     AS_HELP_STRING([--with-systemdsystemunitdir=DIR],[Directory for systemd service files]),
  52     [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  53 if test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ; then
  54     AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
  55 fi
  56 AC_ARG_WITH([systemdsleepdir],
  57     AS_HELP_STRING([--with-systemdsleepdir=DIR],[Directory for systemd suspend/resume scripts]),
  58     [], [with_systemdsleepdir=$($PKG_CONFIG --variable=systemdsleepdir systemd)])
  59 if test -n "$with_systemdsleepdir" -a "x$with_systemdsleepdir" != xno ; then
  60     AC_SUBST([SYSTEMD_SLEEP_DIR], [$with_systemdsleepdir])
  61 fi
  62
  63 # Check libraries
  64
  65 # Check header files
  66 echo .
  67 echo Check header files:
  68 echo .
  69 HAVE_LIBINTL_H=
  70 HAVE_LOCALE_H=
  71 HAVE_SYS_SYSMACROS_H=
  72 HAVE_SYS_PARAM_H=
  73 AC_CHECK_HEADERS(ctype.h)
  74 AC_CHECK_HEADERS(errno.h)
  75 AC_CHECK_HEADERS(libintl.h, HAVE_LIBINTL_H=1)
  76 AC_CHECK_HEADERS(locale.h, HAVE_LOCALE_H=1)
  77 AC_CHECK_HEADERS(linux/sched.h, HAVE_LINUX_SCHED_H=1)
  78 AC_CHECK_HEADERS(net/if.h)
  79 AC_CHECK_HEADERS(regex.h)
  80 AC_CHECK_HEADERS(signal.h)
  81 AC_CHECK_HEADERS(stdio.h)
  82 AC_CHECK_HEADERS(stdint.h)
  83 AC_CHECK_HEADERS(fcntl.h)
  84 AC_CHECK_HEADERS(inttypes.h)
  85 AC_CHECK_HEADERS(libgen.h)
  86 AC_CHECK_HEADERS(pwd.h)
  87 AC_CHECK_HEADERS(time.h)
  88 AC_CHECK_HEADERS(unistd.h)
  89 AC_CHECK_HEADERS(pcp/pmapi.h, HAVE_PCP_PMAPI_H=1)
  90 AC_CHECK_HEADERS(pcp/impl.h, HAVE_PCP_IMPL_H=1)
  91 AC_CHECK_HEADERS(sys/time.h)
  92 AC_CHECK_HEADERS(sys/statvfs.h)
  93 AC_CHECK_HEADERS(sys/types.h)
  94 AC_CHECK_HEADERS(sys/file.h)
  95 AC_CHECK_HEADERS(sys/ioctl.h)
  96 AC_CHECK_HEADERS(sys/param.h, HAVE_SYS_PARAM_H=1)
  97 AC_CHECK_HEADERS(sys/stat.h)
  98 AC_CHECK_HEADERS(sys/sysmacros.h, HAVE_SYS_SYSMACROS_H=1)
  99 AC_CHECK_HEADERS(sys/utsname.h)
 100
 101 echo .
 102 echo Check typedefs, structures and compiler characteristics:
 103 echo .
 104 AC_TYPE_SIGNAL
 105 AC_TYPE_SIZE_T
 106 AC_TYPE_OFF_T
 107
 108 echo .
 109 echo Check library functions:
 110 echo .
 111 AC_CHECK_FUNCS(strchr)
 112 AC_CHECK_FUNCS(strcspn)
 113 AC_CHECK_FUNCS(strspn)
 114 AC_CHECK_FUNCS(strstr)
 115
 116 # Should we check for PCP support?
 117 AC_MSG_CHECKING(for PCP support)
 118 AC_ARG_ENABLE(pcp,
 119               AC_HELP_STRING([--disable-pcp],
 120                              [disable PCP support]),
 121                              PCP=$enableval,PCP=yes)
 122 if test $PCP != "yes"; then
 123         HAVE_PCP="n"
 124 else
 125         HAVE_PCP="y"
 126 fi
 127
 128 if test ! $HAVE_PCP_PMAPI_H; then
 129         HAVE_PCP="n"
 130         PCP=no
 131 fi
 132 AC_MSG_RESULT($PCP)
 133
 134 # Check for PCP libraries
 135 LFPCP=""
 136 DFPCP=""
 137 if test $HAVE_PCP = "y"; then
 138         PCP=no
 139         AC_CHECK_LIB(pcp, pmGetVersion, LFPCP="-lpcp -lpcp_import", HAVE_PCP="n")
 140         AC_MSG_CHECKING(for PCP libraries)
 141         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pcp/pmapi.h>
 142                                              #include <pcp/import.h>]],
 143                                            [[pmiEnd();]])],PCP=yes; DFPCP="-DHAVE_PCP", HAVE_PCP="n"; PCP=no)
 144         AC_MSG_RESULT($PCP)
 145 fi
 146 AC_SUBST(HAVE_PCP)
 147 AC_SUBST(LFPCP)
 148 AC_SUBST(DFPCP)
 149
 150 if test $HAVE_PCP_IMPL_H; then
 151    PCP_IMPL="y"
 152 else
 153    PCP_IMPL="n"
 154 fi
 155 AC_SUBST(PCP_IMPL)
 156
 157 # Should we check for lm_sensors?
 158 AC_MSG_CHECKING(for sensors support)
 159 AC_ARG_ENABLE(sensors,
 160               AC_HELP_STRING([--disable-sensors],
 161                              [disable sensors support]),
 162                              SENSORS=$enableval,SENSORS=yes)
 163 if test $SENSORS != "yes"; then
 164         SENSORS_SUPPORT="n"
 165 else
 166         SENSORS_SUPPORT="y"
 167 fi
 168 AC_MSG_RESULT($SENSORS)
 169
 170 # Check for lm_sensors library
 171 LFSENSORS=""
 172 DFSENSORS=""
 173 HAVE_SENSORS="n"
 174 if test $SENSORS_SUPPORT = "y"; then
 175         SENSORS=no
 176         AC_CHECK_LIB(sensors, sensors_get_detected_chips, LFSENSORS="-lsensors", HAVE_SENSORS="n")
 177         AC_MSG_CHECKING(for sensors library)
 178         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sensors/sensors.h>
 179                                              #include <sensors/error.h>]],
 180                                            [[sensors_cleanup();]])], SENSORS=yes; HAVE_SENSORS="y"; DFSENSORS="-DHAVE_SENSORS", HAVE_SENSORS="n"; SENSORS=no)
 181         AC_MSG_RESULT($SENSORS)
 182 fi
 183 AC_SUBST(HAVE_SENSORS)
 184 AC_SUBST(LFSENSORS)
 185 AC_SUBST(DFSENSORS)
 186
 187 # Check for 32-bit version of lm_sensors library
 188 LFSENSORS32=""
 189 DFSENSORS32=""
 190 HAVE_SENSORS32="n"
 191 if test $SENSORS_SUPPORT = "y"; then
 192         CFLAGS_SAVE=$CFLAGS
 193         CFLAGS+=" -m32"
 194         LDFLAGS=" -lsensors"
 195         SENSORS=no
 196 #       Check for another function to avoid using cached result
 197         AC_CHECK_LIB(sensors, sensors_cleanup, LFSENSORS32="-lsensors", HAVE_SENSORS32="n")
 198         AC_MSG_CHECKING(for sensors 32-bit library)
 199         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sensors/sensors.h>
 200                                           #include <sensors/error.h>]],
 201                                         [[sensors_cleanup();]])], SENSORS=yes; HAVE_SENSORS32="y"; DFSENSORS32="-DHAVE_SENSORS32", HAVE_SENSORS32="n"; SENSORS=no)
 202         AC_MSG_RESULT($SENSORS)
 203         CFLAGS=$CFLAGS_SAVE
 204 fi
 205 AC_SUBST(HAVE_SENSORS32)
 206 AC_SUBST(LFSENSORS32)
 207 AC_SUBST(DFSENSORS32)
 208
 209 # Check for 32-bit system libraries
 210 TGLIB32=no
 211 CFLAGS_SAVE=$CFLAGS
 212 CFLAGS+=" -m32"
 213 AC_MSG_CHECKING(for 32-bit system libraries)
 214 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]],
 215                                    [[printf("%d\n", sizeof(long));]])],TGLIB32=yes, TGLIB32=no)
 216 AC_MSG_RESULT($TGLIB32)
 217 CFLAGS=$CFLAGS_SAVE
 218 AC_SUBST(TGLIB32)
 219
 220 echo .
 221 echo Check system services:
 222 echo .
 223 AC_SYS_LARGEFILE
 224
 225 echo .
 226 echo Check configuration:
 227 echo .
 228 # Check arguments used
 229 #
 230 # Optional Features:
 231 #  --disable-FEATURE        do not include FEATURE (same as --enable-FEATURE=no)
 232 #  --enable-FEATURE[=ARG]   include FEATURE [ARG=yes]
 233 #  --disable-largefile      omit support for large files
 234 #  --disable-nls            disable National Language Support
 235 #  --disable-file-attr      don't set attributes on files being installed
 236 #  --enable-install-cron    tell sysstat to install cron scripts
 237 #  --collect-all            tell sadc to collect all possible data
 238 #  --enable-clean-sa-dir    clean system activity directory
 239 #  --disable-compress-manpg do not compress manual pages when installed
 240 #  --enable-debuginfo       enable debug output (--debuginfo option)
 241 #  --disable-documentation  do not install documentation (man pages...)
 242 #  --disable-sensors        do not link against libsensors even if available
 243 #  --disable-pcp            do not link against PCP libraries even if available
 244 #  --disable-stripping      do not strip object files
 245 #  --enable-copy-only       only copy files when installing sysstat
 246 #  --enable-use-crond       use standard cron daemon
 247 #
 248 # Some influential environment variables:
 249 #  rcdir         directory where startup scripts are installed
 250 #  sa_lib_dir    sadc, sa1 and sa2 directory
 251 #  sa_dir        system activity daily datafiles directory
 252 #  sar_dir       sar binary location. Used only in sa2 shell script
 253 #  conf_dir      sysstat configuration directory (default is /etc/sysconfig)
 254 #  conf_file     sysstat configuration file (default is sysstat)
 255 #  history       number of daily datafiles to keep (default value is 7)
 256 #  delay_range   maximum delay (in seconds) to wait before sa2 script generates its reports
 257 #  compressafter number of days after which datafiles are compressed
 258 #  man_group     group for man pages
 259 #  cron_owner    crontab owner
 260 #  cron_interval crontab sampling interval
 261 #  sadc_options  options to be passed to sadc
 262 #
 263 # Fine tuning the installation directories:
 264 #  --mandir=DIR           man documentation directory [PREFIX/man]
 265 #  --docdir=DIR           other documentation directory [PREFIX/share/doc]
 266 #
 267 # Installation directories:
 268 #  --prefix=PREFIX         install architecture-independent files in PREFIX
 269 #                            [/usr/local]
 270 #  --exec-prefix=EPREFIX   install architecture-dependent files in EPREFIX
 271 #                            [PREFIX]
 272
 273 # Set directories
 274 if test -d /etc/init.d && test ! -L /etc/init.d; then
 275    if test -d /etc/init.d/rc2.d; then
 276       RC_DIR=/etc/init.d
 277       INITD_DIR=.
 278    else
 279       RC_DIR=/etc
 280       INITD_DIR=init.d
 281    fi
 282    INIT_DIR=/etc/init.d
 283 elif test -d /sbin/init.d; then
 284    RC_DIR=/sbin/init.d
 285    INIT_DIR=/sbin/init.d
 286    INITD_DIR=.
 287 else
 288    RC_DIR=/etc/rc.d
 289    INIT_DIR=/etc/rc.d/init.d
 290    INITD_DIR=init.d
 291 fi
 292
 293 AC_MSG_CHECKING(run-commands directory)
 294 AC_ARG_VAR([rcdir],[run-commands directory])
 295 if test x$rcdir != x""; then
 296         # Override previous rc directories values
 297         RC_DIR=$rcdir
 298         INIT_DIR=$rcdir/init.d
 299         INITD_DIR=init.d
 300 fi
 301 AC_MSG_RESULT($RC_DIR)
 302 if test ! -d $RC_DIR; then
 303         echo "INFO: Directory ${RC_DIR} doesn't exist."
 304         echo "INFO: Startup scripts won't be installed."
 305 fi
 306
 307 AC_SUBST(RC_DIR)
 308 AC_SUBST(INIT_DIR)
 309 AC_SUBST(INITD_DIR)
 310
 311 if test $HAVE_SYS_SYSMACROS_H; then
 312    SYSMACROS="y"
 313 else
 314    SYSMACROS="n"
 315 fi
 316 AC_SUBST(SYSMACROS)
 317
 318 if test $HAVE_LINUX_SCHED_H; then
 319    LINUX_SCHED="y"
 320 else
 321    LINUX_SCHED="n"
 322 fi
 323 AC_SUBST(LINUX_SCHED)
 324
 325 if test $HAVE_SYS_PARAM_H; then
 326    SYSPARAM="y"
 327 else
 328    SYSPARAM="n"
 329 fi
 330 AC_SUBST(SYSPARAM)
 331
 332 # Set sadc directory
 333 if test $prefix != "NONE"; then
 334    AuxPrefix=$prefix
 335 else
 336    AuxPrefix=/usr/local
 337 fi
 338
 339 SADC_DIR=$AuxPrefix/lib
 340 if test -d $AuxPrefix/lib64; then
 341     # Verify that this OS is really 64 bit
 342     BITS=$(getconf LONG_BIT 2>/dev/null)
 343     if test $? = 0; then
 344         if test $BITS = 64; then
 345             SADC_DIR=$AuxPrefix/lib64
 346         fi
 347     else
 348         # Fallback: look for lm (long mode) flag to know if CPU is 64 bit
 349         grep " lm " /proc/cpuinfo >/dev/null 2>&1
 350         if test $? = 0; then
 351             SADC_DIR=$AuxPrefix/lib64
 352         fi
 353     fi
 354 fi
 355
 356 AC_MSG_CHECKING(sadc directory)
 357 AC_ARG_VAR([sa_lib_dir],[sadc directory])
 358 if test x$sa_lib_dir != x""; then
 359    SA_LIB_DIR=$sa_lib_dir
 360 else
 361    SA_LIB_DIR=$SADC_DIR/sa
 362 fi
 363 AC_MSG_RESULT($SA_LIB_DIR)
 364 if test ! -d $SA_LIB_DIR; then
 365    echo "INFO: Directory ${SA_LIB_DIR} will be created during installation stage."
 366 fi
 367 AC_SUBST(SA_LIB_DIR)
 368
 369 # Set system activity directory
 370 AC_MSG_CHECKING(system activity directory)
 371 AC_ARG_VAR([sa_dir],[system activity directory])
 372 if test x$sa_dir != x""; then
 373    SA_DIR=$sa_dir
 374 else
 375    SA_DIR=/var/log/sa
 376 fi
 377 AC_MSG_RESULT($SA_DIR)
 378 if test ! -d $SA_DIR; then
 379    echo "INFO: Directory ${SA_DIR} will be created during installation stage."
 380 fi
 381 AC_SUBST(SA_DIR)
 382
 383 # sar binary location. Used only in sa2 shell script
 384 AC_MSG_CHECKING(sar directory)
 385 AC_ARG_VAR([sar_dir],[sar directory])
 386 if test x$sar_dir != x""; then
 387    SAR_DIR=$sar_dir
 388 else
 389    SAR_DIR=
 390 fi
 391 AC_MSG_RESULT($SAR_DIR)
 392 AC_SUBST(SAR_DIR)
 393
 394 # Set configuration directory
 395 AC_MSG_CHECKING(sysstat configuration directory)
 396 AC_ARG_VAR([conf_dir],[sysstat configuration directory])
 397 if test x$conf_dir != x""; then
 398    SYSCONFIG_DIR=$conf_dir
 399 else
 400    SYSCONFIG_DIR=/etc/sysconfig
 401 fi
 402 AC_MSG_RESULT($SYSCONFIG_DIR)
 403 if test ! -d $SYSCONFIG_DIR; then
 404    echo "INFO: Directory ${SYSCONFIG_DIR} will be created during installation stage."
 405 fi
 406 AC_SUBST(SYSCONFIG_DIR)
 407
 408 # Set configuration directory
 409 AC_MSG_CHECKING(sysstat configuration file)
 410 AC_ARG_VAR([conf_file],[sysstat configuration file])
 411 if test x$conf_file != x""; then
 412    SYSCONFIG_FILE=$conf_file
 413 else
 414    SYSCONFIG_FILE=sysstat
 415 fi
 416 AC_MSG_RESULT($SYSCONFIG_FILE)
 417 AC_SUBST(SYSCONFIG_FILE)
 418
 419 # National Language Support
 420 AC_MSG_CHECKING(National Language Support)
 421 AC_ARG_ENABLE(nls,
 422               AC_HELP_STRING([--disable-nls],
 423                              [disable National Language Support]),
 424                              AUX_NLS=$enableval,AUX_NLS=yes)
 425 if test $AUX_NLS != "no" && test $HAVE_LIBINTL_H && test $HAVE_LOCALE_H; then
 426    AUX_NLS="yes"
 427    NLS="y"
 428 else
 429    AUX_NLS="no"
 430    NLS="n"
 431 fi
 432 AC_MSG_RESULT($AUX_NLS)
 433 AC_CHECK_LIB(intl, gettext, LFINTL="-lintl")
 434 AC_SUBST(LFINTL)
 435 LACKING_GETTEXT="n"
 436 if test $AUX_NLS = "yes" &&  test x$MSGFMT != x"msgfmt"; then
 437    echo "WARNING: msgfmt command not found!"
 438    LACKING_GETTEXT="y"
 439 fi
 440 if test $AUX_NLS = "yes" &&  test x$XGETTEXT != x"xgettext"; then
 441    echo "WARNING: xgettext command not found!"
 442    LACKING_GETTEXT="y"
 443 fi
 444 if test $AUX_NLS = "yes" &&  test x$MSGMERGE != x"msgmerge"; then
 445    echo "WARNING: msgmerge command not found!"
 446    LACKING_GETTEXT="y"
 447 fi
 448 if test $NLS = "y" && test $LACKING_GETTEXT = "y"; then
 449    echo "WARNING: Disabling NLS"
 450    NLS="n"
 451 fi
 452 AC_SUBST(NLS)
 453
 454 # Data history to keep by sa2
 455 AC_MSG_CHECKING(number of daily data files to keep)
 456 AC_ARG_VAR([history],[number of daily data files to keep (default value is 7)])
 457 if test x$history = x""; then
 458    HISTORY=7
 459 else
 460    HISTORY=$history
 461 fi
 462 AC_MSG_RESULT($HISTORY)
 463 AC_SUBST(HISTORY)
 464
 465 # Number of days after which datafiles are compressed
 466 AC_MSG_CHECKING(number of days after which data files are compressed)
 467 AC_ARG_VAR([compressafter],[number of days after which data files are compressed (default value is 10)])
 468 if test x$compressafter = x""; then
 469    COMPRESSAFTER=10
 470 else
 471    COMPRESSAFTER=$compressafter
 472 fi
 473 AC_MSG_RESULT($COMPRESSAFTER)
 474 AC_SUBST(COMPRESSAFTER)
 475
 476 # Random delay to wait before sa2 script runs
 477 AC_MSG_CHECKING(random delay to wait before sa2 script runs)
 478 AC_ARG_VAR([delay_range],[maximum delay (in seconds) to wait before sa2 script generates its reports])
 479 if test x$delay_range = x""; then
 480    DELAY_RANGE=0
 481 else
 482    DELAY_RANGE=$delay_range
 483 fi
 484 AC_MSG_RESULT($DELAY_RANGE)
 485 AC_SUBST(DELAY_RANGE)
 486
 487 # Manual page group
 488 grep ^man: /etc/group >/dev/null 2>&1
 489 if test $? = 0; then
 490    GRP=man
 491 else
 492    GRP=root
 493 fi
 494
 495 AC_MSG_CHECKING(group for manual pages)
 496 AC_ARG_VAR([man_group],[group for manual pages])
 497 if test x$man_group = x""; then
 498    MAN_GROUP=$GRP
 499    AC_MSG_RESULT($MAN_GROUP)
 500 else
 501    grep ^$man_group: /etc/group >/dev/null 2>&1
 502    if test $? = 1; then
 503       MAN_GROUP=$GRP
 504       AC_MSG_RESULT($MAN_GROUP)
 505       echo "WARNING: Group ${man_group} not found: Using ${GRP} instead"
 506    else
 507       MAN_GROUP=$man_group
 508       AC_MSG_RESULT($MAN_GROUP)
 509    fi
 510 fi
 511 AC_SUBST(MAN_GROUP)
 512
 513 # Don't set attributes on files being installed?
 514 AC_MSG_CHECKING(whether attributes should not be set on files being installed)
 515 AC_ARG_ENABLE(file-attr,
 516               AC_HELP_STRING([--disable-file-attr],
 517                              [do not set attributes on files being installed]),
 518                              AUX_IMG=$enableval,AUX_IMG=yes)
 519 if test $AUX_IMG != "no"; then
 520    IGNORE_FILE_ATTRIBUTES=n
 521    AUX_IMG=no
 522 else
 523    IGNORE_FILE_ATTRIBUTES=y
 524    AUX_IMG=yes
 525 fi
 526 AC_MSG_RESULT($AUX_IMG)
 527 AC_SUBST(IGNORE_FILE_ATTRIBUTES)
 528
 529 # Compress manual pages?
 530 AC_MSG_CHECKING(whether manual pages should be compressed)
 531 AC_ARG_ENABLE(compress-manpg,
 532               AC_HELP_STRING([--disable-compress-manpg],
 533                              [do not compress sysstat manual pages]),
 534                              AUX_MPG=$enableval,AUX_MPG=yes)
 535 if test $AUX_MPG != "yes"; then
 536    COMPRESS_MANPG=n
 537 else
 538    COMPRESS_MANPG=y
 539 fi
 540 AC_MSG_RESULT($AUX_MPG)
 541 AC_SUBST(COMPRESS_MANPG)
 542
 543 # Check whether sa directory should be cleaned
 544 AC_MSG_CHECKING(whether system activity directory should be cleaned)
 545 AC_ARG_ENABLE(clean-sa-dir,
 546               AC_HELP_STRING([--enable-clean-sa-dir],
 547                              [clean system activity directory]),
 548                             AUX_CSD=$enableval,AUX_CSD=no)
 549 if test $AUX_CSD != "yes"; then
 550    CLEAN_SA_DIR=n
 551    AUX_CSD=no
 552 else
 553    CLEAN_SA_DIR=y
 554 fi
 555 AC_MSG_RESULT($AUX_CSD)
 556 AC_SUBST(CLEAN_SA_DIR)
 557
 558 # Start crontab
 559 AC_MSG_CHECKING(whether cron should start sar automatically)
 560 AC_ARG_ENABLE(install-cron,
 561               AC_HELP_STRING([--enable-install-cron],
 562                              [install a crontab to start sar]),
 563                              INSTALL_CRON=$enableval,INSTALL_CRON=n)
 564 if test $INSTALL_CRON != "yes"; then
 565    INSTALL_CRON=n
 566    AUX_CRON=no
 567 else
 568    INSTALL_CRON=y
 569    AUX_CRON=yes
 570 fi
 571 AC_MSG_RESULT($AUX_CRON)
 572 AC_SUBST(INSTALL_CRON)
 573
 574 # Crontab owner
 575 CUSR="root"
 576 if test $INSTALL_CRON = "y"; then
 577    AC_MSG_CHECKING(crontab owner)
 578    AC_ARG_VAR([cron_owner],[crontab owner])
 579    if test x$cron_owner = x""; then
 580       CRON_OWNER=$CUSR
 581       AC_MSG_RESULT($CRON_OWNER)
 582    else
 583       grep ^$cron_owner: /etc/passwd >/dev/null 2>&1
 584       if test $? = 1; then
 585          CRON_OWNER=$CUSR;
 586          AC_MSG_RESULT($CRON_OWNER)
 587          echo "WARNING: User ${cron_owner} not found: Using ${CUSR} instead."
 588       else
 589          CRON_OWNER=$cron_owner
 590          AC_MSG_RESULT($CRON_OWNER)
 591       fi
 592    fi
 593    echo "INFO: Crontab for ${CRON_OWNER} will be saved in current directory if necessary"
 594    if test $CRON_OWNER = "root"; then
 595       SU_C_OWNER=""
 596       QUOTE=""
 597       REM_CHOWN="# REM_CHOWN"
 598    else
 599       SU_C_OWNER="su $CRON_OWNER -c "
 600       QUOTE=\"
 601       # " (ignore this line)
 602       REM_CHOWN=$CHOWN
 603    fi
 604
 605 #  Check whether we should use the standard cron daemon
 606    AC_MSG_CHECKING(whether we should use the standard cron daemon)
 607    AC_ARG_ENABLE(use-crond,
 608                  AC_HELP_STRING([--enable-use-crond],
 609                                 [use standard cron daemon]),
 610                                 UCROND=$enableval,UCROND=no)
 611    if test $UCROND != "yes"; then
 612       USE_CROND=n
 613       UCROND=no
 614    else
 615       USE_CROND=y
 616    fi
 617    AC_MSG_RESULT($UCROND)
 618    AC_SUBST(USE_CROND)
 619
 620 #  Crontab interval
 621    AC_MSG_CHECKING(crontab interval)
 622    AC_ARG_VAR([cron_interval],[crontab interval])
 623    if test x$cron_interval = x""; then
 624       CRON_INTERVAL=10
 625    else
 626       CRON_INTERVAL=$cron_interval
 627    fi
 628    AC_MSG_RESULT($CRON_INTERVAL)
 629    CRON_INTERVAL_SEC=`expr ${CRON_INTERVAL} \* 60`
 630    CRON_COUNT=`expr 60 / ${CRON_INTERVAL}`
 631
 632 #  Check whether sadc should collect all possible activities
 633    AC_MSG_CHECKING(whether sadc should collect all possible activities)
 634    AC_ARG_ENABLE(collect-all,
 635                  AC_HELP_STRING([--enable-collect-all],
 636                                 [collect all possible activities]),
 637                                 COLLECT_ALL=$enableval,COLLECT_ALL=n)
 638    if test $COLLECT_ALL != "yes"; then
 639       COLLECT_ALL=""
 640       AUX_COLL=no
 641    else
 642       COLLECT_ALL="-S XALL"
 643       AUX_COLL=yes
 644    fi
 645    AC_MSG_RESULT($AUX_COLL)
 646
 647    AC_MSG_CHECKING(options to be passed to sadc)
 648    AC_ARG_VAR([sadc_options],[options to be passed to sadc])
 649    if test x"$sadc_options" != x""; then
 650         SADC_OPT="$sadc_options"
 651    else
 652         SADC_OPT=
 653    fi
 654    AC_MSG_RESULT($SADC_OPT)
 655    AC_SUBST(SADC_OPT)
 656
 657 #  Check whether files should only be copied
 658    AC_MSG_CHECKING(whether files should only be copied)
 659    AC_ARG_ENABLE(copy-only,
 660                  AC_HELP_STRING([--enable-copy-only],
 661                                 [only copy files when installing]),
 662                                 OCOPY=$enableval,OCOPY=no)
 663    if test $OCOPY != "yes"; then
 664       COPY_ONLY=n
 665       OCOPY=no
 666    else
 667       COPY_ONLY=y
 668    fi
 669    AC_MSG_RESULT($OCOPY)
 670    AC_SUBST(COPY_ONLY)
 671
 672 else
 673    CRON_OWNER="root"
 674    SU_C_OWNER=""
 675    QUOTE=""
 676    REM_CHOWN="# REM_CHOWN"
 677    CRON_INTERVAL=10
 678    CRON_INTERVAL_SEC=600
 679    CRON_COUNT=6
 680    COLLECT_ALL=""
 681 fi
 682 AC_SUBST(CRON_OWNER)
 683 AC_SUBST(SU_C_OWNER)
 684 AC_SUBST(CRON_INTERVAL)
 685 AC_SUBST(CRON_INTERVAL_SEC)
 686 AC_SUBST(CRON_COUNT)
 687 AC_SUBST(QUOTE)
 688 AC_SUBST(REM_CHOWN)
 689 AC_SUBST(COLLECT_ALL)
 690
 691 # Check whether documentation should be installed
 692 AC_MSG_CHECKING(whether documentation should be installed)
 693 AC_ARG_ENABLE(documentation,
 694               AC_HELP_STRING([--disable-documentation],
 695                              [do not install documentation]),
 696                              AUX_DOC=$enableval,AUX_DOC=yes)
 697 if test $AUX_DOC != "no"; then
 698    AUX_DOC="yes"
 699    INSTALL_DOC="y"
 700 else
 701    AUX_DOC="no"
 702    INSTALL_DOC="n"
 703 fi
 704 AC_MSG_RESULT($AUX_DOC)
 705 AC_SUBST(INSTALL_DOC)
 706
 707 # Set directory for installing manual pages (see comment in Makefile)
 708 AC_SUBST(mandir)
 709
 710 # Check whether debug mode should be activated
 711 AC_MSG_CHECKING(whether debug mode should be activated)
 712 AC_ARG_ENABLE(debuginfo,
 713               AC_HELP_STRING([--enable-debuginfo],
 714                              [enable debug output (--debuginfo option)]),
 715                              WITH_DEBUG=yes ; DFLAGS="$DFLAGS -DDEBUG" , WITH_DEBUG=no)
 716 AC_MSG_RESULT($WITH_DEBUG)
 717 AC_SUBST(DFLAGS)
 718 AC_SUBST(WITH_DEBUG)
 719
 720 # Check whether object files should be stripped
 721 AC_MSG_CHECKING(whether object files should be stripped)
 722 AC_ARG_ENABLE(stripping,
 723               AC_HELP_STRING([--disable-stripping],
 724                              [do not strip object files]),
 725                              AUX_STRIP=$enableval,AUX_STRIP=yes)
 726 if test $AUX_STRIP != "no"; then
 727    AUX_STRIP="yes"
 728    STRIP="-s"
 729 else
 730    AUX_STRIP="no"
 731    STRIP=
 732 fi
 733 AC_MSG_RESULT($AUX_STRIP)
 734 AC_SUBST(STRIP)
 735
 736 # Create files
 737 echo .
 738 echo Now create files:
 739 echo .
 740 AC_CONFIG_FILES([sa1], [chmod +x sa1])          # Permissions must be changed
 741 AC_CONFIG_FILES([sa2], [chmod +x sa2])          # Permissions must be changed
 742 AC_CONFIG_FILES([cron/crontab:cron/crontab.sample])     # File must be renamed
 743 AC_CONFIG_FILES([sysstat.sysconfig])
 744 AC_CONFIG_FILES([version.h:version.in])         # File must be renamed
 745 AC_CONFIG_FILES([sysconfig.h:sysconfig.in])     # File must be renamed
 746 AC_CONFIG_FILES([cron/sysstat.cron.daily])
 747 AC_CONFIG_FILES([cron/sysstat.cron.hourly])
 748 AC_CONFIG_FILES([cron/sysstat.crond])
 749 AC_CONFIG_FILES([cron/sysstat.crond.sample.in:cron/sysstat.crond.in], [sed s/^/#/ cron/sysstat.crond.sample.in > cron/sysstat.crond.sample])
 750 AC_CONFIG_FILES([sysstat], [chmod +x sysstat])  # Permissions must be changed
 751 AC_CONFIG_FILES([sysstat.service])
 752 AC_CONFIG_FILES([cron/sysstat-collect.service])
 753 AC_CONFIG_FILES([cron/sysstat-collect.timer])
 754 AC_CONFIG_FILES([cron/sysstat-summary.service])
 755 AC_CONFIG_FILES([cron/sysstat-summary.timer])
 756 AC_CONFIG_FILES([cron/sysstat.sleep], [chmod +x cron/sysstat.sleep])    # Permissions must be changed
 757 AC_CONFIG_FILES([man/sa1.8:man/sa1.in])         # File must be renamed
 758 AC_CONFIG_FILES([man/sa2.8:man/sa2.in])         # File must be renamed
 759 AC_CONFIG_FILES([man/sadc.8:man/sadc.in])       # File must be renamed
 760 AC_CONFIG_FILES([man/sadf.1:man/sadf.in])       # File must be renamed
 761 AC_CONFIG_FILES([man/sar.1:man/sar.in])         # File must be renamed
 762 AC_CONFIG_FILES([man/sysstat.5:man/sysstat.in]) # File must be renamed
 763 AC_CONFIG_FILES([man/iostat.1:man/iostat.in])   # File must be renamed
 764 AC_CONFIG_FILES([man/cifsiostat.1:man/cifsiostat.in])   # File must be renamed
 765 AC_CONFIG_FILES([tests/variables])
 766
 767 AC_OUTPUT(Makefile)
 768
 769 echo "
 770    Sysstat version:             $PACKAGE_VERSION
 771    Installation prefix:         $prefix
 772    rc directory:                ${RC_DIR}
 773    Init directory:              ${INIT_DIR}"
 774 if test "$UCROND" != "yes"; then
 775    echo "   Systemd unit dir:           ${with_systemdsystemunitdir}"
 776    echo "   Systemd sleep dir:          ${with_systemdsleepdir}"
 777 else
 778    echo "   Use standard cron daemon"
 779 fi
 780 echo "   Configuration file:            ${SYSCONFIG_DIR}/${SYSCONFIG_FILE}
 781    Man pages directory:         $mandir
 782    Compiler:                    $CC
 783    Compiler flags:              $CFLAGS
 784 "