granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/find_apr.m4)
  18 sinclude(srclib/apr-util/build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APACHE_ENABLE_LAYOUT
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1)
  65
  66 if test "$apr_found" = "no"; then
  67   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  68 fi
  69
  70 if test "$apr_found" = "reconfig"; then
  71   APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  72   dnl We must be the first to build and the last to be cleaned
  73   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  74   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  75 fi
  76
  77 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  78 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  79 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  80 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  81 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  82 APR_BINDIR=`$apr_config --bindir`
  83 APR_INCLUDEDIR=`$apr_config --includes | sed 's|^.*-I\([[^ ]]*apr[[^ ]]*\).*$|\1|'`
  84
  85 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  86
  87 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1)
  88
  89 if test "$apu_found" = "no"; then
  90   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  91 fi
  92
  93 if test "$apu_found" = "reconfig"; then
  94   APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
  95   dnl We must be the last to build and the first to be cleaned
  96   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
  97   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
  98 fi
  99
 100 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 101 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 102 APU_BINDIR=`$apu_config --bindir`
 103 APU_INCLUDEDIR=`$apu_config --includes | sed 's|^ *-I\([[^ ]]*apr[[^ ]]*\).*$|\1|'`
 104
 105 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 106
 107 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
 108
 109 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 110
 111 dnl Absolute source/build directory
 112 abs_srcdir=`(cd $srcdir && pwd)`
 113 abs_builddir=`pwd`
 114
 115 dnl If the source dir is not equal to the build dir,
 116 dnl then we are running in VPATH mode.
 117
 118 if test "$abs_builddir" != "$abs_srcdir"; then
 119   USE_VPATH=1
 120   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/modules/proxy -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/modules/filters -I\$(top_srcdir)/modules/filters -I\$(top_builddir)/include -I\$(top_srcdir)/include])
 121 else
 122   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include])
 123 fi
 124
 125 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 126
 127 case $host in
 128   *os2*)
 129       # Use a custom made libtool replacement
 130       echo "using aplibtool"
 131       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 132       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 133       SH_LIBS="\$(ALL_LIBS)"
 134       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 135       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 136       MK_IMPLIB="emximp"
 137       other_targets="$other_targets os2core"
 138       INSTALL_PROG_FLAGS="-e .exe"
 139       SHLTCFLAGS=""
 140       LTCFLAGS=""
 141       ;;
 142   *)
 143       if test "x$LTFLAGS" = "x"; then
 144           LTFLAGS='--silent'
 145       fi
 146       my_libtool=`$apr_config --apr-libtool`
 147       LIBTOOL="$my_libtool \$(LTFLAGS)"
 148       libtoolversion=`$my_libtool --version`
 149       case $libtoolversion in
 150           *1.4*)
 151               SH_LIBTOOL='$(LIBTOOL)'
 152               SHLTCFLAGS="-prefer-pic"
 153               LTCFLAGS="-prefer-non-pic -static"
 154               ;;
 155           *)
 156               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 157               SHLTCFLAGS=""
 158               LTCFLAGS=""
 159               ;;
 160       esac
 161       ;;
 162 esac
 163 APACHE_SUBST(SHLTCFLAGS)
 164 APACHE_SUBST(LTCFLAGS)
 165
 166 AP_SIG_GRACEFUL=USR1
 167
 168 case $host in
 169   *-apple-aux3*)
 170       APR_SETVAR(APACHE_MPM, [prefork])
 171       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 172       ;;
 173   *-beos*)
 174       APR_SETVAR(APACHE_MPM, [beos])
 175       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 176       ;;
 177   *os2_emx*)
 178       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 179       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 180       ;;
 181   *-linux-*)
 182       case `uname -r` in
 183         2.0* )
 184             AP_SIG_GRACEFUL=WINCH
 185             ;;
 186         2.[[2-9]]* )
 187             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 188             ;;
 189         * )
 190             ;;
 191       esac
 192       ;;
 193   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 194       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 195       ;;
 196   *-solaris2*)
 197       dnl This is a hack -- we should be using AC_TRY_RUN instead
 198       ap_platform_runtime_link_flag="-R"
 199       dnl solaris 8 and above don't have a thundering herd
 200       dnl not sure about rev's before this one.
 201       case `uname -r` in
 202         5.[567]*)
 203             ;;
 204         * )
 205             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 206             ;;
 207       esac
 208       ;;
 209   *cygwin*)
 210       APR_SETVAR(APACHE_MPM, [prefork])
 211       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 212       ;;
 213   *aix*)
 214       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 215       if test $aixver -ge 4320; then
 216         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 217       fi
 218       ;;
 219   *os390*)
 220       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 221       ;;
 222 esac
 223
 224 dnl
 225 dnl Process command line arguments. This is done early in the process so the
 226 dnl user can get feedback quickly in case of an error.
 227 dnl
 228 dnl ### need to move some of the arguments "up here"
 229
 230 dnl ## Check for programs
 231
 232 AC_PATH_PROG(RM, rm)
 233 AC_PROG_AWK
 234 AC_PROG_CC
 235 AC_PROG_CPP
 236 AC_PROG_INSTALL
 237 AC_PROG_LN_S
 238 AC_CHECK_TOOL(RANLIB, ranlib, true)
 239 dnl AC_PATH_PROG(PERL_PATH, perl)
 240
 241 dnl various OS checks that apparently set required flags
 242 AC_AIX
 243 AC_ISC_POSIX
 244 AC_MINIX
 245
 246 dnl ## Check for libraries
 247
 248 dnl ## Check for header files
 249
 250 dnl I think these are just used all over the place, so just check for
 251 dnl them at the base of the tree. If some are specific to a single
 252 dnl directory, they should be moved (Comment #Spoon)
 253
 254 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 255 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 256 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 257
 258 AC_HEADER_STDC
 259 AC_CHECK_HEADERS( \
 260 string.h \
 261 limits.h \
 262 unistd.h \
 263 sys/socket.h \
 264 pwd.h \
 265 grp.h \
 266 strings.h \
 267 sys/processor.h \
 268 sys/sem.h
 269 )
 270 AC_HEADER_SYS_WAIT
 271
 272 dnl ## Check for typedefs, structures, and compiler characteristics.
 273
 274 AC_C_CONST
 275 if test "$ac_cv_prog_gcc" = "yes"; then
 276   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 277 fi
 278
 279 dnl ## Check for library functions
 280
 281 dnl See Comment #Spoon
 282
 283 AC_CHECK_FUNCS( \
 284 getpwnam \
 285 getgrnam \
 286 initgroups \
 287 bindprocessor \
 288 timegm \
 289 )
 290
 291 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 292 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 293 [AC_TRY_COMPILE([#include <sys/types.h>
 294 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 295   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 296 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 297     AC_DEFINE(HAVE_GMTOFF)
 298 fi
 299
 300 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 301
 302 case $host in
 303     *aix*)
 304         # for 32-bit builds, increase MAXDATA to allow lots of threads
 305         if test x$OBJECT_MODE != x64; then
 306             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 307         fi
 308         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 309         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 310         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 311         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 312         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 313         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 314         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 315         ;;
 316     *os390*)
 317         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 318         ;;
 319     *)
 320         OS_SPECIFIC_VARS=""
 321 esac
 322
 323 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 324         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 325         [PORT=80])
 326
 327 dnl ## See if APR has IPv6 support
 328 ap_old_cppflags=$CPPFLAGS
 329 CPPFLAGS="$CPPFLAGS -I$APR_SOURCE_DIR/include -I$abs_builddir/srclib/apr/include"
 330 AC_TRY_COMPILE([#include <apr.h>], [
 331 #if !APR_HAVE_IPV6
 332 #error APR does not have IPv6 support
 333 #endif], apr_have_ipv6=yes, apr_have_ipv6=no)
 334 CPPFLAGS=$ap_old_cppflags
 335
 336 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 337 [
 338   v4mapped=$enableval
 339 ],
 340 [
 341     case $host in
 342     *freebsd5*|*netbsd*|*openbsd*)
 343         v4mapped=no
 344         ;;
 345     *)
 346         v4mapped=yes
 347         ;;
 348 esac
 349 ])
 350
 351 if test $v4mapped = "yes" -o $apr_have_ipv6 = "no"; then
 352     nonssl_listen_stmt_1=""
 353     nonssl_listen_stmt_2="Listen @@Port@@"
 354     if test $apr_have_ipv6 = "yes"; then
 355         AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 356                   [Allow IPv4 connections on IPv6 listening sockets])
 357     fi
 358 else
 359     nonssl_listen_stmt_1="Listen 0.0.0.0:@@Port@@"
 360     nonssl_listen_stmt_2="Listen [[::]]:@@Port@@"
 361 fi
 362
 363 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 364 [
 365   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 366 ])dnl
 367
 368 prefix="$orig_prefix"
 369 APACHE_ENABLE_MODULES
 370
 371 dnl reading config stubs
 372 esyscmd(./build/config-stubs .)
 373
 374 APACHE_SUBST(progname)
 375 APACHE_SUBST(MPM_LIB)
 376 APACHE_SUBST(OS)
 377 APACHE_SUBST(OS_DIR)
 378 APACHE_SUBST(BUILTIN_LIBS)
 379 APACHE_SUBST(SHLIBPATH_VAR)
 380 APACHE_SUBST(OS_SPECIFIC_VARS)
 381
 382 PRE_SHARED_CMDS='echo ""'
 383 POST_SHARED_CMDS='echo ""'
 384
 385 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 386
 387 if test "$apache_need_shared" = "yes"; then
 388   if test -f $ac_aux_dir/ltconfig; then
 389     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 390   fi
 391   shared_build="shared-build"
 392 fi
 393
 394 dnl enable_so tells us if *any* modules can be built as DSOs
 395
 396 if test "$enable_so" = "yes"; then
 397   case $host in
 398     *-ibm-aix*)
 399       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 400       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 401       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 402       ;;
 403     *beos)
 404       SH_LDFLAGS='$(top_builddir)/_APP_'
 405       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 406       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 407       ;;
 408     *os390)
 409       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 410       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 411   esac
 412 fi
 413
 414 APACHE_SUBST(PRE_SHARED_CMDS)
 415 APACHE_SUBST(POST_SHARED_CMDS)
 416 APACHE_SUBST(shared_build)
 417
 418 AC_ARG_WITH(program-name,
 419 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 420   progname="$withval" ], [
 421   progname="httpd"] )
 422
 423 # SuExec parameters
 424 AC_ARG_WITH(suexec-bin,
 425 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 426   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 427 ] )
 428
 429 AC_ARG_WITH(suexec-caller,
 430 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 431   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 432
 433 AC_ARG_WITH(suexec-userdir,
 434 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 435   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 436
 437 AC_ARG_WITH(suexec-docroot,
 438 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 439   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 440
 441 AC_ARG_WITH(suexec-uidmin,
 442 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 443   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 444
 445 AC_ARG_WITH(suexec-gidmin,
 446 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 447   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 448
 449 AC_ARG_WITH(suexec-logfile,
 450 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 451   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 452
 453 AC_ARG_WITH(suexec-safepath,
 454 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 455   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 456
 457 AC_ARG_WITH(suexec-umask,
 458 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 459   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 460
 461 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 462 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 463
 464 dnl APR should go after the other libs, so the right symbols can be picked up
 465 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 466 APACHE_SUBST(AP_LIBS)
 467 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 468 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 469
 470 AC_DEFINE(AP_USING_AUTOCONF, 1,
 471                 [Using autoconf to configure Apache])
 472
 473 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 474     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 475               [This platform doesn't suffer from the thundering herd problem])
 476 fi
 477
 478 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 479 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 480 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 481 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 482 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 483 AC_SUBST(AP_SIG_GRACEFUL)
 484 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 485 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 486
 487 dnl check for endianness
 488 if test "$cross_compiling" = "no"; then
 489   AC_C_BIGENDIAN
 490 else
 491   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 492                 [byte order is unknown due to cross-compilation])
 493 fi
 494
 495 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 496 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 497 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 498 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 499
 500 if test -d ./test; then
 501     APACHE_FAST_OUTPUT(test/Makefile)
 502 fi
 503
 504 dnl ## Finalize the variables
 505 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 506
 507 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 508 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 509 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 510 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 511 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 512 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 513
 514 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 515
 516 APACHE_GEN_CONFIG_VARS
 517
 518 dnl ## Build modules.c
 519 rm -f modules.c
 520 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 521
 522 APR_EXPAND_VAR(ap_prefix, $prefix)
 523 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 524         [Root directory of the Apache install area])
 525 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 526         [Location of the config file, relative to the Apache root directory])
 527 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 528         [Location of the MIME types config file, relative to the Apache root directory])
 529 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 530         [Location of the source for the current MPM])
 531
 532 perlbin=`$ac_aux_dir/PrintPath perl`
 533 if test "x$perlbin" = "x"; then
 534     perlbin="/replace/with/path/to/perl/interpreter"
 535 fi
 536 AC_SUBST(perlbin)
 537
 538 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 539
 540 BSD_MAKEFILE=no
 541 ap_make_include=include
 542 ap_make_delimiter=' '
 543 case $host in
 544 *bsdi*)
 545     # Check whether they've installed GNU make
 546     if make --version > /dev/null 2>&1; then
 547         true
 548     else
 549         BSD_MAKEFILE=yes
 550         ap_make_include=.include
 551         ap_make_delimiter='"'
 552     fi
 553     ;;
 554 esac
 555 AC_SUBST(ap_make_include)
 556 AC_SUBST(ap_make_delimiter)
 557
 558 dnl Ensure that docs/conf is created.
 559 test -d docs/conf||$mkdir_p docs/conf
 560
 561 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 562   APACHE_GEN_MAKEFILES
 563 ])
 564