granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.5devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2015, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sysv5*) template=unixware ;;
  75 esac
  76
  77   if test x"$template" = x"" ; then
  78     AC_MSG_ERROR([[
  79 *******************************************************************
  80 PostgreSQL has apparently not been ported to your platform yet.
  81 To try a manual configuration, look into the src/template directory
  82 for a similar platform and use the '--with-template=' option.
  83
  84 Please also contact <pgsql-bugs@postgresql.org> to see about
  85 rectifying this.  Include the above 'checking host system type...'
  86 line.
  87 *******************************************************************
  88 ]])
  89   fi
  90
  91 ])
  92
  93 AC_MSG_RESULT([$template])
  94
  95 PORTNAME=$template
  96 AC_SUBST(PORTNAME)
  97
  98 # Initialize default assumption that we do not need separate assembly code
  99 # for TAS (test-and-set).  This can be overridden by the template file
 100 # when it's executed.
 101 need_tas=no
 102 tas_file=dummy.s
 103
 104
 105
 106 ##
 107 ## Command line options
 108 ##
 109
 110 #
 111 # Add non-standard directories to the include path
 112 #
 113 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 114
 115
 116 #
 117 # Add non-standard directories to the library search path
 118 #
 119 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 120              [LIBRARY_DIRS=$withval])
 121
 122 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 123              [LIBRARY_DIRS=$withval])
 124
 125
 126 #
 127 # 64-bit integer date/time storage: enabled by default.
 128 #
 129 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 130 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 131               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 132                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 133 AC_MSG_RESULT([$enable_integer_datetimes])
 134
 135
 136 #
 137 # NLS
 138 #
 139 AC_MSG_CHECKING([whether NLS is wanted])
 140 PGAC_ARG_OPTARG(enable, nls,
 141                 [LANGUAGES], [enable Native Language Support],
 142                 [],
 143                 [WANTED_LANGUAGES=$enableval],
 144                 [AC_DEFINE(ENABLE_NLS, 1,
 145                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 146 AC_MSG_RESULT([$enable_nls])
 147 AC_SUBST(enable_nls)
 148 AC_SUBST(WANTED_LANGUAGES)
 149
 150 #
 151 # Default port number (--with-pgport), default 5432
 152 #
 153 AC_MSG_CHECKING([for default port number])
 154 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 155              [default_port=$withval],
 156              [default_port=5432])
 157 AC_MSG_RESULT([$default_port])
 158 # Need both of these because some places want an integer and some a string
 159 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 160 [Define to the default TCP port number on which the server listens and
 161 to which clients will try to connect.  This can be overridden at run-time,
 162 but it's convenient if your clients have the right default compiled in.
 163 (--with-pgport=PORTNUM)])
 164 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 165                    [Define to the default TCP port number as a string constant.])
 166 AC_SUBST(default_port)
 167
 168 #
 169 # '-rpath'-like feature can be disabled
 170 #
 171 PGAC_ARG_BOOL(enable, rpath, yes,
 172               [do not embed shared library search path in executables])
 173 AC_SUBST(enable_rpath)
 174
 175 #
 176 # Spinlocks
 177 #
 178 PGAC_ARG_BOOL(enable, spinlocks, yes,
 179               [do not use spinlocks])
 180
 181 #
 182 # Atomic operations
 183 #
 184 PGAC_ARG_BOOL(enable, atomics, yes,
 185               [do not use atomic operations])
 186
 187 #
 188 # --enable-debug adds -g to compiler flags
 189 #
 190 PGAC_ARG_BOOL(enable, debug, no,
 191               [build with debugging symbols (-g)])
 192 AC_SUBST(enable_debug)
 193
 194 #
 195 # --enable-profiling enables gcc profiling
 196 #
 197 PGAC_ARG_BOOL(enable, profiling, no,
 198               [build with profiling enabled ])
 199
 200 #
 201 # --enable-coverage enables generation of code coverage metrics with gcov
 202 #
 203 PGAC_ARG_BOOL(enable, coverage, no,
 204               [build with coverage testing instrumentation],
 205 [AC_CHECK_PROGS(GCOV, gcov)
 206 if test -z "$GCOV"; then
 207   AC_MSG_ERROR([gcov not found])
 208 fi
 209 AC_CHECK_PROGS(LCOV, lcov)
 210 if test -z "$LCOV"; then
 211   AC_MSG_ERROR([lcov not found])
 212 fi
 213 AC_CHECK_PROGS(GENHTML, genhtml)
 214 if test -z "$GENHTML"; then
 215   AC_MSG_ERROR([genhtml not found])
 216 fi])
 217 AC_SUBST(enable_coverage)
 218
 219 #
 220 # DTrace
 221 #
 222 PGAC_ARG_BOOL(enable, dtrace, no,
 223               [build with DTrace support],
 224 [AC_CHECK_PROGS(DTRACE, dtrace)
 225 if test -z "$DTRACE"; then
 226   AC_MSG_ERROR([dtrace not found])
 227 fi
 228 AC_SUBST(DTRACEFLAGS)])
 229 AC_SUBST(enable_dtrace)
 230
 231 #
 232 # TAP tests
 233 #
 234 PGAC_ARG_BOOL(enable, tap-tests, no,
 235               [enable TAP tests (requires Perl and IPC::Run)])
 236 AC_SUBST(enable_tap_tests)
 237
 238 #
 239 # Block size
 240 #
 241 AC_MSG_CHECKING([for block size])
 242 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 243              [blocksize=$withval],
 244              [blocksize=8])
 245 case ${blocksize} in
 246   1) BLCKSZ=1024;;
 247   2) BLCKSZ=2048;;
 248   4) BLCKSZ=4096;;
 249   8) BLCKSZ=8192;;
 250  16) BLCKSZ=16384;;
 251  32) BLCKSZ=32768;;
 252   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 253 esac
 254 AC_MSG_RESULT([${blocksize}kB])
 255
 256 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 257  Size of a disk block --- this also limits the size of a tuple.  You
 258  can set it bigger if you need bigger tuples (although TOAST should
 259  reduce the need to have large tuples, since fields can be spread
 260  across multiple tuples).
 261
 262  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 263  is currently 2^15 (32768).  This is determined by the 15-bit widths
 264  of the lp_off and lp_len fields in ItemIdData (see
 265  include/storage/itemid.h).
 266
 267  Changing BLCKSZ requires an initdb.
 268 ])
 269
 270 #
 271 # Relation segment size
 272 #
 273 AC_MSG_CHECKING([for segment size])
 274 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 275              [segsize=$withval],
 276              [segsize=1])
 277 # this expression is set up to avoid unnecessary integer overflow
 278 # blocksize is already guaranteed to be a factor of 1024
 279 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 280 test $? -eq 0 || exit 1
 281 AC_MSG_RESULT([${segsize}GB])
 282
 283 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 284  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 285  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 286  relations bigger than that are divided into multiple files.
 287
 288  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 289  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 290  have large file support enabled.  By default, we make the limit 1 GB
 291  to avoid any possible integer-overflow problems within the OS.
 292  A limit smaller than necessary only means we divide a large
 293  relation into more chunks than necessary, so it seems best to err
 294  in the direction of a small limit.
 295
 296  A power-of-2 value is recommended to save a few cycles in md.c,
 297  but is not absolutely required.
 298
 299  Changing RELSEG_SIZE requires an initdb.
 300 ])
 301
 302 #
 303 # WAL block size
 304 #
 305 AC_MSG_CHECKING([for WAL block size])
 306 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 307              [wal_blocksize=$withval],
 308              [wal_blocksize=8])
 309 case ${wal_blocksize} in
 310   1) XLOG_BLCKSZ=1024;;
 311   2) XLOG_BLCKSZ=2048;;
 312   4) XLOG_BLCKSZ=4096;;
 313   8) XLOG_BLCKSZ=8192;;
 314  16) XLOG_BLCKSZ=16384;;
 315  32) XLOG_BLCKSZ=32768;;
 316  64) XLOG_BLCKSZ=65536;;
 317   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 318 esac
 319 AC_MSG_RESULT([${wal_blocksize}kB])
 320
 321 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 322  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 323  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 324  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 325  buffers, else direct I/O may fail.
 326
 327  Changing XLOG_BLCKSZ requires an initdb.
 328 ])
 329
 330 #
 331 # WAL segment size
 332 #
 333 AC_MSG_CHECKING([for WAL segment size])
 334 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 335              [wal_segsize=$withval],
 336              [wal_segsize=16])
 337 case ${wal_segsize} in
 338   1) ;;
 339   2) ;;
 340   4) ;;
 341   8) ;;
 342  16) ;;
 343  32) ;;
 344  64) ;;
 345   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 346 esac
 347 AC_MSG_RESULT([${wal_segsize}MB])
 348
 349 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 350  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 351  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 352  XLOG_BLCKSZ).
 353
 354  Changing XLOG_SEG_SIZE requires an initdb.
 355 ])
 356
 357 #
 358 # C compiler
 359 #
 360
 361 # For historical reasons you can also use --with-CC to specify the C compiler
 362 # to use, although the standard way to do this is to set the CC environment
 363 # variable.
 364 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 365
 366 case $template in
 367   aix) pgac_cc_list="gcc xlc";;
 368     *) pgac_cc_list="gcc cc";;
 369 esac
 370
 371 AC_PROG_CC([$pgac_cc_list])
 372
 373 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 374 # but has idiosyncrasies of its own.  We assume icc will define
 375 # __INTEL_COMPILER regardless of CFLAGS.
 376 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 377 choke me
 378 @%:@endif], [ICC=[yes]], [ICC=[no]])
 379
 380 # Check if it's Sun Studio compiler. We assume that
 381 # __SUNPRO_C will be defined for Sun Studio compilers
 382 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 383 choke me
 384 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 385
 386 AC_SUBST(SUN_STUDIO_CC)
 387
 388 unset CFLAGS
 389
 390 #
 391 # Read the template
 392 #
 393 . "$srcdir/src/template/$template" || exit
 394
 395 # CFLAGS are selected so:
 396 # If the user specifies something in the environment, that is used.
 397 # else:  If the template file set something, that is used.
 398 # else:  If coverage was enabled, don't set anything.
 399 # else:  If the compiler is GCC, then we use -O2.
 400 # else:  If the compiler is something else, then we use -O, unless debugging.
 401
 402 if test "$ac_env_CFLAGS_set" = set; then
 403   CFLAGS=$ac_env_CFLAGS_value
 404 elif test "${CFLAGS+set}" = set; then
 405   : # (keep what template set)
 406 elif test "$enable_coverage" = yes; then
 407   : # no optimization by default
 408 elif test "$GCC" = yes; then
 409   CFLAGS="-O2"
 410 else
 411   # if the user selected debug mode, don't use -O
 412   if test "$enable_debug" != yes; then
 413     CFLAGS="-O"
 414   fi
 415 fi
 416
 417 # CFLAGS we determined above will be added back at the end
 418 user_CFLAGS=$CFLAGS
 419 CFLAGS=""
 420
 421 # set CFLAGS_VECTOR from the environment, if available
 422 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 423   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 424 fi
 425
 426 # Some versions of GCC support some additional useful warning flags.
 427 # Check whether they are supported, and add them to CFLAGS if so.
 428 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 429 # but has its own.  Also check other compiler-specific flags here.
 430
 431 if test "$GCC" = yes -a "$ICC" = no; then
 432   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 433   # These work in some but not all gcc versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 435   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 436   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 437   # This was included in -Wall/-Wformat in older GCC versions
 438   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 439   # Disable strict-aliasing rules; needed for gcc 3.3+
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 442   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 443   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 444   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 445   # Optimization flags for specific files that benefit from vectorization
 446   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 447   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 448 elif test "$ICC" = yes; then
 449   # Intel's compiler has a bug/misoptimization in checking for
 450   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 451   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 452   # Make sure strict aliasing is off (though this is said to be the default)
 453   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 454 elif test "$PORTNAME" = "aix"; then
 455   # AIX's xlc has to have strict aliasing turned off too
 456   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 457 elif test "$PORTNAME" = "hpux"; then
 458   # On some versions of HP-UX, libm functions do not set errno by default.
 459   # Fix that by using +Olibmerrno if the compiler recognizes it.
 460   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 461 fi
 462
 463 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 464
 465 # supply -g if --enable-debug
 466 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 467   CFLAGS="$CFLAGS -g"
 468 fi
 469
 470 # enable code coverage if --enable-coverage
 471 if test "$enable_coverage" = yes; then
 472   if test "$GCC" = yes; then
 473     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 474   else
 475     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 476   fi
 477 fi
 478
 479 # enable profiling if --enable-profiling
 480 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 481   if test "$GCC" = yes; then
 482     AC_DEFINE([PROFILE_PID_DIR], 1,
 483            [Define to 1 to allow profiling output to be saved separately for each process.])
 484     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 485   else
 486     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 487   fi
 488 fi
 489
 490 # We already have this in Makefile.win32, but configure needs it too
 491 if test "$PORTNAME" = "win32"; then
 492   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 493 fi
 494
 495 # Now that we're done automatically adding stuff to CFLAGS, put back the
 496 # user-specified flags (if any) at the end.  This lets users override
 497 # the automatic additions.
 498 CFLAGS="$CFLAGS $user_CFLAGS"
 499
 500 # Check if the compiler still works with the final flag settings
 501 AC_MSG_CHECKING([whether the C compiler still works])
 502 AC_TRY_LINK([], [return 0;],
 503   [AC_MSG_RESULT(yes)],
 504   [AC_MSG_RESULT(no)
 505    AC_MSG_ERROR([cannot proceed])])
 506
 507 # Defend against gcc -ffast-math
 508 if test "$GCC" = yes; then
 509 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 510 choke me
 511 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 512 fi
 513
 514 AC_PROG_CPP
 515 AC_SUBST(GCC)
 516
 517
 518 #
 519 # Set up TAS assembly code if needed; the template file has now had its
 520 # chance to request this.
 521 #
 522 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 523
 524 if test "$need_tas" = yes ; then
 525   TAS=tas.o
 526 else
 527   TAS=""
 528 fi
 529 AC_SUBST(TAS)
 530
 531
 532 #
 533 # Automatic dependency tracking
 534 #
 535 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 536               [autodepend=yes])
 537 AC_SUBST(autodepend)
 538
 539
 540 #
 541 # Enable assert checks
 542 #
 543 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 544               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 545                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 546
 547
 548 #
 549 # Include directories
 550 #
 551 ac_save_IFS=$IFS
 552 IFS="${IFS}${PATH_SEPARATOR}"
 553 # SRCH_INC comes from the template file
 554 for dir in $with_includes $SRCH_INC; do
 555   if test -d "$dir"; then
 556     INCLUDES="$INCLUDES -I$dir"
 557   else
 558     AC_MSG_WARN([*** Include directory $dir does not exist.])
 559   fi
 560 done
 561 IFS=$ac_save_IFS
 562 AC_SUBST(INCLUDES)
 563
 564
 565 #
 566 # Library directories
 567 #
 568 ac_save_IFS=$IFS
 569 IFS="${IFS}${PATH_SEPARATOR}"
 570 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 571 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 572   if test -d "$dir"; then
 573     LIBDIRS="$LIBDIRS -L$dir"
 574   else
 575     AC_MSG_WARN([*** Library directory $dir does not exist.])
 576   fi
 577 done
 578 IFS=$ac_save_IFS
 579
 580 #
 581 # Enable thread-safe client libraries
 582 #
 583 AC_MSG_CHECKING([allow thread-safe client libraries])
 584 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 585 if test "$enable_thread_safety" = yes; then
 586   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 587           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 588 fi
 589 AC_MSG_RESULT([$enable_thread_safety])
 590 AC_SUBST(enable_thread_safety)
 591
 592 #
 593 # Optionally build Tcl modules (PL/Tcl)
 594 #
 595 AC_MSG_CHECKING([whether to build with Tcl])
 596 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 597 AC_MSG_RESULT([$with_tcl])
 598 AC_SUBST([with_tcl])
 599
 600 # We see if the path to the Tcl/Tk configuration scripts is specified.
 601 # This will override the use of tclsh to find the paths to search.
 602
 603 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 604
 605 #
 606 # Optionally build Perl modules (PL/Perl)
 607 #
 608 AC_MSG_CHECKING([whether to build Perl modules])
 609 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 610 AC_MSG_RESULT([$with_perl])
 611 AC_SUBST(with_perl)
 612
 613 #
 614 # Optionally build Python modules (PL/Python)
 615 #
 616 AC_MSG_CHECKING([whether to build Python modules])
 617 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 618 AC_MSG_RESULT([$with_python])
 619 AC_SUBST(with_python)
 620
 621 #
 622 # GSSAPI
 623 #
 624 AC_MSG_CHECKING([whether to build with GSSAPI support])
 625 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 626 [
 627   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 628   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 629 ])
 630 AC_MSG_RESULT([$with_gssapi])
 631
 632
 633 AC_SUBST(krb_srvtab)
 634
 635
 636 #
 637 # Kerberos configuration parameters
 638 #
 639 PGAC_ARG_REQ(with, krb-srvnam,
 640              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 641              [],
 642              [with_krb_srvnam="postgres"])
 643 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 644                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 645
 646
 647 #
 648 # PAM
 649 #
 650 AC_MSG_CHECKING([whether to build with PAM support])
 651 PGAC_ARG_BOOL(with, pam, no,
 652               [build with PAM support],
 653               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 654 AC_MSG_RESULT([$with_pam])
 655
 656
 657 #
 658 # LDAP
 659 #
 660 AC_MSG_CHECKING([whether to build with LDAP support])
 661 PGAC_ARG_BOOL(with, ldap, no,
 662               [build with LDAP support],
 663               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 664 AC_MSG_RESULT([$with_ldap])
 665
 666
 667 #
 668 # Bonjour
 669 #
 670 AC_MSG_CHECKING([whether to build with Bonjour support])
 671 PGAC_ARG_BOOL(with, bonjour, no,
 672               [build with Bonjour support],
 673               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 674 AC_MSG_RESULT([$with_bonjour])
 675
 676
 677 #
 678 # OpenSSL
 679 #
 680 AC_MSG_CHECKING([whether to build with OpenSSL support])
 681 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 682               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 683 AC_MSG_RESULT([$with_openssl])
 684 AC_SUBST(with_openssl)
 685
 686 #
 687 # SELinux
 688 #
 689 AC_MSG_CHECKING([whether to build with SELinux support])
 690 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 691 AC_SUBST(with_selinux)
 692 AC_MSG_RESULT([$with_selinux])
 693
 694 #
 695 # Readline
 696 #
 697 PGAC_ARG_BOOL(with, readline, yes,
 698               [do not use GNU Readline nor BSD Libedit for editing])
 699 # readline on MinGW has problems with backslashes in psql and other bugs.
 700 # This is particularly a problem with non-US code pages.
 701 # Therefore disable its use until we understand the cause. 2004-07-20
 702 if test "$PORTNAME" = "win32"; then
 703   if test "$with_readline" = yes; then
 704     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 705     with_readline=no
 706   fi
 707 fi
 708
 709
 710 #
 711 # Prefer libedit
 712 #
 713 PGAC_ARG_BOOL(with, libedit-preferred, no,
 714               [prefer BSD Libedit over GNU Readline])
 715
 716
 717 #
 718 # UUID library
 719 #
 720 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 721 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 722 # UUID library.  More than one of these might be present on a given platform,
 723 # so we make the user say which one she wants.
 724 #
 725 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 726 if test x"$with_uuid" = x"" ; then
 727   with_uuid=no
 728 fi
 729 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 730 if test "$with_ossp_uuid" = yes ; then
 731   with_uuid=ossp
 732 fi
 733
 734 if test "$with_uuid" = bsd ; then
 735   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 736   UUID_EXTRA_OBJS="md5.o sha1.o"
 737 elif test "$with_uuid" = e2fs ; then
 738   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 739   UUID_EXTRA_OBJS="md5.o sha1.o"
 740 elif test "$with_uuid" = ossp ; then
 741   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 742   UUID_EXTRA_OBJS=""
 743 elif test "$with_uuid" = no ; then
 744   UUID_EXTRA_OBJS=""
 745 else
 746   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 747 fi
 748 AC_SUBST(with_uuid)
 749 AC_SUBST(UUID_EXTRA_OBJS)
 750
 751
 752 #
 753 # XML
 754 #
 755 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 756               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 757
 758 if test "$with_libxml" = yes ; then
 759   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 760   if test -n "$XML2_CONFIG"; then
 761     for pgac_option in `$XML2_CONFIG --cflags`; do
 762       case $pgac_option in
 763         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 764       esac
 765     done
 766     for pgac_option in `$XML2_CONFIG --libs`; do
 767       case $pgac_option in
 768         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 769       esac
 770     done
 771   fi
 772 fi
 773
 774 AC_SUBST(with_libxml)
 775
 776 #
 777 # XSLT
 778 #
 779 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 780               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 781
 782
 783 AC_SUBST(with_libxslt)
 784
 785 #
 786 # tzdata
 787 #
 788 PGAC_ARG_REQ(with, system-tzdata,
 789              [DIR], [use system time zone data in DIR])
 790 AC_SUBST(with_system_tzdata)
 791
 792 #
 793 # Zlib
 794 #
 795 PGAC_ARG_BOOL(with, zlib, yes,
 796               [do not use Zlib])
 797 AC_SUBST(with_zlib)
 798
 799 #
 800 # Elf
 801 #
 802
 803 # Assume system is ELF if it predefines __ELF__ as 1,
 804 # otherwise believe host_os based default.
 805 case $host_os in
 806     freebsd1*|freebsd2*) elf=no;;
 807     freebsd3*|freebsd4*) elf=yes;;
 808 esac
 809
 810 AC_EGREP_CPP(yes,
 811 [#if __ELF__
 812   yes
 813 #endif
 814 ],
 815 [ELF_SYS=true],
 816 [if test "X$elf" = "Xyes" ; then
 817   ELF_SYS=true
 818 else
 819   ELF_SYS=
 820 fi])
 821 AC_SUBST(ELF_SYS)
 822
 823 #
 824 # Assignments
 825 #
 826
 827 CPPFLAGS="$CPPFLAGS $INCLUDES"
 828 LDFLAGS="$LDFLAGS $LIBDIRS"
 829
 830 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 831 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 832
 833 PGAC_PROG_LD
 834 AC_SUBST(LD)
 835 AC_SUBST(with_gnu_ld)
 836 case $host_os in sysv5*)
 837   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 838   [
 839     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 840     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 841     LDFLAGS=$pgac_save_LDFLAGS
 842   ])
 843   ld_R_works=$pgac_cv_prog_ld_R
 844   AC_SUBST(ld_R_works)
 845 esac
 846 AC_PROG_RANLIB
 847 PGAC_CHECK_STRIP
 848 AC_CHECK_TOOL(AR, ar, ar)
 849 if test "$PORTNAME" = "win32"; then
 850   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 851   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 852   AC_CHECK_TOOL(WINDRES, windres, windres)
 853 fi
 854
 855 AC_PROG_INSTALL
 856 # When Autoconf chooses install-sh as install program it tries to generate
 857 # a relative path to it in each makefile where it subsitutes it. This clashes
 858 # with our Makefile.global concept. This workaround helps.
 859 case $INSTALL in
 860   *install-sh*) install_bin='';;
 861   *) install_bin=$INSTALL;;
 862 esac
 863 AC_SUBST(install_bin)
 864
 865 AC_PATH_PROG(TAR, tar)
 866 AC_PROG_LN_S
 867 AC_PROG_AWK
 868 AC_PROG_MKDIR_P
 869 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 870 # a relative path to it in each makefile where it subsitutes it. This clashes
 871 # with our Makefile.global concept. This workaround helps.
 872 case $MKDIR_P in
 873   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 874 esac
 875
 876 PGAC_PATH_BISON
 877 PGAC_PATH_FLEX
 878
 879 PGAC_PATH_PERL
 880 if test "$with_perl" = yes; then
 881   if test -z "$PERL"; then
 882     AC_MSG_ERROR([Perl not found])
 883   fi
 884   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 885   PGAC_CHECK_PERL_EMBED_LDFLAGS
 886 fi
 887
 888 if test "$with_python" = yes; then
 889   PGAC_PATH_PYTHON
 890   PGAC_CHECK_PYTHON_EMBED_SETUP
 891 fi
 892
 893 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 894   AC_PATH_PROG(ZIC, zic)
 895   if test -z "$ZIC"; then
 896     AC_MSG_ERROR([
 897 When cross-compiling, either use the option --with-system-tzdata to use
 898 existing time-zone data, or set the environment variable ZIC to a zic
 899 program to use during the build.])
 900   fi
 901 fi
 902
 903
 904 ##
 905 ## Libraries
 906 ##
 907 ## Most libraries are included only if they demonstrably provide a function
 908 ## we need, but libm is an exception: always include it, because there are
 909 ## too many compilers that play cute optimization games that will break
 910 ## probes for standard functions such as pow().
 911 ##
 912
 913 AC_CHECK_LIB(m, main)
 914 AC_SEARCH_LIBS(setproctitle, util)
 915 AC_SEARCH_LIBS(dlopen, dl)
 916 AC_SEARCH_LIBS(socket, [socket ws2_32])
 917 AC_SEARCH_LIBS(shl_load, dld)
 918 # We only use libld in port/dynloader/aix.c
 919 case $host_os in
 920      aix*)
 921         AC_SEARCH_LIBS(ldopen, ld)
 922         ;;
 923 esac
 924 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 925 AC_SEARCH_LIBS(crypt, crypt)
 926 AC_SEARCH_LIBS(shm_open, rt)
 927 AC_SEARCH_LIBS(shm_unlink, rt)
 928 # Solaris:
 929 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 930 # Required for thread_test.c on Solaris 2.5:
 931 # Other ports use it too (HP-UX) so test unconditionally
 932 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 933 # Cygwin:
 934 AC_SEARCH_LIBS(shmget, cygipc)
 935
 936 if test "$with_readline" = yes; then
 937   PGAC_CHECK_READLINE
 938   if test x"$pgac_cv_check_readline" = x"no"; then
 939     AC_MSG_ERROR([readline library not found
 940 If you have readline already installed, see config.log for details on the
 941 failure.  It is possible the compiler isn't looking in the proper directory.
 942 Use --without-readline to disable readline support.])
 943   fi
 944 fi
 945
 946 if test "$with_zlib" = yes; then
 947   AC_CHECK_LIB(z, inflate, [],
 948                [AC_MSG_ERROR([zlib library not found
 949 If you have zlib already installed, see config.log for details on the
 950 failure.  It is possible the compiler isn't looking in the proper directory.
 951 Use --without-zlib to disable zlib support.])])
 952 fi
 953
 954 if test "$enable_spinlocks" = yes; then
 955   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 956 else
 957   AC_MSG_WARN([
 958 *** Not using spinlocks will cause poor performance.])
 959 fi
 960
 961 if test "$enable_atomics" = yes; then
 962   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
 963 else
 964   AC_MSG_WARN([
 965 *** Not using atomic operations will cause poor performance.])
 966 fi
 967
 968 if test "$with_gssapi" = yes ; then
 969   if test "$PORTNAME" != "win32"; then
 970     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 971                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 972   else
 973     LIBS="$LIBS -lgssapi32"
 974   fi
 975 fi
 976
 977 if test "$with_openssl" = yes ; then
 978   dnl Order matters!
 979   if test "$PORTNAME" != "win32"; then
 980      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 981      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 982   else
 983      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 984      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 985   fi
 986   AC_CHECK_FUNCS([SSL_get_current_compression])
 987 fi
 988
 989 if test "$with_pam" = yes ; then
 990   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 991 fi
 992
 993 if test "$with_libxml" = yes ; then
 994   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 995 fi
 996
 997 if test "$with_libxslt" = yes ; then
 998   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 999 fi
