granicus.if.org Git - postgresql/blob - configure.in

   1 \dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.290 2003/09/15 14:32:35 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4beta3], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55 # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 #
 157 # NLS
 158 #
 159 AC_MSG_CHECKING([whether NLS is wanted])
 160 PGAC_ARG_OPTARG(enable, nls,
 161                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 162                 [],
 163                 [WANTED_LANGUAGES=$enableval],
 164                 [AC_DEFINE(ENABLE_NLS, 1,
 165                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 166 AC_MSG_RESULT([$enable_nls])
 167 AC_SUBST(enable_nls)
 168 AC_SUBST(WANTED_LANGUAGES)
 169
 170 #
 171 # Default port number (--with-pgport), default 5432
 172 #
 173 AC_MSG_CHECKING([for default port number])
 174 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 175              [default_port=$withval],
 176              [default_port=5432])
 177 AC_MSG_RESULT([$default_port])
 178 # Need both of these because some places want an integer and some a string
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 180 [Define to the default TCP port number on which the server listens and
 181 to which clients will try to connect.  This can be overridden at run-time,
 182 but it's convenient if your clients have the right default compiled in.
 183 (--with-pgport=PORTNUM)])
 184 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 185                    [Define to the default TCP port number as a string constant.])
 186 AC_SUBST(default_port)
 187
 188 #
 189 # Option to disable shared libraries
 190 #
 191 PGAC_ARG_BOOL(enable, shared, yes,
 192               [  --disable-shared        do not build shared libraries])
 193 AC_SUBST(enable_shared)
 194
 195 #
 196 # '-rpath'-like feature can be disabled
 197 #
 198 PGAC_ARG_BOOL(enable, rpath, yes,
 199               [  --disable-rpath         do not embed shared library search path in executables])
 200 AC_SUBST(enable_rpath)
 201
 202 #
 203 # Spinlocks
 204 #
 205 PGAC_ARG_BOOL(enable, spinlocks, yes,
 206               [  --disable-spinlocks     do not use Spinlocks])
 207
 208 #
 209 # --enable-debug adds -g to compiler flags
 210 #
 211 PGAC_ARG_BOOL(enable, debug, no,
 212               [  --enable-debug          build with debugging symbols (-g)])
 213 AC_SUBST(enable_debug)
 214
 215 #
 216 # C compiler
 217 #
 218
 219 # For historical reasons you can also use --with-CC to specify the C compiler
 220 # to use, although the standard way to do this is to set the CC environment
 221 # variable.
 222 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 223
 224 case $template in
 225   aix) pgac_cc_list="gcc xlc";;
 226  irix) pgac_cc_list="cc";; # no gcc
 227     *) pgac_cc_list="gcc cc";;
 228 esac
 229
 230 AC_PROG_CC([$pgac_cc_list])
 231
 232 #
 233 # Read the template
 234 #
 235 . "$srcdir/src/template/$template" || exit
 236
 237 # adjust CFLAGS per template
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 fi
 241 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 242   CFLAGS="$CFLAGS -g"
 243 fi
 244 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 245
 246 # We already have this in Makefile.win32, but configure needs it too
 247 if test "$PORTNAME" = "win32"
 248 then
 249         CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32"
 250 fi
 251
 252 # Check if the compiler still works with the template settings
 253 AC_MSG_CHECKING([whether the C compiler still works])
 254 AC_TRY_LINK([], [return 0;],
 255   [AC_MSG_RESULT(yes)],
 256   [AC_MSG_RESULT(no)
 257    AC_MSG_ERROR([cannot proceed])])
 258
 259 # Defend against gcc -ffastmath
 260 if test "$GCC" = yes; then
 261 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 262 choke me
 263 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 264 fi
 265
 266 AC_PROG_CPP
 267 AC_SUBST(GCC)
 268
 269 # Create compiler version string
 270 if test x"$GCC" = x"yes" ; then
 271   cc_string="GCC `${CC} --version | sed q`"
 272 else
 273   cc_string=$CC
 274 fi
 275 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 276                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 277                    [A string containing the version number, platform, and C compiler])
 278
 279
 280 #
 281 # Automatic dependency tracking
 282 #
 283 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 284               [autodepend=yes])
 285 AC_SUBST(autodepend)
 286
 287
 288 #
 289 # Enable assert checks
 290 #
 291 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 292               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 293                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 294
 295
 296 #
 297 # Include directories
 298 #
 299 ac_save_IFS=$IFS
 300 IFS="${IFS}:"
 301 # SRCH_INC comes from the template file
 302 for dir in $with_includes $SRCH_INC; do
 303   if test -d "$dir"; then
 304     INCLUDES="$INCLUDES -I$dir"
 305   else
 306     AC_MSG_WARN([*** Include directory $dir does not exist.])
 307   fi
 308 done
 309 IFS=$ac_save_IFS
 310 AC_SUBST(INCLUDES)
 311
 312
 313 #
 314 # Library directories
 315 #
 316 ac_save_IFS=$IFS
 317 IFS="${IFS}:"
 318 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 319 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 320   if test -d "$dir"; then
 321     LIBDIRS="$LIBDIRS -L$dir"
 322   else
 323     AC_MSG_WARN([*** Library directory $dir does not exist.])
 324   fi
 325 done
 326 IFS=$ac_save_IFS
 327
 328 #
 329 # Enable thread-safe client libraries
 330 #
 331 AC_MSG_CHECKING([allow thread-safe client libraries])
 332 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 333               [AC_DEFINE([USE_THREADS], 1,
 334                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 335 AC_MSG_RESULT([$enable_thread_safety])
 336 AC_SUBST(enable_thread_safety)
 337
 338 #
 339 # Tcl/Tk
 340 #
 341 AC_MSG_CHECKING([whether to build with Tcl])
 342 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 343 AC_MSG_RESULT([$with_tcl])
 344 AC_SUBST([with_tcl])
 345
 346 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 347 AC_MSG_CHECKING([whether to build with Tk])
 348 if test "$with_tcl" = yes; then
 349   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 350 else
 351   with_tk=no
 352 fi
 353 AC_MSG_RESULT([$with_tk])
 354 AC_SUBST([with_tk])
 355
 356
 357 # We see if the path to the Tcl/Tk configuration scripts is specified.
 358 # This will override the use of tclsh to find the paths to search.
 359
 360 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 361
 362 # We see if the path to the Tk configuration scripts is specified.
 363 # This will override the use of tclsh to find the paths to search.
 364
 365 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 366
 367 #
 368 # Optionally build Perl modules (PL/Perl)
 369 #
 370 AC_MSG_CHECKING([whether to build Perl modules])
 371 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 372 AC_MSG_RESULT([$with_perl])
 373 AC_SUBST(with_perl)
 374
 375 #
 376 # Optionally build Python modules (PL/Python)
 377 #
 378 AC_MSG_CHECKING([whether to build Python modules])
 379 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 380 AC_MSG_RESULT([$with_python])
 381 AC_SUBST(with_python)
 382
 383 #
 384 # Optionally build the Java/JDBC tools
 385 #
 386 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 387 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 388 [AC_MSG_RESULT(yes)
 389 PGAC_PATH_ANT
 390 if test -z "$ANT"; then
 391   AC_MSG_ERROR([Ant is required to build Java components
 392 If you have Ant already installed, see config.log for details on the failure.])
 393 fi
 394 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 395   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 396 fi],
 397 [AC_MSG_RESULT(no)])
 398 AC_SUBST(with_java)
 399
 400 dnl A note on the Kerberos and OpenSSL options:
 401 dnl
 402 dnl The user can give an argument to the option in order the specify
 403 dnl the base path of the respective installation (what he specified
 404 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 405 dnl then we take the path where the package installs by default. This
 406 dnl way the user doesn't have to use redundant --with-includes and
 407 dnl --with-libraries options, but he can still use them if the layout
 408 dnl is non-standard.
 409
 410 #
 411 # Kerberos 4
 412 #
 413 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 414 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 415                 [krb4_prefix=/usr/athena],
 416                 [krb4_prefix=$withval],
 417 [
 418   AC_MSG_RESULT(yes)
 419   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 420
 421   if test -d "$krb4_prefix/include"; then
 422     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 423   fi
 424   if test -d "$krb4_prefix/lib"; then
 425     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 426   fi
 427
 428   krb_srvtab="/etc/srvtab"
 429 ],
 430 [AC_MSG_RESULT(no)])
 431
 432 AC_SUBST(with_krb4)
 433
 434
 435 #
 436 # Kerberos 5
 437 #
 438 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 439 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 440               [krb5_prefix=/usr/athena],
 441               [krb5_prefix=$withval],
 442 [
 443   AC_MSG_RESULT([yes])
 444   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 445
 446   if test -d "$krb5_prefix/include"; then
 447     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 448   fi
 449   if test -d "$krb5_prefix/lib"; then
 450     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 451   fi
 452
 453   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 454 ],
 455 [AC_MSG_RESULT(no)])
 456
 457 AC_SUBST(with_krb5)
 458
 459
 460 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 461 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 462   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 463 fi
 464
 465 AC_SUBST(krb_srvtab)
 466
 467
 468 #
 469 # Kerberos configuration parameters
 470 #
 471 PGAC_ARG_REQ(with, krb-srvnam,
 472              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 473              [],
 474              [with_krb_srvnam="postgres"])
 475 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 476                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 477
 478
 479 #
 480 # PAM
 481 #
 482 AC_MSG_CHECKING([whether to build with PAM support])
 483 PGAC_ARG_BOOL(with, pam, no,
 484               [  --with-pam              build with PAM support],
 485               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 486 AC_MSG_RESULT([$with_pam])
 487 AC_SUBST(with_pam)
 488
 489
 490 #
 491 # Rendezvous
 492 #
 493 AC_MSG_CHECKING([whether to build with Rendezvous support])
 494 PGAC_ARG_BOOL(with, rendezvous, no,
 495               [  --with-rendezvous       build with Rendezvous support],
 496               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 497 AC_MSG_RESULT([$with_rendezvous])
 498 AC_SUBST(with_rendezvous)
 499
 500
 501 #
 502 # OpenSSL
 503 #
 504 PGAC_ARG_OPTARG(with, openssl,
 505                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 506                 [openssl_prefix=/usr/local/ssl],
 507                 [openssl_prefix=$withval],
 508 [
 509   AC_MSG_RESULT([building with OpenSSL support])
 510   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 511
 512   if test -d "${openssl_prefix}/include" ; then
 513     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 514   fi
 515   if test -d "${openssl_prefix}/lib" ; then
 516     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 517   fi
 518 ])
 519
 520 AC_SUBST(with_openssl)
 521
 522
 523 #
 524 # Readline
 525 #
 526 PGAC_ARG_BOOL(with, readline, yes,
 527               [  --without-readline      do not use Readline])
 528
 529 #
 530 # Zlib
 531 #
 532 PGAC_ARG_BOOL(with, zlib, yes,
 533               [  --without-zlib          do not use Zlib])
 534
 535 #
 536 # Elf
 537 #
 538
 539 # Assume system is ELF if it predefines __ELF__ as 1,
 540 # otherwise believe host_os based default.
 541 case $host_os in
 542     freebsd1*|freebsd2*) elf=no;;
 543     freebsd3*|freebsd4*) elf=yes;;
 544 esac
 545
 546 AC_EGREP_CPP(yes,
 547 [#if __ELF__
 548   yes
 549 #endif
 550 ],
 551 [ELF_SYS=true],
 552 [if test "X$elf" = "Xyes" ; then
 553   ELF_SYS=true
 554 else
 555   ELF_SYS=
 556 fi])
 557 AC_SUBST(ELF_SYS)
 558
 559 #
 560 # Assignments
 561 #
 562
 563 CPPFLAGS="$CPPFLAGS $INCLUDES"
 564 LDFLAGS="$LDFLAGS $LIBDIRS"
 565
 566 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 567 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 568
 569
 570 AC_PROG_AWK
 571 PGAC_PATH_FLEX
 572 AC_PROG_LN_S
 573 AC_PROG_LD
 574 AC_SUBST(LD)
 575 AC_SUBST(with_gnu_ld)
 576 case $host_os in sysv5*)
 577   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 578   [
 579     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 580     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 581     LDFLAGS=$pgac_save_LDFLAGS
 582   ])
 583   ld_R_works=$pgac_cv_prog_ld_R
 584   AC_SUBST(ld_R_works)
 585 esac
 586 AC_PROG_RANLIB
 587 AC_CHECK_PROGS(LORDER, lorder)
 588 AC_PATH_PROG(TAR, tar)
 589 PGAC_CHECK_STRIP
 590
 591 AC_CHECK_PROGS(YACC, ['bison -y'])
 592
 593 if test "$YACC"; then
 594   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 595     AC_MSG_WARN([
 596 *** The installed version of Bison is too old.  PostgreSQL needs
 597 *** Bison version 1.875 or later.])
 598   fi
 599 fi
 600
 601 if test -z "$YACC"; then
 602   AC_MSG_WARN([
 603 *** Without Bison you will not be able to build PostgreSQL from CVS or
 604 *** change any of the parser definition files.  You can obtain Bison from
 605 *** a GNU mirror site.  (If you are using the official distribution of
 606 *** PostgreSQL then you do not need to worry about this because the Bison
 607 *** output is pre-generated.)  To use a different yacc program (possible,
 608 *** but not recommended), set the environment variable YACC before running
 609 *** 'configure'.])
 610 fi
 611 AC_SUBST(YFLAGS)
 612
 613 PGAC_PATH_PERL
 614 if test "$with_perl" = yes; then
 615   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 616   PGAC_CHECK_PERL_EMBED_LDFLAGS
 617 fi
 618
 619 if test "$with_python" = yes; then
 620   PGAC_PATH_PYTHON
 621   PGAC_CHECK_PYTHON_EMBED_SETUP
 622 fi
 623
 624
 625 ##
 626 ## Libraries
 627 ##
 628
 629 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 630 then
 631         AC_CHECK_LIB(bsd,      main)
 632 fi
 633 AC_CHECK_LIB(util,     setproctitle)
 634 AC_CHECK_LIB(m,        main)
 635 AC_CHECK_LIB(dl,       main)
 636 AC_CHECK_LIB(nsl,      main)
 637 AC_CHECK_LIB(socket,   main)
 638 AC_CHECK_LIB(ipc,      main)
 639 AC_CHECK_LIB(IPC,      main)
 640 AC_CHECK_LIB(lc,       main)
 641 AC_CHECK_LIB(dld,      main)
 642 AC_CHECK_LIB(ld,       main)
 643 AC_CHECK_LIB(compat,   main)
 644 AC_CHECK_LIB(BSD,      main)
 645 AC_CHECK_LIB(gen,      main)
 646 AC_CHECK_LIB(PW,       main)
 647 AC_CHECK_LIB(resolv,   main)
 648 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 649 # QNX:
 650 AC_CHECK_LIB(unix, main)
 651 AC_SEARCH_LIBS(crypt,  crypt)
 652 # BeOS:
 653 if test "$PORTNAME" = "beos"
 654 then
 655         AC_CHECK_LIB(bind, __inet_ntoa)
 656 fi
 657 # Solaris:
 658 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 659 # Cygwin:
 660 AC_CHECK_LIB(cygipc, shmget)
 661 # WIN32:
 662 if test "$PORTNAME" = "win32"
 663 then
 664         AC_CHECK_LIB(wsock32, main)
 665 fi
 666
 667 if test "$with_readline" = yes; then
 668   PGAC_CHECK_READLINE
 669   if test x"$pgac_cv_check_readline" = x"no"; then
 670     AC_MSG_ERROR([readline library not found
 671 If you have readline already installed, see config.log for details on the
 672 failure.  It is possible the compiler isn't looking in the proper directory.
 673 Use --without-readline to disable readline support.])
 674   fi
 675 fi
 676
 677 if test "$with_zlib" = yes; then
 678   AC_CHECK_LIB(z, inflate, [],
 679                [AC_MSG_ERROR([zlib library not found
 680 If you have zlib already installed, see config.log for details on the
 681 failure.  It is possible the compiler isn't looking in the proper directory.
 682 Use --without-zlib to disable zlib support.])])
 683 fi
 684
 685 if test "$enable_spinlocks" = yes; then
 686   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 687 else
 688   AC_MSG_WARN([
 689 *** Not using spinlocks will cause poor performance.])
 690 fi
 691
 692 if test "$with_krb4" = yes ; then
 693   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 694   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 695   AC_REPLACE_FUNCS([gethostname])
 696 fi
 697
 698 if test "$with_krb5" = yes ; then
 699   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 700                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 701   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 702                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 703   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 704                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 705 fi
 706
 707 if test "$with_openssl" = yes ; then
 708   dnl Order matters!
 709   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 710   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 711 fi
 712
 713 if test "$with_pam" = yes ; then
 714   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 715 fi
 716
 717
 718 ##
 719 ## Header files
 720 ##
 721
 722 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 723 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 724
 725 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 726 # netinet/in.h is included first.
 727 AC_CHECK_HEADERS(netinet/in.h)
 728 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 729 [AC_INCLUDES_DEFAULT
 730 #ifdef HAVE_NETINET_IN_H
 731 #include <netinet/in.h>
 732 #endif
 733 ])
 734
 735 if test "$with_readline" = yes; then
 736   AC_CHECK_HEADERS(readline/readline.h, [],
 737                    [AC_CHECK_HEADERS(editline/readline.h, [],
 738                          [AC_CHECK_HEADERS(readline.h, [],
 739                                      [AC_MSG_ERROR([readline header not found
 740 If you have readline already installed, see config.log for details on the
 741 failure.  It is possible the compiler isn't looking in the proper directory.
 742 Use --without-readline to disable readline support.])])])])
 743   AC_CHECK_HEADERS(readline/history.h, [],
 744                    [AC_CHECK_HEADERS(editline/history.h, [],
 745                          [AC_CHECK_HEADERS(history.h, [],
 746                                      [AC_MSG_ERROR([history header not found
 747 If you have readline already installed, see config.log for details on the
 748 failure.  It is possible the compiler isn't looking in the proper directory.
 749 Use --without-readline to disable readline support.])])])])
 750 fi
 751
 752 if test "$with_zlib" = yes; then
 753   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 754 If you have zlib already installed, see config.log for details on the
 755 failure.  It is possible the compiler isn't looking in the proper directory.
 756 Use --without-zlib to disable zlib support.])])
 757 fi
 758
 759 if test "$with_krb4" = yes ; then
 760   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 761 fi
 762
 763 if test "$with_krb5" = yes ; then
 764   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 765   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 766 fi
 767
 768 if test "$with_openssl" = yes ; then
 769   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 770   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 771 fi
 772
 773 if test "$with_pam" = yes ; then
 774   AC_CHECK_HEADERS(security/pam_appl.h, [],
 775                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 776                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 777 fi
 778
 779 if test "$with_rendezvous" = yes ; then
 780   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 781 fi
 782
 783
 784 ##
 785 ## Types, structures, compiler characteristics
 786 ##
 787
 788 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 789 AC_C_CONST
 790 AC_C_INLINE
 791 AC_C_STRINGIZE
 792 PGAC_C_SIGNED
 793 AC_C_VOLATILE
 794 PGAC_C_FUNCNAME_SUPPORT
 795 PGAC_STRUCT_TIMEZONE
 796 PGAC_UNION_SEMUN
 797 PGAC_STRUCT_SOCKADDR_UN
 798 PGAC_STRUCT_SOCKADDR_STORAGE
 799 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 800 PGAC_STRUCT_ADDRINFO
 801
 802 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 803 [#include <sys/param.h>
 804 #include <sys/types.h>
 805 #include <sys/socket.h>
 806 #include <sys/ucred.h>])
 807
 808 AC_CHECK_TYPES([struct option], [], [],
 809 [#ifdef HAVE_GETOPT_H
 810 #include <getopt.h>
 811 #endif])
 812
 813 if test "$with_zlib" = yes; then
 814   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 815   # did not).  While we could work around the lack of z_streamp, it
 816   # seems unwise to encourage people to use such old zlib versions...
 817   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 818 Use --without-zlib to disable zlib support.])],
 819                 [#include <zlib.h>])
 820 fi
 821
 822 if test "$with_krb5" = yes; then
 823 # Check for differences between MIT and Heimdal (KTH) releases
 824   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 825                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 826                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 827                                      [#include <krb5.h>])],
 828                    [#include <krb5.h>])
 829   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 830                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 831                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 832                                      [#include <krb5.h>])],
 833                    [#include <krb5.h>])
 834 fi
 835
 836
 837 ##
 838 ## Functions, global variables
 839 ##
 840
 841 PGAC_VAR_INT_TIMEZONE
 842 AC_FUNC_ACCEPT_ARGTYPES
 843 PGAC_FUNC_GETTIMEOFDAY_1ARG
 844
 845 # SunOS doesn't handle negative byte comparisons properly with +/- return
 846 AC_FUNC_MEMCMP
 847
 848 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 849
 850 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 851
 852 HAVE_IPV6=no
 853 AC_CHECK_TYPE([struct sockaddr_in6],
 854               [AC_CHECK_FUNC(inet_ntop,
 855                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 856                                                           HAVE_IPV6=yes])],
 857               [],
 858 [$ac_includes_default
 859 #include <netinet/in.h>])
 860 AC_SUBST(HAVE_IPV6)
 861
 862 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 863 [AC_TRY_LINK(
 864 [#include <machine/vmparam.h>
 865 #include <sys/exec.h>
 866 ],
 867 [PS_STRINGS->ps_nargvstr = 1;
 868 PS_STRINGS->ps_argvstr = "foo";],
 869 [pgac_cv_var_PS_STRINGS=yes],
 870 [pgac_cv_var_PS_STRINGS=no])])
 871 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 872   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 873 fi
 874
 875
 876 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 877 # is missing.  Yes, there are machines that have only one.  We may
 878 # also decide to use snprintf.c if snprintf() is present but does not
 879 # have working "long long int" support -- see below.
 880
 881 pgac_need_repl_snprintf=no
 882 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 883 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 884
 885
 886 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 887 # include/c.h will provide declarations.  Note this is a separate test
 888 # from whether the functions exist in the C library --- there are
 889 # systems that have the functions but don't bother to declare them :-(
 890
 891 AC_CHECK_DECLS([snprintf, vsnprintf])
 892
 893
 894 # do this one the hard way in case isinf() is a macro
 895 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 896 [AC_TRY_LINK(
 897 [#include <math.h>
 898 ],
 899 [double x = 0.0; int res = isinf(x);],
 900 [ac_cv_func_isinf=yes],
 901 [ac_cv_func_isinf=no])])
 902
 903 if test $ac_cv_func_isinf = yes ; then
 904   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 905 else
 906   AC_LIBOBJ(isinf)
 907   # Look for a way to implement a substitute for isinf()
 908   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 909 fi
 910
 911 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 912
 913 # system's version of getaddrinfo(), if any, may be used only if we found
 914 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 915 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 916   AC_REPLACE_FUNCS([getaddrinfo])
 917 else
 918   AC_LIBOBJ(getaddrinfo)
 919 fi
 920
 921 # similarly, use system's getopt_long() only if system provides struct option.
 922 if test x"$ac_cv_type_struct_option" = xyes ; then
 923   AC_REPLACE_FUNCS([getopt_long])
 924 else
 925   AC_LIBOBJ(getopt_long)
 926 fi
 927
 928 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 929 # We override the previous test that said fseeko/ftello didn't exist
 930 # OS tests are also done in include/c.h and port/fseeko.c
 931 case $host_os in bsdi*|netbsd*)
 932 ac_cv_func_fseeko=yes
 933 esac
 934
 935 # Solaris has a very slow qsort in certain cases, so we replace it.
 936 case $host_os in solaris*)
 937 AC_LIBOBJ(qsort) ;;
 938 esac
 939
 940 # Win32 can't to rename or unlink on an open file
 941 case $host_os in mingw*)
 942 AC_LIBOBJ(dirmod)
 943 AC_LIBOBJ(copydir)
 944 AC_LIBOBJ(gettimeofday) ;;
 945 esac
 946
 947 if test "$with_readline" = yes; then
 948   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 949   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 950   AC_CHECK_FUNCS([replace_history_entry])
 951 fi
 952
 953
 954 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 955 AC_MSG_CHECKING(for finite)
 956 AC_TRY_LINK([#include <math.h>],
 957             [int dummy=finite(1.0);],
 958             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 959 AC_MSG_RESULT(yes)],
 960             [AC_MSG_RESULT(no)])
 961
 962 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 963 dnl (especially on GNU libc)
 964 dnl See also comments in c.h.
 965 AC_MSG_CHECKING(for sigsetjmp)
 966 AC_TRY_LINK([#include <setjmp.h>],
 967             [sigjmp_buf x; sigsetjmp(x, 1);],
 968             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 969 AC_MSG_RESULT(yes)],
 970             [AC_MSG_RESULT(no)])
 971
 972 AC_CHECK_FUNC(syslog,
 973               [AC_CHECK_HEADER(syslog.h,
 974                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 975
 976 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 977 [AC_TRY_LINK([#include <unistd.h>],
 978   [extern int optreset; optreset = 1;],
 979   [pgac_cv_var_int_optreset=yes],
 980   [pgac_cv_var_int_optreset=no])])
 981 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 982   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 983 fi
 984
 985 AC_CHECK_FUNCS([strtoll strtoq], [break])
 986 AC_CHECK_FUNCS([strtoull strtouq], [break])
 987
 988 # Check for one of atexit() or on_exit()
 989 AC_CHECK_FUNCS(atexit, [],
 990                [AC_CHECK_FUNCS(on_exit, [],
 991                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 992
 993 AC_FUNC_FSEEKO
 994
 995 #
 996 # Pthreads
 997 #
 998 # For each platform, we need to know about any special compile and link
 999 # libraries, and whether the normal C function names are thread-safe.
1000 # See the comment at the top of src/port/thread.c for more information.
1001 #
1002 if test "$enable_thread_safety" = yes; then
1003 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
1004
1005 if test "$SUPPORTS_THREADS" != yes; then
1006 AC_MSG_ERROR([
1007 Cannot enable threads on your platform.
1008 Please report your platform threading info to the PostgreSQL mailing lists
1009 so it can be added to the next release.  Report all compile flags, link flags,
1010 functions, or libraries required for threading support.
1011 See the comment at the top of src/port/thread.c for more information.
1012 ])
1013 fi
1014 else
1015 # do not use values from template file
1016 THREAD_CFLAGS=
1017 THREAD_LIBS=
1018 fi
1019 AC_SUBST(THREAD_CFLAGS)
1020 AC_SUBST(THREAD_LIBS)
1021
1022
1023 #
1024 # Check for re-entrant versions of certain functions
1025 #
1026 # Include special flags if threads are enabled _and_ if required for
1027 # threading on this platform.  Some platforms have *_r functions but
1028 # their natively named funcs are threadsafe, and should be used instead.
1029 #
1030 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1031 # functions are marked "not found", which is perfect.
1032 #
1033 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNCS" = yes ; then
1034 _CFLAGS="$CFLAGS"
1035 _LIBS="$LIBS"
1036 CFLAGS="$CFLAGS $THREAD_CFLAGS"
1037 LIBS="$LIBS $THREAD_LIBS"
1038 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1039 CFLAGS="$_CFLAGS"
1040 LIBS="$_LIBS"
1041 fi
1042
1043
1044 # This test makes sure that run tests work at all.  Sometimes a shared
1045 # library is found by the linker, but the runtime linker can't find it.
1046 # This check should come after all modifications of compiler or linker
1047 # variables, and before any other run tests.
1048 AC_MSG_CHECKING([test program])
1049 AC_TRY_RUN([int main() { return 0; }],
1050 [AC_MSG_RESULT(ok)],
1051 [AC_MSG_RESULT(failed)
1052 AC_MSG_ERROR([[
1053 *** Could not execute a simple test program.  This may be a problem
1054 *** related to locating shared libraries.  Check the file 'config.log'
1055 *** for the exact reason.]])],
1056 [AC_MSG_RESULT([cross-compiling])])
1057
1058
1059 dnl Check to see if we have a working 64-bit integer type.
1060 dnl This breaks down into two steps:
1061 dnl (1) figure out if the compiler has a 64-bit int type with working
1062 dnl arithmetic, and if so
1063 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1064 dnl snprintf is the only library routine we really need for int8 support.)
1065 dnl It's entirely possible to have a compiler that handles a 64-bit type
1066 dnl when the C library doesn't; this is fairly likely when using gcc on
1067 dnl an older platform, for example.
1068 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1069 dnl we force our own version of snprintf() to be used instead.
1070 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1071
1072 PGAC_TYPE_64BIT_INT([long int])
1073
1074 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1075   PGAC_TYPE_64BIT_INT([long long int])
1076 fi
1077
1078
1079 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1080
1081 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1082   AC_TRY_COMPILE([
1083 #define INT64CONST(x)  x##LL
1084 long long int foo = INT64CONST(0x1234567890123456);
1085 ],
1086         [],
1087         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1088         [])
1089 fi
1090
1091
1092 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1093 # we found we need to use "long long int", better check.  We cope with
1094 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1095 # neither works, fall back to our own snprintf emulation (which we
1096 # know uses %lld).
1097
1098 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1099   if test $pgac_need_repl_snprintf = no; then
1100     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1101     if test "$LONG_LONG_INT_FORMAT" = ""; then
1102       # Force usage of our own snprintf, since system snprintf is broken
1103       pgac_need_repl_snprintf=yes
1104       LONG_LONG_INT_FORMAT='%lld'
1105     fi
1106   else
1107     # Here if we previously decided we needed to use our own snprintf
1108     LONG_LONG_INT_FORMAT='%lld'
1109   fi
1110   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1111 else
1112   # Here if we are not using 'long long int' at all
1113   INT64_FORMAT='"%ld"'
1114 fi
1115
1116 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1117                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1118
1119 if test $pgac_need_repl_snprintf = yes; then
1120   AC_LIBOBJ(snprintf)
1121 fi
1122
1123 # Need a #define for the size of Datum (unsigned long)
1124 AC_CHECK_SIZEOF([unsigned long])
1125
1126 # Determine memory alignment requirements for the basic C data types.
1127
1128 PGAC_CHECK_ALIGNOF(short)
1129 PGAC_CHECK_ALIGNOF(int)
1130 PGAC_CHECK_ALIGNOF(long)
1131 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1132   PGAC_CHECK_ALIGNOF(long long int)
1133 fi
1134 PGAC_CHECK_ALIGNOF(double)
1135
1136 # Compute maximum alignment of any basic type.
1137 # We assume long's alignment is at least as strong as char, short, or int;
1138 # but we must check long long (if it exists) and double.
1139
1140 MAX_ALIGNOF=$pgac_cv_alignof_long
1141 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1142   MAX_ALIGNOF=$pgac_cv_alignof_double
1143 fi
1144 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1145   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1146 fi
1147 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1148
1149
1150 # Some platforms predefine the types int8, int16, etc.  Only check
1151 # a (hopefully) representative subset.
1152 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1153 [#include <stdio.h>
1154 #ifdef HAVE_SUPPORTDEFS_H
1155 #include <SupportDefs.h>
1156 #endif])
1157
1158 # We also check for sig_atomic_t, which *should* be defined per ANSI
1159 # C, but is missing on some old platforms.
1160 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1161
1162
1163 PGAC_FUNC_POSIX_SIGNALS
1164 if test $ac_cv_func_fseeko = yes; then
1165 AC_SYS_LARGEFILE
1166 fi
1167
1168
1169 # Select semaphore implementation type.
1170 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1171   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1172   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1173 else
1174   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1175     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1176     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1177   else
1178     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1179     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1180   fi
1181 fi
1182
1183
1184 # Select shared-memory implementation type.
1185 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1186 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1187
1188
1189 if test "$enable_nls" = yes ; then
1190   PGAC_CHECK_GETTEXT
1191 fi
1192
1193 # Check for Tcl configuration script tclConfig.sh
1194 if test "$with_tcl" = yes; then
1195     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1196     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1197                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1198     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1199 fi
1200
1201 # Check for Tk configuration script tkConfig.sh
1202 if test "$with_tk" = yes; then
1203     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1204     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1205 fi
1206
1207
1208 #
1209 # Check for DocBook and tools
1210 #
1211 PGAC_PROG_NSGMLS
1212 PGAC_PROG_JADE
1213 PGAC_CHECK_DOCBOOK(3.1)
1214 PGAC_PATH_DOCBOOK_STYLESHEETS
1215 PGAC_PATH_COLLATEINDEX
1216 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1217
1218
1219 # prepare build tree if outside source tree
1220 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1221 # Note 2: /bin/pwd might be better than shell's built-in at getting
1222 #         a symlink-free name.
1223 if test "$no_create" != yes; then
1224   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1225     :
1226   else
1227     AC_SUBST(vpath_build, yes)
1228     _AS_ECHO_N([preparing build tree... ])
1229     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1230     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1231       || AC_MSG_ERROR(failed)
1232     AC_MSG_RESULT(done)
1233   fi
1234 fi
1235
1236
1237 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1238
1239 AC_CONFIG_LINKS([
1240   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1241   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1242   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1243   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1244   src/include/pg_config_os.h:src/include/port/${template}.h
1245   src/Makefile.port:src/makefiles/Makefile.${template}
1246 ])
1247
1248 AC_CONFIG_HEADERS([src/include/pg_config.h],
1249 [
1250 # Update timestamp for pg_config.h (see Makefile.global)
1251 echo >src/include/stamp-h
1252 ])
1253
1254 AC_OUTPUT