granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 AC_ARG_WITH(included-apr,
  65 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  66
  67 # Only APR 1.x is supported.
  68 apr_version=1
  69
  70 if test "x$with_included_apr" = "xyes"; then
  71    apr_found=reconfig
  72    apr_config="$srcdir/srclib/apr/apr-${apr_version}-config"
  73 else
  74    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, ${apr_version})
  75 fi
  76
  77 if test "$apr_found" = "no"; then
  78   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  79 fi
  80
  81 if test "$apr_found" = "reconfig"; then
  82   APR_SUBDIR_CONFIG(srclib/apr,
  83                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  84                     [--enable-layout=*|\'--enable-layout=*])
  85   dnl We must be the first to build and the last to be cleaned
  86   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  87   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  88 fi
  89
  90 APR_SETIFNULL(CC, `$apr_config --cc`)
  91 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  92 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  93 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  94 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  95 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  96 APR_BINDIR=`$apr_config --bindir`
  97 APR_INCLUDEDIR=`$apr_config --includedir`
  98 APR_INCLUDES=`$apr_config --includes`
  99 APR_VERSION=`$apr_config --version`
 100 APR_CONFIG="$APR_BINDIR/apr-`echo ${APR_VERSION} | sed 's,\..*,,'`-config"
 101
 102 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 103
 104 # Only APR-util 1.x is supported.
 105 apu_version=1
 106
 107 if test "x$with_included_apr" = "xyes"; then
 108    apu_found=reconfig
 109    apu_config="${srcdir}/srclib/apr-util/apu-${apu_version}-config"
 110 else
 111    APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1, ${apu_version})
 112 fi
 113
 114 if test "$apu_found" = "no"; then
 115   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 116 fi
 117
 118 # Catch some misconfigurations:
 119 case ${apr_found}.${apu_found} in
 120 reconfig.yes)
 121   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 122   ;;
 123 yes.reconfig)
 124   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 125   ;;
 126 esac
 127
 128 if test "$apu_found" = "reconfig"; then
 129   APR_SUBDIR_CONFIG(srclib/apr-util,
 130                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 131                     [--enable-layout=*|\'--enable-layout=*])
 132   dnl We must be the last to build and the first to be cleaned
 133   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 134   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 135 fi
 136
 137 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 138 APU_BINDIR=`$apu_config --bindir`
 139 APU_INCLUDEDIR=`$apu_config --includedir`
 140 APU_INCLUDES=`$apu_config --includes`
 141 APU_VERSION=`$apu_config --version`
 142 APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 143
 144 dnl In case we picked up CC and CPP from APR, get that info into the
 145 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 146 dnl PCRE and for our config tests will be whatever PCRE determines.
 147 AC_PROG_CC
 148 AC_PROG_CPP
 149
 150 if test "x${cache_file}" = "x/dev/null"; then
 151   # Likewise, ensure that CC and CPP are passed through to the pcre
 152   # configure script iff caching is disabled (the autoconf 2.5x default).
 153   export CC; export CPP
 154 fi
 155
 156 dnl Absolute source/build directory
 157 abs_srcdir=`(cd $srcdir && pwd)`
 158 abs_builddir=`pwd`
 159
 160 AC_ARG_WITH(pcre,
 161 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 162
 163 case $with_pcre in
 164 yes) AC_PATH_PROG(PCRE_CONFIG, pcre-config, false) ;;
 165  /*) if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 166        PCRE_CONFIG=$with_pcre/bin/pcre-config
 167      elif test -x "$with_pcre"; then
 168        PCRE_CONFIG=$with_pcre
 169      fi
 170
 171      if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 172        AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 173      fi
 174      ;;
 175 *) PCRE_CONFIG=false ;;
 176 esac
 177
 178 if test "$PCRE_CONFIG" != "false"; then
 179   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 180   APR_ADDTO(CFLAGS, [`$PCRE_CONFIG --cflags`])
 181   APR_ADDTO(LIBS, [`$PCRE_CONFIG --libs`])
 182 else
 183   # Build the bundled PCRE
 184   AC_MSG_NOTICE([Configuring PCRE regular expression library])
 185
 186   APR_SUBDIR_CONFIG(srclib/pcre,
 187                   [--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir])
 188
 189   APR_ADDTO(AP_LIBS, [$abs_builddir/srclib/pcre/libpcre.la])
 190   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/srclib/pcre])
 191
 192   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS pcre"
 193   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS pcre"
 194 fi
 195
 196 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 197
 198 dnl If the source dir is not equal to the build dir,
 199 dnl then we are running in VPATH mode.
 200
 201 APR_ADDTO(INCLUDES, [-I.])
 202
 203 if test "$abs_builddir" != "$abs_srcdir"; then
 204   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 205 fi
 206
 207 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/aaa -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/modules/session -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators -I\$(top_srcdir)/modules/mappers -I\$(top_srcdir)/modules/database])
 208
 209 # apr/apr-util --includes may pick up system paths for dependent
 210 # libraries, so ensure these are later in INCLUDES than local source
 211 # directories.
 212 APR_ADDTO(INCLUDES, `$apr_config --includes`)
 213 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 214
 215 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 216
 217 case $host in
 218   *os2*)
 219       # Use a custom made libtool replacement
 220       echo "using aplibtool"
 221       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 222       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 223       SH_LIBS="\$(ALL_LIBS)"
 224       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 225       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 226       MK_IMPLIB="emximp"
 227       other_targets="$other_targets os2core"
 228       INSTALL_PROG_FLAGS="-e .exe"
 229       SHLTCFLAGS=""
 230       LTCFLAGS=""
 231       ;;
 232   *)
 233       if test "x$LTFLAGS" = "x"; then
 234           LTFLAGS='--silent'
 235       fi
 236       my_libtool=`$apr_config --apr-libtool`
 237       LIBTOOL="$my_libtool \$(LTFLAGS)"
 238       libtoolversion=`$my_libtool --version`
 239       case $libtoolversion in
 240           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 241               SH_LIBTOOL='$(LIBTOOL)'
 242               SHLTCFLAGS="-prefer-pic"
 243               LTCFLAGS="-prefer-non-pic -static"
 244               ;;
 245           *)
 246               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 247               SHLTCFLAGS=""
 248               LTCFLAGS=""
 249               ;;
 250       esac
 251       ;;
 252 esac
 253 APACHE_SUBST(SHLTCFLAGS)
 254 APACHE_SUBST(LTCFLAGS)
 255
 256 case $host in
 257   *-apple-aux3*)
 258       APR_SETVAR(APACHE_MPM, [prefork])
 259       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 260       ;;
 261   *-beos*)
 262       APR_SETVAR(APACHE_MPM, [beos])
 263       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 264       ;;
 265   *os2-emx*)
 266       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 267       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 268       ;;
 269   *-linux-*)
 270       case `uname -r` in
 271         2.[[2-9]]* )
 272             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 273             ;;
 274         * )
 275             ;;
 276       esac
 277       ;;
 278   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 279       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 280       ;;
 281   *-solaris2*)
 282       dnl This is a hack -- we should be using AC_TRY_RUN instead
 283       ap_platform_runtime_link_flag="-R"
 284       dnl solaris 8 and above don't have a thundering herd
 285       dnl not sure about rev's before this one.
 286       case `uname -r` in
 287         5.[567]*)
 288             ;;
 289         * )
 290             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 291             ;;
 292       esac
 293       ;;
 294   *cygwin*)
 295       APR_SETVAR(APACHE_MPM, [prefork])
 296       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 297       ;;
 298   *mingw32*)
 299       APR_SETVAR(APACHE_MPM, [winnt])
 300       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 301       APR_SETIFNULL(ac_cv_func_times, [no])
 302       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 303       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 304       ;;
 305   *aix*)
 306       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 307       if test $aixver -ge 4320; then
 308         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 309       fi
 310       ;;
 311   *os390*)
 312       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 313       ;;
 314 esac
 315
 316 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 317
 318 dnl
 319 dnl Process command line arguments. This is done early in the process so the
 320 dnl user can get feedback quickly in case of an error.
 321 dnl
 322 dnl ### need to move some of the arguments "up here"
 323
 324 dnl ## Check for programs
 325
 326 AC_PATH_PROG(RM, rm)
 327 AC_PATH_PROG(PKGCONFIG, pkg-config)
 328 AC_PATH_PROG(RSYNC, rsync)
 329 AC_PROG_AWK
 330 AC_PROG_LN_S
 331 AC_CHECK_TOOL(RANLIB, ranlib, true)
 332 dnl AC_PATH_PROG(PERL_PATH, perl)
 333 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 334
 335 # Hard-coded install programs
 336 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 337 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 338 APACHE_SUBST(MKINSTALLDIRS)
 339 APACHE_SUBST(INSTALL)
 340
 341 dnl Various OS checks that apparently set required flags
 342 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 343 AC_USE_SYSTEM_EXTENSIONS
 344 ], [
 345 AC_AIX
 346 AC_MINIX
 347 ])
 348
 349 AC_ISC_POSIX
 350
 351 # Ensure that satisfactory versions of apr and apr-util are
 352 # found if external copies are configured.
 353 if test "${apr_found}" = "yes"; then
 354   # Require APR 1.3.x otherwise fail
 355   APACHE_CHECK_APxVER([apr], 1, 3)
 356 fi
 357
 358 if test "${apu_found}" = "yes"; then
 359   # Require APR-util 1.2.x otherwise fail
 360   APACHE_CHECK_APxVER([apu], 1, 2)
 361 fi
 362
 363 dnl Check for what we can generate dependency files with
 364 APR_CHECK_DEPEND
 365
 366 dnl ## Check for libraries
 367
 368 dnl ## Check for header files
 369
 370 dnl I think these are just used all over the place, so just check for
 371 dnl them at the base of the tree. If some are specific to a single
 372 dnl directory, they should be moved (Comment #Spoon)
 373
 374 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 375 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 376 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 377
 378 AC_HEADER_STDC
 379 AC_CHECK_HEADERS( \
 380 string.h \
 381 limits.h \
 382 unistd.h \
 383 sys/socket.h \
 384 pwd.h \
 385 grp.h \
 386 strings.h \
 387 sys/prctl.h \
 388 sys/processor.h \
 389 sys/sem.h
 390 )
 391 AC_HEADER_SYS_WAIT
 392
 393 dnl ## Check for typedefs, structures, and compiler characteristics.
 394
 395 AC_C_CONST
 396
 397 dnl ## Check for library functions
 398 AC_SEARCH_LIBS(sqrt, m)
 399
 400 dnl See Comment #Spoon
 401
 402 AC_CHECK_FUNCS( \
 403 getpwnam \
 404 getgrnam \
 405 initgroups \
 406 bindprocessor \
 407 prctl \
 408 timegm \
 409 getpgid
 410 )
 411
 412 dnl confirm that a void pointer is large enough to store a long integer
 413 APACHE_CHECK_VOID_PTR_LEN
 414
 415 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 416 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 417 [AC_TRY_COMPILE([#include <sys/types.h>
 418 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 419   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 420 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 421     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 422 fi
 423
 424 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 425
 426 case $host in
 427     *aix*)
 428         # for 32-bit builds, increase MAXDATA to allow lots of threads
 429         if test x$OBJECT_MODE != x64; then
 430             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 431         fi
 432         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 433         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 434         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 435         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 436         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 437         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 438         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 439         ;;
 440     *os390*)
 441         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 442         ;;
 443     *)
 444         OS_SPECIFIC_VARS=""
 445 esac
 446
 447 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 448         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 449         [PORT=80])
 450
 451 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 452         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 453         [SSLPORT=443])
 454
 455 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 456
 457 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 458 [
 459   v4mapped=$enableval
 460 ],
 461 [
 462     case $host in
 463     *freebsd5*|*netbsd*|*openbsd*)
 464         v4mapped=no
 465         ;;
 466     *)
 467         v4mapped=yes
 468         ;;
 469 esac
 470 ])
 471
 472 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 473     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 474               [Allow IPv4 connections on IPv6 listening sockets])
 475 fi
 476
 477 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 478 [
 479     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 480               [Allow modules to run hook after a fatal exception])
 481 ])dnl
 482
 483 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 484 [
 485   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 486 ])dnl
 487
 488 dnl Conditionally enable PIE support for GNU toolchains.
 489 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 490 if test "$enable_pie" = "yes"; then
 491    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 492      save_CFLAGS=$CFLAGS
 493      save_LDFLAGS=$LDFLAGS
 494      CFLAGS="$CFLAGS -fPIE"
 495      LDFLAGS="$LDFLAGS -pie"
 496      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 497       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 498      CFLAGS=$save_CFLAGS
 499      LDFLAGS=$save_LDFLAGS
 500    ])
 501    if test "$ap_cv_cc_pie" = "yes"; then
 502      PICFLAGS="-fPIE"
 503      PILDFLAGS="-pie"
 504    else
 505      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 506    fi
 507 fi
 508 AC_SUBST(PICFLAGS)
 509 AC_SUBST(PILDFLAGS)
 510
 511 prefix="$orig_prefix"
 512 APACHE_ENABLE_MODULES
 513
 514 dnl reading config stubs
 515 esyscmd(./build/config-stubs .)
 516
 517 APACHE_SUBST(progname)
 518 APACHE_SUBST(MPM_LIB)
 519 APACHE_SUBST(OS)
 520 APACHE_SUBST(OS_DIR)
 521 APACHE_SUBST(BUILTIN_LIBS)
 522 APACHE_SUBST(SHLIBPATH_VAR)
 523 APACHE_SUBST(OS_SPECIFIC_VARS)
 524
 525 PRE_SHARED_CMDS='echo ""'
 526 POST_SHARED_CMDS='echo ""'
 527
 528 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 529
 530 if test "$apache_need_shared" = "yes"; then
 531   if test -f $ac_aux_dir/ltconfig; then
 532     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 533   fi
 534   shared_build="shared-build"
 535 fi
 536
 537 dnl enable_so tells us if *any* modules can be built as DSOs
 538
 539 if test "$enable_so" = "yes"; then
 540   case $host in
 541     *-ibm-aix*)
 542       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 543       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 544       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 545       ;;
 546     *beos)
 547       SH_LDFLAGS='$(top_builddir)/_APP_'
 548       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 549       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 550       ;;
 551     *os390)
 552       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 553       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 554   esac
 555   MOD_SO_ENABLED=yes
 556 fi
 557 AC_SUBST(MOD_SO_ENABLED)
 558
 559 APACHE_SUBST(PRE_SHARED_CMDS)
 560 APACHE_SUBST(POST_SHARED_CMDS)
 561 APACHE_SUBST(shared_build)
 562
 563 AC_ARG_WITH(program-name,
 564 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 565   progname="$withval" ], [
 566   progname="httpd"] )
 567
 568 # SuExec parameters
 569 AC_ARG_WITH(suexec-bin,
 570 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 571   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 572 ] )
 573
 574 AC_ARG_WITH(suexec-caller,
 575 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 576   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 577
 578 AC_ARG_WITH(suexec-userdir,
 579 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 580   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 581
 582 AC_ARG_WITH(suexec-docroot,
 583 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 584   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 585
 586 AC_ARG_WITH(suexec-uidmin,
 587 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 588   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 589
 590 AC_ARG_WITH(suexec-gidmin,
 591 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 592   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 593
 594 AC_ARG_WITH(suexec-logfile,
 595 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 596   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 597
 598 AC_ARG_WITH(suexec-safepath,
 599 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 600   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 601
 602 AC_ARG_WITH(suexec-umask,
 603 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 604   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 605
 606 dnl APR should go after the other libs, so the right symbols can be picked up
 607 AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 608 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 609 APACHE_SUBST(AP_LIBS)
 610 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 611 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 612
 613 AC_DEFINE(AP_USING_AUTOCONF, 1,
 614                 [Using autoconf to configure Apache])
 615
 616 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 617     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 618               [This platform doesn't suffer from the thundering herd problem])
 619 fi
 620
 621 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 622     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 623               [Listening sockets are non-blocking when there are more than 1])
 624 fi
 625
 626
 627 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 628 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 629 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 630
 631 if test -d ./test; then
 632     APACHE_FAST_OUTPUT(test/Makefile)
 633 fi
 634
 635 dnl ## Finalize the variables
 636 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 637
 638 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 639 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 640 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 641 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 642 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 643 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 644
 645 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 646
 647 APACHE_GEN_CONFIG_VARS
 648
 649 dnl ## Build modules.c
 650 rm -f modules.c
 651 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 652
 653 APR_EXPAND_VAR(ap_prefix, $prefix)
 654 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 655         [Root directory of the Apache install area])
 656 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 657         [Location of the config file, relative to the Apache root directory])
 658 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 659         [Location of the MIME types config file, relative to the Apache root directory])
 660 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 661         [Location of the source for the current MPM])
 662
 663 perlbin=`$ac_aux_dir/PrintPath perl`
 664 if test "x$perlbin" = "x"; then
 665     perlbin="/replace/with/path/to/perl/interpreter"
 666 fi
 667 AC_SUBST(perlbin)
 668
 669 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 670
 671 BSD_MAKEFILE=no
 672 ap_make_include=include
 673 ap_make_delimiter=' '
 674 case $host in
 675 *bsdi*)
 676     # Check whether they've installed GNU make
 677     if make --version > /dev/null 2>&1; then
 678         true
 679     else
 680         BSD_MAKEFILE=yes
 681         ap_make_include=.include
 682         ap_make_delimiter='"'
 683     fi
 684     ;;
 685 esac
 686 AC_SUBST(ap_make_include)
 687 AC_SUBST(ap_make_delimiter)
 688
 689 dnl Ensure that docs/conf is created.
 690 test -d docs/conf||$mkdir_p docs/conf
 691
 692 dnl Ensure that the httpd version is included
 693 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 694 AC_SUBST(HTTPD_VERSION)
 695
 696 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 697   APACHE_GEN_MAKEFILES
 698 ])
 699
 700 case $MPM_SUBDIR_NAME in
 701 *experimental*)
 702     echo ""
 703     echo ""
 704     echo "============================================================"
 705     echo "    WARNING: THE '${APACHE_MPM}' MPM IS EXPERIMENTAL"
 706     echo "============================================================"
 707     echo " The selected MPM might not be fully functional!"
 708     echo ""
 709     echo " Development of this MPM is not complete. Do not use this"
 710     echo " MPM unless you are a programmer willing to help fix it."
 711     echo ""
 712     echo " If you are looking for a stable server, you should not use"
 713     echo " the '${APACHE_MPM}' MPM until it is moved out of experimental."
 714     echo "============================================================"
 715     echo ""
 716     echo ""
 717     ;;
 718 esac