granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="$srcdir/srclib/apr/apr-${majorver}-config"
  97     if test -f $test_apr_config; then
  98       apr_config=$test_apr_config
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x${apr_major_version}" = "x2"; then
 119    apu_found=obsolete
 120 elif test "x$with_included_apr" = "xyes"; then
 121    apu_found=reconfig
 122 else
 123    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 124    dnl isn't supported.
 125    ifdef([APR_FIND_APU], [
 126      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 127                   1, ${apr_major_version})
 128    ], [apu_found=no])
 129 fi
 130
 131 if test "$apu_found" = "no"; then
 132   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 133 fi
 134
 135 # Catch some misconfigurations:
 136 case ${apr_found}.${apu_found} in
 137 reconfig.yes)
 138   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 139   ;;
 140 yes.reconfig)
 141   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 142   ;;
 143 esac
 144
 145 if test "$apu_found" = "reconfig"; then
 146   APR_SUBDIR_CONFIG(srclib/apr-util,
 147                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 148                     [--enable-layout=*|\'--enable-layout=*])
 149   dnl We must be the last to build and the first to be cleaned
 150   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 151   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 152   dnl APR and APR-Util major versions must match
 153   apu_config="${srcdir}/srclib/apr-util/apu-${apr_major_version}-config"
 154 fi
 155
 156 if test "$apu_found" = "obsolete"; then
 157   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 158 else
 159   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 160   APU_BINDIR=`$apu_config --bindir`
 161   APU_INCLUDEDIR=`$apu_config --includedir`
 162   APU_INCLUDES=`$apu_config --includes`
 163   APU_VERSION=`$apu_config --version`
 164   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 165 fi
 166
 167 dnl In case we picked up CC and CPP from APR, get that info into the
 168 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 169 dnl PCRE and for our config tests will be whatever PCRE determines.
 170 AC_PROG_CC
 171 AC_PROG_CPP
 172
 173 if test "x${cache_file}" = "x/dev/null"; then
 174   # Likewise, ensure that CC and CPP are passed through to the pcre
 175   # configure script iff caching is disabled (the autoconf 2.5x default).
 176   export CC; export CPP
 177 fi
 178
 179 dnl Absolute source/build directory
 180 abs_srcdir=`(cd $srcdir && pwd)`
 181 abs_builddir=`pwd`
 182
 183 AC_ARG_WITH(pcre,
 184 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 185
 186 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 187 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 188    PCRE_CONFIG=$with_pcre/bin/pcre-config
 189 elif test -x "$with_pcre"; then
 190    PCRE_CONFIG=$with_pcre
 191 fi
 192
 193 if test "$PCRE_CONFIG" != "false"; then
 194   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 195     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 196   fi
 197   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 198   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 199   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 200 else
 201   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 202 fi
 203 APACHE_SUBST(PCRE_LIBS)
 204
 205 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 206 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 207
 208 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 209
 210 dnl If the source dir is not equal to the build dir,
 211 dnl then we are running in VPATH mode.
 212
 213 APR_ADDTO(INCLUDES, [-I.])
 214
 215 if test "$abs_builddir" != "$abs_srcdir"; then
 216   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 217 fi
 218
 219 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 220
 221 # apr/apr-util --includes may pick up system paths for dependent
 222 # libraries, so ensure these are later in INCLUDES than local source
 223 # directories.
 224 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 225 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 226
 227 dnl Add in path to PCRE includes
 228 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 229
 230 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 231
 232 case $host in
 233   *os2*)
 234       # Use a custom made libtool replacement
 235       echo "using aplibtool"
 236       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 237       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 238       SH_LIBS="\$(ALL_LIBS)"
 239       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 240       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 241       MK_IMPLIB="emximp"
 242       other_targets="$other_targets os2core"
 243       INSTALL_PROG_FLAGS="-e .exe"
 244       SHLTCFLAGS=""
 245       LTCFLAGS=""
 246       ;;
 247   *)
 248       if test "x$LTFLAGS" = "x"; then
 249           LTFLAGS='--silent'
 250       fi
 251       my_libtool=`$apr_config --apr-libtool`
 252       LIBTOOL="$my_libtool \$(LTFLAGS)"
 253       libtoolversion=`$my_libtool --version`
 254       case $libtoolversion in
 255           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 256               SH_LIBTOOL='$(LIBTOOL)'
 257               SHLTCFLAGS="-prefer-pic"
 258               LTCFLAGS="-prefer-non-pic -static"
 259               ;;
 260           *)
 261               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 262               SHLTCFLAGS=""
 263               LTCFLAGS=""
 264               ;;
 265       esac
 266       ;;
 267 esac
 268 APACHE_SUBST(SHLTCFLAGS)
 269 APACHE_SUBST(LTCFLAGS)
 270
 271 case $host in
 272   *-apple-aux3*)
 273       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 274       ;;
 275   *os2-emx*)
 276       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 277       ;;
 278   *-linux-*)
 279       case `uname -r` in
 280         2.[[2-9]]* )
 281             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 282             ;;
 283         * )
 284             ;;
 285       esac
 286       ;;
 287   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 288       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 289       ;;
 290   *-solaris2*)
 291       dnl This is a hack -- we should be using AC_TRY_RUN instead
 292       ap_platform_runtime_link_flag="-R"
 293       dnl solaris 8 and above don't have a thundering herd
 294       dnl not sure about rev's before this one.
 295       case `uname -r` in
 296         5.[567]*)
 297             ;;
 298         * )
 299             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 300             ;;
 301       esac
 302       ;;
 303   *cygwin*)
 304       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 305       ;;
 306   *mingw32*)
 307       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 308       APR_SETIFNULL(ac_cv_func_times, [no])
 309       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 310       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 311       ;;
 312   *aix*)
 313       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 314       if test $aixver -ge 4320; then
 315         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 316       fi
 317       ;;
 318   *os390*)
 319       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 320       ;;
 321 esac
 322
 323 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 324
 325 dnl
 326 dnl Process command line arguments. This is done early in the process so the
 327 dnl user can get feedback quickly in case of an error.
 328 dnl
 329 dnl ### need to move some of the arguments "up here"
 330
 331 dnl ## Check for programs
 332
 333 AC_PATH_PROG(RM, rm)
 334 AC_PATH_PROG(PKGCONFIG, pkg-config)
 335 AC_PATH_PROG(RSYNC, rsync)
 336 AC_PROG_AWK
 337 AC_PROG_LN_S
 338 AC_CHECK_TOOL(RANLIB, ranlib, true)
 339 dnl AC_PATH_PROG(PERL_PATH, perl)
 340 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 341
 342 # Hard-coded install programs
 343 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 344 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 345 APACHE_SUBST(MKINSTALLDIRS)
 346 APACHE_SUBST(INSTALL)
 347
 348 dnl Various OS checks that apparently set required flags
 349 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 350 AC_USE_SYSTEM_EXTENSIONS
 351 ], [
 352 AC_AIX
 353 AC_MINIX
 354 ])
 355
 356 AC_ISC_POSIX
 357
 358 # Ensure that satisfactory versions of apr and apr-util are
 359 # found if external copies are configured.
 360 if test "${apr_found}" = "yes"; then
 361   # Require at least APR 1.3.x otherwise fail
 362   APACHE_CHECK_APxVER([apr], 1, 3)
 363 fi
 364
 365 if test "${apu_found}" = "yes"; then
 366   # Require at least APR-util 1.3.x otherwise fail
 367   APACHE_CHECK_APxVER([apu], 1, 3)
 368 fi
 369
 370 dnl Check for what we can generate dependency files with
 371 APR_CHECK_DEPEND
 372
 373 dnl ## Check for libraries
 374
 375 dnl ## Check for header files
 376
 377 dnl I think these are just used all over the place, so just check for
 378 dnl them at the base of the tree. If some are specific to a single
 379 dnl directory, they should be moved (Comment #Spoon)
 380
 381 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 382 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 383 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 384
 385 AC_HEADER_STDC
 386 AC_CHECK_HEADERS( \
 387 string.h \
 388 limits.h \
 389 unistd.h \
 390 sys/socket.h \
 391 pwd.h \
 392 grp.h \
 393 strings.h \
 394 sys/prctl.h \
 395 sys/processor.h \
 396 sys/sem.h \
 397 sys/sdt.h
 398 )
 399 AC_HEADER_SYS_WAIT
 400
 401 dnl ## Check for typedefs, structures, and compiler characteristics.
 402
 403 AC_C_CONST
 404
 405 dnl ## Check for library functions
 406 dnl ## sqrt() only needed in support/ab.c
 407 saved_LIBS="$LIBS"
 408 LIBS=""
 409 AC_SEARCH_LIBS(sqrt, m)
 410 MATH_LIBS="$LIBS"
 411 APACHE_SUBST(MATH_LIBS)
 412 LIBS="$saved_LIBS"
 413
 414 dnl See Comment #Spoon
 415
 416 AC_CHECK_FUNCS( \
 417 getpwnam \
 418 getgrnam \
 419 initgroups \
 420 bindprocessor \
 421 prctl \
 422 timegm \
 423 getpgid
 424 )
 425
 426 dnl confirm that a void pointer is large enough to store a long integer
 427 APACHE_CHECK_VOID_PTR_LEN
 428
 429 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 430 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 431 [AC_TRY_COMPILE([#include <sys/types.h>
 432 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 433   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 434 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 435     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 436 fi
 437
 438 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 439
 440 case $host in
 441     *aix*)
 442         # for 32-bit builds, increase MAXDATA to allow lots of threads
 443         if test x$OBJECT_MODE != x64; then
 444             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 445         fi
 446         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 447         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 448         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 449         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 450         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 451         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 452         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 453         ;;
 454     *os390*)
 455         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 456         ;;
 457     *)
 458         OS_SPECIFIC_VARS=""
 459 esac
 460
 461 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 462         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 463         [PORT=80])
 464
 465 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 466         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 467         [SSLPORT=443])
 468
 469 DTRACE=true
 470 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 471 [
 472   enable_dtrace=$enableval
 473   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 474   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 475 ],
 476 [
 477   enable_dtrace=no
 478 ])
 479
 480 dnl Disabled dtrace build for now.
 481 enable_dtrace=no
 482
 483 case $host in
 484   *-solaris2*)
 485     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 486         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 487                   [Enable DTrace probes])
 488         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 489         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 490     fi
 491     ;;
 492 esac
 493
 494 APACHE_SUBST(DTRACE)
 495
 496 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 497
 498 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 499 [
 500   v4mapped=$enableval
 501 ],
 502 [
 503     case $host in
 504     *freebsd5*|*netbsd*|*openbsd*)
 505         v4mapped=no
 506         ;;
 507     *)
 508         v4mapped=yes
 509         ;;
 510 esac
 511 ])
 512
 513 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 514     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 515               [Allow IPv4 connections on IPv6 listening sockets])
 516 fi
 517
 518 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 519 [
 520     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 521               [Allow modules to run hook after a fatal exception])
 522 ])dnl
 523
 524 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 525 [
 526   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 527   if test "$GCC" = "yes"; then
 528     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations])
 529   elif test "$AIX_XLC" = "yes"; then
 530     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 531   fi
 532 ])dnl
 533
 534 dnl Conditionally enable PIE support for GNU toolchains.
 535 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 536 if test "$enable_pie" = "yes"; then
 537    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 538      save_CFLAGS=$CFLAGS
 539      save_LDFLAGS=$LDFLAGS
 540      CFLAGS="$CFLAGS -fPIE"
 541      LDFLAGS="$LDFLAGS -pie"
 542      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 543       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 544      CFLAGS=$save_CFLAGS
 545      LDFLAGS=$save_LDFLAGS
 546    ])
 547    if test "$ap_cv_cc_pie" = "yes"; then
 548      PICFLAGS="-fPIE"
 549      PILDFLAGS="-pie"
 550    else
 551      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 552    fi
 553 fi
 554 AC_SUBST(PICFLAGS)
 555 AC_SUBST(PILDFLAGS)
 556
 557 prefix="$orig_prefix"
 558 APACHE_ENABLE_MODULES
 559
 560 dnl reading config stubs
 561 esyscmd(./build/config-stubs .)
 562
 563 APACHE_SUBST(progname)
 564 APACHE_SUBST(OS)
 565 APACHE_SUBST(OS_DIR)
 566 APACHE_SUBST(BUILTIN_LIBS)
 567 APACHE_SUBST(SHLIBPATH_VAR)
 568 APACHE_SUBST(OS_SPECIFIC_VARS)
 569
 570 PRE_SHARED_CMDS='echo ""'
 571 POST_SHARED_CMDS='echo ""'
 572
 573 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 574
 575 if test "$apache_need_shared" = "yes"; then
 576   if test -f $ac_aux_dir/ltconfig; then
 577     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 578   fi
 579   shared_build="shared-build"
 580 fi
 581
 582 dnl enable_so tells us if *any* modules can be built as DSOs
 583
 584 if test "$enable_so" = "yes"; then
 585   case $host in
 586     *-ibm-aix*)
 587       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 588       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 589       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 590       ;;
 591     *os390)
 592       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 593       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 594   esac
 595   MOD_SO_ENABLED=yes
 596 fi
 597 AC_SUBST(MOD_SO_ENABLED)
 598
 599 APACHE_SUBST(PRE_SHARED_CMDS)
 600 APACHE_SUBST(POST_SHARED_CMDS)
 601 APACHE_SUBST(shared_build)
 602
 603 AC_ARG_WITH(program-name,
 604 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 605   progname="$withval" ], [
 606   progname="httpd"] )
 607
 608 # SuExec parameters
 609 AC_ARG_WITH(suexec-bin,
 610 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 611   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 612 ] )
 613
 614 AC_ARG_WITH(suexec-caller,
 615 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 616   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 617
 618 AC_ARG_WITH(suexec-userdir,
 619 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 620   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 621
 622 AC_ARG_WITH(suexec-docroot,
 623 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 624   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 625
 626 AC_ARG_WITH(suexec-uidmin,
 627 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 628   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 629
 630 AC_ARG_WITH(suexec-gidmin,
 631 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 632   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 633
 634 AC_ARG_WITH(suexec-logfile,
 635 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 636   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 637
 638 AC_ARG_WITH(suexec-safepath,
 639 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 640   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 641
 642 AC_ARG_WITH(suexec-umask,
 643 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 644   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 645
 646 dnl APR should go after the other libs, so the right symbols can be picked up
 647 if test x${apu_found} != xobsolete; then
 648   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 649 fi
 650 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 651 APACHE_SUBST(AP_LIBS)
 652 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 653 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 654
 655 AC_DEFINE(AP_USING_AUTOCONF, 1,
 656                 [Using autoconf to configure Apache])
 657
 658 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 659     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 660               [This platform doesn't suffer from the thundering herd problem])
 661 fi
 662
 663 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 664     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 665               [Listening sockets are non-blocking when there are more than 1])
 666 fi
 667
 668
 669 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 670 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 671 APACHE_FAST_OUTPUT(support/Makefile)
 672
 673 if test -d ./test; then
 674     APACHE_FAST_OUTPUT(test/Makefile)
 675 fi
 676
 677 dnl ## Finalize the variables
 678 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 679
 680 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 681 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 682 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 683 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 684 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 685 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 686
 687 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 688
 689 APACHE_GEN_CONFIG_VARS
 690
 691 dnl ## Build modules.c
 692 rm -f modules.c
 693 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 694
 695 APR_EXPAND_VAR(ap_prefix, $prefix)
 696 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 697         [Root directory of the Apache install area])
 698 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 699         [Location of the config file, relative to the Apache root directory])
 700 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 701         [Location of the MIME types config file, relative to the Apache root directory])
 702
 703 perlbin=`$ac_aux_dir/PrintPath perl`
 704 if test "x$perlbin" = "x"; then
 705     perlbin="/replace/with/path/to/perl/interpreter"
 706 fi
 707 AC_SUBST(perlbin)
 708
 709 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 710
 711 BSD_MAKEFILE=no
 712 ap_make_include=include
 713 ap_make_delimiter=' '
 714 case $host in
 715 *bsdi*)
 716     # Check whether they've installed GNU make
 717     if make --version > /dev/null 2>&1; then
 718         true
 719     else
 720         BSD_MAKEFILE=yes
 721         ap_make_include=.include
 722         ap_make_delimiter='"'
 723     fi
 724     ;;
 725 esac
 726 AC_SUBST(ap_make_include)
 727 AC_SUBST(ap_make_delimiter)
 728
 729 dnl Ensure that docs/conf is created.
 730 test -d docs/conf||$mkdir_p docs/conf
 731
 732 dnl Ensure that the httpd version is included
 733 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 734 AC_SUBST(HTTPD_VERSION)
 735
 736 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 737   APACHE_GEN_MAKEFILES
 738 ])