granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.2beta1], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2012, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58   cygwin*) template=cygwin ;;
  59   darwin*) template=darwin ;;
  60 dragonfly*) template=netbsd ;;
  61  freebsd*) template=freebsd ;;
  62     hpux*) template=hpux ;;
  63     irix*) template=irix ;;
  64  linux*|gnu*|k*bsd*-gnu)
  65            template=linux ;;
  66    mingw*) template=win32 ;;
  67   netbsd*) template=netbsd ;;
  68  openbsd*) template=openbsd ;;
  69      osf*) template=osf ;;
  70      sco*) template=sco ;;
  71  solaris*) template=solaris ;;
  72    sysv5*) template=unixware ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage: enabled by default.
 126 #
 127 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 128 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 129               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 130                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 131 AC_MSG_RESULT([$enable_integer_datetimes])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 #
 167 # Option to disable shared libraries
 168 #
 169 PGAC_ARG_BOOL(enable, shared, yes,
 170               [do not build shared libraries])
 171 AC_SUBST(enable_shared)
 172
 173 #
 174 # '-rpath'-like feature can be disabled
 175 #
 176 PGAC_ARG_BOOL(enable, rpath, yes,
 177               [do not embed shared library search path in executables])
 178 AC_SUBST(enable_rpath)
 179
 180 #
 181 # Spinlocks
 182 #
 183 PGAC_ARG_BOOL(enable, spinlocks, yes,
 184               [do not use spinlocks])
 185
 186 #
 187 # --enable-debug adds -g to compiler flags
 188 #
 189 PGAC_ARG_BOOL(enable, debug, no,
 190               [build with debugging symbols (-g)])
 191 AC_SUBST(enable_debug)
 192
 193 #
 194 # --enable-profiling enables gcc profiling
 195 #
 196 PGAC_ARG_BOOL(enable, profiling, no,
 197               [build with profiling enabled ])
 198
 199 #
 200 # --enable-coverage enables generation of code coverage metrics with gcov
 201 #
 202 PGAC_ARG_BOOL(enable, coverage, no,
 203               [build with coverage testing instrumentation],
 204 [AC_CHECK_PROGS(GCOV, gcov)
 205 if test -z "$GCOV"; then
 206   AC_MSG_ERROR([gcov not found])
 207 fi
 208 AC_CHECK_PROGS(LCOV, lcov)
 209 if test -z "$LCOV"; then
 210   AC_MSG_ERROR([lcov not found])
 211 fi
 212 AC_CHECK_PROGS(GENHTML, genhtml)
 213 if test -z "$GENHTML"; then
 214   AC_MSG_ERROR([genhtml not found])
 215 fi])
 216 AC_SUBST(enable_coverage)
 217
 218 #
 219 # DTrace
 220 #
 221 PGAC_ARG_BOOL(enable, dtrace, no,
 222               [build with DTrace support],
 223 [AC_DEFINE([ENABLE_DTRACE], 1,
 224            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 225 AC_CHECK_PROGS(DTRACE, dtrace)
 226 if test -z "$DTRACE"; then
 227   AC_MSG_ERROR([dtrace not found])
 228 fi
 229 AC_SUBST(DTRACEFLAGS)])
 230 AC_SUBST(enable_dtrace)
 231
 232 #
 233 # Block size
 234 #
 235 AC_MSG_CHECKING([for block size])
 236 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 237              [blocksize=$withval],
 238              [blocksize=8])
 239 case ${blocksize} in
 240   1) BLCKSZ=1024;;
 241   2) BLCKSZ=2048;;
 242   4) BLCKSZ=4096;;
 243   8) BLCKSZ=8192;;
 244  16) BLCKSZ=16384;;
 245  32) BLCKSZ=32768;;
 246   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 247 esac
 248 AC_MSG_RESULT([${blocksize}kB])
 249
 250 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 251  Size of a disk block --- this also limits the size of a tuple.  You
 252  can set it bigger if you need bigger tuples (although TOAST should
 253  reduce the need to have large tuples, since fields can be spread
 254  across multiple tuples).
 255
 256  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 257  is currently 2^15 (32768).  This is determined by the 15-bit widths
 258  of the lp_off and lp_len fields in ItemIdData (see
 259  include/storage/itemid.h).
 260
 261  Changing BLCKSZ requires an initdb.
 262 ])
 263
 264 #
 265 # Relation segment size
 266 #
 267 AC_MSG_CHECKING([for segment size])
 268 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 269              [segsize=$withval],
 270              [segsize=1])
 271 # this expression is set up to avoid unnecessary integer overflow
 272 # blocksize is already guaranteed to be a factor of 1024
 273 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 274 test $? -eq 0 || exit 1
 275 AC_MSG_RESULT([${segsize}GB])
 276
 277 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 278  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 279  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 280  relations bigger than that are divided into multiple files.
 281
 282  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 283  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 284  have large file support enabled.  By default, we make the limit 1 GB
 285  to avoid any possible integer-overflow problems within the OS.
 286  A limit smaller than necessary only means we divide a large
 287  relation into more chunks than necessary, so it seems best to err
 288  in the direction of a small limit.
 289
 290  A power-of-2 value is recommended to save a few cycles in md.c,
 291  but is not absolutely required.
 292
 293  Changing RELSEG_SIZE requires an initdb.
 294 ])
 295
 296 #
 297 # WAL block size
 298 #
 299 AC_MSG_CHECKING([for WAL block size])
 300 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 301              [wal_blocksize=$withval],
 302              [wal_blocksize=8])
 303 case ${wal_blocksize} in
 304   1) XLOG_BLCKSZ=1024;;
 305   2) XLOG_BLCKSZ=2048;;
 306   4) XLOG_BLCKSZ=4096;;
 307   8) XLOG_BLCKSZ=8192;;
 308  16) XLOG_BLCKSZ=16384;;
 309  32) XLOG_BLCKSZ=32768;;
 310  64) XLOG_BLCKSZ=65536;;
 311   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 312 esac
 313 AC_MSG_RESULT([${wal_blocksize}kB])
 314
 315 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 316  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 317  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 318  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 319  buffers, else direct I/O may fail.
 320
 321  Changing XLOG_BLCKSZ requires an initdb.
 322 ])
 323
 324 #
 325 # WAL segment size
 326 #
 327 AC_MSG_CHECKING([for WAL segment size])
 328 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 329              [wal_segsize=$withval],
 330              [wal_segsize=16])
 331 case ${wal_segsize} in
 332   1) ;;
 333   2) ;;
 334   4) ;;
 335   8) ;;
 336  16) ;;
 337  32) ;;
 338  64) ;;
 339   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 340 esac
 341 AC_MSG_RESULT([${wal_segsize}MB])
 342
 343 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 344  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 345  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 346  XLOG_BLCKSZ).
 347
 348  Changing XLOG_SEG_SIZE requires an initdb.
 349 ])
 350
 351 #
 352 # C compiler
 353 #
 354
 355 # For historical reasons you can also use --with-CC to specify the C compiler
 356 # to use, although the standard way to do this is to set the CC environment
 357 # variable.
 358 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 359
 360 case $template in
 361   aix) pgac_cc_list="gcc xlc";;
 362  irix) pgac_cc_list="cc";; # no gcc
 363     *) pgac_cc_list="gcc cc";;
 364 esac
 365
 366 AC_PROG_CC([$pgac_cc_list])
 367
 368 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 369 # but has idiosyncrasies of its own.  We assume icc will define
 370 # __INTEL_COMPILER regardless of CFLAGS.
 371 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 372 choke me
 373 @%:@endif], [ICC=[yes]], [ICC=[no]])
 374
 375 # Check if it's Sun Studio compiler. We assume that
 376 # __SUNPRO_C will be defined for Sun Studio compilers
 377 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 378 choke me
 379 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 380
 381 AC_SUBST(SUN_STUDIO_CC)
 382
 383 unset CFLAGS
 384
 385 #
 386 # Read the template
 387 #
 388 . "$srcdir/src/template/$template" || exit
 389
 390 # CFLAGS are selected so:
 391 # If the user specifies something in the environment, that is used.
 392 # else:  If the template file set something, that is used.
 393 # else:  If coverage was enabled, don't set anything.
 394 # else:  If the compiler is GCC, then we use -O2.
 395 # else:  If the compiler is something else, then we use -O, unless debugging.
 396
 397 if test "$ac_env_CFLAGS_set" = set; then
 398   CFLAGS=$ac_env_CFLAGS_value
 399 elif test "${CFLAGS+set}" = set; then
 400   : # (keep what template set)
 401 elif test "$enable_coverage" = yes; then
 402   : # no optimization by default
 403 elif test "$GCC" = yes; then
 404   CFLAGS="-O2"
 405 else
 406   # if the user selected debug mode, don't use -O
 407   if test "$enable_debug" != yes; then
 408     CFLAGS="-O"
 409   fi
 410 fi
 411
 412 # Some versions of GCC support some additional useful warning flags.
 413 # Check whether they are supported, and add them to CFLAGS if so.
 414 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 415 # but has its own.  Also check other compiler-specific flags here.
 416
 417 if test "$GCC" = yes -a "$ICC" = no; then
 418   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 419   # These work in some but not all gcc versions
 420   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 421   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 422   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 423   # This was included in -Wall/-Wformat in older GCC versions
 424   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 425   # Disable strict-aliasing rules; needed for gcc 3.3+
 426   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 427   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 428   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 429   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 430   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 431 elif test "$ICC" = yes; then
 432   # Intel's compiler has a bug/misoptimization in checking for
 433   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 434   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 435   # Make sure strict aliasing is off (though this is said to be the default)
 436   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 437 elif test "$PORTNAME" = "aix"; then
 438   # AIX's xlc has to have strict aliasing turned off too
 439   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 440 elif test "$PORTNAME" = "hpux"; then
 441   # On some versions of HP-UX, libm functions do not set errno by default.
 442   # Fix that by using +Olibmerrno if the compiler recognizes it.
 443   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 444 fi
 445
 446 # supply -g if --enable-debug
 447 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 448   CFLAGS="$CFLAGS -g"
 449 fi
 450
 451 # enable code coverage if --enable-coverage
 452 if test "$enable_coverage" = yes; then
 453   if test "$GCC" = yes; then
 454     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 455   else
 456     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 457   fi
 458 fi
 459
 460 # enable profiling if --enable-profiling
 461 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 462   if test "$GCC" = yes; then
 463     AC_DEFINE([PROFILE_PID_DIR], 1,
 464            [Define to 1 to allow profiling output to be saved separately for each process.])
 465     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 466   else
 467     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 468   fi
 469 fi
 470
 471 # We already have this in Makefile.win32, but configure needs it too
 472 if test "$PORTNAME" = "win32"; then
 473   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 474 fi
 475
 476 # Check if the compiler still works with the template settings
 477 AC_MSG_CHECKING([whether the C compiler still works])
 478 AC_TRY_LINK([], [return 0;],
 479   [AC_MSG_RESULT(yes)],
 480   [AC_MSG_RESULT(no)
 481    AC_MSG_ERROR([cannot proceed])])
 482
 483 # Defend against gcc -ffast-math
 484 if test "$GCC" = yes; then
 485 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 486 choke me
 487 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 488 fi
 489
 490 AC_PROG_CPP
 491 AC_SUBST(GCC)
 492
 493
 494 #
 495 # Set up TAS assembly code if needed; the template file has now had its
 496 # chance to request this.
 497 #
 498 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 499
 500 if test "$need_tas" = yes ; then
 501   TAS=tas.o
 502 else
 503   TAS=""
 504 fi
 505 AC_SUBST(TAS)
 506
 507
 508 #
 509 # Automatic dependency tracking
 510 #
 511 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 512               [autodepend=yes])
 513 AC_SUBST(autodepend)
 514
 515
 516 #
 517 # Enable assert checks
 518 #
 519 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 520               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 521                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 522
 523
 524 #
 525 # Include directories
 526 #
 527 ac_save_IFS=$IFS
 528 IFS="${IFS}${PATH_SEPARATOR}"
 529 # SRCH_INC comes from the template file
 530 for dir in $with_includes $SRCH_INC; do
 531   if test -d "$dir"; then
 532     INCLUDES="$INCLUDES -I$dir"
 533   else
 534     AC_MSG_WARN([*** Include directory $dir does not exist.])
 535   fi
 536 done
 537 IFS=$ac_save_IFS
 538 AC_SUBST(INCLUDES)
 539
 540
 541 #
 542 # Library directories
 543 #
 544 ac_save_IFS=$IFS
 545 IFS="${IFS}${PATH_SEPARATOR}"
 546 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 547 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 548   if test -d "$dir"; then
 549     LIBDIRS="$LIBDIRS -L$dir"
 550   else
 551     AC_MSG_WARN([*** Library directory $dir does not exist.])
 552   fi
 553 done
 554 IFS=$ac_save_IFS
 555
 556 #
 557 # Enable thread-safe client libraries
 558 #
 559 AC_MSG_CHECKING([allow thread-safe client libraries])
 560 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 561 if test "$enable_thread_safety" = yes; then
 562   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 563           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 564 fi
 565 AC_MSG_RESULT([$enable_thread_safety])
 566 AC_SUBST(enable_thread_safety)
 567
 568 #
 569 # Optionally build Tcl modules (PL/Tcl)
 570 #
 571 AC_MSG_CHECKING([whether to build with Tcl])
 572 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 573 AC_MSG_RESULT([$with_tcl])
 574 AC_SUBST([with_tcl])
 575
 576 # We see if the path to the Tcl/Tk configuration scripts is specified.
 577 # This will override the use of tclsh to find the paths to search.
 578
 579 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 580
 581 #
 582 # Optionally build Perl modules (PL/Perl)
 583 #
 584 AC_MSG_CHECKING([whether to build Perl modules])
 585 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 586 AC_MSG_RESULT([$with_perl])
 587 AC_SUBST(with_perl)
 588
 589 #
 590 # Optionally build Python modules (PL/Python)
 591 #
 592 AC_MSG_CHECKING([whether to build Python modules])
 593 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 594 AC_MSG_RESULT([$with_python])
 595 AC_SUBST(with_python)
 596
 597 #
 598 # GSSAPI
 599 #
 600 AC_MSG_CHECKING([whether to build with GSSAPI support])
 601 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 602 [
 603   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 604   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 605 ])
 606 AC_MSG_RESULT([$with_gssapi])
 607
 608 #
 609 # Kerberos 5
 610 #
 611 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 612 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 613 [
 614   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 615   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 616 ])
 617 AC_MSG_RESULT([$with_krb5])
 618
 619
 620 AC_SUBST(krb_srvtab)
 621
 622
 623 #
 624 # Kerberos configuration parameters
 625 #
 626 PGAC_ARG_REQ(with, krb-srvnam,
 627              [NAME], [default service principal name in Kerberos [postgres]],
 628              [],
 629              [with_krb_srvnam="postgres"])
 630 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 631                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 632
 633
 634 #
 635 # PAM
 636 #
 637 AC_MSG_CHECKING([whether to build with PAM support])
 638 PGAC_ARG_BOOL(with, pam, no,
 639               [build with PAM support],
 640               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 641 AC_MSG_RESULT([$with_pam])
 642
 643
 644 #
 645 # LDAP
 646 #
 647 AC_MSG_CHECKING([whether to build with LDAP support])
 648 PGAC_ARG_BOOL(with, ldap, no,
 649               [build with LDAP support],
 650               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 651 AC_MSG_RESULT([$with_ldap])
 652
 653
 654 #
 655 # Bonjour
 656 #
 657 AC_MSG_CHECKING([whether to build with Bonjour support])
 658 PGAC_ARG_BOOL(with, bonjour, no,
 659               [build with Bonjour support],
 660               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 661 AC_MSG_RESULT([$with_bonjour])
 662
 663
 664 #
 665 # OpenSSL
 666 #
 667 AC_MSG_CHECKING([whether to build with OpenSSL support])
 668 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 669               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 670 AC_MSG_RESULT([$with_openssl])
 671 AC_SUBST(with_openssl)
 672
 673 #
 674 # SELinux
 675 #
 676 AC_MSG_CHECKING([whether to build with SELinux support])
 677 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 678 AC_SUBST(with_selinux)
 679 AC_MSG_RESULT([$with_selinux])
 680
 681 #
 682 # Readline
 683 #
 684 PGAC_ARG_BOOL(with, readline, yes,
 685               [do not use GNU Readline nor BSD Libedit for editing])
 686 # readline on MinGW has problems with backslashes in psql and other bugs.
 687 # This is particularly a problem with non-US code pages.
 688 # Therefore disable its use until we understand the cause. 2004-07-20
 689 if test "$PORTNAME" = "win32"; then
 690   if test "$with_readline" = yes; then
 691     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 692     with_readline=no
 693   fi
 694 fi
 695
 696
 697 #
 698 # Prefer libedit
 699 #
 700 PGAC_ARG_BOOL(with, libedit-preferred, no,
 701               [prefer BSD Libedit over GNU Readline])
 702
 703
 704 #
 705 # OSSP UUID library
 706 #
 707 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 708 AC_SUBST(with_ossp_uuid)
 709
 710
 711 #
 712 # XML
 713 #
 714 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 715               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 716
 717 if test "$with_libxml" = yes ; then
 718   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 719   if test -n "$XML2_CONFIG"; then
 720     for pgac_option in `$XML2_CONFIG --cflags`; do
 721       case $pgac_option in
 722         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 723       esac
 724     done
 725     for pgac_option in `$XML2_CONFIG --libs`; do
 726       case $pgac_option in
 727         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 728       esac
 729     done
 730   fi
 731 fi
 732
 733 AC_SUBST(with_libxml)
 734
 735 #
 736 # XSLT
 737 #
 738 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 739               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 740
 741
 742 AC_SUBST(with_libxslt)
 743
 744 #
 745 # tzdata
 746 #
 747 PGAC_ARG_REQ(with, system-tzdata,
 748              [DIR], [use system time zone data in DIR])
 749 AC_SUBST(with_system_tzdata)
 750
 751 #
 752 # Zlib
 753 #
 754 PGAC_ARG_BOOL(with, zlib, yes,
 755               [do not use Zlib])
 756 AC_SUBST(with_zlib)
 757
 758 #
 759 # Elf
 760 #
 761
 762 # Assume system is ELF if it predefines __ELF__ as 1,
 763 # otherwise believe host_os based default.
 764 case $host_os in
 765     freebsd1*|freebsd2*) elf=no;;
 766     freebsd3*|freebsd4*) elf=yes;;
 767 esac
 768
 769 AC_EGREP_CPP(yes,
 770 [#if __ELF__
 771   yes
 772 #endif
 773 ],
 774 [ELF_SYS=true],
 775 [if test "X$elf" = "Xyes" ; then
 776   ELF_SYS=true
 777 else
 778   ELF_SYS=
 779 fi])
 780 AC_SUBST(ELF_SYS)
 781
 782 #
 783 # Assignments
 784 #
 785
 786 CPPFLAGS="$CPPFLAGS $INCLUDES"
 787 LDFLAGS="$LDFLAGS $LIBDIRS"
 788
 789 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 790 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 791
 792 PGAC_PROG_LD
 793 AC_SUBST(LD)
 794 AC_SUBST(with_gnu_ld)
 795 case $host_os in sysv5*)
 796   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 797   [
 798     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 799     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 800     LDFLAGS=$pgac_save_LDFLAGS
 801   ])
 802   ld_R_works=$pgac_cv_prog_ld_R
 803   AC_SUBST(ld_R_works)
 804 esac
 805 AC_PROG_RANLIB
 806 PGAC_CHECK_STRIP
 807 AC_CHECK_TOOL(AR, ar, ar)
 808 if test "$PORTNAME" = "win32"; then
 809   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 810   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 811   AC_CHECK_TOOL(WINDRES, windres, windres)
 812 fi
 813
 814 AC_PATH_PROG(TAR, tar)
 815 AC_PROG_LN_S
 816 AC_PROG_AWK
 817 AC_PROG_MKDIR_P
 818 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 819 # a relative path to it in each makefile where it subsitutes it. This clashes
 820 # with our Makefile.global concept. This workaround helps.
 821 case $MKDIR_P in
 822   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 823 esac
 824
 825 PGAC_PATH_BISON
 826 PGAC_PATH_FLEX
 827
 828 PGAC_PATH_PERL
 829 if test "$with_perl" = yes; then
 830   if test -z "$PERL"; then
 831     AC_MSG_ERROR([Perl not found])
 832   fi
 833   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 834   PGAC_CHECK_PERL_EMBED_LDFLAGS
 835 fi
 836
 837 if test "$with_python" = yes; then
 838   PGAC_PATH_PYTHON
 839   PGAC_CHECK_PYTHON_EMBED_SETUP
 840 fi
 841
 842 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 843   AC_PATH_PROG(ZIC, zic)
 844   if test -z "$ZIC"; then
 845     AC_MSG_ERROR([
 846 When cross-compiling, either use the option --with-system-tzdata to use
 847 existing time-zone data, or set the environment variable ZIC to a zic
 848 program to use during the build.])
 849   fi
 850 fi
 851
 852
 853 ##
 854 ## Libraries
 855 ##
 856 ## Most libraries are included only if they demonstrably provide a function
 857 ## we need, but libm is an exception: always include it, because there are
 858 ## too many compilers that play cute optimization games that will break
 859 ## probes for standard functions such as pow().
 860 ##
 861
 862 AC_CHECK_LIB(m, main)
 863 AC_SEARCH_LIBS(setproctitle, util)
 864 AC_SEARCH_LIBS(dlopen, dl)
 865 AC_SEARCH_LIBS(socket, [socket wsock32])
 866 AC_SEARCH_LIBS(shl_load, dld)
 867 # We only use libld in port/dynloader/aix.c
 868 case $host_os in
 869      aix*)
 870         AC_SEARCH_LIBS(ldopen, ld)
 871         ;;
 872 esac
 873 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 874 AC_SEARCH_LIBS(crypt, crypt)
 875 # Solaris:
 876 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 877 # Required for thread_test.c on Solaris 2.5:
 878 # Other ports use it too (HP-UX) so test unconditionally
 879 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 880 # Cygwin:
 881 AC_SEARCH_LIBS(shmget, cygipc)
 882
 883 if test "$with_readline" = yes; then
 884   PGAC_CHECK_READLINE
 885   if test x"$pgac_cv_check_readline" = x"no"; then
 886     AC_MSG_ERROR([readline library not found
 887 If you have readline already installed, see config.log for details on the
 888 failure.  It is possible the compiler isn't looking in the proper directory.
 889 Use --without-readline to disable readline support.])
 890   fi
 891 fi
 892
 893 if test "$with_zlib" = yes; then
 894   AC_CHECK_LIB(z, inflate, [],
 895                [AC_MSG_ERROR([zlib library not found
 896 If you have zlib already installed, see config.log for details on the
 897 failure.  It is possible the compiler isn't looking in the proper directory.
 898 Use --without-zlib to disable zlib support.])])
 899 fi
 900
 901 if test "$enable_spinlocks" = yes; then
 902   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 903 else
 904   AC_MSG_WARN([
 905 *** Not using spinlocks will cause poor performance.])
 906 fi
 907
 908 if test "$with_gssapi" = yes ; then
 909   if test "$PORTNAME" != "win32"; then
 910     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 911                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 912   else
 913     LIBS="$LIBS -lgssapi32"
 914   fi
 915 fi
 916
 917 if test "$with_krb5" = yes ; then
 918   if test "$PORTNAME" != "win32"; then
 919      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 920                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 921      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 922                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 923   else
 924      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 925                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 926   fi
 927 fi
 928
 929 if test "$with_openssl" = yes ; then
 930   dnl Order matters!
 931   if test "$PORTNAME" != "win32"; then
 932      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 933      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 934   else
 935      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 936      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 937   fi
 938 fi
 939
 940 if test "$with_pam" = yes ; then
 941   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 942 fi
 943
 944 if test "$with_libxml" = yes ; then
 945   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 946 fi
 947
 948 if test "$with_libxslt" = yes ; then
 949   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 950 fi
 951
 952 # for contrib/sepgsql
 953 if test "$with_selinux" = yes; then
 954   AC_CHECK_LIB(selinux, selinux_status_open, [],
 955                [AC_MSG_ERROR([library 'libselinux', version 2.0.99 or newer, is required for SELinux support])])
 956 fi
 957
 958 # for contrib/uuid-ossp
 959 if test "$with_ossp_uuid" = yes ; then
 960   AC_CHECK_LIB(ossp-uuid, uuid_export,
 961     [OSSP_UUID_LIBS="-lossp-uuid"],
 962     [AC_CHECK_LIB(uuid, uuid_export,
 963       [OSSP_UUID_LIBS="-luuid"],
 964       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 965 fi
 966 AC_SUBST(OSSP_UUID_LIBS)
 967
 968
 969 ##
 970 ## Header files
 971 ##
 972
 973 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 974 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/ucred.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
 975
 976 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 977 # is included first.
 978 AC_CHECK_HEADERS(net/if.h, [], [],
 979 [AC_INCLUDES_DEFAULT
 980 #ifdef HAVE_SYS_SOCKET_H
 981 #include <sys/socket.h>
 982 #endif
 983 ])
 984
 985 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 986 # netinet/in.h is included first.
 987 AC_CHECK_HEADERS(netinet/in.h)
 988 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 989 [AC_INCLUDES_DEFAULT
 990 #ifdef HAVE_NETINET_IN_H
 991 #include <netinet/in.h>
 992 #endif
 993 ])
 994
 995 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 996   AC_CHECK_HEADERS(readline/readline.h, [],
 997         [AC_CHECK_HEADERS(readline.h, [],
 998                 [AC_MSG_ERROR([readline header not found
 999 If you have readline already installed, see config.log for details on the
1000 failure.  It is possible the compiler isn't looking in the proper directory.
1001 Use --without-readline to disable readline support.])])])
1002   AC_CHECK_HEADERS(readline/history.h, [],
1003         [AC_CHECK_HEADERS(history.h, [],
1004                 [AC_MSG_ERROR([history header not found
1005 If you have readline already installed, see config.log for details on the
1006 failure.  It is possible the compiler isn't looking in the proper directory.
1007 Use --without-readline to disable readline support.])])])
1008 fi
1009
1010 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1011 # Some installations of libedit usurp /usr/include/readline/, which seems
1012 # bad practice, since in combined installations readline will have its headers
1013 # there.  We might have to resort to AC_EGREP checks to make sure we found
1014 # the proper header...
1015   AC_CHECK_HEADERS(editline/readline.h, [],
1016         [AC_CHECK_HEADERS(readline.h, [],
1017                 [AC_CHECK_HEADERS(readline/readline.h, [],
1018                         [AC_MSG_ERROR([readline header not found
1019 If you have libedit already installed, see config.log for details on the
1020 failure.  It is possible the compiler isn't looking in the proper directory.
1021 Use --without-readline to disable libedit support.])])])])
1022 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1023 # not be there at all.  Hence, don't complain if not found.  We must check
1024 # though, since in yet other versions it is an independent header.
1025   AC_CHECK_HEADERS(editline/history.h, [],
1026         [AC_CHECK_HEADERS(history.h, [],
1027                 [AC_CHECK_HEADERS(readline/history.h)])])
1028 fi
1029
1030 if test "$with_zlib" = yes; then
1031   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1032 If you have zlib already installed, see config.log for details on the
1033 failure.  It is possible the compiler isn't looking in the proper directory.
1034 Use --without-zlib to disable zlib support.])])
1035 fi
1036
1037 if test "$with_gssapi" = yes ; then
1038   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1039         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1040 fi
1041
1042 if test "$with_krb5" = yes ; then
1043   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1044 fi
1045
1046 if test "$with_openssl" = yes ; then
1047   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1048   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1049   AC_CHECK_FUNCS([ERR_set_mark])
1050 fi
1051
1052 if test "$with_pam" = yes ; then
1053   AC_CHECK_HEADERS(security/pam_appl.h, [],
1054                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1055                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1056 fi
1057
1058 if test "$with_libxml" = yes ; then
1059   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1060 fi
1061
1062 if test "$with_libxslt" = yes ; then
1063   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1064 fi
1065
1066 if test "$with_ldap" = yes ; then
1067   if test "$PORTNAME" != "win32"; then
1068      AC_CHECK_HEADERS(ldap.h, [],
1069                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1070   else
1071      AC_CHECK_HEADERS(winldap.h, [],
1072                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1073                       [AC_INCLUDES_DEFAULT
1074 #include <windows.h>
1075                       ])
1076   fi
1077 fi
1078
1079 if test "$with_bonjour" = yes ; then
1080   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1081 fi
1082
1083 # for contrib/uuid-ossp
1084 if test "$with_ossp_uuid" = yes ; then
1085   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1086     AC_CHECK_HEADERS(uuid.h, [],
1087       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1088 fi
1089
1090 if test "$PORTNAME" = "win32" ; then
1091    AC_CHECK_HEADERS(crtdefs.h)
1092 fi
1093
1094 ##
1095 ## Types, structures, compiler characteristics
1096 ##
1097
1098 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1099 AC_C_BIGENDIAN
1100 AC_C_CONST
1101 PGAC_C_INLINE
1102 AC_C_STRINGIZE
1103 AC_C_FLEXIBLE_ARRAY_MEMBER
1104 PGAC_C_SIGNED
1105 AC_C_VOLATILE
1106 PGAC_C_FUNCNAME_SUPPORT
1107 PGAC_STRUCT_TIMEZONE
1108 PGAC_UNION_SEMUN
1109 PGAC_STRUCT_SOCKADDR_UN
1110 PGAC_STRUCT_SOCKADDR_STORAGE
1111 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1112 PGAC_STRUCT_ADDRINFO
1113 AC_TYPE_INTPTR_T
1114 AC_TYPE_UINTPTR_T
1115 AC_TYPE_LONG_LONG_INT
1116
1117 PGAC_TYPE_LOCALE_T
1118
1119 AC_CHECK_TYPES([struct cmsgcred], [], [],
1120 [#include <sys/socket.h>
1121 #ifdef HAVE_SYS_UCRED_H
1122 #include <sys/ucred.h>
1123 #endif])
1124
1125 AC_CHECK_TYPES([struct option], [], [],
1126 [#ifdef HAVE_GETOPT_H
1127 #include <getopt.h>
1128 #endif])
1129
1130 if test "$with_zlib" = yes; then
1131   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1132   # did not).  While we could work around the lack of z_streamp, it
1133   # seems unwise to encourage people to use such old zlib versions...
1134   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1135 Use --without-zlib to disable zlib support.])],
1136                 [#include <zlib.h>])
1137 fi
1138
1139 if test "$with_krb5" = yes; then
1140 # Check for differences between MIT and Heimdal (KTH) releases
1141   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1142                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1143                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1144                                      [#include <krb5.h>])],
1145                    [#include <krb5.h>])
1146   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1147                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1148                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1149                                      [#include <krb5.h>])],
1150                    [#include <krb5.h>])
1151
1152 # Win32 requires headers to be loaded for __stdcall, so can't use
1153 # AC_CHECK_FUNCS here.
1154   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1155   AC_TRY_LINK([#include <krb5.h>],
1156               [krb5_free_unparsed_name(NULL,NULL);],
1157               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name.])
1158 AC_MSG_RESULT(yes)],
1159               [AC_MSG_RESULT(no)])
1160 fi
1161
1162 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1163 case $host_cpu in
1164   ppc*|powerpc*)
1165     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1166     AC_TRY_COMPILE([],
1167         [int a = 0; int *p = &a; int r;
1168          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1169         [pgac_cv_have_ppc_mutex_hint=yes],
1170         [pgac_cv_have_ppc_mutex_hint=no])
1171     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1172     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1173         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1174     fi
1175   ;;
1176 esac
1177
1178 # Check largefile support.  You might think this is a system service not a
1179 # compiler characteristic, but you'd be wrong.  We must check this before
1180 # probing existence of related functions such as fseeko, since the largefile
1181 # defines can affect what is generated for that.
1182 if test "$PORTNAME" != "win32"; then
1183    AC_SYS_LARGEFILE
1184 fi
1185
1186 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1187 AC_CHECK_SIZEOF([off_t])
1188
1189 # If we don't have largefile support, can't handle segsize >= 2GB.
1190 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1191    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1192 fi
1193
1194
1195 ##
1196 ## Functions, global variables
1197 ##
1198
1199 PGAC_VAR_INT_TIMEZONE
1200 AC_FUNC_ACCEPT_ARGTYPES
1201 PGAC_FUNC_GETTIMEOFDAY_1ARG
1202
1203 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getifaddrs getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs wcstombs_l])
1204
1205 AC_REPLACE_FUNCS(fseeko)
1206 case $host_os in
1207         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1208         # Mingw uses macros to access Win32 API calls
1209         netbsd*|mingw*)
1210                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1211                 ac_cv_func_fseeko=yes;;
1212         *)
1213                 AC_FUNC_FSEEKO;;
1214 esac
1215
1216 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1217 # by calling it, 2009-04-02
1218 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1219 if test "$PORTNAME" != "solaris"; then
1220 AC_CHECK_FUNCS(posix_fadvise)
1221 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1222 fi
1223
1224 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1225 AC_CHECK_DECLS([strlcat, strlcpy])
1226 # This is probably only present on Darwin, but may as well check always
1227 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1228
1229 HAVE_IPV6=no
1230 AC_CHECK_TYPE([struct sockaddr_in6],
1231         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1232          HAVE_IPV6=yes],
1233         [],
1234 [$ac_includes_default
1235 #include <netinet/in.h>])
1236 AC_SUBST(HAVE_IPV6)
1237
1238 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1239 [AC_TRY_LINK(
1240 [#include <machine/vmparam.h>
1241 #include <sys/exec.h>
1242 ],
1243 [PS_STRINGS->ps_nargvstr = 1;
1244 PS_STRINGS->ps_argvstr = "foo";],
1245 [pgac_cv_var_PS_STRINGS=yes],
1246 [pgac_cv_var_PS_STRINGS=no])])
1247 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1248   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1249 fi
1250
1251
1252 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1253 # is missing.  Yes, there are machines that have only one.  We may
1254 # also decide to use snprintf.c if snprintf() is present but does not
1255 # have all the features we need --- see below.
1256
1257 if test "$PORTNAME" = "win32"; then
1258   # Win32 gets snprintf.c built unconditionally.
1259   #
1260   # To properly translate all NLS languages strings, we must support the
1261   # *printf() %$ format, which allows *printf() arguments to be selected
1262   # by position in the translated string.
1263   #
1264   # libintl versions < 0.13 use the native *printf() functions, and Win32
1265   # *printf() doesn't understand %$, so we must use our /port versions,
1266   # which do understand %$. libintl versions >= 0.13 include their own
1267   # *printf versions on Win32.  The libintl 0.13 release note text is:
1268   #
1269   #   C format strings with positions, as they arise when a translator
1270   #   needs to reorder a sentence, are now supported on all platforms.
1271   #   On those few platforms (NetBSD and Woe32) for which the native
1272   #   printf()/fprintf()/... functions don't support such format
1273   #   strings, replacements are provided through <libintl.h>.
1274   #
1275   # We could use libintl >= 0.13's *printf() if we were sure that we had
1276   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1277   # to guarantee that, it is best to just use our own, so we are sure to
1278   # get %$ support. In include/port.h we disable the *printf() macros
1279   # that might have been defined by libintl.
1280   #
1281   # We do this unconditionally whether NLS is used or not so we are sure
1282   # that all Win32 libraries and binaries behave the same.
1283   pgac_need_repl_snprintf=yes
1284 else
1285   pgac_need_repl_snprintf=no
1286   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1287   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1288 fi
1289
1290
1291 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1292 # include/c.h will provide declarations.  Note this is a separate test
1293 # from whether the functions exist in the C library --- there are
1294 # systems that have the functions but don't bother to declare them :-(
1295
1296 AC_CHECK_DECLS([snprintf, vsnprintf])
1297
1298
1299 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1300 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1301 [AC_TRY_LINK([
1302 #include <math.h>
1303 double glob_double;
1304 ],
1305 [return isinf(glob_double) ? 0 : 1;],
1306 [ac_cv_func_isinf=yes],
1307 [ac_cv_func_isinf=no])])
1308
1309 if test $ac_cv_func_isinf = yes ; then
1310   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1311 else
1312   AC_LIBOBJ(isinf)
1313   # Look for a way to implement a substitute for isinf()
1314   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1315 fi
1316
1317 # Some versions of libedit contain strlcpy(); so disregard that library while
1318 # checking for these standard libc functions.
1319 pgac_save_LIBS="$LIBS"
1320 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1321
1322 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton random rint srandom strerror strlcat strlcpy])
1323
1324 case $host_os in
1325
1326         # Windows uses a specialised env handler
1327         # and doesn't need a replacement getpeereid because it doesn't use
1328         # Unix sockets.
1329         mingw*)
1330                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1331                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1332                 ac_cv_func_unsetenv=yes
1333                 ac_cv_func_getpeereid=yes;;
1334         *)
1335                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1336                 ;;
1337 esac
1338
1339
1340 LIBS="$pgac_save_LIBS"
1341
1342 # System's version of getaddrinfo(), if any, may be used only if we found
1343 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1344 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1345 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1346 # because we want to use our own getaddrinfo.c on Windows anyway.)
1347 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1348   AC_REPLACE_FUNCS([getaddrinfo])
1349 else
1350   AC_LIBOBJ(getaddrinfo)
1351 fi
1352
1353 # Similarly, use system's getopt_long() only if system provides struct option.
1354 if test x"$ac_cv_type_struct_option" = xyes ; then
1355   AC_REPLACE_FUNCS([getopt_long])
1356 else
1357   AC_LIBOBJ(getopt_long)
1358 fi
1359
1360 # Solaris' getopt() doesn't do what we want for long options, so always use
1361 # our version on that platform.
1362 if test "$PORTNAME" = "solaris"; then
1363   AC_LIBOBJ(getopt)
1364 fi
1365
1366 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1367 # so always use our version on Windows.
1368 if test "$PORTNAME" = "win32"; then
1369   AC_LIBOBJ(getopt)
1370   AC_LIBOBJ(getopt_long)
1371 fi
1372
1373 # Win32 support
1374 if test "$PORTNAME" = "win32"; then
1375   AC_REPLACE_FUNCS(gettimeofday)
1376   AC_LIBOBJ(kill)
1377   AC_LIBOBJ(open)
1378   AC_LIBOBJ(win32env)
1379   AC_LIBOBJ(win32error)
1380   AC_LIBOBJ(win32setlocale)
1381   AC_DEFINE([HAVE_SYMLINK], 1,
1382             [Define to 1 if you have the `symlink' function.])
1383   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1384 #define WIN32_LEAN_AND_MEAN
1385 #include <windows.h>
1386 #include <string.h>
1387 #include <dbghelp.h>])
1388 fi
1389 if test x"$pgac_minidump_type" = x"yes" ; then
1390   AC_SUBST(have_win32_dbghelp,yes)
1391 else
1392   AC_SUBST(have_win32_dbghelp,no)
1393 fi
1394
1395 if test "$with_readline" = yes; then
1396   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1397   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1398   AC_CHECK_FUNCS([append_history history_truncate_file])
1399 fi
1400
1401
1402 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1403 dnl (especially on GNU libc)
1404 dnl See also comments in c.h.
1405 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1406 [AC_TRY_LINK([#include <setjmp.h>],
1407             [sigjmp_buf x; sigsetjmp(x, 1);],
1408             [pgac_cv_func_sigsetjmp=yes],
1409             [pgac_cv_func_sigsetjmp=no])])
1410 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1411   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1412 fi
1413
1414 AC_DECL_SYS_SIGLIST
1415
1416 AC_CHECK_FUNC(syslog,
1417               [AC_CHECK_HEADER(syslog.h,
1418                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1419
1420 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1421 [AC_TRY_LINK([#include <unistd.h>],
1422   [extern int opterr; opterr = 1;],
1423   [pgac_cv_var_int_opterr=yes],
1424   [pgac_cv_var_int_opterr=no])])
1425 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1426   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1427 fi
1428
1429 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1430 [AC_TRY_LINK([#include <unistd.h>],
1431   [extern int optreset; optreset = 1;],
1432   [pgac_cv_var_int_optreset=yes],
1433   [pgac_cv_var_int_optreset=no])])
1434 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1435   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1436 fi
1437
1438 AC_CHECK_FUNCS([strtoll strtoq], [break])
1439 AC_CHECK_FUNCS([strtoull strtouq], [break])
1440
1441 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1442 [AC_TRY_LINK([],
1443   [int lock = 0;
1444    __sync_lock_test_and_set(&lock, 1);
1445    __sync_lock_release(&lock);],
1446   [pgac_cv_gcc_int_atomics="yes"],
1447   [pgac_cv_gcc_int_atomics="no"])])
1448 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1449   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1450 fi
1451
1452
1453 #
1454 # Pthreads
1455 #
1456 # For each platform, we need to know about any special compile and link
1457 # libraries, and whether the normal C function names are thread-safe.
1458 # See the comment at the top of src/port/thread.c for more information.
1459 # WIN32 doesn't need the pthread tests;  it always uses threads
1460 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1461 ACX_PTHREAD     # set thread flags
1462
1463 # Some platforms use these, so just define them.  They can't hurt if they
1464 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1465 # enables 5-arg getpwuid_r, among other things.
1466 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1467
1468
1469 # At this point, we don't want to muck with the compiler name for threading.
1470 # Let's see who fails, perhaps AIX.  2004-04-23
1471 if test "$PTHREAD_CC" != "$CC"; then
1472 AC_MSG_ERROR([
1473 PostgreSQL does not support platforms that require a special compiler
1474 for thread safety;  use --disable-thread-safety to disable thread safety.])
1475 fi
1476
1477 # Check for *_r functions
1478 _CFLAGS="$CFLAGS"
1479 _LIBS="$LIBS"
1480 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1481 LIBS="$LIBS $PTHREAD_LIBS"
1482
1483 if test "$PORTNAME" != "win32"; then
1484 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1485 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1486 fi
1487
1488 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1489
1490 # Do test here with the proper thread flags
1491 PGAC_FUNC_GETPWUID_R_5ARG
1492 PGAC_FUNC_STRERROR_R_INT
1493
1494 CFLAGS="$_CFLAGS"
1495 LIBS="$_LIBS"
1496
1497 else
1498 # do not use values from template file
1499 PTHREAD_CFLAGS=
1500 PTHREAD_LIBS=
1501 fi
1502
1503 AC_SUBST(PTHREAD_CFLAGS)
1504 AC_SUBST(PTHREAD_LIBS)
1505
1506
1507 # We can test for libldap_r only after we know PTHREAD_LIBS
1508 if test "$with_ldap" = yes ; then
1509   _LIBS="$LIBS"
1510   if test "$PORTNAME" != "win32"; then
1511     AC_CHECK_LIB(ldap, ldap_bind, [],
1512                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1513                  [$EXTRA_LDAP_LIBS])
1514     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1515     if test "$enable_thread_safety" = yes; then
1516       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1517       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1518                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1519                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1520       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1521     else
1522       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1523     fi
1524   else
1525     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1526     LDAP_LIBS_FE="-lwldap32"
1527     LDAP_LIBS_BE="-lwldap32"
1528   fi
1529   LIBS="$_LIBS"
1530 fi
1531 AC_SUBST(LDAP_LIBS_FE)
1532 AC_SUBST(LDAP_LIBS_BE)
1533
1534
1535 # Older versions of libxml2 lack the xmlStructuredErrorContext variable
1536 # (which could be a macro referring to a function, if threading is enabled)
1537 if test "$with_libxml" = yes ; then
1538   AC_CACHE_CHECK([for xmlStructuredErrorContext], pgac_cv_libxml_structerrctx,
1539   [AC_TRY_LINK([#include <libxml/globals.h>
1540                 void *globptr;],
1541                [globptr = xmlStructuredErrorContext],
1542                [pgac_cv_libxml_structerrctx=yes],
1543                [pgac_cv_libxml_structerrctx=no])])
1544   if test x"$pgac_cv_libxml_structerrctx" = x"yes"; then
1545     AC_DEFINE(HAVE_XMLSTRUCTUREDERRORCONTEXT,
1546              1,
1547              [Define to 1 if your libxml has xmlStructuredErrorContext.])
1548   fi
1549 fi
1550
1551
1552 # This test makes sure that run tests work at all.  Sometimes a shared
1553 # library is found by the linker, but the runtime linker can't find it.
1554 # This check should come after all modifications of compiler or linker
1555 # variables, and before any other run tests.
1556 AC_MSG_CHECKING([test program])
1557 AC_TRY_RUN([int main() { return 0; }],
1558 [AC_MSG_RESULT(ok)],
1559 [AC_MSG_RESULT(failed)
1560 AC_MSG_ERROR([[
1561 Could not execute a simple test program.  This may be a problem
1562 related to locating shared libraries.  Check the file 'config.log'
1563 for the exact reason.]])],
1564 [AC_MSG_RESULT([cross-compiling])])
1565
1566 # --------------------
1567 # Run tests below here
1568 # --------------------
1569
1570 # Force use of our snprintf if system's doesn't do arg control
1571 # See comment above at snprintf test for details.
1572 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1573   PGAC_FUNC_PRINTF_ARG_CONTROL
1574   if test $pgac_cv_printf_arg_control != yes ; then
1575     pgac_need_repl_snprintf=yes
1576   fi
1577 fi
1578
1579
1580 dnl Check to see if we have a working 64-bit integer type.
1581 dnl This breaks down into two steps:
1582 dnl (1) figure out if the compiler has a 64-bit int type with working
1583 dnl arithmetic, and if so
1584 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1585 dnl snprintf is the only library routine we really need for int8 support.)
1586 dnl It's entirely possible to have a compiler that handles a 64-bit type
1587 dnl when the C library doesn't; this is fairly likely when using gcc on
1588 dnl an older platform, for example.
1589 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1590 dnl we force our own version of snprintf() to be used instead.
1591 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1592
1593 dnl As of Postgres 8.4, we no longer support compilers without a working
1594 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1595
1596 PGAC_TYPE_64BIT_INT([long int])
1597
1598 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1599   PGAC_TYPE_64BIT_INT([long long int])
1600   if test x"$HAVE_LONG_LONG_INT_64" = x"no" ; then
1601     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1602   fi
1603 fi
1604
1605
1606 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1607
1608 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1609   AC_TRY_COMPILE([
1610 #define INT64CONST(x)  x##LL
1611 long long int foo = INT64CONST(0x1234567890123456);
1612 ],
1613         [],
1614         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1615         [])
1616 fi
1617
1618
1619 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1620 # we found we need to use "long long int", better check.  We cope with
1621 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1622 # work, fall back to our own snprintf emulation (which we know uses %lld).
1623
1624 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1625   if test $pgac_need_repl_snprintf = no; then
1626     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1627     if test "$LONG_LONG_INT_FORMAT" = ""; then
1628       # Force usage of our own snprintf, since system snprintf is broken
1629       pgac_need_repl_snprintf=yes
1630       LONG_LONG_INT_FORMAT='%lld'
1631     fi
1632   else
1633     # Here if we previously decided we needed to use our own snprintf
1634     LONG_LONG_INT_FORMAT='%lld'
1635   fi
1636   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1637   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1638   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1639 else
1640   # Here if we are not using 'long long int' at all
1641   INT64_FORMAT='"%ld"'
1642   UINT64_FORMAT='"%lu"'
1643 fi
1644
1645 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1646                    [Define to the appropriate snprintf format for 64-bit ints.])
1647
1648 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1649                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1650
1651 # Now we have checked all the reasons to replace snprintf
1652 if test $pgac_need_repl_snprintf = yes; then
1653   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1654   AC_LIBOBJ(snprintf)
1655 fi
1656
1657 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1658 AC_CHECK_SIZEOF([void *])
1659 AC_CHECK_SIZEOF([size_t])
1660 AC_CHECK_SIZEOF([long])
1661
1662 # Decide whether float4 is passed by value: user-selectable, enabled by default
1663 AC_MSG_CHECKING([whether to build with float4 passed by value])
1664 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1665               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1666                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1667                float4passbyval=true],
1668               [float4passbyval=false])
1669 AC_MSG_RESULT([$enable_float4_byval])
1670 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1671
1672 # Decide whether float8 is passed by value.
1673 # Note: this setting also controls int8 and related types such as timestamp.
1674 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1675 # If not, trying to select it is an error.
1676 AC_MSG_CHECKING([whether to build with float8 passed by value])
1677 if test $ac_cv_sizeof_void_p -ge 8 ; then
1678   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1679 else
1680   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1681   if test "$enable_float8_byval" = yes ; then
1682     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1683   fi
1684 fi
1685 if test "$enable_float8_byval" = yes ; then
1686   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1687             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1688   float8passbyval=true
1689 else
1690   float8passbyval=false
1691 fi
1692 AC_MSG_RESULT([$enable_float8_byval])
1693 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1694
1695 # Determine memory alignment requirements for the basic C data types.
1696
1697 AC_CHECK_ALIGNOF(short)
1698 AC_CHECK_ALIGNOF(int)
1699 AC_CHECK_ALIGNOF(long)
1700 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1701   AC_CHECK_ALIGNOF(long long int)
1702 fi
1703 AC_CHECK_ALIGNOF(double)
1704
1705 # Compute maximum alignment of any basic type.
1706 # We assume long's alignment is at least as strong as char, short, or int;
1707 # but we must check long long (if it exists) and double.
1708
1709 MAX_ALIGNOF=$ac_cv_alignof_long
1710 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1711   MAX_ALIGNOF=$ac_cv_alignof_double
1712 fi
1713 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1714   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1715 fi
1716 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1717
1718
1719 # Some platforms predefine the types int8, int16, etc.  Only check
1720 # a (hopefully) representative subset.
1721 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1722 [#include <stdio.h>])
1723
1724 # We also check for sig_atomic_t, which *should* be defined per ANSI
1725 # C, but is missing on some old platforms.
1726 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1727
1728
1729 if test "$PORTNAME" != "win32"
1730 then
1731 PGAC_FUNC_POSIX_SIGNALS
1732 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1733   AC_MSG_ERROR([
1734 Thread-safety requires POSIX signals, which are not supported by this
1735 operating system;  use --disable-thread-safety to disable thread safety.])
1736 fi
1737 fi
1738
1739 # SunOS doesn't handle negative byte comparisons properly with +/- return
1740 AC_FUNC_MEMCMP
1741
1742
1743 # Select semaphore implementation type.
1744 if test "$PORTNAME" != "win32"; then
1745   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1746     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1747     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1748   else
1749     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1750       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1751       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1752     else
1753       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1754       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1755     fi
1756   fi
1757 else
1758   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1759   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1760 fi
1761
1762
1763 # Select shared-memory implementation type.
1764 if test "$PORTNAME" != "win32"; then
1765   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1766   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1767 else
1768   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1769   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1770 fi
1771
1772 # Select latch implementation type.
1773 if test "$PORTNAME" != "win32"; then
1774   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1775 else
1776   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1777 fi
1778
1779 # If not set in template file, set bytes to use libc memset()
1780 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1781   MEMSET_LOOP_LIMIT=1024
1782 fi
1783 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1784
1785
1786 if test "$enable_nls" = yes ; then
1787   PGAC_CHECK_GETTEXT
1788 fi
1789
1790 # Check for Tcl configuration script tclConfig.sh
1791 if test "$with_tcl" = yes; then
1792     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1793     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1794                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1795     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1796     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1797     ac_save_CPPFLAGS=$CPPFLAGS
1798     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1799     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1800     CPPFLAGS=$ac_save_CPPFLAGS
1801 fi
1802
1803 # check for <Python.h>
1804 if test "$with_python" = yes; then
1805   ac_save_CPPFLAGS=$CPPFLAGS
1806   CPPFLAGS="$python_includespec $CPPFLAGS"
1807   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1808   CPPFLAGS=$ac_save_CPPFLAGS
1809 fi
1810
1811 #
1812 # Check for DocBook and tools
1813 #
1814 PGAC_PROG_NSGMLS
1815 PGAC_PROG_JADE
1816 PGAC_CHECK_DOCBOOK(4.2)
1817 PGAC_PATH_DOCBOOK_STYLESHEETS
1818 PGAC_PATH_COLLATEINDEX
1819 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1820 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1821
1822 # Thread testing
1823
1824 # We have to run the thread test near the end so we have all our symbols
1825 # defined.  Cross compiling throws a warning.
1826 #
1827 if test "$enable_thread_safety" = yes; then
1828 if test "$PORTNAME" != "win32"
1829 then
1830 AC_MSG_CHECKING([thread safety of required library functions])
1831
1832 _CFLAGS="$CFLAGS"
1833 _LIBS="$LIBS"
1834 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1835 LIBS="$LIBS $PTHREAD_LIBS"
1836 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1837   [AC_MSG_RESULT(yes)],
1838   [AC_MSG_RESULT(no)
1839   AC_MSG_ERROR([thread test program failed
1840 This platform is not thread-safe.  Check the file 'config.log' or compile
1841 and run src/test/thread/thread_test for the exact reason.
1842 Use --disable-thread-safety to disable thread safety.])],
1843   [AC_MSG_RESULT(maybe)
1844   AC_MSG_WARN([
1845 *** Skipping thread test program because of cross-compile build.
1846 *** Run the program in src/test/thread on the target machine.
1847 ])])
1848 CFLAGS="$_CFLAGS"
1849 LIBS="$_LIBS"
1850 else
1851 AC_MSG_WARN([*** skipping thread test on Win32])
1852 fi
1853 fi
1854
1855 # If compiler will take -Wl,--as-needed (or various platform-specific
1856 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1857 # trying to filter LIBS to the minimum for each executable.
1858 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1859 # libreadline; therefore we postpone testing it until we know what library
1860 # dependencies readline has.  The test code will try to link with $LIBS.
1861 if test "$with_readline" = yes; then
1862   link_test_func=readline
1863 else
1864   link_test_func=exit
1865 fi
1866
1867 if test "$PORTNAME" = "darwin"; then
1868   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1869 elif test "$PORTNAME" = "openbsd"; then
1870   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1871 else
1872   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1873 fi
1874
1875 # Create compiler version string
1876 if test x"$GCC" = x"yes" ; then
1877   cc_string=`${CC} --version | sed q`
1878   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1879 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1880   cc_string=`${CC} -V 2>&1 | sed q`
1881 else
1882   cc_string=$CC
1883 fi
1884
1885 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1886                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1887                    [A string containing the version number, platform, and C compiler])
1888
1889 # Supply a numeric version string for use by 3rd party add-ons
1890 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1891 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1892 tr '.' '        ' |
1893 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1894 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1895
1896
1897 # Begin output steps
1898
1899 AC_MSG_NOTICE([using compiler=$cc_string])
1900 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1901 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1902 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1903
1904 # prepare build tree if outside source tree
1905 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1906 # Note 2: /bin/pwd might be better than shell's built-in at getting
1907 #         a symlink-free name.
1908 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1909   vpath_build=no
1910 else
1911   vpath_build=yes
1912   if test "$no_create" != yes; then
1913     _AS_ECHO_N([preparing build tree... ])
1914     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1915     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1916       || AC_MSG_ERROR(failed)
1917     AC_MSG_RESULT(done)
1918   fi
1919 fi
1920 AC_SUBST(vpath_build)
1921
1922
1923 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1924
1925 AC_CONFIG_LINKS([
1926   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1927   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1928   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1929   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1930   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1931   src/include/pg_config_os.h:src/include/port/${template}.h
1932   src/Makefile.port:src/makefiles/Makefile.${template}
1933 ])
1934
1935 if test "$PORTNAME" = "win32"; then
1936 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1937 # Links sometimes fail undetected on Mingw -
1938 # so here we detect it and warn the user
1939 for FILE in $CONFIG_LINKS
1940  do
1941         # test -e works for symlinks in the MinGW console
1942         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1943  done
1944 ])
1945 fi
1946
1947 AC_CONFIG_HEADERS([src/include/pg_config.h],
1948 [
1949 # Update timestamp for pg_config.h (see Makefile.global)
1950 echo >src/include/stamp-h
1951 ])
1952
1953 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1954                   [echo >src/interfaces/ecpg/include/stamp-h])
1955
1956 AC_OUTPUT