granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 HTTPD_MMN=`$abs_srcdir/build/get-version.sh mmn $abs_srcdir/include/ap_mmn.h MODULE_MAGIC_NUMBER`
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir statedir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225 if test "x$with_pcre" = "x" || test "$with_pcre" = "yes"; then
 226   with_pcre="$PATH"
 227 else if which $with_pcre 2>/dev/null; then :; else
 228   with_pcre="$with_pcre/bin:$with_pcre"
 229 fi
 230 fi
 231
 232 AC_CHECK_TARGET_TOOLS(PCRE_CONFIG, [pcre2-config pcre-config],
 233                       [`which $with_pcre 2>/dev/null`], $with_pcre)
 234
 235 if test "x$PCRE_CONFIG" != "x"; then
 236   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 237     AC_MSG_ERROR([Did not find working script at $PCRE_CONFIG])
 238   fi
 239   case `$PCRE_CONFIG --version` in
 240   [1[0-9].*])
 241     AC_DEFINE(HAVE_PCRE2, 1, [Detected PCRE2])
 242     ;;
 243   [[1-5].*])
 244     AC_MSG_ERROR([Need at least pcre version 6.7])
 245     ;;
 246   [6.[0-6]*])
 247     AC_MSG_ERROR([Need at least pcre version 6.7])
 248     ;;
 249   esac
 250   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 251   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 252   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs8 2>/dev/null || $PCRE_CONFIG --libs`])
 253   APR_ADDTO(HTTPD_LIBS, [\$(PCRE_LIBS)])
 254 else
 255   AC_MSG_ERROR([pcre(2)-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 256 fi
 257 APACHE_SUBST(PCRE_LIBS)
 258
 259 AC_MSG_NOTICE([])
 260 AC_MSG_NOTICE([Configuring Apache httpd...])
 261 AC_MSG_NOTICE([])
 262
 263 dnl If the source dir is not equal to the build dir,
 264 dnl then we are running in VPATH mode.
 265
 266 APR_ADDTO(INCLUDES, [-I.])
 267
 268 if test "$abs_builddir" != "$abs_srcdir"; then
 269   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 270 fi
 271
 272 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 273
 274 # apr/apr-util --includes may pick up system paths for dependent
 275 # libraries, so ensure these are later in INCLUDES than local source
 276 # directories.
 277 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 278 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 279
 280 dnl Add in path to PCRE includes
 281 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 282
 283 save_CPPFLAGS="$CPPFLAGS"
 284 CPPFLAGS="$CPPFLAGS $PCRE_INCLUDES"
 285 AC_EGREP_CPP(yes,
 286 [
 287 #ifdef HAVE_PCRE2
 288 yes
 289 #else
 290 #include <pcre.h>
 291 #ifdef PCRE_DUPNAMES
 292 yes
 293 #endif
 294 #endif
 295 ],pcre_have_dupnames=yes,pcre_have_dupnames=no)
 296 if test "$pcre_have_dupnames" != "yes"; then
 297     AC_MSG_ERROR([pcre version does not support PCRE_DUPNAMES])
 298 fi
 299 CPPFLAGS="$save_CPPFLAGS"
 300
 301 AC_MSG_NOTICE([])
 302 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 303 AC_MSG_NOTICE([])
 304
 305 case $host in
 306   *os2*)
 307       # Use a custom made libtool replacement
 308       echo "using aplibtool"
 309       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 310       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 311       SH_LIBS="\$(ALL_LIBS)"
 312       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 313       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 314       MK_IMPLIB="emximp"
 315       other_targets="$other_targets os2core"
 316       INSTALL_PROG_FLAGS="-e .exe"
 317       SHLTCFLAGS=""
 318       LTCFLAGS=""
 319       ;;
 320   *)
 321       if test "x$LTFLAGS" = "x"; then
 322           LTFLAGS='--silent'
 323       fi
 324       my_libtool=`$apr_config --apr-libtool`
 325       LIBTOOL="$my_libtool \$(LTFLAGS)"
 326       libtoolversion=`$my_libtool --version`
 327       case $libtoolversion in
 328           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 329               SH_LIBTOOL='$(LIBTOOL)'
 330               SHLTCFLAGS="-prefer-pic"
 331               LTCFLAGS="-prefer-non-pic -static"
 332               ;;
 333           *)
 334               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 335               SHLTCFLAGS=""
 336               LTCFLAGS=""
 337               ;;
 338       esac
 339       ;;
 340 esac
 341 APACHE_SUBST(SHLTCFLAGS)
 342 APACHE_SUBST(LTCFLAGS)
 343
 344 case $host in
 345   *-apple-aux3*)
 346       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 347       ;;
 348   *os2-emx*)
 349       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 350       ;;
 351   *-linux-*)
 352       case `uname -r` in
 353         # Unserialized accept() was not recommended until Linux 2.2.
 354         [[01]].* | 2.[[01]]* )
 355             ;;
 356         * )
 357             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 358             ;;
 359       esac
 360       ;;
 361   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 362       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 363       ;;
 364   *-solaris2*)
 365       dnl This is a hack -- we should be using AC_TRY_RUN instead
 366       ap_platform_runtime_link_flag="-R"
 367       dnl solaris 8 and above don't have a thundering herd
 368       dnl not sure about rev's before this one.
 369       case `uname -r` in
 370         5.[[567]]*)
 371             ;;
 372         * )
 373             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 374             ;;
 375       esac
 376       ;;
 377   *cygwin*)
 378       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 379       ;;
 380   *mingw32*)
 381       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 382       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 383       APR_SETIFNULL(ac_cv_func_times, [no])
 384       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 385       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 386       ;;
 387   *aix*)
 388       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 389       if test $aixver -ge 4320; then
 390         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 391       fi
 392       ;;
 393   *os390*)
 394       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 395       ;;
 396 esac
 397
 398 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 399
 400 dnl
 401 dnl Process command line arguments. This is done early in the process so the
 402 dnl user can get feedback quickly in case of an error.
 403 dnl
 404 dnl ### need to move some of the arguments "up here"
 405
 406 dnl ## Check for programs
 407
 408 AC_PATH_PROG(RM, rm)
 409 AC_PATH_PROG(PKGCONFIG, pkg-config)
 410 AC_PATH_PROG(RSYNC, rsync)
 411 AC_PROG_AWK
 412 AC_PROG_LN_S
 413 AC_CHECK_TOOL(RANLIB, ranlib, true)
 414 dnl AC_PATH_PROG(PERL_PATH, perl)
 415 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 416
 417 # Hard-coded install programs
 418 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 419 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 420 APACHE_SUBST(MKINSTALLDIRS)
 421 APACHE_SUBST(INSTALL)
 422
 423 dnl Various OS checks that apparently set required flags
 424 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 425 AC_USE_SYSTEM_EXTENSIONS
 426 ], [
 427 AC_AIX
 428 AC_MINIX
 429 ])
 430
 431 AC_ISC_POSIX
 432
 433 # Ensure that satisfactory versions of apr and apr-util are
 434 # found if external copies are configured.
 435 if test "${apr_found}" = "yes"; then
 436   # Require at least APR 1.3.x otherwise fail
 437   APACHE_CHECK_APxVER([apr], 1, 3)
 438 fi
 439
 440 if test "${apu_found}" = "yes"; then
 441   # Require at least APR-util 1.3.x otherwise fail
 442   if test "${apr_found}" = "yes"; then
 443     # we need to add the APR includes to CPPFLAGS
 444     apu_ckver_CPPFLAGS="$CPPFLAGS"
 445     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 446     APACHE_CHECK_APxVER([apu], 1, 3)
 447     CPPFLAGS="$apu_ckver_CPPFLAGS"
 448   else
 449     APACHE_CHECK_APxVER([apu], 1, 3)
 450   fi
 451 fi
 452
 453 dnl Check for what we can generate dependency files with
 454 APR_CHECK_DEPEND
 455
 456 dnl ## Check for libraries
 457
 458 dnl ## Check for header files
 459
 460 dnl I think these are just used all over the place, so just check for
 461 dnl them at the base of the tree. If some are specific to a single
 462 dnl directory, they should be moved (Comment #Spoon)
 463
 464 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 465 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 466 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 467
 468 AC_HEADER_STDC
 469 AC_CHECK_HEADERS( \
 470 string.h \
 471 limits.h \
 472 unistd.h \
 473 sys/socket.h \
 474 pwd.h \
 475 grp.h \
 476 strings.h \
 477 sys/prctl.h \
 478 sys/processor.h \
 479 sys/sem.h \
 480 sys/sdt.h \
 481 sys/loadavg.h
 482 )
 483 AC_HEADER_SYS_WAIT
 484
 485 dnl ## Check for typedefs, structures, and compiler characteristics.
 486
 487 AC_C_CONST
 488
 489 dnl ## Check for library functions
 490 dnl ## sqrt() only needed in support/ab.c
 491 saved_LIBS="$LIBS"
 492 LIBS=""
 493 AC_SEARCH_LIBS(sqrt, m)
 494 MATH_LIBS="$LIBS"
 495 APACHE_SUBST(MATH_LIBS)
 496 LIBS="$saved_LIBS"
 497
 498 saved_LIBS="$LIBS"
 499 LIBS=""
 500 AC_SEARCH_LIBS(crypt, crypt)
 501 CRYPT_LIBS="$LIBS"
 502 APACHE_SUBST(CRYPT_LIBS)
 503 LIBS="$saved_LIBS"
 504
 505 dnl See Comment #Spoon
 506
 507 AC_CHECK_FUNCS( \
 508 getpwnam \
 509 getgrnam \
 510 initgroups \
 511 bindprocessor \
 512 prctl \
 513 timegm \
 514 getpgid \
 515 fopen64 \
 516 getloadavg
 517 )
 518
 519 dnl confirm that a void pointer is large enough to store a long integer
 520 APACHE_CHECK_VOID_PTR_LEN
 521
 522 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 523 [AC_TRY_RUN(#define _GNU_SOURCE
 524 #include <unistd.h>
 525 #include <sys/syscall.h>
 526 #include <sys/types.h>
 527 int main(int argc, char **argv) {
 528 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 529 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 530 if test "$ac_cv_gettid" = "yes"; then
 531     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 532 fi
 533
 534 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 535 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 536 [AC_TRY_COMPILE([#include <sys/types.h>
 537 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 538   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 539 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 540     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 541 fi
 542
 543 APACHE_CHECK_SYSTEMD
 544
 545 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 546
 547 case $host in
 548     *aix*)
 549         # for 32-bit builds, increase MAXDATA to allow lots of threads
 550         if test x$OBJECT_MODE != x64; then
 551             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 552         fi
 553         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 554         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 555         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 556         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 557         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 558         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 559         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 560         ;;
 561     *os390*)
 562         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 563         ;;
 564     *)
 565         OS_SPECIFIC_VARS=""
 566 esac
 567
 568 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 569         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 570         [PORT=80])
 571
 572 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 573         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 574         [SSLPORT=443])
 575
 576 DTRACE=true
 577 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 578 [
 579   enable_dtrace=$enableval
 580   if test "$enableval" = "yes"; then
 581     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 582     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 583   fi
 584 ],
 585 [
 586   enable_dtrace=no
 587 ])
 588
 589 dnl Disabled dtrace build for now.
 590 enable_dtrace=no
 591
 592 case $host in
 593   *-solaris2*)
 594     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 595         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 596                   [Enable DTrace probes])
 597         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 598         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 599     fi
 600     ;;
 601 esac
 602
 603 APACHE_SUBST(DTRACE)
 604
 605 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 606 [
 607     if test "$enableval" = "yes"; then
 608         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 609                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 610         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 611     fi
 612 ])dnl
 613
 614 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 615 [
 616     if test "$enableval" = "yes"; then
 617         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 618                   [Allow modules to run hook after a fatal exception])
 619     fi
 620 ])dnl
 621
 622 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 623 [
 624   LOAD_ALL_MODULES=$enableval
 625   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 626 ],
 627 [
 628   LOAD_ALL_MODULES="no"
 629 ])
 630
 631 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 632 [
 633   if test "$enableval" = "yes"; then
 634     APR_ADDTO(NOTEST_CPPFLAGS, -DAP_DEBUG)
 635     if test "$GCC" = "yes"; then
 636       APACHE_ADD_GCC_CFLAG([-std=c89])
 637       APACHE_ADD_GCC_CFLAG([-Werror])
 638       APACHE_ADD_GCC_CFLAG([-Wall])
 639       APACHE_ADD_GCC_CFLAG([-Wstrict-prototypes])
 640       APACHE_ADD_GCC_CFLAG([-Wmissing-prototypes])
 641       APACHE_ADD_GCC_CFLAG([-Wmissing-declarations])
 642       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 643       APACHE_ADD_GCC_CFLAG([-Wpointer-arith])
 644       APACHE_ADD_GCC_CFLAG([-Wformat])
 645       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 646       APACHE_ADD_GCC_CFLAG([-Wunused])
 647     elif test "$AIX_XLC" = "yes"; then
 648       APR_ADDTO(NOTEST_CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 649     fi
 650     if test "x$enable_load_all_modules" = "x"; then
 651       LOAD_ALL_MODULES=yes
 652       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 653     fi
 654     if test "x$enable_bucketeer" = "x"; then
 655       enable_bucketeer=yes
 656       AC_MSG_NOTICE([Maintainer mode setting "enable_bucketeer" to yes])
 657     fi
 658   fi
 659 ])dnl
 660
 661 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 662 [
 663   if test "$enableval" = "yes"; then
 664     APR_ADDTO(NOTEST_CPPFLAGS, -DAP_DEBUG)
 665     if test "$GCC" = "yes"; then
 666       APACHE_ADD_GCC_CFLAG([-O0])
 667       APACHE_ADD_GCC_CFLAG([-Wall])
 668       APACHE_ADD_GCC_CFLAG([-Wstrict-prototypes])
 669       APACHE_ADD_GCC_CFLAG([-Wmissing-prototypes])
 670       APACHE_ADD_GCC_CFLAG([-Wmissing-declarations])
 671       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 672       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 673       APACHE_ADD_GCC_CFLAG([-Wpointer-arith])
 674       APACHE_ADD_GCC_CFLAG([-Wformat])
 675       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 676       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 677     elif test "$AIX_XLC" = "yes"; then
 678       APR_ADDTO(NOTEST_CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 679     fi
 680   fi
 681 ])dnl
 682
 683 dnl Conditionally enable PIE support for GNU toolchains.
 684 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 685 if test "$enable_pie" = "yes"; then
 686    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 687      save_CFLAGS=$CFLAGS
 688      save_LDFLAGS=$LDFLAGS
 689      CFLAGS="$CFLAGS -fPIE"
 690      LDFLAGS="$LDFLAGS -pie"
 691      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 692       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 693      CFLAGS=$save_CFLAGS
 694      LDFLAGS=$save_LDFLAGS
 695    ])
 696    if test "$ap_cv_cc_pie" = "yes"; then
 697      PICFLAGS="-fPIE"
 698      PILDFLAGS="-pie"
 699    else
 700      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 701    fi
 702 fi
 703 APACHE_SUBST(PICFLAGS)
 704 APACHE_SUBST(PILDFLAGS)
 705
 706 AC_ARG_WITH(valgrind,
 707   [  --with-valgrind[[=DIR]]   Enable code to reduce valgrind false positives
 708                           (optionally: set path to valgrind headers) ],
 709   [ if test "$withval" != no; then
 710       if test "$withval" = yes; then
 711         withval=/usr/include/valgrind
 712       fi
 713       APR_ADDTO(CPPFLAGS, -I$withval)
 714       AC_CHECK_HEADERS(valgrind.h memcheck.h)
 715       APR_IFALLYES(header:valgrind.h header:memcheck.h,
 716         [AC_DEFINE(HAVE_VALGRIND, 1, [Compile in valgrind support]) ],
 717         [AC_MSG_ERROR(valgrind headers not found) ]
 718       )
 719     fi ]
 720 )
 721
 722 dnl Enable the unit test executable if Check is installed.
 723 dnl TODO: at the moment, only pkg-config discovery is supported.
 724 AC_MSG_CHECKING([for Check to enable unit tests])
 725 if test "x$PKGCONFIG" != "x" && `$PKGCONFIG --atleast-version='0.9.12' check`; then
 726   UNITTEST_CFLAGS=`$PKGCONFIG --cflags check`
 727   UNITTEST_LIBS=`$PKGCONFIG --libs check`
 728   other_targets="$other_targets test/httpdunit"
 729
 730   AC_MSG_RESULT([yes])
 731 else
 732   AC_MSG_RESULT([no])
 733 fi
 734 APACHE_SUBST(UNITTEST_CFLAGS)
 735 APACHE_SUBST(UNITTEST_LIBS)
 736
 737
 738 prefix="$orig_prefix"
 739 APACHE_ENABLE_MODULES
 740
 741 dnl reading config stubs
 742 esyscmd(./build/config-stubs .)
 743
 744 APACHE_SUBST(progname)
 745 APACHE_SUBST(OS)
 746 APACHE_SUBST(OS_DIR)
 747 APACHE_SUBST(BUILTIN_LIBS)
 748 APACHE_SUBST(SHLIBPATH_VAR)
 749 APACHE_SUBST(OS_SPECIFIC_VARS)
 750 APACHE_SUBST(HTTPD_LIBS)
 751
 752 PRE_SHARED_CMDS='echo ""'
 753 POST_SHARED_CMDS='echo ""'
 754
 755 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 756
 757 if test "$apache_need_shared" = "yes"; then
 758   if test -f $ac_aux_dir/ltconfig; then
 759     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 760   fi
 761   shared_build="shared-build"
 762 fi
 763
 764 dnl enable_so tells us if *any* modules can be built as DSOs
 765
 766 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 767   case $host in
 768     *-ibm-aix*)
 769       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 770       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 771       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 772       ;;
 773     *os390)
 774       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 775       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 776   esac
 777   MOD_SO_ENABLED=yes
 778 fi
 779 AC_SUBST(MOD_SO_ENABLED)
 780
 781 APACHE_SUBST(PRE_SHARED_CMDS)
 782 APACHE_SUBST(POST_SHARED_CMDS)
 783 APACHE_SUBST(shared_build)
 784
 785 AC_ARG_WITH(program-name,
 786 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 787   progname="$withval" ], [
 788   progname="httpd"] )
 789
 790 # SuExec parameters
 791 AC_ARG_WITH(suexec-bin,
 792 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 793   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 794 ] )
 795
 796 AC_ARG_WITH(suexec-caller,
 797 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 798   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 799
 800 AC_ARG_WITH(suexec-userdir,
 801 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 802   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 803
 804 AC_ARG_WITH(suexec-docroot,
 805 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 806   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 807
 808 AC_ARG_WITH(suexec-uidmin,
 809 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 810   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 811
 812 AC_ARG_WITH(suexec-gidmin,
 813 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 814   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 815
 816 AC_ARG_WITH(suexec-logfile,
 817 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 818   if test "x$withval" = "xyes"; then
 819     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 820   elif test "x$withval" != "xno"; then
 821     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 822   fi
 823 ])
 824
 825 AC_ARG_WITH(suexec-syslog,
 826 APACHE_HELP_STRING(--with-suexec-syslog,Use syslog for suexec logging),[
 827   if test $withval = "yes"; then
 828     if test "x${with_suexec_logfile}" != "xno"; then
 829       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 830       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 831     fi
 832     AC_CHECK_FUNCS([vsyslog], [], [
 833        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 834     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 835   fi
 836 ])
 837
 838
 839 AC_ARG_WITH(suexec-safepath,
 840 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 841   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 842
 843 AC_ARG_WITH(suexec-umask,
 844 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 845   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 846
 847 INSTALL_SUEXEC=setuid
 848 AC_ARG_ENABLE([suexec-capabilities],
 849 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 850   if test "$enableval" = "yes"; then
 851     INSTALL_SUEXEC=caps
 852     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 853               [Enable if suexec is installed with Linux capabilities, not setuid])
 854   fi
 855 ])
 856 APACHE_SUBST(INSTALL_SUEXEC)
 857
 858 dnl APR should go after the other libs, so the right symbols can be picked up
 859 if test x${apu_found} != xobsolete; then
 860   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 861 fi
 862 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 863 APACHE_SUBST(AP_LIBS)
 864 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 865 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 866
 867 AC_DEFINE(AP_USING_AUTOCONF, 1,
 868                 [Using autoconf to configure Apache])
 869
 870 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 871     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 872               [This platform doesn't suffer from the thundering herd problem])
 873 fi
 874
 875 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 876     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 877               [Listening sockets are non-blocking when there are more than 1])
 878 fi
 879
 880 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 881
 882 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 883 [
 884   v4mapped=$enableval
 885 ],
 886 [
 887     case $host in
 888     *freebsd[[1234]].*)
 889         v4mapped=yes
 890         ;;
 891     *freebsd*|*netbsd*|*openbsd*)
 892         v4mapped=no
 893         ;;
 894     *)
 895         v4mapped=yes
 896         ;;
 897     esac
 898     if ap_mpm_is_enabled winnt; then
 899         dnl WinNT MPM doesn't support this.
 900         v4mapped=no
 901     fi
 902 ])
 903
 904 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 905     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 906               [Allow IPv4 connections on IPv6 listening sockets])
 907 fi
 908
 909 AC_ARG_ENABLE(bsd-makefiles,APACHE_HELP_STRING(--enable-bsd-makefiles,use BSD Makefile syntax),
 910 [
 911   FORCE_BSD_MAKEFILE=$enableval
 912   AC_MSG_NOTICE([Setting "FORCE_BSD_MAKEFILE" to $FORCE_BSD_MAKEFILE])
 913 ],
 914 [
 915   FORCE_BSD_MAKEFILE="auto"
 916 ])
 917
 918 AC_ARG_WITH([test-suite],
 919     APACHE_HELP_STRING([--with-test-suite=PATH], [enable in-tree 'make check' with the given Apache::Test suite location]),
 920     [
 921         if test "x$withval" = "xyes"; then
 922             AC_MSG_ERROR([option --with-test-suite requires a directory]);
 923         else
 924             test -f "$withval/Makefile.PL" || AC_MSG_ERROR([--with-test-suite directory $withval does not contain the expected Makefile.PL])
 925             TEST_SUITE_LOCATION="$withval"
 926             WITH_TEST_SUITE=yes
 927         fi
 928     ],
 929     [ WITH_TEST_SUITE=no ]
 930 )
 931
 932 APACHE_SUBST(TEST_SUITE_LOCATION)
 933 APACHE_SUBST(WITH_TEST_SUITE)
 934
 935 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 936 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 937 APACHE_FAST_OUTPUT(support/Makefile)
 938
 939 if test -d ./test; then
 940     APACHE_FAST_OUTPUT(test/Makefile)
 941 fi
 942
 943 dnl ## Finalize the variables
 944 AC_MSG_NOTICE([])
 945 AC_MSG_NOTICE([Restore user-defined environment settings...])
 946 AC_MSG_NOTICE([])
 947
 948 APACHE_CONF_SEL_CC=${CC}
 949 APACHE_CONF_SEL_CFLAGS="${CFLAGS} ${EXTRA_CFLAGS} ${NOTEST_CFLAGS}"
 950 APACHE_CONF_SEL_CPPFLAGS="${CPPFLAGS} ${EXTRA_CPPFLAGS} ${NOTEST_CPPFLAGS}"
 951 APACHE_CONF_SEL_LDFLAGS="${LDFLAGS} ${EXTRA_LDFLAGS} ${NOTEST_LDFLAGS}"
 952 APACHE_CONF_SEL_LIBS="${LIBS} ${EXTRA_LIBS} ${NOTEST_LIBS}"
 953 APACHE_CONF_SEL_CPP=${CPP}
 954
 955 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 956 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 957 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 958 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 959 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 960 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 961
 962 AC_MSG_NOTICE([])
 963 AC_MSG_NOTICE([Construct makefiles and header files...])
 964 AC_MSG_NOTICE([])
 965
 966 APACHE_GEN_CONFIG_VARS
 967
 968 dnl ## Build modules.c
 969 rm -f modules.c
 970 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 971
 972 APR_EXPAND_VAR(ap_prefix, $prefix)
 973 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 974         [Root directory of the Apache install area])
 975 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 976         [Location of the config file, relative to the Apache root directory])
 977 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 978         [Location of the MIME types config file, relative to the Apache root directory])
 979
 980 perlbin=`$ac_aux_dir/PrintPath perl`
 981 if test "x$perlbin" = "x"; then
 982     perlbin="/replace/with/path/to/perl/interpreter"
 983 fi
 984 AC_SUBST(perlbin)
 985
 986 dnl If we are running on a BSD variant, see if we need to use the BSD .include syntax.
 987
 988 ap_make_include=include
 989 ap_make_ifdef=ifdef
 990 ap_make_else=else
 991 ap_make_endif=endif
 992 ap_make_delimiter=' '
 993 if test "x$FORCE_BSD_MAKEFILE" = "xno"; then
 994   BSD_MAKEFILE=no
 995 elif test "x$FORCE_BSD_MAKEFILE" = "xyes"; then
 996   BSD_MAKEFILE=yes
 997 else
 998   case $host in
 999   *bsd*)
1000       # Check whether they've installed GNU make
1001       if make --version > /dev/null 2>&1; then
1002           BSD_MAKEFILE=no
1003       elif gmake --version > /dev/null 2>&1; then
1004           BSD_MAKEFILE=no
1005       else
1006           BSD_MAKEFILE=yes
1007       fi
1008       ;;
1009   *)
1010       BSD_MAKEFILE=no
1011       ;;
1012   esac
1013 fi
1014 if test "x$BSD_MAKEFILE" = "xyes"; then
1015   ap_make_include=.include
1016   ap_make_ifdef=.ifdef
1017   ap_make_else=.else
1018   ap_make_endif=.endif
1019   ap_make_delimiter='"'
1020 fi
1021 AC_MSG_NOTICE([using BSD Makefile syntax... $BSD_MAKEFILE])
1022
1023 AC_SUBST(ap_make_include)
1024 AC_SUBST(ap_make_ifdef)
1025 AC_SUBST(ap_make_else)
1026 AC_SUBST(ap_make_endif)
1027 AC_SUBST(ap_make_delimiter)
1028
1029 dnl Ensure that docs/conf is created.
1030 test -d docs/conf||$mkdir_p docs/conf
1031
1032 AC_CONFIG_FILES(docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf docs/conf/extra/httpd-macro.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh)
1033 AC_CONFIG_COMMANDS([default], [true], [APACHE_GEN_MAKEFILES])
1034 AC_OUTPUT
1035
1036 AC_MSG_NOTICE([summary of build options:
1037
1038     Server Version: ${HTTPD_VERSION}
1039     Install prefix: ${prefix}
1040     C compiler:     ${APACHE_CONF_SEL_CC}
1041     CFLAGS:         ${APACHE_CONF_SEL_CFLAGS}
1042     CPPFLAGS:       ${APACHE_CONF_SEL_CPPFLAGS}
1043     LDFLAGS:        ${APACHE_CONF_SEL_LDFLAGS}
1044     LIBS:           ${APACHE_CONF_SEL_LIBS}
1045     C preprocessor: ${APACHE_CONF_SEL_CPP}
1046 ])