granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, "1 2")
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="$srcdir/srclib/apr/apr-${majorver}-config"
  97     if test -f $test_apr_config; then
  98       apr_config=$test_apr_config
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x${apr_major_version}" = "x2"; then
 119    apu_found=obsolete
 120 elif test "x$with_included_apr" = "xyes"; then
 121    apu_found=reconfig
 122 else
 123    APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1, ${apr_major_version})
 124 fi
 125
 126 if test "$apu_found" = "no"; then
 127   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 128 fi
 129
 130 # Catch some misconfigurations:
 131 case ${apr_found}.${apu_found} in
 132 reconfig.yes)
 133   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 134   ;;
 135 yes.reconfig)
 136   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 137   ;;
 138 esac
 139
 140 if test "$apu_found" = "reconfig"; then
 141   APR_SUBDIR_CONFIG(srclib/apr-util,
 142                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 143                     [--enable-layout=*|\'--enable-layout=*])
 144   dnl We must be the last to build and the first to be cleaned
 145   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 146   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 147   dnl APR and APR-Util major versions must match
 148   apu_config="${srcdir}/srclib/apr-util/apu-${apr_major_version}-config"
 149 fi
 150
 151 if test "$apu_found" = "obsolete"; then
 152   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 153 else
 154   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 155   APU_BINDIR=`$apu_config --bindir`
 156   APU_INCLUDEDIR=`$apu_config --includedir`
 157   APU_INCLUDES=`$apu_config --includes`
 158   APU_VERSION=`$apu_config --version`
 159   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 160 fi
 161
 162 dnl In case we picked up CC and CPP from APR, get that info into the
 163 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 164 dnl PCRE and for our config tests will be whatever PCRE determines.
 165 AC_PROG_CC
 166 AC_PROG_CPP
 167
 168 if test "x${cache_file}" = "x/dev/null"; then
 169   # Likewise, ensure that CC and CPP are passed through to the pcre
 170   # configure script iff caching is disabled (the autoconf 2.5x default).
 171   export CC; export CPP
 172 fi
 173
 174 dnl Absolute source/build directory
 175 abs_srcdir=`(cd $srcdir && pwd)`
 176 abs_builddir=`pwd`
 177
 178 AC_ARG_WITH(pcre,
 179 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 180
 181 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 182 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 183    PCRE_CONFIG=$with_pcre/bin/pcre-config
 184 elif test -x "$with_pcre"; then
 185    PCRE_CONFIG=$with_pcre
 186 fi
 187
 188 if test "$PCRE_CONFIG" != "false"; then
 189   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 190     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 191   fi
 192   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 193   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 194   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 195 else
 196   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 197 fi
 198 APACHE_SUBST(PCRE_LIBS)
 199
 200 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 201 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 202
 203 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 204
 205 dnl If the source dir is not equal to the build dir,
 206 dnl then we are running in VPATH mode.
 207
 208 APR_ADDTO(INCLUDES, [-I.])
 209
 210 if test "$abs_builddir" != "$abs_srcdir"; then
 211   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 212 fi
 213
 214 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/aaa -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/modules/session -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators -I\$(top_srcdir)/modules/mappers -I\$(top_srcdir)/modules/database])
 215
 216 # apr/apr-util --includes may pick up system paths for dependent
 217 # libraries, so ensure these are later in INCLUDES than local source
 218 # directories.
 219 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 220 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 221
 222 dnl Add in path to PCRE includes
 223 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 224
 225 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 226
 227 case $host in
 228   *os2*)
 229       # Use a custom made libtool replacement
 230       echo "using aplibtool"
 231       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 232       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 233       SH_LIBS="\$(ALL_LIBS)"
 234       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 235       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 236       MK_IMPLIB="emximp"
 237       other_targets="$other_targets os2core"
 238       INSTALL_PROG_FLAGS="-e .exe"
 239       SHLTCFLAGS=""
 240       LTCFLAGS=""
 241       ;;
 242   *)
 243       if test "x$LTFLAGS" = "x"; then
 244           LTFLAGS='--silent'
 245       fi
 246       my_libtool=`$apr_config --apr-libtool`
 247       LIBTOOL="$my_libtool \$(LTFLAGS)"
 248       libtoolversion=`$my_libtool --version`
 249       case $libtoolversion in
 250           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 251               SH_LIBTOOL='$(LIBTOOL)'
 252               SHLTCFLAGS="-prefer-pic"
 253               LTCFLAGS="-prefer-non-pic -static"
 254               ;;
 255           *)
 256               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 257               SHLTCFLAGS=""
 258               LTCFLAGS=""
 259               ;;
 260       esac
 261       ;;
 262 esac
 263 APACHE_SUBST(SHLTCFLAGS)
 264 APACHE_SUBST(LTCFLAGS)
 265
 266 case $host in
 267   *-apple-aux3*)
 268       APR_SETVAR(APACHE_MPM, [prefork])
 269       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 270       ;;
 271   *-beos*)
 272       APR_SETVAR(APACHE_MPM, [beos])
 273       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 274       ;;
 275   *os2-emx*)
 276       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 277       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 278       ;;
 279   *-linux-*)
 280       case `uname -r` in
 281         2.[[2-9]]* )
 282             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 283             ;;
 284         * )
 285             ;;
 286       esac
 287       ;;
 288   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 289       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 290       ;;
 291   *-solaris2*)
 292       dnl This is a hack -- we should be using AC_TRY_RUN instead
 293       ap_platform_runtime_link_flag="-R"
 294       dnl solaris 8 and above don't have a thundering herd
 295       dnl not sure about rev's before this one.
 296       case `uname -r` in
 297         5.[567]*)
 298             ;;
 299         * )
 300             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 301             ;;
 302       esac
 303       ;;
 304   *cygwin*)
 305       APR_SETVAR(APACHE_MPM, [prefork])
 306       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 307       ;;
 308   *mingw32*)
 309       APR_SETVAR(APACHE_MPM, [winnt])
 310       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 311       APR_SETIFNULL(ac_cv_func_times, [no])
 312       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 313       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 314       ;;
 315   *aix*)
 316       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 317       if test $aixver -ge 4320; then
 318         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 319       fi
 320       ;;
 321   *os390*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324 esac
 325
 326 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 327
 328 dnl
 329 dnl Process command line arguments. This is done early in the process so the
 330 dnl user can get feedback quickly in case of an error.
 331 dnl
 332 dnl ### need to move some of the arguments "up here"
 333
 334 dnl ## Check for programs
 335
 336 AC_PATH_PROG(RM, rm)
 337 AC_PATH_PROG(PKGCONFIG, pkg-config)
 338 AC_PATH_PROG(RSYNC, rsync)
 339 AC_PROG_AWK
 340 AC_PROG_LN_S
 341 AC_CHECK_TOOL(RANLIB, ranlib, true)
 342 dnl AC_PATH_PROG(PERL_PATH, perl)
 343 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 344
 345 # Hard-coded install programs
 346 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 347 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 348 APACHE_SUBST(MKINSTALLDIRS)
 349 APACHE_SUBST(INSTALL)
 350
 351 dnl Various OS checks that apparently set required flags
 352 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 353 AC_USE_SYSTEM_EXTENSIONS
 354 ], [
 355 AC_AIX
 356 AC_MINIX
 357 ])
 358
 359 AC_ISC_POSIX
 360
 361 # Ensure that satisfactory versions of apr and apr-util are
 362 # found if external copies are configured.
 363 if test "${apr_found}" = "yes"; then
 364   # Require at least APR 1.3.x otherwise fail
 365   APACHE_CHECK_APxVER([apr], 1, 3)
 366 fi
 367
 368 if test "${apu_found}" = "yes"; then
 369   # Require at least APR-util 1.3.x otherwise fail
 370   APACHE_CHECK_APxVER([apu], 1, 3)
 371 fi
 372
 373 dnl Check for what we can generate dependency files with
 374 APR_CHECK_DEPEND
 375
 376 dnl ## Check for libraries
 377
 378 dnl ## Check for header files
 379
 380 dnl I think these are just used all over the place, so just check for
 381 dnl them at the base of the tree. If some are specific to a single
 382 dnl directory, they should be moved (Comment #Spoon)
 383
 384 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 385 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 386 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 387
 388 AC_HEADER_STDC
 389 AC_CHECK_HEADERS( \
 390 string.h \
 391 limits.h \
 392 unistd.h \
 393 sys/socket.h \
 394 pwd.h \
 395 grp.h \
 396 strings.h \
 397 sys/prctl.h \
 398 sys/processor.h \
 399 sys/sem.h \
 400 sys/sdt.h
 401 )
 402 AC_HEADER_SYS_WAIT
 403
 404 dnl ## Check for typedefs, structures, and compiler characteristics.
 405
 406 AC_C_CONST
 407
 408 dnl ## Check for library functions
 409 dnl ## sqrt() only needed in support/ab.c
 410 saved_LIBS="$LIBS"
 411 LIBS=""
 412 AC_SEARCH_LIBS(sqrt, m)
 413 MATH_LIBS="$LIBS"
 414 APACHE_SUBST(MATH_LIBS)
 415 LIBS="$saved_LIBS"
 416
 417 dnl See Comment #Spoon
 418
 419 AC_CHECK_FUNCS( \
 420 getpwnam \
 421 getgrnam \
 422 initgroups \
 423 bindprocessor \
 424 prctl \
 425 timegm \
 426 getpgid
 427 )
 428
 429 dnl confirm that a void pointer is large enough to store a long integer
 430 APACHE_CHECK_VOID_PTR_LEN
 431
 432 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 433 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 434 [AC_TRY_COMPILE([#include <sys/types.h>
 435 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 436   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 437 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 438     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 439 fi
 440
 441 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 442
 443 case $host in
 444     *aix*)
 445         # for 32-bit builds, increase MAXDATA to allow lots of threads
 446         if test x$OBJECT_MODE != x64; then
 447             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 448         fi
 449         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 450         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 451         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 452         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 453         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 454         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 455         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 456         ;;
 457     *os390*)
 458         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 459         ;;
 460     *)
 461         OS_SPECIFIC_VARS=""
 462 esac
 463
 464 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 465         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 466         [PORT=80])
 467
 468 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 469         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 470         [SSLPORT=443])
 471
 472 DTRACE=true
 473 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 474 [
 475   enable_dtrace=$enableval
 476   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 477   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 478 ],
 479 [
 480   enable_dtrace=no
 481 ])
 482
 483 dnl Disabled dtrace build for now.
 484 enable_dtrace=no
 485
 486 case $host in
 487   *-solaris2*)
 488     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 489         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 490                   [Enable DTrace probes])
 491         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 492         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 493     fi
 494     ;;
 495 esac
 496
 497 APACHE_SUBST(DTRACE)
 498
 499 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 500
 501 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 502 [
 503   v4mapped=$enableval
 504 ],
 505 [
 506     case $host in
 507     *freebsd5*|*netbsd*|*openbsd*)
 508         v4mapped=no
 509         ;;
 510     *)
 511         v4mapped=yes
 512         ;;
 513 esac
 514 ])
 515
 516 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 517     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 518               [Allow IPv4 connections on IPv6 listening sockets])
 519 fi
 520
 521 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 522 [
 523     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 524               [Allow modules to run hook after a fatal exception])
 525 ])dnl
 526
 527 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 528 [
 529   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 530 ])dnl
 531
 532 dnl Conditionally enable PIE support for GNU toolchains.
 533 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 534 if test "$enable_pie" = "yes"; then
 535    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 536      save_CFLAGS=$CFLAGS
 537      save_LDFLAGS=$LDFLAGS
 538      CFLAGS="$CFLAGS -fPIE"
 539      LDFLAGS="$LDFLAGS -pie"
 540      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 541       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 542      CFLAGS=$save_CFLAGS
 543      LDFLAGS=$save_LDFLAGS
 544    ])
 545    if test "$ap_cv_cc_pie" = "yes"; then
 546      PICFLAGS="-fPIE"
 547      PILDFLAGS="-pie"
 548    else
 549      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 550    fi
 551 fi
 552 AC_SUBST(PICFLAGS)
 553 AC_SUBST(PILDFLAGS)
 554
 555 prefix="$orig_prefix"
 556 APACHE_ENABLE_MODULES
 557
 558 dnl reading config stubs
 559 esyscmd(./build/config-stubs .)
 560
 561 APACHE_SUBST(progname)
 562 APACHE_SUBST(MPM_LIB)
 563 APACHE_SUBST(OS)
 564 APACHE_SUBST(OS_DIR)
 565 APACHE_SUBST(BUILTIN_LIBS)
 566 APACHE_SUBST(SHLIBPATH_VAR)
 567 APACHE_SUBST(OS_SPECIFIC_VARS)
 568
 569 PRE_SHARED_CMDS='echo ""'
 570 POST_SHARED_CMDS='echo ""'
 571
 572 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 573
 574 if test "$apache_need_shared" = "yes"; then
 575   if test -f $ac_aux_dir/ltconfig; then
 576     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 577   fi
 578   shared_build="shared-build"
 579 fi
 580
 581 dnl enable_so tells us if *any* modules can be built as DSOs
 582
 583 if test "$enable_so" = "yes"; then
 584   case $host in
 585     *-ibm-aix*)
 586       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 587       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 588       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 589       ;;
 590     *beos)
 591       SH_LDFLAGS='$(top_builddir)/_APP_'
 592       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 593       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 594       ;;
 595     *os390)
 596       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 597       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 598   esac
 599   MOD_SO_ENABLED=yes
 600 fi
 601 AC_SUBST(MOD_SO_ENABLED)
 602
 603 APACHE_SUBST(PRE_SHARED_CMDS)
 604 APACHE_SUBST(POST_SHARED_CMDS)
 605 APACHE_SUBST(shared_build)
 606
 607 AC_ARG_WITH(program-name,
 608 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 609   progname="$withval" ], [
 610   progname="httpd"] )
 611
 612 # SuExec parameters
 613 AC_ARG_WITH(suexec-bin,
 614 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 615   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 616 ] )
 617
 618 AC_ARG_WITH(suexec-caller,
 619 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 620   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 621
 622 AC_ARG_WITH(suexec-userdir,
 623 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 624   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 625
 626 AC_ARG_WITH(suexec-docroot,
 627 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 628   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 629
 630 AC_ARG_WITH(suexec-uidmin,
 631 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 632   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 633
 634 AC_ARG_WITH(suexec-gidmin,
 635 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 636   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 637
 638 AC_ARG_WITH(suexec-logfile,
 639 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 640   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 641
 642 AC_ARG_WITH(suexec-safepath,
 643 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 644   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 645
 646 AC_ARG_WITH(suexec-umask,
 647 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 648   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 649
 650 dnl APR should go after the other libs, so the right symbols can be picked up
 651 if test x${apu_found} != xobsolete; then
 652   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 653 fi
 654 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 655 APACHE_SUBST(AP_LIBS)
 656 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 657 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 658
 659 AC_DEFINE(AP_USING_AUTOCONF, 1,
 660                 [Using autoconf to configure Apache])
 661
 662 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 663     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 664               [This platform doesn't suffer from the thundering herd problem])
 665 fi
 666
 667 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 668     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 669               [Listening sockets are non-blocking when there are more than 1])
 670 fi
 671
 672
 673 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 674 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 675 APACHE_FAST_OUTPUT(support/Makefile)
 676
 677 if test -d ./test; then
 678     APACHE_FAST_OUTPUT(test/Makefile)
 679 fi
 680
 681 dnl ## Finalize the variables
 682 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 683
 684 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 685 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 686 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 687 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 688 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 689 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 690
 691 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 692
 693 APACHE_GEN_CONFIG_VARS
 694
 695 dnl ## Build modules.c
 696 rm -f modules.c
 697 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 698
 699 APR_EXPAND_VAR(ap_prefix, $prefix)
 700 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 701         [Root directory of the Apache install area])
 702 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 703         [Location of the config file, relative to the Apache root directory])
 704 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 705         [Location of the MIME types config file, relative to the Apache root directory])
 706 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 707         [Location of the source for the current MPM])
 708
 709 perlbin=`$ac_aux_dir/PrintPath perl`
 710 if test "x$perlbin" = "x"; then
 711     perlbin="/replace/with/path/to/perl/interpreter"
 712 fi
 713 AC_SUBST(perlbin)
 714
 715 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 716
 717 BSD_MAKEFILE=no
 718 ap_make_include=include
 719 ap_make_delimiter=' '
 720 case $host in
 721 *bsdi*)
 722     # Check whether they've installed GNU make
 723     if make --version > /dev/null 2>&1; then
 724         true
 725     else
 726         BSD_MAKEFILE=yes
 727         ap_make_include=.include
 728         ap_make_delimiter='"'
 729     fi
 730     ;;
 731 esac
 732 AC_SUBST(ap_make_include)
 733 AC_SUBST(ap_make_delimiter)
 734
 735 dnl Ensure that docs/conf is created.
 736 test -d docs/conf||$mkdir_p docs/conf
 737
 738 dnl Ensure that the httpd version is included
 739 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 740 AC_SUBST(HTTPD_VERSION)
 741
 742 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 743   APACHE_GEN_MAKEFILES
 744 ])
 745
 746 case $MPM_SUBDIR_NAME in
 747 *experimental*)
 748     echo ""
 749     echo ""
 750     echo "============================================================"
 751     echo "    WARNING: THE '${APACHE_MPM}' MPM IS EXPERIMENTAL"
 752     echo "============================================================"
 753     echo " The selected MPM might not be fully functional!"
 754     echo ""
 755     echo " Development of this MPM is not complete. Do not use this"
 756     echo " MPM unless you are a programmer willing to help fix it."
 757     echo ""
 758     echo " If you are looking for a stable server, you should not use"
 759     echo " the '${APACHE_MPM}' MPM until it is moved out of experimental."
 760     echo "============================================================"
 761     echo ""
 762     echo ""
 763     ;;
 764 esac