granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2014, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sysv5*) template=unixware ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-bugs@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Add non-standard directories to the include path
 113 #
 114 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 115
 116
 117 #
 118 # Add non-standard directories to the library search path
 119 #
 120 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 121              [LIBRARY_DIRS=$withval])
 122
 123 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 124              [LIBRARY_DIRS=$withval])
 125
 126
 127 #
 128 # 64-bit integer date/time storage: enabled by default.
 129 #
 130 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 131 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 132               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 133                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 134 AC_MSG_RESULT([$enable_integer_datetimes])
 135
 136
 137 #
 138 # NLS
 139 #
 140 AC_MSG_CHECKING([whether NLS is wanted])
 141 PGAC_ARG_OPTARG(enable, nls,
 142                 [LANGUAGES], [enable Native Language Support],
 143                 [],
 144                 [WANTED_LANGUAGES=$enableval],
 145                 [AC_DEFINE(ENABLE_NLS, 1,
 146                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 147 AC_MSG_RESULT([$enable_nls])
 148 AC_SUBST(enable_nls)
 149 AC_SUBST(WANTED_LANGUAGES)
 150
 151 #
 152 # Default port number (--with-pgport), default 5432
 153 #
 154 AC_MSG_CHECKING([for default port number])
 155 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 156              [default_port=$withval],
 157              [default_port=5432])
 158 AC_MSG_RESULT([$default_port])
 159 # Need both of these because some places want an integer and some a string
 160 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 161 [Define to the default TCP port number on which the server listens and
 162 to which clients will try to connect.  This can be overridden at run-time,
 163 but it's convenient if your clients have the right default compiled in.
 164 (--with-pgport=PORTNUM)])
 165 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 166                    [Define to the default TCP port number as a string constant.])
 167 AC_SUBST(default_port)
 168
 169 #
 170 # '-rpath'-like feature can be disabled
 171 #
 172 PGAC_ARG_BOOL(enable, rpath, yes,
 173               [do not embed shared library search path in executables])
 174 AC_SUBST(enable_rpath)
 175
 176 #
 177 # Spinlocks
 178 #
 179 PGAC_ARG_BOOL(enable, spinlocks, yes,
 180               [do not use spinlocks])
 181
 182 #
 183 # --enable-debug adds -g to compiler flags
 184 #
 185 PGAC_ARG_BOOL(enable, debug, no,
 186               [build with debugging symbols (-g)])
 187 AC_SUBST(enable_debug)
 188
 189 #
 190 # --enable-profiling enables gcc profiling
 191 #
 192 PGAC_ARG_BOOL(enable, profiling, no,
 193               [build with profiling enabled ])
 194
 195 #
 196 # --enable-coverage enables generation of code coverage metrics with gcov
 197 #
 198 PGAC_ARG_BOOL(enable, coverage, no,
 199               [build with coverage testing instrumentation],
 200 [AC_CHECK_PROGS(GCOV, gcov)
 201 if test -z "$GCOV"; then
 202   AC_MSG_ERROR([gcov not found])
 203 fi
 204 AC_CHECK_PROGS(LCOV, lcov)
 205 if test -z "$LCOV"; then
 206   AC_MSG_ERROR([lcov not found])
 207 fi
 208 AC_CHECK_PROGS(GENHTML, genhtml)
 209 if test -z "$GENHTML"; then
 210   AC_MSG_ERROR([genhtml not found])
 211 fi])
 212 AC_SUBST(enable_coverage)
 213
 214 #
 215 # DTrace
 216 #
 217 PGAC_ARG_BOOL(enable, dtrace, no,
 218               [build with DTrace support],
 219 [AC_CHECK_PROGS(DTRACE, dtrace)
 220 if test -z "$DTRACE"; then
 221   AC_MSG_ERROR([dtrace not found])
 222 fi
 223 AC_SUBST(DTRACEFLAGS)])
 224 AC_SUBST(enable_dtrace)
 225
 226 #
 227 # Block size
 228 #
 229 AC_MSG_CHECKING([for block size])
 230 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 231              [blocksize=$withval],
 232              [blocksize=8])
 233 case ${blocksize} in
 234   1) BLCKSZ=1024;;
 235   2) BLCKSZ=2048;;
 236   4) BLCKSZ=4096;;
 237   8) BLCKSZ=8192;;
 238  16) BLCKSZ=16384;;
 239  32) BLCKSZ=32768;;
 240   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 241 esac
 242 AC_MSG_RESULT([${blocksize}kB])
 243
 244 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 245  Size of a disk block --- this also limits the size of a tuple.  You
 246  can set it bigger if you need bigger tuples (although TOAST should
 247  reduce the need to have large tuples, since fields can be spread
 248  across multiple tuples).
 249
 250  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 251  is currently 2^15 (32768).  This is determined by the 15-bit widths
 252  of the lp_off and lp_len fields in ItemIdData (see
 253  include/storage/itemid.h).
 254
 255  Changing BLCKSZ requires an initdb.
 256 ])
 257
 258 #
 259 # Relation segment size
 260 #
 261 AC_MSG_CHECKING([for segment size])
 262 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 263              [segsize=$withval],
 264              [segsize=1])
 265 # this expression is set up to avoid unnecessary integer overflow
 266 # blocksize is already guaranteed to be a factor of 1024
 267 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 268 test $? -eq 0 || exit 1
 269 AC_MSG_RESULT([${segsize}GB])
 270
 271 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 272  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 273  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 274  relations bigger than that are divided into multiple files.
 275
 276  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 277  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 278  have large file support enabled.  By default, we make the limit 1 GB
 279  to avoid any possible integer-overflow problems within the OS.
 280  A limit smaller than necessary only means we divide a large
 281  relation into more chunks than necessary, so it seems best to err
 282  in the direction of a small limit.
 283
 284  A power-of-2 value is recommended to save a few cycles in md.c,
 285  but is not absolutely required.
 286
 287  Changing RELSEG_SIZE requires an initdb.
 288 ])
 289
 290 #
 291 # WAL block size
 292 #
 293 AC_MSG_CHECKING([for WAL block size])
 294 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 295              [wal_blocksize=$withval],
 296              [wal_blocksize=8])
 297 case ${wal_blocksize} in
 298   1) XLOG_BLCKSZ=1024;;
 299   2) XLOG_BLCKSZ=2048;;
 300   4) XLOG_BLCKSZ=4096;;
 301   8) XLOG_BLCKSZ=8192;;
 302  16) XLOG_BLCKSZ=16384;;
 303  32) XLOG_BLCKSZ=32768;;
 304  64) XLOG_BLCKSZ=65536;;
 305   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 306 esac
 307 AC_MSG_RESULT([${wal_blocksize}kB])
 308
 309 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 310  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 311  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 312  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 313  buffers, else direct I/O may fail.
 314
 315  Changing XLOG_BLCKSZ requires an initdb.
 316 ])
 317
 318 #
 319 # WAL segment size
 320 #
 321 AC_MSG_CHECKING([for WAL segment size])
 322 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 323              [wal_segsize=$withval],
 324              [wal_segsize=16])
 325 case ${wal_segsize} in
 326   1) ;;
 327   2) ;;
 328   4) ;;
 329   8) ;;
 330  16) ;;
 331  32) ;;
 332  64) ;;
 333   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_segsize}MB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 338  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 339  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 340  XLOG_BLCKSZ).
 341
 342  Changing XLOG_SEG_SIZE requires an initdb.
 343 ])
 344
 345 #
 346 # C compiler
 347 #
 348
 349 # For historical reasons you can also use --with-CC to specify the C compiler
 350 # to use, although the standard way to do this is to set the CC environment
 351 # variable.
 352 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 353
 354 case $template in
 355   aix) pgac_cc_list="gcc xlc";;
 356     *) pgac_cc_list="gcc cc";;
 357 esac
 358
 359 AC_PROG_CC([$pgac_cc_list])
 360
 361 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 362 # but has idiosyncrasies of its own.  We assume icc will define
 363 # __INTEL_COMPILER regardless of CFLAGS.
 364 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 365 choke me
 366 @%:@endif], [ICC=[yes]], [ICC=[no]])
 367
 368 # Check if it's Sun Studio compiler. We assume that
 369 # __SUNPRO_C will be defined for Sun Studio compilers
 370 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 371 choke me
 372 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 373
 374 AC_SUBST(SUN_STUDIO_CC)
 375
 376 unset CFLAGS
 377
 378 #
 379 # Read the template
 380 #
 381 . "$srcdir/src/template/$template" || exit
 382
 383 # CFLAGS are selected so:
 384 # If the user specifies something in the environment, that is used.
 385 # else:  If the template file set something, that is used.
 386 # else:  If coverage was enabled, don't set anything.
 387 # else:  If the compiler is GCC, then we use -O2.
 388 # else:  If the compiler is something else, then we use -O, unless debugging.
 389
 390 if test "$ac_env_CFLAGS_set" = set; then
 391   CFLAGS=$ac_env_CFLAGS_value
 392 elif test "${CFLAGS+set}" = set; then
 393   : # (keep what template set)
 394 elif test "$enable_coverage" = yes; then
 395   : # no optimization by default
 396 elif test "$GCC" = yes; then
 397   CFLAGS="-O2"
 398 else
 399   # if the user selected debug mode, don't use -O
 400   if test "$enable_debug" != yes; then
 401     CFLAGS="-O"
 402   fi
 403 fi
 404
 405 # set CFLAGS_VECTOR from the environment, if available
 406 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 407   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 408 fi
 409
 410 # Some versions of GCC support some additional useful warning flags.
 411 # Check whether they are supported, and add them to CFLAGS if so.
 412 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 413 # but has its own.  Also check other compiler-specific flags here.
 414
 415 if test "$GCC" = yes -a "$ICC" = no; then
 416   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 417   # These work in some but not all gcc versions
 418   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 419   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 420   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 421   # This was included in -Wall/-Wformat in older GCC versions
 422   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 423   # Disable strict-aliasing rules; needed for gcc 3.3+
 424   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 425   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 426   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 427   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 428   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 429   # Optimization flags for specific files that benefit from vectorization
 430   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 431   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 432 elif test "$ICC" = yes; then
 433   # Intel's compiler has a bug/misoptimization in checking for
 434   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 435   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 436   # Make sure strict aliasing is off (though this is said to be the default)
 437   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 438 elif test "$PORTNAME" = "aix"; then
 439   # AIX's xlc has to have strict aliasing turned off too
 440   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 441 elif test "$PORTNAME" = "hpux"; then
 442   # On some versions of HP-UX, libm functions do not set errno by default.
 443   # Fix that by using +Olibmerrno if the compiler recognizes it.
 444   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 445 fi
 446
 447 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 448
 449 # supply -g if --enable-debug
 450 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 451   CFLAGS="$CFLAGS -g"
 452 fi
 453
 454 # enable code coverage if --enable-coverage
 455 if test "$enable_coverage" = yes; then
 456   if test "$GCC" = yes; then
 457     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 458   else
 459     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 460   fi
 461 fi
 462
 463 # enable profiling if --enable-profiling
 464 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 465   if test "$GCC" = yes; then
 466     AC_DEFINE([PROFILE_PID_DIR], 1,
 467            [Define to 1 to allow profiling output to be saved separately for each process.])
 468     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 469   else
 470     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 471   fi
 472 fi
 473
 474 # We already have this in Makefile.win32, but configure needs it too
 475 if test "$PORTNAME" = "win32"; then
 476   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 477 fi
 478
 479 # Check if the compiler still works with the template settings
 480 AC_MSG_CHECKING([whether the C compiler still works])
 481 AC_TRY_LINK([], [return 0;],
 482   [AC_MSG_RESULT(yes)],
 483   [AC_MSG_RESULT(no)
 484    AC_MSG_ERROR([cannot proceed])])
 485
 486 # Defend against gcc -ffast-math
 487 if test "$GCC" = yes; then
 488 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 489 choke me
 490 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 491 fi
 492
 493 AC_PROG_CPP
 494 AC_SUBST(GCC)
 495
 496
 497 #
 498 # Set up TAS assembly code if needed; the template file has now had its
 499 # chance to request this.
 500 #
 501 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 502
 503 if test "$need_tas" = yes ; then
 504   TAS=tas.o
 505 else
 506   TAS=""
 507 fi
 508 AC_SUBST(TAS)
 509
 510
 511 #
 512 # Automatic dependency tracking
 513 #
 514 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 515               [autodepend=yes])
 516 AC_SUBST(autodepend)
 517
 518
 519 #
 520 # Enable assert checks
 521 #
 522 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 523               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 524                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 525
 526
 527 #
 528 # Include directories
 529 #
 530 ac_save_IFS=$IFS
 531 IFS="${IFS}${PATH_SEPARATOR}"
 532 # SRCH_INC comes from the template file
 533 for dir in $with_includes $SRCH_INC; do
 534   if test -d "$dir"; then
 535     INCLUDES="$INCLUDES -I$dir"
 536   else
 537     AC_MSG_WARN([*** Include directory $dir does not exist.])
 538   fi
 539 done
 540 IFS=$ac_save_IFS
 541 AC_SUBST(INCLUDES)
 542
 543
 544 #
 545 # Library directories
 546 #
 547 ac_save_IFS=$IFS
 548 IFS="${IFS}${PATH_SEPARATOR}"
 549 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 550 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 551   if test -d "$dir"; then
 552     LIBDIRS="$LIBDIRS -L$dir"
 553   else
 554     AC_MSG_WARN([*** Library directory $dir does not exist.])
 555   fi
 556 done
 557 IFS=$ac_save_IFS
 558
 559 #
 560 # Enable thread-safe client libraries
 561 #
 562 AC_MSG_CHECKING([allow thread-safe client libraries])
 563 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 564 if test "$enable_thread_safety" = yes; then
 565   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 566           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 567 fi
 568 AC_MSG_RESULT([$enable_thread_safety])
 569 AC_SUBST(enable_thread_safety)
 570
 571 #
 572 # Optionally build Tcl modules (PL/Tcl)
 573 #
 574 AC_MSG_CHECKING([whether to build with Tcl])
 575 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 576 AC_MSG_RESULT([$with_tcl])
 577 AC_SUBST([with_tcl])
 578
 579 # We see if the path to the Tcl/Tk configuration scripts is specified.
 580 # This will override the use of tclsh to find the paths to search.
 581
 582 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 583
 584 #
 585 # Optionally build Perl modules (PL/Perl)
 586 #
 587 AC_MSG_CHECKING([whether to build Perl modules])
 588 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 589 AC_MSG_RESULT([$with_perl])
 590 AC_SUBST(with_perl)
 591
 592 #
 593 # Optionally build Python modules (PL/Python)
 594 #
 595 AC_MSG_CHECKING([whether to build Python modules])
 596 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 597 AC_MSG_RESULT([$with_python])
 598 AC_SUBST(with_python)
 599
 600 #
 601 # GSSAPI
 602 #
 603 AC_MSG_CHECKING([whether to build with GSSAPI support])
 604 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 605 [
 606   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 607   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 608 ])
 609 AC_MSG_RESULT([$with_gssapi])
 610
 611
 612 AC_SUBST(krb_srvtab)
 613
 614
 615 #
 616 # Kerberos configuration parameters
 617 #
 618 PGAC_ARG_REQ(with, krb-srvnam,
 619              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 620              [],
 621              [with_krb_srvnam="postgres"])
 622 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 623                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 624
 625
 626 #
 627 # PAM
 628 #
 629 AC_MSG_CHECKING([whether to build with PAM support])
 630 PGAC_ARG_BOOL(with, pam, no,
 631               [build with PAM support],
 632               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 633 AC_MSG_RESULT([$with_pam])
 634
 635
 636 #
 637 # LDAP
 638 #
 639 AC_MSG_CHECKING([whether to build with LDAP support])
 640 PGAC_ARG_BOOL(with, ldap, no,
 641               [build with LDAP support],
 642               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 643 AC_MSG_RESULT([$with_ldap])
 644
 645
 646 #
 647 # Bonjour
 648 #
 649 AC_MSG_CHECKING([whether to build with Bonjour support])
 650 PGAC_ARG_BOOL(with, bonjour, no,
 651               [build with Bonjour support],
 652               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 653 AC_MSG_RESULT([$with_bonjour])
 654
 655
 656 #
 657 # OpenSSL
 658 #
 659 AC_MSG_CHECKING([whether to build with OpenSSL support])
 660 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 661               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 662 AC_MSG_RESULT([$with_openssl])
 663 AC_SUBST(with_openssl)
 664
 665 #
 666 # SELinux
 667 #
 668 AC_MSG_CHECKING([whether to build with SELinux support])
 669 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 670 AC_SUBST(with_selinux)
 671 AC_MSG_RESULT([$with_selinux])
 672
 673 #
 674 # Readline
 675 #
 676 PGAC_ARG_BOOL(with, readline, yes,
 677               [do not use GNU Readline nor BSD Libedit for editing])
 678 # readline on MinGW has problems with backslashes in psql and other bugs.
 679 # This is particularly a problem with non-US code pages.
 680 # Therefore disable its use until we understand the cause. 2004-07-20
 681 if test "$PORTNAME" = "win32"; then
 682   if test "$with_readline" = yes; then
 683     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 684     with_readline=no
 685   fi
 686 fi
 687
 688
 689 #
 690 # Prefer libedit
 691 #
 692 PGAC_ARG_BOOL(with, libedit-preferred, no,
 693               [prefer BSD Libedit over GNU Readline])
 694
 695
 696 #
 697 # OSSP UUID library
 698 #
 699 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 700 AC_SUBST(with_ossp_uuid)
 701
 702
 703 #
 704 # XML
 705 #
 706 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 707               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 708
 709 if test "$with_libxml" = yes ; then
 710   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 711   if test -n "$XML2_CONFIG"; then
 712     for pgac_option in `$XML2_CONFIG --cflags`; do
 713       case $pgac_option in
 714         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 715       esac
 716     done
 717     for pgac_option in `$XML2_CONFIG --libs`; do
 718       case $pgac_option in
 719         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 720       esac
 721     done
 722   fi
 723 fi
 724
 725 AC_SUBST(with_libxml)
 726
 727 #
 728 # XSLT
 729 #
 730 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 731               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 732
 733
 734 AC_SUBST(with_libxslt)
 735
 736 #
 737 # tzdata
 738 #
 739 PGAC_ARG_REQ(with, system-tzdata,
 740              [DIR], [use system time zone data in DIR])
 741 AC_SUBST(with_system_tzdata)
 742
 743 #
 744 # Zlib
 745 #
 746 PGAC_ARG_BOOL(with, zlib, yes,
 747               [do not use Zlib])
 748 AC_SUBST(with_zlib)
 749
 750 #
 751 # Elf
 752 #
 753
 754 # Assume system is ELF if it predefines __ELF__ as 1,
 755 # otherwise believe host_os based default.
 756 case $host_os in
 757     freebsd1*|freebsd2*) elf=no;;
 758     freebsd3*|freebsd4*) elf=yes;;
 759 esac
 760
 761 AC_EGREP_CPP(yes,
 762 [#if __ELF__
 763   yes
 764 #endif
 765 ],
 766 [ELF_SYS=true],
 767 [if test "X$elf" = "Xyes" ; then
 768   ELF_SYS=true
 769 else
 770   ELF_SYS=
 771 fi])
 772 AC_SUBST(ELF_SYS)
 773
 774 #
 775 # Assignments
 776 #
 777
 778 CPPFLAGS="$CPPFLAGS $INCLUDES"
 779 LDFLAGS="$LDFLAGS $LIBDIRS"
 780
 781 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 782 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 783
 784 PGAC_PROG_LD
 785 AC_SUBST(LD)
 786 AC_SUBST(with_gnu_ld)
 787 case $host_os in sysv5*)
 788   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 789   [
 790     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 791     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 792     LDFLAGS=$pgac_save_LDFLAGS
 793   ])
 794   ld_R_works=$pgac_cv_prog_ld_R
 795   AC_SUBST(ld_R_works)
 796 esac
 797 AC_PROG_RANLIB
 798 PGAC_CHECK_STRIP
 799 AC_CHECK_TOOL(AR, ar, ar)
 800 if test "$PORTNAME" = "win32"; then
 801   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 802   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 803   AC_CHECK_TOOL(WINDRES, windres, windres)
 804 fi
 805
 806 AC_PROG_INSTALL
 807 # When Autoconf chooses install-sh as install program it tries to generate
 808 # a relative path to it in each makefile where it subsitutes it. This clashes
 809 # with our Makefile.global concept. This workaround helps.
 810 case $INSTALL in
 811   *install-sh*) install_bin='';;
 812   *) install_bin=$INSTALL;;
 813 esac
 814 AC_SUBST(install_bin)
 815
 816 AC_PATH_PROG(TAR, tar)
 817 AC_PROG_LN_S
 818 AC_PROG_AWK
 819 AC_PROG_MKDIR_P
 820 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 821 # a relative path to it in each makefile where it subsitutes it. This clashes
 822 # with our Makefile.global concept. This workaround helps.
 823 case $MKDIR_P in
 824   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 825 esac
 826
 827 PGAC_PATH_BISON
 828 PGAC_PATH_FLEX
 829
 830 PGAC_PATH_PERL
 831 if test "$with_perl" = yes; then
 832   if test -z "$PERL"; then
 833     AC_MSG_ERROR([Perl not found])
 834   fi
 835   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 836   PGAC_CHECK_PERL_EMBED_LDFLAGS
 837 fi
 838
 839 if test "$with_python" = yes; then
 840   PGAC_PATH_PYTHON
 841   PGAC_CHECK_PYTHON_EMBED_SETUP
 842 fi
 843
 844 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 845   AC_PATH_PROG(ZIC, zic)
 846   if test -z "$ZIC"; then
 847     AC_MSG_ERROR([
 848 When cross-compiling, either use the option --with-system-tzdata to use
 849 existing time-zone data, or set the environment variable ZIC to a zic
 850 program to use during the build.])
 851   fi
 852 fi
 853
 854
 855 ##
 856 ## Libraries
 857 ##
 858 ## Most libraries are included only if they demonstrably provide a function
 859 ## we need, but libm is an exception: always include it, because there are
 860 ## too many compilers that play cute optimization games that will break
 861 ## probes for standard functions such as pow().
 862 ##
 863
 864 AC_CHECK_LIB(m, main)
 865 AC_SEARCH_LIBS(setproctitle, util)
 866 AC_SEARCH_LIBS(dlopen, dl)
 867 AC_SEARCH_LIBS(socket, [socket wsock32])
 868 AC_SEARCH_LIBS(shl_load, dld)
 869 # We only use libld in port/dynloader/aix.c
 870 case $host_os in
 871      aix*)
 872         AC_SEARCH_LIBS(ldopen, ld)
 873         ;;
 874 esac
 875 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 876 AC_SEARCH_LIBS(crypt, crypt)
 877 AC_SEARCH_LIBS(shm_open, rt)
 878 AC_SEARCH_LIBS(shm_unlink, rt)
 879 # Solaris:
 880 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 881 # Required for thread_test.c on Solaris 2.5:
 882 # Other ports use it too (HP-UX) so test unconditionally
 883 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 884 # Cygwin:
 885 AC_SEARCH_LIBS(shmget, cygipc)
 886
 887 if test "$with_readline" = yes; then
 888   PGAC_CHECK_READLINE
 889   if test x"$pgac_cv_check_readline" = x"no"; then
 890     AC_MSG_ERROR([readline library not found
 891 If you have readline already installed, see config.log for details on the
 892 failure.  It is possible the compiler isn't looking in the proper directory.
 893 Use --without-readline to disable readline support.])
 894   fi
 895 fi
 896
 897 if test "$with_zlib" = yes; then
 898   AC_CHECK_LIB(z, inflate, [],
 899                [AC_MSG_ERROR([zlib library not found
 900 If you have zlib already installed, see config.log for details on the
 901 failure.  It is possible the compiler isn't looking in the proper directory.
 902 Use --without-zlib to disable zlib support.])])
 903 fi
 904
 905 if test "$enable_spinlocks" = yes; then
 906   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 907 else
 908   AC_MSG_WARN([
 909 *** Not using spinlocks will cause poor performance.])
 910 fi
 911
 912 if test "$with_gssapi" = yes ; then
 913   if test "$PORTNAME" != "win32"; then
 914     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 915                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 916   else
 917     LIBS="$LIBS -lgssapi32"
 918   fi
 919 fi
 920
 921 if test "$with_openssl" = yes ; then
 922   dnl Order matters!
 923   if test "$PORTNAME" != "win32"; then
 924      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 925      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 926   else
 927      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 928      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 929   fi
 930 fi
 931
 932 if test "$with_pam" = yes ; then
 933   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 934 fi
 935
 936 if test "$with_libxml" = yes ; then
 937   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 938 fi
 939
 940 if test "$with_libxslt" = yes ; then
 941   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 942 fi
 943
 944 # for contrib/sepgsql
 945 if test "$with_selinux" = yes; then
 946   AC_CHECK_LIB(selinux, security_compute_create_name, [],
 947                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
 948 fi
 949
 950 # for contrib/uuid-ossp
 951 if test "$with_ossp_uuid" = yes ; then
 952   AC_CHECK_LIB(ossp-uuid, uuid_export,
 953     [OSSP_UUID_LIBS="-lossp-uuid"],
 954     [AC_CHECK_LIB(uuid, uuid_export,
 955       [OSSP_UUID_LIBS="-luuid"],
 956       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 957 fi
 958 AC_SUBST(OSSP_UUID_LIBS)
 959
 960
 961 ##
 962 ## Header files
 963 ##
 964
 965 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 966 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
 967
 968 # On BSD, test for net/if.h will fail unless sys/socket.h
 969 # is included first.
 970 AC_CHECK_HEADERS(net/if.h, [], [],
 971 [AC_INCLUDES_DEFAULT
 972 #ifdef HAVE_SYS_SOCKET_H
 973 #include <sys/socket.h>
 974 #endif
 975 ])
 976
 977 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
 978 # is included first.
 979 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 980 [AC_INCLUDES_DEFAULT
 981 #include <sys/param.h>
 982 ])
 983
 984 # At least on IRIX, test for netinet/tcp.h will fail unless
 985 # netinet/in.h is included first.
 986 AC_CHECK_HEADERS(netinet/in.h)
 987 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 988 [AC_INCLUDES_DEFAULT
 989 #ifdef HAVE_NETINET_IN_H
 990 #include <netinet/in.h>
 991 #endif
 992 ])
 993
 994 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 995   AC_CHECK_HEADERS(readline/readline.h, [],
 996         [AC_CHECK_HEADERS(readline.h, [],
 997                 [AC_MSG_ERROR([readline header not found
 998 If you have readline already installed, see config.log for details on the
 999 failure.  It is possible the compiler isn't looking in the proper directory.
1000 Use --without-readline to disable readline support.])])])
1001   AC_CHECK_HEADERS(readline/history.h, [],
1002         [AC_CHECK_HEADERS(history.h, [],
1003                 [AC_MSG_ERROR([history header not found
1004 If you have readline already installed, see config.log for details on the
1005 failure.  It is possible the compiler isn't looking in the proper directory.
1006 Use --without-readline to disable readline support.])])])
1007 fi
1008
1009 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1010 # Some installations of libedit usurp /usr/include/readline/, which seems
1011 # bad practice, since in combined installations readline will have its headers
1012 # there.  We might have to resort to AC_EGREP checks to make sure we found
1013 # the proper header...
1014   AC_CHECK_HEADERS(editline/readline.h, [],
1015         [AC_CHECK_HEADERS(readline.h, [],
1016                 [AC_CHECK_HEADERS(readline/readline.h, [],
1017                         [AC_MSG_ERROR([readline header not found
1018 If you have libedit already installed, see config.log for details on the
1019 failure.  It is possible the compiler isn't looking in the proper directory.
1020 Use --without-readline to disable libedit support.])])])])
1021 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1022 # not be there at all.  Hence, don't complain if not found.  We must check
1023 # though, since in yet other versions it is an independent header.
1024   AC_CHECK_HEADERS(editline/history.h, [],
1025         [AC_CHECK_HEADERS(history.h, [],
1026                 [AC_CHECK_HEADERS(readline/history.h)])])
1027 fi
1028
1029 if test "$with_zlib" = yes; then
1030   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1031 If you have zlib already installed, see config.log for details on the
1032 failure.  It is possible the compiler isn't looking in the proper directory.
1033 Use --without-zlib to disable zlib support.])])
1034 fi
1035
1036 if test "$with_gssapi" = yes ; then
1037   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1038         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1039 fi
1040
1041 if test "$with_openssl" = yes ; then
1042   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1043   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1044 fi
1045
1046 if test "$with_pam" = yes ; then
1047   AC_CHECK_HEADERS(security/pam_appl.h, [],
1048                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1049                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1050 fi
1051
1052 if test "$with_libxml" = yes ; then
1053   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1054 fi
1055
1056 if test "$with_libxslt" = yes ; then
1057   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1058 fi
1059
1060 if test "$with_ldap" = yes ; then
1061   if test "$PORTNAME" != "win32"; then
1062      AC_CHECK_HEADERS(ldap.h, [],
1063                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1064   else
1065      AC_CHECK_HEADERS(winldap.h, [],
1066                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1067                       [AC_INCLUDES_DEFAULT
1068 #include <windows.h>
1069                       ])
1070   fi
1071 fi
1072
1073 if test "$with_bonjour" = yes ; then
1074   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1075 fi
1076
1077 # for contrib/uuid-ossp
1078 if test "$with_ossp_uuid" = yes ; then
1079   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1080     AC_CHECK_HEADERS(uuid.h, [],
1081       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1082 fi
1083
1084 if test "$PORTNAME" = "win32" ; then
1085    AC_CHECK_HEADERS(crtdefs.h)
1086 fi
1087
1088 ##
1089 ## Types, structures, compiler characteristics
1090 ##
1091
1092 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1093 AC_C_BIGENDIAN
1094 PGAC_C_INLINE
1095 AC_C_FLEXIBLE_ARRAY_MEMBER
1096 PGAC_C_SIGNED
1097 PGAC_C_FUNCNAME_SUPPORT
1098 PGAC_C_STATIC_ASSERT
1099 PGAC_C_TYPES_COMPATIBLE
1100 PGAC_C_BUILTIN_CONSTANT_P
1101 PGAC_C_BUILTIN_UNREACHABLE
1102 PGAC_C_VA_ARGS
1103 PGAC_STRUCT_TIMEZONE
1104 PGAC_UNION_SEMUN
1105 PGAC_STRUCT_SOCKADDR_UN
1106 PGAC_STRUCT_SOCKADDR_STORAGE
1107 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1108 PGAC_STRUCT_ADDRINFO
1109 AC_TYPE_INTPTR_T
1110 AC_TYPE_UINTPTR_T
1111 AC_TYPE_LONG_LONG_INT
1112
1113 PGAC_TYPE_LOCALE_T
1114
1115 AC_CHECK_TYPES([struct cmsgcred], [], [],
1116 [#include <sys/socket.h>
1117 #include <sys/param.h>
1118 #ifdef HAVE_SYS_UCRED_H
1119 #include <sys/ucred.h>
1120 #endif])
1121
1122 AC_CHECK_TYPES([struct option], [], [],
1123 [#ifdef HAVE_GETOPT_H
1124 #include <getopt.h>
1125 #endif])
1126
1127 if test "$with_zlib" = yes; then
1128   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1129   # did not).  While we could work around the lack of z_streamp, it
1130   # seems unwise to encourage people to use such old zlib versions...
1131   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1132 Use --without-zlib to disable zlib support.])],
1133                 [#include <zlib.h>])
1134 fi
1135
1136 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1137 case $host_cpu in
1138   ppc*|powerpc*)
1139     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1140     AC_TRY_COMPILE([],
1141         [int a = 0; int *p = &a; int r;
1142          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1143         [pgac_cv_have_ppc_mutex_hint=yes],
1144         [pgac_cv_have_ppc_mutex_hint=no])
1145     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1146     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1147         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1148     fi
1149   ;;
1150 esac
1151
1152 # Check largefile support.  You might think this is a system service not a
1153 # compiler characteristic, but you'd be wrong.  We must check this before
1154 # probing existence of related functions such as fseeko, since the largefile
1155 # defines can affect what is generated for that.
1156 if test "$PORTNAME" != "win32"; then
1157    AC_SYS_LARGEFILE
1158    # Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1159    # _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1160    # bug that causes readdir() to sometimes return EINVAL.  On later OS X
1161    # versions where the feature actually works, it's on by default anyway.
1162    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1163 fi
1164
1165 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1166 AC_CHECK_SIZEOF([off_t])
1167
1168 # If we don't have largefile support, can't handle segsize >= 2GB.
1169 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1170    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1171 fi
1172
1173
1174 ##
1175 ## Functions, global variables
1176 ##
1177
1178 PGAC_VAR_INT_TIMEZONE
1179 AC_FUNC_ACCEPT_ARGTYPES
1180 PGAC_FUNC_GETTIMEOFDAY_1ARG
1181
1182 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1183 # symbols that that library has no business exposing to the world.  Pending
1184 # acquisition of a clue by those developers, ignore libedit (including its
1185 # possible alias of libreadline) while checking for everything else.
1186 LIBS_including_readline="$LIBS"
1187 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1188
1189 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1190
1191 AC_REPLACE_FUNCS(fseeko)
1192 case $host_os in
1193         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1194         # Mingw uses macros to access Win32 API calls
1195         netbsd*|mingw*)
1196                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1197                 ac_cv_func_fseeko=yes;;
1198         *)
1199                 AC_FUNC_FSEEKO;;
1200 esac
1201
1202 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1203 # by calling it, 2009-04-02
1204 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1205 if test "$PORTNAME" != "solaris"; then
1206 AC_CHECK_FUNCS(posix_fadvise)
1207 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1208 fi
1209
1210 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1211 AC_CHECK_DECLS([strlcat, strlcpy])
1212 # This is probably only present on Darwin, but may as well check always
1213 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1214
1215 HAVE_IPV6=no
1216 AC_CHECK_TYPE([struct sockaddr_in6],
1217         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1218          HAVE_IPV6=yes],
1219         [],
1220 [$ac_includes_default
1221 #include <netinet/in.h>])
1222 AC_SUBST(HAVE_IPV6)
1223
1224 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1225 [AC_TRY_LINK(
1226 [#include <machine/vmparam.h>
1227 #include <sys/exec.h>
1228 ],
1229 [PS_STRINGS->ps_nargvstr = 1;
1230 PS_STRINGS->ps_argvstr = "foo";],
1231 [pgac_cv_var_PS_STRINGS=yes],
1232 [pgac_cv_var_PS_STRINGS=no])])
1233 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1234   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1235 fi
1236
1237
1238 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1239 # is missing.  Yes, there are machines that have only one.  We may
1240 # also decide to use snprintf.c if snprintf() is present but does not
1241 # have all the features we need --- see below.
1242
1243 if test "$PORTNAME" = "win32"; then
1244   # Win32 gets snprintf.c built unconditionally.
1245   #
1246   # To properly translate all NLS languages strings, we must support the
1247   # *printf() %$ format, which allows *printf() arguments to be selected
1248   # by position in the translated string.
1249   #
1250   # libintl versions < 0.13 use the native *printf() functions, and Win32
1251   # *printf() doesn't understand %$, so we must use our /port versions,
1252   # which do understand %$. libintl versions >= 0.13 include their own
1253   # *printf versions on Win32.  The libintl 0.13 release note text is:
1254   #
1255   #   C format strings with positions, as they arise when a translator
1256   #   needs to reorder a sentence, are now supported on all platforms.
1257   #   On those few platforms (NetBSD and Woe32) for which the native
1258   #   printf()/fprintf()/... functions don't support such format
1259   #   strings, replacements are provided through <libintl.h>.
1260   #
1261   # We could use libintl >= 0.13's *printf() if we were sure that we had
1262   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1263   # to guarantee that, it is best to just use our own, so we are sure to
1264   # get %$ support. In include/port.h we disable the *printf() macros
1265   # that might have been defined by libintl.
1266   #
1267   # We do this unconditionally whether NLS is used or not so we are sure
1268   # that all Win32 libraries and binaries behave the same.
1269   pgac_need_repl_snprintf=yes
1270 else
1271   pgac_need_repl_snprintf=no
1272   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1273   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1274 fi
1275
1276
1277 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1278 # include/c.h will provide declarations.  Note this is a separate test
1279 # from whether the functions exist in the C library --- there are
1280 # systems that have the functions but don't bother to declare them :-(
1281
1282 AC_CHECK_DECLS([snprintf, vsnprintf])
1283
1284
1285 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1286 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1287 [AC_TRY_LINK([
1288 #include <math.h>
1289 double glob_double;
1290 ],
1291 [return isinf(glob_double) ? 0 : 1;],
1292 [ac_cv_func_isinf=yes],
1293 [ac_cv_func_isinf=no])])
1294
1295 if test $ac_cv_func_isinf = yes ; then
1296   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1297 else
1298   AC_LIBOBJ(isinf)
1299   # Look for a way to implement a substitute for isinf()
1300   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1301 fi
1302
1303 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton random rint srandom strerror strlcat strlcpy])
1304
1305 case $host_os in
1306
1307         # Windows uses a specialised env handler
1308         # and doesn't need a replacement getpeereid because it doesn't use
1309         # Unix sockets.
1310         mingw*)
1311                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1312                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1313                 ac_cv_func_unsetenv=yes
1314                 ac_cv_func_getpeereid=yes;;
1315         *)
1316                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1317                 ;;
1318 esac
1319
1320 # System's version of getaddrinfo(), if any, may be used only if we found
1321 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1322 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1323 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1324 # because we want to use our own getaddrinfo.c on Windows anyway.)
1325 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1326   AC_REPLACE_FUNCS([getaddrinfo])
1327 else
1328   AC_LIBOBJ(getaddrinfo)
1329 fi
1330
1331 # Similarly, use system's getopt_long() only if system provides struct option.
1332 if test x"$ac_cv_type_struct_option" = xyes ; then
1333   AC_REPLACE_FUNCS([getopt_long])
1334 else
1335   AC_LIBOBJ(getopt_long)
1336 fi
1337
1338 # Solaris' getopt() doesn't do what we want for long options, so always use
1339 # our version on that platform.
1340 if test "$PORTNAME" = "solaris"; then
1341   AC_LIBOBJ(getopt)
1342 fi
1343
1344 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1345 # so always use our version on Windows.
1346 if test "$PORTNAME" = "win32"; then
1347   AC_LIBOBJ(getopt)
1348   AC_LIBOBJ(getopt_long)
1349 fi
1350
1351 # Win32 support
1352 if test "$PORTNAME" = "win32"; then
1353   AC_REPLACE_FUNCS(gettimeofday)
1354   AC_LIBOBJ(kill)
1355   AC_LIBOBJ(open)
1356   AC_LIBOBJ(win32env)
1357   AC_LIBOBJ(win32error)
1358   AC_LIBOBJ(win32setlocale)
1359   AC_DEFINE([HAVE_SYMLINK], 1,
1360             [Define to 1 if you have the `symlink' function.])
1361   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1362 #define WIN32_LEAN_AND_MEAN
1363 #include <windows.h>
1364 #include <string.h>
1365 #include <dbghelp.h>])
1366 fi
1367 if test x"$pgac_minidump_type" = x"yes" ; then
1368   AC_SUBST(have_win32_dbghelp,yes)
1369 else
1370   AC_SUBST(have_win32_dbghelp,no)
1371 fi
1372
1373 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1374 dnl (especially on GNU libc)
1375 dnl See also comments in c.h.
1376 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1377 [AC_TRY_LINK([#include <setjmp.h>],
1378             [sigjmp_buf x; sigsetjmp(x, 1);],
1379             [pgac_cv_func_sigsetjmp=yes],
1380             [pgac_cv_func_sigsetjmp=no])])
1381 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1382   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1383 fi
1384
1385 AC_DECL_SYS_SIGLIST
1386
1387 AC_CHECK_FUNC(syslog,
1388               [AC_CHECK_HEADER(syslog.h,
1389                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1390
1391 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1392 [AC_TRY_LINK([#include <unistd.h>],
1393   [extern int opterr; opterr = 1;],
1394   [pgac_cv_var_int_opterr=yes],
1395   [pgac_cv_var_int_opterr=no])])
1396 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1397   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1398 fi
1399
1400 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1401 [AC_TRY_LINK([#include <unistd.h>],
1402   [extern int optreset; optreset = 1;],
1403   [pgac_cv_var_int_optreset=yes],
1404   [pgac_cv_var_int_optreset=no])])
1405 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1406   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1407 fi
1408
1409 AC_CHECK_FUNCS([strtoll strtoq], [break])
1410 AC_CHECK_FUNCS([strtoull strtouq], [break])
1411
1412 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1413 [AC_TRY_LINK([],
1414   [int lock = 0;
1415    __sync_lock_test_and_set(&lock, 1);
1416    __sync_lock_release(&lock);],
1417   [pgac_cv_gcc_int_atomics="yes"],
1418   [pgac_cv_gcc_int_atomics="no"])])
1419 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1420   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1421 fi
1422
1423 # Lastly, restore full LIBS list and check for readline/libedit symbols
1424 LIBS="$LIBS_including_readline"
1425
1426 if test "$with_readline" = yes; then
1427   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1428   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1429   AC_CHECK_FUNCS([append_history history_truncate_file])
1430 fi
1431
1432
1433 #
1434 # Pthreads
1435 #
1436 # For each platform, we need to know about any special compile and link
1437 # libraries, and whether the normal C function names are thread-safe.
1438 # See the comment at the top of src/port/thread.c for more information.
1439 # WIN32 doesn't need the pthread tests;  it always uses threads
1440 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1441 ACX_PTHREAD     # set thread flags
1442
1443 # Some platforms use these, so just define them.  They can't hurt if they
1444 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1445 # enables 5-arg getpwuid_r, among other things.
1446 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1447
1448
1449 # At this point, we don't want to muck with the compiler name for threading.
1450 # Let's see who fails, perhaps AIX.  2004-04-23
1451 if test "$PTHREAD_CC" != "$CC"; then
1452 AC_MSG_ERROR([
1453 PostgreSQL does not support platforms that require a special compiler
1454 for thread safety;  use --disable-thread-safety to disable thread safety.])
1455 fi
1456
1457 # Check for *_r functions
1458 _CFLAGS="$CFLAGS"
1459 _LIBS="$LIBS"
1460 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1461 LIBS="$LIBS $PTHREAD_LIBS"
1462
1463 if test "$PORTNAME" != "win32"; then
1464 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1465 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1466 fi
1467
1468 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1469
1470 # Do test here with the proper thread flags
1471 PGAC_FUNC_GETPWUID_R_5ARG
1472 PGAC_FUNC_STRERROR_R_INT
1473
1474 CFLAGS="$_CFLAGS"
1475 LIBS="$_LIBS"
1476
1477 else
1478 # do not use values from template file
1479 PTHREAD_CFLAGS=
1480 PTHREAD_LIBS=
1481 fi
1482
1483 AC_SUBST(PTHREAD_CFLAGS)
1484 AC_SUBST(PTHREAD_LIBS)
1485
1486
1487 # We can test for libldap_r only after we know PTHREAD_LIBS
1488 if test "$with_ldap" = yes ; then
1489   _LIBS="$LIBS"
1490   if test "$PORTNAME" != "win32"; then
1491     AC_CHECK_LIB(ldap, ldap_bind, [],
1492                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1493                  [$EXTRA_LDAP_LIBS])
1494     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1495     if test "$enable_thread_safety" = yes; then
1496       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1497       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1498                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1499                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1500       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1501     else
1502       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1503     fi
1504   else
1505     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1506     LDAP_LIBS_FE="-lwldap32"
1507     LDAP_LIBS_BE="-lwldap32"
1508   fi
1509   LIBS="$_LIBS"
1510 fi
1511 AC_SUBST(LDAP_LIBS_FE)
1512 AC_SUBST(LDAP_LIBS_BE)
1513
1514
1515 # This test makes sure that run tests work at all.  Sometimes a shared
1516 # library is found by the linker, but the runtime linker can't find it.
1517 # This check should come after all modifications of compiler or linker
1518 # variables, and before any other run tests.
1519 AC_MSG_CHECKING([test program])
1520 AC_TRY_RUN([int main() { return 0; }],
1521 [AC_MSG_RESULT(ok)],
1522 [AC_MSG_RESULT(failed)
1523 AC_MSG_ERROR([[
1524 Could not execute a simple test program.  This may be a problem
1525 related to locating shared libraries.  Check the file 'config.log'
1526 for the exact reason.]])],
1527 [AC_MSG_RESULT([cross-compiling])])
1528
1529 # --------------------
1530 # Run tests below here
1531 # --------------------
1532
1533 # Force use of our snprintf if system's doesn't do arg control
1534 # See comment above at snprintf test for details.
1535 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1536   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1537   if test $pgac_cv_snprintf_arg_control != yes ; then
1538     pgac_need_repl_snprintf=yes
1539   fi
1540 fi
1541
1542
1543 dnl Check to see if we have a working 64-bit integer type.
1544 dnl This breaks down into two steps:
1545 dnl (1) figure out if the compiler has a 64-bit int type with working
1546 dnl arithmetic, and if so
1547 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1548 dnl snprintf is the only library routine we really need for int8 support.)
1549 dnl It's entirely possible to have a compiler that handles a 64-bit type
1550 dnl when the C library doesn't; this is fairly likely when using gcc on
1551 dnl an older platform, for example.
1552 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1553 dnl we force our own version of snprintf() to be used instead.
1554 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1555
1556 dnl As of Postgres 8.4, we no longer support compilers without a working
1557 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1558
1559 PGAC_TYPE_64BIT_INT([long int])
1560
1561 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1562   pg_int64_type="long int"
1563 else
1564   PGAC_TYPE_64BIT_INT([long long int])
1565   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1566     pg_int64_type="long long int"
1567   else
1568     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1569   fi
1570 fi
1571
1572 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1573   [Define to the name of a signed 64-bit integer type.])
1574
1575 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1576
1577 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1578   AC_TRY_COMPILE([
1579 #define INT64CONST(x)  x##LL
1580 long long int foo = INT64CONST(0x1234567890123456);
1581 ],
1582         [],
1583         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1584         [])
1585 fi
1586
1587
1588 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1589 # we found we need to use "long long int", better check.  We cope with
1590 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1591 # work, fall back to our own snprintf emulation (which we know uses %lld).
1592
1593 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1594   if test $pgac_need_repl_snprintf = no; then
1595     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1596     if test "$LONG_LONG_INT_FORMAT" = ""; then
1597       # Force usage of our own snprintf, since system snprintf is broken
1598       pgac_need_repl_snprintf=yes
1599       LONG_LONG_INT_FORMAT='%lld'
1600     fi
1601   else
1602     # Here if we previously decided we needed to use our own snprintf
1603     LONG_LONG_INT_FORMAT='%lld'
1604   fi
1605   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1606   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1607   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1608 else
1609   # Here if we are not using 'long long int' at all
1610   INT64_FORMAT='"%ld"'
1611   UINT64_FORMAT='"%lu"'
1612 fi
1613
1614 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1615                    [Define to the appropriate snprintf format for 64-bit ints.])
1616
1617 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1618                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1619
1620 # Also force use of our snprintf if the system's doesn't support the %z flag.
1621 if test "$pgac_need_repl_snprintf" = no; then
1622   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1623   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1624     pgac_need_repl_snprintf=yes
1625   fi
1626 fi
1627
1628 # Now we have checked all the reasons to replace snprintf
1629 if test $pgac_need_repl_snprintf = yes; then
1630   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1631   AC_LIBOBJ(snprintf)
1632 fi
1633
1634 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1635 AC_CHECK_SIZEOF([void *])
1636 AC_CHECK_SIZEOF([size_t])
1637 AC_CHECK_SIZEOF([long])
1638
1639 # Decide whether float4 is passed by value: user-selectable, enabled by default
1640 AC_MSG_CHECKING([whether to build with float4 passed by value])
1641 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1642               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1643                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1644                float4passbyval=true],
1645               [float4passbyval=false])
1646 AC_MSG_RESULT([$enable_float4_byval])
1647 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1648
1649 # Decide whether float8 is passed by value.
1650 # Note: this setting also controls int8 and related types such as timestamp.
1651 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1652 # If not, trying to select it is an error.
1653 AC_MSG_CHECKING([whether to build with float8 passed by value])
1654 if test $ac_cv_sizeof_void_p -ge 8 ; then
1655   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1656 else
1657   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1658   if test "$enable_float8_byval" = yes ; then
1659     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1660   fi
1661 fi
1662 if test "$enable_float8_byval" = yes ; then
1663   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1664             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1665   float8passbyval=true
1666 else
1667   float8passbyval=false
1668 fi
1669 AC_MSG_RESULT([$enable_float8_byval])
1670 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1671
1672 # Determine memory alignment requirements for the basic C data types.
1673
1674 AC_CHECK_ALIGNOF(short)
1675 AC_CHECK_ALIGNOF(int)
1676 AC_CHECK_ALIGNOF(long)
1677 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1678   AC_CHECK_ALIGNOF(long long int)
1679 fi
1680 AC_CHECK_ALIGNOF(double)
1681
1682 # Compute maximum alignment of any basic type.
1683 # We assume long's alignment is at least as strong as char, short, or int;
1684 # but we must check long long (if it exists) and double.
1685
1686 MAX_ALIGNOF=$ac_cv_alignof_long
1687 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1688   MAX_ALIGNOF=$ac_cv_alignof_double
1689 fi
1690 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1691   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1692 fi
1693 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1694
1695
1696 # Some platforms predefine the types int8, int16, etc.  Only check
1697 # a (hopefully) representative subset.
1698 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1699 [#include <stdio.h>])
1700
1701 # We also check for sig_atomic_t, which *should* be defined per ANSI
1702 # C, but is missing on some old platforms.
1703 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1704
1705
1706 if test "$PORTNAME" != "win32"
1707 then
1708 PGAC_FUNC_POSIX_SIGNALS
1709 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1710   AC_MSG_ERROR([
1711 Thread-safety requires POSIX signals, which are not supported by this
1712 operating system;  use --disable-thread-safety to disable thread safety.])
1713 fi
1714 fi
1715
1716
1717 # Select semaphore implementation type.
1718 if test "$PORTNAME" != "win32"; then
1719   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1720     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1721     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1722   else
1723     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1724       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1725       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1726     else
1727       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1728       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1729     fi
1730   fi
1731 else
1732   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1733   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1734 fi
1735
1736
1737 # Select shared-memory implementation type.
1738 if test "$PORTNAME" != "win32"; then
1739   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1740   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1741 else
1742   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1743   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1744 fi
1745
1746 # Select latch implementation type.
1747 if test "$PORTNAME" != "win32"; then
1748   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1749 else
1750   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1751 fi
1752
1753 # If not set in template file, set bytes to use libc memset()
1754 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1755   MEMSET_LOOP_LIMIT=1024
1756 fi
1757 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1758
1759
1760 if test "$enable_nls" = yes ; then
1761   PGAC_CHECK_GETTEXT
1762 fi
1763
1764 # Check for Tcl configuration script tclConfig.sh
1765 if test "$with_tcl" = yes; then
1766     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1767     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1768                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1769     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1770     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1771     ac_save_CPPFLAGS=$CPPFLAGS
1772     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1773     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1774     CPPFLAGS=$ac_save_CPPFLAGS
1775 fi
1776
1777 # check for <perl.h>
1778 if test "$with_perl" = yes; then
1779   ac_save_CPPFLAGS=$CPPFLAGS
1780   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1781   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1782                   [#include <EXTERN.h>])
1783   # While we're at it, check that we can link to libperl.
1784   # On most platforms, if perl.h is there then libperl.so will be too, but at
1785   # this writing Debian packages them separately.  There is no known reason to
1786   # waste cycles on separate probes for the Tcl or Python libraries, though.
1787   pgac_save_LIBS=$LIBS
1788   LIBS="$perl_embed_ldflags"
1789   AC_MSG_CHECKING([for libperl])
1790   AC_TRY_LINK([
1791 #include <EXTERN.h>
1792 #include <perl.h>
1793 ],  [perl_alloc();],
1794     [AC_MSG_RESULT(yes)],
1795     [AC_MSG_RESULT(no)
1796      AC_MSG_ERROR([libperl library is required for Perl])])
1797   LIBS=$pgac_save_LIBS
1798   CPPFLAGS=$ac_save_CPPFLAGS
1799 fi
1800
1801 # check for <Python.h>
1802 if test "$with_python" = yes; then
1803   ac_save_CPPFLAGS=$CPPFLAGS
1804   CPPFLAGS="$python_includespec $CPPFLAGS"
1805   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1806   CPPFLAGS=$ac_save_CPPFLAGS
1807 fi
1808
1809 #
1810 # Check for DocBook and tools
1811 #
1812 PGAC_PROG_NSGMLS
1813 PGAC_PROG_JADE
1814 PGAC_CHECK_DOCBOOK(4.2)
1815 PGAC_PATH_DOCBOOK_STYLESHEETS
1816 PGAC_PATH_COLLATEINDEX
1817 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1818 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1819
1820 # Thread testing
1821
1822 # We have to run the thread test near the end so we have all our symbols
1823 # defined.  Cross compiling throws a warning.
1824 #
1825 if test "$enable_thread_safety" = yes; then
1826 if test "$PORTNAME" != "win32"
1827 then
1828 AC_MSG_CHECKING([thread safety of required library functions])
1829
1830 _CFLAGS="$CFLAGS"
1831 _LIBS="$LIBS"
1832 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1833 LIBS="$LIBS $PTHREAD_LIBS"
1834 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1835   [AC_MSG_RESULT(yes)],
1836   [AC_MSG_RESULT(no)
1837   AC_MSG_ERROR([thread test program failed
1838 This platform is not thread-safe.  Check the file 'config.log' or compile
1839 and run src/test/thread/thread_test for the exact reason.
1840 Use --disable-thread-safety to disable thread safety.])],
1841   [AC_MSG_RESULT(maybe)
1842   AC_MSG_WARN([
1843 *** Skipping thread test program because of cross-compile build.
1844 *** Run the program in src/test/thread on the target machine.
1845 ])])
1846 CFLAGS="$_CFLAGS"
1847 LIBS="$_LIBS"
1848 else
1849 AC_MSG_WARN([*** skipping thread test on Win32])
1850 fi
1851 fi
1852
1853 # If compiler will take -Wl,--as-needed (or various platform-specific
1854 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1855 # trying to filter LIBS to the minimum for each executable.
1856 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1857 # libreadline; therefore we postpone testing it until we know what library
1858 # dependencies readline has.  The test code will try to link with $LIBS.
1859 if test "$with_readline" = yes; then
1860   link_test_func=readline
1861 else
1862   link_test_func=exit
1863 fi
1864
1865 if test "$PORTNAME" = "darwin"; then
1866   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1867 elif test "$PORTNAME" = "openbsd"; then
1868   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1869 else
1870   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1871 fi
1872
1873 # Create compiler version string
1874 if test x"$GCC" = x"yes" ; then
1875   cc_string=`${CC} --version | sed q`
1876   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1877 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1878   cc_string=`${CC} -V 2>&1 | sed q`
1879 else
1880   cc_string=$CC
1881 fi
1882
1883 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1884                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1885                    [A string containing the version number, platform, and C compiler])
1886
1887 # Supply a numeric version string for use by 3rd party add-ons
1888 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1889 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1890 tr '.' '        ' |
1891 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1892 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1893
1894
1895 # Begin output steps
1896
1897 AC_MSG_NOTICE([using compiler=$cc_string])
1898 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1899 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1900 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1901
1902 # prepare build tree if outside source tree
1903 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1904 # Note 2: /bin/pwd might be better than shell's built-in at getting
1905 #         a symlink-free name.
1906 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1907   vpath_build=no
1908 else
1909   vpath_build=yes
1910   if test "$no_create" != yes; then
1911     _AS_ECHO_N([preparing build tree... ])
1912     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1913     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1914       || AC_MSG_ERROR(failed)
1915     AC_MSG_RESULT(done)
1916   fi
1917 fi
1918 AC_SUBST(vpath_build)
1919
1920
1921 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1922
1923 AC_CONFIG_LINKS([
1924   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1925   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1926   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1927   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1928   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1929   src/include/pg_config_os.h:src/include/port/${template}.h
1930   src/Makefile.port:src/makefiles/Makefile.${template}
1931 ])
1932
1933 if test "$PORTNAME" = "win32"; then
1934 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1935 # Links sometimes fail undetected on Mingw -
1936 # so here we detect it and warn the user
1937 for FILE in $CONFIG_LINKS
1938  do
1939         # test -e works for symlinks in the MinGW console
1940         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1941  done
1942 ])
1943 fi
1944
1945 AC_CONFIG_HEADERS([src/include/pg_config.h],
1946 [
1947 # Update timestamp for pg_config.h (see Makefile.global)
1948 echo >src/include/stamp-h
1949 ])
1950
1951 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
1952 [
1953 # Update timestamp for pg_config_ext.h (see Makefile.global)
1954 echo >src/include/stamp-ext-h
1955 ])
1956
1957 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1958                   [echo >src/interfaces/ecpg/include/stamp-h])
1959
1960 AC_OUTPUT