granicus.if.org Git - linux-pam/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(conf/pam_conv1/pam_conv_y.y)
   3 AM_INIT_AUTOMAKE("Linux-PAM", 0.99.10.0)
   4 AC_PREREQ([2.60])
   5 AM_CONFIG_HEADER(config.h)
   6 AC_CANONICAL_HOST
   7
   8 AC_SUBST(PACKAGE)
   9 AC_SUBST(VERSION)
  10
  11 dnl
  12 dnl By default, everything under PAM is installed below /usr.
  13 dnl
  14 AC_PREFIX_DEFAULT(/usr)
  15
  16 dnl and some hacks to use /etc and /lib
  17 test "${prefix}" = "NONE" && prefix="/usr"
  18 if test ${prefix} = '/usr'
  19 then
  20 dnl If we use /usr as prefix, use /etc for config files
  21         if test ${sysconfdir} = '${prefix}/etc'
  22         then
  23                 sysconfdir="/etc"
  24         fi
  25         if test ${libdir} = '${exec_prefix}/lib'
  26         then
  27                 case "`uname -m`" in
  28                     x86_64|ppc64|s390x|sparc64)
  29                         libdir="/lib64" ;;
  30                     *)
  31                         libdir="/lib" ;;
  32                 esac
  33         fi
  34         if test ${sbindir} = '${exec_prefix}/sbin'
  35         then
  36                 sbindir="/sbin"
  37         fi
  38 dnl If we use /usr as prefix, use /usr/share/man for manual pages
  39         if test ${mandir} = '${prefix}/man'
  40         then
  41                 mandir='${prefix}/share/man'
  42         fi
  43 dnl Add security to include directory
  44         if test ${includedir} = '${prefix}/include'
  45         then
  46                 includedir="${prefix}/include/security"
  47         fi
  48
  49 dnl Add /var directory
  50         if test ${localstatedir} = '${prefix}/var'
  51         then
  52                 localstatedir="/var"
  53         fi
  54
  55 fi
  56
  57 dnl
  58 dnl check if we should link everything static into libpam
  59 dnl
  60 AC_ARG_ENABLE(static-modules,AS_HELP_STRING([--enable-static-modules],
  61         [do not make the modules dynamically loadable]),
  62         STATIC_MODULES=$enableval,STATIC_MODULES=no)
  63 if test "$STATIC_MODULES" != "no" ; then
  64         CFLAGS="$CFLAGS -DPAM_STATIC"
  65         AC_ENABLE_STATIC([yes])
  66         AC_ENABLE_SHARED([no])
  67 else
  68 # per default don't build static libraries
  69         AC_ENABLE_STATIC([no])
  70         AC_ENABLE_SHARED([yes])
  71 fi
  72 AM_CONDITIONAL([STATIC_MODULES], [test "$STATIC_MODULES" != "no"])
  73
  74 dnl Checks for programs.
  75 AC_GNU_SOURCE
  76 AC_PROG_CC
  77 AC_PROG_YACC
  78 AM_PROG_LEX
  79 AC_PROG_INSTALL
  80 AC_PROG_LN_S
  81 AC_PROG_MAKE_SET
  82 AC_PROG_LIBTOOL
  83 AM_PROG_CC_C_O
  84 PAM_LD_AS_NEEDED
  85 PAM_LD_O1
  86
  87 dnl Largefile support
  88 AC_SYS_LARGEFILE
  89
  90 dnl icc claims to be GCC compatible, but use other flags for warnings
  91 if eval "test x$GCC = xyes -a $CC != icc"; then
  92   for flag in \
  93       -W \
  94       -Wall \
  95       -Wbad-function-cast \
  96       -Wcast-align \
  97       -Wcast-qual \
  98       -Wmissing-declarations \
  99       -Wmissing-prototypes \
 100       -Wpointer-arith \
 101       -Wreturn-type \
 102       -Wstrict-prototypes \
 103       -Wwrite-strings \
 104       -Winline \
 105       -Wshadow
 106   do
 107     JAPHAR_GREP_CFLAGS($flag, [ CFLAGS="$CFLAGS $flag" ])
 108   done
 109 fi
 110 dnl icc has special warning flags
 111 if eval "test x$CC = xicc"; then
 112   for flag in \
 113       -Wall \
 114       -Wmissing-prototypes \
 115       -Wpointer-arith \
 116       -Wreturn-type \
 117       -Wstrict-prototypes \
 118       -Wwrite-strings \
 119       -Wshadow \
 120       -Wp64 \
 121       -Wdeprecated \
 122       -Wuninitialized \
 123       -Wmain
 124   do
 125     JAPHAR_GREP_CFLAGS($flag, [ CFLAGS="$CFLAGS $flag" ])
 126   done
 127 fi
 128
 129 AC_C___ATTRIBUTE__
 130
 131 dnl
 132 dnl Check if --version-script is supported by ld
 133 dnl
 134 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 135 [cat > conftest.s <<EOF
 136 ${libc_cv_dot_text}
 137 _sym:
 138 .symver _sym,sym@VERS
 139 EOF
 140 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 141   libc_cv_asm_symver_directive=yes
 142 else
 143   libc_cv_asm_symver_directive=no
 144 fi
 145 rm -f conftest*])
 146 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 147 if test $libc_cv_asm_symver_directive = yes; then
 148   cat > conftest.s <<EOF
 149 ${libc_cv_dot_text}
 150 _sym:
 151 .symver _sym,sym@VERS
 152 EOF
 153   cat > conftest.map <<EOF
 154 VERS_1 {
 155         global: sym;
 156 };
 157
 158 VERS_2 {
 159         global: sym;
 160 } VERS_1;
 161 EOF
 162   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 163 then
 164     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
 165                                 -o conftest.so conftest.o
 166                                 -nostartfiles -nostdlib
 167                                 -Wl,--version-script,conftest.map
 168                        1>&AS_MESSAGE_LOG_FD]);
 169     then
 170       libc_cv_ld_version_script_option=yes
 171     else
 172       libc_cv_ld_version_script_option=no
 173     fi
 174   else
 175     libc_cv_ld_version_script_option=no
 176   fi
 177 else
 178   libc_cv_ld_version_script_option=no
 179 fi
 180 rm -f conftest*])
 181 AM_CONDITIONAL([HAVE_VERSIONING],
 182         [test "$libc_cv_ld_version_script_option" = "yes"])
 183
 184 dnl
 185 dnl check for -fPIE/-pie support
 186 dnl
 187 dnl icc handles -fpie as -fp without error, so blacklist icc
 188 dnl
 189 AC_ARG_ENABLE(pie,AS_HELP_STRING([--disable-pie],
 190                         [disable position-independent executeables (PIE)]),
 191         USE_PIE=$enableval, USE_PIE=yes)
 192
 193 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
 194   cat > conftest.c <<EOF
 195 int foo;
 196 main () { return 0;}
 197 EOF
 198   if test "$USE_PIE" = "yes" -a "$CC" != "icc" &&
 199         AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
 200                               -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
 201   then
 202     libc_cv_fpie=yes
 203     PIE_CFLAGS="-fpie"
 204     PIE_LDFLAGS="-pie"
 205   else
 206     libc_cv_fpie=no
 207     PIE_CFLAGS=""
 208     PIE_LDFLAGS=""
 209   fi
 210   rm -f conftest*])
 211 AC_SUBST(libc_cv_fpie)
 212 AC_SUBST(PIE_CFLAGS)
 213 AC_SUBST(PIE_LDFLAGS)
 214
 215
 216 dnl
 217 dnl options and defaults
 218 dnl
 219
 220 AC_ARG_ENABLE([prelude],
 221         AC_HELP_STRING([--disable-prelude],[do not use prelude]),
 222         WITH_PRELUDE=$enableval, WITH_PRELUDE=yes)
 223 if test "$WITH_PRELUDE" == "yes" ; then
 224   AM_PATH_LIBPRELUDE([0.9.0])
 225   if test "$LIBPRELUDE_CONFIG" != "no" ; then
 226     LIBPRELUDE_CFLAGS="$LIBPRELUDE_CFLAGS -DPRELUDE=1"
 227   fi
 228 fi
 229
 230 dnl lots of debugging information goes to /var/run/pam-debug.log
 231 AC_ARG_ENABLE([debug],
 232     AC_HELP_STRING([--enable-debug],
 233         [specify you are building with debugging on]),
 234         WITH_DEBUG=yes ; AC_DEFINE([DEBUG],,
 235                 [lots of stuff gets written to /var/run/pam-debug.log]),
 236                 WITH_DEBUG=no)
 237 AC_SUBST(WITH_DEBUG)
 238
 239 AC_ARG_ENABLE(securedir,
 240         AC_HELP_STRING([--enable-securedir=DIR],[path to location of PAMs @<:@default=$libdir/security@:>@]),
 241         SECUREDIR=$enableval, SECUREDIR=$libdir/security)
 242 AC_SUBST(SECUREDIR)
 243
 244 AC_ARG_ENABLE([isadir],
 245         AC_HELP_STRING([--enable-isadir=DIR],[path to arch-specific module files @<:@default=../../(basename of $libdir)/security@:>@]),
 246 ISA=$enableval,
 247 ISA=../../`basename $libdir`/security)
 248 unset mylibdirbase
 249 AC_DEFINE_UNQUOTED(_PAM_ISA,"$ISA",[Define to the path, relative to SECUREDIR, where PAMs specific to this architecture can be found.])
 250 AC_MSG_RESULT([Defining \$ISA to "$ISA"])
 251
 252 AC_ARG_ENABLE(sconfigdir,
 253         AC_HELP_STRING([--enable-sconfigdir=DIR],[path to module conf files @<:@default=$sysconfdir/security@:>@]),
 254         SCONFIGDIR=$enableval, SCONFIGDIR=$sysconfdir/security)
 255 AC_SUBST(SCONFIGDIR)
 256
 257 AC_ARG_ENABLE(pamlocking,
 258         AC_HELP_STRING([--enable-pamlocking],[configure libpam to observe a global authentication lock]),
 259         WITH_PAMLOCKING=yes ; AC_DEFINE([PAM_LOCKING],,
 260                 [libpam should observe a global authentication lock]),
 261                 WITH_PAMLOCKING=no)
 262 AC_SUBST(WITH_PAMLOCKING)
 263
 264 AC_ARG_ENABLE(read-both-confs,
 265         AC_HELP_STRING([--enable-read-both-confs],[read both /etc/pam.d and /etc/pam.conf files]),
 266         AC_DEFINE([PAM_READ_BOTH_CONFS],,
 267                 [read both /etc/pam.d and /etc/pam.conf files]))
 268 AC_SUBST(PAM_READ_BOTH_CONFS)
 269
 270 AC_ARG_ENABLE([lckpwdf],
 271         AC_HELP_STRING([--disable-lckpwdf],[do not use the lckpwdf function]),
 272         WITH_LCKPWDF=$enableval, WITH_LCKPWDF=yes)
 273 if test "$WITH_LCKPWDF" == "yes" ; then
 274     AC_DEFINE([USE_LCKPWDF], 1,
 275                 [Define to 1 if the lckpwdf function should be used])
 276 fi
 277
 278 AC_CHECK_HEADERS(paths.h)
 279 AC_ARG_WITH(mailspool,
 280 [  --with-mailspool        path to mail spool directory
 281                           [default _PATH_MAILDIR if defined in paths.h, otherwise /var/spool/mail]],
 282 with_mailspool=${withval})
 283 if test x$with_mailspool != x ; then
 284         pam_mail_spool="\"$with_mailspool\""
 285 else
 286         AC_TRY_RUN([
 287 #include <paths.h>
 288 int main() {
 289 #ifdef _PATH_MAILDIR
 290 exit(0);
 291 #else
 292 exit(1);
 293 #endif
 294 }], pam_mail_spool="_PATH_MAILDIR",
 295 pam_mail_spool="\"/var/spool/mail\"",
 296 pam_mail_spool="\"/var/spool/mail\"")
 297 fi
 298 AC_DEFINE_UNQUOTED(PAM_PATH_MAILDIR, $pam_mail_spool,
 299         [Path where mails are stored])
 300
 301 AC_ARG_WITH(xauth,
 302 [  --with-xauth            additional path to check for xauth when it is called from pam_xauth
 303                           [added to the default of /usr/X11R6/bin/xauth, /usr/bin/xauth, /usr/bin/X11/xauth]],
 304 pam_xauth_path=${withval})
 305 if test x$with_xauth == x ; then
 306         AC_PATH_PROG(pam_xauth_path, xauth)
 307 dnl There is no sense in adding the first default path
 308         if test x$pam_xauth_path == x/usr/X11R6/bin/xauth ; then
 309                 unset pam_xauth_path
 310         fi
 311 fi
 312
 313 if test x$pam_xauth_path != x ; then
 314         AC_DEFINE_UNQUOTED(PAM_PATH_XAUTH, "$pam_xauth_path",
 315         [Additional path of xauth executable])
 316 fi
 317
 318 dnl Checks for the existence of libdl - on BSD and Tru64 its part of libc
 319 AC_CHECK_LIB([dl], [dlopen], LIBDL="-ldl", LIBDL="")
 320 AC_SUBST(LIBDL)
 321
 322 # Check for cracklib
 323 AC_ARG_ENABLE([cracklib],
 324         AC_HELP_STRING([--disable-cracklib],[do not use cracklib]),
 325         WITH_CRACKLIB=$enableval, WITH_CRACKLIB=yes)
 326 if test x"$WITH_CRACKLIB" != xno ; then
 327         AC_CHECK_HEADERS([crack.h],
 328               AC_CHECK_LIB([crack], [FascistCheck], LIBCRACK="-lcrack", LIBCRACK=""))
 329 else
 330         LIBCRACK=""
 331 fi
 332 AC_SUBST(LIBCRACK)
 333 AM_CONDITIONAL([HAVE_LIBCRACK], [test ! -z "$LIBCRACK"])
 334
 335 dnl Look for Linux Auditing library - see documentation
 336 AC_ARG_ENABLE([audit],
 337         AC_HELP_STRING([--disable-audit],[do not enable audit support]),
 338         WITH_LIBAUDIT=$enableval, WITH_LIBAUDIT=yes)
 339 if test x"$WITH_LIBAUDIT" != xno ; then
 340         AC_CHECK_HEADER([libaudit.h],
 341               [AC_CHECK_LIB(audit, audit_log_acct_message, LIBAUDIT=-laudit, LIBAUDIT="")
 342                AC_CHECK_TYPE([struct audit_tty_status],
 343                              [HAVE_AUDIT_TTY_STATUS=yes],
 344                              [HAVE_AUDIT_TTY_STATUS=""],
 345                              [#include <libaudit.h>])]
 346         )
 347         if test ! -z "$LIBAUDIT" -a "ac_cv_header_libaudit_h" != "no" ; then
 348             AC_DEFINE([HAVE_LIBAUDIT], 1, [Define to 1 if audit support should be compiled in.])
 349         fi
 350         if test ! -z "$HAVE_AUDIT_TTY_STATUS" ; then
 351             AC_DEFINE([HAVE_AUDIT_TTY_STATUS], 1, [Define to 1 if struct audit_tty_status exists.])
 352         fi
 353 else
 354         LIBAUDIT=""
 355 fi
 356 AC_SUBST(LIBAUDIT)
 357 AM_CONDITIONAL([HAVE_AUDIT_TTY_STATUS],
 358                [test "x$HAVE_AUDIT_TTY_STATUS" = xyes])
 359
 360 BACKUP_LIBS=$LIBS
 361 AC_SEARCH_LIBS([crypt],[xcrypt crypt], LIBCRYPT="-l$ac_lib", LIBCRYPT="")
 362 AC_CHECK_FUNCS(crypt_r)
 363 LIBS=$BACKUP_LIBS
 364 AC_SUBST(LIBCRYPT)
 365
 366 AC_ARG_WITH([randomdev], AC_HELP_STRING([--with-randomdev=(<path>|yes|no)], [use specified random device instead of /dev/urandom or 'no' to disable]), opt_randomdev=$withval)
 367 if test "$opt_randomdev" = yes -o -z "$opt_randomdev"; then
 368        opt_randomdev="/dev/urandom"
 369 elif test "$opt_randomdev" = no; then
 370        opt_randomdev=
 371 fi
 372 if test -n "$opt_randomdev"; then
 373        AC_DEFINE_UNQUOTED(PAM_PATH_RANDOMDEV, "$opt_randomdev", [Random device path.])
 374 fi
 375
 376 dnl check for libdb or libndbm as fallback. Some libndbm compat
 377 dnl libraries are unuseable, so try libdb first.
 378 AC_ARG_ENABLE([db],
 379         AC_HELP_STRING([--enable-db=(db|ndbm|yes|no)],[Default behavior 'yes', which is to check for libdb first, followed by ndbm. Use 'no' to disable db support.]),
 380         WITH_DB=$enableval, WITH_DB=yes)
 381 AC_ARG_WITH([db-uniquename],
 382         AC_HELP_STRING([--with-db-uniquename=extension],[Unique name for db libraries and functions.]))
 383 if test x"$WITH_DB" != xno ; then
 384         if test x"$WITH_DB" = xyes -o x"$WITH_DB" = xdb ; then
 385               AC_CHECK_LIB([db$with_db_uniquename], [db_create$with_db_uniquename], LIBDB="-ldb$with_db_uniquename", LIBDB="")
 386               if test -z "$LIBDB" ; then
 387                   AC_CHECK_LIB([db$with_db_uniquename], [dbm_store$with_db_uniquename], LIBDB="-ldb$with_db_uniquename", LIBDB="")
 388               fi
 389         fi
 390         if test -z "$LIBDB" ; then
 391             AC_CHECK_LIB([ndbm],[dbm_store], LIBDB="-lndbm", LIBDB="")
 392             if test ! -z "$LIBDB" ; then
 393                 AC_CHECK_HEADERS(ndbm.h)
 394             fi
 395         else
 396             AC_CHECK_HEADERS(db.h)
 397         fi
 398 fi
 399 AC_SUBST(LIBDB)
 400 AM_CONDITIONAL([HAVE_LIBDB], [test ! -z "$LIBDB"])
 401
 402 AC_CHECK_LIB([nsl],[yp_get_default_domain], LIBNSL="-lnsl", LIBNSL="")
 403 BACKUP_LIBS=$LIBS
 404 LIBS="$LIBS $LIBNSL"
 405 AC_CHECK_FUNCS(yp_get_default_domain)
 406 LIBS=$BACKUP_LIBS
 407 AC_SUBST(LIBNSL)
 408
 409 AC_ARG_ENABLE([selinux],
 410         AC_HELP_STRING([--disable-selinux],[do not use SELinux]),
 411         WITH_SELINUX=$enableval, WITH_SELINUX=yes)
 412 if test "$WITH_SELINUX" == "yes" ; then
 413   AC_CHECK_LIB([selinux],[getfilecon], LIBSELINUX="-lselinux", LIBSELINUX="")
 414 else
 415   LIBSELINUX=""
 416 fi
 417 AC_SUBST(LIBSELINUX)
 418 AM_CONDITIONAL([HAVE_LIBSELINUX], [test ! -z "$LIBSELINUX"])
 419 if test ! -z "$LIBSELINUX" ; then
 420     AC_DEFINE([WITH_SELINUX], 1, [Defined if SE Linux support is compiled in])
 421     BACKUP_LIBS=$LIBS
 422     LIBS="$LIBS $LIBSELINUX"
 423     AC_CHECK_FUNCS(setkeycreatecon)
 424     LIBS=$BACKUP_LIBS
 425 fi
 426
 427 dnl Checks for header files.
 428 AC_HEADER_DIRENT
 429 AC_HEADER_STDC
 430 AC_HEADER_SYS_WAIT
 431 AC_CHECK_HEADERS(fcntl.h limits.h malloc.h sys/file.h sys/ioctl.h sys/time.h syslog.h net/if.h termio.h unistd.h sys/fsuid.h inittypes.h)
 432
 433 AC_CHECK_HEADERS(crypt.h)
 434
 435 dnl For module/pam_lastlog
 436 AC_CHECK_HEADERS(lastlog.h utmp.h utmpx.h)
 437
 438 dnl Checks for typedefs, structures, and compiler characteristics.
 439 AC_C_BIGENDIAN
 440 AC_C_CONST
 441 AC_TYPE_UID_T
 442 AC_TYPE_OFF_T
 443 AC_TYPE_PID_T
 444 AC_TYPE_SIZE_T
 445 AC_HEADER_TIME
 446 AC_STRUCT_TM
 447
 448 dnl Checks for library functions.
 449 AC_TYPE_GETGROUPS
 450 AC_PROG_GCC_TRADITIONAL
 451 AC_FUNC_MEMCMP
 452 AC_FUNC_VPRINTF
 453 AC_CHECK_FUNCS(fseeko gethostname gettimeofday lckpwdf mkdir select)
 454 AC_CHECK_FUNCS(strcspn strdup strspn strstr strtol uname)
 455 AC_CHECK_FUNCS(getpwnam_r getpwuid_r getgrnam_r getgrgid_r getspnam_r)
 456 AC_CHECK_FUNCS(getgrouplist getline getdelim)
 457 AC_CHECK_FUNCS(inet_ntop inet_pton ruserok_af)
 458
 459 AC_CHECK_FUNCS(unshare, [UNSHARE=yes], [UNSHARE=no])
 460 AM_CONDITIONAL([HAVE_UNSHARE], [test "$UNSHARE" = yes])
 461
 462 dnl
 463 dnl Check for xsltproc
 464 dnl
 465 enable_man=yes
 466 AC_PATH_PROG([XSLTPROC], [xsltproc])
 467 if test -z "$XSLTPROC"; then
 468      enable_man=no
 469 fi
 470 AC_PATH_PROG([XMLLINT], [xmllint],[/bin/true])
 471 dnl check for DocBook DTD and stylesheets in the local catalog.
 472 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.4//EN],
 473                 [DocBook XML DTD V4.4], [], enable_man=no)
 474 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
 475                 [DocBook XSL Stylesheets], [], enable_man=no)
 476
 477 AC_PATH_PROG([BROWSER], [w3m])
 478 if test ! -z "$BROWSER"; then
 479      BROWSER="$BROWSER -T text/html -dump"
 480 else
 481      enable_man=no
 482 fi
 483
 484 AC_PATH_PROG([FO2PDF], [fop])
 485
 486 AM_CONDITIONAL(ENABLE_REGENERATE_MAN, test x$enable_man != xno)
 487 AM_CONDITIONAL(ENABLE_GENERATE_PDF, test ! -z "$FO2PDF")
 488
 489
 490 AM_GNU_GETTEXT_VERSION
 491 AM_GNU_GETTEXT([external])
 492 AC_CHECK_FUNCS(dngettext)
 493
 494 AH_VERBATIM([_ZZENABLE_NLS],
 495 [#ifdef ENABLE_NLS
 496 #include <libintl.h>
 497 #define _(msgid) dgettext(PACKAGE, msgid)
 498 #define N_(msgid) msgid
 499 #else
 500 #define _(msgid) (msgid)
 501 #define N_(msgid) msgid
 502 #endif /* ENABLE_NLS */])
 503
 504 dnl
 505 dnl Check for the availability of the kernel key management facility
 506 dnl - The pam_keyinit module only requires the syscalls, not the error codes
 507 dnl
 508 AC_CHECK_DECL(__NR_keyctl, [have_key_syscalls=1],[have_key_syscalls=0],[#include <sys/syscall.h>])
 509 AC_CHECK_DECL(ENOKEY, [have_key_errors=1],[have_key_errors=0],[#include <errno.h>])
 510
 511 HAVE_KEY_MANAGEMENT=0
 512 if test $have_key_syscalls$have_key_errors = 11
 513 then
 514         HAVE_KEY_MANAGEMENT=1
 515 fi
 516
 517 if test $HAVE_KEY_MANAGEMENT = 1; then
 518    AC_DEFINE([HAVE_KEY_MANAGEMENT], 1,
 519              [Defined if the kernel key management facility is available])
 520 fi
 521 AC_SUBST([HAVE_KEY_MANAGEMENT], $HAVE_KEY_MANAGEMENT)
 522
 523 AM_CONDITIONAL([HAVE_KEY_MANAGEMENT], [test "$have_key_syscalls" = 1])
 524
 525 dnl Files to be created from when we run configure
 526 AC_OUTPUT(Makefile libpam/Makefile libpamc/Makefile libpamc/test/Makefile \
 527         libpam_misc/Makefile conf/Makefile conf/pam_conv1/Makefile \
 528         po/Makefile.in \
 529         modules/Makefile \
 530         modules/pam_access/Makefile modules/pam_cracklib/Makefile \
 531         modules/pam_debug/Makefile modules/pam_deny/Makefile \
 532         modules/pam_echo/Makefile modules/pam_env/Makefile \
 533         modules/pam_faildelay/Makefile \
 534         modules/pam_filter/Makefile modules/pam_filter/upperLOWER/Makefile \
 535         modules/pam_ftp/Makefile modules/pam_group/Makefile \
 536         modules/pam_issue/Makefile modules/pam_keyinit/Makefile \
 537         modules/pam_lastlog/Makefile modules/pam_limits/Makefile \
 538         modules/pam_listfile/Makefile modules/pam_localuser/Makefile \
 539         modules/pam_loginuid/Makefile modules/pam_mail/Makefile \
 540         modules/pam_mkhomedir/Makefile modules/pam_motd/Makefile \
 541         modules/pam_namespace/Makefile \
 542         modules/pam_nologin/Makefile modules/pam_permit/Makefile \
 543         modules/pam_rhosts/Makefile \
 544         modules/pam_rootok/Makefile modules/pam_exec/Makefile \
 545         modules/pam_securetty/Makefile modules/pam_selinux/Makefile \
 546         modules/pam_sepermit/Makefile \
 547         modules/pam_shells/Makefile modules/pam_stress/Makefile \
 548         modules/pam_succeed_if/Makefile modules/pam_tally/Makefile \
 549         modules/pam_time/Makefile modules/pam_tty_audit/Makefile \
 550         modules/pam_umask/Makefile \
 551         modules/pam_unix/Makefile modules/pam_userdb/Makefile \
 552         modules/pam_warn/Makefile modules/pam_wheel/Makefile \
 553         modules/pam_xauth/Makefile doc/Makefile doc/specs/Makefile \
 554         doc/man/Makefile doc/sag/Makefile doc/adg/Makefile \
 555         doc/mwg/Makefile examples/Makefile tests/Makefile \
 556         xtests/Makefile)