granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="$srcdir/srclib/apr/apr-${majorver}-config"
  97     if test -f $test_apr_config; then
  98       apr_config=$test_apr_config
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x${apr_major_version}" = "x2"; then
 119    apu_found=obsolete
 120 elif test "x$with_included_apr" = "xyes"; then
 121    apu_found=reconfig
 122 else
 123    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 124    dnl isn't supported.
 125    ifdef([APR_FIND_APU], [
 126      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 127                   1, ${apr_major_version})
 128    ], [apu_found=no])
 129 fi
 130
 131 if test "$apu_found" = "no"; then
 132   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 133 fi
 134
 135 # Catch some misconfigurations:
 136 case ${apr_found}.${apu_found} in
 137 reconfig.yes)
 138   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 139   ;;
 140 yes.reconfig)
 141   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 142   ;;
 143 esac
 144
 145 if test "$apu_found" = "reconfig"; then
 146   APR_SUBDIR_CONFIG(srclib/apr-util,
 147                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 148                     [--enable-layout=*|\'--enable-layout=*])
 149   dnl We must be the last to build and the first to be cleaned
 150   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 151   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 152   dnl APR and APR-Util major versions must match
 153   apu_config="${srcdir}/srclib/apr-util/apu-${apr_major_version}-config"
 154 fi
 155
 156 if test "$apu_found" = "obsolete"; then
 157   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 158 else
 159   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 160   APU_BINDIR=`$apu_config --bindir`
 161   APU_INCLUDEDIR=`$apu_config --includedir`
 162   APU_INCLUDES=`$apu_config --includes`
 163   APU_VERSION=`$apu_config --version`
 164   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 165 fi
 166
 167 dnl In case we picked up CC and CPP from APR, get that info into the
 168 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 169 dnl PCRE and for our config tests will be whatever PCRE determines.
 170 AC_PROG_CC
 171 AC_PROG_CPP
 172
 173 if test "x${cache_file}" = "x/dev/null"; then
 174   # Likewise, ensure that CC and CPP are passed through to the pcre
 175   # configure script iff caching is disabled (the autoconf 2.5x default).
 176   export CC; export CPP
 177 fi
 178
 179 dnl Absolute source/build directory
 180 abs_srcdir=`(cd $srcdir && pwd)`
 181 abs_builddir=`pwd`
 182
 183 AC_ARG_WITH(pcre,
 184 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 185
 186 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 187 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 188    PCRE_CONFIG=$with_pcre/bin/pcre-config
 189 elif test -x "$with_pcre"; then
 190    PCRE_CONFIG=$with_pcre
 191 fi
 192
 193 if test "$PCRE_CONFIG" != "false"; then
 194   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 195     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 196   fi
 197   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 198   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 199   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 200 else
 201   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 202 fi
 203 APACHE_SUBST(PCRE_LIBS)
 204
 205 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 206 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 207
 208 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 209
 210 dnl If the source dir is not equal to the build dir,
 211 dnl then we are running in VPATH mode.
 212
 213 APR_ADDTO(INCLUDES, [-I.])
 214
 215 if test "$abs_builddir" != "$abs_srcdir"; then
 216   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 217 fi
 218
 219 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 220
 221 # apr/apr-util --includes may pick up system paths for dependent
 222 # libraries, so ensure these are later in INCLUDES than local source
 223 # directories.
 224 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 225 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 226
 227 dnl Add in path to PCRE includes
 228 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 229
 230 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 231
 232 case $host in
 233   *os2*)
 234       # Use a custom made libtool replacement
 235       echo "using aplibtool"
 236       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 237       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 238       SH_LIBS="\$(ALL_LIBS)"
 239       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 240       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 241       MK_IMPLIB="emximp"
 242       other_targets="$other_targets os2core"
 243       INSTALL_PROG_FLAGS="-e .exe"
 244       SHLTCFLAGS=""
 245       LTCFLAGS=""
 246       ;;
 247   *)
 248       if test "x$LTFLAGS" = "x"; then
 249           LTFLAGS='--silent'
 250       fi
 251       my_libtool=`$apr_config --apr-libtool`
 252       LIBTOOL="$my_libtool \$(LTFLAGS)"
 253       libtoolversion=`$my_libtool --version`
 254       case $libtoolversion in
 255           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 256               SH_LIBTOOL='$(LIBTOOL)'
 257               SHLTCFLAGS="-prefer-pic"
 258               LTCFLAGS="-prefer-non-pic -static"
 259               ;;
 260           *)
 261               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 262               SHLTCFLAGS=""
 263               LTCFLAGS=""
 264               ;;
 265       esac
 266       ;;
 267 esac
 268 APACHE_SUBST(SHLTCFLAGS)
 269 APACHE_SUBST(LTCFLAGS)
 270
 271 case $host in
 272   *-apple-aux3*)
 273       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 274       ;;
 275   *os2-emx*)
 276       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 277       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 278       ;;
 279   *-linux-*)
 280       case `uname -r` in
 281         2.[[2-9]]* )
 282             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 283             ;;
 284         * )
 285             ;;
 286       esac
 287       ;;
 288   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 289       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 290       ;;
 291   *-solaris2*)
 292       dnl This is a hack -- we should be using AC_TRY_RUN instead
 293       ap_platform_runtime_link_flag="-R"
 294       dnl solaris 8 and above don't have a thundering herd
 295       dnl not sure about rev's before this one.
 296       case `uname -r` in
 297         5.[567]*)
 298             ;;
 299         * )
 300             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 301             ;;
 302       esac
 303       ;;
 304   *cygwin*)
 305       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 306       ;;
 307   *mingw32*)
 308       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 309       APR_SETIFNULL(ac_cv_func_times, [no])
 310       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 311       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 312       ;;
 313   *aix*)
 314       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 315       if test $aixver -ge 4320; then
 316         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 317       fi
 318       ;;
 319   *os390*)
 320       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 321       ;;
 322 esac
 323
 324 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 325
 326 dnl
 327 dnl Process command line arguments. This is done early in the process so the
 328 dnl user can get feedback quickly in case of an error.
 329 dnl
 330 dnl ### need to move some of the arguments "up here"
 331
 332 dnl ## Check for programs
 333
 334 AC_PATH_PROG(RM, rm)
 335 AC_PATH_PROG(PKGCONFIG, pkg-config)
 336 AC_PATH_PROG(RSYNC, rsync)
 337 AC_PROG_AWK
 338 AC_PROG_LN_S
 339 AC_CHECK_TOOL(RANLIB, ranlib, true)
 340 dnl AC_PATH_PROG(PERL_PATH, perl)
 341 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 342
 343 # Hard-coded install programs
 344 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 345 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 346 APACHE_SUBST(MKINSTALLDIRS)
 347 APACHE_SUBST(INSTALL)
 348
 349 dnl Various OS checks that apparently set required flags
 350 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 351 AC_USE_SYSTEM_EXTENSIONS
 352 ], [
 353 AC_AIX
 354 AC_MINIX
 355 ])
 356
 357 AC_ISC_POSIX
 358
 359 # Ensure that satisfactory versions of apr and apr-util are
 360 # found if external copies are configured.
 361 if test "${apr_found}" = "yes"; then
 362   # Require at least APR 1.3.x otherwise fail
 363   APACHE_CHECK_APxVER([apr], 1, 3)
 364 fi
 365
 366 if test "${apu_found}" = "yes"; then
 367   # Require at least APR-util 1.3.x otherwise fail
 368   APACHE_CHECK_APxVER([apu], 1, 3)
 369 fi
 370
 371 dnl Check for what we can generate dependency files with
 372 APR_CHECK_DEPEND
 373
 374 dnl ## Check for libraries
 375
 376 dnl ## Check for header files
 377
 378 dnl I think these are just used all over the place, so just check for
 379 dnl them at the base of the tree. If some are specific to a single
 380 dnl directory, they should be moved (Comment #Spoon)
 381
 382 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 383 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 384 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 385
 386 AC_HEADER_STDC
 387 AC_CHECK_HEADERS( \
 388 string.h \
 389 limits.h \
 390 unistd.h \
 391 sys/socket.h \
 392 pwd.h \
 393 grp.h \
 394 strings.h \
 395 sys/prctl.h \
 396 sys/processor.h \
 397 sys/sem.h \
 398 sys/sdt.h
 399 )
 400 AC_HEADER_SYS_WAIT
 401
 402 dnl ## Check for typedefs, structures, and compiler characteristics.
 403
 404 AC_C_CONST
 405
 406 dnl ## Check for library functions
 407 dnl ## sqrt() only needed in support/ab.c
 408 saved_LIBS="$LIBS"
 409 LIBS=""
 410 AC_SEARCH_LIBS(sqrt, m)
 411 MATH_LIBS="$LIBS"
 412 APACHE_SUBST(MATH_LIBS)
 413 LIBS="$saved_LIBS"
 414
 415 dnl See Comment #Spoon
 416
 417 AC_CHECK_FUNCS( \
 418 getpwnam \
 419 getgrnam \
 420 initgroups \
 421 bindprocessor \
 422 prctl \
 423 timegm \
 424 getpgid
 425 )
 426
 427 dnl confirm that a void pointer is large enough to store a long integer
 428 APACHE_CHECK_VOID_PTR_LEN
 429
 430 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 431 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 432 [AC_TRY_COMPILE([#include <sys/types.h>
 433 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 434   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 435 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 436     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 437 fi
 438
 439 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 440
 441 case $host in
 442     *aix*)
 443         # for 32-bit builds, increase MAXDATA to allow lots of threads
 444         if test x$OBJECT_MODE != x64; then
 445             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 446         fi
 447         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 448         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 449         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 450         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 451         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 452         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 453         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 454         ;;
 455     *os390*)
 456         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 457         ;;
 458     *)
 459         OS_SPECIFIC_VARS=""
 460 esac
 461
 462 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 463         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 464         [PORT=80])
 465
 466 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 467         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 468         [SSLPORT=443])
 469
 470 DTRACE=true
 471 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 472 [
 473   enable_dtrace=$enableval
 474   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 475   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 476 ],
 477 [
 478   enable_dtrace=no
 479 ])
 480
 481 dnl Disabled dtrace build for now.
 482 enable_dtrace=no
 483
 484 case $host in
 485   *-solaris2*)
 486     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 487         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 488                   [Enable DTrace probes])
 489         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 490         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 491     fi
 492     ;;
 493 esac
 494
 495 APACHE_SUBST(DTRACE)
 496
 497 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 498
 499 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 500 [
 501   v4mapped=$enableval
 502 ],
 503 [
 504     case $host in
 505     *freebsd5*|*netbsd*|*openbsd*)
 506         v4mapped=no
 507         ;;
 508     *)
 509         v4mapped=yes
 510         ;;
 511 esac
 512 ])
 513
 514 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 515     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 516               [Allow IPv4 connections on IPv6 listening sockets])
 517 fi
 518
 519 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 520 [
 521     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 522               [Allow modules to run hook after a fatal exception])
 523 ])dnl
 524
 525 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 526 [
 527   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 528   if test "$GCC" = "yes"; then
 529     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations])
 530   elif test "$AIX_XLC" = "yes"; then
 531     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 532   fi
 533 ])dnl
 534
 535 dnl Conditionally enable PIE support for GNU toolchains.
 536 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 537 if test "$enable_pie" = "yes"; then
 538    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 539      save_CFLAGS=$CFLAGS
 540      save_LDFLAGS=$LDFLAGS
 541      CFLAGS="$CFLAGS -fPIE"
 542      LDFLAGS="$LDFLAGS -pie"
 543      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 544       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 545      CFLAGS=$save_CFLAGS
 546      LDFLAGS=$save_LDFLAGS
 547    ])
 548    if test "$ap_cv_cc_pie" = "yes"; then
 549      PICFLAGS="-fPIE"
 550      PILDFLAGS="-pie"
 551    else
 552      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 553    fi
 554 fi
 555 AC_SUBST(PICFLAGS)
 556 AC_SUBST(PILDFLAGS)
 557
 558 prefix="$orig_prefix"
 559 APACHE_ENABLE_MODULES
 560
 561 dnl reading config stubs
 562 esyscmd(./build/config-stubs .)
 563
 564 APACHE_SUBST(progname)
 565 APACHE_SUBST(OS)
 566 APACHE_SUBST(OS_DIR)
 567 APACHE_SUBST(BUILTIN_LIBS)
 568 APACHE_SUBST(SHLIBPATH_VAR)
 569 APACHE_SUBST(OS_SPECIFIC_VARS)
 570
 571 PRE_SHARED_CMDS='echo ""'
 572 POST_SHARED_CMDS='echo ""'
 573
 574 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 575
 576 if test "$apache_need_shared" = "yes"; then
 577   if test -f $ac_aux_dir/ltconfig; then
 578     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 579   fi
 580   shared_build="shared-build"
 581 fi
 582
 583 dnl enable_so tells us if *any* modules can be built as DSOs
 584
 585 if test "$enable_so" = "yes"; then
 586   case $host in
 587     *-ibm-aix*)
 588       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 589       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 590       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 591       ;;
 592     *os390)
 593       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 594       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 595   esac
 596   MOD_SO_ENABLED=yes
 597 fi
 598 AC_SUBST(MOD_SO_ENABLED)
 599
 600 APACHE_SUBST(PRE_SHARED_CMDS)
 601 APACHE_SUBST(POST_SHARED_CMDS)
 602 APACHE_SUBST(shared_build)
 603
 604 AC_ARG_WITH(program-name,
 605 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 606   progname="$withval" ], [
 607   progname="httpd"] )
 608
 609 # SuExec parameters
 610 AC_ARG_WITH(suexec-bin,
 611 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 612   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 613 ] )
 614
 615 AC_ARG_WITH(suexec-caller,
 616 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 617   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 618
 619 AC_ARG_WITH(suexec-userdir,
 620 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 621   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 622
 623 AC_ARG_WITH(suexec-docroot,
 624 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 625   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 626
 627 AC_ARG_WITH(suexec-uidmin,
 628 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 629   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 630
 631 AC_ARG_WITH(suexec-gidmin,
 632 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 633   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 634
 635 AC_ARG_WITH(suexec-logfile,
 636 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 637   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 638
 639 AC_ARG_WITH(suexec-safepath,
 640 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 641   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 642
 643 AC_ARG_WITH(suexec-umask,
 644 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 645   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 646
 647 dnl APR should go after the other libs, so the right symbols can be picked up
 648 if test x${apu_found} != xobsolete; then
 649   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 650 fi
 651 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 652 APACHE_SUBST(AP_LIBS)
 653 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 654 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 655
 656 AC_DEFINE(AP_USING_AUTOCONF, 1,
 657                 [Using autoconf to configure Apache])
 658
 659 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 660     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 661               [This platform doesn't suffer from the thundering herd problem])
 662 fi
 663
 664 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 665     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 666               [Listening sockets are non-blocking when there are more than 1])
 667 fi
 668
 669
 670 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 671 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 672 APACHE_FAST_OUTPUT(support/Makefile)
 673
 674 if test -d ./test; then
 675     APACHE_FAST_OUTPUT(test/Makefile)
 676 fi
 677
 678 dnl ## Finalize the variables
 679 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 680
 681 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 682 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 683 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 684 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 685 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 686 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 687
 688 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 689
 690 APACHE_GEN_CONFIG_VARS
 691
 692 dnl ## Build modules.c
 693 rm -f modules.c
 694 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 695
 696 APR_EXPAND_VAR(ap_prefix, $prefix)
 697 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 698         [Root directory of the Apache install area])
 699 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 700         [Location of the config file, relative to the Apache root directory])
 701 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 702         [Location of the MIME types config file, relative to the Apache root directory])
 703
 704 perlbin=`$ac_aux_dir/PrintPath perl`
 705 if test "x$perlbin" = "x"; then
 706     perlbin="/replace/with/path/to/perl/interpreter"
 707 fi
 708 AC_SUBST(perlbin)
 709
 710 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 711
 712 BSD_MAKEFILE=no
 713 ap_make_include=include
 714 ap_make_delimiter=' '
 715 case $host in
 716 *bsdi*)
 717     # Check whether they've installed GNU make
 718     if make --version > /dev/null 2>&1; then
 719         true
 720     else
 721         BSD_MAKEFILE=yes
 722         ap_make_include=.include
 723         ap_make_delimiter='"'
 724     fi
 725     ;;
 726 esac
 727 AC_SUBST(ap_make_include)
 728 AC_SUBST(ap_make_delimiter)
 729
 730 dnl Ensure that docs/conf is created.
 731 test -d docs/conf||$mkdir_p docs/conf
 732
 733 dnl Ensure that the httpd version is included
 734 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 735 AC_SUBST(HTTPD_VERSION)
 736
 737 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 738   APACHE_GEN_MAKEFILES
 739 ])