granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.502 2007/02/21 15:12:39 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2007, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # --enable-profiling enables gcc profiling
 210 #
 211 PGAC_ARG_BOOL(enable, profiling, no,
 212               [  --enable-profiling      build with profiling enabled ])
 213 AC_SUBST(enable_profiling)
 214
 215 #
 216 # DTrace
 217 #
 218 PGAC_ARG_BOOL(enable, dtrace, no,
 219               [  --enable-dtrace         build with DTrace support],
 220 [AC_DEFINE([ENABLE_DTRACE], 1,
 221            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 222 AC_CHECK_PROGS(DTRACE, dtrace)
 223 if test -z "$DTRACE"; then
 224   AC_MSG_ERROR([dtrace not found])
 225 fi
 226 AC_SUBST(DTRACEFLAGS)])
 227 AC_SUBST(enable_dtrace)
 228
 229 #
 230 # C compiler
 231 #
 232
 233 # For historical reasons you can also use --with-CC to specify the C compiler
 234 # to use, although the standard way to do this is to set the CC environment
 235 # variable.
 236 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 237
 238 case $template in
 239   aix) pgac_cc_list="gcc xlc";;
 240  irix) pgac_cc_list="cc";; # no gcc
 241     *) pgac_cc_list="gcc cc";;
 242 esac
 243
 244 AC_PROG_CC([$pgac_cc_list])
 245
 246 unset CFLAGS
 247
 248 #
 249 # Read the template
 250 #
 251 . "$srcdir/src/template/$template" || exit
 252
 253 # CFLAGS are selected so:
 254 # If the user specifies something in the environment, that is used.
 255 # else:  If the template file set something, that is used.
 256 # else:  If the compiler is GCC, then we use -O2.
 257 # else:  If the compiler is something else, then we use -0.
 258
 259 if test "$ac_env_CFLAGS_set" = set; then
 260   CFLAGS=$ac_env_CFLAGS_value
 261 elif test "${CFLAGS+set}" = set; then
 262   : # (keep what template set)
 263 elif test "$GCC" = yes; then
 264   CFLAGS="-O2"
 265 else
 266   # if the user selected debug mode, don't use -O
 267   if test "$enable_debug" != yes; then
 268     CFLAGS="-O"
 269   fi
 270 fi
 271
 272 # Some versions of GCC support some additional useful warning flags.
 273 # Check whether they are supported, and add them to CFLAGS if so.
 274
 275 if test "$GCC" = yes; then
 276
 277 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 278 # So we have to check if "GCC" is really ICC.
 279 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 280 choke me
 281 @%:@endif], [ICC=[yes]], [ICC=[no]])
 282
 283   if test "$ICC" = no; then
 284     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 285
 286     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 287     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 288   else
 289     # Intel compiler has a bug/misoptimization in checking for
 290     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 291     # CFLAGS.
 292     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 293   fi
 294
 295   # Disable strict-aliasing rules; needed for gcc 3.3+
 296   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 297 elif test x"${CC}" = x"xlc"; then
 298   # AIX xlc has to have strict aliasing turned off too
 299   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 300 fi
 301
 302 # supply -g if --enable-debug
 303 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 304   CFLAGS="$CFLAGS -g"
 305 fi
 306
 307 # enable profiling if --enable-profiling
 308 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 309   if test "$GCC" = yes; then
 310     AC_DEFINE([PROFILE_PID_DIR], 1,
 311            [Define to 1 to enable profiling. (--enable-profiling)])
 312     CFLAGS="$CFLAGS -pg"
 313   else
 314     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 315   fi
 316 fi
 317
 318 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 319
 320 # We already have this in Makefile.win32, but configure needs it too
 321 if test "$PORTNAME" = "win32"; then
 322   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 323 fi
 324
 325 # Check if the compiler still works with the template settings
 326 AC_MSG_CHECKING([whether the C compiler still works])
 327 AC_TRY_LINK([], [return 0;],
 328   [AC_MSG_RESULT(yes)],
 329   [AC_MSG_RESULT(no)
 330    AC_MSG_ERROR([cannot proceed])])
 331
 332 # Defend against gcc -ffast-math
 333 if test "$GCC" = yes; then
 334 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 335 choke me
 336 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 337 fi
 338
 339 AC_PROG_CPP
 340 AC_SUBST(GCC)
 341
 342 # Create compiler version string
 343 if test x"$GCC" = x"yes" ; then
 344   cc_string="GCC `${CC} --version | sed q`"
 345 else
 346   cc_string=$CC
 347 fi
 348 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 349                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 350                    [A string containing the version number, platform, and C compiler])
 351
 352
 353 #
 354 # Set up TAS assembly code if needed; the template file has now had its
 355 # chance to request this.
 356 #
 357 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 358
 359 if test "$need_tas" = yes ; then
 360   TAS=tas.o
 361 else
 362   TAS=""
 363 fi
 364 AC_SUBST(TAS)
 365
 366
 367 #
 368 # Automatic dependency tracking
 369 #
 370 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 371               [autodepend=yes])
 372 AC_SUBST(autodepend)
 373
 374
 375 #
 376 # Enable assert checks
 377 #
 378 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 379               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 380                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 381
 382
 383 #
 384 # Include directories
 385 #
 386 ac_save_IFS=$IFS
 387 IFS="${IFS}${PATH_SEPARATOR}"
 388 # SRCH_INC comes from the template file
 389 for dir in $with_includes $SRCH_INC; do
 390   if test -d "$dir"; then
 391     INCLUDES="$INCLUDES -I$dir"
 392   else
 393     AC_MSG_WARN([*** Include directory $dir does not exist.])
 394   fi
 395 done
 396 IFS=$ac_save_IFS
 397 AC_SUBST(INCLUDES)
 398
 399
 400 #
 401 # Library directories
 402 #
 403 ac_save_IFS=$IFS
 404 IFS="${IFS}${PATH_SEPARATOR}"
 405 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 406 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 407   if test -d "$dir"; then
 408     LIBDIRS="$LIBDIRS -L$dir"
 409   else
 410     AC_MSG_WARN([*** Library directory $dir does not exist.])
 411   fi
 412 done
 413 IFS=$ac_save_IFS
 414
 415 #
 416 # Enable thread-safe client libraries
 417 #
 418 AC_MSG_CHECKING([allow thread-safe client libraries])
 419 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 420 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 421 if test "$enable_thread_safety" = yes -o \
 422         "$enable_thread_safety_force" = yes; then
 423   enable_thread_safety="yes"    # for 'force'
 424   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 425           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 426 fi
 427 AC_MSG_RESULT([$enable_thread_safety])
 428 AC_SUBST(enable_thread_safety)
 429
 430 #
 431 # Optionally build Tcl modules (PL/Tcl)
 432 #
 433 AC_MSG_CHECKING([whether to build with Tcl])
 434 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 435 AC_MSG_RESULT([$with_tcl])
 436 AC_SUBST([with_tcl])
 437
 438 # We see if the path to the Tcl/Tk configuration scripts is specified.
 439 # This will override the use of tclsh to find the paths to search.
 440
 441 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 442
 443 #
 444 # Optionally build Perl modules (PL/Perl)
 445 #
 446 AC_MSG_CHECKING([whether to build Perl modules])
 447 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 448 AC_MSG_RESULT([$with_perl])
 449 AC_SUBST(with_perl)
 450
 451 #
 452 # Optionally build Python modules (PL/Python)
 453 #
 454 AC_MSG_CHECKING([whether to build Python modules])
 455 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 456 AC_MSG_RESULT([$with_python])
 457 AC_SUBST(with_python)
 458
 459 #
 460 # Kerberos 5
 461 #
 462 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 463 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 464 [
 465   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 466   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 467 ])
 468 AC_MSG_RESULT([$with_krb5])
 469 AC_SUBST(with_krb5)
 470
 471
 472 AC_SUBST(krb_srvtab)
 473
 474
 475 #
 476 # Kerberos configuration parameters
 477 #
 478 PGAC_ARG_REQ(with, krb-srvnam,
 479              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 480              [],
 481              [with_krb_srvnam="postgres"])
 482 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 483                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 484
 485
 486 #
 487 # PAM
 488 #
 489 AC_MSG_CHECKING([whether to build with PAM support])
 490 PGAC_ARG_BOOL(with, pam, no,
 491               [  --with-pam              build with PAM support],
 492               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 493 AC_MSG_RESULT([$with_pam])
 494 AC_SUBST(with_pam)
 495
 496
 497 #
 498 # LDAP
 499 #
 500 AC_MSG_CHECKING([whether to build with LDAP support])
 501 PGAC_ARG_BOOL(with, ldap, no,
 502               [  --with-ldap             build with LDAP support],
 503               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 504 AC_MSG_RESULT([$with_ldap])
 505 AC_SUBST(with_ldap)
 506
 507
 508 #
 509 # Bonjour
 510 #
 511 AC_MSG_CHECKING([whether to build with Bonjour support])
 512 PGAC_ARG_BOOL(with, bonjour, no,
 513               [  --with-bonjour          build with Bonjour support],
 514               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 515 AC_MSG_RESULT([$with_bonjour])
 516 AC_SUBST(with_bonjour)
 517
 518
 519 #
 520 # OpenSSL
 521 #
 522 AC_MSG_CHECKING([whether to build with OpenSSL support])
 523 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 524               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 525 AC_MSG_RESULT([$with_openssl])
 526 AC_SUBST(with_openssl)
 527
 528
 529 #
 530 # Readline
 531 #
 532 PGAC_ARG_BOOL(with, readline, yes,
 533               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 534 # readline on MinGW has problems with backslashes in psql and other bugs.
 535 # This is particularly a problem with non-US code pages.
 536 # Therefore disable its use until we understand the cause. 2004-07-20
 537 if test "$PORTNAME" = "win32"; then
 538   if test "$with_readline" = yes; then
 539     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 540     with_readline=no
 541   fi
 542 fi
 543
 544
 545 #
 546 # Prefer libedit
 547 #
 548 PGAC_ARG_BOOL(with, libedit-preferred, no,
 549               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 550
 551
 552 #
 553 # XML
 554 #
 555 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 556               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 557
 558 if test "$with_libxml" = yes ; then
 559   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 560   if test -n "$XML2_CONFIG"; then
 561     for pgac_option in `$XML2_CONFIG --cflags`; do
 562       case $pgac_option in
 563         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 564       esac
 565     done
 566     for pgac_option in `$XML2_CONFIG --libs`; do
 567       case $pgac_option in
 568         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 569       esac
 570     done
 571   fi
 572 fi
 573
 574
 575 #
 576 # Zlib
 577 #
 578 PGAC_ARG_BOOL(with, zlib, yes,
 579               [  --without-zlib          do not use Zlib])
 580 AC_SUBST(with_zlib)
 581
 582 #
 583 # Elf
 584 #
 585
 586 # Assume system is ELF if it predefines __ELF__ as 1,
 587 # otherwise believe host_os based default.
 588 case $host_os in
 589     freebsd1*|freebsd2*) elf=no;;
 590     freebsd3*|freebsd4*) elf=yes;;
 591 esac
 592
 593 AC_EGREP_CPP(yes,
 594 [#if __ELF__
 595   yes
 596 #endif
 597 ],
 598 [ELF_SYS=true],
 599 [if test "X$elf" = "Xyes" ; then
 600   ELF_SYS=true
 601 else
 602   ELF_SYS=
 603 fi])
 604 AC_SUBST(ELF_SYS)
 605
 606 #
 607 # Assignments
 608 #
 609
 610 CPPFLAGS="$CPPFLAGS $INCLUDES"
 611 LDFLAGS="$LDFLAGS $LIBDIRS"
 612
 613 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 614 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 615
 616 AC_ARG_VAR(LDFLAGS_SL)
 617
 618 AC_PROG_AWK
 619 PGAC_PATH_FLEX
 620 AC_PROG_LN_S
 621 PGAC_PROG_LD
 622 AC_SUBST(LD)
 623 AC_SUBST(with_gnu_ld)
 624 case $host_os in sysv5*)
 625   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 626   [
 627     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 628     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 629     LDFLAGS=$pgac_save_LDFLAGS
 630   ])
 631   ld_R_works=$pgac_cv_prog_ld_R
 632   AC_SUBST(ld_R_works)
 633 esac
 634 AC_PROG_RANLIB
 635 AC_PATH_PROG(TAR, tar)
 636 PGAC_CHECK_STRIP
 637
 638 if test -z "$YACC"; then
 639   AC_CHECK_PROGS(YACC, ['bison -y'])
 640
 641   if test "$YACC"; then
 642     if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 643       AC_MSG_WARN([
 644 *** The installed version of Bison is too old to use with PostgreSQL.
 645 *** Bison version 1.875 or later is required.])
 646       YACC=""
 647     fi
 648   fi
 649
 650   if test -z "$YACC"; then
 651     AC_MSG_WARN([
 652 *** Without Bison you will not be able to build PostgreSQL from CVS nor
 653 *** change any of the parser definition files.  You can obtain Bison from
 654 *** a GNU mirror site.  (If you are using the official distribution of
 655 *** PostgreSQL then you do not need to worry about this, because the Bison
 656 *** output is pre-generated.)  To use a different yacc program (possible,
 657 *** but not recommended), set the environment variable YACC before running
 658 *** 'configure'.])
 659   fi
 660 fi
 661 AC_SUBST(YFLAGS)
 662
 663 PGAC_PATH_PERL
 664 if test "$with_perl" = yes; then
 665   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 666   PGAC_CHECK_PERL_EMBED_LDFLAGS
 667 fi
 668
 669 if test "$with_python" = yes; then
 670   PGAC_PATH_PYTHON
 671   PGAC_CHECK_PYTHON_EMBED_SETUP
 672 fi
 673
 674 # Supply a numeric version string for use by 3rd party add-ons
 675 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 676 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 677 tr '.' '        ' |
 678 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 679 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 680
 681 ##
 682 ## Libraries
 683 ##
 684 ## Most libraries are included only if they demonstrably provide a function
 685 ## we need, but libm is an exception: always include it, because there are
 686 ## too many compilers that play cute optimization games that will break
 687 ## probes for standard functions such as pow().
 688 ##
 689
 690 AC_CHECK_LIB(m, main)
 691 AC_SEARCH_LIBS(setproctitle, util)
 692 AC_SEARCH_LIBS(dlopen, dl)
 693 AC_SEARCH_LIBS(socket, [socket wsock32])
 694 AC_SEARCH_LIBS(shl_load, dld)
 695 # We only use libld in port/dynloader/aix.c
 696 case $host_os in
 697      aix*)
 698         AC_SEARCH_LIBS(ldopen, ld)
 699         ;;
 700 esac
 701 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 702 AC_SEARCH_LIBS(crypt, crypt)
 703 # Solaris:
 704 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 705 # Cygwin:
 706 AC_SEARCH_LIBS(shmget, cygipc)
 707
 708 if test "$with_readline" = yes; then
 709   PGAC_CHECK_READLINE
 710   if test x"$pgac_cv_check_readline" = x"no"; then
 711     AC_MSG_ERROR([readline library not found
 712 If you have readline already installed, see config.log for details on the
 713 failure.  It is possible the compiler isn't looking in the proper directory.
 714 Use --without-readline to disable readline support.])
 715   fi
 716 fi
 717
 718 if test "$with_zlib" = yes; then
 719   AC_CHECK_LIB(z, inflate, [],
 720                [AC_MSG_ERROR([zlib library not found
 721 If you have zlib already installed, see config.log for details on the
 722 failure.  It is possible the compiler isn't looking in the proper directory.
 723 Use --without-zlib to disable zlib support.])])
 724 fi
 725
 726 if test "$enable_spinlocks" = yes; then
 727   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 728 else
 729   AC_MSG_WARN([
 730 *** Not using spinlocks will cause poor performance.])
 731 fi
 732
 733 if test "$with_krb5" = yes ; then
 734   if test "$PORTNAME" != "win32"; then
 735      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 736                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 737      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 738                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 739   else
 740      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 741                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 742   fi
 743 fi
 744
 745 if test "$with_openssl" = yes ; then
 746   dnl Order matters!
 747   if test "$PORTNAME" != "win32"; then
 748      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 749      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 750   else
 751      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 752      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 753   fi
 754 fi
 755
 756 if test "$with_pam" = yes ; then
 757   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 758 fi
 759
 760 if test "$with_libxml" = yes ; then
 761   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 762 fi
 763
 764
 765 ##
 766 ## Header files
 767 ##
 768
 769 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 770 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 771
 772 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 773 # netinet/in.h is included first.
 774 AC_CHECK_HEADERS(netinet/in.h)
 775 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 776 [AC_INCLUDES_DEFAULT
 777 #ifdef HAVE_NETINET_IN_H
 778 #include <netinet/in.h>
 779 #endif
 780 ])
 781
 782 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 783   AC_CHECK_HEADERS(readline/readline.h, [],
 784         [AC_CHECK_HEADERS(readline.h, [],
 785                 [AC_MSG_ERROR([readline header not found
 786 If you have readline already installed, see config.log for details on the
 787 failure.  It is possible the compiler isn't looking in the proper directory.
 788 Use --without-readline to disable readline support.])])])
 789   AC_CHECK_HEADERS(readline/history.h, [],
 790         [AC_CHECK_HEADERS(history.h, [],
 791                 [AC_MSG_ERROR([history header not found
 792 If you have readline already installed, see config.log for details on the
 793 failure.  It is possible the compiler isn't looking in the proper directory.
 794 Use --without-readline to disable readline support.])])])
 795 fi
 796
 797 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 798 # Some installations of libedit usurp /usr/include/readline/, which seems
 799 # bad practice, since in combined installations readline will have its headers
 800 # there.  We might have to resort to AC_EGREP checks to make sure we found
 801 # the proper header...
 802   AC_CHECK_HEADERS(editline/readline.h, [],
 803         [AC_CHECK_HEADERS(readline.h, [],
 804                 [AC_CHECK_HEADERS(readline/readline.h, [],
 805                         [AC_MSG_ERROR([readline header not found
 806 If you have libedit already installed, see config.log for details on the
 807 failure.  It is possible the compiler isn't looking in the proper directory.
 808 Use --without-readline to disable libedit support.])])])])
 809 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 810 # not be there at all.  Hence, don't complain if not found.  We must check
 811 # though, since in yet other versions it is an independent header.
 812   AC_CHECK_HEADERS(editline/history.h, [],
 813         [AC_CHECK_HEADERS(history.h, [],
 814                 [AC_CHECK_HEADERS(readline/history.h)])])
 815 fi
 816
 817 if test "$with_zlib" = yes; then
 818   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 819 If you have zlib already installed, see config.log for details on the
 820 failure.  It is possible the compiler isn't looking in the proper directory.
 821 Use --without-zlib to disable zlib support.])])
 822 fi
 823
 824 if test "$with_krb5" = yes ; then
 825   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 826 fi
 827
 828 if test "$with_openssl" = yes ; then
 829   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 830   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 831 fi
 832
 833 if test "$with_pam" = yes ; then
 834   AC_CHECK_HEADERS(security/pam_appl.h, [],
 835                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 836                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 837 fi
 838
 839 if test "$with_libxml" = yes ; then
 840   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 841 fi
 842
 843 if test "$with_ldap" = yes ; then
 844   if test "$PORTNAME" != "win32"; then
 845      AC_CHECK_HEADERS(ldap.h, [],
 846                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 847   else
 848      AC_CHECK_HEADERS(winldap.h, [],
 849                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 850                       [AC_INCLUDES_DEFAULT
 851 #include <windows.h>
 852                       ])
 853   fi
 854 fi
 855
 856 if test "$with_bonjour" = yes ; then
 857   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 858 fi
 859
 860
 861 ##
 862 ## Types, structures, compiler characteristics
 863 ##
 864
 865 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 866 AC_C_CONST
 867 AC_C_INLINE
 868 AC_C_STRINGIZE
 869 PGAC_C_SIGNED
 870 AC_C_VOLATILE
 871 PGAC_C_FUNCNAME_SUPPORT
 872 PGAC_STRUCT_TIMEZONE
 873 PGAC_UNION_SEMUN
 874 PGAC_STRUCT_SOCKADDR_UN
 875 PGAC_STRUCT_SOCKADDR_STORAGE
 876 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 877 PGAC_STRUCT_ADDRINFO
 878
 879 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 880 [#include <sys/param.h>
 881 #include <sys/types.h>
 882 #include <sys/socket.h>
 883 #include <sys/ucred.h>])
 884
 885 AC_CHECK_TYPES([struct option], [], [],
 886 [#ifdef HAVE_GETOPT_H
 887 #include <getopt.h>
 888 #endif])
 889
 890 if test "$with_zlib" = yes; then
 891   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 892   # did not).  While we could work around the lack of z_streamp, it
 893   # seems unwise to encourage people to use such old zlib versions...
 894   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 895 Use --without-zlib to disable zlib support.])],
 896                 [#include <zlib.h>])
 897 fi
 898
 899 if test "$with_krb5" = yes; then
 900 # Check for differences between MIT and Heimdal (KTH) releases
 901   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 902                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 903                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 904                                      [#include <krb5.h>])],
 905                    [#include <krb5.h>])
 906   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 907                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 908                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 909                                      [#include <krb5.h>])],
 910                    [#include <krb5.h>])
 911 fi
 912
 913
 914 ##
 915 ## Functions, global variables
 916 ##
 917
 918 PGAC_VAR_INT_TIMEZONE
 919 AC_FUNC_ACCEPT_ARGTYPES
 920 PGAC_FUNC_GETTIMEOFDAY_1ARG
 921
 922 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 923
 924 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 925 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 926 AC_CHECK_DECLS([strlcat, strlcpy])
 927 # This is probably only present on Darwin, but may as well check always
 928 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 929
 930 HAVE_IPV6=no
 931 AC_CHECK_TYPE([struct sockaddr_in6],
 932         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 933          HAVE_IPV6=yes],
 934         [],
 935 [$ac_includes_default
 936 #include <netinet/in.h>])
 937 AC_SUBST(HAVE_IPV6)
 938
 939 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 940 [AC_TRY_LINK(
 941 [#include <machine/vmparam.h>
 942 #include <sys/exec.h>
 943 ],
 944 [PS_STRINGS->ps_nargvstr = 1;
 945 PS_STRINGS->ps_argvstr = "foo";],
 946 [pgac_cv_var_PS_STRINGS=yes],
 947 [pgac_cv_var_PS_STRINGS=no])])
 948 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 949   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 950 fi
 951
 952
 953 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 954 # is missing.  Yes, there are machines that have only one.  We may
 955 # also decide to use snprintf.c if snprintf() is present but does not
 956 # have all the features we need --- see below.
 957
 958 if test "$PORTNAME" = "win32"; then
 959   # Win32 gets snprintf.c built unconditionally.
 960   #
 961   # To properly translate all NLS languages strings, we must support the
 962   # *printf() %$ format, which allows *printf() arguments to be selected
 963   # by position in the translated string.
 964   #
 965   # libintl versions < 0.13 use the native *printf() functions, and Win32
 966   # *printf() doesn't understand %$, so we must use our /port versions,
 967   # which do understand %$. libintl versions >= 0.13 include their own
 968   # *printf versions on Win32.  The libintl 0.13 release note text is:
 969   #
 970   #   C format strings with positions, as they arise when a translator
 971   #   needs to reorder a sentence, are now supported on all platforms.
 972   #   On those few platforms (NetBSD and Woe32) for which the native
 973   #   printf()/fprintf()/... functions don't support such format
 974   #   strings, replacements are provided through <libintl.h>.
 975   #
 976   # We could use libintl >= 0.13's *printf() if we were sure that we had
 977   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 978   # to guarantee that, it is best to just use our own, so we are sure to
 979   # get %$ support. In include/port.h we disable the *printf() macros
 980   # that might have been defined by libintl.
 981   #
 982   # We do this unconditionally whether NLS is used or not so we are sure
 983   # that all Win32 libraries and binaries behave the same.
 984   pgac_need_repl_snprintf=yes
 985 else
 986   pgac_need_repl_snprintf=no
 987   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 988   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 989 fi
 990
 991
 992 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 993 # include/c.h will provide declarations.  Note this is a separate test
 994 # from whether the functions exist in the C library --- there are
 995 # systems that have the functions but don't bother to declare them :-(
 996
 997 AC_CHECK_DECLS([snprintf, vsnprintf])
 998
 999
1000 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1001 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1002 [AC_TRY_LINK([
1003 #include <math.h>
1004 double glob_double;
1005 ],
1006 [return isinf(glob_double) ? 0 : 1;],
1007 [ac_cv_func_isinf=yes],
1008 [ac_cv_func_isinf=no])])
1009
1010 if test $ac_cv_func_isinf = yes ; then
1011   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1012 else
1013   AC_LIBOBJ(isinf)
1014   # Look for a way to implement a substitute for isinf()
1015   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1016 fi
1017
1018 # Some versions of libedit contain strlcpy(); so disregard that library while
1019 # checking for these standard libc functions.
1020 pgac_save_LIBS="$LIBS"
1021 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1022
1023 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1024
1025 LIBS="$pgac_save_LIBS"
1026
1027 # System's version of getaddrinfo(), if any, may be used only if we found
1028 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1029 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1030 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1031 # because we want to use our own getaddrinfo.c on Windows anyway.)
1032 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1033   AC_REPLACE_FUNCS([getaddrinfo])
1034 else
1035   AC_LIBOBJ(getaddrinfo)
1036 fi
1037
1038 # similarly, use system's getopt_long() only if system provides struct option.
1039 if test x"$ac_cv_type_struct_option" = xyes ; then
1040   AC_REPLACE_FUNCS([getopt_long])
1041 else
1042   AC_LIBOBJ(getopt_long)
1043 fi
1044
1045 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1046 # We override the previous test that said fseeko/ftello didn't exist
1047 # OS tests are also done in include/c.h and port/fseeko.c
1048 case $host_os in bsdi*|netbsd*)
1049 ac_cv_func_fseeko=yes
1050 esac
1051
1052 # Win32 support
1053 if test "$PORTNAME" = "win32"; then
1054 AC_LIBOBJ(gettimeofday)
1055 AC_LIBOBJ(kill)
1056 AC_LIBOBJ(open)
1057 AC_LIBOBJ(rand)
1058 AC_LIBOBJ(win32error)
1059 AC_DEFINE([HAVE_SYMLINK], 1,
1060           [Define to 1 if you have the `symlink' function.])
1061 fi
1062
1063 if test "$with_readline" = yes; then
1064   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1065   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1066   AC_CHECK_FUNCS([replace_history_entry])
1067 fi
1068
1069
1070 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1071 dnl (especially on GNU libc)
1072 dnl See also comments in c.h.
1073 AC_MSG_CHECKING(for sigsetjmp)
1074 AC_TRY_LINK([#include <setjmp.h>],
1075             [sigjmp_buf x; sigsetjmp(x, 1);],
1076             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1077 AC_MSG_RESULT(yes)],
1078             [AC_MSG_RESULT(no)])
1079
1080 AC_DECL_SYS_SIGLIST
1081
1082 AC_CHECK_FUNC(syslog,
1083               [AC_CHECK_HEADER(syslog.h,
1084                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1085
1086 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1087 [AC_TRY_LINK([#include <unistd.h>],
1088   [extern int optreset; optreset = 1;],
1089   [pgac_cv_var_int_optreset=yes],
1090   [pgac_cv_var_int_optreset=no])])
1091 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1092   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1093 fi
1094
1095 AC_CHECK_FUNCS([strtoll strtoq], [break])
1096 AC_CHECK_FUNCS([strtoull strtouq], [break])
1097
1098 # Check for one of atexit() or on_exit()
1099 AC_CHECK_FUNCS(atexit, [],
1100                [AC_CHECK_FUNCS(on_exit, [],
1101                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1102
1103 AC_FUNC_FSEEKO
1104
1105 #
1106 # Pthreads
1107 #
1108 # For each platform, we need to know about any special compile and link
1109 # libraries, and whether the normal C function names are thread-safe.
1110 # See the comment at the top of src/port/thread.c for more information.
1111 #
1112 if test "$enable_thread_safety" = yes; then
1113 ACX_PTHREAD     # set thread flags
1114
1115 # Some platforms use these, so just defineed them.  They can't hurt if they
1116 # are not supported.
1117 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1118
1119
1120 # At this point, we don't want to muck with the compiler name for threading.
1121 # Let's see who fails, perhaps AIX.  2004-04-23
1122 if test "$PTHREAD_CC" != "$CC"; then
1123 AC_MSG_ERROR([
1124 PostgreSQL does not support platforms that require a special compiler
1125 for thread safety.])
1126 fi
1127
1128 if test "$THREAD_SUPPORT" = no; then
1129 AC_MSG_ERROR([cannot enable threads on this platform
1130 This platform is known to not support thread-safe programs.  For details,
1131 compile and run src/bin/pg_thread_test.])
1132 fi
1133
1134 # Check for *_r functions
1135 _CFLAGS="$CFLAGS"
1136 _LIBS="$LIBS"
1137 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1138 LIBS="$LIBS $PTHREAD_LIBS"
1139
1140 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1141
1142 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1143
1144 # Do test here with the proper thread flags
1145 PGAC_FUNC_GETPWUID_R_5ARG
1146 PGAC_FUNC_STRERROR_R_INT
1147
1148 CFLAGS="$_CFLAGS"
1149 LIBS="$_LIBS"
1150
1151 else
1152 # do not use values from template file
1153 PTHREAD_CFLAGS=
1154 PTHREAD_LIBS=
1155 fi
1156
1157 AC_SUBST(PTHREAD_CFLAGS)
1158 AC_SUBST(PTHREAD_LIBS)
1159
1160
1161 # We can test for libldap_r only after we know PTHREAD_LIBS
1162 if test "$with_ldap" = yes ; then
1163   _LIBS="$LIBS"
1164   if test "$PORTNAME" != "win32"; then
1165     AC_CHECK_LIB(ldap, ldap_bind, [],
1166                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1167                  [$EXTRA_LDAP_LIBS])
1168     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1169     if test "$enable_thread_safety" = yes; then
1170       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1171       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1172                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1173                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1174       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1175     else
1176       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1177     fi
1178   else
1179     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1180     LDAP_LIBS_FE="-lwldap32"
1181     LDAP_LIBS_BE="-lwldap32"
1182   fi
1183   LIBS="$_LIBS"
1184 fi
1185 AC_SUBST(LDAP_LIBS_FE)
1186 AC_SUBST(LDAP_LIBS_BE)
1187
1188
1189 # This test makes sure that run tests work at all.  Sometimes a shared
1190 # library is found by the linker, but the runtime linker can't find it.
1191 # This check should come after all modifications of compiler or linker
1192 # variables, and before any other run tests.
1193 AC_MSG_CHECKING([test program])
1194 AC_TRY_RUN([int main() { return 0; }],
1195 [AC_MSG_RESULT(ok)],
1196 [AC_MSG_RESULT(failed)
1197 AC_MSG_ERROR([[
1198 Could not execute a simple test program.  This may be a problem
1199 related to locating shared libraries.  Check the file 'config.log'
1200 for the exact reason.]])],
1201 [AC_MSG_RESULT([cross-compiling])])
1202
1203 # --------------------
1204 # Run tests below here
1205 # --------------------
1206
1207 # Force use of our snprintf if system's doesn't do arg control
1208 # See comment above at snprintf test for details.
1209 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1210   PGAC_FUNC_PRINTF_ARG_CONTROL
1211   if test $pgac_cv_printf_arg_control != yes ; then
1212     pgac_need_repl_snprintf=yes
1213   fi
1214 fi
1215
1216
1217 dnl Check to see if we have a working 64-bit integer type.
1218 dnl This breaks down into two steps:
1219 dnl (1) figure out if the compiler has a 64-bit int type with working
1220 dnl arithmetic, and if so
1221 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1222 dnl snprintf is the only library routine we really need for int8 support.)
1223 dnl It's entirely possible to have a compiler that handles a 64-bit type
1224 dnl when the C library doesn't; this is fairly likely when using gcc on
1225 dnl an older platform, for example.
1226 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1227 dnl we force our own version of snprintf() to be used instead.
1228 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1229
1230 PGAC_TYPE_64BIT_INT([long int])
1231
1232 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1233   PGAC_TYPE_64BIT_INT([long long int])
1234 fi
1235
1236
1237 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1238
1239 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1240   AC_TRY_COMPILE([
1241 #define INT64CONST(x)  x##LL
1242 long long int foo = INT64CONST(0x1234567890123456);
1243 ],
1244         [],
1245         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1246         [])
1247 fi
1248
1249
1250 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1251 # we found we need to use "long long int", better check.  We cope with
1252 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1253 # work, fall back to our own snprintf emulation (which we know uses %lld).
1254
1255 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1256   if test $pgac_need_repl_snprintf = no; then
1257     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1258     if test "$LONG_LONG_INT_FORMAT" = ""; then
1259       # Force usage of our own snprintf, since system snprintf is broken
1260       pgac_need_repl_snprintf=yes
1261       LONG_LONG_INT_FORMAT='%lld'
1262     fi
1263   else
1264     # Here if we previously decided we needed to use our own snprintf
1265     LONG_LONG_INT_FORMAT='%lld'
1266   fi
1267   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1268   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1269   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1270 else
1271   # Here if we are not using 'long long int' at all
1272   INT64_FORMAT='"%ld"'
1273   UINT64_FORMAT='"%lu"'
1274 fi
1275
1276 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1277                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1278
1279 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1280                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1281
1282 # Now we have checked all the reasons to replace snprintf
1283 if test $pgac_need_repl_snprintf = yes; then
1284   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1285   AC_LIBOBJ(snprintf)
1286 fi
1287
1288 # Need a #define for the size of Datum (unsigned long)
1289 AC_CHECK_SIZEOF([unsigned long])
1290
1291 # And one for the size of size_t (enables tweaks for > 32bit address space)
1292 AC_CHECK_SIZEOF([size_t])
1293
1294 # Determine memory alignment requirements for the basic C data types.
1295
1296 PGAC_CHECK_ALIGNOF(short)
1297 PGAC_CHECK_ALIGNOF(int)
1298 PGAC_CHECK_ALIGNOF(long)
1299 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1300   PGAC_CHECK_ALIGNOF(long long int)
1301 fi
1302 PGAC_CHECK_ALIGNOF(double)
1303
1304 # Compute maximum alignment of any basic type.
1305 # We assume long's alignment is at least as strong as char, short, or int;
1306 # but we must check long long (if it exists) and double.
1307
1308 MAX_ALIGNOF=$pgac_cv_alignof_long
1309 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1310   MAX_ALIGNOF=$pgac_cv_alignof_double
1311 fi
1312 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1313   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1314 fi
1315 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1316
1317
1318 # Some platforms predefine the types int8, int16, etc.  Only check
1319 # a (hopefully) representative subset.
1320 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1321 [#include <stdio.h>
1322 #ifdef HAVE_SUPPORTDEFS_H
1323 #include <SupportDefs.h>
1324 #endif])
1325
1326 # We also check for sig_atomic_t, which *should* be defined per ANSI
1327 # C, but is missing on some old platforms.
1328 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1329
1330
1331 if test x"$template" != x"win32"
1332 then
1333 PGAC_FUNC_POSIX_SIGNALS
1334 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1335   AC_MSG_ERROR([
1336 Thread-safety requires POSIX signals, which are not supported by this
1337 operating system.])
1338 fi
1339 fi
1340
1341 if test $ac_cv_func_fseeko = yes; then
1342 AC_SYS_LARGEFILE
1343 fi
1344
1345 # SunOS doesn't handle negative byte comparisons properly with +/- return
1346 AC_FUNC_MEMCMP
1347
1348
1349 # Select semaphore implementation type.
1350 if test "$PORTNAME" != "win32"; then
1351   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1352     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1353     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1354   else
1355     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1356       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1357       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1358     else
1359       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1360       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1361     fi
1362   fi
1363 else
1364   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1365   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1366 fi
1367
1368
1369 # Select shared-memory implementation type.
1370 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1371 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1372
1373
1374 # If not set in template file, set bytes to use libc memset()
1375 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1376   MEMSET_LOOP_LIMIT=1024
1377 fi
1378 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1379
1380
1381 if test "$enable_nls" = yes ; then
1382   PGAC_CHECK_GETTEXT
1383 fi
1384
1385 # Check for Tcl configuration script tclConfig.sh
1386 if test "$with_tcl" = yes; then
1387     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1388     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1389                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1390     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1391     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1392     ac_save_CPPFLAGS=$CPPFLAGS
1393     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1394     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1395     CPPFLAGS=$ac_save_CPPFLAGS
1396 fi
1397
1398 #
1399 # Check for DocBook and tools
1400 #
1401 PGAC_PROG_NSGMLS
1402 PGAC_PROG_JADE
1403 PGAC_CHECK_DOCBOOK(4.2)
1404 PGAC_PATH_DOCBOOK_STYLESHEETS
1405 PGAC_PATH_COLLATEINDEX
1406 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1407
1408 # Thread testing
1409
1410 # We have to run the thread test near the end so we have all our symbols
1411 # defined.  Cross compiling throws a warning.
1412 #
1413 if test "$enable_thread_safety_force" = yes; then
1414 if test x"$template" != x"win32"
1415 then
1416   AC_MSG_WARN([
1417 *** Skipping thread test program.  --enable-thread-safety-force was used.
1418 *** Run the program in src/test/thread on the your machine and add proper
1419 *** locking function calls to your applications to guarantee thread safety.
1420 ])
1421 else
1422 AC_MSG_WARN([*** skipping thread test on Win32])
1423 fi
1424 elif test "$enable_thread_safety" = yes; then
1425 if test x"$template" != x"win32"
1426 then
1427 AC_MSG_CHECKING([thread safety of required library functions])
1428
1429 _CFLAGS="$CFLAGS"
1430 _LIBS="$LIBS"
1431 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1432 LIBS="$LIBS $PTHREAD_LIBS"
1433 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1434   [AC_MSG_RESULT(yes)],
1435   [AC_MSG_RESULT(no)
1436   AC_MSG_ERROR([thread test program failed
1437 This platform is not thread-safe.  Check the file 'config.log'for the
1438 exact reason.
1439
1440 You can use the configure option --enable-thread-safety-force to force
1441 threads to be enabled.  But you must then run the program in
1442 src/test/thread and add locking function calls to your applications to
1443 guarantee thread safety.])],
1444   [AC_MSG_RESULT(maybe)
1445   AC_MSG_WARN([
1446 *** Skipping thread test program because of cross-compile build.
1447 *** Run the program in src/test/thread on the target machine.
1448 ])])
1449 CFLAGS="$_CFLAGS"
1450 LIBS="$_LIBS"
1451 else
1452 AC_MSG_WARN([*** skipping thread test on Win32])
1453 fi
1454 fi
1455
1456 # prepare build tree if outside source tree
1457 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1458 # Note 2: /bin/pwd might be better than shell's built-in at getting
1459 #         a symlink-free name.
1460 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1461   vpath_build=no
1462 else
1463   vpath_build=yes
1464   if test "$no_create" != yes; then
1465     _AS_ECHO_N([preparing build tree... ])
1466     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1467     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1468       || AC_MSG_ERROR(failed)
1469     AC_MSG_RESULT(done)
1470   fi
1471 fi
1472 AC_SUBST(vpath_build)
1473
1474
1475 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1476
1477 AC_CONFIG_LINKS([
1478   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1479   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1480   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1481   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1482   src/include/pg_config_os.h:src/include/port/${template}.h
1483   src/Makefile.port:src/makefiles/Makefile.${template}
1484 ])
1485
1486 if test "$PORTNAME" = "win32"; then
1487 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1488 # Links sometimes fail undetected on Mingw -
1489 # so here we detect it and warn the user
1490 for FILE in $CONFIG_LINKS
1491  do
1492         # test -e works for symlinks in the MinGW console
1493         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1494  done
1495 ])
1496 fi
1497
1498 AC_CONFIG_HEADERS([src/include/pg_config.h],
1499 [
1500 # Update timestamp for pg_config.h (see Makefile.global)
1501 echo >src/include/stamp-h
1502 ])
1503
1504 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1505
1506 AC_OUTPUT
1507
1508 # Warn about unknown options
1509 PGAC_ARG_CHECK