granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.455 2006/03/06 17:41:43 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2006, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # C compiler
 210 #
 211
 212 # For historical reasons you can also use --with-CC to specify the C compiler
 213 # to use, although the standard way to do this is to set the CC environment
 214 # variable.
 215 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 216
 217 case $template in
 218   aix) pgac_cc_list="gcc xlc";;
 219  irix) pgac_cc_list="cc";; # no gcc
 220     *) pgac_cc_list="gcc cc";;
 221 esac
 222
 223 AC_PROG_CC([$pgac_cc_list])
 224
 225 unset CFLAGS
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # CFLAGS are selected so:
 233 # If the user specifies something in the environment, that is used.
 234 # else:  If the template file set something, that is used.
 235 # else:  If the compiler is GCC, then we use -O2.
 236 # else:  If the compiler is something else, then we use -0.
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 elif test "${CFLAGS+set}" = set; then
 241   : # (keep what template set)
 242 elif test "$GCC" = yes; then
 243   CFLAGS="-O2"
 244 else
 245   # if the user selected debug mode, don't use -O
 246   if test "$enable_debug" != yes; then
 247     CFLAGS="-O"
 248   fi
 249 fi
 250
 251 if test "$GCC" = yes; then
 252   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 253
 254   # Some versions of GCC support some additional useful warning flags.
 255   # Check whether they are supported, and add them to CFLAGS if so.
 256   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 257   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 258
 259   # Disable strict-aliasing rules; needed for gcc 3.3+
 260   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 261 fi
 262
 263 # supply -g if --enable-debug
 264 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 265   CFLAGS="$CFLAGS -g"
 266 fi
 267
 268 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 269
 270 # We already have this in Makefile.win32, but configure needs it too
 271 if test "$PORTNAME" = "win32"; then
 272   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 273 fi
 274
 275 # Check if the compiler still works with the template settings
 276 AC_MSG_CHECKING([whether the C compiler still works])
 277 AC_TRY_LINK([], [return 0;],
 278   [AC_MSG_RESULT(yes)],
 279   [AC_MSG_RESULT(no)
 280    AC_MSG_ERROR([cannot proceed])])
 281
 282 # Defend against gcc -ffast-math
 283 if test "$GCC" = yes; then
 284 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 285 choke me
 286 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 287 fi
 288
 289 AC_PROG_CPP
 290 AC_SUBST(GCC)
 291
 292 # Create compiler version string
 293 if test x"$GCC" = x"yes" ; then
 294   cc_string="GCC `${CC} --version | sed q`"
 295 else
 296   cc_string=$CC
 297 fi
 298 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 299                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 300                    [A string containing the version number, platform, and C compiler])
 301
 302
 303 #
 304 # Set up TAS assembly code if needed; the template file has now had its
 305 # chance to request this.
 306 #
 307 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 308
 309 if test "$need_tas" = yes ; then
 310   TAS=tas.o
 311 else
 312   TAS=""
 313 fi
 314 AC_SUBST(TAS)
 315
 316
 317 #
 318 # Automatic dependency tracking
 319 #
 320 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 321               [autodepend=yes])
 322 AC_SUBST(autodepend)
 323
 324
 325 #
 326 # Enable assert checks
 327 #
 328 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 329               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 330                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 331
 332
 333 #
 334 # Include directories
 335 #
 336 ac_save_IFS=$IFS
 337 IFS="${IFS}${PATH_SEPARATOR}"
 338 # SRCH_INC comes from the template file
 339 for dir in $with_includes $SRCH_INC; do
 340   if test -d "$dir"; then
 341     INCLUDES="$INCLUDES -I$dir"
 342   else
 343     AC_MSG_WARN([*** Include directory $dir does not exist.])
 344   fi
 345 done
 346 IFS=$ac_save_IFS
 347 AC_SUBST(INCLUDES)
 348
 349
 350 #
 351 # Library directories
 352 #
 353 ac_save_IFS=$IFS
 354 IFS="${IFS}${PATH_SEPARATOR}"
 355 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 356 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 357   if test -d "$dir"; then
 358     LIBDIRS="$LIBDIRS -L$dir"
 359   else
 360     AC_MSG_WARN([*** Library directory $dir does not exist.])
 361   fi
 362 done
 363 IFS=$ac_save_IFS
 364
 365 #
 366 # Enable thread-safe client libraries
 367 #
 368 AC_MSG_CHECKING([allow thread-safe client libraries])
 369 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 370 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 371 if test "$enable_thread_safety" = yes -o \
 372         "$enable_thread_safety_force" = yes; then
 373   enable_thread_safety="yes"    # for 'force'
 374   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 375           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 376 fi
 377 AC_MSG_RESULT([$enable_thread_safety])
 378 AC_SUBST(enable_thread_safety)
 379
 380 #
 381 # Optionally build Tcl modules (PL/Tcl)
 382 #
 383 AC_MSG_CHECKING([whether to build with Tcl])
 384 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 385 AC_MSG_RESULT([$with_tcl])
 386 AC_SUBST([with_tcl])
 387
 388 # We see if the path to the Tcl/Tk configuration scripts is specified.
 389 # This will override the use of tclsh to find the paths to search.
 390
 391 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 392
 393 #
 394 # Optionally build Perl modules (PL/Perl)
 395 #
 396 AC_MSG_CHECKING([whether to build Perl modules])
 397 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 398 AC_MSG_RESULT([$with_perl])
 399 AC_SUBST(with_perl)
 400
 401 #
 402 # Optionally build Python modules (PL/Python)
 403 #
 404 AC_MSG_CHECKING([whether to build Python modules])
 405 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 406 AC_MSG_RESULT([$with_python])
 407 AC_SUBST(with_python)
 408
 409 #
 410 # Kerberos 5
 411 #
 412 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 413 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 414 [
 415   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 416   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 417 ])
 418 AC_MSG_RESULT([$with_krb5])
 419 AC_SUBST(with_krb5)
 420
 421
 422 AC_SUBST(krb_srvtab)
 423
 424
 425 #
 426 # Kerberos configuration parameters
 427 #
 428 PGAC_ARG_REQ(with, krb-srvnam,
 429              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 430              [],
 431              [with_krb_srvnam="postgres"])
 432 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 433                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 434
 435
 436 #
 437 # PAM
 438 #
 439 AC_MSG_CHECKING([whether to build with PAM support])
 440 PGAC_ARG_BOOL(with, pam, no,
 441               [  --with-pam              build with PAM support],
 442               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 443 AC_MSG_RESULT([$with_pam])
 444 AC_SUBST(with_pam)
 445
 446
 447 #
 448 # LDAP
 449 #
 450 AC_MSG_CHECKING([whether to build with LDAP support])
 451 PGAC_ARG_BOOL(with, ldap, no,
 452               [  --with-ldap             build with LDAP support],
 453               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 454 AC_MSG_RESULT([$with_ldap])
 455 AC_SUBST(with_ldap)
 456
 457
 458 #
 459 # Bonjour
 460 #
 461 AC_MSG_CHECKING([whether to build with Bonjour support])
 462 PGAC_ARG_BOOL(with, bonjour, no,
 463               [  --with-bonjour          build with Bonjour support],
 464               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 465 AC_MSG_RESULT([$with_bonjour])
 466 AC_SUBST(with_bonjour)
 467
 468
 469 #
 470 # OpenSSL
 471 #
 472 AC_MSG_CHECKING([whether to build with OpenSSL support])
 473 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 474               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 475 AC_MSG_RESULT([$with_openssl])
 476 AC_SUBST(with_openssl)
 477
 478
 479 #
 480 # Prefer libedit
 481 #
 482 PGAC_ARG_BOOL(with, libedit-preferred, no,
 483               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 484
 485
 486 #
 487 # Readline
 488 #
 489 PGAC_ARG_BOOL(with, readline, yes,
 490               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 491 # readline on MinGW has problems with backslashes in psql and other bugs.
 492 # This is particularly a problem with non-US code pages.
 493 # Therefore disable its use until we understand the cause. 2004-07-20
 494 if test "$PORTNAME" = "win32"; then
 495   if test "$with_readline" = yes; then
 496     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 497     with_readline=no
 498   fi
 499 fi
 500
 501
 502 #
 503 # Zlib
 504 #
 505 PGAC_ARG_BOOL(with, zlib, yes,
 506               [  --without-zlib          do not use Zlib])
 507 AC_SUBST(with_zlib)
 508
 509 #
 510 # Elf
 511 #
 512
 513 # Assume system is ELF if it predefines __ELF__ as 1,
 514 # otherwise believe host_os based default.
 515 case $host_os in
 516     freebsd1*|freebsd2*) elf=no;;
 517     freebsd3*|freebsd4*) elf=yes;;
 518 esac
 519
 520 AC_EGREP_CPP(yes,
 521 [#if __ELF__
 522   yes
 523 #endif
 524 ],
 525 [ELF_SYS=true],
 526 [if test "X$elf" = "Xyes" ; then
 527   ELF_SYS=true
 528 else
 529   ELF_SYS=
 530 fi])
 531 AC_SUBST(ELF_SYS)
 532
 533 #
 534 # Assignments
 535 #
 536
 537 CPPFLAGS="$CPPFLAGS $INCLUDES"
 538 LDFLAGS="$LDFLAGS $LIBDIRS"
 539
 540 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 541 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 542
 543 AC_ARG_VAR(LDFLAGS_SL)
 544
 545 AC_PROG_AWK
 546 PGAC_PATH_FLEX
 547 AC_PROG_LN_S
 548 PGAC_PROG_LD
 549 AC_SUBST(LD)
 550 AC_SUBST(with_gnu_ld)
 551 case $host_os in sysv5*)
 552   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 553   [
 554     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 555     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 556     LDFLAGS=$pgac_save_LDFLAGS
 557   ])
 558   ld_R_works=$pgac_cv_prog_ld_R
 559   AC_SUBST(ld_R_works)
 560 esac
 561 AC_PROG_RANLIB
 562 AC_CHECK_PROGS(LORDER, lorder)
 563 AC_PATH_PROG(TAR, tar)
 564 PGAC_CHECK_STRIP
 565
 566 AC_CHECK_PROGS(YACC, ['bison -y'])
 567
 568 if test "$YACC"; then
 569   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 570     AC_MSG_WARN([
 571 *** If you are going to modify the grammar files or build from CVS, the installed
 572 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 573   fi
 574 fi
 575
 576 if test -z "$YACC"; then
 577   AC_MSG_WARN([
 578 *** Without Bison you will not be able to build PostgreSQL from CVS or
 579 *** change any of the parser definition files.  You can obtain Bison from
 580 *** a GNU mirror site.  (If you are using the official distribution of
 581 *** PostgreSQL then you do not need to worry about this because the Bison
 582 *** output is pre-generated.)  To use a different yacc program (possible,
 583 *** but not recommended), set the environment variable YACC before running
 584 *** 'configure'.])
 585 fi
 586 AC_SUBST(YFLAGS)
 587
 588 PGAC_PATH_PERL
 589 if test "$with_perl" = yes; then
 590   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 591   PGAC_CHECK_PERL_EMBED_LDFLAGS
 592 fi
 593
 594 if test "$with_python" = yes; then
 595   PGAC_PATH_PYTHON
 596   PGAC_CHECK_PYTHON_EMBED_SETUP
 597 fi
 598
 599 # Supply a numeric version string for use by 3rd party add-ons
 600 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 601 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 602 tr '.' '        ' |
 603 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 604 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 605
 606 ##
 607 ## Libraries
 608 ##
 609
 610 AC_SEARCH_LIBS(setproctitle, util)
 611 AC_SEARCH_LIBS(pow, m)
 612 AC_SEARCH_LIBS(dlopen, dl)
 613 AC_SEARCH_LIBS(socket, [socket wsock32])
 614 AC_SEARCH_LIBS(shl_load, dld)
 615 # We only use libld in port/dynloader/aix.c
 616 case $host_os in
 617      aix*)
 618         AC_SEARCH_LIBS(ldopen, ld)
 619         ;;
 620 esac
 621 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 622 AC_SEARCH_LIBS(crypt, crypt)
 623 # Solaris:
 624 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 625 # Cygwin:
 626 AC_SEARCH_LIBS(shmget, cygipc)
 627
 628 if test "$with_readline" = yes; then
 629   PGAC_CHECK_READLINE
 630   if test x"$pgac_cv_check_readline" = x"no"; then
 631     AC_MSG_ERROR([readline library not found
 632 If you have readline already installed, see config.log for details on the
 633 failure.  It is possible the compiler isn't looking in the proper directory.
 634 Use --without-readline to disable readline support.])
 635   fi
 636 fi
 637
 638 if test "$with_zlib" = yes; then
 639   AC_CHECK_LIB(z, inflate, [],
 640                [AC_MSG_ERROR([zlib library not found
 641 If you have zlib already installed, see config.log for details on the
 642 failure.  It is possible the compiler isn't looking in the proper directory.
 643 Use --without-zlib to disable zlib support.])])
 644 fi
 645
 646 if test "$enable_spinlocks" = yes; then
 647   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 648 else
 649   AC_MSG_WARN([
 650 *** Not using spinlocks will cause poor performance.])
 651 fi
 652
 653 if test "$with_krb5" = yes ; then
 654   if test "$PORTNAME" != "win32"; then
 655      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 656                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 657      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 658                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 659      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 660                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 661   else
 662      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 663                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 664   fi
 665 fi
 666
 667 if test "$with_openssl" = yes ; then
 668   dnl Order matters!
 669   if test "$PORTNAME" != "win32"; then
 670      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 671      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 672   else
 673      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 674      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 675   fi
 676 fi
 677
 678 if test "$with_pam" = yes ; then
 679   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 680 fi
 681
 682
 683 if test "$with_ldap" = yes ; then
 684   if test "$PORTNAME" != "win32"; then
 685      AC_CHECK_LIB(ldap,    ldap_bind, [], [AC_MSG_ERROR([library 'ldap' is required for LDAP])])
 686   else
 687      AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
 688   fi
 689 fi
 690
 691 ##
 692 ## Header files
 693 ##
 694
 695 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 696 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 697
 698 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 699 # netinet/in.h is included first.
 700 AC_CHECK_HEADERS(netinet/in.h)
 701 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 702 [AC_INCLUDES_DEFAULT
 703 #ifdef HAVE_NETINET_IN_H
 704 #include <netinet/in.h>
 705 #endif
 706 ])
 707
 708 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 709   AC_CHECK_HEADERS(readline/readline.h, [],
 710         [AC_CHECK_HEADERS(readline.h, [],
 711                 [AC_MSG_ERROR([readline header not found
 712 If you have readline already installed, see config.log for details on the
 713 failure.  It is possible the compiler isn't looking in the proper directory.
 714 Use --without-readline to disable readline support.])])])
 715   AC_CHECK_HEADERS(readline/history.h, [],
 716         [AC_CHECK_HEADERS(history.h, [],
 717                 [AC_MSG_ERROR([history header not found
 718 If you have readline already installed, see config.log for details on the
 719 failure.  It is possible the compiler isn't looking in the proper directory.
 720 Use --without-readline to disable readline support.])])])
 721 fi
 722
 723 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 724 # Some installations of libedit usurp /usr/include/readline/, which seems
 725 # bad practice, since in combined installations readline will have its headers
 726 # there.  We might have to resort to AC_EGREP checks to make sure we found
 727 # the proper header...
 728   AC_CHECK_HEADERS(editline/readline.h, [],
 729         [AC_CHECK_HEADERS(readline.h, [],
 730                 [AC_CHECK_HEADERS(readline/readline.h, [],
 731                         [AC_MSG_ERROR([readline header not found
 732 If you have libedit already installed, see config.log for details on the
 733 failure.  It is possible the compiler isn't looking in the proper directory.
 734 Use --without-readline to disable libedit support.])])])])
 735   AC_CHECK_HEADERS(editline/history.h, [],
 736         [AC_CHECK_HEADERS(history.h, [],
 737                 [AC_CHECK_HEADERS(readline/history.h, [],
 738                         [AC_MSG_ERROR([history header not found
 739 If you have libedit already installed, see config.log for details on the
 740 failure.  It is possible the compiler isn't looking in the proper directory.
 741 Use --without-readline to disable libedit support.])])])])
 742 fi
 743
 744 if test "$with_zlib" = yes; then
 745   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 746 If you have zlib already installed, see config.log for details on the
 747 failure.  It is possible the compiler isn't looking in the proper directory.
 748 Use --without-zlib to disable zlib support.])])
 749 fi
 750
 751 if test "$with_krb5" = yes ; then
 752   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 753 fi
 754
 755 if test "$with_openssl" = yes ; then
 756   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 757   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 758 fi
 759
 760 if test "$with_pam" = yes ; then
 761   AC_CHECK_HEADERS(security/pam_appl.h, [],
 762                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 763                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 764 fi
 765
 766 if test "$with_ldap" = yes ; then
 767   if test "$PORTNAME" != "win32"; then
 768      AC_CHECK_HEADERS(ldap.h, [],
 769                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 770   else
 771      AC_CHECK_HEADERS(winldap.h, [],
 772                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 773                       [AC_INCLUDES_DEFAULT
 774 #include <windows.h>
 775                       ])
 776   fi
 777 fi
 778
 779 if test "$with_bonjour" = yes ; then
 780   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 781 fi
 782
 783
 784 ##
 785 ## Types, structures, compiler characteristics
 786 ##
 787
 788 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 789 AC_C_CONST
 790 AC_C_INLINE
 791 AC_C_STRINGIZE
 792 PGAC_C_SIGNED
 793 AC_C_VOLATILE
 794 PGAC_C_FUNCNAME_SUPPORT
 795 PGAC_STRUCT_TIMEZONE
 796 PGAC_UNION_SEMUN
 797 PGAC_STRUCT_SOCKADDR_UN
 798 PGAC_STRUCT_SOCKADDR_STORAGE
 799 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 800 PGAC_STRUCT_ADDRINFO
 801
 802 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 803 [#include <sys/param.h>
 804 #include <sys/types.h>
 805 #include <sys/socket.h>
 806 #include <sys/ucred.h>])
 807
 808 AC_CHECK_TYPES([struct option], [], [],
 809 [#ifdef HAVE_GETOPT_H
 810 #include <getopt.h>
 811 #endif])
 812
 813 if test "$with_zlib" = yes; then
 814   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 815   # did not).  While we could work around the lack of z_streamp, it
 816   # seems unwise to encourage people to use such old zlib versions...
 817   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 818 Use --without-zlib to disable zlib support.])],
 819                 [#include <zlib.h>])
 820 fi
 821
 822 if test "$with_krb5" = yes; then
 823 # Check for differences between MIT and Heimdal (KTH) releases
 824   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 825                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 826                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 827                                      [#include <krb5.h>])],
 828                    [#include <krb5.h>])
 829   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 830                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 831                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 832                                      [#include <krb5.h>])],
 833                    [#include <krb5.h>])
 834 fi
 835
 836 # This is probably only present on Darwin, but may as well check always
 837 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 838
 839 ##
 840 ## Functions, global variables
 841 ##
 842
 843 PGAC_VAR_INT_TIMEZONE
 844 AC_FUNC_ACCEPT_ARGTYPES
 845 PGAC_FUNC_GETTIMEOFDAY_1ARG
 846
 847 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 848
 849 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 850
 851 HAVE_IPV6=no
 852 AC_CHECK_TYPE([struct sockaddr_in6],
 853         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 854          HAVE_IPV6=yes],
 855         [],
 856 [$ac_includes_default
 857 #include <netinet/in.h>])
 858 AC_SUBST(HAVE_IPV6)
 859
 860 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 861 [AC_TRY_LINK(
 862 [#include <machine/vmparam.h>
 863 #include <sys/exec.h>
 864 ],
 865 [PS_STRINGS->ps_nargvstr = 1;
 866 PS_STRINGS->ps_argvstr = "foo";],
 867 [pgac_cv_var_PS_STRINGS=yes],
 868 [pgac_cv_var_PS_STRINGS=no])])
 869 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 870   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 871 fi
 872
 873
 874 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 875 # is missing.  Yes, there are machines that have only one.  We may
 876 # also decide to use snprintf.c if snprintf() is present but does not
 877 # have all the features we need --- see below.
 878
 879 if test "$PORTNAME" = "win32"; then
 880   # Win32 gets snprintf.c built unconditionally.
 881   #
 882   # To properly translate all NLS languages strings, we must support the
 883   # *printf() %$ format, which allows *printf() arguments to be selected
 884   # by position in the translated string.
 885   #
 886   # libintl versions < 0.13 use the native *printf() functions, and Win32
 887   # *printf() doesn't understand %$, so we must use our /port versions,
 888   # which do understand %$. libintl versions >= 0.13 include their own
 889   # *printf versions on Win32.  The libintl 0.13 release note text is:
 890   #
 891   #   C format strings with positions, as they arise when a translator
 892   #   needs to reorder a sentence, are now supported on all platforms.
 893   #   On those few platforms (NetBSD and Woe32) for which the native
 894   #   printf()/fprintf()/... functions don't support such format
 895   #   strings, replacements are provided through <libintl.h>.
 896   #
 897   # We could use libintl >= 0.13's *printf() if we were sure that we had
 898   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 899   # to guarantee that, it is best to just use our own, so we are sure to
 900   # get %$ support. In include/port.h we disable the *printf() macros
 901   # that might have been defined by libintl.
 902   #
 903   # We do this unconditionally whether NLS is used or not so we are sure
 904   # that all Win32 libraries and binaries behave the same.
 905   pgac_need_repl_snprintf=yes
 906 else
 907   pgac_need_repl_snprintf=no
 908   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 909   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 910 fi
 911
 912
 913 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 914 # include/c.h will provide declarations.  Note this is a separate test
 915 # from whether the functions exist in the C library --- there are
 916 # systems that have the functions but don't bother to declare them :-(
 917
 918 AC_CHECK_DECLS([snprintf, vsnprintf])
 919
 920
 921 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 922 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 923 [AC_TRY_LINK([
 924 #include <math.h>
 925 double glob_double;
 926 ],
 927 [return isinf(glob_double) ? 0 : 1;],
 928 [ac_cv_func_isinf=yes],
 929 [ac_cv_func_isinf=no])])
 930
 931 if test $ac_cv_func_isinf = yes ; then
 932   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 933 else
 934   AC_LIBOBJ(isinf)
 935   # Look for a way to implement a substitute for isinf()
 936   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 937 fi
 938
 939 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 940
 941 # System's version of getaddrinfo(), if any, may be used only if we found
 942 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 943 # (Note: the AC_TRY_LINK probe fails on Windows, where the available
 944 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 945 # because we want to use our own getaddrinfo.c on Windows anyway.)
 946 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 947   dnl Cannot use AC_CHECK_FUNC because getaddrinfo may be a macro
 948   AC_MSG_CHECKING(for getaddrinfo)
 949   AC_TRY_LINK([
 950 #include <sys/socket.h>
 951 #include <netdb.h>
 952 ],
 953             [return getaddrinfo("", "", NULL, NULL) ? 0 : 1;],
 954             [AC_DEFINE(HAVE_GETADDRINFO, 1, [Define to 1 if you have getaddrinfo().])
 955   AC_MSG_RESULT(yes)],
 956             [AC_MSG_RESULT(no)
 957              AC_LIBOBJ(getaddrinfo)])
 958 else
 959   AC_LIBOBJ(getaddrinfo)
 960 fi
 961
 962 # similarly, use system's getopt_long() only if system provides struct option.
 963 if test x"$ac_cv_type_struct_option" = xyes ; then
 964   AC_REPLACE_FUNCS([getopt_long])
 965 else
 966   AC_LIBOBJ(getopt_long)
 967 fi
 968
 969 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 970 # We override the previous test that said fseeko/ftello didn't exist
 971 # OS tests are also done in include/c.h and port/fseeko.c
 972 case $host_os in bsdi*|netbsd*)
 973 ac_cv_func_fseeko=yes
 974 esac
 975
 976 # Solaris has a very slow qsort in certain cases, so we replace it:
 977 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 978 # Supposedly it is fixed in Solaris, but not sure which version, and
 979 # no confirmed testing.  2005-12-16
 980 if test "$PORTNAME" = "solaris"; then
 981 AC_LIBOBJ(qsort)
 982 fi
 983
 984 # Win32 support
 985 if test "$PORTNAME" = "win32"; then
 986 AC_LIBOBJ(gettimeofday)
 987 AC_LIBOBJ(kill)
 988 AC_LIBOBJ(open)
 989 AC_LIBOBJ(rand)
 990 AC_DEFINE([HAVE_SYMLINK], 1,
 991           [Define to 1 if you have the `symlink' function.])
 992 fi
 993
 994 if test "$with_readline" = yes; then
 995   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 996   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 997   AC_CHECK_FUNCS([replace_history_entry])
 998 fi
 999
1000
1001 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
1002 AC_MSG_CHECKING(for finite)
1003 AC_TRY_LINK([
1004 #include <math.h>
1005 double glob_double;
1006 ],
1007             [return finite(glob_double) ? 0 : 1;],
1008             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
1009 AC_MSG_RESULT(yes)],
1010             [AC_MSG_RESULT(no)])
1011
1012 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1013 dnl (especially on GNU libc)
1014 dnl See also comments in c.h.
1015 AC_MSG_CHECKING(for sigsetjmp)
1016 AC_TRY_LINK([#include <setjmp.h>],
1017             [sigjmp_buf x; sigsetjmp(x, 1);],
1018             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1019 AC_MSG_RESULT(yes)],
1020             [AC_MSG_RESULT(no)])
1021
1022 AC_CHECK_FUNC(syslog,
1023               [AC_CHECK_HEADER(syslog.h,
1024                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1025
1026 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1027 [AC_TRY_LINK([#include <unistd.h>],
1028   [extern int optreset; optreset = 1;],
1029   [pgac_cv_var_int_optreset=yes],
1030   [pgac_cv_var_int_optreset=no])])
1031 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1032   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1033 fi
1034
1035 AC_CHECK_FUNCS([strtoll strtoq], [break])
1036 AC_CHECK_FUNCS([strtoull strtouq], [break])
1037
1038 # Check for one of atexit() or on_exit()
1039 AC_CHECK_FUNCS(atexit, [],
1040                [AC_CHECK_FUNCS(on_exit, [],
1041                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1042
1043 AC_FUNC_FSEEKO
1044
1045 #
1046 # Pthreads
1047 #
1048 # For each platform, we need to know about any special compile and link
1049 # libraries, and whether the normal C function names are thread-safe.
1050 # See the comment at the top of src/port/thread.c for more information.
1051 #
1052 if test "$enable_thread_safety" = yes; then
1053 ACX_PTHREAD     # set thread flags
1054
1055 # Some platforms use these, so just defineed them.  They can't hurt if they
1056 # are not supported.
1057 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1058
1059
1060 # At this point, we don't want to muck with the compiler name for threading.
1061 # Let's see who fails, perhaps AIX.  2004-04-23
1062 if test "$PTHREAD_CC" != "$CC"; then
1063 AC_MSG_ERROR([
1064 PostgreSQL does not support platforms that require a special
1065 compiler binary for thread-safety.
1066 ])
1067 fi
1068
1069 if test "$THREAD_SUPPORT" = no; then
1070 AC_MSG_ERROR([
1071 Cannot enable threads on your platform.
1072 Your platform is known to not support thread-safe programs.
1073 For details, compile and run src/bin/pg_thread_test.
1074 ])
1075 fi
1076
1077 # Check for *_r functions
1078 _CFLAGS="$CFLAGS"
1079 _LIBS="$LIBS"
1080 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1081 LIBS="$LIBS $PTHREAD_LIBS"
1082
1083 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1084
1085 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1086
1087 # Do test here with the proper thread flags
1088 PGAC_FUNC_GETPWUID_R_5ARG
1089 PGAC_FUNC_STRERROR_R_INT
1090
1091 CFLAGS="$_CFLAGS"
1092 LIBS="$_LIBS"
1093
1094 else
1095 # do not use values from template file
1096 PTHREAD_CFLAGS=
1097 PTHREAD_LIBS=
1098 fi
1099
1100 AC_SUBST(PTHREAD_CFLAGS)
1101 AC_SUBST(PTHREAD_LIBS)
1102
1103
1104 # This test makes sure that run tests work at all.  Sometimes a shared
1105 # library is found by the linker, but the runtime linker can't find it.
1106 # This check should come after all modifications of compiler or linker
1107 # variables, and before any other run tests.
1108 AC_MSG_CHECKING([test program])
1109 AC_TRY_RUN([int main() { return 0; }],
1110 [AC_MSG_RESULT(ok)],
1111 [AC_MSG_RESULT(failed)
1112 AC_MSG_ERROR([[
1113 *** Could not execute a simple test program.  This may be a problem
1114 *** related to locating shared libraries.  Check the file 'config.log'
1115 *** for the exact reason.]])],
1116 [AC_MSG_RESULT([cross-compiling])])
1117
1118 # --------------------
1119 # Run tests below here
1120 # --------------------
1121
1122 # Force use of our snprintf if system's doesn't do arg control
1123 # See comment above at snprintf test for details.
1124 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1125   PGAC_FUNC_PRINTF_ARG_CONTROL
1126   if test $pgac_cv_printf_arg_control != yes ; then
1127     pgac_need_repl_snprintf=yes
1128   fi
1129 fi
1130
1131
1132 dnl Check to see if we have a working 64-bit integer type.
1133 dnl This breaks down into two steps:
1134 dnl (1) figure out if the compiler has a 64-bit int type with working
1135 dnl arithmetic, and if so
1136 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1137 dnl snprintf is the only library routine we really need for int8 support.)
1138 dnl It's entirely possible to have a compiler that handles a 64-bit type
1139 dnl when the C library doesn't; this is fairly likely when using gcc on
1140 dnl an older platform, for example.
1141 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1142 dnl we force our own version of snprintf() to be used instead.
1143 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1144
1145 PGAC_TYPE_64BIT_INT([long int])
1146
1147 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1148   PGAC_TYPE_64BIT_INT([long long int])
1149 fi
1150
1151
1152 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1153
1154 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1155   AC_TRY_COMPILE([
1156 #define INT64CONST(x)  x##LL
1157 long long int foo = INT64CONST(0x1234567890123456);
1158 ],
1159         [],
1160         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1161         [])
1162 fi
1163
1164
1165 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1166 # we found we need to use "long long int", better check.  We cope with
1167 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1168 # work, fall back to our own snprintf emulation (which we know uses %lld).
1169
1170 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1171   if test $pgac_need_repl_snprintf = no; then
1172     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1173     if test "$LONG_LONG_INT_FORMAT" = ""; then
1174       # Force usage of our own snprintf, since system snprintf is broken
1175       pgac_need_repl_snprintf=yes
1176       LONG_LONG_INT_FORMAT='%lld'
1177     fi
1178   else
1179     # Here if we previously decided we needed to use our own snprintf
1180     LONG_LONG_INT_FORMAT='%lld'
1181   fi
1182   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1183   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1184   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1185 else
1186   # Here if we are not using 'long long int' at all
1187   INT64_FORMAT='"%ld"'
1188   UINT64_FORMAT='"%lu"'
1189 fi
1190
1191 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1192                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1193
1194 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1195                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1196
1197 # Now we have checked all the reasons to replace snprintf
1198 if test $pgac_need_repl_snprintf = yes; then
1199   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1200   AC_LIBOBJ(snprintf)
1201 fi
1202
1203 # Need a #define for the size of Datum (unsigned long)
1204 AC_CHECK_SIZEOF([unsigned long])
1205
1206 # And one for the size of size_t (enables tweaks for > 32bit address space)
1207 AC_CHECK_SIZEOF([size_t])
1208
1209 # Determine memory alignment requirements for the basic C data types.
1210
1211 PGAC_CHECK_ALIGNOF(short)
1212 PGAC_CHECK_ALIGNOF(int)
1213 PGAC_CHECK_ALIGNOF(long)
1214 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1215   PGAC_CHECK_ALIGNOF(long long int)
1216 fi
1217 PGAC_CHECK_ALIGNOF(double)
1218
1219 # Compute maximum alignment of any basic type.
1220 # We assume long's alignment is at least as strong as char, short, or int;
1221 # but we must check long long (if it exists) and double.
1222
1223 MAX_ALIGNOF=$pgac_cv_alignof_long
1224 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1225   MAX_ALIGNOF=$pgac_cv_alignof_double
1226 fi
1227 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1228   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1229 fi
1230 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1231
1232
1233 # Some platforms predefine the types int8, int16, etc.  Only check
1234 # a (hopefully) representative subset.
1235 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1236 [#include <stdio.h>
1237 #ifdef HAVE_SUPPORTDEFS_H
1238 #include <SupportDefs.h>
1239 #endif])
1240
1241 # We also check for sig_atomic_t, which *should* be defined per ANSI
1242 # C, but is missing on some old platforms.
1243 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1244
1245
1246 if test x"$template" != x"win32"
1247 then
1248 PGAC_FUNC_POSIX_SIGNALS
1249 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1250   AC_MSG_ERROR([
1251 *** Thread-safety requires POSIX signals, which are not supported by your
1252 *** operating system.
1253 ])
1254 fi
1255 fi
1256
1257 if test $ac_cv_func_fseeko = yes; then
1258 AC_SYS_LARGEFILE
1259 fi
1260
1261 # SunOS doesn't handle negative byte comparisons properly with +/- return
1262 AC_FUNC_MEMCMP
1263
1264
1265 # Select semaphore implementation type.
1266 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1267   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1268   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1269 else
1270   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1271     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1272     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1273   else
1274     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1275     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1276   fi
1277 fi
1278
1279
1280 # Select shared-memory implementation type.
1281 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1282 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1283
1284
1285 # If not set in template file, set bytes to use libc memset()
1286 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1287   MEMSET_LOOP_LIMIT=1024
1288 fi
1289 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1290
1291
1292 if test "$enable_nls" = yes ; then
1293   PGAC_CHECK_GETTEXT
1294 fi
1295
1296 # Check for Tcl configuration script tclConfig.sh
1297 if test "$with_tcl" = yes; then
1298     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1299     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1300                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1301     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1302     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1303     ac_save_CPPFLAGS=$CPPFLAGS
1304     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1305     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1306     CPPFLAGS=$ac_save_CPPFLAGS
1307 fi
1308
1309 #
1310 # Check for DocBook and tools
1311 #
1312 PGAC_PROG_NSGMLS
1313 PGAC_PROG_JADE
1314 PGAC_CHECK_DOCBOOK(4.2)
1315 PGAC_PATH_DOCBOOK_STYLESHEETS
1316 PGAC_PATH_COLLATEINDEX
1317 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1318
1319 # Thread testing
1320
1321 # We have to run the thread test near the end so we have all our symbols
1322 # defined.  Cross compiling throws a warning.
1323 #
1324 if test "$enable_thread_safety_force" = yes; then
1325 if test x"$template" != x"win32"
1326 then
1327   AC_MSG_WARN([
1328 *** Skipping thread test program.  --enable-thread-safety-force was used.
1329 *** Run the program in src/test/thread on the your machine and add
1330 proper locking function calls to your applications to guarantee thread
1331 safety.
1332 ])
1333 else
1334 AC_MSG_WARN([*** Skipping thread test on Win32])
1335 fi
1336 elif test "$enable_thread_safety" = yes; then
1337 if test x"$template" != x"win32"
1338 then
1339 AC_MSG_CHECKING([thread safety of required library functions])
1340
1341 _CFLAGS="$CFLAGS"
1342 _LIBS="$LIBS"
1343 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1344 LIBS="$LIBS $PTHREAD_LIBS"
1345 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1346   [AC_MSG_RESULT(yes)],
1347   [AC_MSG_RESULT(no)
1348   AC_MSG_ERROR([
1349 *** Thread test program failed.  Your platform is not thread-safe.
1350 *** Check the file 'config.log'for the exact reason.
1351 ***
1352 *** You can use the configure option --enable-thread-safety-force
1353 *** to force threads to be enabled.  However, you must then run
1354 *** the program in src/test/thread and add locking function calls
1355 *** to your applications to guarantee thread safety.
1356 ])],
1357   [AC_MSG_RESULT(maybe)
1358   AC_MSG_WARN([
1359 *** Skipping thread test program because of cross-compile build.
1360 *** Run the program in src/test/thread on the target machine.
1361 ])])
1362 CFLAGS="$_CFLAGS"
1363 LIBS="$_LIBS"
1364 else
1365 AC_MSG_WARN([*** Skipping thread test on Win32])
1366 fi
1367 fi
1368
1369 # prepare build tree if outside source tree
1370 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1371 # Note 2: /bin/pwd might be better than shell's built-in at getting
1372 #         a symlink-free name.
1373 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1374   vpath_build=no
1375 else
1376   vpath_build=yes
1377   if test "$no_create" != yes; then
1378     _AS_ECHO_N([preparing build tree... ])
1379     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1380     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1381       || AC_MSG_ERROR(failed)
1382     AC_MSG_RESULT(done)
1383   fi
1384 fi
1385 AC_SUBST(vpath_build)
1386
1387
1388 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1389
1390 AC_CONFIG_LINKS([
1391   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1392   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1393   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1394   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1395   src/include/pg_config_os.h:src/include/port/${template}.h
1396   src/Makefile.port:src/makefiles/Makefile.${template}
1397 ])
1398
1399 if test "$PORTNAME" = "win32"; then
1400 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1401 # Links sometimes fail undetected on Mingw -
1402 # so here we detect it and warn the user
1403 for FILE in $CONFIG_LINKS
1404  do
1405         # test -e works for symlinks in the MinGW console
1406         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1407  done
1408 ])
1409 fi
1410
1411 AC_CONFIG_HEADERS([src/include/pg_config.h],
1412 [
1413 # Update timestamp for pg_config.h (see Makefile.global)
1414 echo >src/include/stamp-h
1415 ])
1416
1417 AC_OUTPUT
1418