granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please read the documentation.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 if test "x${cache_file}" = "x/dev/null"; then
 210   # Likewise, ensure that CC and CPP are passed through to the pcre
 211   # configure script iff caching is disabled (the autoconf 2.5x default).
 212   export CC; export CPP
 213 fi
 214
 215 AC_ARG_WITH(pcre,
 216 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 217
 218 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 219 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 220    PCRE_CONFIG=$with_pcre/bin/pcre-config
 221 elif test -x "$with_pcre"; then
 222    PCRE_CONFIG=$with_pcre
 223 fi
 224
 225 if test "$PCRE_CONFIG" != "false"; then
 226   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 227     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 228   fi
 229   case `$PCRE_CONFIG --version` in
 230   [[1-5].*])
 231     AC_MSG_ERROR([Need at least pcre version 6.0])
 232     ;;
 233   esac
 234   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 235   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 236   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 237 else
 238   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 239 fi
 240 APACHE_SUBST(PCRE_LIBS)
 241
 242 AC_MSG_NOTICE([])
 243 AC_MSG_NOTICE([Configuring Apache httpd...])
 244 AC_MSG_NOTICE([])
 245
 246 dnl If the source dir is not equal to the build dir,
 247 dnl then we are running in VPATH mode.
 248
 249 APR_ADDTO(INCLUDES, [-I.])
 250
 251 if test "$abs_builddir" != "$abs_srcdir"; then
 252   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 253 fi
 254
 255 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 256
 257 # apr/apr-util --includes may pick up system paths for dependent
 258 # libraries, so ensure these are later in INCLUDES than local source
 259 # directories.
 260 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 261 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 262
 263 dnl Add in path to PCRE includes
 264 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 265
 266 AC_MSG_NOTICE([])
 267 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 268 AC_MSG_NOTICE([])
 269
 270 case $host in
 271   *os2*)
 272       # Use a custom made libtool replacement
 273       echo "using aplibtool"
 274       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 275       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 276       SH_LIBS="\$(ALL_LIBS)"
 277       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 278       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 279       MK_IMPLIB="emximp"
 280       other_targets="$other_targets os2core"
 281       INSTALL_PROG_FLAGS="-e .exe"
 282       SHLTCFLAGS=""
 283       LTCFLAGS=""
 284       ;;
 285   *)
 286       if test "x$LTFLAGS" = "x"; then
 287           LTFLAGS='--silent'
 288       fi
 289       my_libtool=`$apr_config --apr-libtool`
 290       LIBTOOL="$my_libtool \$(LTFLAGS)"
 291       libtoolversion=`$my_libtool --version`
 292       case $libtoolversion in
 293           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 294               SH_LIBTOOL='$(LIBTOOL)'
 295               SHLTCFLAGS="-prefer-pic"
 296               LTCFLAGS="-prefer-non-pic -static"
 297               ;;
 298           *)
 299               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 300               SHLTCFLAGS=""
 301               LTCFLAGS=""
 302               ;;
 303       esac
 304       ;;
 305 esac
 306 APACHE_SUBST(SHLTCFLAGS)
 307 APACHE_SUBST(LTCFLAGS)
 308
 309 case $host in
 310   *-apple-aux3*)
 311       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 312       ;;
 313   *os2-emx*)
 314       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 315       ;;
 316   *-linux-*)
 317       case `uname -r` in
 318         2.[[2-9]]* )
 319             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 320             ;;
 321         * )
 322             ;;
 323       esac
 324       ;;
 325   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 326       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 327       ;;
 328   *-solaris2*)
 329       dnl This is a hack -- we should be using AC_TRY_RUN instead
 330       ap_platform_runtime_link_flag="-R"
 331       dnl solaris 8 and above don't have a thundering herd
 332       dnl not sure about rev's before this one.
 333       case `uname -r` in
 334         5.[567]*)
 335             ;;
 336         * )
 337             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 338             ;;
 339       esac
 340       ;;
 341   *cygwin*)
 342       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 343       ;;
 344   *mingw32*)
 345       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 346       APR_SETIFNULL(ac_cv_func_times, [no])
 347       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 348       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 349       ;;
 350   *aix*)
 351       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 352       if test $aixver -ge 4320; then
 353         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 354       fi
 355       ;;
 356   *os390*)
 357       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 358       ;;
 359 esac
 360
 361 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 362
 363 dnl
 364 dnl Process command line arguments. This is done early in the process so the
 365 dnl user can get feedback quickly in case of an error.
 366 dnl
 367 dnl ### need to move some of the arguments "up here"
 368
 369 dnl ## Check for programs
 370
 371 AC_PATH_PROG(RM, rm)
 372 AC_PATH_PROG(PKGCONFIG, pkg-config)
 373 AC_PATH_PROG(RSYNC, rsync)
 374 AC_PROG_AWK
 375 AC_PROG_LN_S
 376 AC_CHECK_TOOL(RANLIB, ranlib, true)
 377 dnl AC_PATH_PROG(PERL_PATH, perl)
 378 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 379
 380 # Hard-coded install programs
 381 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 382 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 383 APACHE_SUBST(MKINSTALLDIRS)
 384 APACHE_SUBST(INSTALL)
 385
 386 dnl Various OS checks that apparently set required flags
 387 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 388 AC_USE_SYSTEM_EXTENSIONS
 389 ], [
 390 AC_AIX
 391 AC_MINIX
 392 ])
 393
 394 AC_ISC_POSIX
 395
 396 # Ensure that satisfactory versions of apr and apr-util are
 397 # found if external copies are configured.
 398 if test "${apr_found}" = "yes"; then
 399   # Require at least APR 1.3.x otherwise fail
 400   APACHE_CHECK_APxVER([apr], 1, 3)
 401 fi
 402
 403 if test "${apu_found}" = "yes"; then
 404   # Require at least APR-util 1.3.x otherwise fail
 405   if test "${apr_found}" = "yes"; then
 406     # we need to add the APR includes to CPPFLAGS
 407     apu_ckver_CPPFLAGS="$CPPFLAGS"
 408     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 409     APACHE_CHECK_APxVER([apu], 1, 3)
 410     CPPFLAGS="$apu_ckver_CPPFLAGS"
 411   else
 412     APACHE_CHECK_APxVER([apu], 1, 3)
 413   fi
 414 fi
 415
 416 dnl Check for what we can generate dependency files with
 417 APR_CHECK_DEPEND
 418
 419 dnl ## Check for libraries
 420
 421 dnl ## Check for header files
 422
 423 dnl I think these are just used all over the place, so just check for
 424 dnl them at the base of the tree. If some are specific to a single
 425 dnl directory, they should be moved (Comment #Spoon)
 426
 427 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 428 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 429 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 430
 431 AC_HEADER_STDC
 432 AC_CHECK_HEADERS( \
 433 string.h \
 434 limits.h \
 435 unistd.h \
 436 sys/socket.h \
 437 pwd.h \
 438 grp.h \
 439 strings.h \
 440 sys/prctl.h \
 441 sys/processor.h \
 442 sys/sem.h \
 443 sys/sdt.h \
 444 sys/loadavg.h
 445 )
 446 AC_HEADER_SYS_WAIT
 447
 448 dnl ## Check for typedefs, structures, and compiler characteristics.
 449
 450 AC_C_CONST
 451
 452 dnl ## Check for library functions
 453 dnl ## sqrt() only needed in support/ab.c
 454 saved_LIBS="$LIBS"
 455 LIBS=""
 456 AC_SEARCH_LIBS(sqrt, m)
 457 MATH_LIBS="$LIBS"
 458 APACHE_SUBST(MATH_LIBS)
 459 LIBS="$saved_LIBS"
 460
 461 saved_LIBS="$LIBS"
 462 LIBS=""
 463 AC_SEARCH_LIBS(crypt, crypt)
 464 CRYPT_LIBS="$LIBS"
 465 APACHE_SUBST(CRYPT_LIBS)
 466 LIBS="$saved_LIBS"
 467
 468 dnl See Comment #Spoon
 469
 470 AC_CHECK_FUNCS( \
 471 getpwnam \
 472 getgrnam \
 473 initgroups \
 474 bindprocessor \
 475 prctl \
 476 timegm \
 477 getpgid \
 478 fopen64 \
 479 getloadavg
 480 )
 481
 482 dnl confirm that a void pointer is large enough to store a long integer
 483 APACHE_CHECK_VOID_PTR_LEN
 484
 485 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 486 [AC_TRY_RUN(#define _GNU_SOURCE
 487 #include <unistd.h>
 488 #include <sys/syscall.h>
 489 #include <sys/types.h>
 490 int main(int argc, char **argv) {
 491 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 492 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 493 if test "$ac_cv_gettid" = "yes"; then
 494     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 495 fi
 496
 497 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 498 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 499 [AC_TRY_COMPILE([#include <sys/types.h>
 500 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 501   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 502 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 503     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 504 fi
 505
 506 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 507
 508 case $host in
 509     *aix*)
 510         # for 32-bit builds, increase MAXDATA to allow lots of threads
 511         if test x$OBJECT_MODE != x64; then
 512             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 513         fi
 514         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 515         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 516         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 517         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 518         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 519         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 520         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 521         ;;
 522     *os390*)
 523         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 524         ;;
 525     *)
 526         OS_SPECIFIC_VARS=""
 527 esac
 528
 529 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 530         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 531         [PORT=80])
 532
 533 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 534         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 535         [SSLPORT=443])
 536
 537 DTRACE=true
 538 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 539 [
 540   enable_dtrace=$enableval
 541   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 542   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 543 ],
 544 [
 545   enable_dtrace=no
 546 ])
 547
 548 dnl Disabled dtrace build for now.
 549 enable_dtrace=no
 550
 551 case $host in
 552   *-solaris2*)
 553     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 554         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 555                   [Enable DTrace probes])
 556         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 557         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 558     fi
 559     ;;
 560 esac
 561
 562 APACHE_SUBST(DTRACE)
 563
 564 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 565 [
 566     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 567         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 568     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 569 ])dnl
 570
 571 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 572 [
 573     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 574               [Allow modules to run hook after a fatal exception])
 575 ])dnl
 576
 577 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 578 [
 579   LOAD_ALL_MODULES=$enableval
 580   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 581 ],
 582 [
 583   LOAD_ALL_MODULES="no"
 584 ])
 585
 586 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 587 [
 588   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 589   if test "$GCC" = "yes"; then
 590     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 591     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 592     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 593     APACHE_ADD_GCC_CFLAG([-Wformat])
 594     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 595     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 596   elif test "$AIX_XLC" = "yes"; then
 597     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 598   fi
 599   if test "x$enable_load_all_modules" = "x"; then
 600     LOAD_ALL_MODULES=yes
 601     AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 602   fi
 603 ])dnl
 604
 605 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 606 [
 607   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 608   if test "$GCC" = "yes"; then
 609     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 610     APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 611     APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 612     APACHE_ADD_GCC_CFLAG([-Wformat])
 613     APACHE_ADD_GCC_CFLAG([-Wformat-security])
 614     APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 615   elif test "$AIX_XLC" = "yes"; then
 616     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 617   fi
 618 ])dnl
 619
 620 dnl Conditionally enable PIE support for GNU toolchains.
 621 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 622 if test "$enable_pie" = "yes"; then
 623    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 624      save_CFLAGS=$CFLAGS
 625      save_LDFLAGS=$LDFLAGS
 626      CFLAGS="$CFLAGS -fPIE"
 627      LDFLAGS="$LDFLAGS -pie"
 628      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 629       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 630      CFLAGS=$save_CFLAGS
 631      LDFLAGS=$save_LDFLAGS
 632    ])
 633    if test "$ap_cv_cc_pie" = "yes"; then
 634      PICFLAGS="-fPIE"
 635      PILDFLAGS="-pie"
 636    else
 637      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 638    fi
 639 fi
 640 APACHE_SUBST(PICFLAGS)
 641 APACHE_SUBST(PILDFLAGS)
 642
 643 prefix="$orig_prefix"
 644 APACHE_ENABLE_MODULES
 645
 646 dnl reading config stubs
 647 esyscmd(./build/config-stubs .)
 648
 649 APACHE_SUBST(progname)
 650 APACHE_SUBST(OS)
 651 APACHE_SUBST(OS_DIR)
 652 APACHE_SUBST(BUILTIN_LIBS)
 653 APACHE_SUBST(SHLIBPATH_VAR)
 654 APACHE_SUBST(OS_SPECIFIC_VARS)
 655
 656 PRE_SHARED_CMDS='echo ""'
 657 POST_SHARED_CMDS='echo ""'
 658
 659 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 660
 661 if test "$apache_need_shared" = "yes"; then
 662   if test -f $ac_aux_dir/ltconfig; then
 663     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 664   fi
 665   shared_build="shared-build"
 666 fi
 667
 668 dnl enable_so tells us if *any* modules can be built as DSOs
 669
 670 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 671   case $host in
 672     *-ibm-aix*)
 673       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 674       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 675       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 676       ;;
 677     *os390)
 678       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 679       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 680   esac
 681   MOD_SO_ENABLED=yes
 682 fi
 683 AC_SUBST(MOD_SO_ENABLED)
 684
 685 APACHE_SUBST(PRE_SHARED_CMDS)
 686 APACHE_SUBST(POST_SHARED_CMDS)
 687 APACHE_SUBST(shared_build)
 688
 689 AC_ARG_WITH(program-name,
 690 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 691   progname="$withval" ], [
 692   progname="httpd"] )
 693
 694 # SuExec parameters
 695 AC_ARG_WITH(suexec-bin,
 696 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 697   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 698 ] )
 699
 700 AC_ARG_WITH(suexec-caller,
 701 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 702   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 703
 704 AC_ARG_WITH(suexec-userdir,
 705 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 706   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 707
 708 AC_ARG_WITH(suexec-docroot,
 709 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 710   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 711
 712 AC_ARG_WITH(suexec-uidmin,
 713 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 714   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 715
 716 AC_ARG_WITH(suexec-gidmin,
 717 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 718   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 719
 720 AC_ARG_WITH(suexec-logfile,
 721 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 722   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 723
 724 AC_ARG_WITH(suexec-safepath,
 725 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 726   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 727
 728 AC_ARG_WITH(suexec-umask,
 729 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 730   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 731
 732 dnl APR should go after the other libs, so the right symbols can be picked up
 733 if test x${apu_found} != xobsolete; then
 734   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 735 fi
 736 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 737 APACHE_SUBST(AP_LIBS)
 738 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 739 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 740
 741 AC_DEFINE(AP_USING_AUTOCONF, 1,
 742                 [Using autoconf to configure Apache])
 743
 744 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 745     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 746               [This platform doesn't suffer from the thundering herd problem])
 747 fi
 748
 749 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 750     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 751               [Listening sockets are non-blocking when there are more than 1])
 752 fi
 753
 754 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 755
 756 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 757 [
 758   v4mapped=$enableval
 759 ],
 760 [
 761     case $host in
 762     *freebsd5*|*netbsd*|*openbsd*)
 763         v4mapped=no
 764         ;;
 765     *)
 766         v4mapped=yes
 767         ;;
 768     esac
 769     if ap_mpm_is_enabled winnt; then
 770         dnl WinNT MPM doesn't support this.
 771         v4mapped=no
 772     fi
 773 ])
 774
 775 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 776     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 777               [Allow IPv4 connections on IPv6 listening sockets])
 778 fi
 779
 780 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 781 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 782 APACHE_FAST_OUTPUT(support/Makefile)
 783
 784 if test -d ./test; then
 785     APACHE_FAST_OUTPUT(test/Makefile)
 786 fi
 787
 788 dnl ## Finalize the variables
 789 AC_MSG_NOTICE([])
 790 AC_MSG_NOTICE([Restore user-defined environment settings...])
 791 AC_MSG_NOTICE([])
 792
 793 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 794 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 795 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 796 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 797 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 798 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 799
 800 AC_MSG_NOTICE([])
 801 AC_MSG_NOTICE([Construct makefiles and header files...])
 802 AC_MSG_NOTICE([])
 803
 804 APACHE_GEN_CONFIG_VARS
 805
 806 dnl ## Build modules.c
 807 rm -f modules.c
 808 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 809
 810 APR_EXPAND_VAR(ap_prefix, $prefix)
 811 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 812         [Root directory of the Apache install area])
 813 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 814         [Location of the config file, relative to the Apache root directory])
 815 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 816         [Location of the MIME types config file, relative to the Apache root directory])
 817
 818 perlbin=`$ac_aux_dir/PrintPath perl`
 819 if test "x$perlbin" = "x"; then
 820     perlbin="/replace/with/path/to/perl/interpreter"
 821 fi
 822 AC_SUBST(perlbin)
 823
 824 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 825
 826 BSD_MAKEFILE=no
 827 ap_make_include=include
 828 ap_make_delimiter=' '
 829 case $host in
 830 *bsdi*)
 831     # Check whether they've installed GNU make
 832     if make --version > /dev/null 2>&1; then
 833         true
 834     else
 835         BSD_MAKEFILE=yes
 836         ap_make_include=.include
 837         ap_make_delimiter='"'
 838     fi
 839     ;;
 840 esac
 841 AC_SUBST(ap_make_include)
 842 AC_SUBST(ap_make_delimiter)
 843
 844 dnl Ensure that docs/conf is created.
 845 test -d docs/conf||$mkdir_p docs/conf
 846
 847 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 848   APACHE_GEN_MAKEFILES
 849 ])