granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225
 226 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 227 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 228    PCRE_CONFIG=$with_pcre/bin/pcre-config
 229 elif test -x "$with_pcre"; then
 230    PCRE_CONFIG=$with_pcre
 231 fi
 232
 233 if test "$PCRE_CONFIG" != "false"; then
 234   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 235     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 236   fi
 237   case `$PCRE_CONFIG --version` in
 238   [[1-5].*])
 239     AC_MSG_ERROR([Need at least pcre version 6.0])
 240     ;;
 241   esac
 242   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 243   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 244   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 245   APR_ADDTO(HTTPD_LIBS, [\$(PCRE_LIBS)])
 246 else
 247   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 248 fi
 249 APACHE_SUBST(PCRE_LIBS)
 250
 251 AC_MSG_NOTICE([])
 252 AC_MSG_NOTICE([Configuring Apache httpd...])
 253 AC_MSG_NOTICE([])
 254
 255 dnl If the source dir is not equal to the build dir,
 256 dnl then we are running in VPATH mode.
 257
 258 APR_ADDTO(INCLUDES, [-I.])
 259
 260 if test "$abs_builddir" != "$abs_srcdir"; then
 261   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 262 fi
 263
 264 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 265
 266 # apr/apr-util --includes may pick up system paths for dependent
 267 # libraries, so ensure these are later in INCLUDES than local source
 268 # directories.
 269 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 270 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 271
 272 dnl Add in path to PCRE includes
 273 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 274
 275 AC_MSG_NOTICE([])
 276 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 277 AC_MSG_NOTICE([])
 278
 279 case $host in
 280   *os2*)
 281       # Use a custom made libtool replacement
 282       echo "using aplibtool"
 283       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 284       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 285       SH_LIBS="\$(ALL_LIBS)"
 286       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 287       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 288       MK_IMPLIB="emximp"
 289       other_targets="$other_targets os2core"
 290       INSTALL_PROG_FLAGS="-e .exe"
 291       SHLTCFLAGS=""
 292       LTCFLAGS=""
 293       ;;
 294   *)
 295       if test "x$LTFLAGS" = "x"; then
 296           LTFLAGS='--silent'
 297       fi
 298       my_libtool=`$apr_config --apr-libtool`
 299       LIBTOOL="$my_libtool \$(LTFLAGS)"
 300       libtoolversion=`$my_libtool --version`
 301       case $libtoolversion in
 302           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 303               SH_LIBTOOL='$(LIBTOOL)'
 304               SHLTCFLAGS="-prefer-pic"
 305               LTCFLAGS="-prefer-non-pic -static"
 306               ;;
 307           *)
 308               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 309               SHLTCFLAGS=""
 310               LTCFLAGS=""
 311               ;;
 312       esac
 313       ;;
 314 esac
 315 APACHE_SUBST(SHLTCFLAGS)
 316 APACHE_SUBST(LTCFLAGS)
 317
 318 case $host in
 319   *-apple-aux3*)
 320       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 321       ;;
 322   *os2-emx*)
 323       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 324       ;;
 325   *-linux-*)
 326       case `uname -r` in
 327         # Unserialized accept() was not recommended until Linux 2.2.
 328         [[01]].* | 2.[[01]]* )
 329             ;;
 330         * )
 331             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 332             ;;
 333       esac
 334       ;;
 335   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 336       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 337       ;;
 338   *-solaris2*)
 339       dnl This is a hack -- we should be using AC_TRY_RUN instead
 340       ap_platform_runtime_link_flag="-R"
 341       dnl solaris 8 and above don't have a thundering herd
 342       dnl not sure about rev's before this one.
 343       case `uname -r` in
 344         5.[567]*)
 345             ;;
 346         * )
 347             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 348             ;;
 349       esac
 350       ;;
 351   *cygwin*)
 352       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 353       ;;
 354   *mingw32*)
 355       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 356       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 357       APR_SETIFNULL(ac_cv_func_times, [no])
 358       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 359       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 360       ;;
 361   *aix*)
 362       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 363       if test $aixver -ge 4320; then
 364         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 365       fi
 366       ;;
 367   *os390*)
 368       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 369       ;;
 370 esac
 371
 372 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 373
 374 dnl
 375 dnl Process command line arguments. This is done early in the process so the
 376 dnl user can get feedback quickly in case of an error.
 377 dnl
 378 dnl ### need to move some of the arguments "up here"
 379
 380 dnl ## Check for programs
 381
 382 AC_PATH_PROG(RM, rm)
 383 AC_PATH_PROG(PKGCONFIG, pkg-config)
 384 AC_PATH_PROG(RSYNC, rsync)
 385 AC_PROG_AWK
 386 AC_PROG_LN_S
 387 AC_CHECK_TOOL(RANLIB, ranlib, true)
 388 dnl AC_PATH_PROG(PERL_PATH, perl)
 389 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 390
 391 # Hard-coded install programs
 392 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 393 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 394 APACHE_SUBST(MKINSTALLDIRS)
 395 APACHE_SUBST(INSTALL)
 396
 397 dnl Various OS checks that apparently set required flags
 398 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 399 AC_USE_SYSTEM_EXTENSIONS
 400 ], [
 401 AC_AIX
 402 AC_MINIX
 403 ])
 404
 405 AC_ISC_POSIX
 406
 407 # Ensure that satisfactory versions of apr and apr-util are
 408 # found if external copies are configured.
 409 if test "${apr_found}" = "yes"; then
 410   # Require at least APR 1.3.x otherwise fail
 411   APACHE_CHECK_APxVER([apr], 1, 3)
 412 fi
 413
 414 if test "${apu_found}" = "yes"; then
 415   # Require at least APR-util 1.3.x otherwise fail
 416   if test "${apr_found}" = "yes"; then
 417     # we need to add the APR includes to CPPFLAGS
 418     apu_ckver_CPPFLAGS="$CPPFLAGS"
 419     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 420     APACHE_CHECK_APxVER([apu], 1, 3)
 421     CPPFLAGS="$apu_ckver_CPPFLAGS"
 422   else
 423     APACHE_CHECK_APxVER([apu], 1, 3)
 424   fi
 425 fi
 426
 427 dnl Check for what we can generate dependency files with
 428 APR_CHECK_DEPEND
 429
 430 dnl ## Check for libraries
 431
 432 dnl ## Check for header files
 433
 434 dnl I think these are just used all over the place, so just check for
 435 dnl them at the base of the tree. If some are specific to a single
 436 dnl directory, they should be moved (Comment #Spoon)
 437
 438 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 439 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 440 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 441
 442 AC_HEADER_STDC
 443 AC_CHECK_HEADERS( \
 444 string.h \
 445 limits.h \
 446 unistd.h \
 447 sys/socket.h \
 448 pwd.h \
 449 grp.h \
 450 strings.h \
 451 sys/prctl.h \
 452 sys/processor.h \
 453 sys/sem.h \
 454 sys/sdt.h \
 455 sys/loadavg.h
 456 )
 457 AC_HEADER_SYS_WAIT
 458
 459 dnl ## Check for typedefs, structures, and compiler characteristics.
 460
 461 AC_C_CONST
 462
 463 dnl ## Check for library functions
 464 dnl ## sqrt() only needed in support/ab.c
 465 saved_LIBS="$LIBS"
 466 LIBS=""
 467 AC_SEARCH_LIBS(sqrt, m)
 468 MATH_LIBS="$LIBS"
 469 APACHE_SUBST(MATH_LIBS)
 470 LIBS="$saved_LIBS"
 471
 472 saved_LIBS="$LIBS"
 473 LIBS=""
 474 AC_SEARCH_LIBS(crypt, crypt)
 475 CRYPT_LIBS="$LIBS"
 476 APACHE_SUBST(CRYPT_LIBS)
 477 LIBS="$saved_LIBS"
 478
 479 dnl See Comment #Spoon
 480
 481 AC_CHECK_FUNCS( \
 482 getpwnam \
 483 getgrnam \
 484 initgroups \
 485 bindprocessor \
 486 prctl \
 487 timegm \
 488 getpgid \
 489 fopen64 \
 490 getloadavg
 491 )
 492
 493 dnl confirm that a void pointer is large enough to store a long integer
 494 APACHE_CHECK_VOID_PTR_LEN
 495
 496 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 497 [AC_TRY_RUN(#define _GNU_SOURCE
 498 #include <unistd.h>
 499 #include <sys/syscall.h>
 500 #include <sys/types.h>
 501 int main(int argc, char **argv) {
 502 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 503 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 504 if test "$ac_cv_gettid" = "yes"; then
 505     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 506 fi
 507
 508 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 509 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 510 [AC_TRY_COMPILE([#include <sys/types.h>
 511 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 512   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 513 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 514     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 515 fi
 516
 517 dnl Check for systemd support for listen.c's socket activation.
 518 case $host in
 519 *-linux-*)
 520       AC_CHECK_LIB(systemd-daemon, sd_notify, SYSTEMD_LIBS="-lsystemd-daemon")
 521       AC_CHECK_HEADERS(systemd/sd-daemon.h)
 522       if test "${ac_cv_header_systemd_sd_daemon_h}" = "no" || test -z "${SYSTEMD_LIBS}"; then
 523         AC_MSG_WARN([Your system does not support systemd.])
 524       else
 525         APR_ADDTO(HTTPD_LIBS, [$SYSTEMD_LIBS])
 526         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd is supported])
 527       fi
 528 esac
 529
 530 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 531
 532 case $host in
 533     *aix*)
 534         # for 32-bit builds, increase MAXDATA to allow lots of threads
 535         if test x$OBJECT_MODE != x64; then
 536             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 537         fi
 538         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 539         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 540         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 541         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 542         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 543         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 544         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 545         ;;
 546     *os390*)
 547         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 548         ;;
 549     *)
 550         OS_SPECIFIC_VARS=""
 551 esac
 552
 553 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 554         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 555         [PORT=80])
 556
 557 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 558         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 559         [SSLPORT=443])
 560
 561 DTRACE=true
 562 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 563 [
 564   enable_dtrace=$enableval
 565   if test "$enableval" = "yes"; then
 566     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 567     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 568   fi
 569 ],
 570 [
 571   enable_dtrace=no
 572 ])
 573
 574 dnl Disabled dtrace build for now.
 575 enable_dtrace=no
 576
 577 case $host in
 578   *-solaris2*)
 579     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 580         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 581                   [Enable DTrace probes])
 582         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 583         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 584     fi
 585     ;;
 586 esac
 587
 588 APACHE_SUBST(DTRACE)
 589
 590 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 591 [
 592     if test "$enableval" = "yes"; then
 593         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 594                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 595         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 596     fi
 597 ])dnl
 598
 599 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 600 [
 601     if test "$enableval" = "yes"; then
 602         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 603                   [Allow modules to run hook after a fatal exception])
 604     fi
 605 ])dnl
 606
 607 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 608 [
 609   LOAD_ALL_MODULES=$enableval
 610   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 611 ],
 612 [
 613   LOAD_ALL_MODULES="no"
 614 ])
 615
 616 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 617 [
 618   if test "$enableval" = "yes"; then
 619     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 620     if test "$GCC" = "yes"; then
 621       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 622       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 623       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 624       APACHE_ADD_GCC_CFLAG([-Wformat])
 625       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 626       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 627     elif test "$AIX_XLC" = "yes"; then
 628       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 629     fi
 630     if test "x$enable_load_all_modules" = "x"; then
 631       LOAD_ALL_MODULES=yes
 632       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 633     fi
 634     if test "x$enable_bucketeer" = "x"; then
 635       enable_bucketeer=yes
 636       AC_MSG_NOTICE([Maintainer mode setting "enable_bucketeer" to yes])
 637     fi
 638   fi
 639 ])dnl
 640
 641 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 642 [
 643   if test "$enableval" = "yes"; then
 644     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 645     if test "$GCC" = "yes"; then
 646       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 647       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 648       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 649       APACHE_ADD_GCC_CFLAG([-Wformat])
 650       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 651       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 652     elif test "$AIX_XLC" = "yes"; then
 653       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 654     fi
 655   fi
 656 ])dnl
 657
 658 dnl Conditionally enable PIE support for GNU toolchains.
 659 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 660 if test "$enable_pie" = "yes"; then
 661    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 662      save_CFLAGS=$CFLAGS
 663      save_LDFLAGS=$LDFLAGS
 664      CFLAGS="$CFLAGS -fPIE"
 665      LDFLAGS="$LDFLAGS -pie"
 666      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 667       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 668      CFLAGS=$save_CFLAGS
 669      LDFLAGS=$save_LDFLAGS
 670    ])
 671    if test "$ap_cv_cc_pie" = "yes"; then
 672      PICFLAGS="-fPIE"
 673      PILDFLAGS="-pie"
 674    else
 675      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 676    fi
 677 fi
 678 APACHE_SUBST(PICFLAGS)
 679 APACHE_SUBST(PILDFLAGS)
 680
 681 AC_ARG_WITH(valgrind,
 682   [  --with-valgrind[[=DIR]]   Enable code to reduce valgrind false positives
 683                           (optionally: set path to valgrind headers) ],
 684   [ if test "$withval" != no; then
 685       if test "$withval" = yes; then
 686         withval=/usr/include/valgrind
 687       fi
 688       APR_ADDTO(CPPFLAGS, -I$withval)
 689       AC_CHECK_HEADERS(valgrind.h memcheck.h)
 690       APR_IFALLYES(header:valgrind.h header:memcheck.h,
 691         [AC_DEFINE(HAVE_VALGRIND, 1, [Compile in valgrind support]) ],
 692         [AC_MSG_ERROR(valgrind headers not found) ]
 693       )
 694     fi ]
 695 )
 696
 697 prefix="$orig_prefix"
 698 APACHE_ENABLE_MODULES
 699
 700 dnl reading config stubs
 701 esyscmd(./build/config-stubs .)
 702
 703 APACHE_SUBST(progname)
 704 APACHE_SUBST(OS)
 705 APACHE_SUBST(OS_DIR)
 706 APACHE_SUBST(BUILTIN_LIBS)
 707 APACHE_SUBST(SHLIBPATH_VAR)
 708 APACHE_SUBST(OS_SPECIFIC_VARS)
 709 APACHE_SUBST(HTTPD_LIBS)
 710
 711 PRE_SHARED_CMDS='echo ""'
 712 POST_SHARED_CMDS='echo ""'
 713
 714 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 715
 716 if test "$apache_need_shared" = "yes"; then
 717   if test -f $ac_aux_dir/ltconfig; then
 718     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 719   fi
 720   shared_build="shared-build"
 721 fi
 722
 723 dnl enable_so tells us if *any* modules can be built as DSOs
 724
 725 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 726   case $host in
 727     *-ibm-aix*)
 728       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 729       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 730       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 731       ;;
 732     *os390)
 733       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 734       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 735   esac
 736   MOD_SO_ENABLED=yes
 737 fi
 738 AC_SUBST(MOD_SO_ENABLED)
 739
 740 APACHE_SUBST(PRE_SHARED_CMDS)
 741 APACHE_SUBST(POST_SHARED_CMDS)
 742 APACHE_SUBST(shared_build)
 743
 744 AC_ARG_WITH(program-name,
 745 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 746   progname="$withval" ], [
 747   progname="httpd"] )
 748
 749 # SuExec parameters
 750 AC_ARG_WITH(suexec-bin,
 751 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 752   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 753 ] )
 754
 755 AC_ARG_WITH(suexec-caller,
 756 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 757   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 758
 759 AC_ARG_WITH(suexec-userdir,
 760 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 761   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 762
 763 AC_ARG_WITH(suexec-docroot,
 764 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 765   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 766
 767 AC_ARG_WITH(suexec-uidmin,
 768 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 769   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 770
 771 AC_ARG_WITH(suexec-gidmin,
 772 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 773   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 774
 775 AC_ARG_WITH(suexec-logfile,
 776 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 777   if test "x$withval" = "xyes"; then
 778     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 779   elif test "x$withval" != "xno"; then
 780     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 781   fi
 782 ])
 783
 784 AC_ARG_WITH(suexec-syslog,
 785 APACHE_HELP_STRING(--with-suexec-syslog,Set the logfile),[
 786   if test $withval = "yes"; then
 787     if test "x${with_suexec_logfile}" != "xno"; then
 788       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 789       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 790     fi
 791     AC_CHECK_FUNCS([vsyslog], [], [
 792        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 793     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 794   fi
 795 ])
 796
 797
 798 AC_ARG_WITH(suexec-safepath,
 799 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 800   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 801
 802 AC_ARG_WITH(suexec-umask,
 803 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 804   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 805
 806 INSTALL_SUEXEC=setuid
 807 AC_ARG_ENABLE([suexec-capabilities],
 808 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 809   if test "$enableval" = "yes"; then
 810     INSTALL_SUEXEC=caps
 811     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 812               [Enable if suexec is installed with Linux capabilities, not setuid])
 813   fi
 814 ])
 815 APACHE_SUBST(INSTALL_SUEXEC)
 816
 817 dnl APR should go after the other libs, so the right symbols can be picked up
 818 if test x${apu_found} != xobsolete; then
 819   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 820 fi
 821 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 822 APACHE_SUBST(AP_LIBS)
 823 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 824 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 825
 826 AC_DEFINE(AP_USING_AUTOCONF, 1,
 827                 [Using autoconf to configure Apache])
 828
 829 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 830     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 831               [This platform doesn't suffer from the thundering herd problem])
 832 fi
 833
 834 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 835     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 836               [Listening sockets are non-blocking when there are more than 1])
 837 fi
 838
 839 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 840
 841 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 842 [
 843   v4mapped=$enableval
 844 ],
 845 [
 846     case $host in
 847     *freebsd[1234].*)
 848         v4mapped=yes
 849         ;;
 850     *freebsd*|*netbsd*|*openbsd*)
 851         v4mapped=no
 852         ;;
 853     *)
 854         v4mapped=yes
 855         ;;
 856     esac
 857     if ap_mpm_is_enabled winnt; then
 858         dnl WinNT MPM doesn't support this.
 859         v4mapped=no
 860     fi
 861 ])
 862
 863 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 864     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 865               [Allow IPv4 connections on IPv6 listening sockets])
 866 fi
 867
 868 AC_ARG_ENABLE(bsd-makefiles,APACHE_HELP_STRING(--enable-bsd-makefiles,use BSD Makefile syntax),
 869 [
 870   FORCE_BSD_MAKEFILE=$enableval
 871   AC_MSG_NOTICE([Setting "FORCE_BSD_MAKEFILE" to $FORCE_BSD_MAKEFILE])
 872 ],
 873 [
 874   FORCE_BSD_MAKEFILE="auto"
 875 ])
 876
 877 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 878 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 879 APACHE_FAST_OUTPUT(support/Makefile)
 880
 881 if test -d ./test; then
 882     APACHE_FAST_OUTPUT(test/Makefile)
 883 fi
 884
 885 dnl ## Finalize the variables
 886 AC_MSG_NOTICE([])
 887 AC_MSG_NOTICE([Restore user-defined environment settings...])
 888 AC_MSG_NOTICE([])
 889
 890 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 891 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 892 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 893 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 894 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 895 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 896
 897 AC_MSG_NOTICE([])
 898 AC_MSG_NOTICE([Construct makefiles and header files...])
 899 AC_MSG_NOTICE([])
 900
 901 APACHE_GEN_CONFIG_VARS
 902
 903 dnl ## Build modules.c
 904 rm -f modules.c
 905 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 906
 907 APR_EXPAND_VAR(ap_prefix, $prefix)
 908 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 909         [Root directory of the Apache install area])
 910 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 911         [Location of the config file, relative to the Apache root directory])
 912 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 913         [Location of the MIME types config file, relative to the Apache root directory])
 914
 915 perlbin=`$ac_aux_dir/PrintPath perl`
 916 if test "x$perlbin" = "x"; then
 917     perlbin="/replace/with/path/to/perl/interpreter"
 918 fi
 919 AC_SUBST(perlbin)
 920
 921 dnl If we are running on a BSD variant, see if we need to use the BSD .include syntax.
 922
 923 ap_make_include=include
 924 ap_make_ifdef=ifdef
 925 ap_make_else=else
 926 ap_make_endif=endif
 927 ap_make_delimiter=' '
 928 if test "x$FORCE_BSD_MAKEFILE" = "xno"; then
 929   BSD_MAKEFILE=no
 930 elif test "x$FORCE_BSD_MAKEFILE" = "xyes"; then
 931   BSD_MAKEFILE=yes
 932 else
 933   case $host in
 934   *bsd*)
 935       # Check whether they've installed GNU make
 936       if make --version > /dev/null 2>&1; then
 937           BSD_MAKEFILE=no
 938       else
 939           BSD_MAKEFILE=yes
 940       fi
 941       ;;
 942   *)
 943       BSD_MAKEFILE=no
 944       ;;
 945   esac
 946 fi
 947 if test "x$BSD_MAKEFILE" = "xyes"; then
 948   ap_make_include=.include
 949   ap_make_ifdef=.ifdef
 950   ap_make_else=.else
 951   ap_make_endif=.endif
 952   ap_make_delimiter='"'
 953 fi
 954 AC_MSG_NOTICE([using BSD Makefile syntax... $BSD_MAKEFILE])
 955
 956 AC_SUBST(ap_make_include)
 957 AC_SUBST(ap_make_ifdef)
 958 AC_SUBST(ap_make_else)
 959 AC_SUBST(ap_make_endif)
 960 AC_SUBST(ap_make_delimiter)
 961
 962 dnl Ensure that docs/conf is created.
 963 test -d docs/conf||$mkdir_p docs/conf
 964
 965 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 966   APACHE_GEN_MAKEFILES
 967 ])