granicus.if.org Git - sysstat/blob - configure.in

   1 # configure.in
   2 #
   3 # (C) 2007 - Ivana Varekova <varekova@redhat.com>
   4 # Modified by Sebastien Godard (sysstat <at> orange.fr)
   5
   6 # Initialization of $PACKAGE_VERSION and $PACKAGE_NAME variables
   7 AC_INIT(sysstat, 12.1.1)
   8
   9 # Ensure that a recent enough version of Autoconf is being used
  10 AC_PREREQ(2.53)
  11
  12 # Check whether the configure script is in the right dir
  13 AC_CONFIG_SRCDIR(ioconf.h)
  14
  15 # Check programs
  16 echo .
  17 echo Check programs:
  18 echo .
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_PROG_LN_S
  23
  24 DFLAGS=""
  25
  26 AC_CHECK_PROG(CHMOD, chmod, chmod)
  27 AC_CHECK_PROG(CHOWN, chown, chown)
  28 AC_CHECK_PROG(AR, ar, ar)
  29 AC_CHECK_PROG(INSTALL, install, install)
  30 AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
  31 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
  32 AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
  33 AC_CHECK_PROGS(ZIP, xz bzip2 gzip, gzip)
  34 INSTALL_DATA="\${INSTALL} -m 644"
  35 AC_SUBST(INSTALL_DATA)
  36 INSTALL_BIN="\${INSTALL} -m 755"
  37 AC_SUBST(INSTALL_BIN)
  38
  39 AC_PATH_PROG(PATH_CP, cp)
  40 AC_PATH_PROG(PATH_CHKCONFIG, chkconfig)
  41
  42 # Check for systemd
  43 AC_CHECK_PROG(PKG_CONFIG, pkg-config, pkg-config)
  44 AC_PATH_PROG(SYSTEMCTL, systemctl)
  45 AC_ARG_WITH([systemdsystemunitdir],
  46     AS_HELP_STRING([--with-systemdsystemunitdir=DIR],[Directory for systemd service files]),
  47     [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  48 if test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ; then
  49     AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
  50 fi
  51
  52 # Check libraries
  53
  54 # Check header files
  55 echo .
  56 echo Check header files:
  57 echo .
  58 HAVE_LIBINTL_H=
  59 HAVE_LOCALE_H=
  60 HAVE_SYS_SYSMACROS_H=
  61 HAVE_SYS_PARAM_H=
  62 AC_HEADER_STDC
  63 AC_HEADER_DIRENT
  64 AC_CHECK_HEADERS(ctype.h)
  65 AC_CHECK_HEADERS(errno.h)
  66 AC_CHECK_HEADERS(libintl.h, HAVE_LIBINTL_H=1)
  67 AC_CHECK_HEADERS(locale.h, HAVE_LOCALE_H=1)
  68 AC_CHECK_HEADERS(net/if.h)
  69 AC_CHECK_HEADERS(regex.h)
  70 AC_CHECK_HEADERS(signal.h)
  71 AC_CHECK_HEADERS(stdio.h)
  72 AC_CHECK_HEADERS(sys/file.h)
  73 AC_CHECK_HEADERS(sys/ioctl.h)
  74 AC_CHECK_HEADERS(sys/param.h, HAVE_SYS_PARAM_H=1)
  75 AC_CHECK_HEADERS(sys/stat.h)
  76 AC_CHECK_HEADERS(sys/sysmacros.h, HAVE_SYS_SYSMACROS_H=1)
  77
  78 echo .
  79 echo Check typedefs, structures and compiler characteristics:
  80 echo .
  81 AC_TYPE_SIGNAL
  82 AC_TYPE_SIZE_T
  83 AC_TYPE_OFF_T
  84
  85 echo .
  86 echo Check library functions:
  87 echo .
  88 AC_CHECK_FUNCS(strchr)
  89 AC_CHECK_FUNCS(strcspn)
  90 AC_CHECK_FUNCS(strspn)
  91 AC_CHECK_FUNCS(strstr)
  92
  93 # Should we check for lm_sensors?
  94 AC_MSG_CHECKING(for sensors support)
  95 AC_ARG_ENABLE(sensors,
  96               AC_HELP_STRING([--disable-sensors],
  97                              [disable sensors support]),
  98                              SENSORS=$enableval,SENSORS=yes)
  99 if test $SENSORS != "yes"; then
 100    HAVE_SENSORS="n"
 101 else
 102    HAVE_SENSORS="y"
 103 fi
 104 AC_MSG_RESULT($SENSORS)
 105
 106 # Check for lm_sensors
 107 SENSORS=no
 108 LFSENSORS=""
 109 DFSENSORS=""
 110 AC_CHECK_LIB(sensors, sensors_get_detected_chips, LFSENSORS="-lsensors", HAVE_SENSORS="n")
 111 AC_MSG_CHECKING(for sensors lib)
 112 AC_TRY_COMPILE(#include <sensors/sensors.h>
 113 #include <sensors/error.h>
 114                 , sensors_cleanup();,SENSORS=yes; DFSENSORS="-DHAVE_SENSORS", HAVE_SENSORS="n"; SENSORS=no)
 115 AC_MSG_RESULT($SENSORS)
 116 AC_SUBST(HAVE_SENSORS)
 117 AC_SUBST(LFSENSORS)
 118 AC_SUBST(DFSENSORS)
 119
 120 echo .
 121 echo Check system services:
 122 echo .
 123 AC_SYS_LARGEFILE
 124
 125 echo .
 126 echo Check configuration:
 127 echo .
 128 # Check arguments used
 129 #
 130 # Optional Features:
 131 #  --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
 132 #  --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
 133 #  --disable-largefile     omit support for large files
 134 #  --disable-nls           disable National Language Support
 135 #  --disable-file-attr     don't set attributes on files being installed
 136 #  --enable-install-cron   tell sysstat to install cron scripts
 137 #  --collect-all           tell sadc to collect all possible data
 138 #  --enable-clean-sa-dir   clean system activity directory
 139 #  --enable-compress-manpg compress manual pages
 140 #  --enable-debuginfo      enable debug output (--debuginfo option)
 141 #  --disable-documentation do not install documentation (man pages...)
 142 #  --disable-sensors       do not link against libsensors even if available
 143 #  --disable-stripping     do not strip object files
 144 #  --enablle-copy-only     only copy files when installing sysstat
 145 #
 146 # Some influential environment variables:
 147 #  rcdir         directory where startup scripts are installed
 148 #  sa_lib_dir    sadc, sa1 and sa2 directory
 149 #  sa_dir        system activity daily datafiles directory
 150 #  conf_dir      sysstat configuration directory (default is /etc/sysconfig)
 151 #  history       number of daily datafiles to keep (default value is 7)
 152 #  compressafter number of days after which datafiles are compressed
 153 #  man_group     group for man pages
 154 #  cron_owner    crontab owner
 155 #  cron_interval crontab sampling interval
 156 #  sadc_options  options to be passed to sadc
 157 #
 158 # Fine tuning the installation directories:
 159 #  --mandir=DIR           man documentation directory [PREFIX/man]
 160 #  --docdir=DIR           other documentation directory [PREFIX/share/doc]
 161 #
 162 # Installation directories:
 163 #  --prefix=PREFIX         install architecture-independent files in PREFIX
 164 #                            [/usr/local]
 165 #  --exec-prefix=EPREFIX   install architecture-dependent files in EPREFIX
 166 #                            [PREFIX]
 167
 168 # Set directories
 169 if test -d /etc/init.d && test ! -L /etc/init.d; then
 170    if test -d /etc/init.d/rc2.d; then
 171       RC_DIR=/etc/init.d
 172       INITD_DIR=.
 173    else
 174       RC_DIR=/etc
 175       INITD_DIR=init.d
 176    fi
 177    INIT_DIR=/etc/init.d
 178 elif test -d /sbin/init.d; then
 179    RC_DIR=/sbin/init.d
 180    INIT_DIR=/sbin/init.d
 181    INITD_DIR=.
 182 else
 183    RC_DIR=/etc/rc.d
 184    INIT_DIR=/etc/rc.d/init.d
 185    INITD_DIR=init.d
 186 fi
 187
 188 AC_MSG_CHECKING(run-commands directory)
 189 AC_ARG_VAR([rcdir],[run-commands directory])
 190 if test x$rcdir != x""; then
 191         # Override previous rc directories values
 192         RC_DIR=$rcdir
 193         INIT_DIR=$rcdir/init.d
 194         INITD_DIR=init.d
 195 fi
 196 AC_MSG_RESULT($RC_DIR)
 197 if test ! -d $RC_DIR; then
 198         echo "INFO: Directory ${RC_DIR} doesn't exist."
 199         echo "INFO: Startup scripts won't be installed."
 200 fi
 201
 202 AC_SUBST(RC_DIR)
 203 AC_SUBST(INIT_DIR)
 204 AC_SUBST(INITD_DIR)
 205
 206 if test $HAVE_SYS_SYSMACROS_H; then
 207    SYSMACROS="y"
 208 else
 209    SYSMACROS="n"
 210 fi
 211 AC_SUBST(SYSMACROS)
 212
 213 if test $HAVE_SYS_PARAM_H; then
 214    SYSPARAM="y"
 215 else
 216    SYSPARAM="n"
 217 fi
 218 AC_SUBST(SYSPARAM)
 219
 220 # Set sadc directory
 221 if test $prefix != "NONE"; then
 222    AuxPrefix=$prefix
 223 else
 224    AuxPrefix=/usr/local
 225 fi
 226
 227 SADC_DIR=$AuxPrefix/lib
 228 if test -d $AuxPrefix/lib64; then
 229     # Verify that this OS is really 64 bit
 230     BITS=$(getconf LONG_BIT 2>/dev/null)
 231     if test $? = 0; then
 232         if test $BITS = 64; then
 233             SADC_DIR=$AuxPrefix/lib64
 234         fi
 235     else
 236         # Fallback: look for lm (long mode) flag to know if CPU is 64 bit
 237         grep " lm " /proc/cpuinfo >/dev/null 2>&1
 238         if test $? = 0; then
 239             SADC_DIR=$AuxPrefix/lib64
 240         fi
 241     fi
 242 fi
 243
 244 AC_MSG_CHECKING(sadc directory)
 245 AC_ARG_VAR([sa_lib_dir],[sadc directory])
 246 if test x$sa_lib_dir != x""; then
 247    SA_LIB_DIR=$sa_lib_dir
 248 else
 249    SA_LIB_DIR=$SADC_DIR/sa
 250 fi
 251 AC_MSG_RESULT($SA_LIB_DIR)
 252 if test ! -d $SA_LIB_DIR; then
 253    echo "INFO: Directory ${SA_LIB_DIR} will be created during installation stage."
 254 fi
 255 AC_SUBST(SA_LIB_DIR)
 256
 257 # Set system activity directory
 258 AC_MSG_CHECKING(system activity directory)
 259 AC_ARG_VAR([sa_dir],[system activity directory])
 260 if test x$sa_dir != x""; then
 261    SA_DIR=$sa_dir
 262 else
 263    SA_DIR=/var/log/sa
 264 fi
 265 AC_MSG_RESULT($SA_DIR)
 266 if test ! -d $SA_DIR; then
 267    echo "INFO: Directory ${SA_DIR} will be created during installation stage."
 268 fi
 269 AC_SUBST(SA_DIR)
 270
 271 # Set configuration directory
 272 AC_MSG_CHECKING(sysstat configuration directory)
 273 AC_ARG_VAR([conf_dir],[sysstat configuration directory])
 274 if test x$conf_dir != x""; then
 275    SYSCONFIG_DIR=$conf_dir
 276 else
 277    SYSCONFIG_DIR=/etc/sysconfig
 278 fi
 279 AC_MSG_RESULT($SYSCONFIG_DIR)
 280 if test ! -d $SYSCONFIG_DIR; then
 281    echo "INFO: Directory ${SYSCONFIG_DIR} will be created during installation stage."
 282 fi
 283 AC_SUBST(SYSCONFIG_DIR)
 284
 285 # National Language Support
 286 AC_MSG_CHECKING(National Language Support)
 287 AC_ARG_ENABLE(nls,
 288               AC_HELP_STRING([--disable-nls],
 289                              [disable National Language Support]),
 290                              AUX_NLS=$enableval,AUX_NLS=yes)
 291 if test $AUX_NLS != "no" && test $HAVE_LIBINTL_H && test $HAVE_LOCALE_H; then
 292    AUX_NLS="yes"
 293    NLS="y"
 294 else
 295    AUX_NLS="no"
 296    NLS="n"
 297 fi
 298 AC_MSG_RESULT($AUX_NLS)
 299 LACKING_GETTEXT="n"
 300 if test $AUX_NLS = "yes" &&  test x$MSGFMT != x"msgfmt"; then
 301    echo "WARNING: msgfmt command not found!"
 302    LACKING_GETTEXT="y"
 303 fi
 304 if test $AUX_NLS = "yes" &&  test x$XGETTEXT != x"xgettext"; then
 305    echo "WARNING: xgettext command not found!"
 306    LACKING_GETTEXT="y"
 307 fi
 308 if test $AUX_NLS = "yes" &&  test x$MSGMERGE != x"msgmerge"; then
 309    echo "WARNING: msgmerge command not found!"
 310    LACKING_GETTEXT="y"
 311 fi
 312 if test $NLS = "y" && test $LACKING_GETTEXT = "y"; then
 313    echo "WARNING: Disabling NLS"
 314    NLS="n"
 315 fi
 316 AC_SUBST(NLS)
 317
 318 # Data history to keep by sa2
 319 AC_MSG_CHECKING(number of daily data files to keep)
 320 AC_ARG_VAR([history],[number of daily data files to keep (default value is 7)])
 321 if test x$history = x""; then
 322    HISTORY=7
 323 else
 324    HISTORY=$history
 325 fi
 326 AC_MSG_RESULT($HISTORY)
 327 AC_SUBST(HISTORY)
 328
 329 # Number of days after which datafiles are compressed
 330 AC_MSG_CHECKING(number of days after which data files are compressed)
 331 AC_ARG_VAR([compressafter],[number of days after which data files are compressed (default value is 10)])
 332 if test x$compressafter = x""; then
 333    COMPRESSAFTER=10
 334 else
 335    COMPRESSAFTER=$compressafter
 336 fi
 337 AC_MSG_RESULT($COMPRESSAFTER)
 338 AC_SUBST(COMPRESSAFTER)
 339
 340 # Manual page group
 341 grep ^man: /etc/group >/dev/null 2>&1
 342 if test $? = 0; then
 343    GRP=man
 344 else
 345    GRP=root
 346 fi
 347
 348 AC_MSG_CHECKING(group for manual pages)
 349 AC_ARG_VAR([man_group],[group for manual pages])
 350 if test x$man_group = x""; then
 351    MAN_GROUP=$GRP
 352    AC_MSG_RESULT($MAN_GROUP)
 353 else
 354    grep ^$man_group: /etc/group >/dev/null 2>&1
 355    if test $? = 1; then
 356       MAN_GROUP=$GRP
 357       AC_MSG_RESULT($MAN_GROUP)
 358       echo "WARNING: Group ${man_group} not found: Using ${GRP} instead"
 359    else
 360       MAN_GROUP=$man_group
 361       AC_MSG_RESULT($MAN_GROUP)
 362    fi
 363 fi
 364 AC_SUBST(MAN_GROUP)
 365
 366 # Don't set attributes on files being installed?
 367 AC_MSG_CHECKING(whether attributes should not be set on files being installed)
 368 AC_ARG_ENABLE(file-attr,
 369               AC_HELP_STRING([--disable-file-attr],
 370                              [do not set attributes on files being installed]),
 371                              AUX_IMG=$enableval,AUX_IMG=yes)
 372 if test $AUX_IMG != "no"; then
 373    IGNORE_FILE_ATTRIBUTES=n
 374    AUX_IMG=no
 375 else
 376    IGNORE_FILE_ATTRIBUTES=y
 377    AUX_IMG=yes
 378 fi
 379 AC_MSG_RESULT($AUX_IMG)
 380 AC_SUBST(IGNORE_FILE_ATTRIBUTES)
 381
 382 # Compress manual pages?
 383 AC_MSG_CHECKING(whether manual pages should be compressed)
 384 AC_ARG_ENABLE(compress-manpg,
 385               AC_HELP_STRING([--enable-compress-manpg],
 386                              [compress sysstat manual pages]),
 387                              AUX_MPG=$enableval,AUX_MPG=no)
 388 if test $AUX_MPG != "yes"; then
 389    COMPRESS_MANPG=n
 390    AUX_MPG=no
 391 else
 392    COMPRESS_MANPG=y
 393 fi
 394 AC_MSG_RESULT($AUX_MPG)
 395 AC_SUBST(COMPRESS_MANPG)
 396
 397 # Check whether sa directory should be cleaned
 398 AC_MSG_CHECKING(whether system activity directory should be cleaned)
 399 AC_ARG_ENABLE(clean-sa-dir,
 400               AC_HELP_STRING([--enable-clean-sa-dir],
 401                              [clean system activity directory]),
 402                             AUX_CSD=$enableval,AUX_CSD=no)
 403 if test $AUX_CSD != "yes"; then
 404    CLEAN_SA_DIR=n
 405    AUX_CSD=no
 406 else
 407    CLEAN_SA_DIR=y
 408 fi
 409 AC_MSG_RESULT($AUX_CSD)
 410 AC_SUBST(CLEAN_SA_DIR)
 411
 412 # Start crontab
 413 AC_MSG_CHECKING(whether cron should start sar automatically)
 414 AC_ARG_ENABLE(install-cron,
 415               AC_HELP_STRING([--enable-install-cron],
 416                              [install a crontab to start sar]),
 417                              INSTALL_CRON=$enableval,INSTALL_CRON=n)
 418 if test $INSTALL_CRON != "yes"; then
 419    INSTALL_CRON=n
 420    AUX_CRON=no
 421 else
 422    INSTALL_CRON=y
 423    AUX_CRON=yes
 424 fi
 425 AC_MSG_RESULT($AUX_CRON)
 426 AC_SUBST(INSTALL_CRON)
 427
 428 # Crontab owner
 429 CUSR="root"
 430 if test $INSTALL_CRON = "y"; then
 431    AC_MSG_CHECKING(crontab owner)
 432    AC_ARG_VAR([cron_owner],[crontab owner])
 433    if test x$cron_owner = x""; then
 434       CRON_OWNER=$CUSR
 435       AC_MSG_RESULT($CRON_OWNER)
 436    else
 437       grep ^$cron_owner: /etc/passwd >/dev/null 2>&1
 438       if test $? = 1; then
 439          CRON_OWNER=$CUSR;
 440          AC_MSG_RESULT($CRON_OWNER)
 441          echo "WARNING: User ${cron_owner} not found: Using ${CUSR} instead."
 442       else
 443          CRON_OWNER=$cron_owner
 444          AC_MSG_RESULT($CRON_OWNER)
 445       fi
 446    fi
 447    echo "INFO: Crontab for ${CRON_OWNER} will be saved in current directory if necessary"
 448    if test $CRON_OWNER = "root"; then
 449       SU_C_OWNER=""
 450       QUOTE=""
 451       REM_CHOWN="# REM_CHOWN"
 452    else
 453       SU_C_OWNER="su $CRON_OWNER -c "
 454       QUOTE=\"
 455       # " (ignore this line)
 456       REM_CHOWN=$CHOWN
 457    fi
 458
 459 #  Crontab interval
 460    AC_MSG_CHECKING(crontab interval)
 461    AC_ARG_VAR([cron_interval],[crontab interval])
 462    if test x$cron_interval = x""; then
 463       CRON_INTERVAL=10
 464    else
 465       CRON_INTERVAL=$cron_interval
 466    fi
 467    AC_MSG_RESULT($CRON_INTERVAL)
 468    CRON_INTERVAL_SEC=`expr ${CRON_INTERVAL} \* 60`
 469    CRON_COUNT=`expr 60 / ${CRON_INTERVAL}`
 470
 471 #  Check whether sadc should collect all possible activities
 472    AC_MSG_CHECKING(whether sadc should collect all possible activities)
 473    AC_ARG_ENABLE(collect-all,
 474                  AC_HELP_STRING([--enable-collect-all],
 475                                 [collect all possible activities]),
 476                                 COLLECT_ALL=$enableval,COLLECT_ALL=n)
 477    if test $COLLECT_ALL != "yes"; then
 478       COLLECT_ALL=""
 479       AUX_COLL=no
 480    else
 481       COLLECT_ALL="-S XALL"
 482       AUX_COLL=yes
 483    fi
 484    AC_MSG_RESULT($AUX_COLL)
 485
 486    AC_MSG_CHECKING(options to be passed to sadc)
 487    AC_ARG_VAR([sadc_options],[options to be passed to sadc])
 488    if test x"$sadc_options" != x""; then
 489         SADC_OPT="$sadc_options"
 490    else
 491         SADC_OPT=
 492    fi
 493    AC_MSG_RESULT($SADC_OPT)
 494    AC_SUBST(SADC_OPT)
 495
 496 #  Check whether files should only be copied
 497    AC_MSG_CHECKING(whether files should only be copied)
 498    AC_ARG_ENABLE(copy-only,
 499                  AC_HELP_STRING([--enable-copy-only],
 500                                 [only copy files when installing]),
 501                                 OCOPY=$enableval,OCOPY=no)
 502    if test $OCOPY != "yes"; then
 503       COPY_ONLY=n
 504       OCOPY=no
 505    else
 506       COPY_ONLY=y
 507    fi
 508    AC_MSG_RESULT($OCOPY)
 509    AC_SUBST(COPY_ONLY)
 510
 511 else
 512    CRON_OWNER="root"
 513    SU_C_OWNER=""
 514    QUOTE=""
 515    REM_CHOWN="# REM_CHOWN"
 516    CRON_INTERVAL=10
 517    CRON_INTERVAL_SEC=600
 518    CRON_COUNT=6
 519    COLLECT_ALL=""
 520 fi
 521 AC_SUBST(CRON_OWNER)
 522 AC_SUBST(SU_C_OWNER)
 523 AC_SUBST(CRON_INTERVAL)
 524 AC_SUBST(CRON_INTERVAL_SEC)
 525 AC_SUBST(CRON_COUNT)
 526 AC_SUBST(QUOTE)
 527 AC_SUBST(REM_CHOWN)
 528 AC_SUBST(COLLECT_ALL)
 529
 530 # Check whether documentation should be installed
 531 AC_MSG_CHECKING(whether documentation should be installed)
 532 AC_ARG_ENABLE(documentation,
 533               AC_HELP_STRING([--disable-documentation],
 534                              [do not install documentation]),
 535                              AUX_DOC=$enableval,AUX_DOC=yes)
 536 if  test  $AUX_DOC !=  "no"; then
 537    AUX_DOC="yes"
 538    INSTALL_DOC="y"
 539 else
 540    AUX_DOC="no"
 541    INSTALL_DOC="n"
 542 fi
 543 AC_MSG_RESULT($AUX_DOC)
 544 AC_SUBST(INSTALL_DOC)
 545
 546 # Set directory for installing manual pages (see comment in Makefile)
 547 AC_SUBST(mandir)
 548
 549 # Check whether --debuginfo options should be allowed
 550 AC_ARG_ENABLE(debuginfo,
 551               AC_HELP_STRING([--enable-debuginfo],
 552                              [enable debug output (--debuginfo option)]),
 553                              WITH_DEBUG=yes ; DFLAGS="$DFLAGS -DDEBUG" , WITH_DEBUG=no)
 554 AC_SUBST(WITH_DEBUG)
 555 AC_SUBST(DFLAGS)
 556
 557 # Check whether object files should be stripped
 558 AC_MSG_CHECKING(whether object files should be stripped)
 559 AC_ARG_ENABLE(stripping,
 560               AC_HELP_STRING([--disable-stripping],
 561                              [do not strip object files]),
 562                              AUX_STRIP=$enableval,AUX_STRIP=yes)
 563 if test $AUX_STRIP != "no"; then
 564    AUX_STRIP="yes"
 565    STRIP="-s"
 566 else
 567    AUX_STRIP="no"
 568    STRIP=
 569 fi
 570 AC_MSG_RESULT($AUX_STRIP)
 571 AC_SUBST(STRIP)
 572
 573 # Create files
 574 echo .
 575 echo Now create files:
 576 echo .
 577 AC_CONFIG_FILES([sa1], [chmod +x sa1])          # Permissions must be changed
 578 AC_CONFIG_FILES([sa2], [chmod +x sa2])          # Permissions must be changed
 579 AC_CONFIG_FILES([cron/crontab:cron/crontab.sample])     # File must be renamed
 580 AC_CONFIG_FILES([sysstat.sysconfig])
 581 AC_CONFIG_FILES([version.h:version.in])         # File must be renamed
 582 AC_CONFIG_FILES([sysconfig.h:sysconfig.in])     # File must be renamed
 583 AC_CONFIG_FILES([cron/sysstat.cron.daily])
 584 AC_CONFIG_FILES([cron/sysstat.cron.hourly])
 585 AC_CONFIG_FILES([cron/sysstat.crond])
 586 AC_CONFIG_FILES([cron/sysstat.crond.sample.in:cron/sysstat.crond.in], [sed s/^/#/ cron/sysstat.crond.sample.in > cron/sysstat.crond.sample])
 587 AC_CONFIG_FILES([sysstat], [chmod +x sysstat])  # Permissions must be changed
 588 AC_CONFIG_FILES([sysstat.service])
 589 AC_CONFIG_FILES([cron/sysstat-collect.service])
 590 AC_CONFIG_FILES([cron/sysstat-collect.timer])
 591 AC_CONFIG_FILES([cron/sysstat-summary.service])
 592 AC_CONFIG_FILES([cron/sysstat-summary.timer])
 593 AC_CONFIG_FILES([man/sa1.8:man/sa1.in])         # File must be renamed
 594 AC_CONFIG_FILES([man/sa2.8:man/sa2.in])         # File must be renamed
 595 AC_CONFIG_FILES([man/sadc.8:man/sadc.in])       # File must be renamed
 596 AC_CONFIG_FILES([man/sadf.1:man/sadf.in])       # File must be renamed
 597 AC_CONFIG_FILES([man/sar.1:man/sar.in])         # File must be renamed
 598 AC_CONFIG_FILES([man/sysstat.5:man/sysstat.in]) # File must be renamed
 599 AC_CONFIG_FILES([man/iostat.1:man/iostat.in])   # File must be renamed
 600 AC_CONFIG_FILES([man/cifsiostat.1:man/cifsiostat.in])   # File must be renamed
 601
 602 AC_OUTPUT(Makefile)
 603
 604 echo "
 605    Sysstat version:             $PACKAGE_VERSION
 606    Installation prefix:         $prefix
 607    rc directory:                ${RC_DIR}
 608    Init directory:              ${INIT_DIR}
 609    Systemd unit dir:            ${with_systemdsystemunitdir}
 610    Configuration directory:     ${SYSCONFIG_DIR}
 611    Man pages directory:         $mandir
 612    Compiler:                    $CC
 613    Compiler flags:              $CFLAGS
 614 "
 615