granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225
 226 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 227 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 228    PCRE_CONFIG=$with_pcre/bin/pcre-config
 229 elif test -x "$with_pcre"; then
 230    PCRE_CONFIG=$with_pcre
 231 fi
 232
 233 if test "$PCRE_CONFIG" != "false"; then
 234   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 235     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 236   fi
 237   case `$PCRE_CONFIG --version` in
 238   [[1-5].*])
 239     AC_MSG_ERROR([Need at least pcre version 6.0])
 240     ;;
 241   esac
 242   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 243   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 244   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 245 else
 246   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 247 fi
 248 APACHE_SUBST(PCRE_LIBS)
 249
 250 AC_MSG_NOTICE([])
 251 AC_MSG_NOTICE([Configuring Apache httpd...])
 252 AC_MSG_NOTICE([])
 253
 254 dnl If the source dir is not equal to the build dir,
 255 dnl then we are running in VPATH mode.
 256
 257 APR_ADDTO(INCLUDES, [-I.])
 258
 259 if test "$abs_builddir" != "$abs_srcdir"; then
 260   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 261 fi
 262
 263 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 264
 265 # apr/apr-util --includes may pick up system paths for dependent
 266 # libraries, so ensure these are later in INCLUDES than local source
 267 # directories.
 268 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 269 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 270
 271 dnl Add in path to PCRE includes
 272 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 273
 274 AC_MSG_NOTICE([])
 275 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 276 AC_MSG_NOTICE([])
 277
 278 case $host in
 279   *os2*)
 280       # Use a custom made libtool replacement
 281       echo "using aplibtool"
 282       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 283       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 284       SH_LIBS="\$(ALL_LIBS)"
 285       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 286       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 287       MK_IMPLIB="emximp"
 288       other_targets="$other_targets os2core"
 289       INSTALL_PROG_FLAGS="-e .exe"
 290       SHLTCFLAGS=""
 291       LTCFLAGS=""
 292       ;;
 293   *)
 294       if test "x$LTFLAGS" = "x"; then
 295           LTFLAGS='--silent'
 296       fi
 297       my_libtool=`$apr_config --apr-libtool`
 298       LIBTOOL="$my_libtool \$(LTFLAGS)"
 299       libtoolversion=`$my_libtool --version`
 300       case $libtoolversion in
 301           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 302               SH_LIBTOOL='$(LIBTOOL)'
 303               SHLTCFLAGS="-prefer-pic"
 304               LTCFLAGS="-prefer-non-pic -static"
 305               ;;
 306           *)
 307               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 308               SHLTCFLAGS=""
 309               LTCFLAGS=""
 310               ;;
 311       esac
 312       ;;
 313 esac
 314 APACHE_SUBST(SHLTCFLAGS)
 315 APACHE_SUBST(LTCFLAGS)
 316
 317 case $host in
 318   *-apple-aux3*)
 319       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 320       ;;
 321   *os2-emx*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324   *-linux-*)
 325       AC_CHECK_LIB(systemd-daemon, sd_notify, SYSTEMD_LIBS="-lsystemd-daemon")
 326       AC_CHECK_HEADERS(systemd/sd-daemon.h, [ap_HAVE_SD_DAEMON_H="yes"], [ap_HAVE_SD_DAEMON_H="no"])
 327       if test $ap_HAVE_SD_DAEMON_H = "no" || test -z "${SYSTEMD_LIBS}"; then
 328         AC_MSG_WARN([Your system does not support systemd.])
 329       else
 330         APR_ADDTO(LIBS, $SYSTEMD_LIBS)
 331         APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_SYSTEMD_SUPPORT])
 332       fi
 333
 334       case `uname -r` in
 335         # Unserialized accept() was not recommended until Linux 2.2.
 336         [[01]].* | 2.[[01]]* )
 337             ;;
 338         * )
 339             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 340             ;;
 341       esac
 342       ;;
 343   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 344       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 345       ;;
 346   *-solaris2*)
 347       dnl This is a hack -- we should be using AC_TRY_RUN instead
 348       ap_platform_runtime_link_flag="-R"
 349       dnl solaris 8 and above don't have a thundering herd
 350       dnl not sure about rev's before this one.
 351       case `uname -r` in
 352         5.[567]*)
 353             ;;
 354         * )
 355             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 356             ;;
 357       esac
 358       ;;
 359   *cygwin*)
 360       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 361       ;;
 362   *mingw32*)
 363       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 364       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 365       APR_SETIFNULL(ac_cv_func_times, [no])
 366       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 367       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 368       ;;
 369   *aix*)
 370       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 371       if test $aixver -ge 4320; then
 372         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 373       fi
 374       ;;
 375   *os390*)
 376       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 377       ;;
 378 esac
 379
 380 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 381
 382 dnl
 383 dnl Process command line arguments. This is done early in the process so the
 384 dnl user can get feedback quickly in case of an error.
 385 dnl
 386 dnl ### need to move some of the arguments "up here"
 387
 388 dnl ## Check for programs
 389
 390 AC_PATH_PROG(RM, rm)
 391 AC_PATH_PROG(PKGCONFIG, pkg-config)
 392 AC_PATH_PROG(RSYNC, rsync)
 393 AC_PROG_AWK
 394 AC_PROG_LN_S
 395 AC_CHECK_TOOL(RANLIB, ranlib, true)
 396 dnl AC_PATH_PROG(PERL_PATH, perl)
 397 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 398
 399 # Hard-coded install programs
 400 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 401 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 402 APACHE_SUBST(MKINSTALLDIRS)
 403 APACHE_SUBST(INSTALL)
 404
 405 dnl Various OS checks that apparently set required flags
 406 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 407 AC_USE_SYSTEM_EXTENSIONS
 408 ], [
 409 AC_AIX
 410 AC_MINIX
 411 ])
 412
 413 AC_ISC_POSIX
 414
 415 # Ensure that satisfactory versions of apr and apr-util are
 416 # found if external copies are configured.
 417 if test "${apr_found}" = "yes"; then
 418   # Require at least APR 1.3.x otherwise fail
 419   APACHE_CHECK_APxVER([apr], 1, 3)
 420 fi
 421
 422 if test "${apu_found}" = "yes"; then
 423   # Require at least APR-util 1.3.x otherwise fail
 424   if test "${apr_found}" = "yes"; then
 425     # we need to add the APR includes to CPPFLAGS
 426     apu_ckver_CPPFLAGS="$CPPFLAGS"
 427     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 428     APACHE_CHECK_APxVER([apu], 1, 3)
 429     CPPFLAGS="$apu_ckver_CPPFLAGS"
 430   else
 431     APACHE_CHECK_APxVER([apu], 1, 3)
 432   fi
 433 fi
 434
 435 dnl Check for what we can generate dependency files with
 436 APR_CHECK_DEPEND
 437
 438 dnl ## Check for libraries
 439
 440 dnl ## Check for header files
 441
 442 dnl I think these are just used all over the place, so just check for
 443 dnl them at the base of the tree. If some are specific to a single
 444 dnl directory, they should be moved (Comment #Spoon)
 445
 446 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 447 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 448 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 449
 450 AC_HEADER_STDC
 451 AC_CHECK_HEADERS( \
 452 string.h \
 453 limits.h \
 454 unistd.h \
 455 sys/socket.h \
 456 pwd.h \
 457 grp.h \
 458 strings.h \
 459 sys/prctl.h \
 460 sys/processor.h \
 461 sys/sem.h \
 462 sys/sdt.h \
 463 sys/loadavg.h
 464 )
 465 AC_HEADER_SYS_WAIT
 466
 467 dnl ## Check for typedefs, structures, and compiler characteristics.
 468
 469 AC_C_CONST
 470
 471 dnl ## Check for library functions
 472 dnl ## sqrt() only needed in support/ab.c
 473 saved_LIBS="$LIBS"
 474 LIBS=""
 475 AC_SEARCH_LIBS(sqrt, m)
 476 MATH_LIBS="$LIBS"
 477 APACHE_SUBST(MATH_LIBS)
 478 LIBS="$saved_LIBS"
 479
 480 saved_LIBS="$LIBS"
 481 LIBS=""
 482 AC_SEARCH_LIBS(crypt, crypt)
 483 CRYPT_LIBS="$LIBS"
 484 APACHE_SUBST(CRYPT_LIBS)
 485 LIBS="$saved_LIBS"
 486
 487 dnl See Comment #Spoon
 488
 489 AC_CHECK_FUNCS( \
 490 getpwnam \
 491 getgrnam \
 492 initgroups \
 493 bindprocessor \
 494 prctl \
 495 timegm \
 496 getpgid \
 497 fopen64 \
 498 getloadavg
 499 )
 500
 501 dnl confirm that a void pointer is large enough to store a long integer
 502 APACHE_CHECK_VOID_PTR_LEN
 503
 504 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 505 [AC_TRY_RUN(#define _GNU_SOURCE
 506 #include <unistd.h>
 507 #include <sys/syscall.h>
 508 #include <sys/types.h>
 509 int main(int argc, char **argv) {
 510 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 511 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 512 if test "$ac_cv_gettid" = "yes"; then
 513     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 514 fi
 515
 516 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 517 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 518 [AC_TRY_COMPILE([#include <sys/types.h>
 519 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 520   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 521 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 522     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 523 fi
 524
 525 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 526
 527 case $host in
 528     *aix*)
 529         # for 32-bit builds, increase MAXDATA to allow lots of threads
 530         if test x$OBJECT_MODE != x64; then
 531             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 532         fi
 533         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 534         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 535         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 536         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 537         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 538         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 539         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 540         ;;
 541     *os390*)
 542         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 543         ;;
 544     *)
 545         OS_SPECIFIC_VARS=""
 546 esac
 547
 548 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 549         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 550         [PORT=80])
 551
 552 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 553         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 554         [SSLPORT=443])
 555
 556 DTRACE=true
 557 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 558 [
 559   enable_dtrace=$enableval
 560   if test "$enableval" = "yes"; then
 561     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 562     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 563   fi
 564 ],
 565 [
 566   enable_dtrace=no
 567 ])
 568
 569 dnl Disabled dtrace build for now.
 570 enable_dtrace=no
 571
 572 case $host in
 573   *-solaris2*)
 574     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 575         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 576                   [Enable DTrace probes])
 577         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 578         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 579     fi
 580     ;;
 581 esac
 582
 583 APACHE_SUBST(DTRACE)
 584
 585 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 586 [
 587     if test "$enableval" = "yes"; then
 588         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 589                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 590         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 591     fi
 592 ])dnl
 593
 594 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 595 [
 596     if test "$enableval" = "yes"; then
 597         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 598                   [Allow modules to run hook after a fatal exception])
 599     fi
 600 ])dnl
 601
 602 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 603 [
 604   LOAD_ALL_MODULES=$enableval
 605   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 606 ],
 607 [
 608   LOAD_ALL_MODULES="no"
 609 ])
 610
 611 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 612 [
 613   if test "$enableval" = "yes"; then
 614     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 615     if test "$GCC" = "yes"; then
 616       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 617       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 618       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 619       APACHE_ADD_GCC_CFLAG([-Wformat])
 620       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 621       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 622     elif test "$AIX_XLC" = "yes"; then
 623       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 624     fi
 625     if test "x$enable_load_all_modules" = "x"; then
 626       LOAD_ALL_MODULES=yes
 627       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 628     fi
 629     if test "x$enable_bucketeer" = "x"; then
 630       enable_bucketeer=yes
 631       AC_MSG_NOTICE([Maintainer mode setting "enable_bucketeer" to yes])
 632     fi
 633   fi
 634 ])dnl
 635
 636 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 637 [
 638   if test "$enableval" = "yes"; then
 639     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 640     if test "$GCC" = "yes"; then
 641       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 642       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 643       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 644       APACHE_ADD_GCC_CFLAG([-Wformat])
 645       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 646       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 647     elif test "$AIX_XLC" = "yes"; then
 648       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 649     fi
 650   fi
 651 ])dnl
 652
 653 dnl Conditionally enable PIE support for GNU toolchains.
 654 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 655 if test "$enable_pie" = "yes"; then
 656    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 657      save_CFLAGS=$CFLAGS
 658      save_LDFLAGS=$LDFLAGS
 659      CFLAGS="$CFLAGS -fPIE"
 660      LDFLAGS="$LDFLAGS -pie"
 661      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 662       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 663      CFLAGS=$save_CFLAGS
 664      LDFLAGS=$save_LDFLAGS
 665    ])
 666    if test "$ap_cv_cc_pie" = "yes"; then
 667      PICFLAGS="-fPIE"
 668      PILDFLAGS="-pie"
 669    else
 670      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 671    fi
 672 fi
 673 APACHE_SUBST(PICFLAGS)
 674 APACHE_SUBST(PILDFLAGS)
 675
 676 AC_ARG_WITH(valgrind,
 677   [  --with-valgrind[[=DIR]]   Enable code to reduce valgrind false positives
 678                           (optionally: set path to valgrind headers) ],
 679   [ if test "$withval" != no; then
 680       if test "$withval" = yes; then
 681         withval=/usr/include/valgrind
 682       fi
 683       APR_ADDTO(CPPFLAGS, -I$withval)
 684       AC_CHECK_HEADERS(valgrind.h memcheck.h)
 685       APR_IFALLYES(header:valgrind.h header:memcheck.h,
 686         [AC_DEFINE(HAVE_VALGRIND, 1, [Compile in valgrind support]) ],
 687         [AC_MSG_ERROR(valgrind headers not found) ]
 688       )
 689     fi ]
 690 )
 691
 692 prefix="$orig_prefix"
 693 APACHE_ENABLE_MODULES
 694
 695 dnl reading config stubs
 696 esyscmd(./build/config-stubs .)
 697
 698 APACHE_SUBST(progname)
 699 APACHE_SUBST(OS)
 700 APACHE_SUBST(OS_DIR)
 701 APACHE_SUBST(BUILTIN_LIBS)
 702 APACHE_SUBST(SHLIBPATH_VAR)
 703 APACHE_SUBST(OS_SPECIFIC_VARS)
 704
 705 PRE_SHARED_CMDS='echo ""'
 706 POST_SHARED_CMDS='echo ""'
 707
 708 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 709
 710 if test "$apache_need_shared" = "yes"; then
 711   if test -f $ac_aux_dir/ltconfig; then
 712     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 713   fi
 714   shared_build="shared-build"
 715 fi
 716
 717 dnl enable_so tells us if *any* modules can be built as DSOs
 718
 719 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 720   case $host in
 721     *-ibm-aix*)
 722       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 723       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 724       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 725       ;;
 726     *os390)
 727       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 728       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 729   esac
 730   MOD_SO_ENABLED=yes
 731 fi
 732 AC_SUBST(MOD_SO_ENABLED)
 733
 734 APACHE_SUBST(PRE_SHARED_CMDS)
 735 APACHE_SUBST(POST_SHARED_CMDS)
 736 APACHE_SUBST(shared_build)
 737
 738 AC_ARG_WITH(program-name,
 739 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 740   progname="$withval" ], [
 741   progname="httpd"] )
 742
 743 # SuExec parameters
 744 AC_ARG_WITH(suexec-bin,
 745 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 746   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 747 ] )
 748
 749 AC_ARG_WITH(suexec-caller,
 750 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 751   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 752
 753 AC_ARG_WITH(suexec-userdir,
 754 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 755   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 756
 757 AC_ARG_WITH(suexec-docroot,
 758 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 759   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 760
 761 AC_ARG_WITH(suexec-uidmin,
 762 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 763   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 764
 765 AC_ARG_WITH(suexec-gidmin,
 766 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 767   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 768
 769 AC_ARG_WITH(suexec-logfile,
 770 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 771   if test "x$withval" = "xyes"; then
 772     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 773   elif test "x$withval" != "xno"; then
 774     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 775   fi
 776 ])
 777
 778 AC_ARG_WITH(suexec-syslog,
 779 APACHE_HELP_STRING(--with-suexec-syslog,Set the logfile),[
 780   if test $withval = "yes"; then
 781     if test "x${with_suexec_logfile}" != "xno"; then
 782       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 783       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 784     fi
 785     AC_CHECK_FUNCS([vsyslog], [], [
 786        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 787     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 788   fi
 789 ])
 790
 791
 792 AC_ARG_WITH(suexec-safepath,
 793 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 794   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 795
 796 AC_ARG_WITH(suexec-umask,
 797 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 798   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 799
 800 INSTALL_SUEXEC=setuid
 801 AC_ARG_ENABLE([suexec-capabilities],
 802 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 803   if test "$enableval" = "yes"; then
 804     INSTALL_SUEXEC=caps
 805     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 806               [Enable if suexec is installed with Linux capabilities, not setuid])
 807   fi
 808 ])
 809 APACHE_SUBST(INSTALL_SUEXEC)
 810
 811 dnl APR should go after the other libs, so the right symbols can be picked up
 812 if test x${apu_found} != xobsolete; then
 813   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 814 fi
 815 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 816 APACHE_SUBST(AP_LIBS)
 817 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 818 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 819
 820 AC_DEFINE(AP_USING_AUTOCONF, 1,
 821                 [Using autoconf to configure Apache])
 822
 823 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 824     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 825               [This platform doesn't suffer from the thundering herd problem])
 826 fi
 827
 828 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 829     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 830               [Listening sockets are non-blocking when there are more than 1])
 831 fi
 832
 833 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 834
 835 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 836 [
 837   v4mapped=$enableval
 838 ],
 839 [
 840     case $host in
 841     *freebsd5*|*netbsd*|*openbsd*)
 842         v4mapped=no
 843         ;;
 844     *)
 845         v4mapped=yes
 846         ;;
 847     esac
 848     if ap_mpm_is_enabled winnt; then
 849         dnl WinNT MPM doesn't support this.
 850         v4mapped=no
 851     fi
 852 ])
 853
 854 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 855     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 856               [Allow IPv4 connections on IPv6 listening sockets])
 857 fi
 858
 859 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 860 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 861 APACHE_FAST_OUTPUT(support/Makefile)
 862
 863 if test -d ./test; then
 864     APACHE_FAST_OUTPUT(test/Makefile)
 865 fi
 866
 867 dnl ## Finalize the variables
 868 AC_MSG_NOTICE([])
 869 AC_MSG_NOTICE([Restore user-defined environment settings...])
 870 AC_MSG_NOTICE([])
 871
 872 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 873 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 874 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 875 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 876 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 877 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 878
 879 AC_MSG_NOTICE([])
 880 AC_MSG_NOTICE([Construct makefiles and header files...])
 881 AC_MSG_NOTICE([])
 882
 883 APACHE_GEN_CONFIG_VARS
 884
 885 dnl ## Build modules.c
 886 rm -f modules.c
 887 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 888
 889 APR_EXPAND_VAR(ap_prefix, $prefix)
 890 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 891         [Root directory of the Apache install area])
 892 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 893         [Location of the config file, relative to the Apache root directory])
 894 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 895         [Location of the MIME types config file, relative to the Apache root directory])
 896
 897 perlbin=`$ac_aux_dir/PrintPath perl`
 898 if test "x$perlbin" = "x"; then
 899     perlbin="/replace/with/path/to/perl/interpreter"
 900 fi
 901 AC_SUBST(perlbin)
 902
 903 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 904
 905 BSD_MAKEFILE=no
 906 ap_make_include=include
 907 ap_make_delimiter=' '
 908 case $host in
 909 *bsdi*)
 910     # Check whether they've installed GNU make
 911     if make --version > /dev/null 2>&1; then
 912         true
 913     else
 914         BSD_MAKEFILE=yes
 915         ap_make_include=.include
 916         ap_make_delimiter='"'
 917     fi
 918     ;;
 919 esac
 920 AC_SUBST(ap_make_include)
 921 AC_SUBST(ap_make_delimiter)
 922
 923 dnl Ensure that docs/conf is created.
 924 test -d docs/conf||$mkdir_p docs/conf
 925
 926 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 927   APACHE_GEN_MAKEFILES
 928 ])