1000
1001 # for contrib/sepgsql
1002 if test "$with_selinux" = yes; then
1003   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1004                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1005 fi
1006
1007 # for contrib/uuid-ossp
1008 if test "$with_uuid" = bsd ; then
1009   # On BSD, the UUID functions are in libc
1010   AC_CHECK_FUNC(uuid_to_string,
1011     [UUID_LIBS=""],
1012     [AC_MSG_ERROR([BSD UUID functions are not present])])
1013 elif test "$with_uuid" = e2fs ; then
1014   # On OS X, the UUID functions are in libc
1015   AC_CHECK_FUNC(uuid_generate,
1016     [UUID_LIBS=""],
1017     [AC_CHECK_LIB(uuid, uuid_generate,
1018       [UUID_LIBS="-luuid"],
1019       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1020 elif test "$with_uuid" = ossp ; then
1021   AC_CHECK_LIB(ossp-uuid, uuid_export,
1022     [UUID_LIBS="-lossp-uuid"],
1023     [AC_CHECK_LIB(uuid, uuid_export,
1024       [UUID_LIBS="-luuid"],
1025       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1026 fi
1027 AC_SUBST(UUID_LIBS)
1028
1029
1030 ##
1031 ## Header files
1032 ##
1033
1034 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1035 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1036
1037 # On BSD, test for net/if.h will fail unless sys/socket.h
1038 # is included first.
1039 AC_CHECK_HEADERS(net/if.h, [], [],
1040 [AC_INCLUDES_DEFAULT
1041 #ifdef HAVE_SYS_SOCKET_H
1042 #include <sys/socket.h>
1043 #endif
1044 ])
1045
1046 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1047 # is included first.
1048 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1049 [AC_INCLUDES_DEFAULT
1050 #include <sys/param.h>
1051 ])
1052
1053 # At least on IRIX, test for netinet/tcp.h will fail unless
1054 # netinet/in.h is included first.
1055 AC_CHECK_HEADERS(netinet/in.h)
1056 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1057 [AC_INCLUDES_DEFAULT
1058 #ifdef HAVE_NETINET_IN_H
1059 #include <netinet/in.h>
1060 #endif
1061 ])
1062
1063 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1064   AC_CHECK_HEADERS(readline/readline.h, [],
1065         [AC_CHECK_HEADERS(readline.h, [],
1066                 [AC_MSG_ERROR([readline header not found
1067 If you have readline already installed, see config.log for details on the
1068 failure.  It is possible the compiler isn't looking in the proper directory.
1069 Use --without-readline to disable readline support.])])])
1070   AC_CHECK_HEADERS(readline/history.h, [],
1071         [AC_CHECK_HEADERS(history.h, [],
1072                 [AC_MSG_ERROR([history header not found
1073 If you have readline already installed, see config.log for details on the
1074 failure.  It is possible the compiler isn't looking in the proper directory.
1075 Use --without-readline to disable readline support.])])])
1076 fi
1077
1078 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1079 # Some installations of libedit usurp /usr/include/readline/, which seems
1080 # bad practice, since in combined installations readline will have its headers
1081 # there.  We might have to resort to AC_EGREP checks to make sure we found
1082 # the proper header...
1083   AC_CHECK_HEADERS(editline/readline.h, [],
1084         [AC_CHECK_HEADERS(readline.h, [],
1085                 [AC_CHECK_HEADERS(readline/readline.h, [],
1086                         [AC_MSG_ERROR([readline header not found
1087 If you have libedit already installed, see config.log for details on the
1088 failure.  It is possible the compiler isn't looking in the proper directory.
1089 Use --without-readline to disable libedit support.])])])])
1090 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1091 # not be there at all.  Hence, don't complain if not found.  We must check
1092 # though, since in yet other versions it is an independent header.
1093   AC_CHECK_HEADERS(editline/history.h, [],
1094         [AC_CHECK_HEADERS(history.h, [],
1095                 [AC_CHECK_HEADERS(readline/history.h)])])
1096 fi
1097
1098 if test "$with_zlib" = yes; then
1099   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1100 If you have zlib already installed, see config.log for details on the
1101 failure.  It is possible the compiler isn't looking in the proper directory.
1102 Use --without-zlib to disable zlib support.])])
1103 fi
1104
1105 if test "$with_gssapi" = yes ; then
1106   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1107         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1108 fi
1109
1110 if test "$with_openssl" = yes ; then
1111   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1112   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1113 fi
1114
1115 if test "$with_pam" = yes ; then
1116   AC_CHECK_HEADERS(security/pam_appl.h, [],
1117                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1118                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1119 fi
1120
1121 if test "$with_libxml" = yes ; then
1122   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1123 fi
1124
1125 if test "$with_libxslt" = yes ; then
1126   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1127 fi
1128
1129 if test "$with_ldap" = yes ; then
1130   if test "$PORTNAME" != "win32"; then
1131      AC_CHECK_HEADERS(ldap.h, [],
1132                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1133      PGAC_LDAP_SAFE
1134   else
1135      AC_CHECK_HEADERS(winldap.h, [],
1136                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1137                       [AC_INCLUDES_DEFAULT
1138 #include <windows.h>
1139                       ])
1140   fi
1141 fi
1142
1143 if test "$with_bonjour" = yes ; then
1144   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1145 fi
1146
1147 # for contrib/uuid-ossp
1148 if test "$with_uuid" = bsd ; then
1149   AC_CHECK_HEADERS(uuid.h,
1150     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1151       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1152     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1153 elif test "$with_uuid" = e2fs ; then
1154   AC_CHECK_HEADERS(uuid/uuid.h,
1155     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1156       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1157     [AC_CHECK_HEADERS(uuid.h,
1158       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1159         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1160       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1161 elif test "$with_uuid" = ossp ; then
1162   AC_CHECK_HEADERS(ossp/uuid.h,
1163     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1164       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1165     [AC_CHECK_HEADERS(uuid.h,
1166       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1167         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1168       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1169 fi
1170
1171 if test "$PORTNAME" = "win32" ; then
1172    AC_CHECK_HEADERS(crtdefs.h)
1173 fi
1174
1175 ##
1176 ## Types, structures, compiler characteristics
1177 ##
1178
1179 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1180 AC_C_BIGENDIAN
1181 PGAC_C_INLINE
1182 PGAC_PRINTF_ARCHETYPE
1183 AC_C_FLEXIBLE_ARRAY_MEMBER
1184 PGAC_C_SIGNED
1185 PGAC_C_FUNCNAME_SUPPORT
1186 PGAC_C_STATIC_ASSERT
1187 PGAC_C_TYPES_COMPATIBLE
1188 PGAC_C_BUILTIN_BSWAP32
1189 PGAC_C_BUILTIN_CONSTANT_P
1190 PGAC_C_BUILTIN_UNREACHABLE
1191 PGAC_C_VA_ARGS
1192 PGAC_STRUCT_TIMEZONE
1193 PGAC_UNION_SEMUN
1194 PGAC_STRUCT_SOCKADDR_UN
1195 PGAC_STRUCT_SOCKADDR_STORAGE
1196 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1197 PGAC_STRUCT_ADDRINFO
1198 AC_TYPE_INTPTR_T
1199 AC_TYPE_UINTPTR_T
1200 AC_TYPE_LONG_LONG_INT
1201
1202 PGAC_TYPE_LOCALE_T
1203
1204 AC_CHECK_TYPES([struct cmsgcred], [], [],
1205 [#include <sys/socket.h>
1206 #include <sys/param.h>
1207 #ifdef HAVE_SYS_UCRED_H
1208 #include <sys/ucred.h>
1209 #endif])
1210
1211 AC_CHECK_TYPES([struct option], [], [],
1212 [#ifdef HAVE_GETOPT_H
1213 #include <getopt.h>
1214 #endif])
1215
1216 if test "$with_zlib" = yes; then
1217   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1218   # did not).  While we could work around the lack of z_streamp, it
1219   # seems unwise to encourage people to use such old zlib versions...
1220   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1221 Use --without-zlib to disable zlib support.])],
1222                 [#include <zlib.h>])
1223 fi
1224
1225 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1226 case $host_cpu in
1227   ppc*|powerpc*)
1228     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1229     AC_TRY_COMPILE([],
1230         [int a = 0; int *p = &a; int r;
1231          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1232         [pgac_cv_have_ppc_mutex_hint=yes],
1233         [pgac_cv_have_ppc_mutex_hint=no])
1234     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1235     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1236         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1237     fi
1238   ;;
1239 esac
1240
1241 # Check largefile support.  You might think this is a system service not a
1242 # compiler characteristic, but you'd be wrong.  We must check this before
1243 # probing existence of related functions such as fseeko, since the largefile
1244 # defines can affect what is generated for that.
1245 if test "$PORTNAME" != "win32"; then
1246    AC_SYS_LARGEFILE
1247    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1248    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1249    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1250    dnl versions where the feature actually works, it's on by default anyway.
1251    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1252 fi
1253
1254 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1255 AC_CHECK_SIZEOF([off_t])
1256
1257 # If we don't have largefile support, can't handle segsize >= 2GB.
1258 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1259    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1260 fi
1261
1262
1263 ##
1264 ## Functions, global variables
1265 ##
1266
1267 PGAC_VAR_INT_TIMEZONE
1268 AC_FUNC_ACCEPT_ARGTYPES
1269 PGAC_FUNC_GETTIMEOFDAY_1ARG
1270
1271 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1272 # symbols that that library has no business exposing to the world.  Pending
1273 # acquisition of a clue by those developers, ignore libedit (including its
1274 # possible alias of libreadline) while checking for everything else.
1275 LIBS_including_readline="$LIBS"
1276 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1277
1278 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1279
1280 AC_REPLACE_FUNCS(fseeko)
1281 case $host_os in
1282         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1283         # Mingw uses macros to access Win32 API calls
1284         netbsd*|mingw*)
1285                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1286                 ac_cv_func_fseeko=yes;;
1287         *)
1288                 AC_FUNC_FSEEKO;;
1289 esac
1290
1291 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1292 # by calling it, 2009-04-02
1293 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1294 if test "$PORTNAME" != "solaris"; then
1295 AC_CHECK_FUNCS(posix_fadvise)
1296 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1297 fi
1298
1299 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1300 AC_CHECK_DECLS([strlcat, strlcpy])
1301 # This is probably only present on Darwin, but may as well check always
1302 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1303
1304 HAVE_IPV6=no
1305 AC_CHECK_TYPE([struct sockaddr_in6],
1306         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1307          HAVE_IPV6=yes],
1308         [],
1309 [$ac_includes_default
1310 #include <netinet/in.h>])
1311 AC_SUBST(HAVE_IPV6)
1312
1313 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1314 [AC_TRY_LINK(
1315 [#include <machine/vmparam.h>
1316 #include <sys/exec.h>
1317 ],
1318 [PS_STRINGS->ps_nargvstr = 1;
1319 PS_STRINGS->ps_argvstr = "foo";],
1320 [pgac_cv_var_PS_STRINGS=yes],
1321 [pgac_cv_var_PS_STRINGS=no])])
1322 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1323   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1324 fi
1325
1326
1327 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1328 # is missing.  Yes, there are machines that have only one.  We may
1329 # also decide to use snprintf.c if snprintf() is present but does not
1330 # have all the features we need --- see below.
1331
1332 if test "$PORTNAME" = "win32"; then
1333   # Win32 gets snprintf.c built unconditionally.
1334   #
1335   # To properly translate all NLS languages strings, we must support the
1336   # *printf() %$ format, which allows *printf() arguments to be selected
1337   # by position in the translated string.
1338   #
1339   # libintl versions < 0.13 use the native *printf() functions, and Win32
1340   # *printf() doesn't understand %$, so we must use our /port versions,
1341   # which do understand %$. libintl versions >= 0.13 include their own
1342   # *printf versions on Win32.  The libintl 0.13 release note text is:
1343   #
1344   #   C format strings with positions, as they arise when a translator
1345   #   needs to reorder a sentence, are now supported on all platforms.
1346   #   On those few platforms (NetBSD and Woe32) for which the native
1347   #   printf()/fprintf()/... functions don't support such format
1348   #   strings, replacements are provided through <libintl.h>.
1349   #
1350   # We could use libintl >= 0.13's *printf() if we were sure that we had
1351   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1352   # to guarantee that, it is best to just use our own, so we are sure to
1353   # get %$ support. In include/port.h we disable the *printf() macros
1354   # that might have been defined by libintl.
1355   #
1356   # We do this unconditionally whether NLS is used or not so we are sure
1357   # that all Win32 libraries and binaries behave the same.
1358   pgac_need_repl_snprintf=yes
1359 else
1360   pgac_need_repl_snprintf=no
1361   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1362   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1363 fi
1364
1365
1366 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1367 # include/c.h will provide declarations.  Note this is a separate test
1368 # from whether the functions exist in the C library --- there are
1369 # systems that have the functions but don't bother to declare them :-(
1370
1371 AC_CHECK_DECLS([snprintf, vsnprintf])
1372
1373
1374 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1375 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1376 [AC_TRY_LINK([
1377 #include <math.h>
1378 double glob_double;
1379 ],
1380 [return isinf(glob_double) ? 0 : 1;],
1381 [ac_cv_func_isinf=yes],
1382 [ac_cv_func_isinf=no])])
1383
1384 if test $ac_cv_func_isinf = yes ; then
1385   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1386 else
1387   AC_LIBOBJ(isinf)
1388   # Look for a way to implement a substitute for isinf()
1389   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1390 fi
1391
1392 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1393
1394 case $host_os in
1395
1396         # Windows uses a specialised env handler
1397         # and doesn't need a replacement getpeereid because it doesn't use
1398         # Unix sockets.
1399         mingw*)
1400                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1401                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1402                 ac_cv_func_unsetenv=yes
1403                 ac_cv_func_getpeereid=yes;;
1404         *)
1405                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1406                 ;;
1407 esac
1408
1409 # System's version of getaddrinfo(), if any, may be used only if we found
1410 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1411 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1412 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1413    test "$PORTNAME" != "win32"; then
1414   AC_REPLACE_FUNCS([getaddrinfo])
1415 else
1416   AC_LIBOBJ(getaddrinfo)
1417 fi
1418
1419 # Similarly, use system's getopt_long() only if system provides struct option.
1420 if test x"$ac_cv_type_struct_option" = xyes ; then
1421   AC_REPLACE_FUNCS([getopt_long])
1422 else
1423   AC_LIBOBJ(getopt_long)
1424 fi
1425
1426 # Solaris' getopt() doesn't do what we want for long options, so always use
1427 # our version on that platform.
1428 if test "$PORTNAME" = "solaris"; then
1429   AC_LIBOBJ(getopt)
1430 fi
1431
1432 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1433 # so always use our version on Windows.
1434 if test "$PORTNAME" = "win32"; then
1435   AC_LIBOBJ(getopt)
1436   AC_LIBOBJ(getopt_long)
1437 fi
1438
1439 # Win32 (really MinGW) support
1440 if test "$PORTNAME" = "win32"; then
1441   AC_REPLACE_FUNCS(gettimeofday)
1442   AC_LIBOBJ(dirmod)
1443   AC_LIBOBJ(kill)
1444   AC_LIBOBJ(open)
1445   AC_LIBOBJ(system)
1446   AC_LIBOBJ(win32env)
1447   AC_LIBOBJ(win32error)
1448   AC_LIBOBJ(win32setlocale)
1449   AC_DEFINE([HAVE_SYMLINK], 1,
1450             [Define to 1 if you have the `symlink' function.])
1451   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1452 #define WIN32_LEAN_AND_MEAN
1453 #include <windows.h>
1454 #include <string.h>
1455 #include <dbghelp.h>])
1456 fi
1457 if test x"$pgac_minidump_type" = x"yes" ; then
1458   AC_SUBST(have_win32_dbghelp,yes)
1459 else
1460   AC_SUBST(have_win32_dbghelp,no)
1461 fi
1462
1463 # Cygwin needs only a bit of that
1464 if test "$PORTNAME" = "cygwin"; then
1465   AC_LIBOBJ(dirmod)
1466 fi
1467
1468 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1469 dnl (especially on GNU libc)
1470 dnl See also comments in c.h.
1471 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1472 [AC_TRY_LINK([#include <setjmp.h>],
1473             [sigjmp_buf x; sigsetjmp(x, 1);],
1474             [pgac_cv_func_sigsetjmp=yes],
1475             [pgac_cv_func_sigsetjmp=no])])
1476 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1477   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1478 fi
1479
1480 AC_DECL_SYS_SIGLIST
1481
1482 AC_CHECK_FUNC(syslog,
1483               [AC_CHECK_HEADER(syslog.h,
1484                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1485
1486 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1487 [AC_TRY_LINK([#include <unistd.h>],
1488   [extern int opterr; opterr = 1;],
1489   [pgac_cv_var_int_opterr=yes],
1490   [pgac_cv_var_int_opterr=no])])
1491 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1492   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1493 fi
1494
1495 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1496 [AC_TRY_LINK([#include <unistd.h>],
1497   [extern int optreset; optreset = 1;],
1498   [pgac_cv_var_int_optreset=yes],
1499   [pgac_cv_var_int_optreset=no])])
1500 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1501   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1502 fi
1503
1504 AC_CHECK_FUNCS([strtoll strtoq], [break])
1505 AC_CHECK_FUNCS([strtoull strtouq], [break])
1506
1507 # Lastly, restore full LIBS list and check for readline/libedit symbols
1508 LIBS="$LIBS_including_readline"
1509
1510 if test "$with_readline" = yes; then
1511   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1512   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1513   AC_CHECK_FUNCS([append_history history_truncate_file])
1514 fi
1515
1516
1517 #
1518 # Pthreads
1519 #
1520 # For each platform, we need to know about any special compile and link
1521 # libraries, and whether the normal C function names are thread-safe.
1522 # See the comment at the top of src/port/thread.c for more information.
1523 # WIN32 doesn't need the pthread tests;  it always uses threads
1524 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1525 ACX_PTHREAD     # set thread flags
1526
1527 # Some platforms use these, so just define them.  They can't hurt if they
1528 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1529 # enables 5-arg getpwuid_r, among other things.
1530 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1531
1532 # Check for *_r functions
1533 _CFLAGS="$CFLAGS"
1534 _LIBS="$LIBS"
1535 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1536 LIBS="$LIBS $PTHREAD_LIBS"
1537
1538 if test "$PORTNAME" != "win32"; then
1539 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1540 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1541 fi
1542
1543 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1544
1545 # Do test here with the proper thread flags
1546 PGAC_FUNC_STRERROR_R_INT
1547
1548 CFLAGS="$_CFLAGS"
1549 LIBS="$_LIBS"
1550
1551 else
1552 # do not use values from template file
1553 PTHREAD_CFLAGS=
1554 PTHREAD_LIBS=
1555 fi
1556
1557 AC_SUBST(PTHREAD_CFLAGS)
1558 AC_SUBST(PTHREAD_LIBS)
1559
1560
1561 # We can test for libldap_r only after we know PTHREAD_LIBS
1562 if test "$with_ldap" = yes ; then
1563   _LIBS="$LIBS"
1564   if test "$PORTNAME" != "win32"; then
1565     AC_CHECK_LIB(ldap, ldap_bind, [],
1566                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1567                  [$EXTRA_LDAP_LIBS])
1568     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1569     if test "$enable_thread_safety" = yes; then
1570       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1571       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1572                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1573                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1574       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1575     else
1576       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1577     fi
1578   else
1579     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1580     LDAP_LIBS_FE="-lwldap32"
1581     LDAP_LIBS_BE="-lwldap32"
1582   fi
1583   LIBS="$_LIBS"
1584 fi
1585 AC_SUBST(LDAP_LIBS_FE)
1586 AC_SUBST(LDAP_LIBS_BE)
1587
1588
1589 # This test makes sure that run tests work at all.  Sometimes a shared
1590 # library is found by the linker, but the runtime linker can't find it.
1591 # This check should come after all modifications of compiler or linker
1592 # variables, and before any other run tests.
1593 AC_MSG_CHECKING([test program])
1594 AC_TRY_RUN([int main() { return 0; }],
1595 [AC_MSG_RESULT(ok)],
1596 [AC_MSG_RESULT(failed)
1597 AC_MSG_ERROR([[
1598 Could not execute a simple test program.  This may be a problem
1599 related to locating shared libraries.  Check the file 'config.log'
1600 for the exact reason.]])],
1601 [AC_MSG_RESULT([cross-compiling])])
1602
1603 # --------------------
1604 # Run tests below here
1605 # --------------------
1606
1607 # Force use of our snprintf if system's doesn't do arg control
1608 # See comment above at snprintf test for details.
1609 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1610   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1611   if test $pgac_cv_snprintf_arg_control != yes ; then
1612     pgac_need_repl_snprintf=yes
1613   fi
1614 fi
1615
1616
1617 dnl Check to see if we have a working 64-bit integer type.
1618 dnl This breaks down into two steps:
1619 dnl (1) figure out if the compiler has a 64-bit int type with working
1620 dnl arithmetic, and if so
1621 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1622 dnl snprintf is the only library routine we really need for int8 support.)
1623 dnl It's entirely possible to have a compiler that handles a 64-bit type
1624 dnl when the C library doesn't; this is fairly likely when using gcc on
1625 dnl an older platform, for example.
1626 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1627 dnl we force our own version of snprintf() to be used instead.
1628 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1629
1630 dnl As of Postgres 8.4, we no longer support compilers without a working
1631 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1632
1633 PGAC_TYPE_64BIT_INT([long int])
1634
1635 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1636   pg_int64_type="long int"
1637 else
1638   PGAC_TYPE_64BIT_INT([long long int])
1639   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1640     pg_int64_type="long long int"
1641   else
1642     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1643   fi
1644 fi
1645
1646 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1647   [Define to the name of a signed 64-bit integer type.])
1648
1649 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1650
1651 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1652   AC_TRY_COMPILE([
1653 #define INT64CONST(x)  x##LL
1654 long long int foo = INT64CONST(0x1234567890123456);
1655 ],
1656         [],
1657         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1658         [])
1659 fi
1660
1661
1662 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1663 # we found we need to use "long long int", better check.  We cope with
1664 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1665 # work, fall back to our own snprintf emulation (which we know uses %lld).
1666
1667 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1668   if test $pgac_need_repl_snprintf = no; then
1669     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1670     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1671       # Force usage of our own snprintf, since system snprintf is broken
1672       pgac_need_repl_snprintf=yes
1673       LONG_LONG_INT_MODIFIER='ll'
1674     fi
1675   else
1676     # Here if we previously decided we needed to use our own snprintf
1677     LONG_LONG_INT_MODIFIER='ll'
1678   fi
1679 else
1680   # Here if we are not using 'long long int' at all
1681   LONG_LONG_INT_MODIFIER='l'
1682 fi
1683
1684 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1685
1686 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1687                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1688
1689 # Also force use of our snprintf if the system's doesn't support the %z flag.
1690 if test "$pgac_need_repl_snprintf" = no; then
1691   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1692   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1693     pgac_need_repl_snprintf=yes
1694   fi
1695 fi
1696
1697 # Now we have checked all the reasons to replace snprintf
1698 if test $pgac_need_repl_snprintf = yes; then
1699   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1700   AC_LIBOBJ(snprintf)
1701 fi
1702
1703 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1704 AC_CHECK_SIZEOF([void *])
1705 AC_CHECK_SIZEOF([size_t])
1706 AC_CHECK_SIZEOF([long])
1707
1708 # Decide whether float4 is passed by value: user-selectable, enabled by default
1709 AC_MSG_CHECKING([whether to build with float4 passed by value])
1710 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1711               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1712                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1713                float4passbyval=true],
1714               [float4passbyval=false])
1715 AC_MSG_RESULT([$enable_float4_byval])
1716 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1717
1718 # Decide whether float8 is passed by value.
1719 # Note: this setting also controls int8 and related types such as timestamp.
1720 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1721 # If not, trying to select it is an error.
1722 AC_MSG_CHECKING([whether to build with float8 passed by value])
1723 if test $ac_cv_sizeof_void_p -ge 8 ; then
1724   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1725 else
1726   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1727   if test "$enable_float8_byval" = yes ; then
1728     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1729   fi
1730 fi
1731 if test "$enable_float8_byval" = yes ; then
1732   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1733             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1734   float8passbyval=true
1735 else
1736   float8passbyval=false
1737 fi
1738 AC_MSG_RESULT([$enable_float8_byval])
1739 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1740
1741 # Determine memory alignment requirements for the basic C data types.
1742
1743 AC_CHECK_ALIGNOF(short)
1744 AC_CHECK_ALIGNOF(int)
1745 AC_CHECK_ALIGNOF(long)
1746 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1747   AC_CHECK_ALIGNOF(long long int)
1748 fi
1749 AC_CHECK_ALIGNOF(double)
1750
1751 # Compute maximum alignment of any basic type.
1752 # We assume long's alignment is at least as strong as char, short, or int;
1753 # but we must check long long (if it exists) and double.
1754
1755 MAX_ALIGNOF=$ac_cv_alignof_long
1756 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1757   MAX_ALIGNOF=$ac_cv_alignof_double
1758 fi
1759 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1760   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1761 fi
1762 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1763
1764
1765 # Some platforms predefine the types int8, int16, etc.  Only check
1766 # a (hopefully) representative subset.
1767 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1768 [#include <stdio.h>])
1769
1770 # We also check for sig_atomic_t, which *should* be defined per ANSI
1771 # C, but is missing on some old platforms.
1772 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1773
1774 # Check for extensions offering the integer scalar type __int128.
1775 PGAC_TYPE_128BIT_INT
1776
1777 # Check for various atomic operations now that we have checked how to declare
1778 # 64bit integers.
1779 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1780 PGAC_HAVE_GCC__SYNC_INT32_TAS
1781 PGAC_HAVE_GCC__SYNC_INT32_CAS
1782 PGAC_HAVE_GCC__SYNC_INT64_CAS
1783 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1784 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1785
1786 if test "$PORTNAME" != "win32"
1787 then
1788 PGAC_FUNC_POSIX_SIGNALS
1789 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1790   AC_MSG_ERROR([
1791 Thread-safety requires POSIX signals, which are not supported by this
1792 operating system;  use --disable-thread-safety to disable thread safety.])
1793 fi
1794 fi
1795
1796
1797 # Select semaphore implementation type.
1798 if test "$PORTNAME" != "win32"; then
1799   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1800     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1801     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1802   else
1803     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1804       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1805       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1806     else
1807       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1808       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1809     fi
1810   fi
1811 else
1812   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1813   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1814 fi
1815
1816
1817 # Select shared-memory implementation type.
1818 if test "$PORTNAME" != "win32"; then
1819   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1820   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1821 else
1822   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1823   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1824 fi
1825
1826 # Select latch implementation type.
1827 if test "$PORTNAME" != "win32"; then
1828   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1829 else
1830   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1831 fi
1832
1833 # If not set in template file, set bytes to use libc memset()
1834 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1835   MEMSET_LOOP_LIMIT=1024
1836 fi
1837 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1838
1839
1840 if test "$enable_nls" = yes ; then
1841   PGAC_CHECK_GETTEXT
1842 fi
1843
1844 # Check for Tcl configuration script tclConfig.sh
1845 if test "$with_tcl" = yes; then
1846     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1847     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1848                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1849     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1850     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1851     ac_save_CPPFLAGS=$CPPFLAGS
1852     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1853     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1854     CPPFLAGS=$ac_save_CPPFLAGS
1855 fi
1856
1857 # check for <perl.h>
1858 if test "$with_perl" = yes; then
1859   ac_save_CPPFLAGS=$CPPFLAGS
1860   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1861   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1862                   [#include <EXTERN.h>])
1863   # While we're at it, check that we can link to libperl.
1864   # On most platforms, if perl.h is there then libperl.so will be too, but at
1865   # this writing Debian packages them separately.  There is no known reason to
1866   # waste cycles on separate probes for the Tcl or Python libraries, though.
1867   pgac_save_LIBS=$LIBS
1868   LIBS="$perl_embed_ldflags"
1869   AC_MSG_CHECKING([for libperl])
1870   AC_TRY_LINK([
1871 #include <EXTERN.h>
1872 #include <perl.h>
1873 ],  [perl_alloc();],
1874     [AC_MSG_RESULT(yes)],
1875     [AC_MSG_RESULT(no)
1876      AC_MSG_ERROR([libperl library is required for Perl])])
1877   LIBS=$pgac_save_LIBS
1878   CPPFLAGS=$ac_save_CPPFLAGS
1879 fi
1880
1881 # check for <Python.h>
1882 if test "$with_python" = yes; then
1883   ac_save_CPPFLAGS=$CPPFLAGS
1884   CPPFLAGS="$python_includespec $CPPFLAGS"
1885   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1886   CPPFLAGS=$ac_save_CPPFLAGS
1887 fi
1888
1889 #
1890 # Check for DocBook and tools
1891 #
1892 PGAC_PROG_NSGMLS
1893 PGAC_PROG_JADE
1894 PGAC_CHECK_DOCBOOK(4.2)
1895 PGAC_PATH_DOCBOOK_STYLESHEETS
1896 PGAC_PATH_COLLATEINDEX
1897 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
1898 AC_CHECK_PROGS(XMLLINT, xmllint)
1899 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1900 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1901
1902 #
1903 # Check for test tools
1904 #
1905 if test "$enable_tap_tests" = yes; then
1906   AC_CHECK_PROGS(PROVE, prove)
1907   if test -z "$PROVE"; then
1908     AC_MSG_ERROR([prove not found])
1909   fi
1910   if test -z "$PERL"; then
1911     AC_MSG_ERROR([Perl not found])
1912   fi
1913 fi
1914
1915 # Thread testing
1916
1917 # We have to run the thread test near the end so we have all our symbols
1918 # defined.  Cross compiling throws a warning.
1919 #
1920 if test "$enable_thread_safety" = yes; then
1921 if test "$PORTNAME" != "win32"
1922 then
1923 AC_MSG_CHECKING([thread safety of required library functions])
1924
1925 _CFLAGS="$CFLAGS"
1926 _LIBS="$LIBS"
1927 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1928 LIBS="$LIBS $PTHREAD_LIBS"
1929 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1930   [AC_MSG_RESULT(yes)],
1931   [AC_MSG_RESULT(no)
1932   AC_MSG_ERROR([thread test program failed
1933 This platform is not thread-safe.  Check the file 'config.log' or compile
1934 and run src/test/thread/thread_test for the exact reason.
1935 Use --disable-thread-safety to disable thread safety.])],
1936   [AC_MSG_RESULT(maybe)
1937   AC_MSG_WARN([
1938 *** Skipping thread test program because of cross-compile build.
1939 *** Run the program in src/test/thread on the target machine.
1940 ])])
1941 CFLAGS="$_CFLAGS"
1942 LIBS="$_LIBS"
1943 else
1944 AC_MSG_WARN([*** skipping thread test on Win32])
1945 fi
1946 fi
1947
1948 # If compiler will take -Wl,--as-needed (or various platform-specific
1949 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1950 # trying to filter LIBS to the minimum for each executable.
1951 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1952 # libreadline; therefore we postpone testing it until we know what library
1953 # dependencies readline has.  The test code will try to link with $LIBS.
1954 if test "$with_readline" = yes; then
1955   link_test_func=readline
1956 else
1957   link_test_func=exit
1958 fi
1959
1960 if test "$PORTNAME" = "darwin"; then
1961   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1962 elif test "$PORTNAME" = "openbsd"; then
1963   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1964 else
1965   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1966 fi
1967
1968 # Create compiler version string
1969 if test x"$GCC" = x"yes" ; then
1970   cc_string=`${CC} --version | sed q`
1971   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1972 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1973   cc_string=`${CC} -V 2>&1 | sed q`
1974 else
1975   cc_string=$CC
1976 fi
1977
1978 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1979                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1980                    [A string containing the version number, platform, and C compiler])
1981
1982 # Supply a numeric version string for use by 3rd party add-ons
1983 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1984 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1985 tr '.' '        ' |
1986 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1987 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1988
1989
1990 # Begin output steps
1991
1992 AC_MSG_NOTICE([using compiler=$cc_string])
1993 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1994 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1995 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1996
1997 # prepare build tree if outside source tree
1998 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1999 # Note 2: /bin/pwd might be better than shell's built-in at getting
2000 #         a symlink-free name.
2001 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2002   vpath_build=no
2003 else
2004   vpath_build=yes
2005   if test "$no_create" != yes; then
2006     _AS_ECHO_N([preparing build tree... ])
2007     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2008     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2009       || AC_MSG_ERROR(failed)
2010     AC_MSG_RESULT(done)
2011   fi
2012 fi
2013 AC_SUBST(vpath_build)
2014
2015
2016 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2017
2018 AC_CONFIG_LINKS([
2019   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2020   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2021   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2022   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
2023   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2024   src/include/pg_config_os.h:src/include/port/${template}.h
2025   src/Makefile.port:src/makefiles/Makefile.${template}
2026 ])
2027
2028 if test "$PORTNAME" = "win32"; then
2029 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2030 # Links sometimes fail undetected on Mingw -
2031 # so here we detect it and warn the user
2032 for FILE in $CONFIG_LINKS
2033  do
2034         # test -e works for symlinks in the MinGW console
2035         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2036  done
2037 ])
2038 fi
2039
2040 AC_CONFIG_HEADERS([src/include/pg_config.h],
2041 [
2042 # Update timestamp for pg_config.h (see Makefile.global)
2043 echo >src/include/stamp-h
2044 ])
2045
2046 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2047 [
2048 # Update timestamp for pg_config_ext.h (see Makefile.global)
2049 echo >src/include/stamp-ext-h
2050 ])
2051
2052 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2053                   [echo >src/interfaces/ecpg/include/stamp-h])
2054
2055 AC_OUTPUT