granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [10beta1], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2017, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [AC_CHECK_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 AC_CHECK_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 AC_CHECK_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [AC_CHECK_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # WAL segment size
 348 #
 349 AC_MSG_CHECKING([for WAL segment size])
 350 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 351              [wal_segsize=$withval],
 352              [wal_segsize=16])
 353 case ${wal_segsize} in
 354   1) ;;
 355   2) ;;
 356   4) ;;
 357   8) ;;
 358  16) ;;
 359  32) ;;
 360  64) ;;
 361  128) ;;
 362  256) ;;
 363  512) ;;
 364  1024) ;;
 365   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64,128,256,512,1024.])
 366 esac
 367 AC_MSG_RESULT([${wal_segsize}MB])
 368
 369 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 370  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 371  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 372  XLOG_BLCKSZ).
 373
 374  Changing XLOG_SEG_SIZE requires an initdb.
 375 ])
 376
 377 #
 378 # C compiler
 379 #
 380
 381 # For historical reasons you can also use --with-CC to specify the C compiler
 382 # to use, although the standard way to do this is to set the CC environment
 383 # variable.
 384 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 385
 386 case $template in
 387   aix) pgac_cc_list="gcc xlc";;
 388     *) pgac_cc_list="gcc cc";;
 389 esac
 390
 391 AC_PROG_CC([$pgac_cc_list])
 392
 393 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 394 # but has idiosyncrasies of its own.  We assume icc will define
 395 # __INTEL_COMPILER regardless of CFLAGS.
 396 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 397 choke me
 398 @%:@endif])], [ICC=yes], [ICC=no])
 399
 400 # Check if it's Sun Studio compiler. We assume that
 401 # __SUNPRO_C will be defined for Sun Studio compilers
 402 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 403 choke me
 404 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 405
 406 AC_SUBST(SUN_STUDIO_CC)
 407
 408 unset CFLAGS
 409
 410 #
 411 # Read the template
 412 #
 413 . "$srcdir/src/template/$template" || exit
 414
 415 # CFLAGS are selected so:
 416 # If the user specifies something in the environment, that is used.
 417 # else:  If the template file set something, that is used.
 418 # else:  If coverage was enabled, don't set anything.
 419 # else:  If the compiler is GCC, then we use -O2.
 420 # else:  If the compiler is something else, then we use -O, unless debugging.
 421
 422 if test "$ac_env_CFLAGS_set" = set; then
 423   CFLAGS=$ac_env_CFLAGS_value
 424 elif test "${CFLAGS+set}" = set; then
 425   : # (keep what template set)
 426 elif test "$enable_coverage" = yes; then
 427   : # no optimization by default
 428 elif test "$GCC" = yes; then
 429   CFLAGS="-O2"
 430 else
 431   # if the user selected debug mode, don't use -O
 432   if test "$enable_debug" != yes; then
 433     CFLAGS="-O"
 434   fi
 435 fi
 436
 437 # CFLAGS we determined above will be added back at the end
 438 user_CFLAGS=$CFLAGS
 439 CFLAGS=""
 440
 441 # set CFLAGS_VECTOR from the environment, if available
 442 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 443   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 444 fi
 445
 446 # Some versions of GCC support some additional useful warning flags.
 447 # Check whether they are supported, and add them to CFLAGS if so.
 448 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 449 # but has its own.  Also check other compiler-specific flags here.
 450
 451 if test "$GCC" = yes -a "$ICC" = no; then
 452   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 453   # These work in some but not all gcc versions
 454   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 455   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 456   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 457   # This was included in -Wall/-Wformat in older GCC versions
 458   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 459   # Disable strict-aliasing rules; needed for gcc 3.3+
 460   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 461   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 462   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 463   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 464   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 465   # Optimization flags for specific files that benefit from vectorization
 466   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 467   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 468   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 469   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 470   # test for the positive form and if that works, add the negative form
 471   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 472   if test -n "$NOT_THE_CFLAGS"; then
 473     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 474   fi
 475 elif test "$ICC" = yes; then
 476   # Intel's compiler has a bug/misoptimization in checking for
 477   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 478   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 479   # Make sure strict aliasing is off (though this is said to be the default)
 480   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 481 elif test "$PORTNAME" = "aix"; then
 482   # AIX's xlc has to have strict aliasing turned off too
 483   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 484   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 485 elif test "$PORTNAME" = "hpux"; then
 486   # On some versions of HP-UX, libm functions do not set errno by default.
 487   # Fix that by using +Olibmerrno if the compiler recognizes it.
 488   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 489 fi
 490
 491 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 492
 493 # supply -g if --enable-debug
 494 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 495   CFLAGS="$CFLAGS -g"
 496 fi
 497
 498 # enable code coverage if --enable-coverage
 499 if test "$enable_coverage" = yes; then
 500   if test "$GCC" = yes; then
 501     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 502   else
 503     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 504   fi
 505 fi
 506
 507 # enable profiling if --enable-profiling
 508 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 509   if test "$GCC" = yes; then
 510     AC_DEFINE([PROFILE_PID_DIR], 1,
 511            [Define to 1 to allow profiling output to be saved separately for each process.])
 512     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 513   else
 514     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 515   fi
 516 fi
 517
 518 # We already have this in Makefile.win32, but configure needs it too
 519 if test "$PORTNAME" = "win32"; then
 520   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 521 fi
 522
 523 # Now that we're done automatically adding stuff to CFLAGS, put back the
 524 # user-specified flags (if any) at the end.  This lets users override
 525 # the automatic additions.
 526 CFLAGS="$CFLAGS $user_CFLAGS"
 527
 528 # Check if the compiler still works with the final flag settings
 529 AC_MSG_CHECKING([whether the C compiler still works])
 530 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 531   [AC_MSG_RESULT(yes)],
 532   [AC_MSG_RESULT(no)
 533    AC_MSG_ERROR([cannot proceed])])
 534
 535 # Defend against gcc -ffast-math
 536 if test "$GCC" = yes; then
 537 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 538 choke me
 539 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 540 fi
 541
 542 AC_PROG_CPP
 543 AC_SUBST(GCC)
 544
 545
 546 #
 547 # Set up TAS assembly code if needed; the template file has now had its
 548 # chance to request this.
 549 #
 550 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 551
 552 if test "$need_tas" = yes ; then
 553   TAS=tas.o
 554 else
 555   TAS=""
 556 fi
 557 AC_SUBST(TAS)
 558
 559
 560 #
 561 # Automatic dependency tracking
 562 #
 563 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 564               [autodepend=yes])
 565 AC_SUBST(autodepend)
 566
 567
 568 #
 569 # Enable assert checks
 570 #
 571 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 572               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 573                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 574
 575
 576 #
 577 # Include directories
 578 #
 579 ac_save_IFS=$IFS
 580 IFS="${IFS}${PATH_SEPARATOR}"
 581 # SRCH_INC comes from the template file
 582 for dir in $with_includes $SRCH_INC; do
 583   if test -d "$dir"; then
 584     INCLUDES="$INCLUDES -I$dir"
 585   else
 586     AC_MSG_WARN([*** Include directory $dir does not exist.])
 587   fi
 588 done
 589 IFS=$ac_save_IFS
 590 AC_SUBST(INCLUDES)
 591
 592
 593 #
 594 # Library directories
 595 #
 596 ac_save_IFS=$IFS
 597 IFS="${IFS}${PATH_SEPARATOR}"
 598 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 599 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 600   if test -d "$dir"; then
 601     LIBDIRS="$LIBDIRS -L$dir"
 602   else
 603     AC_MSG_WARN([*** Library directory $dir does not exist.])
 604   fi
 605 done
 606 IFS=$ac_save_IFS
 607
 608 #
 609 # Enable thread-safe client libraries
 610 #
 611 AC_MSG_CHECKING([allow thread-safe client libraries])
 612 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 613 if test "$enable_thread_safety" = yes; then
 614   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 615           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 616 fi
 617 AC_MSG_RESULT([$enable_thread_safety])
 618 AC_SUBST(enable_thread_safety)
 619
 620 #
 621 # ICU
 622 #
 623 AC_MSG_CHECKING([whether to build with ICU support])
 624 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 625               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 626 AC_MSG_RESULT([$with_icu])
 627 AC_SUBST(with_icu)
 628
 629 if test "$with_icu" = yes; then
 630   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 631 fi
 632
 633 #
 634 # Optionally build Tcl modules (PL/Tcl)
 635 #
 636 AC_MSG_CHECKING([whether to build with Tcl])
 637 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 638 AC_MSG_RESULT([$with_tcl])
 639 AC_SUBST([with_tcl])
 640
 641 # We see if the path to the Tcl/Tk configuration scripts is specified.
 642 # This will override the use of tclsh to find the paths to search.
 643
 644 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 645
 646 #
 647 # Optionally build Perl modules (PL/Perl)
 648 #
 649 AC_MSG_CHECKING([whether to build Perl modules])
 650 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 651 AC_MSG_RESULT([$with_perl])
 652 AC_SUBST(with_perl)
 653
 654 #
 655 # Optionally build Python modules (PL/Python)
 656 #
 657 AC_MSG_CHECKING([whether to build Python modules])
 658 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 659 AC_MSG_RESULT([$with_python])
 660 AC_SUBST(with_python)
 661
 662 #
 663 # GSSAPI
 664 #
 665 AC_MSG_CHECKING([whether to build with GSSAPI support])
 666 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 667 [
 668   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 669   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 670 ])
 671 AC_MSG_RESULT([$with_gssapi])
 672
 673
 674 AC_SUBST(krb_srvtab)
 675
 676
 677 #
 678 # Kerberos configuration parameters
 679 #
 680 PGAC_ARG_REQ(with, krb-srvnam,
 681              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 682              [],
 683              [with_krb_srvnam="postgres"])
 684 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 685                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 686
 687
 688 #
 689 # PAM
 690 #
 691 AC_MSG_CHECKING([whether to build with PAM support])
 692 PGAC_ARG_BOOL(with, pam, no,
 693               [build with PAM support],
 694               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 695 AC_MSG_RESULT([$with_pam])
 696
 697
 698 #
 699 # BSD AUTH
 700 #
 701 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 702 PGAC_ARG_BOOL(with, bsd-auth, no,
 703               [build with BSD Authentication support],
 704               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 705 AC_MSG_RESULT([$with_bsd_auth])
 706
 707
 708 #
 709 # LDAP
 710 #
 711 AC_MSG_CHECKING([whether to build with LDAP support])
 712 PGAC_ARG_BOOL(with, ldap, no,
 713               [build with LDAP support],
 714               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 715 AC_MSG_RESULT([$with_ldap])
 716
 717
 718 #
 719 # Bonjour
 720 #
 721 AC_MSG_CHECKING([whether to build with Bonjour support])
 722 PGAC_ARG_BOOL(with, bonjour, no,
 723               [build with Bonjour support],
 724               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 725 AC_MSG_RESULT([$with_bonjour])
 726
 727
 728 #
 729 # OpenSSL
 730 #
 731 AC_MSG_CHECKING([whether to build with OpenSSL support])
 732 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 733               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 734 AC_MSG_RESULT([$with_openssl])
 735 AC_SUBST(with_openssl)
 736
 737 #
 738 # SELinux
 739 #
 740 AC_MSG_CHECKING([whether to build with SELinux support])
 741 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 742 AC_SUBST(with_selinux)
 743 AC_MSG_RESULT([$with_selinux])
 744
 745 #
 746 # Systemd
 747 #
 748 AC_MSG_CHECKING([whether to build with systemd support])
 749 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 750               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 751 AC_SUBST(with_systemd)
 752 AC_MSG_RESULT([$with_systemd])
 753
 754 #
 755 # Readline
 756 #
 757 PGAC_ARG_BOOL(with, readline, yes,
 758               [do not use GNU Readline nor BSD Libedit for editing])
 759 # readline on MinGW has problems with backslashes in psql and other bugs.
 760 # This is particularly a problem with non-US code pages.
 761 # Therefore disable its use until we understand the cause. 2004-07-20
 762 if test "$PORTNAME" = "win32"; then
 763   if test "$with_readline" = yes; then
 764     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 765     with_readline=no
 766   fi
 767 fi
 768
 769
 770 #
 771 # Prefer libedit
 772 #
 773 PGAC_ARG_BOOL(with, libedit-preferred, no,
 774               [prefer BSD Libedit over GNU Readline])
 775
 776
 777 #
 778 # UUID library
 779 #
 780 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 781 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 782 # UUID library.  More than one of these might be present on a given platform,
 783 # so we make the user say which one she wants.
 784 #
 785 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 786 if test x"$with_uuid" = x"" ; then
 787   with_uuid=no
 788 fi
 789 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 790 if test "$with_ossp_uuid" = yes ; then
 791   with_uuid=ossp
 792 fi
 793
 794 if test "$with_uuid" = bsd ; then
 795   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 796   UUID_EXTRA_OBJS="md5.o sha1.o"
 797 elif test "$with_uuid" = e2fs ; then
 798   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 799   UUID_EXTRA_OBJS="md5.o sha1.o"
 800 elif test "$with_uuid" = ossp ; then
 801   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 802   UUID_EXTRA_OBJS=""
 803 elif test "$with_uuid" = no ; then
 804   UUID_EXTRA_OBJS=""
 805 else
 806   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 807 fi
 808 AC_SUBST(with_uuid)
 809 AC_SUBST(UUID_EXTRA_OBJS)
 810
 811
 812 #
 813 # XML
 814 #
 815 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 816               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 817
 818 if test "$with_libxml" = yes ; then
 819   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 820   if test -n "$XML2_CONFIG"; then
 821     for pgac_option in `$XML2_CONFIG --cflags`; do
 822       case $pgac_option in
 823         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 824       esac
 825     done
 826     for pgac_option in `$XML2_CONFIG --libs`; do
 827       case $pgac_option in
 828         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 829       esac
 830     done
 831   fi
 832 fi
 833
 834 AC_SUBST(with_libxml)
 835
 836 #
 837 # XSLT
 838 #
 839 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 840               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 841
 842
 843 AC_SUBST(with_libxslt)
 844
 845 #
 846 # tzdata
 847 #
 848 PGAC_ARG_REQ(with, system-tzdata,
 849              [DIR], [use system time zone data in DIR])
 850 AC_SUBST(with_system_tzdata)
 851
 852 #
 853 # Zlib
 854 #
 855 PGAC_ARG_BOOL(with, zlib, yes,
 856               [do not use Zlib])
 857 AC_SUBST(with_zlib)
 858
 859 #
 860 # Elf
 861 #
 862
 863 # Assume system is ELF if it predefines __ELF__ as 1,
 864 # otherwise believe host_os based default.
 865 case $host_os in
 866     freebsd1*|freebsd2*) elf=no;;
 867     freebsd3*|freebsd4*) elf=yes;;
 868 esac
 869
 870 AC_EGREP_CPP(yes,
 871 [#if __ELF__
 872   yes
 873 #endif
 874 ],
 875 [ELF_SYS=true],
 876 [if test "X$elf" = "Xyes" ; then
 877   ELF_SYS=true
 878 else
 879   ELF_SYS=
 880 fi])
 881 AC_SUBST(ELF_SYS)
 882
 883 #
 884 # Assignments
 885 #
 886
 887 CPPFLAGS="$CPPFLAGS $INCLUDES"
 888 LDFLAGS="$LDFLAGS $LIBDIRS"
 889
 890 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 891 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 892
 893 PGAC_PROG_LD
 894 AC_SUBST(LD)
 895 AC_SUBST(with_gnu_ld)
 896 AC_PROG_RANLIB
 897 PGAC_CHECK_STRIP
 898 AC_CHECK_TOOL(AR, ar, ar)
 899 if test "$PORTNAME" = "win32"; then
 900   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 901   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 902   AC_CHECK_TOOL(WINDRES, windres, windres)
 903 fi
 904
 905 AC_PROG_INSTALL
 906 # When Autoconf chooses install-sh as install program it tries to generate
 907 # a relative path to it in each makefile where it substitutes it. This clashes
 908 # with our Makefile.global concept. This workaround helps.
 909 case $INSTALL in
 910   *install-sh*) install_bin='';;
 911   *) install_bin=$INSTALL;;
 912 esac
 913 AC_SUBST(install_bin)
 914
 915 AC_PATH_PROG(TAR, tar)
 916 AC_PROG_LN_S
 917 AC_PROG_AWK
 918 AC_PROG_MKDIR_P
 919 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 920 # a relative path to it in each makefile where it substitutes it. This clashes
 921 # with our Makefile.global concept. This workaround helps.
 922 case $MKDIR_P in
 923   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 924 esac
 925
 926 PGAC_PATH_BISON
 927 PGAC_PATH_FLEX
 928
 929 PGAC_PATH_PERL
 930 if test "$with_perl" = yes; then
 931   if test -z "$PERL"; then
 932     AC_MSG_ERROR([Perl not found])
 933   fi
 934   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 935   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 936     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 937 You might have to rebuild your Perl installation.  Refer to the
 938 documentation for details.  Use --without-perl to disable building
 939 PL/Perl.])
 940   fi
 941   PGAC_CHECK_PERL_EMBED_LDFLAGS
 942 fi
 943
 944 if test "$with_python" = yes; then
 945   PGAC_PATH_PYTHON
 946   PGAC_CHECK_PYTHON_EMBED_SETUP
 947 fi
 948
 949 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 950   AC_PATH_PROG(ZIC, zic)
 951   if test -z "$ZIC"; then
 952     AC_MSG_ERROR([
 953 When cross-compiling, either use the option --with-system-tzdata to use
 954 existing time-zone data, or set the environment variable ZIC to a zic
 955 program to use during the build.])
 956   fi
 957 fi
 958
 959 #
 960 # Pthreads
 961 #
 962 # For each platform, we need to know about any special compile and link
 963 # libraries, and whether the normal C function names are thread-safe.
 964 # See the comment at the top of src/port/thread.c for more information.
 965 # WIN32 doesn't need the pthread tests;  it always uses threads
 966 #
 967 # These tests are run before the library-tests, because linking with the
 968 # other libraries can pull in the pthread functions as a side-effect.  We
 969 # want to use the -pthread or similar flags directly, and not rely on
 970 # the side-effects of linking with some other library.
 971 #
 972 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 973 # invocation below is the first one in the script, and autoconf generates
 974 # additional code for that, which must not be inside the if-block. AS_IF
 975 # knows how to do that.
 976 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 977 [ # then
 978 AX_PTHREAD      # set thread flags
 979
 980 # Some platforms use these, so just define them.  They can't hurt if they
 981 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 982 # enables 5-arg getpwuid_r, among other things.
 983 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 984
 985 # Check for *_r functions
 986 _CFLAGS="$CFLAGS"
 987 _LIBS="$LIBS"
 988 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 989 LIBS="$LIBS $PTHREAD_LIBS"
 990
 991 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 992 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 993
 994 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 995
 996 # Do test here with the proper thread flags
 997 PGAC_FUNC_STRERROR_R_INT
 998
 999 CFLAGS="$_CFLAGS"
1000 LIBS="$_LIBS"
1001
1002 ], [ # else
1003 # do not use values from template file
1004 PTHREAD_CFLAGS=
1005 PTHREAD_LIBS=
1006 ]) # fi
1007
1008 AC_SUBST(PTHREAD_CFLAGS)
1009 AC_SUBST(PTHREAD_LIBS)
1010
1011
1012 ##
1013 ## Libraries
1014 ##
1015 ## Most libraries are included only if they demonstrably provide a function
1016 ## we need, but libm is an exception: always include it, because there are
1017 ## too many compilers that play cute optimization games that will break
1018 ## probes for standard functions such as pow().
1019 ##
1020
1021 AC_CHECK_LIB(m, main)
1022 AC_SEARCH_LIBS(setproctitle, util)
1023 AC_SEARCH_LIBS(dlopen, dl)
1024 AC_SEARCH_LIBS(socket, [socket ws2_32])
1025 AC_SEARCH_LIBS(shl_load, dld)
1026 # We only use libld in port/dynloader/aix.c
1027 case $host_os in
1028      aix*)
1029         AC_SEARCH_LIBS(ldopen, ld)
1030         ;;
1031 esac
1032 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1033 AC_SEARCH_LIBS(crypt, crypt)
1034 AC_SEARCH_LIBS(shm_open, rt)
1035 AC_SEARCH_LIBS(shm_unlink, rt)
1036 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1037 # Solaris:
1038 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1039 # Required for thread_test.c on Solaris
1040 AC_SEARCH_LIBS(sched_yield, rt)
1041 # Required for thread_test.c on Solaris 2.5:
1042 # Other ports use it too (HP-UX) so test unconditionally
1043 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1044 # Cygwin:
1045 AC_SEARCH_LIBS(shmget, cygipc)
1046
1047 if test "$with_readline" = yes; then
1048   PGAC_CHECK_READLINE
1049   if test x"$pgac_cv_check_readline" = x"no"; then
1050     AC_MSG_ERROR([readline library not found
1051 If you have readline already installed, see config.log for details on the
1052 failure.  It is possible the compiler isn't looking in the proper directory.
1053 Use --without-readline to disable readline support.])
1054   fi
1055 fi
1056
1057 if test "$with_zlib" = yes; then
1058   AC_CHECK_LIB(z, inflate, [],
1059                [AC_MSG_ERROR([zlib library not found
1060 If you have zlib already installed, see config.log for details on the
1061 failure.  It is possible the compiler isn't looking in the proper directory.
1062 Use --without-zlib to disable zlib support.])])
1063 fi
1064
1065 if test "$enable_spinlocks" = yes; then
1066   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1067 else
1068   AC_MSG_WARN([
1069 *** Not using spinlocks will cause poor performance.])
1070 fi
1071
1072 if test "$enable_atomics" = yes; then
1073   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1074 else
1075   AC_MSG_WARN([
1076 *** Not using atomic operations will cause poor performance.])
1077 fi
1078
1079 if test "$with_gssapi" = yes ; then
1080   if test "$PORTNAME" != "win32"; then
1081     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1082                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1083   else
1084     LIBS="$LIBS -lgssapi32"
1085   fi
1086 fi
1087
1088 if test "$with_openssl" = yes ; then
1089   dnl Order matters!
1090   if test "$PORTNAME" != "win32"; then
1091      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1092      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1093   else
1094      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1095      AC_SEARCH_LIBS(SSL_new, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1096   fi
1097   AC_CHECK_FUNCS([SSL_get_current_compression])
1098   # Functions introduced in OpenSSL 1.1.0. We used to check for
1099   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1100   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1101   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1102   # functions.
1103   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1104   # OpenSSL versions before 1.1.0 required setting callback functions, for
1105   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1106   # function was removed.
1107   AC_CHECK_FUNCS([CRYPTO_lock])
1108 fi
1109
1110 if test "$with_pam" = yes ; then
1111   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1112 fi
1113
1114 if test "$with_libxml" = yes ; then
1115   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1116 fi
1117
1118 if test "$with_libxslt" = yes ; then
1119   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1120 fi
1121
1122 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1123 if test "$with_ldap" = yes ; then
1124   _LIBS="$LIBS"
1125   if test "$PORTNAME" != "win32"; then
1126     AC_CHECK_LIB(ldap, ldap_bind, [],
1127                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1128                  [$EXTRA_LDAP_LIBS])
1129     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1130     if test "$enable_thread_safety" = yes; then
1131       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1132       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1133                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1134                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1135       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1136     else
1137       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1138     fi
1139   else
1140     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1141     LDAP_LIBS_FE="-lwldap32"
1142     LDAP_LIBS_BE="-lwldap32"
1143   fi
1144   LIBS="$_LIBS"
1145 fi
1146 AC_SUBST(LDAP_LIBS_FE)
1147 AC_SUBST(LDAP_LIBS_BE)
1148
1149 # for contrib/sepgsql
1150 if test "$with_selinux" = yes; then
1151   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1152                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1153 fi
1154
1155 # for contrib/uuid-ossp
1156 if test "$with_uuid" = bsd ; then
1157   # On BSD, the UUID functions are in libc
1158   AC_CHECK_FUNC(uuid_to_string,
1159     [UUID_LIBS=""],
1160     [AC_MSG_ERROR([BSD UUID functions are not present])])
1161 elif test "$with_uuid" = e2fs ; then
1162   # On macOS, the UUID functions are in libc
1163   AC_CHECK_FUNC(uuid_generate,
1164     [UUID_LIBS=""],
1165     [AC_CHECK_LIB(uuid, uuid_generate,
1166       [UUID_LIBS="-luuid"],
1167       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1168 elif test "$with_uuid" = ossp ; then
1169   AC_CHECK_LIB(ossp-uuid, uuid_export,
1170     [UUID_LIBS="-lossp-uuid"],
1171     [AC_CHECK_LIB(uuid, uuid_export,
1172       [UUID_LIBS="-luuid"],
1173       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1174 fi
1175 AC_SUBST(UUID_LIBS)
1176
1177
1178 ##
1179 ## Header files
1180 ##
1181
1182 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1183
1184 # On BSD, test for net/if.h will fail unless sys/socket.h
1185 # is included first.
1186 AC_CHECK_HEADERS(net/if.h, [], [],
1187 [AC_INCLUDES_DEFAULT
1188 #include <sys/socket.h>
1189 ])
1190
1191 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1192 # is included first.
1193 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1194 [AC_INCLUDES_DEFAULT
1195 #include <sys/param.h>
1196 ])
1197
1198 # At least on IRIX, test for netinet/tcp.h will fail unless
1199 # netinet/in.h is included first.
1200 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1201 [AC_INCLUDES_DEFAULT
1202 #include <netinet/in.h>
1203 ])
1204
1205 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1206   AC_CHECK_HEADERS(readline/readline.h, [],
1207         [AC_CHECK_HEADERS(readline.h, [],
1208                 [AC_MSG_ERROR([readline header not found
1209 If you have readline already installed, see config.log for details on the
1210 failure.  It is possible the compiler isn't looking in the proper directory.
1211 Use --without-readline to disable readline support.])])])
1212   AC_CHECK_HEADERS(readline/history.h, [],
1213         [AC_CHECK_HEADERS(history.h, [],
1214                 [AC_MSG_ERROR([history header not found
1215 If you have readline already installed, see config.log for details on the
1216 failure.  It is possible the compiler isn't looking in the proper directory.
1217 Use --without-readline to disable readline support.])])])
1218 fi
1219
1220 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1221 # Some installations of libedit usurp /usr/include/readline/, which seems
1222 # bad practice, since in combined installations readline will have its headers
1223 # there.  We might have to resort to AC_EGREP checks to make sure we found
1224 # the proper header...
1225   AC_CHECK_HEADERS(editline/readline.h, [],
1226         [AC_CHECK_HEADERS(readline.h, [],
1227                 [AC_CHECK_HEADERS(readline/readline.h, [],
1228                         [AC_MSG_ERROR([readline header not found
1229 If you have libedit already installed, see config.log for details on the
1230 failure.  It is possible the compiler isn't looking in the proper directory.
1231 Use --without-readline to disable libedit support.])])])])
1232 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1233 # not be there at all.  Hence, don't complain if not found.  We must check
1234 # though, since in yet other versions it is an independent header.
1235   AC_CHECK_HEADERS(editline/history.h, [],
1236         [AC_CHECK_HEADERS(history.h, [],
1237                 [AC_CHECK_HEADERS(readline/history.h)])])
1238 fi
1239
1240 if test "$with_zlib" = yes; then
1241   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1242 If you have zlib already installed, see config.log for details on the
1243 failure.  It is possible the compiler isn't looking in the proper directory.
1244 Use --without-zlib to disable zlib support.])])
1245 fi
1246
1247 if test "$with_gssapi" = yes ; then
1248   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1249         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1250 fi
1251
1252 if test "$with_openssl" = yes ; then
1253   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1254   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1255 fi
1256
1257 if test "$with_pam" = yes ; then
1258   AC_CHECK_HEADERS(security/pam_appl.h, [],
1259                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1260                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1261 fi
1262
1263 if test "$with_bsd_auth" = yes ; then
1264   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1265 fi
1266
1267 if test "$with_systemd" = yes ; then
1268   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1269 fi
1270
1271 if test "$with_libxml" = yes ; then
1272   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1273 fi
1274
1275 if test "$with_libxslt" = yes ; then
1276   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1277 fi
1278
1279 if test "$with_ldap" = yes ; then
1280   if test "$PORTNAME" != "win32"; then
1281      AC_CHECK_HEADERS(ldap.h, [],
1282                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1283      PGAC_LDAP_SAFE
1284   else
1285      AC_CHECK_HEADERS(winldap.h, [],
1286                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1287                       [AC_INCLUDES_DEFAULT
1288 #include <windows.h>
1289                       ])
1290   fi
1291 fi
1292
1293 if test "$with_bonjour" = yes ; then
1294   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1295 fi
1296
1297 # for contrib/uuid-ossp
1298 if test "$with_uuid" = bsd ; then
1299   AC_CHECK_HEADERS(uuid.h,
1300     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1301       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1302     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1303 elif test "$with_uuid" = e2fs ; then
1304   AC_CHECK_HEADERS(uuid/uuid.h,
1305     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1306       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1307     [AC_CHECK_HEADERS(uuid.h,
1308       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1309         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1310       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1311 elif test "$with_uuid" = ossp ; then
1312   AC_CHECK_HEADERS(ossp/uuid.h,
1313     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1314       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1315     [AC_CHECK_HEADERS(uuid.h,
1316       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1317         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1318       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1319 fi
1320
1321 if test "$PORTNAME" = "win32" ; then
1322    AC_CHECK_HEADERS(crtdefs.h)
1323 fi
1324
1325 ##
1326 ## Types, structures, compiler characteristics
1327 ##
1328
1329 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1330 AC_C_BIGENDIAN
1331 AC_C_INLINE
1332 PGAC_PRINTF_ARCHETYPE
1333 AC_C_FLEXIBLE_ARRAY_MEMBER
1334 PGAC_C_SIGNED
1335 PGAC_C_FUNCNAME_SUPPORT
1336 PGAC_C_STATIC_ASSERT
1337 PGAC_C_TYPEOF
1338 PGAC_C_TYPES_COMPATIBLE
1339 PGAC_C_BUILTIN_BSWAP32
1340 PGAC_C_BUILTIN_BSWAP64
1341 PGAC_C_BUILTIN_CONSTANT_P
1342 PGAC_C_BUILTIN_UNREACHABLE
1343 PGAC_C_COMPUTED_GOTO
1344 PGAC_C_VA_ARGS
1345 PGAC_STRUCT_TIMEZONE
1346 PGAC_UNION_SEMUN
1347 PGAC_STRUCT_SOCKADDR_UN
1348 PGAC_STRUCT_SOCKADDR_STORAGE
1349 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1350 PGAC_STRUCT_ADDRINFO
1351 AC_TYPE_INTPTR_T
1352 AC_TYPE_UINTPTR_T
1353 AC_TYPE_LONG_LONG_INT
1354
1355 PGAC_TYPE_LOCALE_T
1356
1357 AC_CHECK_TYPES([struct cmsgcred], [], [],
1358 [#include <sys/socket.h>
1359 #include <sys/param.h>
1360 #ifdef HAVE_SYS_UCRED_H
1361 #include <sys/ucred.h>
1362 #endif])
1363
1364 AC_CHECK_TYPES([struct option], [], [],
1365 [#ifdef HAVE_GETOPT_H
1366 #include <getopt.h>
1367 #endif])
1368
1369 if test "$with_zlib" = yes; then
1370   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1371   # did not).  While we could work around the lack of z_streamp, it
1372   # seems unwise to encourage people to use such old zlib versions...
1373   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1374 Use --without-zlib to disable zlib support.])],
1375                 [#include <zlib.h>])
1376 fi
1377
1378 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1379 case $host_cpu in
1380   ppc*|powerpc*)
1381     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1382     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1383         [int a = 0; int *p = &a; int r;
1384          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1385         [pgac_cv_have_ppc_mutex_hint=yes],
1386         [pgac_cv_have_ppc_mutex_hint=no])
1387     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1388     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1389         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1390     fi
1391   ;;
1392 esac
1393
1394 # Check largefile support.  You might think this is a system service not a
1395 # compiler characteristic, but you'd be wrong.  We must check this before
1396 # probing existence of related functions such as fseeko, since the largefile
1397 # defines can affect what is generated for that.
1398 if test "$PORTNAME" != "win32"; then
1399    AC_SYS_LARGEFILE
1400    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1401    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1402    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1403    dnl versions where the feature actually works, it's on by default anyway.
1404    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1405 fi
1406
1407 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1408 AC_CHECK_SIZEOF([off_t])
1409
1410 # If we don't have largefile support, can't handle segsize >= 2GB.
1411 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1412    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1413 fi
1414
1415
1416 ##
1417 ## Functions, global variables
1418 ##
1419
1420 PGAC_VAR_INT_TIMEZONE
1421 AC_FUNC_ACCEPT_ARGTYPES
1422 PGAC_FUNC_GETTIMEOFDAY_1ARG
1423 PGAC_FUNC_WCSTOMBS_L
1424
1425 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1426 # symbols that that library has no business exposing to the world.  Pending
1427 # acquisition of a clue by those developers, ignore libedit (including its
1428 # possible alias of libreadline) while checking for everything else.
1429 LIBS_including_readline="$LIBS"
1430 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1431
1432 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1433
1434 AC_REPLACE_FUNCS(fseeko)
1435 case $host_os in
1436         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1437         # Mingw uses macros to access Win32 API calls
1438         netbsd*|mingw*)
1439                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1440                 ac_cv_func_fseeko=yes;;
1441         *)
1442                 AC_FUNC_FSEEKO;;
1443 esac
1444
1445 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1446 # by calling it, 2009-04-02
1447 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1448 if test "$PORTNAME" != "solaris"; then
1449 AC_CHECK_FUNCS(posix_fadvise)
1450 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1451 fi
1452
1453 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1454 AC_CHECK_DECLS([strlcat, strlcpy])
1455 # This is probably only present on macOS, but may as well check always
1456 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1457
1458 HAVE_IPV6=no
1459 AC_CHECK_TYPE([struct sockaddr_in6],
1460         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1461          HAVE_IPV6=yes],
1462         [],
1463 [$ac_includes_default
1464 #include <netinet/in.h>])
1465 AC_SUBST(HAVE_IPV6)
1466
1467 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1468 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1469 [#include <machine/vmparam.h>
1470 #include <sys/exec.h>
1471 ],
1472 [PS_STRINGS->ps_nargvstr = 1;
1473 PS_STRINGS->ps_argvstr = "foo";])],
1474 [pgac_cv_var_PS_STRINGS=yes],
1475 [pgac_cv_var_PS_STRINGS=no])])
1476 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1477   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1478 fi
1479
1480
1481 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1482 # is missing.  Yes, there are machines that have only one.  We may
1483 # also decide to use snprintf.c if snprintf() is present but does not
1484 # have all the features we need --- see below.
1485
1486 if test "$PORTNAME" = "win32"; then
1487   # Win32 gets snprintf.c built unconditionally.
1488   #
1489   # To properly translate all NLS languages strings, we must support the
1490   # *printf() %$ format, which allows *printf() arguments to be selected
1491   # by position in the translated string.
1492   #
1493   # libintl versions < 0.13 use the native *printf() functions, and Win32
1494   # *printf() doesn't understand %$, so we must use our /port versions,
1495   # which do understand %$. libintl versions >= 0.13 include their own
1496   # *printf versions on Win32.  The libintl 0.13 release note text is:
1497   #
1498   #   C format strings with positions, as they arise when a translator
1499   #   needs to reorder a sentence, are now supported on all platforms.
1500   #   On those few platforms (NetBSD and Woe32) for which the native
1501   #   printf()/fprintf()/... functions don't support such format
1502   #   strings, replacements are provided through <libintl.h>.
1503   #
1504   # We could use libintl >= 0.13's *printf() if we were sure that we had
1505   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1506   # to guarantee that, it is best to just use our own, so we are sure to
1507   # get %$ support. In include/port.h we disable the *printf() macros
1508   # that might have been defined by libintl.
1509   #
1510   # We do this unconditionally whether NLS is used or not so we are sure
1511   # that all Win32 libraries and binaries behave the same.
1512   pgac_need_repl_snprintf=yes
1513 else
1514   pgac_need_repl_snprintf=no
1515   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1516   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1517 fi
1518
1519
1520 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1521 # include/c.h will provide declarations.  Note this is a separate test
1522 # from whether the functions exist in the C library --- there are
1523 # systems that have the functions but don't bother to declare them :-(
1524
1525 AC_CHECK_DECLS([snprintf, vsnprintf])
1526
1527
1528 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1529 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1530 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1531 #include <math.h>
1532 double glob_double;
1533 ],
1534 [return isinf(glob_double) ? 0 : 1;])],
1535 [ac_cv_func_isinf=yes],
1536 [ac_cv_func_isinf=no])])
1537
1538 if test $ac_cv_func_isinf = yes ; then
1539   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1540 else
1541   AC_LIBOBJ(isinf)
1542   # Look for a way to implement a substitute for isinf()
1543   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1544 fi
1545
1546 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1547
1548 case $host_os in
1549
1550         # Windows uses a specialised env handler
1551         # and doesn't need a replacement getpeereid because it doesn't use
1552         # Unix sockets.
1553         mingw*)
1554                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1555                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1556                 ac_cv_func_unsetenv=yes
1557                 ac_cv_func_getpeereid=yes;;
1558         *)
1559                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1560                 ;;
1561 esac
1562
1563 # System's version of getaddrinfo(), if any, may be used only if we found
1564 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1565 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1566 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1567    test "$PORTNAME" != "win32"; then
1568   AC_REPLACE_FUNCS([getaddrinfo])
1569 else
1570   AC_LIBOBJ(getaddrinfo)
1571 fi
1572
1573 # Similarly, use system's getopt_long() only if system provides struct option.
1574 if test x"$ac_cv_type_struct_option" = xyes ; then
1575   AC_REPLACE_FUNCS([getopt_long])
1576 else
1577   AC_LIBOBJ(getopt_long)
1578 fi
1579
1580 # Solaris' getopt() doesn't do what we want for long options, so always use
1581 # our version on that platform.
1582 if test "$PORTNAME" = "solaris"; then
1583   AC_LIBOBJ(getopt)
1584 fi
1585
1586 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1587 # so always use our version on Windows.
1588 if test "$PORTNAME" = "win32"; then
1589   AC_LIBOBJ(getopt)
1590   AC_LIBOBJ(getopt_long)
1591 fi
1592
1593 # Win32 (really MinGW) support
1594 if test "$PORTNAME" = "win32"; then
1595   AC_REPLACE_FUNCS(gettimeofday)
1596   AC_LIBOBJ(dirmod)
1597   AC_LIBOBJ(kill)
1598   AC_LIBOBJ(open)
1599   AC_LIBOBJ(system)
1600   AC_LIBOBJ(win32env)
1601   AC_LIBOBJ(win32error)
1602   AC_LIBOBJ(win32security)
1603   AC_LIBOBJ(win32setlocale)
1604   AC_DEFINE([HAVE_SYMLINK], 1,
1605             [Define to 1 if you have the `symlink' function.])
1606   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1607 #define WIN32_LEAN_AND_MEAN
1608 #include <windows.h>
1609 #include <string.h>
1610 #include <dbghelp.h>])
1611 fi
1612 if test x"$pgac_minidump_type" = x"yes" ; then
1613   AC_SUBST(have_win32_dbghelp,yes)
1614 else
1615   AC_SUBST(have_win32_dbghelp,no)
1616 fi
1617
1618 # Cygwin needs only a bit of that
1619 if test "$PORTNAME" = "cygwin"; then
1620   AC_LIBOBJ(dirmod)
1621 fi
1622
1623 AC_CHECK_DECLS([sys_siglist], [], [],
1624 [#include <signal.h>
1625 /* NetBSD declares sys_siglist in unistd.h.  */
1626 #ifdef HAVE_UNISTD_H
1627 # include <unistd.h>
1628 #endif
1629 ])
1630
1631 AC_CHECK_FUNC(syslog,
1632               [AC_CHECK_HEADER(syslog.h,
1633                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1634
1635 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1636 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1637   [extern int opterr; opterr = 1;])],
1638   [pgac_cv_var_int_opterr=yes],
1639   [pgac_cv_var_int_opterr=no])])
1640 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1641   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1642 fi
1643
1644 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1645 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1646   [extern int optreset; optreset = 1;])],
1647   [pgac_cv_var_int_optreset=yes],
1648   [pgac_cv_var_int_optreset=no])])
1649 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1650   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1651 fi
1652
1653 AC_CHECK_FUNCS([strtoll strtoq], [break])
1654 AC_CHECK_FUNCS([strtoull strtouq], [break])
1655
1656 if test "$with_icu" = yes; then
1657   # ICU functions are macros, so we need to do this the long way.
1658
1659   # ucol_strcollUTF8() appeared in ICU 50.
1660   AC_CACHE_CHECK([for ucol_strcollUTF8], [pgac_cv_func_ucol_strcollUTF8],
1661 [ac_save_CPPFLAGS=$CPPFLAGS
1662 CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1663 ac_save_LIBS=$LIBS
1664 LIBS="$ICU_LIBS $LIBS"
1665 AC_LINK_IFELSE([AC_LANG_PROGRAM(
1666 [#include <unicode/ucol.h>
1667 ],
1668 [ucol_strcollUTF8(NULL, NULL, 0, NULL, 0, NULL);])],
1669 [pgac_cv_func_ucol_strcollUTF8=yes],
1670 [pgac_cv_func_ucol_strcollUTF8=no])
1671 CPPFLAGS=$ac_save_CPPFLAGS
1672 LIBS=$ac_save_LIBS])
1673   if test "$pgac_cv_func_ucol_strcollUTF8" = yes ; then
1674     AC_DEFINE([HAVE_UCOL_STRCOLLUTF8], 1, [Define to 1 if you have the `ucol_strcollUTF8' function.])
1675   fi
1676 fi
1677
1678 # Lastly, restore full LIBS list and check for readline/libedit symbols
1679 LIBS="$LIBS_including_readline"
1680
1681 if test "$with_readline" = yes; then
1682   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1683   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1684   AC_CHECK_FUNCS([append_history history_truncate_file])
1685 fi
1686
1687
1688 # This test makes sure that run tests work at all.  Sometimes a shared
1689 # library is found by the linker, but the runtime linker can't find it.
1690 # This check should come after all modifications of compiler or linker
1691 # variables, and before any other run tests.
1692 AC_MSG_CHECKING([test program])
1693 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1694 [AC_MSG_RESULT(ok)],
1695 [AC_MSG_RESULT(failed)
1696 AC_MSG_ERROR([[
1697 Could not execute a simple test program.  This may be a problem
1698 related to locating shared libraries.  Check the file 'config.log'
1699 for the exact reason.]])],
1700 [AC_MSG_RESULT([cross-compiling])])
1701
1702 # --------------------
1703 # Run tests below here
1704 # --------------------
1705
1706 # Force use of our snprintf if system's doesn't do arg control
1707 # See comment above at snprintf test for details.
1708 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1709   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1710   if test $pgac_cv_snprintf_arg_control != yes ; then
1711     pgac_need_repl_snprintf=yes
1712   fi
1713 fi
1714
1715
1716 dnl Check to see if we have a working 64-bit integer type.
1717 dnl This breaks down into two steps:
1718 dnl (1) figure out if the compiler has a 64-bit int type with working
1719 dnl arithmetic, and if so
1720 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1721 dnl snprintf is the only library routine we really need for int8 support.)
1722 dnl It's entirely possible to have a compiler that handles a 64-bit type
1723 dnl when the C library doesn't; this is fairly likely when using gcc on
1724 dnl an older platform, for example.
1725 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1726 dnl we force our own version of snprintf() to be used instead.
1727 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1728
1729 dnl As of Postgres 8.4, we no longer support compilers without a working
1730 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1731
1732 PGAC_TYPE_64BIT_INT([long int])
1733
1734 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1735   pg_int64_type="long int"
1736 else
1737   PGAC_TYPE_64BIT_INT([long long int])
1738   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1739     pg_int64_type="long long int"
1740   else
1741     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1742   fi
1743 fi
1744
1745 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1746   [Define to the name of a signed 64-bit integer type.])
1747
1748 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1749
1750 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1751   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1752 #define INT64CONST(x)  x##LL
1753 long long int foo = INT64CONST(0x1234567890123456);
1754 ])],
1755         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1756         [])
1757 fi
1758
1759
1760 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1761 # we found we need to use "long long int", better check.  We cope with
1762 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1763 # work, fall back to our own snprintf emulation (which we know uses %lld).
1764
1765 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1766   if test $pgac_need_repl_snprintf = no; then
1767     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1768     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1769       # Force usage of our own snprintf, since system snprintf is broken
1770       pgac_need_repl_snprintf=yes
1771       LONG_LONG_INT_MODIFIER='ll'
1772     fi
1773   else
1774     # Here if we previously decided we needed to use our own snprintf
1775     LONG_LONG_INT_MODIFIER='ll'
1776   fi
1777 else
1778   # Here if we are not using 'long long int' at all
1779   LONG_LONG_INT_MODIFIER='l'
1780 fi
1781
1782 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1783
1784 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1785                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1786
1787 # Also force use of our snprintf if the system's doesn't support the %z flag.
1788 if test "$pgac_need_repl_snprintf" = no; then
1789   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1790   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1791     pgac_need_repl_snprintf=yes
1792   fi
1793 fi
1794
1795 # Now we have checked all the reasons to replace snprintf
1796 if test $pgac_need_repl_snprintf = yes; then
1797   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1798   AC_LIBOBJ(snprintf)
1799 fi
1800
1801 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1802 AC_CHECK_SIZEOF([void *])
1803 AC_CHECK_SIZEOF([size_t])
1804 AC_CHECK_SIZEOF([long])
1805
1806 # Decide whether float4 is passed by value: user-selectable, enabled by default
1807 AC_MSG_CHECKING([whether to build with float4 passed by value])
1808 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1809               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1810                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1811                float4passbyval=true],
1812               [float4passbyval=false])
1813 AC_MSG_RESULT([$enable_float4_byval])
1814 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1815
1816 # Decide whether float8 is passed by value.
1817 # Note: this setting also controls int8 and related types such as timestamp.
1818 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1819 # If not, trying to select it is an error.
1820 AC_MSG_CHECKING([whether to build with float8 passed by value])
1821 if test $ac_cv_sizeof_void_p -ge 8 ; then
1822   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1823 else
1824   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1825   if test "$enable_float8_byval" = yes ; then
1826     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1827   fi
1828 fi
1829 if test "$enable_float8_byval" = yes ; then
1830   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1831             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1832   float8passbyval=true
1833 else
1834   float8passbyval=false
1835 fi
1836 AC_MSG_RESULT([$enable_float8_byval])
1837 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1838
1839 # Determine memory alignment requirements for the basic C data types.
1840
1841 AC_CHECK_ALIGNOF(short)
1842 AC_CHECK_ALIGNOF(int)
1843 AC_CHECK_ALIGNOF(long)
1844 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1845   AC_CHECK_ALIGNOF(long long int)
1846 fi
1847 AC_CHECK_ALIGNOF(double)
1848
1849 # Compute maximum alignment of any basic type.
1850 # We assume long's alignment is at least as strong as char, short, or int;
1851 # but we must check long long (if it exists) and double.
1852
1853 MAX_ALIGNOF=$ac_cv_alignof_long
1854 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1855   MAX_ALIGNOF=$ac_cv_alignof_double
1856 fi
1857 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1858   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1859 fi
1860 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1861
1862
1863 # Some platforms predefine the types int8, int16, etc.  Only check
1864 # a (hopefully) representative subset.
1865 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1866 [#include <stdio.h>])
1867
1868 # Check for extensions offering the integer scalar type __int128.
1869 PGAC_TYPE_128BIT_INT
1870
1871 # Check for various atomic operations now that we have checked how to declare
1872 # 64bit integers.
1873 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1874 PGAC_HAVE_GCC__SYNC_INT32_TAS
1875 PGAC_HAVE_GCC__SYNC_INT32_CAS
1876 PGAC_HAVE_GCC__SYNC_INT64_CAS
1877 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1878 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1879
1880
1881 # Check for x86 cpuid instruction
1882 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1883 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1884   [[unsigned int exx[4] = {0, 0, 0, 0};
1885   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1886   ]])],
1887   [pgac_cv__get_cpuid="yes"],
1888   [pgac_cv__get_cpuid="no"])])
1889 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1890   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1891 fi
1892
1893 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1894 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1895   [[unsigned int exx[4] = {0, 0, 0, 0};
1896   __get_cpuid(exx[0], 1);
1897   ]])],
1898   [pgac_cv__cpuid="yes"],
1899   [pgac_cv__cpuid="no"])])
1900 if test x"$pgac_cv__cpuid" = x"yes"; then
1901   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1902 fi
1903
1904 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1905 #
1906 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1907 # with the default compiler flags. If not, check if adding the -msse4.2
1908 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1909 PGAC_SSE42_CRC32_INTRINSICS([])
1910 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1911   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1912 fi
1913 AC_SUBST(CFLAGS_SSE42)
1914
1915 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1916 # define __SSE4_2__ in that case.
1917 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1918 #ifndef __SSE4_2__
1919 #error __SSE4_2__ not defined
1920 #endif
1921 ])], [SSE4_2_TARGETED=1])
1922
1923 # Select CRC-32C implementation.
1924 #
1925 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1926 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1927 # a processor, but we can nevertheless produce code that uses the SSE
1928 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1929 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1930 # by the processor we're running on.
1931 #
1932 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1933 # in the template or configure command line.
1934 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1935   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1936     USE_SSE42_CRC32C=1
1937   else
1938     # the CPUID instruction is needed for the runtime check.
1939     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1940       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1941     else
1942       # fall back to slicing-by-8 algorithm which doesn't require any special
1943       # CPU support.
1944       USE_SLICING_BY_8_CRC32C=1
1945     fi
1946   fi
1947 fi
1948
1949 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1950 AC_MSG_CHECKING([which CRC-32C implementation to use])
1951 if test x"$USE_SSE42_CRC32C" = x"1"; then
1952   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1953   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1954   AC_MSG_RESULT(SSE 4.2)
1955 else
1956   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1957     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1958     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1959     AC_MSG_RESULT(SSE 4.2 with runtime check)
1960   else
1961     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1962     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1963     AC_MSG_RESULT(slicing-by-8)
1964   fi
1965 fi
1966 AC_SUBST(PG_CRC32C_OBJS)
1967
1968
1969 # Select semaphore implementation type.
1970 if test "$PORTNAME" != "win32"; then
1971   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1972     # Need sem_open for this
1973     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1974   fi
1975   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1976     # Need sem_init for this
1977     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1978   fi
1979   AC_MSG_CHECKING([which semaphore API to use])
1980   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1981     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1982     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1983     sematype="named POSIX"
1984   else
1985     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1986       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1987       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1988       sematype="unnamed POSIX"
1989     else
1990       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1991       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1992       sematype="System V"
1993     fi
1994   fi
1995   AC_MSG_RESULT([$sematype])
1996 else
1997   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1998   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1999 fi
2000
2001
2002 # Select shared-memory implementation type.
2003 if test "$PORTNAME" != "win32"; then
2004   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2005   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2006 else
2007   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2008   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2009 fi
2010
2011 # Select random number source
2012 #
2013 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2014 # in the template or configure command line.
2015
2016 # If not selected manually, try to select a source automatically.
2017 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2018   if test x"$with_openssl" = x"yes" ; then
2019     USE_OPENSSL_RANDOM=1
2020   elif test "$PORTNAME" = "win32" ; then
2021     USE_WIN32_RANDOM=1
2022   else
2023     AC_CHECK_FILE([/dev/urandom], [], [])
2024
2025     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2026       USE_DEV_URANDOM=1
2027     fi
2028   fi
2029 fi
2030
2031 AC_MSG_CHECKING([which random number source to use])
2032 if test "$enable_strong_random" = yes ; then
2033   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2034     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2035     AC_MSG_RESULT([OpenSSL])
2036   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2037     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2038     AC_MSG_RESULT([Windows native])
2039   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2040     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2041     AC_MSG_RESULT([/dev/urandom])
2042   else
2043     AC_MSG_ERROR([
2044 no source of strong random numbers was found
2045 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2046 for authentication protocols. You can use --disable-strong-random to use a
2047 built-in pseudo random number generator, but that may be insecure.])
2048   fi
2049   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2050 else
2051     AC_MSG_RESULT([weak builtin PRNG])
2052     AC_MSG_WARN([
2053 *** Not using a strong random number source may be insecure.])
2054 fi
2055
2056 # If not set in template file, set bytes to use libc memset()
2057 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2058   MEMSET_LOOP_LIMIT=1024
2059 fi
2060 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2061
2062
2063 if test "$enable_nls" = yes ; then
2064   PGAC_CHECK_GETTEXT
2065 fi
2066
2067 # Check for Tcl configuration script tclConfig.sh
2068 if test "$with_tcl" = yes; then
2069     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2070     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2071                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2072     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2073     if test "$TCL_SHARED_BUILD" != 1; then
2074       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2075 Use --without-tcl to disable building PL/Tcl.])
2076     fi
2077     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2078     ac_save_CPPFLAGS=$CPPFLAGS
2079     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2080     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2081     CPPFLAGS=$ac_save_CPPFLAGS
2082 fi
2083
2084 # check for <perl.h>
2085 if test "$with_perl" = yes; then
2086   ac_save_CPPFLAGS=$CPPFLAGS
2087   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2088   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2089                   [#include <EXTERN.h>])
2090   # While we're at it, check that we can link to libperl.
2091   # On most platforms, if perl.h is there then libperl.so will be too, but at
2092   # this writing Debian packages them separately.  There is no known reason to
2093   # waste cycles on separate probes for the Tcl or Python libraries, though.
2094   pgac_save_LIBS=$LIBS
2095   LIBS="$perl_embed_ldflags"
2096   AC_MSG_CHECKING([for libperl])
2097   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2098 #include <EXTERN.h>
2099 #include <perl.h>
2100 ],  [perl_alloc();])],
2101     [AC_MSG_RESULT(yes)],
2102     [AC_MSG_RESULT(no)
2103      AC_MSG_ERROR([libperl library is required for Perl])])
2104   LIBS=$pgac_save_LIBS
2105   CPPFLAGS=$ac_save_CPPFLAGS
2106 fi
2107
2108 # check for <Python.h>
2109 if test "$with_python" = yes; then
2110   ac_save_CPPFLAGS=$CPPFLAGS
2111   CPPFLAGS="$python_includespec $CPPFLAGS"
2112   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2113   CPPFLAGS=$ac_save_CPPFLAGS
2114 fi
2115
2116 #
2117 # Check for DocBook and tools
2118 #
2119 PGAC_PROG_NSGMLS
2120 PGAC_CHECK_DOCBOOK(4.2)
2121 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
2122 AC_CHECK_PROGS(XMLLINT, xmllint)
2123 AC_CHECK_PROGS(XSLTPROC, xsltproc)
2124 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
2125 AC_CHECK_PROGS(FOP, fop)
2126
2127 #
2128 # Check for test tools
2129 #
2130 if test "$enable_tap_tests" = yes; then
2131   AC_CHECK_PROGS(PROVE, prove)
2132   if test -z "$PROVE"; then
2133     AC_MSG_ERROR([prove not found])
2134   fi
2135   if test -z "$PERL"; then
2136     AC_MSG_ERROR([Perl not found])
2137   fi
2138 fi
2139
2140 # Thread testing
2141
2142 # We have to run the thread test near the end so we have all our symbols
2143 # defined.  Cross compiling throws a warning.
2144 #
2145 if test "$enable_thread_safety" = yes; then
2146 if test "$PORTNAME" != "win32"
2147 then
2148 AC_MSG_CHECKING([thread safety of required library functions])
2149
2150 _CFLAGS="$CFLAGS"
2151 _LIBS="$LIBS"
2152 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2153 LIBS="$LIBS $PTHREAD_LIBS"
2154 AC_RUN_IFELSE(
2155   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2156   [AC_MSG_RESULT(yes)],
2157   [AC_MSG_RESULT(no)
2158   AC_MSG_ERROR([thread test program failed
2159 This platform is not thread-safe.  Check the file 'config.log' or compile
2160 and run src/test/thread/thread_test for the exact reason.
2161 Use --disable-thread-safety to disable thread safety.])],
2162   [AC_MSG_RESULT(maybe)
2163   AC_MSG_WARN([
2164 *** Skipping thread test program because of cross-compile build.
2165 *** Run the program in src/test/thread on the target machine.
2166 ])])
2167 CFLAGS="$_CFLAGS"
2168 LIBS="$_LIBS"
2169 else
2170 AC_MSG_WARN([*** skipping thread test on Win32])
2171 fi
2172 fi
2173
2174 # If compiler will take -Wl,--as-needed (or various platform-specific
2175 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2176 # trying to filter LIBS to the minimum for each executable.
2177 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2178 # libreadline; therefore we postpone testing it until we know what library
2179 # dependencies readline has.  The test code will try to link with $LIBS.
2180 if test "$with_readline" = yes; then
2181   link_test_func=readline
2182 else
2183   link_test_func=exit
2184 fi
2185
2186 if test "$PORTNAME" = "darwin"; then
2187   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2188 elif test "$PORTNAME" = "openbsd"; then
2189   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2190 else
2191   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2192 fi
2193
2194 # Create compiler version string
2195 if test x"$GCC" = x"yes" ; then
2196   cc_string=`${CC} --version | sed q`
2197   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2198 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2199   cc_string=`${CC} -V 2>&1 | sed q`
2200 else
2201   cc_string=$CC
2202 fi
2203
2204 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2205                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2206                    [A string containing the version number, platform, and C compiler])
2207
2208 # Supply a numeric version string for use by 3rd party add-ons
2209 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2210 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2211 tr '.' '        ' |
2212 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2213 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2214 AC_SUBST(PG_VERSION_NUM)
2215
2216
2217 # Begin output steps
2218
2219 AC_MSG_NOTICE([using compiler=$cc_string])
2220 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2221 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2222 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2223
2224 # prepare build tree if outside source tree
2225 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2226 # Note 2: /bin/pwd might be better than shell's built-in at getting
2227 #         a symlink-free name.
2228 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2229   vpath_build=no
2230 else
2231   vpath_build=yes
2232   if test "$no_create" != yes; then
2233     _AS_ECHO_N([preparing build tree... ])
2234     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2235     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2236       || AC_MSG_ERROR(failed)
2237     AC_MSG_RESULT(done)
2238   fi
2239 fi
2240 AC_SUBST(vpath_build)
2241
2242
2243 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2244
2245 AC_CONFIG_LINKS([
2246   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2247   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2248   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2249   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2250   src/include/pg_config_os.h:src/include/port/${template}.h
2251   src/Makefile.port:src/makefiles/Makefile.${template}
2252 ])
2253
2254 if test "$PORTNAME" = "win32"; then
2255 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2256 # Links sometimes fail undetected on Mingw -
2257 # so here we detect it and warn the user
2258 for FILE in $CONFIG_LINKS
2259  do
2260         # test -e works for symlinks in the MinGW console
2261         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2262  done
2263 ])
2264 fi
2265
2266 AC_CONFIG_HEADERS([src/include/pg_config.h],
2267 [
2268 # Update timestamp for pg_config.h (see Makefile.global)
2269 echo >src/include/stamp-h
2270 ])
2271
2272 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2273 [
2274 # Update timestamp for pg_config_ext.h (see Makefile.global)
2275 echo >src/include/stamp-ext-h
2276 ])
2277
2278 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2279                   [echo >src/interfaces/ecpg/include/stamp-h])
2280
2281 AC_OUTPUT