granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.528 2007/10/02 00:25:20 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2007, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # --enable-profiling enables gcc profiling
 210 #
 211 PGAC_ARG_BOOL(enable, profiling, no,
 212               [  --enable-profiling      build with profiling enabled ])
 213 AC_SUBST(enable_profiling)
 214
 215 #
 216 # DTrace
 217 #
 218 PGAC_ARG_BOOL(enable, dtrace, no,
 219               [  --enable-dtrace         build with DTrace support],
 220 [AC_DEFINE([ENABLE_DTRACE], 1,
 221            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 222 AC_CHECK_PROGS(DTRACE, dtrace)
 223 if test -z "$DTRACE"; then
 224   AC_MSG_ERROR([dtrace not found])
 225 fi
 226 AC_SUBST(DTRACEFLAGS)])
 227 AC_SUBST(enable_dtrace)
 228
 229 #
 230 # C compiler
 231 #
 232
 233 # For historical reasons you can also use --with-CC to specify the C compiler
 234 # to use, although the standard way to do this is to set the CC environment
 235 # variable.
 236 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 237
 238 case $template in
 239   aix) pgac_cc_list="gcc xlc";;
 240  irix) pgac_cc_list="cc";; # no gcc
 241     *) pgac_cc_list="gcc cc";;
 242 esac
 243
 244 AC_PROG_CC([$pgac_cc_list])
 245
 246 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 247 # but has idiosyncrasies of its own.  We assume icc will define
 248 # __INTEL_COMPILER regardless of CFLAGS.
 249 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 250 choke me
 251 @%:@endif], [ICC=[yes]], [ICC=[no]])
 252
 253 unset CFLAGS
 254
 255 #
 256 # Read the template
 257 #
 258 . "$srcdir/src/template/$template" || exit
 259
 260 # CFLAGS are selected so:
 261 # If the user specifies something in the environment, that is used.
 262 # else:  If the template file set something, that is used.
 263 # else:  If the compiler is GCC, then we use -O2.
 264 # else:  If the compiler is something else, then we use -0.
 265
 266 if test "$ac_env_CFLAGS_set" = set; then
 267   CFLAGS=$ac_env_CFLAGS_value
 268 elif test "${CFLAGS+set}" = set; then
 269   : # (keep what template set)
 270 elif test "$GCC" = yes; then
 271   CFLAGS="-O2"
 272 else
 273   # if the user selected debug mode, don't use -O
 274   if test "$enable_debug" != yes; then
 275     CFLAGS="-O"
 276   fi
 277 fi
 278
 279 # Some versions of GCC support some additional useful warning flags.
 280 # Check whether they are supported, and add them to CFLAGS if so.
 281 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 282
 283 if test "$GCC" = yes -a "$ICC" = no; then
 284   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 285   # These work in some but not all gcc versions
 286   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 287   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 288   # Disable strict-aliasing rules; needed for gcc 3.3+
 289   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 290 elif test "$ICC" = yes; then
 291   # Intel's compiler has a bug/misoptimization in checking for
 292   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 293   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 294   # Make sure strict aliasing is off (though this is said to be the default)
 295   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 296 elif test x"${CC}" = x"xlc"; then
 297   # AIX xlc has to have strict aliasing turned off too
 298   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 299 fi
 300
 301 # supply -g if --enable-debug
 302 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 303   CFLAGS="$CFLAGS -g"
 304 fi
 305
 306 # enable profiling if --enable-profiling
 307 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 308   if test "$GCC" = yes; then
 309     AC_DEFINE([PROFILE_PID_DIR], 1,
 310            [Define to 1 to allow profiling output to be saved separately for each process.])
 311     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 312   else
 313     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 314   fi
 315 fi
 316
 317 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 318
 319 # We already have this in Makefile.win32, but configure needs it too
 320 if test "$PORTNAME" = "win32"; then
 321   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 322 fi
 323
 324 # Check if the compiler still works with the template settings
 325 AC_MSG_CHECKING([whether the C compiler still works])
 326 AC_TRY_LINK([], [return 0;],
 327   [AC_MSG_RESULT(yes)],
 328   [AC_MSG_RESULT(no)
 329    AC_MSG_ERROR([cannot proceed])])
 330
 331 # Defend against gcc -ffast-math
 332 if test "$GCC" = yes; then
 333 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 334 choke me
 335 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 336 fi
 337
 338 AC_PROG_CPP
 339 AC_SUBST(GCC)
 340
 341 # Create compiler version string
 342 if test x"$GCC" = x"yes" ; then
 343   cc_string="GCC `${CC} --version | sed q`"
 344 else
 345   cc_string=$CC
 346 fi
 347 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 348                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 349                    [A string containing the version number, platform, and C compiler])
 350
 351
 352 #
 353 # Set up TAS assembly code if needed; the template file has now had its
 354 # chance to request this.
 355 #
 356 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 357
 358 if test "$need_tas" = yes ; then
 359   TAS=tas.o
 360 else
 361   TAS=""
 362 fi
 363 AC_SUBST(TAS)
 364
 365
 366 #
 367 # Automatic dependency tracking
 368 #
 369 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 370               [autodepend=yes])
 371 AC_SUBST(autodepend)
 372
 373
 374 #
 375 # Enable assert checks
 376 #
 377 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 378               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 379                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 380
 381
 382 #
 383 # Include directories
 384 #
 385 ac_save_IFS=$IFS
 386 IFS="${IFS}${PATH_SEPARATOR}"
 387 # SRCH_INC comes from the template file
 388 for dir in $with_includes $SRCH_INC; do
 389   if test -d "$dir"; then
 390     INCLUDES="$INCLUDES -I$dir"
 391   else
 392     AC_MSG_WARN([*** Include directory $dir does not exist.])
 393   fi
 394 done
 395 IFS=$ac_save_IFS
 396 AC_SUBST(INCLUDES)
 397
 398
 399 #
 400 # Library directories
 401 #
 402 ac_save_IFS=$IFS
 403 IFS="${IFS}${PATH_SEPARATOR}"
 404 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 405 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 406   if test -d "$dir"; then
 407     LIBDIRS="$LIBDIRS -L$dir"
 408   else
 409     AC_MSG_WARN([*** Library directory $dir does not exist.])
 410   fi
 411 done
 412 IFS=$ac_save_IFS
 413
 414 #
 415 # Enable thread-safe client libraries
 416 #
 417 AC_MSG_CHECKING([allow thread-safe client libraries])
 418 if test "$PORTNAME" != "win32"; then
 419 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 420 else
 421 # Win32 should always use threads
 422 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 423 fi
 424
 425 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 426 if test "$enable_thread_safety" = yes -o \
 427         "$enable_thread_safety_force" = yes; then
 428   enable_thread_safety="yes"    # for 'force'
 429   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 430           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 431 fi
 432 AC_MSG_RESULT([$enable_thread_safety])
 433 AC_SUBST(enable_thread_safety)
 434
 435 #
 436 # Optionally build Tcl modules (PL/Tcl)
 437 #
 438 AC_MSG_CHECKING([whether to build with Tcl])
 439 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 440 AC_MSG_RESULT([$with_tcl])
 441 AC_SUBST([with_tcl])
 442
 443 # We see if the path to the Tcl/Tk configuration scripts is specified.
 444 # This will override the use of tclsh to find the paths to search.
 445
 446 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 447
 448 #
 449 # Optionally build Perl modules (PL/Perl)
 450 #
 451 AC_MSG_CHECKING([whether to build Perl modules])
 452 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 453 AC_MSG_RESULT([$with_perl])
 454 AC_SUBST(with_perl)
 455
 456 #
 457 # Optionally build Python modules (PL/Python)
 458 #
 459 AC_MSG_CHECKING([whether to build Python modules])
 460 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 461 AC_MSG_RESULT([$with_python])
 462 AC_SUBST(with_python)
 463
 464 #
 465 # GSSAPI
 466 #
 467 AC_MSG_CHECKING([whether to build with GSSAPI support])
 468 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 469 [
 470   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 471   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 472 ])
 473 AC_MSG_RESULT([$with_gssapi])
 474 AC_SUBST(with_gssapi)
 475
 476 #
 477 # Kerberos 5
 478 #
 479 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 480 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 481 [
 482   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 483   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 484 ])
 485 AC_MSG_RESULT([$with_krb5])
 486 AC_SUBST(with_krb5)
 487
 488
 489 AC_SUBST(krb_srvtab)
 490
 491
 492 #
 493 # Kerberos configuration parameters
 494 #
 495 PGAC_ARG_REQ(with, krb-srvnam,
 496              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 497              [],
 498              [with_krb_srvnam="postgres"])
 499 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 500                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 501
 502
 503 #
 504 # PAM
 505 #
 506 AC_MSG_CHECKING([whether to build with PAM support])
 507 PGAC_ARG_BOOL(with, pam, no,
 508               [  --with-pam              build with PAM support],
 509               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 510 AC_MSG_RESULT([$with_pam])
 511 AC_SUBST(with_pam)
 512
 513
 514 #
 515 # LDAP
 516 #
 517 AC_MSG_CHECKING([whether to build with LDAP support])
 518 PGAC_ARG_BOOL(with, ldap, no,
 519               [  --with-ldap             build with LDAP support],
 520               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 521 AC_MSG_RESULT([$with_ldap])
 522 AC_SUBST(with_ldap)
 523
 524
 525 #
 526 # Bonjour
 527 #
 528 AC_MSG_CHECKING([whether to build with Bonjour support])
 529 PGAC_ARG_BOOL(with, bonjour, no,
 530               [  --with-bonjour          build with Bonjour support],
 531               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 532 AC_MSG_RESULT([$with_bonjour])
 533 AC_SUBST(with_bonjour)
 534
 535
 536 #
 537 # OpenSSL
 538 #
 539 AC_MSG_CHECKING([whether to build with OpenSSL support])
 540 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 541               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 542 AC_MSG_RESULT([$with_openssl])
 543 AC_SUBST(with_openssl)
 544
 545
 546 #
 547 # Readline
 548 #
 549 PGAC_ARG_BOOL(with, readline, yes,
 550               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 551 # readline on MinGW has problems with backslashes in psql and other bugs.
 552 # This is particularly a problem with non-US code pages.
 553 # Therefore disable its use until we understand the cause. 2004-07-20
 554 if test "$PORTNAME" = "win32"; then
 555   if test "$with_readline" = yes; then
 556     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 557     with_readline=no
 558   fi
 559 fi
 560
 561
 562 #
 563 # Prefer libedit
 564 #
 565 PGAC_ARG_BOOL(with, libedit-preferred, no,
 566               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 567
 568
 569 #
 570 # OSSP UUID library
 571 #
 572 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        build with OSSP UUID library for UUID generation])
 573 AC_SUBST(with_ossp_uuid)
 574
 575
 576 #
 577 # XML
 578 #
 579 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 580               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 581
 582 if test "$with_libxml" = yes ; then
 583   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 584   if test -n "$XML2_CONFIG"; then
 585     for pgac_option in `$XML2_CONFIG --cflags`; do
 586       case $pgac_option in
 587         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 588       esac
 589     done
 590     for pgac_option in `$XML2_CONFIG --libs`; do
 591       case $pgac_option in
 592         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 593       esac
 594     done
 595   fi
 596 fi
 597
 598 AC_SUBST(with_libxml)
 599
 600 #
 601 # XSLT
 602 #
 603 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          build with XSLT support],
 604               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to build with XSLT support. (--with-libxslt)])])
 605
 606
 607 AC_SUBST(with_libxslt)
 608
 609 #
 610 # tzdata
 611 #
 612 PGAC_ARG_REQ(with, system-tzdata,
 613              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 614 AC_SUBST(with_system_tzdata)
 615
 616 #
 617 # Zlib
 618 #
 619 PGAC_ARG_BOOL(with, zlib, yes,
 620               [  --without-zlib          do not use Zlib])
 621 AC_SUBST(with_zlib)
 622
 623 #
 624 # Elf
 625 #
 626
 627 # Assume system is ELF if it predefines __ELF__ as 1,
 628 # otherwise believe host_os based default.
 629 case $host_os in
 630     freebsd1*|freebsd2*) elf=no;;
 631     freebsd3*|freebsd4*) elf=yes;;
 632 esac
 633
 634 AC_EGREP_CPP(yes,
 635 [#if __ELF__
 636   yes
 637 #endif
 638 ],
 639 [ELF_SYS=true],
 640 [if test "X$elf" = "Xyes" ; then
 641   ELF_SYS=true
 642 else
 643   ELF_SYS=
 644 fi])
 645 AC_SUBST(ELF_SYS)
 646
 647 #
 648 # Assignments
 649 #
 650
 651 CPPFLAGS="$CPPFLAGS $INCLUDES"
 652 LDFLAGS="$LDFLAGS $LIBDIRS"
 653
 654 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 655 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 656
 657 AC_ARG_VAR(LDFLAGS_SL)
 658
 659 PGAC_PROG_LD
 660 AC_SUBST(LD)
 661 AC_SUBST(with_gnu_ld)
 662 case $host_os in sysv5*)
 663   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 664   [
 665     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 666     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 667     LDFLAGS=$pgac_save_LDFLAGS
 668   ])
 669   ld_R_works=$pgac_cv_prog_ld_R
 670   AC_SUBST(ld_R_works)
 671 esac
 672 AC_PROG_RANLIB
 673 PGAC_CHECK_STRIP
 674
 675 AC_PATH_PROG(TAR, tar)
 676 AC_PROG_LN_S
 677 AC_PROG_AWK
 678
 679 PGAC_PATH_YACC
 680 PGAC_PATH_FLEX
 681
 682 PGAC_PATH_PERL
 683 if test "$with_perl" = yes; then
 684   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 685   PGAC_CHECK_PERL_EMBED_LDFLAGS
 686 fi
 687
 688 if test "$with_python" = yes; then
 689   PGAC_PATH_PYTHON
 690   PGAC_CHECK_PYTHON_EMBED_SETUP
 691 fi
 692
 693 # Supply a numeric version string for use by 3rd party add-ons
 694 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 695 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 696 tr '.' '        ' |
 697 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 698 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 699
 700 ##
 701 ## Libraries
 702 ##
 703 ## Most libraries are included only if they demonstrably provide a function
 704 ## we need, but libm is an exception: always include it, because there are
 705 ## too many compilers that play cute optimization games that will break
 706 ## probes for standard functions such as pow().
 707 ##
 708
 709 AC_CHECK_LIB(m, main)
 710 AC_SEARCH_LIBS(setproctitle, util)
 711 AC_SEARCH_LIBS(dlopen, dl)
 712 AC_SEARCH_LIBS(socket, [socket wsock32])
 713 AC_SEARCH_LIBS(shl_load, dld)
 714 # We only use libld in port/dynloader/aix.c
 715 case $host_os in
 716      aix*)
 717         AC_SEARCH_LIBS(ldopen, ld)
 718         ;;
 719 esac
 720 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 721 AC_SEARCH_LIBS(crypt, crypt)
 722 # Solaris:
 723 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 724 # Cygwin:
 725 AC_SEARCH_LIBS(shmget, cygipc)
 726
 727 if test "$with_readline" = yes; then
 728   PGAC_CHECK_READLINE
 729   if test x"$pgac_cv_check_readline" = x"no"; then
 730     AC_MSG_ERROR([readline library not found
 731 If you have readline already installed, see config.log for details on the
 732 failure.  It is possible the compiler isn't looking in the proper directory.
 733 Use --without-readline to disable readline support.])
 734   fi
 735 fi
 736
 737 if test "$with_zlib" = yes; then
 738   AC_CHECK_LIB(z, inflate, [],
 739                [AC_MSG_ERROR([zlib library not found
 740 If you have zlib already installed, see config.log for details on the
 741 failure.  It is possible the compiler isn't looking in the proper directory.
 742 Use --without-zlib to disable zlib support.])])
 743 fi
 744
 745 if test "$enable_spinlocks" = yes; then
 746   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 747 else
 748   AC_MSG_WARN([
 749 *** Not using spinlocks will cause poor performance.])
 750 fi
 751
 752 if test "$with_gssapi" = yes ; then
 753   if test "$PORTNAME" != "win32"; then
 754     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 755                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 756   else
 757     LIBS="$LIBS -lgssapi32"
 758   fi
 759 fi
 760
 761 if test "$with_krb5" = yes ; then
 762   if test "$PORTNAME" != "win32"; then
 763      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 764                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 765      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 766                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 767   else
 768      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 769                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 770   fi
 771 fi
 772
 773 if test "$with_openssl" = yes ; then
 774   dnl Order matters!
 775   if test "$PORTNAME" != "win32"; then
 776      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 777      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 778   else
 779      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 780      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 781   fi
 782 fi
 783
 784 if test "$with_pam" = yes ; then
 785   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 786 fi
 787
 788 if test "$with_libxml" = yes ; then
 789   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 790 fi
 791
 792 if test "$with_libxslt" = yes ; then
 793   AC_CHECK_LIB(xslt, xsltLibxmlVersion, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 794 fi
 795
 796
 797 ##
 798 ## Header files
 799 ##
 800
 801 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 802 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 803
 804 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 805 # netinet/in.h is included first.
 806 AC_CHECK_HEADERS(netinet/in.h)
 807 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 808 [AC_INCLUDES_DEFAULT
 809 #ifdef HAVE_NETINET_IN_H
 810 #include <netinet/in.h>
 811 #endif
 812 ])
 813
 814 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 815   AC_CHECK_HEADERS(readline/readline.h, [],
 816         [AC_CHECK_HEADERS(readline.h, [],
 817                 [AC_MSG_ERROR([readline header not found
 818 If you have readline already installed, see config.log for details on the
 819 failure.  It is possible the compiler isn't looking in the proper directory.
 820 Use --without-readline to disable readline support.])])])
 821   AC_CHECK_HEADERS(readline/history.h, [],
 822         [AC_CHECK_HEADERS(history.h, [],
 823                 [AC_MSG_ERROR([history header not found
 824 If you have readline already installed, see config.log for details on the
 825 failure.  It is possible the compiler isn't looking in the proper directory.
 826 Use --without-readline to disable readline support.])])])
 827 fi
 828
 829 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 830 # Some installations of libedit usurp /usr/include/readline/, which seems
 831 # bad practice, since in combined installations readline will have its headers
 832 # there.  We might have to resort to AC_EGREP checks to make sure we found
 833 # the proper header...
 834   AC_CHECK_HEADERS(editline/readline.h, [],
 835         [AC_CHECK_HEADERS(readline.h, [],
 836                 [AC_CHECK_HEADERS(readline/readline.h, [],
 837                         [AC_MSG_ERROR([readline header not found
 838 If you have libedit already installed, see config.log for details on the
 839 failure.  It is possible the compiler isn't looking in the proper directory.
 840 Use --without-readline to disable libedit support.])])])])
 841 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 842 # not be there at all.  Hence, don't complain if not found.  We must check
 843 # though, since in yet other versions it is an independent header.
 844   AC_CHECK_HEADERS(editline/history.h, [],
 845         [AC_CHECK_HEADERS(history.h, [],
 846                 [AC_CHECK_HEADERS(readline/history.h)])])
 847 fi
 848
 849 if test "$with_zlib" = yes; then
 850   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 851 If you have zlib already installed, see config.log for details on the
 852 failure.  It is possible the compiler isn't looking in the proper directory.
 853 Use --without-zlib to disable zlib support.])])
 854 fi
 855
 856 if test "$with_gssapi" = yes ; then
 857   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 858         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 859 fi
 860
 861 if test "$with_krb5" = yes ; then
 862   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 863 fi
 864
 865 if test "$with_openssl" = yes ; then
 866   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 867   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 868   AC_CHECK_FUNCS([ERR_set_mark])
 869 fi
 870
 871 if test "$with_pam" = yes ; then
 872   AC_CHECK_HEADERS(security/pam_appl.h, [],
 873                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 874                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 875 fi
 876
 877 if test "$with_libxml" = yes ; then
 878   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 879 fi
 880
 881 if test "$with_libxslt" = yes ; then
 882   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 883 fi
 884
 885 if test "$with_ldap" = yes ; then
 886   if test "$PORTNAME" != "win32"; then
 887      AC_CHECK_HEADERS(ldap.h, [],
 888                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 889   else
 890      AC_CHECK_HEADERS(winldap.h, [],
 891                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 892                       [AC_INCLUDES_DEFAULT
 893 #include <windows.h>
 894                       ])
 895   fi
 896 fi
 897
 898 if test "$with_bonjour" = yes ; then
 899   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 900 fi
 901
 902
 903 ##
 904 ## Types, structures, compiler characteristics
 905 ##
 906
 907 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 908 AC_C_BIGENDIAN
 909 AC_C_CONST
 910 AC_C_INLINE
 911 AC_C_STRINGIZE
 912 PGAC_C_SIGNED
 913 AC_C_VOLATILE
 914 PGAC_C_FUNCNAME_SUPPORT
 915 PGAC_STRUCT_TIMEZONE
 916 PGAC_UNION_SEMUN
 917 PGAC_STRUCT_SOCKADDR_UN
 918 PGAC_STRUCT_SOCKADDR_STORAGE
 919 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 920 PGAC_STRUCT_ADDRINFO
 921
 922 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 923 [#include <sys/param.h>
 924 #include <sys/types.h>
 925 #include <sys/socket.h>
 926 #include <sys/ucred.h>])
 927
 928 AC_CHECK_TYPES([struct option], [], [],
 929 [#ifdef HAVE_GETOPT_H
 930 #include <getopt.h>
 931 #endif])
 932
 933 if test "$with_zlib" = yes; then
 934   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 935   # did not).  While we could work around the lack of z_streamp, it
 936   # seems unwise to encourage people to use such old zlib versions...
 937   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 938 Use --without-zlib to disable zlib support.])],
 939                 [#include <zlib.h>])
 940 fi
 941
 942 if test "$with_krb5" = yes; then
 943 # Check for differences between MIT and Heimdal (KTH) releases
 944   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 945                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 946                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 947                                      [#include <krb5.h>])],
 948                    [#include <krb5.h>])
 949   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 950                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 951                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 952                                      [#include <krb5.h>])],
 953                    [#include <krb5.h>])
 954
 955 # Win32 requires headers to be loaded for __stdcall, so can't use
 956 # AC_CHECK_FUNCS here.
 957   AC_MSG_CHECKING(for krb5_free_unparsed_name)
 958   AC_TRY_LINK([#include <krb5.h>],
 959               [krb5_free_unparsed_name(NULL,NULL);],
 960               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
 961 AC_MSG_RESULT(yes)],
 962               [AC_MSG_RESULT(no)])
 963 fi
 964
 965
 966 ##
 967 ## Functions, global variables
 968 ##
 969
 970 PGAC_VAR_INT_TIMEZONE
 971 AC_FUNC_ACCEPT_ARGTYPES
 972 PGAC_FUNC_GETTIMEOFDAY_1ARG
 973
 974 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 975
 976 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 977 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 978 AC_CHECK_DECLS([strlcat, strlcpy])
 979 # This is probably only present on Darwin, but may as well check always
 980 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 981
 982 HAVE_IPV6=no
 983 AC_CHECK_TYPE([struct sockaddr_in6],
 984         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 985          HAVE_IPV6=yes],
 986         [],
 987 [$ac_includes_default
 988 #include <netinet/in.h>])
 989 AC_SUBST(HAVE_IPV6)
 990
 991 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 992 [AC_TRY_LINK(
 993 [#include <machine/vmparam.h>
 994 #include <sys/exec.h>
 995 ],
 996 [PS_STRINGS->ps_nargvstr = 1;
 997 PS_STRINGS->ps_argvstr = "foo";],
 998 [pgac_cv_var_PS_STRINGS=yes],
 999 [pgac_cv_var_PS_STRINGS=no])])
1000 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1001   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1002 fi
1003
1004
1005 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1006 # is missing.  Yes, there are machines that have only one.  We may
1007 # also decide to use snprintf.c if snprintf() is present but does not
1008 # have all the features we need --- see below.
1009
1010 if test "$PORTNAME" = "win32"; then
1011   # Win32 gets snprintf.c built unconditionally.
1012   #
1013   # To properly translate all NLS languages strings, we must support the
1014   # *printf() %$ format, which allows *printf() arguments to be selected
1015   # by position in the translated string.
1016   #
1017   # libintl versions < 0.13 use the native *printf() functions, and Win32
1018   # *printf() doesn't understand %$, so we must use our /port versions,
1019   # which do understand %$. libintl versions >= 0.13 include their own
1020   # *printf versions on Win32.  The libintl 0.13 release note text is:
1021   #
1022   #   C format strings with positions, as they arise when a translator
1023   #   needs to reorder a sentence, are now supported on all platforms.
1024   #   On those few platforms (NetBSD and Woe32) for which the native
1025   #   printf()/fprintf()/... functions don't support such format
1026   #   strings, replacements are provided through <libintl.h>.
1027   #
1028   # We could use libintl >= 0.13's *printf() if we were sure that we had
1029   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1030   # to guarantee that, it is best to just use our own, so we are sure to
1031   # get %$ support. In include/port.h we disable the *printf() macros
1032   # that might have been defined by libintl.
1033   #
1034   # We do this unconditionally whether NLS is used or not so we are sure
1035   # that all Win32 libraries and binaries behave the same.
1036   pgac_need_repl_snprintf=yes
1037 else
1038   pgac_need_repl_snprintf=no
1039   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1040   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1041 fi
1042
1043
1044 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1045 # include/c.h will provide declarations.  Note this is a separate test
1046 # from whether the functions exist in the C library --- there are
1047 # systems that have the functions but don't bother to declare them :-(
1048
1049 AC_CHECK_DECLS([snprintf, vsnprintf])
1050
1051
1052 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1053 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1054 [AC_TRY_LINK([
1055 #include <math.h>
1056 double glob_double;
1057 ],
1058 [return isinf(glob_double) ? 0 : 1;],
1059 [ac_cv_func_isinf=yes],
1060 [ac_cv_func_isinf=no])])
1061
1062 if test $ac_cv_func_isinf = yes ; then
1063   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1064 else
1065   AC_LIBOBJ(isinf)
1066   # Look for a way to implement a substitute for isinf()
1067   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1068 fi
1069
1070 # Some versions of libedit contain strlcpy(); so disregard that library while
1071 # checking for these standard libc functions.
1072 pgac_save_LIBS="$LIBS"
1073 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1074
1075 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1076
1077 LIBS="$pgac_save_LIBS"
1078
1079 # System's version of getaddrinfo(), if any, may be used only if we found
1080 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1081 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1082 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1083 # because we want to use our own getaddrinfo.c on Windows anyway.)
1084 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1085   AC_REPLACE_FUNCS([getaddrinfo])
1086 else
1087   AC_LIBOBJ(getaddrinfo)
1088 fi
1089
1090 # similarly, use system's getopt_long() only if system provides struct option.
1091 if test x"$ac_cv_type_struct_option" = xyes ; then
1092   AC_REPLACE_FUNCS([getopt_long])
1093 else
1094   AC_LIBOBJ(getopt_long)
1095 fi
1096
1097 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1098 # We override the previous test that said fseeko/ftello didn't exist
1099 # OS tests are also done in include/c.h and port/fseeko.c
1100 case $host_os in bsdi*|netbsd*)
1101 ac_cv_func_fseeko=yes
1102 esac
1103
1104 # Win32 support
1105 if test "$PORTNAME" = "win32"; then
1106 AC_LIBOBJ(gettimeofday)
1107 AC_LIBOBJ(kill)
1108 AC_LIBOBJ(open)
1109 AC_LIBOBJ(rand)
1110 AC_LIBOBJ(win32error)
1111 AC_DEFINE([HAVE_SYMLINK], 1,
1112           [Define to 1 if you have the `symlink' function.])
1113 fi
1114
1115 if test "$with_readline" = yes; then
1116   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1117   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1118   AC_CHECK_FUNCS([replace_history_entry])
1119 fi
1120
1121
1122 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1123 dnl (especially on GNU libc)
1124 dnl See also comments in c.h.
1125 AC_MSG_CHECKING(for sigsetjmp)
1126 AC_TRY_LINK([#include <setjmp.h>],
1127             [sigjmp_buf x; sigsetjmp(x, 1);],
1128             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1129 AC_MSG_RESULT(yes)],
1130             [AC_MSG_RESULT(no)])
1131
1132 AC_DECL_SYS_SIGLIST
1133
1134 AC_CHECK_FUNC(syslog,
1135               [AC_CHECK_HEADER(syslog.h,
1136                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1137
1138 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1139 [AC_TRY_LINK([#include <unistd.h>],
1140   [extern int optreset; optreset = 1;],
1141   [pgac_cv_var_int_optreset=yes],
1142   [pgac_cv_var_int_optreset=no])])
1143 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1144   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1145 fi
1146
1147 AC_CHECK_FUNCS([strtoll strtoq], [break])
1148 AC_CHECK_FUNCS([strtoull strtouq], [break])
1149
1150 # Check for one of atexit() or on_exit()
1151 AC_CHECK_FUNCS(atexit, [],
1152                [AC_CHECK_FUNCS(on_exit, [],
1153                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1154
1155 AC_FUNC_FSEEKO
1156
1157 #
1158 # Pthreads
1159 #
1160 # For each platform, we need to know about any special compile and link
1161 # libraries, and whether the normal C function names are thread-safe.
1162 # See the comment at the top of src/port/thread.c for more information.
1163 # WIN32 doesn't need the pthread tests;  it always uses threads
1164 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1165 ACX_PTHREAD     # set thread flags
1166
1167 # Some platforms use these, so just defineed them.  They can't hurt if they
1168 # are not supported.
1169 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1170
1171
1172 # At this point, we don't want to muck with the compiler name for threading.
1173 # Let's see who fails, perhaps AIX.  2004-04-23
1174 if test "$PTHREAD_CC" != "$CC"; then
1175 AC_MSG_ERROR([
1176 PostgreSQL does not support platforms that require a special compiler
1177 for thread safety.])
1178 fi
1179
1180 if test "$THREAD_SUPPORT" = no; then
1181 AC_MSG_ERROR([cannot enable threads on this platform
1182 This platform is known to not support thread-safe programs.  For details,
1183 compile and run src/bin/pg_thread_test.])
1184 fi
1185
1186 # Check for *_r functions
1187 _CFLAGS="$CFLAGS"
1188 _LIBS="$LIBS"
1189 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1190 LIBS="$LIBS $PTHREAD_LIBS"
1191
1192 if test "$PORTNAME" != "win32"; then
1193 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1194 fi
1195
1196 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1197
1198 # Do test here with the proper thread flags
1199 PGAC_FUNC_GETPWUID_R_5ARG
1200 PGAC_FUNC_STRERROR_R_INT
1201
1202 CFLAGS="$_CFLAGS"
1203 LIBS="$_LIBS"
1204
1205 else
1206 # do not use values from template file
1207 PTHREAD_CFLAGS=
1208 PTHREAD_LIBS=
1209 fi
1210
1211 AC_SUBST(PTHREAD_CFLAGS)
1212 AC_SUBST(PTHREAD_LIBS)
1213
1214
1215 # We can test for libldap_r only after we know PTHREAD_LIBS
1216 if test "$with_ldap" = yes ; then
1217   _LIBS="$LIBS"
1218   if test "$PORTNAME" != "win32"; then
1219     AC_CHECK_LIB(ldap, ldap_bind, [],
1220                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1221                  [$EXTRA_LDAP_LIBS])
1222     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1223     if test "$enable_thread_safety" = yes; then
1224       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1225       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1226                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1227                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1228       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1229     else
1230       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1231     fi
1232   else
1233     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1234     LDAP_LIBS_FE="-lwldap32"
1235     LDAP_LIBS_BE="-lwldap32"
1236   fi
1237   LIBS="$_LIBS"
1238 fi
1239 AC_SUBST(LDAP_LIBS_FE)
1240 AC_SUBST(LDAP_LIBS_BE)
1241
1242
1243 # This test makes sure that run tests work at all.  Sometimes a shared
1244 # library is found by the linker, but the runtime linker can't find it.
1245 # This check should come after all modifications of compiler or linker
1246 # variables, and before any other run tests.
1247 AC_MSG_CHECKING([test program])
1248 AC_TRY_RUN([int main() { return 0; }],
1249 [AC_MSG_RESULT(ok)],
1250 [AC_MSG_RESULT(failed)
1251 AC_MSG_ERROR([[
1252 Could not execute a simple test program.  This may be a problem
1253 related to locating shared libraries.  Check the file 'config.log'
1254 for the exact reason.]])],
1255 [AC_MSG_RESULT([cross-compiling])])
1256
1257 # --------------------
1258 # Run tests below here
1259 # --------------------
1260
1261 # Force use of our snprintf if system's doesn't do arg control
1262 # See comment above at snprintf test for details.
1263 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1264   PGAC_FUNC_PRINTF_ARG_CONTROL
1265   if test $pgac_cv_printf_arg_control != yes ; then
1266     pgac_need_repl_snprintf=yes
1267   fi
1268 fi
1269
1270
1271 dnl Check to see if we have a working 64-bit integer type.
1272 dnl This breaks down into two steps:
1273 dnl (1) figure out if the compiler has a 64-bit int type with working
1274 dnl arithmetic, and if so
1275 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1276 dnl snprintf is the only library routine we really need for int8 support.)
1277 dnl It's entirely possible to have a compiler that handles a 64-bit type
1278 dnl when the C library doesn't; this is fairly likely when using gcc on
1279 dnl an older platform, for example.
1280 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1281 dnl we force our own version of snprintf() to be used instead.
1282 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1283
1284 PGAC_TYPE_64BIT_INT([long int])
1285
1286 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1287   PGAC_TYPE_64BIT_INT([long long int])
1288 fi
1289
1290
1291 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1292
1293 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1294   AC_TRY_COMPILE([
1295 #define INT64CONST(x)  x##LL
1296 long long int foo = INT64CONST(0x1234567890123456);
1297 ],
1298         [],
1299         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1300         [])
1301 fi
1302
1303
1304 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1305 # we found we need to use "long long int", better check.  We cope with
1306 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1307 # work, fall back to our own snprintf emulation (which we know uses %lld).
1308
1309 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1310   if test $pgac_need_repl_snprintf = no; then
1311     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1312     if test "$LONG_LONG_INT_FORMAT" = ""; then
1313       # Force usage of our own snprintf, since system snprintf is broken
1314       pgac_need_repl_snprintf=yes
1315       LONG_LONG_INT_FORMAT='%lld'
1316     fi
1317   else
1318     # Here if we previously decided we needed to use our own snprintf
1319     LONG_LONG_INT_FORMAT='%lld'
1320   fi
1321   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1322   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1323   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1324 else
1325   # Here if we are not using 'long long int' at all
1326   INT64_FORMAT='"%ld"'
1327   UINT64_FORMAT='"%lu"'
1328 fi
1329
1330 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1331                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1332
1333 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1334                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1335
1336 # Now we have checked all the reasons to replace snprintf
1337 if test $pgac_need_repl_snprintf = yes; then
1338   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1339   AC_LIBOBJ(snprintf)
1340 fi
1341
1342 # Need a #define for the size of Datum (unsigned long)
1343 AC_CHECK_SIZEOF([unsigned long])
1344
1345 # And one for the size of size_t (enables tweaks for > 32bit address space)
1346 AC_CHECK_SIZEOF([size_t])
1347
1348 # Determine memory alignment requirements for the basic C data types.
1349
1350 PGAC_CHECK_ALIGNOF(short)
1351 PGAC_CHECK_ALIGNOF(int)
1352 PGAC_CHECK_ALIGNOF(long)
1353 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1354   PGAC_CHECK_ALIGNOF(long long int)
1355 fi
1356 PGAC_CHECK_ALIGNOF(double)
1357
1358 # Compute maximum alignment of any basic type.
1359 # We assume long's alignment is at least as strong as char, short, or int;
1360 # but we must check long long (if it exists) and double.
1361
1362 MAX_ALIGNOF=$pgac_cv_alignof_long
1363 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1364   MAX_ALIGNOF=$pgac_cv_alignof_double
1365 fi
1366 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1367   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1368 fi
1369 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1370
1371
1372 # Some platforms predefine the types int8, int16, etc.  Only check
1373 # a (hopefully) representative subset.
1374 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1375 [#include <stdio.h>
1376 #ifdef HAVE_SUPPORTDEFS_H
1377 #include <SupportDefs.h>
1378 #endif])
1379
1380 # We also check for sig_atomic_t, which *should* be defined per ANSI
1381 # C, but is missing on some old platforms.
1382 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1383
1384
1385 if test "$PORTNAME" != "win32"
1386 then
1387 PGAC_FUNC_POSIX_SIGNALS
1388 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1389   AC_MSG_ERROR([
1390 Thread-safety requires POSIX signals, which are not supported by this
1391 operating system.])
1392 fi
1393 fi
1394
1395 if test $ac_cv_func_fseeko = yes; then
1396 AC_SYS_LARGEFILE
1397 fi
1398
1399 # SunOS doesn't handle negative byte comparisons properly with +/- return
1400 AC_FUNC_MEMCMP
1401
1402
1403 # Select semaphore implementation type.
1404 if test "$PORTNAME" != "win32"; then
1405   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1406     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1407     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1408   else
1409     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1410       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1411       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1412     else
1413       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1414       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1415     fi
1416   fi
1417 else
1418   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1419   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1420 fi
1421
1422
1423 # Select shared-memory implementation type.
1424 if test "$PORTNAME" != "win32"; then
1425   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1426   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1427 else
1428   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1429   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1430 fi
1431
1432 # If not set in template file, set bytes to use libc memset()
1433 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1434   MEMSET_LOOP_LIMIT=1024
1435 fi
1436 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1437
1438
1439 if test "$enable_nls" = yes ; then
1440   PGAC_CHECK_GETTEXT
1441 fi
1442
1443 # Check for Tcl configuration script tclConfig.sh
1444 if test "$with_tcl" = yes; then
1445     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1446     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1447                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1448     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1449     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1450     ac_save_CPPFLAGS=$CPPFLAGS
1451     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1452     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1453     CPPFLAGS=$ac_save_CPPFLAGS
1454 fi
1455
1456 #
1457 # Check for DocBook and tools
1458 #
1459 PGAC_PROG_NSGMLS
1460 PGAC_PROG_JADE
1461 PGAC_CHECK_DOCBOOK(4.2)
1462 PGAC_PATH_DOCBOOK_STYLESHEETS
1463 PGAC_PATH_COLLATEINDEX
1464 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1465
1466 # Thread testing
1467
1468 # We have to run the thread test near the end so we have all our symbols
1469 # defined.  Cross compiling throws a warning.
1470 #
1471 if test "$enable_thread_safety_force" = yes; then
1472 if test "$PORTNAME" != "win32"
1473 then
1474   AC_MSG_WARN([
1475 *** Skipping thread test program.  --enable-thread-safety-force was used.
1476 *** Run the program in src/test/thread on the your machine and add proper
1477 *** locking function calls to your applications to guarantee thread safety.
1478 ])
1479 else
1480 AC_MSG_WARN([*** skipping thread test on Win32])
1481 fi
1482 elif test "$enable_thread_safety" = yes; then
1483 if test "$PORTNAME" != "win32"
1484 then
1485 AC_MSG_CHECKING([thread safety of required library functions])
1486
1487 _CFLAGS="$CFLAGS"
1488 _LIBS="$LIBS"
1489 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1490 LIBS="$LIBS $PTHREAD_LIBS"
1491 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1492   [AC_MSG_RESULT(yes)],
1493   [AC_MSG_RESULT(no)
1494   AC_MSG_ERROR([thread test program failed
1495 This platform is not thread-safe.  Check the file 'config.log'for the
1496 exact reason.
1497
1498 You can use the configure option --enable-thread-safety-force to force
1499 threads to be enabled.  But you must then run the program in
1500 src/test/thread and add locking function calls to your applications to
1501 guarantee thread safety.])],
1502   [AC_MSG_RESULT(maybe)
1503   AC_MSG_WARN([
1504 *** Skipping thread test program because of cross-compile build.
1505 *** Run the program in src/test/thread on the target machine.
1506 ])])
1507 CFLAGS="$_CFLAGS"
1508 LIBS="$_LIBS"
1509 else
1510 AC_MSG_WARN([*** skipping thread test on Win32])
1511 fi
1512 fi
1513
1514 # prepare build tree if outside source tree
1515 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1516 # Note 2: /bin/pwd might be better than shell's built-in at getting
1517 #         a symlink-free name.
1518 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1519   vpath_build=no
1520 else
1521   vpath_build=yes
1522   if test "$no_create" != yes; then
1523     _AS_ECHO_N([preparing build tree... ])
1524     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1525     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1526       || AC_MSG_ERROR(failed)
1527     AC_MSG_RESULT(done)
1528   fi
1529 fi
1530 AC_SUBST(vpath_build)
1531
1532
1533 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1534
1535 AC_CONFIG_LINKS([
1536   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1537   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1538   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1539   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1540   src/include/pg_config_os.h:src/include/port/${template}.h
1541   src/Makefile.port:src/makefiles/Makefile.${template}
1542 ])
1543
1544 if test "$PORTNAME" = "win32"; then
1545 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1546 # Links sometimes fail undetected on Mingw -
1547 # so here we detect it and warn the user
1548 for FILE in $CONFIG_LINKS
1549  do
1550         # test -e works for symlinks in the MinGW console
1551         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1552  done
1553 ])
1554 fi
1555
1556 AC_CONFIG_HEADERS([src/include/pg_config.h],
1557 [
1558 # Update timestamp for pg_config.h (see Makefile.global)
1559 echo >src/include/stamp-h
1560 ])
1561
1562 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1563
1564 AC_OUTPUT
1565
1566 # Warn about unknown options
1567 PGAC_ARG_CHECK