granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.442 2006/01/12 19:23:22 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2005, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # C compiler
 210 #
 211
 212 # For historical reasons you can also use --with-CC to specify the C compiler
 213 # to use, although the standard way to do this is to set the CC environment
 214 # variable.
 215 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 216
 217 case $template in
 218   aix) pgac_cc_list="gcc xlc";;
 219  irix) pgac_cc_list="cc";; # no gcc
 220     *) pgac_cc_list="gcc cc";;
 221 esac
 222
 223 AC_PROG_CC([$pgac_cc_list])
 224
 225 unset CFLAGS
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # CFLAGS are selected so:
 233 # If the user specifies something in the environment, that is used.
 234 # else:  If the template file set something, that is used.
 235 # else:  If the compiler is GCC, then we use -O2.
 236 # else:  If the compiler is something else, then we use -0.
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 elif test "${CFLAGS+set}" = set; then
 241   : # (keep what template set)
 242 elif test "$GCC" = yes; then
 243   CFLAGS="-O2"
 244 else
 245   # if the user selected debug mode, don't use -O
 246   if test "$enable_debug" != yes; then
 247     CFLAGS="-O"
 248   fi
 249 fi
 250
 251 if test "$GCC" = yes; then
 252   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 253
 254   # Some versions of GCC support some additional useful warning flags.
 255   # Check whether they are supported, and add them to CFLAGS if so.
 256   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 257   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 258
 259   # Disable strict-aliasing rules; needed for gcc 3.3+
 260   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 261 fi
 262
 263 # supply -g if --enable-debug
 264 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 265   CFLAGS="$CFLAGS -g"
 266 fi
 267
 268 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 269
 270 # We already have this in Makefile.win32, but configure needs it too
 271 if test "$PORTNAME" = "win32"; then
 272   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 273 fi
 274
 275 # Check if the compiler still works with the template settings
 276 AC_MSG_CHECKING([whether the C compiler still works])
 277 AC_TRY_LINK([], [return 0;],
 278   [AC_MSG_RESULT(yes)],
 279   [AC_MSG_RESULT(no)
 280    AC_MSG_ERROR([cannot proceed])])
 281
 282 # Defend against gcc -ffast-math
 283 if test "$GCC" = yes; then
 284 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 285 choke me
 286 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 287 fi
 288
 289 AC_PROG_CPP
 290 AC_SUBST(GCC)
 291
 292 # Create compiler version string
 293 if test x"$GCC" = x"yes" ; then
 294   cc_string="GCC `${CC} --version | sed q`"
 295 else
 296   cc_string=$CC
 297 fi
 298 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 299                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 300                    [A string containing the version number, platform, and C compiler])
 301
 302
 303 #
 304 # Set up TAS assembly code if needed; the template file has now had its
 305 # chance to request this.
 306 #
 307 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 308
 309 if test "$need_tas" = yes ; then
 310   TAS=tas.o
 311 else
 312   TAS=""
 313 fi
 314 AC_SUBST(TAS)
 315
 316
 317 #
 318 # Automatic dependency tracking
 319 #
 320 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 321               [autodepend=yes])
 322 AC_SUBST(autodepend)
 323
 324
 325 #
 326 # Enable assert checks
 327 #
 328 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 329               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 330                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 331
 332
 333 #
 334 # Include directories
 335 #
 336 ac_save_IFS=$IFS
 337 IFS="${IFS}${PATH_SEPARATOR}"
 338 # SRCH_INC comes from the template file
 339 for dir in $with_includes $SRCH_INC; do
 340   if test -d "$dir"; then
 341     INCLUDES="$INCLUDES -I$dir"
 342   else
 343     AC_MSG_WARN([*** Include directory $dir does not exist.])
 344   fi
 345 done
 346 IFS=$ac_save_IFS
 347 AC_SUBST(INCLUDES)
 348
 349
 350 #
 351 # Library directories
 352 #
 353 ac_save_IFS=$IFS
 354 IFS="${IFS}${PATH_SEPARATOR}"
 355 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 356 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 357   if test -d "$dir"; then
 358     LIBDIRS="$LIBDIRS -L$dir"
 359   else
 360     AC_MSG_WARN([*** Library directory $dir does not exist.])
 361   fi
 362 done
 363 IFS=$ac_save_IFS
 364
 365 #
 366 # Enable thread-safe client libraries
 367 #
 368 AC_MSG_CHECKING([allow thread-safe client libraries])
 369 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 370 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 371 if test "$enable_thread_safety" = yes -o \
 372         "$enable_thread_safety_force" = yes; then
 373   enable_thread_safety="yes"    # for 'force'
 374   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 375           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 376 fi
 377 AC_MSG_RESULT([$enable_thread_safety])
 378 AC_SUBST(enable_thread_safety)
 379
 380 #
 381 # Optionally build Tcl modules (PL/Tcl)
 382 #
 383 AC_MSG_CHECKING([whether to build with Tcl])
 384 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 385 AC_MSG_RESULT([$with_tcl])
 386 AC_SUBST([with_tcl])
 387
 388 # We see if the path to the Tcl/Tk configuration scripts is specified.
 389 # This will override the use of tclsh to find the paths to search.
 390
 391 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 392
 393 #
 394 # Optionally build Perl modules (PL/Perl)
 395 #
 396 AC_MSG_CHECKING([whether to build Perl modules])
 397 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 398 AC_MSG_RESULT([$with_perl])
 399 AC_SUBST(with_perl)
 400
 401 #
 402 # Optionally build Python modules (PL/Python)
 403 #
 404 AC_MSG_CHECKING([whether to build Python modules])
 405 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 406 AC_MSG_RESULT([$with_python])
 407 AC_SUBST(with_python)
 408
 409 #
 410 # Kerberos 5
 411 #
 412 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 413 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 414 [
 415   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 416   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 417 ])
 418 AC_MSG_RESULT([$with_krb5])
 419 AC_SUBST(with_krb5)
 420
 421
 422 AC_SUBST(krb_srvtab)
 423
 424
 425 #
 426 # Kerberos configuration parameters
 427 #
 428 PGAC_ARG_REQ(with, krb-srvnam,
 429              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 430              [],
 431              [with_krb_srvnam="postgres"])
 432 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 433                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 434
 435
 436 #
 437 # PAM
 438 #
 439 AC_MSG_CHECKING([whether to build with PAM support])
 440 PGAC_ARG_BOOL(with, pam, no,
 441               [  --with-pam              build with PAM support],
 442               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 443 AC_MSG_RESULT([$with_pam])
 444 AC_SUBST(with_pam)
 445
 446
 447 #
 448 # Bonjour
 449 #
 450 AC_MSG_CHECKING([whether to build with Bonjour support])
 451 PGAC_ARG_BOOL(with, bonjour, no,
 452               [  --with-bonjour          build with Bonjour support],
 453               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 454 AC_MSG_RESULT([$with_bonjour])
 455 AC_SUBST(with_bonjour)
 456
 457
 458 #
 459 # OpenSSL
 460 #
 461 AC_MSG_CHECKING([whether to build with OpenSSL support])
 462 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 463               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 464 AC_MSG_RESULT([$with_openssl])
 465 AC_SUBST(with_openssl)
 466
 467
 468 #
 469 # Prefer libedit
 470 #
 471 PGAC_ARG_BOOL(with, libedit-preferred, no,
 472               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 473
 474
 475 #
 476 # Readline
 477 #
 478 PGAC_ARG_BOOL(with, readline, yes,
 479               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 480 # readline on MinGW has problems with backslashes in psql and other bugs.
 481 # This is particularly a problem with non-US code pages.
 482 # Therefore disable its use until we understand the cause. 2004-07-20
 483 if test "$PORTNAME" = "win32"; then
 484   if test "$with_readline" = yes; then
 485     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 486     with_readline=no
 487   fi
 488 fi
 489
 490
 491 #
 492 # Zlib
 493 #
 494 PGAC_ARG_BOOL(with, zlib, yes,
 495               [  --without-zlib          do not use Zlib])
 496 AC_SUBST(with_zlib)
 497
 498 #
 499 # Elf
 500 #
 501
 502 # Assume system is ELF if it predefines __ELF__ as 1,
 503 # otherwise believe host_os based default.
 504 case $host_os in
 505     freebsd1*|freebsd2*) elf=no;;
 506     freebsd3*|freebsd4*) elf=yes;;
 507 esac
 508
 509 AC_EGREP_CPP(yes,
 510 [#if __ELF__
 511   yes
 512 #endif
 513 ],
 514 [ELF_SYS=true],
 515 [if test "X$elf" = "Xyes" ; then
 516   ELF_SYS=true
 517 else
 518   ELF_SYS=
 519 fi])
 520 AC_SUBST(ELF_SYS)
 521
 522 #
 523 # Assignments
 524 #
 525
 526 CPPFLAGS="$CPPFLAGS $INCLUDES"
 527 LDFLAGS="$LDFLAGS $LIBDIRS"
 528
 529 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 530 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 531
 532 AC_ARG_VAR(LDFLAGS_SL)
 533
 534 AC_PROG_AWK
 535 PGAC_PATH_FLEX
 536 AC_PROG_LN_S
 537 PGAC_PROG_LD
 538 AC_SUBST(LD)
 539 AC_SUBST(with_gnu_ld)
 540 case $host_os in sysv5*)
 541   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 542   [
 543     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 544     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 545     LDFLAGS=$pgac_save_LDFLAGS
 546   ])
 547   ld_R_works=$pgac_cv_prog_ld_R
 548   AC_SUBST(ld_R_works)
 549 esac
 550 AC_PROG_RANLIB
 551 AC_CHECK_PROGS(LORDER, lorder)
 552 AC_PATH_PROG(TAR, tar)
 553 PGAC_CHECK_STRIP
 554
 555 AC_CHECK_PROGS(YACC, ['bison -y'])
 556
 557 if test "$YACC"; then
 558   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 559     AC_MSG_WARN([
 560 *** If you are going to modify the grammar files or build from CVS, the installed
 561 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 562   fi
 563 fi
 564
 565 if test -z "$YACC"; then
 566   AC_MSG_WARN([
 567 *** Without Bison you will not be able to build PostgreSQL from CVS or
 568 *** change any of the parser definition files.  You can obtain Bison from
 569 *** a GNU mirror site.  (If you are using the official distribution of
 570 *** PostgreSQL then you do not need to worry about this because the Bison
 571 *** output is pre-generated.)  To use a different yacc program (possible,
 572 *** but not recommended), set the environment variable YACC before running
 573 *** 'configure'.])
 574 fi
 575 AC_SUBST(YFLAGS)
 576
 577 PGAC_PATH_PERL
 578 if test "$with_perl" = yes; then
 579   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 580   PGAC_CHECK_PERL_EMBED_LDFLAGS
 581 fi
 582
 583 if test "$with_python" = yes; then
 584   PGAC_PATH_PYTHON
 585   PGAC_CHECK_PYTHON_EMBED_SETUP
 586 fi
 587
 588
 589 ##
 590 ## Libraries
 591 ##
 592
 593 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 594 then
 595         AC_CHECK_LIB(bsd,      main)
 596 fi
 597 AC_CHECK_LIB(util,     setproctitle)
 598 AC_CHECK_LIB(m,        main)
 599 AC_CHECK_LIB(dl,       main)
 600 AC_CHECK_LIB(nsl,      main)
 601 AC_CHECK_LIB(socket,   main)
 602 AC_CHECK_LIB(ipc,      main)
 603 AC_CHECK_LIB(IPC,      main)
 604 AC_CHECK_LIB(lc,       main)
 605 AC_CHECK_LIB(dld,      main)
 606 AC_CHECK_LIB(ld,       main)
 607 AC_CHECK_LIB(compat,   main)
 608 AC_CHECK_LIB(BSD,      main)
 609 AC_CHECK_LIB(gen,      main)
 610 AC_CHECK_LIB(PW,       main)
 611 AC_CHECK_LIB(resolv,   main)
 612 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 613 # QNX:
 614 AC_CHECK_LIB(unix, main)
 615 AC_SEARCH_LIBS(crypt,  crypt)
 616 # Solaris:
 617 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 618 # Cygwin:
 619 AC_CHECK_LIB(cygipc, shmget)
 620 # WIN32:
 621 if test "$PORTNAME" = "win32"
 622 then
 623         AC_CHECK_LIB(wsock32, main)
 624 fi
 625
 626 if test "$with_readline" = yes; then
 627   PGAC_CHECK_READLINE
 628   if test x"$pgac_cv_check_readline" = x"no"; then
 629     AC_MSG_ERROR([readline library not found
 630 If you have readline already installed, see config.log for details on the
 631 failure.  It is possible the compiler isn't looking in the proper directory.
 632 Use --without-readline to disable readline support.])
 633   fi
 634 fi
 635
 636 if test "$with_zlib" = yes; then
 637   AC_CHECK_LIB(z, inflate, [],
 638                [AC_MSG_ERROR([zlib library not found
 639 If you have zlib already installed, see config.log for details on the
 640 failure.  It is possible the compiler isn't looking in the proper directory.
 641 Use --without-zlib to disable zlib support.])])
 642 fi
 643
 644 if test "$enable_spinlocks" = yes; then
 645   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 646 else
 647   AC_MSG_WARN([
 648 *** Not using spinlocks will cause poor performance.])
 649 fi
 650
 651 if test "$with_krb5" = yes ; then
 652   if test "$PORTNAME" != "win32"; then
 653      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 654                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 655      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 656                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 657      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 658                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 659   else
 660      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 661                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 662   fi
 663 fi
 664
 665 if test "$with_openssl" = yes ; then
 666   dnl Order matters!
 667   if test "$PORTNAME" != "win32"; then
 668      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 669      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 670   else
 671      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 672      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 673   fi
 674 fi
 675
 676 if test "$with_pam" = yes ; then
 677   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 678 fi
 679
 680
 681 ##
 682 ## Header files
 683 ##
 684
 685 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 686 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 687
 688 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 689 # netinet/in.h is included first.
 690 AC_CHECK_HEADERS(netinet/in.h)
 691 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 692 [AC_INCLUDES_DEFAULT
 693 #ifdef HAVE_NETINET_IN_H
 694 #include <netinet/in.h>
 695 #endif
 696 ])
 697
 698 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 699   AC_CHECK_HEADERS(readline/readline.h, [],
 700         [AC_CHECK_HEADERS(readline.h, [],
 701                 [AC_MSG_ERROR([readline header not found
 702 If you have readline already installed, see config.log for details on the
 703 failure.  It is possible the compiler isn't looking in the proper directory.
 704 Use --without-readline to disable readline support.])])])
 705   AC_CHECK_HEADERS(readline/history.h, [],
 706         [AC_CHECK_HEADERS(history.h, [],
 707                 [AC_MSG_ERROR([history header not found
 708 If you have readline already installed, see config.log for details on the
 709 failure.  It is possible the compiler isn't looking in the proper directory.
 710 Use --without-readline to disable readline support.])])])
 711 fi
 712
 713 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 714 # Some installations of libedit usurp /usr/include/readline/, which seems
 715 # bad practice, since in combined installations readline will have its headers
 716 # there.  We might have to resort to AC_EGREP checks to make sure we found
 717 # the proper header...
 718   AC_CHECK_HEADERS(editline/readline.h, [],
 719         [AC_CHECK_HEADERS(readline.h, [],
 720                 [AC_CHECK_HEADERS(readline/readline.h, [],
 721                         [AC_MSG_ERROR([readline header not found
 722 If you have libedit already installed, see config.log for details on the
 723 failure.  It is possible the compiler isn't looking in the proper directory.
 724 Use --without-readline to disable libedit support.])])])])
 725   AC_CHECK_HEADERS(editline/history.h, [],
 726         [AC_CHECK_HEADERS(history.h, [],
 727                 [AC_CHECK_HEADERS(readline/history.h, [],
 728                         [AC_MSG_ERROR([history header not found
 729 If you have libedit already installed, see config.log for details on the
 730 failure.  It is possible the compiler isn't looking in the proper directory.
 731 Use --without-readline to disable libedit support.])])])])
 732 fi
 733
 734 if test "$with_zlib" = yes; then
 735   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 736 If you have zlib already installed, see config.log for details on the
 737 failure.  It is possible the compiler isn't looking in the proper directory.
 738 Use --without-zlib to disable zlib support.])])
 739 fi
 740
 741 if test "$with_krb5" = yes ; then
 742   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 743 fi
 744
 745 if test "$with_openssl" = yes ; then
 746   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 747   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 748 fi
 749
 750 if test "$with_pam" = yes ; then
 751   AC_CHECK_HEADERS(security/pam_appl.h, [],
 752                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 753                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 754 fi
 755
 756 if test "$with_bonjour" = yes ; then
 757   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 758 fi
 759
 760
 761 ##
 762 ## Types, structures, compiler characteristics
 763 ##
 764
 765 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 766 AC_C_CONST
 767 AC_C_INLINE
 768 AC_C_STRINGIZE
 769 PGAC_C_SIGNED
 770 AC_C_VOLATILE
 771 PGAC_C_FUNCNAME_SUPPORT
 772 PGAC_STRUCT_TIMEZONE
 773 PGAC_UNION_SEMUN
 774 PGAC_STRUCT_SOCKADDR_UN
 775 PGAC_STRUCT_SOCKADDR_STORAGE
 776 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 777 PGAC_STRUCT_ADDRINFO
 778
 779 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 780 [#include <sys/param.h>
 781 #include <sys/types.h>
 782 #include <sys/socket.h>
 783 #include <sys/ucred.h>])
 784
 785 AC_CHECK_TYPES([struct option], [], [],
 786 [#ifdef HAVE_GETOPT_H
 787 #include <getopt.h>
 788 #endif])
 789
 790 if test "$with_zlib" = yes; then
 791   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 792   # did not).  While we could work around the lack of z_streamp, it
 793   # seems unwise to encourage people to use such old zlib versions...
 794   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 795 Use --without-zlib to disable zlib support.])],
 796                 [#include <zlib.h>])
 797 fi
 798
 799 if test "$with_krb5" = yes; then
 800 # Check for differences between MIT and Heimdal (KTH) releases
 801   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 802                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 803                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 804                                      [#include <krb5.h>])],
 805                    [#include <krb5.h>])
 806   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 807                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 808                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 809                                      [#include <krb5.h>])],
 810                    [#include <krb5.h>])
 811 fi
 812
 813 ##
 814 ## Functions, global variables
 815 ##
 816
 817 PGAC_VAR_INT_TIMEZONE
 818 AC_FUNC_ACCEPT_ARGTYPES
 819 PGAC_FUNC_GETTIMEOFDAY_1ARG
 820
 821 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 822
 823 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 824
 825 HAVE_IPV6=no
 826 AC_CHECK_TYPE([struct sockaddr_in6],
 827         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 828          HAVE_IPV6=yes],
 829         [],
 830 [$ac_includes_default
 831 #include <netinet/in.h>])
 832 AC_SUBST(HAVE_IPV6)
 833
 834 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 835 [AC_TRY_LINK(
 836 [#include <machine/vmparam.h>
 837 #include <sys/exec.h>
 838 ],
 839 [PS_STRINGS->ps_nargvstr = 1;
 840 PS_STRINGS->ps_argvstr = "foo";],
 841 [pgac_cv_var_PS_STRINGS=yes],
 842 [pgac_cv_var_PS_STRINGS=no])])
 843 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 844   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 845 fi
 846
 847
 848 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 849 # is missing.  Yes, there are machines that have only one.  We may
 850 # also decide to use snprintf.c if snprintf() is present but does not
 851 # have all the features we need --- see below.
 852
 853 if test "$PORTNAME" = "win32"; then
 854   # Win32 gets snprintf.c built unconditionally.
 855   #
 856   # To properly translate all NLS languages strings, we must support the
 857   # *printf() %$ format, which allows *printf() arguments to be selected
 858   # by position in the translated string.
 859   #
 860   # libintl versions < 0.13 use the native *printf() functions, and Win32
 861   # *printf() doesn't understand %$, so we must use our /port versions,
 862   # which do understand %$. libintl versions >= 0.13 include their own
 863   # *printf versions on Win32.  The libintl 0.13 release note text is:
 864   #
 865   #   C format strings with positions, as they arise when a translator
 866   #   needs to reorder a sentence, are now supported on all platforms.
 867   #   On those few platforms (NetBSD and Woe32) for which the native
 868   #   printf()/fprintf()/... functions don't support such format
 869   #   strings, replacements are provided through <libintl.h>.
 870   #
 871   # We could use libintl >= 0.13's *printf() if we were sure that we had
 872   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 873   # to guarantee that, it is best to just use our own, so we are sure to
 874   # get %$ support. In include/port.h we disable the *printf() macros
 875   # that might have been defined by libintl.
 876   #
 877   # We do this unconditionally whether NLS is used or not so we are sure
 878   # that all Win32 libraries and binaries behave the same.
 879   pgac_need_repl_snprintf=yes
 880 else
 881   pgac_need_repl_snprintf=no
 882   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 883   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 884 fi
 885
 886
 887 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 888 # include/c.h will provide declarations.  Note this is a separate test
 889 # from whether the functions exist in the C library --- there are
 890 # systems that have the functions but don't bother to declare them :-(
 891
 892 AC_CHECK_DECLS([snprintf, vsnprintf])
 893
 894
 895 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 896 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 897 [AC_TRY_LINK([
 898 #include <math.h>
 899 double glob_double;
 900 ],
 901 [return isinf(glob_double) ? 0 : 1;],
 902 [ac_cv_func_isinf=yes],
 903 [ac_cv_func_isinf=no])])
 904
 905 if test $ac_cv_func_isinf = yes ; then
 906   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 907 else
 908   AC_LIBOBJ(isinf)
 909   # Look for a way to implement a substitute for isinf()
 910   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 911 fi
 912
 913 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 914
 915 # System's version of getaddrinfo(), if any, may be used only if we found
 916 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 917 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 918 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 919 # because we want to use our own getaddrinfo.c on Windows anyway.)
 920 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 921   AC_REPLACE_FUNCS([getaddrinfo])
 922 else
 923   AC_LIBOBJ(getaddrinfo)
 924 fi
 925
 926 # similarly, use system's getopt_long() only if system provides struct option.
 927 if test x"$ac_cv_type_struct_option" = xyes ; then
 928   AC_REPLACE_FUNCS([getopt_long])
 929 else
 930   AC_LIBOBJ(getopt_long)
 931 fi
 932
 933 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 934 # We override the previous test that said fseeko/ftello didn't exist
 935 # OS tests are also done in include/c.h and port/fseeko.c
 936 case $host_os in bsdi*|netbsd*)
 937 ac_cv_func_fseeko=yes
 938 esac
 939
 940 # Solaris has a very slow qsort in certain cases, so we replace it:
 941 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 942 # Supposedly it is fixed in Solaris, but not sure which version, and
 943 # no confirmed testing.  2005-12-16
 944 if test "$PORTNAME" = "solaris"; then
 945 AC_LIBOBJ(qsort)
 946 fi
 947
 948 # Win32 support
 949 if test "$PORTNAME" = "win32"; then
 950 AC_LIBOBJ(gettimeofday)
 951 AC_LIBOBJ(kill)
 952 AC_LIBOBJ(open)
 953 AC_LIBOBJ(rand)
 954 AC_DEFINE([HAVE_SYMLINK], 1,
 955           [Define to 1 if you have the `symlink' function.])
 956 fi
 957
 958 if test "$with_readline" = yes; then
 959   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 960   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 961   AC_CHECK_FUNCS([replace_history_entry])
 962 fi
 963
 964
 965 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 966 AC_MSG_CHECKING(for finite)
 967 AC_TRY_LINK([
 968 #include <math.h>
 969 double glob_double;
 970 ],
 971             [return finite(glob_double) ? 0 : 1;],
 972             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 973 AC_MSG_RESULT(yes)],
 974             [AC_MSG_RESULT(no)])
 975
 976 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 977 dnl (especially on GNU libc)
 978 dnl See also comments in c.h.
 979 AC_MSG_CHECKING(for sigsetjmp)
 980 AC_TRY_LINK([#include <setjmp.h>],
 981             [sigjmp_buf x; sigsetjmp(x, 1);],
 982             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 983 AC_MSG_RESULT(yes)],
 984             [AC_MSG_RESULT(no)])
 985
 986 AC_CHECK_FUNC(syslog,
 987               [AC_CHECK_HEADER(syslog.h,
 988                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 989
 990 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 991 [AC_TRY_LINK([#include <unistd.h>],
 992   [extern int optreset; optreset = 1;],
 993   [pgac_cv_var_int_optreset=yes],
 994   [pgac_cv_var_int_optreset=no])])
 995 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 996   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 997 fi
 998
 999 AC_CHECK_FUNCS([strtoll strtoq], [break])
1000 AC_CHECK_FUNCS([strtoull strtouq], [break])
1001
1002 # Check for one of atexit() or on_exit()
1003 AC_CHECK_FUNCS(atexit, [],
1004                [AC_CHECK_FUNCS(on_exit, [],
1005                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1006
1007 AC_FUNC_FSEEKO
1008
1009 #
1010 # Pthreads
1011 #
1012 # For each platform, we need to know about any special compile and link
1013 # libraries, and whether the normal C function names are thread-safe.
1014 # See the comment at the top of src/port/thread.c for more information.
1015 #
1016 if test "$enable_thread_safety" = yes; then
1017 ACX_PTHREAD     # set thread flags
1018
1019 # Some platforms use these, so just defineed them.  They can't hurt if they
1020 # are not supported.
1021 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1022
1023
1024 # At this point, we don't want to muck with the compiler name for threading.
1025 # Let's see who fails, perhaps AIX.  2004-04-23
1026 if test "$PTHREAD_CC" != "$CC"; then
1027 AC_MSG_ERROR([
1028 PostgreSQL does not support platforms that require a special
1029 compiler binary for thread-safety.
1030 ])
1031 fi
1032
1033 if test "$THREAD_SUPPORT" = no; then
1034 AC_MSG_ERROR([
1035 Cannot enable threads on your platform.
1036 Your platform is known to not support thread-safe programs.
1037 For details, compile and run src/bin/pg_thread_test.
1038 ])
1039 fi
1040
1041 # Check for *_r functions
1042 _CFLAGS="$CFLAGS"
1043 _LIBS="$LIBS"
1044 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1045 LIBS="$LIBS $PTHREAD_LIBS"
1046
1047 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1048
1049 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1050
1051 # Do test here with the proper thread flags
1052 PGAC_FUNC_GETPWUID_R_5ARG
1053 PGAC_FUNC_STRERROR_R_INT
1054
1055 CFLAGS="$_CFLAGS"
1056 LIBS="$_LIBS"
1057
1058 else
1059 # do not use values from template file
1060 PTHREAD_CFLAGS=
1061 PTHREAD_LIBS=
1062 fi
1063
1064 AC_SUBST(PTHREAD_CFLAGS)
1065 AC_SUBST(PTHREAD_LIBS)
1066
1067
1068 # This test makes sure that run tests work at all.  Sometimes a shared
1069 # library is found by the linker, but the runtime linker can't find it.
1070 # This check should come after all modifications of compiler or linker
1071 # variables, and before any other run tests.
1072 AC_MSG_CHECKING([test program])
1073 AC_TRY_RUN([int main() { return 0; }],
1074 [AC_MSG_RESULT(ok)],
1075 [AC_MSG_RESULT(failed)
1076 AC_MSG_ERROR([[
1077 *** Could not execute a simple test program.  This may be a problem
1078 *** related to locating shared libraries.  Check the file 'config.log'
1079 *** for the exact reason.]])],
1080 [AC_MSG_RESULT([cross-compiling])])
1081
1082 # --------------------
1083 # Run tests below here
1084 # --------------------
1085
1086 # Force use of our snprintf if system's doesn't do arg control
1087 # See comment above at snprintf test for details.
1088 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1089   PGAC_FUNC_PRINTF_ARG_CONTROL
1090   if test $pgac_cv_printf_arg_control != yes ; then
1091     pgac_need_repl_snprintf=yes
1092   fi
1093 fi
1094
1095
1096 dnl Check to see if we have a working 64-bit integer type.
1097 dnl This breaks down into two steps:
1098 dnl (1) figure out if the compiler has a 64-bit int type with working
1099 dnl arithmetic, and if so
1100 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1101 dnl snprintf is the only library routine we really need for int8 support.)
1102 dnl It's entirely possible to have a compiler that handles a 64-bit type
1103 dnl when the C library doesn't; this is fairly likely when using gcc on
1104 dnl an older platform, for example.
1105 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1106 dnl we force our own version of snprintf() to be used instead.
1107 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1108
1109 PGAC_TYPE_64BIT_INT([long int])
1110
1111 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1112   PGAC_TYPE_64BIT_INT([long long int])
1113 fi
1114
1115
1116 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1117
1118 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1119   AC_TRY_COMPILE([
1120 #define INT64CONST(x)  x##LL
1121 long long int foo = INT64CONST(0x1234567890123456);
1122 ],
1123         [],
1124         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1125         [])
1126 fi
1127
1128
1129 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1130 # we found we need to use "long long int", better check.  We cope with
1131 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1132 # work, fall back to our own snprintf emulation (which we know uses %lld).
1133
1134 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1135   if test $pgac_need_repl_snprintf = no; then
1136     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1137     if test "$LONG_LONG_INT_FORMAT" = ""; then
1138       # Force usage of our own snprintf, since system snprintf is broken
1139       pgac_need_repl_snprintf=yes
1140       LONG_LONG_INT_FORMAT='%lld'
1141     fi
1142   else
1143     # Here if we previously decided we needed to use our own snprintf
1144     LONG_LONG_INT_FORMAT='%lld'
1145   fi
1146   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1147   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1148   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1149 else
1150   # Here if we are not using 'long long int' at all
1151   INT64_FORMAT='"%ld"'
1152   UINT64_FORMAT='"%lu"'
1153 fi
1154
1155 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1156                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1157
1158 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1159                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1160
1161 # Now we have checked all the reasons to replace snprintf
1162 if test $pgac_need_repl_snprintf = yes; then
1163   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1164   AC_LIBOBJ(snprintf)
1165 fi
1166
1167 # Need a #define for the size of Datum (unsigned long)
1168 AC_CHECK_SIZEOF([unsigned long])
1169
1170 # And one for the size of size_t (enables tweaks for > 32bit address space)
1171 AC_CHECK_SIZEOF([size_t])
1172
1173 # Determine memory alignment requirements for the basic C data types.
1174
1175 PGAC_CHECK_ALIGNOF(short)
1176 PGAC_CHECK_ALIGNOF(int)
1177 PGAC_CHECK_ALIGNOF(long)
1178 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1179   PGAC_CHECK_ALIGNOF(long long int)
1180 fi
1181 PGAC_CHECK_ALIGNOF(double)
1182
1183 # Compute maximum alignment of any basic type.
1184 # We assume long's alignment is at least as strong as char, short, or int;
1185 # but we must check long long (if it exists) and double.
1186
1187 MAX_ALIGNOF=$pgac_cv_alignof_long
1188 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1189   MAX_ALIGNOF=$pgac_cv_alignof_double
1190 fi
1191 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1192   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1193 fi
1194 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1195
1196
1197 # Some platforms predefine the types int8, int16, etc.  Only check
1198 # a (hopefully) representative subset.
1199 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1200 [#include <stdio.h>
1201 #ifdef HAVE_SUPPORTDEFS_H
1202 #include <SupportDefs.h>
1203 #endif])
1204
1205 # We also check for sig_atomic_t, which *should* be defined per ANSI
1206 # C, but is missing on some old platforms.
1207 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1208
1209
1210 if test x"$template" != x"win32"
1211 then
1212 PGAC_FUNC_POSIX_SIGNALS
1213 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1214   AC_MSG_ERROR([
1215 *** Thread-safety requires POSIX signals, which are not supported by your
1216 *** operating system.
1217 ])
1218 fi
1219 fi
1220
1221 if test $ac_cv_func_fseeko = yes; then
1222 AC_SYS_LARGEFILE
1223 fi
1224
1225 # SunOS doesn't handle negative byte comparisons properly with +/- return
1226 AC_FUNC_MEMCMP
1227
1228
1229 # Select semaphore implementation type.
1230 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1231   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1232   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1233 else
1234   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1235     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1236     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1237   else
1238     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1239     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1240   fi
1241 fi
1242
1243
1244 # Select shared-memory implementation type.
1245 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1246 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1247
1248
1249 if test "$enable_nls" = yes ; then
1250   PGAC_CHECK_GETTEXT
1251 fi
1252
1253 # Check for Tcl configuration script tclConfig.sh
1254 if test "$with_tcl" = yes; then
1255     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1256     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1257                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1258     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1259     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1260     ac_save_CPPFLAGS=$CPPFLAGS
1261     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1262     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1263     CPPFLAGS=$ac_save_CPPFLAGS
1264 fi
1265
1266 #
1267 # Check for DocBook and tools
1268 #
1269 PGAC_PROG_NSGMLS
1270 PGAC_PROG_JADE
1271 PGAC_CHECK_DOCBOOK(4.2)
1272 PGAC_PATH_DOCBOOK_STYLESHEETS
1273 PGAC_PATH_COLLATEINDEX
1274 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1275
1276 # Thread testing
1277
1278 # We have to run the thread test near the end so we have all our symbols
1279 # defined.  Cross compiling throws a warning.
1280 #
1281 if test "$enable_thread_safety_force" = yes; then
1282 if test x"$template" != x"win32"
1283 then
1284   AC_MSG_WARN([
1285 *** Skipping thread test program.  --enable-thread-safety-force was used.
1286 *** Run the program in src/tools/thread on the your machine and add
1287 proper locking function calls to your applications to guarantee thread
1288 safety.
1289 ])
1290 else
1291 AC_MSG_WARN([*** Skipping thread test on Win32])
1292 fi
1293 elif test "$enable_thread_safety" = yes; then
1294 if test x"$template" != x"win32"
1295 then
1296 AC_MSG_CHECKING([thread safety of required library functions])
1297
1298 _CFLAGS="$CFLAGS"
1299 _LIBS="$LIBS"
1300 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1301 LIBS="$LIBS $PTHREAD_LIBS"
1302 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1303   [AC_MSG_RESULT(yes)],
1304   [AC_MSG_RESULT(no)
1305   AC_MSG_ERROR([
1306 *** Thread test program failed.  Your platform is not thread-safe.
1307 *** Check the file 'config.log'for the exact reason.
1308 ***
1309 *** You can use the configure option --enable-thread-safety-force
1310 *** to force threads to be enabled.  However, you must then run
1311 *** the program in src/tools/thread and add locking function calls
1312 *** to your applications to guarantee thread safety.
1313 ])],
1314   [AC_MSG_RESULT(maybe)
1315   AC_MSG_WARN([
1316 *** Skipping thread test program because of cross-compile build.
1317 *** Run the program in src/tools/thread on the target machine.
1318 ])])
1319 CFLAGS="$_CFLAGS"
1320 LIBS="$_LIBS"
1321 else
1322 AC_MSG_WARN([*** Skipping thread test on Win32])
1323 fi
1324 fi
1325
1326 # prepare build tree if outside source tree
1327 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1328 # Note 2: /bin/pwd might be better than shell's built-in at getting
1329 #         a symlink-free name.
1330 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1331   vpath_build=no
1332 else
1333   vpath_build=yes
1334   if test "$no_create" != yes; then
1335     _AS_ECHO_N([preparing build tree... ])
1336     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1337     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1338       || AC_MSG_ERROR(failed)
1339     AC_MSG_RESULT(done)
1340   fi
1341 fi
1342 AC_SUBST(vpath_build)
1343
1344
1345 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1346
1347 AC_CONFIG_LINKS([
1348   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1349   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1350   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1351   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1352   src/include/pg_config_os.h:src/include/port/${template}.h
1353   src/Makefile.port:src/makefiles/Makefile.${template}
1354 ])
1355
1356 if test "$PORTNAME" = "win32"; then
1357 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1358 # Links sometimes fail undetected on Mingw -
1359 # so here we detect it and warn the user
1360 for FILE in $CONFIG_LINKS
1361  do
1362         # test -e works for symlinks in the MinGW console
1363         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1364  done
1365 ])
1366 fi
1367
1368 AC_CONFIG_HEADERS([src/include/pg_config.h],
1369 [
1370 # Update timestamp for pg_config.h (see Makefile.global)
1371 echo >src/include/stamp-h
1372 ])
1373
1374 AC_OUTPUT
1375