granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.448 2006/02/10 11:35:47 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2005, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # C compiler
 210 #
 211
 212 # For historical reasons you can also use --with-CC to specify the C compiler
 213 # to use, although the standard way to do this is to set the CC environment
 214 # variable.
 215 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 216
 217 case $template in
 218   aix) pgac_cc_list="gcc xlc";;
 219  irix) pgac_cc_list="cc";; # no gcc
 220     *) pgac_cc_list="gcc cc";;
 221 esac
 222
 223 AC_PROG_CC([$pgac_cc_list])
 224
 225 unset CFLAGS
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # CFLAGS are selected so:
 233 # If the user specifies something in the environment, that is used.
 234 # else:  If the template file set something, that is used.
 235 # else:  If the compiler is GCC, then we use -O2.
 236 # else:  If the compiler is something else, then we use -0.
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 elif test "${CFLAGS+set}" = set; then
 241   : # (keep what template set)
 242 elif test "$GCC" = yes; then
 243   CFLAGS="-O2"
 244 else
 245   # if the user selected debug mode, don't use -O
 246   if test "$enable_debug" != yes; then
 247     CFLAGS="-O"
 248   fi
 249 fi
 250
 251 if test "$GCC" = yes; then
 252   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 253
 254   # Some versions of GCC support some additional useful warning flags.
 255   # Check whether they are supported, and add them to CFLAGS if so.
 256   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 257   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 258
 259   # Disable strict-aliasing rules; needed for gcc 3.3+
 260   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 261 fi
 262
 263 # supply -g if --enable-debug
 264 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 265   CFLAGS="$CFLAGS -g"
 266 fi
 267
 268 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 269
 270 # We already have this in Makefile.win32, but configure needs it too
 271 if test "$PORTNAME" = "win32"; then
 272   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 273 fi
 274
 275 # Check if the compiler still works with the template settings
 276 AC_MSG_CHECKING([whether the C compiler still works])
 277 AC_TRY_LINK([], [return 0;],
 278   [AC_MSG_RESULT(yes)],
 279   [AC_MSG_RESULT(no)
 280    AC_MSG_ERROR([cannot proceed])])
 281
 282 # Defend against gcc -ffast-math
 283 if test "$GCC" = yes; then
 284 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 285 choke me
 286 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 287 fi
 288
 289 AC_PROG_CPP
 290 AC_SUBST(GCC)
 291
 292 # Create compiler version string
 293 if test x"$GCC" = x"yes" ; then
 294   cc_string="GCC `${CC} --version | sed q`"
 295 else
 296   cc_string=$CC
 297 fi
 298 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 299                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 300                    [A string containing the version number, platform, and C compiler])
 301
 302
 303 #
 304 # Set up TAS assembly code if needed; the template file has now had its
 305 # chance to request this.
 306 #
 307 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 308
 309 if test "$need_tas" = yes ; then
 310   TAS=tas.o
 311 else
 312   TAS=""
 313 fi
 314 AC_SUBST(TAS)
 315
 316
 317 #
 318 # Automatic dependency tracking
 319 #
 320 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 321               [autodepend=yes])
 322 AC_SUBST(autodepend)
 323
 324
 325 #
 326 # Enable assert checks
 327 #
 328 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 329               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 330                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 331
 332
 333 #
 334 # Include directories
 335 #
 336 ac_save_IFS=$IFS
 337 IFS="${IFS}${PATH_SEPARATOR}"
 338 # SRCH_INC comes from the template file
 339 for dir in $with_includes $SRCH_INC; do
 340   if test -d "$dir"; then
 341     INCLUDES="$INCLUDES -I$dir"
 342   else
 343     AC_MSG_WARN([*** Include directory $dir does not exist.])
 344   fi
 345 done
 346 IFS=$ac_save_IFS
 347 AC_SUBST(INCLUDES)
 348
 349
 350 #
 351 # Library directories
 352 #
 353 ac_save_IFS=$IFS
 354 IFS="${IFS}${PATH_SEPARATOR}"
 355 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 356 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 357   if test -d "$dir"; then
 358     LIBDIRS="$LIBDIRS -L$dir"
 359   else
 360     AC_MSG_WARN([*** Library directory $dir does not exist.])
 361   fi
 362 done
 363 IFS=$ac_save_IFS
 364
 365 #
 366 # Enable thread-safe client libraries
 367 #
 368 AC_MSG_CHECKING([allow thread-safe client libraries])
 369 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 370 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 371 if test "$enable_thread_safety" = yes -o \
 372         "$enable_thread_safety_force" = yes; then
 373   enable_thread_safety="yes"    # for 'force'
 374   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 375           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 376 fi
 377 AC_MSG_RESULT([$enable_thread_safety])
 378 AC_SUBST(enable_thread_safety)
 379
 380 #
 381 # Optionally build Tcl modules (PL/Tcl)
 382 #
 383 AC_MSG_CHECKING([whether to build with Tcl])
 384 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 385 AC_MSG_RESULT([$with_tcl])
 386 AC_SUBST([with_tcl])
 387
 388 # We see if the path to the Tcl/Tk configuration scripts is specified.
 389 # This will override the use of tclsh to find the paths to search.
 390
 391 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 392
 393 #
 394 # Optionally build Perl modules (PL/Perl)
 395 #
 396 AC_MSG_CHECKING([whether to build Perl modules])
 397 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 398 AC_MSG_RESULT([$with_perl])
 399 AC_SUBST(with_perl)
 400
 401 #
 402 # Optionally build Python modules (PL/Python)
 403 #
 404 AC_MSG_CHECKING([whether to build Python modules])
 405 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 406 AC_MSG_RESULT([$with_python])
 407 AC_SUBST(with_python)
 408
 409 #
 410 # Kerberos 5
 411 #
 412 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 413 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 414 [
 415   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 416   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 417 ])
 418 AC_MSG_RESULT([$with_krb5])
 419 AC_SUBST(with_krb5)
 420
 421
 422 AC_SUBST(krb_srvtab)
 423
 424
 425 #
 426 # Kerberos configuration parameters
 427 #
 428 PGAC_ARG_REQ(with, krb-srvnam,
 429              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 430              [],
 431              [with_krb_srvnam="postgres"])
 432 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 433                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 434
 435
 436 #
 437 # PAM
 438 #
 439 AC_MSG_CHECKING([whether to build with PAM support])
 440 PGAC_ARG_BOOL(with, pam, no,
 441               [  --with-pam              build with PAM support],
 442               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 443 AC_MSG_RESULT([$with_pam])
 444 AC_SUBST(with_pam)
 445
 446
 447 #
 448 # Bonjour
 449 #
 450 AC_MSG_CHECKING([whether to build with Bonjour support])
 451 PGAC_ARG_BOOL(with, bonjour, no,
 452               [  --with-bonjour          build with Bonjour support],
 453               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 454 AC_MSG_RESULT([$with_bonjour])
 455 AC_SUBST(with_bonjour)
 456
 457
 458 #
 459 # OpenSSL
 460 #
 461 AC_MSG_CHECKING([whether to build with OpenSSL support])
 462 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 463               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 464 AC_MSG_RESULT([$with_openssl])
 465 AC_SUBST(with_openssl)
 466
 467
 468 #
 469 # Prefer libedit
 470 #
 471 PGAC_ARG_BOOL(with, libedit-preferred, no,
 472               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 473
 474
 475 #
 476 # Readline
 477 #
 478 PGAC_ARG_BOOL(with, readline, yes,
 479               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 480 # readline on MinGW has problems with backslashes in psql and other bugs.
 481 # This is particularly a problem with non-US code pages.
 482 # Therefore disable its use until we understand the cause. 2004-07-20
 483 if test "$PORTNAME" = "win32"; then
 484   if test "$with_readline" = yes; then
 485     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 486     with_readline=no
 487   fi
 488 fi
 489
 490
 491 #
 492 # Zlib
 493 #
 494 PGAC_ARG_BOOL(with, zlib, yes,
 495               [  --without-zlib          do not use Zlib])
 496 AC_SUBST(with_zlib)
 497
 498 #
 499 # Elf
 500 #
 501
 502 # Assume system is ELF if it predefines __ELF__ as 1,
 503 # otherwise believe host_os based default.
 504 case $host_os in
 505     freebsd1*|freebsd2*) elf=no;;
 506     freebsd3*|freebsd4*) elf=yes;;
 507 esac
 508
 509 AC_EGREP_CPP(yes,
 510 [#if __ELF__
 511   yes
 512 #endif
 513 ],
 514 [ELF_SYS=true],
 515 [if test "X$elf" = "Xyes" ; then
 516   ELF_SYS=true
 517 else
 518   ELF_SYS=
 519 fi])
 520 AC_SUBST(ELF_SYS)
 521
 522 #
 523 # Assignments
 524 #
 525
 526 CPPFLAGS="$CPPFLAGS $INCLUDES"
 527 LDFLAGS="$LDFLAGS $LIBDIRS"
 528
 529 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 530 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 531
 532 AC_ARG_VAR(LDFLAGS_SL)
 533
 534 AC_PROG_AWK
 535 PGAC_PATH_FLEX
 536 AC_PROG_LN_S
 537 PGAC_PROG_LD
 538 AC_SUBST(LD)
 539 AC_SUBST(with_gnu_ld)
 540 case $host_os in sysv5*)
 541   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 542   [
 543     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 544     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 545     LDFLAGS=$pgac_save_LDFLAGS
 546   ])
 547   ld_R_works=$pgac_cv_prog_ld_R
 548   AC_SUBST(ld_R_works)
 549 esac
 550 AC_PROG_RANLIB
 551 AC_CHECK_PROGS(LORDER, lorder)
 552 AC_PATH_PROG(TAR, tar)
 553 PGAC_CHECK_STRIP
 554
 555 AC_CHECK_PROGS(YACC, ['bison -y'])
 556
 557 if test "$YACC"; then
 558   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 559     AC_MSG_WARN([
 560 *** If you are going to modify the grammar files or build from CVS, the installed
 561 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 562   fi
 563 fi
 564
 565 if test -z "$YACC"; then
 566   AC_MSG_WARN([
 567 *** Without Bison you will not be able to build PostgreSQL from CVS or
 568 *** change any of the parser definition files.  You can obtain Bison from
 569 *** a GNU mirror site.  (If you are using the official distribution of
 570 *** PostgreSQL then you do not need to worry about this because the Bison
 571 *** output is pre-generated.)  To use a different yacc program (possible,
 572 *** but not recommended), set the environment variable YACC before running
 573 *** 'configure'.])
 574 fi
 575 AC_SUBST(YFLAGS)
 576
 577 PGAC_PATH_PERL
 578 if test "$with_perl" = yes; then
 579   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 580   PGAC_CHECK_PERL_EMBED_LDFLAGS
 581 fi
 582
 583 if test "$with_python" = yes; then
 584   PGAC_PATH_PYTHON
 585   PGAC_CHECK_PYTHON_EMBED_SETUP
 586 fi
 587
 588
 589 ##
 590 ## Libraries
 591 ##
 592
 593 AC_SEARCH_LIBS(setproctitle, util)
 594 AC_SEARCH_LIBS(pow, m)
 595 AC_SEARCH_LIBS(dlopen, dl)
 596 AC_SEARCH_LIBS(socket, [socket wsock32])
 597 AC_SEARCH_LIBS(shl_load, dld)
 598 AC_SEARCH_LIBS(ldopen, ld)
 599 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 600 AC_SEARCH_LIBS(crypt, crypt)
 601 # Solaris:
 602 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 603 # Cygwin:
 604 AC_SEARCH_LIBS(shmget, cygipc)
 605
 606 if test "$with_readline" = yes; then
 607   PGAC_CHECK_READLINE
 608   if test x"$pgac_cv_check_readline" = x"no"; then
 609     AC_MSG_ERROR([readline library not found
 610 If you have readline already installed, see config.log for details on the
 611 failure.  It is possible the compiler isn't looking in the proper directory.
 612 Use --without-readline to disable readline support.])
 613   fi
 614 fi
 615
 616 if test "$with_zlib" = yes; then
 617   AC_CHECK_LIB(z, inflate, [],
 618                [AC_MSG_ERROR([zlib library not found
 619 If you have zlib already installed, see config.log for details on the
 620 failure.  It is possible the compiler isn't looking in the proper directory.
 621 Use --without-zlib to disable zlib support.])])
 622 fi
 623
 624 if test "$enable_spinlocks" = yes; then
 625   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 626 else
 627   AC_MSG_WARN([
 628 *** Not using spinlocks will cause poor performance.])
 629 fi
 630
 631 if test "$with_krb5" = yes ; then
 632   if test "$PORTNAME" != "win32"; then
 633      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 634                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 635      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 636                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 637      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 638                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 639   else
 640      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 641                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 642   fi
 643 fi
 644
 645 if test "$with_openssl" = yes ; then
 646   dnl Order matters!
 647   if test "$PORTNAME" != "win32"; then
 648      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 649      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 650   else
 651      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 652      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 653   fi
 654 fi
 655
 656 if test "$with_pam" = yes ; then
 657   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 658 fi
 659
 660
 661 ##
 662 ## Header files
 663 ##
 664
 665 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 666 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 667
 668 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 669 # netinet/in.h is included first.
 670 AC_CHECK_HEADERS(netinet/in.h)
 671 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 672 [AC_INCLUDES_DEFAULT
 673 #ifdef HAVE_NETINET_IN_H
 674 #include <netinet/in.h>
 675 #endif
 676 ])
 677
 678 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 679   AC_CHECK_HEADERS(readline/readline.h, [],
 680         [AC_CHECK_HEADERS(readline.h, [],
 681                 [AC_MSG_ERROR([readline header not found
 682 If you have readline already installed, see config.log for details on the
 683 failure.  It is possible the compiler isn't looking in the proper directory.
 684 Use --without-readline to disable readline support.])])])
 685   AC_CHECK_HEADERS(readline/history.h, [],
 686         [AC_CHECK_HEADERS(history.h, [],
 687                 [AC_MSG_ERROR([history header not found
 688 If you have readline already installed, see config.log for details on the
 689 failure.  It is possible the compiler isn't looking in the proper directory.
 690 Use --without-readline to disable readline support.])])])
 691 fi
 692
 693 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 694 # Some installations of libedit usurp /usr/include/readline/, which seems
 695 # bad practice, since in combined installations readline will have its headers
 696 # there.  We might have to resort to AC_EGREP checks to make sure we found
 697 # the proper header...
 698   AC_CHECK_HEADERS(editline/readline.h, [],
 699         [AC_CHECK_HEADERS(readline.h, [],
 700                 [AC_CHECK_HEADERS(readline/readline.h, [],
 701                         [AC_MSG_ERROR([readline header not found
 702 If you have libedit already installed, see config.log for details on the
 703 failure.  It is possible the compiler isn't looking in the proper directory.
 704 Use --without-readline to disable libedit support.])])])])
 705   AC_CHECK_HEADERS(editline/history.h, [],
 706         [AC_CHECK_HEADERS(history.h, [],
 707                 [AC_CHECK_HEADERS(readline/history.h, [],
 708                         [AC_MSG_ERROR([history header not found
 709 If you have libedit already installed, see config.log for details on the
 710 failure.  It is possible the compiler isn't looking in the proper directory.
 711 Use --without-readline to disable libedit support.])])])])
 712 fi
 713
 714 if test "$with_zlib" = yes; then
 715   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 716 If you have zlib already installed, see config.log for details on the
 717 failure.  It is possible the compiler isn't looking in the proper directory.
 718 Use --without-zlib to disable zlib support.])])
 719 fi
 720
 721 if test "$with_krb5" = yes ; then
 722   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 723 fi
 724
 725 if test "$with_openssl" = yes ; then
 726   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 727   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 728 fi
 729
 730 if test "$with_pam" = yes ; then
 731   AC_CHECK_HEADERS(security/pam_appl.h, [],
 732                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 733                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 734 fi
 735
 736 if test "$with_bonjour" = yes ; then
 737   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 738 fi
 739
 740
 741 ##
 742 ## Types, structures, compiler characteristics
 743 ##
 744
 745 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 746 AC_C_CONST
 747 AC_C_INLINE
 748 AC_C_STRINGIZE
 749 PGAC_C_SIGNED
 750 AC_C_VOLATILE
 751 PGAC_C_FUNCNAME_SUPPORT
 752 PGAC_STRUCT_TIMEZONE
 753 PGAC_UNION_SEMUN
 754 PGAC_STRUCT_SOCKADDR_UN
 755 PGAC_STRUCT_SOCKADDR_STORAGE
 756 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 757 PGAC_STRUCT_ADDRINFO
 758
 759 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 760 [#include <sys/param.h>
 761 #include <sys/types.h>
 762 #include <sys/socket.h>
 763 #include <sys/ucred.h>])
 764
 765 AC_CHECK_TYPES([struct option], [], [],
 766 [#ifdef HAVE_GETOPT_H
 767 #include <getopt.h>
 768 #endif])
 769
 770 if test "$with_zlib" = yes; then
 771   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 772   # did not).  While we could work around the lack of z_streamp, it
 773   # seems unwise to encourage people to use such old zlib versions...
 774   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 775 Use --without-zlib to disable zlib support.])],
 776                 [#include <zlib.h>])
 777 fi
 778
 779 if test "$with_krb5" = yes; then
 780 # Check for differences between MIT and Heimdal (KTH) releases
 781   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 782                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 783                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 784                                      [#include <krb5.h>])],
 785                    [#include <krb5.h>])
 786   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 787                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 788                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 789                                      [#include <krb5.h>])],
 790                    [#include <krb5.h>])
 791 fi
 792
 793 # This is probably only present on Darwin, but may as well check always
 794 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 795
 796 ##
 797 ## Functions, global variables
 798 ##
 799
 800 PGAC_VAR_INT_TIMEZONE
 801 AC_FUNC_ACCEPT_ARGTYPES
 802 PGAC_FUNC_GETTIMEOFDAY_1ARG
 803
 804 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 805
 806 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 807
 808 HAVE_IPV6=no
 809 AC_CHECK_TYPE([struct sockaddr_in6],
 810         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 811          HAVE_IPV6=yes],
 812         [],
 813 [$ac_includes_default
 814 #include <netinet/in.h>])
 815 AC_SUBST(HAVE_IPV6)
 816
 817 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 818 [AC_TRY_LINK(
 819 [#include <machine/vmparam.h>
 820 #include <sys/exec.h>
 821 ],
 822 [PS_STRINGS->ps_nargvstr = 1;
 823 PS_STRINGS->ps_argvstr = "foo";],
 824 [pgac_cv_var_PS_STRINGS=yes],
 825 [pgac_cv_var_PS_STRINGS=no])])
 826 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 827   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 828 fi
 829
 830
 831 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 832 # is missing.  Yes, there are machines that have only one.  We may
 833 # also decide to use snprintf.c if snprintf() is present but does not
 834 # have all the features we need --- see below.
 835
 836 if test "$PORTNAME" = "win32"; then
 837   # Win32 gets snprintf.c built unconditionally.
 838   #
 839   # To properly translate all NLS languages strings, we must support the
 840   # *printf() %$ format, which allows *printf() arguments to be selected
 841   # by position in the translated string.
 842   #
 843   # libintl versions < 0.13 use the native *printf() functions, and Win32
 844   # *printf() doesn't understand %$, so we must use our /port versions,
 845   # which do understand %$. libintl versions >= 0.13 include their own
 846   # *printf versions on Win32.  The libintl 0.13 release note text is:
 847   #
 848   #   C format strings with positions, as they arise when a translator
 849   #   needs to reorder a sentence, are now supported on all platforms.
 850   #   On those few platforms (NetBSD and Woe32) for which the native
 851   #   printf()/fprintf()/... functions don't support such format
 852   #   strings, replacements are provided through <libintl.h>.
 853   #
 854   # We could use libintl >= 0.13's *printf() if we were sure that we had
 855   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 856   # to guarantee that, it is best to just use our own, so we are sure to
 857   # get %$ support. In include/port.h we disable the *printf() macros
 858   # that might have been defined by libintl.
 859   #
 860   # We do this unconditionally whether NLS is used or not so we are sure
 861   # that all Win32 libraries and binaries behave the same.
 862   pgac_need_repl_snprintf=yes
 863 else
 864   pgac_need_repl_snprintf=no
 865   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 866   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 867 fi
 868
 869
 870 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 871 # include/c.h will provide declarations.  Note this is a separate test
 872 # from whether the functions exist in the C library --- there are
 873 # systems that have the functions but don't bother to declare them :-(
 874
 875 AC_CHECK_DECLS([snprintf, vsnprintf])
 876
 877
 878 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 879 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 880 [AC_TRY_LINK([
 881 #include <math.h>
 882 double glob_double;
 883 ],
 884 [return isinf(glob_double) ? 0 : 1;],
 885 [ac_cv_func_isinf=yes],
 886 [ac_cv_func_isinf=no])])
 887
 888 if test $ac_cv_func_isinf = yes ; then
 889   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 890 else
 891   AC_LIBOBJ(isinf)
 892   # Look for a way to implement a substitute for isinf()
 893   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 894 fi
 895
 896 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 897
 898 # System's version of getaddrinfo(), if any, may be used only if we found
 899 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 900 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 901 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 902 # because we want to use our own getaddrinfo.c on Windows anyway.)
 903 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 904   AC_REPLACE_FUNCS([getaddrinfo])
 905 else
 906   AC_LIBOBJ(getaddrinfo)
 907 fi
 908
 909 # similarly, use system's getopt_long() only if system provides struct option.
 910 if test x"$ac_cv_type_struct_option" = xyes ; then
 911   AC_REPLACE_FUNCS([getopt_long])
 912 else
 913   AC_LIBOBJ(getopt_long)
 914 fi
 915
 916 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 917 # We override the previous test that said fseeko/ftello didn't exist
 918 # OS tests are also done in include/c.h and port/fseeko.c
 919 case $host_os in bsdi*|netbsd*)
 920 ac_cv_func_fseeko=yes
 921 esac
 922
 923 # Solaris has a very slow qsort in certain cases, so we replace it:
 924 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 925 # Supposedly it is fixed in Solaris, but not sure which version, and
 926 # no confirmed testing.  2005-12-16
 927 if test "$PORTNAME" = "solaris"; then
 928 AC_LIBOBJ(qsort)
 929 fi
 930
 931 # Win32 support
 932 if test "$PORTNAME" = "win32"; then
 933 AC_LIBOBJ(gettimeofday)
 934 AC_LIBOBJ(kill)
 935 AC_LIBOBJ(open)
 936 AC_LIBOBJ(rand)
 937 AC_DEFINE([HAVE_SYMLINK], 1,
 938           [Define to 1 if you have the `symlink' function.])
 939 fi
 940
 941 if test "$with_readline" = yes; then
 942   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 943   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 944   AC_CHECK_FUNCS([replace_history_entry])
 945 fi
 946
 947
 948 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 949 AC_MSG_CHECKING(for finite)
 950 AC_TRY_LINK([
 951 #include <math.h>
 952 double glob_double;
 953 ],
 954             [return finite(glob_double) ? 0 : 1;],
 955             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 956 AC_MSG_RESULT(yes)],
 957             [AC_MSG_RESULT(no)])
 958
 959 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 960 dnl (especially on GNU libc)
 961 dnl See also comments in c.h.
 962 AC_MSG_CHECKING(for sigsetjmp)
 963 AC_TRY_LINK([#include <setjmp.h>],
 964             [sigjmp_buf x; sigsetjmp(x, 1);],
 965             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 966 AC_MSG_RESULT(yes)],
 967             [AC_MSG_RESULT(no)])
 968
 969 AC_CHECK_FUNC(syslog,
 970               [AC_CHECK_HEADER(syslog.h,
 971                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 972
 973 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 974 [AC_TRY_LINK([#include <unistd.h>],
 975   [extern int optreset; optreset = 1;],
 976   [pgac_cv_var_int_optreset=yes],
 977   [pgac_cv_var_int_optreset=no])])
 978 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 979   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 980 fi
 981
 982 AC_CHECK_FUNCS([strtoll strtoq], [break])
 983 AC_CHECK_FUNCS([strtoull strtouq], [break])
 984
 985 # Check for one of atexit() or on_exit()
 986 AC_CHECK_FUNCS(atexit, [],
 987                [AC_CHECK_FUNCS(on_exit, [],
 988                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 989
 990 AC_FUNC_FSEEKO
 991
 992 #
 993 # Pthreads
 994 #
 995 # For each platform, we need to know about any special compile and link
 996 # libraries, and whether the normal C function names are thread-safe.
 997 # See the comment at the top of src/port/thread.c for more information.
 998 #
 999 if test "$enable_thread_safety" = yes; then
1000 ACX_PTHREAD     # set thread flags
1001
1002 # Some platforms use these, so just defineed them.  They can't hurt if they
1003 # are not supported.
1004 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1005
1006
1007 # At this point, we don't want to muck with the compiler name for threading.
1008 # Let's see who fails, perhaps AIX.  2004-04-23
1009 if test "$PTHREAD_CC" != "$CC"; then
1010 AC_MSG_ERROR([
1011 PostgreSQL does not support platforms that require a special
1012 compiler binary for thread-safety.
1013 ])
1014 fi
1015
1016 if test "$THREAD_SUPPORT" = no; then
1017 AC_MSG_ERROR([
1018 Cannot enable threads on your platform.
1019 Your platform is known to not support thread-safe programs.
1020 For details, compile and run src/bin/pg_thread_test.
1021 ])
1022 fi
1023
1024 # Check for *_r functions
1025 _CFLAGS="$CFLAGS"
1026 _LIBS="$LIBS"
1027 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1028 LIBS="$LIBS $PTHREAD_LIBS"
1029
1030 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1031
1032 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1033
1034 # Do test here with the proper thread flags
1035 PGAC_FUNC_GETPWUID_R_5ARG
1036 PGAC_FUNC_STRERROR_R_INT
1037
1038 CFLAGS="$_CFLAGS"
1039 LIBS="$_LIBS"
1040
1041 else
1042 # do not use values from template file
1043 PTHREAD_CFLAGS=
1044 PTHREAD_LIBS=
1045 fi
1046
1047 AC_SUBST(PTHREAD_CFLAGS)
1048 AC_SUBST(PTHREAD_LIBS)
1049
1050
1051 # This test makes sure that run tests work at all.  Sometimes a shared
1052 # library is found by the linker, but the runtime linker can't find it.
1053 # This check should come after all modifications of compiler or linker
1054 # variables, and before any other run tests.
1055 AC_MSG_CHECKING([test program])
1056 AC_TRY_RUN([int main() { return 0; }],
1057 [AC_MSG_RESULT(ok)],
1058 [AC_MSG_RESULT(failed)
1059 AC_MSG_ERROR([[
1060 *** Could not execute a simple test program.  This may be a problem
1061 *** related to locating shared libraries.  Check the file 'config.log'
1062 *** for the exact reason.]])],
1063 [AC_MSG_RESULT([cross-compiling])])
1064
1065 # --------------------
1066 # Run tests below here
1067 # --------------------
1068
1069 # Force use of our snprintf if system's doesn't do arg control
1070 # See comment above at snprintf test for details.
1071 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1072   PGAC_FUNC_PRINTF_ARG_CONTROL
1073   if test $pgac_cv_printf_arg_control != yes ; then
1074     pgac_need_repl_snprintf=yes
1075   fi
1076 fi
1077
1078
1079 dnl Check to see if we have a working 64-bit integer type.
1080 dnl This breaks down into two steps:
1081 dnl (1) figure out if the compiler has a 64-bit int type with working
1082 dnl arithmetic, and if so
1083 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1084 dnl snprintf is the only library routine we really need for int8 support.)
1085 dnl It's entirely possible to have a compiler that handles a 64-bit type
1086 dnl when the C library doesn't; this is fairly likely when using gcc on
1087 dnl an older platform, for example.
1088 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1089 dnl we force our own version of snprintf() to be used instead.
1090 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1091
1092 PGAC_TYPE_64BIT_INT([long int])
1093
1094 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1095   PGAC_TYPE_64BIT_INT([long long int])
1096 fi
1097
1098
1099 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1100
1101 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1102   AC_TRY_COMPILE([
1103 #define INT64CONST(x)  x##LL
1104 long long int foo = INT64CONST(0x1234567890123456);
1105 ],
1106         [],
1107         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1108         [])
1109 fi
1110
1111
1112 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1113 # we found we need to use "long long int", better check.  We cope with
1114 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1115 # work, fall back to our own snprintf emulation (which we know uses %lld).
1116
1117 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1118   if test $pgac_need_repl_snprintf = no; then
1119     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1120     if test "$LONG_LONG_INT_FORMAT" = ""; then
1121       # Force usage of our own snprintf, since system snprintf is broken
1122       pgac_need_repl_snprintf=yes
1123       LONG_LONG_INT_FORMAT='%lld'
1124     fi
1125   else
1126     # Here if we previously decided we needed to use our own snprintf
1127     LONG_LONG_INT_FORMAT='%lld'
1128   fi
1129   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1130   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1131   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1132 else
1133   # Here if we are not using 'long long int' at all
1134   INT64_FORMAT='"%ld"'
1135   UINT64_FORMAT='"%lu"'
1136 fi
1137
1138 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1139                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1140
1141 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1142                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1143
1144 # Now we have checked all the reasons to replace snprintf
1145 if test $pgac_need_repl_snprintf = yes; then
1146   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1147   AC_LIBOBJ(snprintf)
1148 fi
1149
1150 # Need a #define for the size of Datum (unsigned long)
1151 AC_CHECK_SIZEOF([unsigned long])
1152
1153 # And one for the size of size_t (enables tweaks for > 32bit address space)
1154 AC_CHECK_SIZEOF([size_t])
1155
1156 # Determine memory alignment requirements for the basic C data types.
1157
1158 PGAC_CHECK_ALIGNOF(short)
1159 PGAC_CHECK_ALIGNOF(int)
1160 PGAC_CHECK_ALIGNOF(long)
1161 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1162   PGAC_CHECK_ALIGNOF(long long int)
1163 fi
1164 PGAC_CHECK_ALIGNOF(double)
1165
1166 # Compute maximum alignment of any basic type.
1167 # We assume long's alignment is at least as strong as char, short, or int;
1168 # but we must check long long (if it exists) and double.
1169
1170 MAX_ALIGNOF=$pgac_cv_alignof_long
1171 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1172   MAX_ALIGNOF=$pgac_cv_alignof_double
1173 fi
1174 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1175   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1176 fi
1177 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1178
1179
1180 # Some platforms predefine the types int8, int16, etc.  Only check
1181 # a (hopefully) representative subset.
1182 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1183 [#include <stdio.h>
1184 #ifdef HAVE_SUPPORTDEFS_H
1185 #include <SupportDefs.h>
1186 #endif])
1187
1188 # We also check for sig_atomic_t, which *should* be defined per ANSI
1189 # C, but is missing on some old platforms.
1190 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1191
1192
1193 if test x"$template" != x"win32"
1194 then
1195 PGAC_FUNC_POSIX_SIGNALS
1196 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1197   AC_MSG_ERROR([
1198 *** Thread-safety requires POSIX signals, which are not supported by your
1199 *** operating system.
1200 ])
1201 fi
1202 fi
1203
1204 if test $ac_cv_func_fseeko = yes; then
1205 AC_SYS_LARGEFILE
1206 fi
1207
1208 # SunOS doesn't handle negative byte comparisons properly with +/- return
1209 AC_FUNC_MEMCMP
1210
1211
1212 # Select semaphore implementation type.
1213 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1214   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1215   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1216 else
1217   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1218     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1219     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1220   else
1221     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1222     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1223   fi
1224 fi
1225
1226
1227 # Select shared-memory implementation type.
1228 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1229 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1230
1231
1232 # If not set in template file, set bytes to use libc memset()
1233 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1234   MEMSET_LOOP_LIMIT=1024
1235 fi
1236 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1237
1238
1239 if test "$enable_nls" = yes ; then
1240   PGAC_CHECK_GETTEXT
1241 fi
1242
1243 # Check for Tcl configuration script tclConfig.sh
1244 if test "$with_tcl" = yes; then
1245     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1246     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1247                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1248     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1249     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1250     ac_save_CPPFLAGS=$CPPFLAGS
1251     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1252     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1253     CPPFLAGS=$ac_save_CPPFLAGS
1254 fi
1255
1256 #
1257 # Check for DocBook and tools
1258 #
1259 PGAC_PROG_NSGMLS
1260 PGAC_PROG_JADE
1261 PGAC_CHECK_DOCBOOK(4.2)
1262 PGAC_PATH_DOCBOOK_STYLESHEETS
1263 PGAC_PATH_COLLATEINDEX
1264 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1265
1266 # Thread testing
1267
1268 # We have to run the thread test near the end so we have all our symbols
1269 # defined.  Cross compiling throws a warning.
1270 #
1271 if test "$enable_thread_safety_force" = yes; then
1272 if test x"$template" != x"win32"
1273 then
1274   AC_MSG_WARN([
1275 *** Skipping thread test program.  --enable-thread-safety-force was used.
1276 *** Run the program in src/test/thread on the your machine and add
1277 proper locking function calls to your applications to guarantee thread
1278 safety.
1279 ])
1280 else
1281 AC_MSG_WARN([*** Skipping thread test on Win32])
1282 fi
1283 elif test "$enable_thread_safety" = yes; then
1284 if test x"$template" != x"win32"
1285 then
1286 AC_MSG_CHECKING([thread safety of required library functions])
1287
1288 _CFLAGS="$CFLAGS"
1289 _LIBS="$LIBS"
1290 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1291 LIBS="$LIBS $PTHREAD_LIBS"
1292 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1293   [AC_MSG_RESULT(yes)],
1294   [AC_MSG_RESULT(no)
1295   AC_MSG_ERROR([
1296 *** Thread test program failed.  Your platform is not thread-safe.
1297 *** Check the file 'config.log'for the exact reason.
1298 ***
1299 *** You can use the configure option --enable-thread-safety-force
1300 *** to force threads to be enabled.  However, you must then run
1301 *** the program in src/test/thread and add locking function calls
1302 *** to your applications to guarantee thread safety.
1303 ])],
1304   [AC_MSG_RESULT(maybe)
1305   AC_MSG_WARN([
1306 *** Skipping thread test program because of cross-compile build.
1307 *** Run the program in src/test/thread on the target machine.
1308 ])])
1309 CFLAGS="$_CFLAGS"
1310 LIBS="$_LIBS"
1311 else
1312 AC_MSG_WARN([*** Skipping thread test on Win32])
1313 fi
1314 fi
1315
1316 # prepare build tree if outside source tree
1317 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1318 # Note 2: /bin/pwd might be better than shell's built-in at getting
1319 #         a symlink-free name.
1320 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1321   vpath_build=no
1322 else
1323   vpath_build=yes
1324   if test "$no_create" != yes; then
1325     _AS_ECHO_N([preparing build tree... ])
1326     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1327     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1328       || AC_MSG_ERROR(failed)
1329     AC_MSG_RESULT(done)
1330   fi
1331 fi
1332 AC_SUBST(vpath_build)
1333
1334
1335 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1336
1337 AC_CONFIG_LINKS([
1338   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1339   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1340   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1341   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1342   src/include/pg_config_os.h:src/include/port/${template}.h
1343   src/Makefile.port:src/makefiles/Makefile.${template}
1344 ])
1345
1346 if test "$PORTNAME" = "win32"; then
1347 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1348 # Links sometimes fail undetected on Mingw -
1349 # so here we detect it and warn the user
1350 for FILE in $CONFIG_LINKS
1351  do
1352         # test -e works for symlinks in the MinGW console
1353         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1354  done
1355 ])
1356 fi
1357
1358 AC_CONFIG_HEADERS([src/include/pg_config.h],
1359 [
1360 # Update timestamp for pg_config.h (see Makefile.global)
1361 echo >src/include/stamp-h
1362 ])
1363
1364 AC_OUTPUT
1365