granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(srclib/apr/build/find_apr.m4)
  20 sinclude(srclib/apr-util/build/find_apu.m4)
  21 sinclude(acinclude.m4)
  22
  23 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  24 dnl by configure until it is too late.  Is that how it should be or not?
  25 dnl Something seems broken here.
  26 AC_PREFIX_DEFAULT(/usr/local/apache2)
  27
  28 dnl Get the layout here, so we can pass the required variables to apr
  29 APACHE_ENABLE_LAYOUT
  30
  31 dnl reparse the configure arguments.
  32 APR_PARSE_ARGUMENTS
  33
  34 dnl export expanded and relative configure argument variables
  35 APACHE_EXPORT_ARGUMENTS
  36
  37 dnl Save user-defined environment settings for later restoration
  38 dnl
  39 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  42 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  43 APR_SAVE_THE_ENVIRONMENT(LIBS)
  44 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  45
  46 dnl Generate ./config.nice for reproducing runs of configure
  47 dnl
  48 APR_CONFIG_NICE(config.nice)
  49
  50 nl='
  51 '
  52 dnl Check that mkdir -p works
  53 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  54
  55 dnl ## Run configure for packages Apache uses
  56
  57 dnl shared library support for these packages doesn't currently
  58 dnl work on some platforms
  59
  60 AC_CANONICAL_SYSTEM
  61
  62 orig_prefix="$prefix"
  63
  64 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  65
  66 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr")
  67
  68 if test "$apr_found" = "no"; then
  69   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  70 fi
  71
  72 if test "$apr_found" = "reconfig"; then
  73   APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  80 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  81 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  82 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  83 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  84 APR_BINDIR=`$apr_config --bindir`
  85
  86 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  87
  88 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util")
  89
  90 if test "$apu_found" = "no"; then
  91   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  92 fi
  93
  94 if test "$apu_found" = "reconfig"; then
  95   APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
  96   dnl We must be the last to build and the first to be cleaned
  97   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
  98   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
  99 fi
 100
 101 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 102 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 103 APU_BINDIR=`$apu_config --bindir`
 104
 105 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 106
 107 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
 108
 109 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 110
 111 dnl Absolute source/build directory
 112 abs_srcdir=`(cd $srcdir && pwd)`
 113 abs_builddir=`pwd`
 114
 115 dnl If the source dir is not equal to the build dir,
 116 dnl then we are running in VPATH mode.
 117
 118 if test "$abs_builddir" != "$abs_srcdir"; then
 119   USE_VPATH=1
 120   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/modules/proxy -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/modules/filters -I\$(top_srcdir)/modules/filters -I\$(top_builddir)/include -I\$(top_srcdir)/include])
 121 else
 122   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include])
 123 fi
 124
 125 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 126
 127 case $host in
 128   *os2*)
 129       # Use a custom made libtool replacement
 130       echo "using aplibtool"
 131       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 132       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 133       SH_LIBS="\$(ALL_LIBS)"
 134       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 135       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 136       MK_IMPLIB="emximp"
 137       other_targets="$other_targets os2core"
 138       INSTALL_PROG_FLAGS="-e .exe"
 139       SHLTCFLAGS=""
 140       LTCFLAGS=""
 141       ;;
 142   *)
 143       if test "x$LTFLAGS" = "x"; then
 144           LTFLAGS='--silent'
 145       fi
 146       my_libtool=`$apr_config --apr-libtool`
 147       LIBTOOL="$my_libtool \$(LTFLAGS)"
 148       libtoolversion=`$my_libtool --version`
 149       case $libtoolversion in
 150           *1.4*)
 151               SH_LIBTOOL='$(LIBTOOL)'
 152               SHLTCFLAGS="-prefer-pic"
 153               LTCFLAGS="-prefer-non-pic -static"
 154               ;;
 155           *)
 156               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 157               SHLTCFLAGS=""
 158               LTCFLAGS=""
 159               ;;
 160       esac
 161       ;;
 162 esac
 163 APACHE_SUBST(SHLTCFLAGS)
 164 APACHE_SUBST(LTCFLAGS)
 165
 166 AP_SIG_GRACEFUL=USR1
 167
 168 case $host in
 169   *-apple-aux3*)
 170       APR_SETVAR(APACHE_MPM, [prefork])
 171       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 172       ;;
 173   *-beos*)
 174       APR_SETVAR(APACHE_MPM, [beos])
 175       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 176       ;;
 177   *os2_emx*)
 178       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 179       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 180       ;;
 181   *-linux-*)
 182       case `uname -r` in
 183         2.0* )
 184             AP_SIG_GRACEFUL=WINCH
 185             ;;
 186         2.[[2-9]]* )
 187             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 188             ;;
 189         * )
 190             ;;
 191       esac
 192       ;;
 193   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 194       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 195       ;;
 196   *-solaris2*)
 197       dnl This is a hack -- we should be using AC_TRY_RUN instead
 198       ap_platform_runtime_link_flag="-R"
 199       dnl solaris 8 and above don't have a thundering herd
 200       dnl not sure about rev's before this one.
 201       case `uname -r` in
 202         5.[567]*)
 203             ;;
 204         * )
 205             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 206             ;;
 207       esac
 208       ;;
 209   *cygwin*)
 210       APR_SETVAR(APACHE_MPM, [prefork])
 211       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 212       ;;
 213   *aix*)
 214       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 215       if test $aixver -ge 4320; then
 216         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 217       fi
 218       ;;
 219   *os390*)
 220       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 221       ;;
 222 esac
 223
 224 dnl
 225 dnl Process command line arguments. This is done early in the process so the
 226 dnl user can get feedback quickly in case of an error.
 227 dnl
 228 dnl ### need to move some of the arguments "up here"
 229
 230 dnl ## Check for programs
 231
 232 AC_PATH_PROG(RM, rm)
 233 AC_PROG_AWK
 234 AC_PROG_CC
 235 AC_PROG_CPP
 236 AC_PROG_INSTALL
 237 AC_PROG_LN_S
 238 AC_CHECK_TOOL(RANLIB, ranlib, true)
 239 dnl AC_PATH_PROG(PERL_PATH, perl)
 240
 241 dnl various OS checks that apparently set required flags
 242 AC_AIX
 243 AC_ISC_POSIX
 244 AC_MINIX
 245
 246 dnl ## Check for libraries
 247
 248 dnl ## Check for header files
 249
 250 dnl I think these are just used all over the place, so just check for
 251 dnl them at the base of the tree. If some are specific to a single
 252 dnl directory, they should be moved (Comment #Spoon)
 253
 254 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 255 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 256 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 257
 258 AC_HEADER_STDC
 259 AC_CHECK_HEADERS( \
 260 string.h \
 261 limits.h \
 262 unistd.h \
 263 sys/socket.h \
 264 pwd.h \
 265 grp.h \
 266 strings.h \
 267 sys/processor.h \
 268 sys/sem.h
 269 )
 270 AC_HEADER_SYS_WAIT
 271
 272 dnl ## Check for typedefs, structures, and compiler characteristics.
 273
 274 AC_C_CONST
 275 if test "$ac_cv_prog_gcc" = "yes"; then
 276   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 277 fi
 278
 279 dnl ## Check for library functions
 280
 281 dnl See Comment #Spoon
 282
 283 AC_CHECK_FUNCS( \
 284 getpwnam \
 285 getgrnam \
 286 initgroups \
 287 bindprocessor \
 288 timegm \
 289 )
 290
 291 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 292 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 293 [AC_TRY_COMPILE([#include <sys/types.h>
 294 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 295   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 296 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 297     AC_DEFINE(HAVE_GMTOFF)
 298 fi
 299
 300 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 301
 302 case $host in
 303     *aix*)
 304         # for 32-bit builds, increase MAXDATA to allow lots of threads
 305         if test x$OBJECT_MODE != x64; then
 306             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 307         fi
 308         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 309         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 310         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 311         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 312         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 313         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 314         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 315         ;;
 316     *os390*)
 317         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 318         ;;
 319     *)
 320         OS_SPECIFIC_VARS=""
 321 esac
 322
 323 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 324         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 325         [PORT=80])
 326
 327 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 328 [
 329   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 330 ])dnl
 331
 332 prefix="$orig_prefix"
 333 APACHE_ENABLE_MODULES
 334
 335 dnl reading config stubs
 336 esyscmd(./build/config-stubs .)
 337
 338 APACHE_SUBST(progname)
 339 APACHE_SUBST(MPM_LIB)
 340 APACHE_SUBST(OS)
 341 APACHE_SUBST(OS_DIR)
 342 APACHE_SUBST(BUILTIN_LIBS)
 343 APACHE_SUBST(SHLIBPATH_VAR)
 344 APACHE_SUBST(OS_SPECIFIC_VARS)
 345
 346 PRE_SHARED_CMDS='echo ""'
 347 POST_SHARED_CMDS='echo ""'
 348
 349 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 350
 351 if test "$apache_need_shared" = "yes"; then
 352   if test -f $ac_aux_dir/ltconfig; then
 353     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 354   fi
 355   shared_build="shared-build"
 356 fi
 357
 358 dnl enable_so tells us if *any* modules can be built as DSOs
 359
 360 if test "$enable_so" = "yes"; then
 361   case $host in
 362     *-ibm-aix*)
 363       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 364       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 365       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 366       ;;
 367     *beos)
 368       SH_LDFLAGS='$(top_builddir)/_APP_'
 369       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 370       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 371       ;;
 372     *os390)
 373       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 374       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 375   esac
 376 fi
 377
 378 APACHE_SUBST(PRE_SHARED_CMDS)
 379 APACHE_SUBST(POST_SHARED_CMDS)
 380 APACHE_SUBST(shared_build)
 381
 382 AC_ARG_WITH(program-name,
 383 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 384   progname="$withval" ], [
 385   progname="httpd"] )
 386
 387 # SuExec parameters
 388 AC_ARG_WITH(suexec-bin,
 389 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 390   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 391 ] )
 392
 393 AC_ARG_WITH(suexec-caller,
 394 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 395   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 396
 397 AC_ARG_WITH(suexec-userdir,
 398 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 399   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 400
 401 AC_ARG_WITH(suexec-docroot,
 402 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 403   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 404
 405 AC_ARG_WITH(suexec-uidmin,
 406 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 407   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 408
 409 AC_ARG_WITH(suexec-gidmin,
 410 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 411   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 412
 413 AC_ARG_WITH(suexec-logfile,
 414 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 415   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 416
 417 AC_ARG_WITH(suexec-safepath,
 418 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 419   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 420
 421 AC_ARG_WITH(suexec-umask,
 422 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 423   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 424
 425 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 426 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 427
 428 dnl APR should go after the other libs, so the right symbols can be picked up
 429 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 430 APACHE_SUBST(AP_LIBS)
 431 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 432 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 433
 434 AC_DEFINE(AP_USING_AUTOCONF, 1,
 435                 [Using autoconf to configure Apache])
 436
 437 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 438     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 439               [This platform doesn't suffer from the thundering herd problem])
 440 fi
 441
 442 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 443 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 444 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 445 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 446 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 447 AC_SUBST(AP_SIG_GRACEFUL)
 448 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 449 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 450
 451 dnl check for endianness
 452 if test "$cross_compiling" = "no"; then
 453   AC_C_BIGENDIAN
 454 else
 455   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 456                 [byte order is unknown due to cross-compilation])
 457 fi
 458
 459 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 460 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 461 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 462 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 463
 464 if test -d ./test; then
 465     APACHE_FAST_OUTPUT(test/Makefile)
 466 fi
 467
 468 dnl ## Finalize the variables
 469 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 470
 471 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 472 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 473 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 474 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 475 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 476 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 477
 478 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 479
 480 APACHE_GEN_CONFIG_VARS
 481
 482 dnl ## Build modules.c
 483 rm -f modules.c
 484 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 485
 486 APR_EXPAND_VAR(ap_prefix, $prefix)
 487 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 488         [Root directory of the Apache install area])
 489 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 490         [Location of the config file, relative to the Apache root directory])
 491 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 492         [Location of the MIME types config file, relative to the Apache root directory])
 493 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 494         [Location of the source for the current MPM])
 495
 496 perlbin=`$ac_aux_dir/PrintPath perl`
 497 if test "x$perlbin" = "x"; then
 498     perlbin="/replace/with/path/to/perl/interpreter"
 499 fi
 500 AC_SUBST(perlbin)
 501
 502 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 503
 504 BSD_MAKEFILE=no
 505 ap_make_include=include
 506 ap_make_delimiter=' '
 507 case $host in
 508 *bsdi*)
 509     # Check whether they've installed GNU make
 510     if make --version > /dev/null 2>&1; then
 511         true
 512     else
 513         BSD_MAKEFILE=yes
 514         ap_make_include=.include
 515         ap_make_delimiter='"'
 516     fi
 517     ;;
 518 esac
 519 AC_SUBST(ap_make_include)
 520 AC_SUBST(ap_make_delimiter)
 521
 522 dnl Ensure that docs/conf is created.
 523 test -d docs/conf||$mkdir_p docs/conf
 524
 525 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 526   APACHE_GEN_MAKEFILES
 527 ])
 528