granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.322 2004/03/24 03:54:16 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [7.5devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix5 ;;
  60    linux*) template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      qnx*) template=qnx4 ;;
  67      sco*) template=sco ;;
  68  solaris*) template=solaris ;;
  69    sunos*) template=sunos4 ;;
  70  sysv4.2*)
  71         case $host_vendor in
  72           univel) template=univel ;;
  73         esac ;;
  74    sysv4*) template=svr4 ;;
  75    sysv5*) template=unixware ;;
  76   ultrix*) template=ultrix4 ;;
  77 esac
  78
  79   if test x"$template" = x"" ; then
  80     AC_MSG_ERROR([[
  81 *******************************************************************
  82 PostgreSQL has apparently not been ported to your platform yet.
  83 To try a manual configuration, look into the src/template directory
  84 for a similar platform and use the '--with-template=' option.
  85
  86 Please also contact <pgsql-ports@postgresql.org> to see about
  87 rectifying this.  Include the above 'checking host system type...'
  88 line.
  89 *******************************************************************
  90 ]])
  91   fi
  92
  93 ])
  94
  95 AC_MSG_RESULT([$template])
  96
  97 PORTNAME=$template
  98 AC_SUBST(PORTNAME)
  99
 100 # Initialize default assumption that we do not need separate assembly code
 101 # for TAS (test-and-set).  This can be overridden by the template file
 102 # when it's executed.
 103 need_tas=no
 104 tas_file=dummy.s
 105
 106
 107
 108 ##
 109 ## Command line options
 110 ##
 111
 112 #
 113 # Installation directory for documentation
 114 #
 115 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 116   --without-docdir        do not install the documentation],
 117          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 118          [docdir=],
 119          [docdir=$withval],
 120          [docdir='${prefix}/doc'])
 121 AC_SUBST(docdir)
 122
 123
 124 #
 125 # Add non-standard directories to the include path
 126 #
 127 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 128
 129
 130 #
 131 # Add non-standard directories to the library search path
 132 #
 133 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 134              [LIBRARY_DIRS=$withval])
 135
 136 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 137              [LIBRARY_DIRS=$withval])
 138
 139
 140 #
 141 # 64-bit integer date/time storage (--enable-integer-datetimes)
 142 #
 143 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 144 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 145               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 146                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 147 AC_MSG_RESULT([$enable_integer_datetimes])
 148
 149
 150 #
 151 # NLS
 152 #
 153 AC_MSG_CHECKING([whether NLS is wanted])
 154 PGAC_ARG_OPTARG(enable, nls,
 155                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 156                 [],
 157                 [WANTED_LANGUAGES=$enableval],
 158                 [AC_DEFINE(ENABLE_NLS, 1,
 159                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 160 AC_MSG_RESULT([$enable_nls])
 161 AC_SUBST(enable_nls)
 162 AC_SUBST(WANTED_LANGUAGES)
 163
 164 #
 165 # Default port number (--with-pgport), default 5432
 166 #
 167 AC_MSG_CHECKING([for default port number])
 168 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 169              [default_port=$withval],
 170              [default_port=5432])
 171 AC_MSG_RESULT([$default_port])
 172 # Need both of these because some places want an integer and some a string
 173 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 174 [Define to the default TCP port number on which the server listens and
 175 to which clients will try to connect.  This can be overridden at run-time,
 176 but it's convenient if your clients have the right default compiled in.
 177 (--with-pgport=PORTNUM)])
 178 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 179                    [Define to the default TCP port number as a string constant.])
 180 AC_SUBST(default_port)
 181
 182 #
 183 # Option to disable shared libraries
 184 #
 185 PGAC_ARG_BOOL(enable, shared, yes,
 186               [  --disable-shared        do not build shared libraries])
 187 AC_SUBST(enable_shared)
 188
 189 #
 190 # '-rpath'-like feature can be disabled
 191 #
 192 PGAC_ARG_BOOL(enable, rpath, yes,
 193               [  --disable-rpath         do not embed shared library search path in executables])
 194 AC_SUBST(enable_rpath)
 195
 196 #
 197 # Spinlocks
 198 #
 199 PGAC_ARG_BOOL(enable, spinlocks, yes,
 200               [  --disable-spinlocks     do not use spinlocks])
 201
 202 #
 203 # --enable-debug adds -g to compiler flags
 204 #
 205 PGAC_ARG_BOOL(enable, debug, no,
 206               [  --enable-debug          build with debugging symbols (-g)])
 207 AC_SUBST(enable_debug)
 208
 209 #
 210 # C compiler
 211 #
 212
 213 # For historical reasons you can also use --with-CC to specify the C compiler
 214 # to use, although the standard way to do this is to set the CC environment
 215 # variable.
 216 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 217
 218 case $template in
 219   aix) pgac_cc_list="gcc xlc";;
 220  irix) pgac_cc_list="cc";; # no gcc
 221     *) pgac_cc_list="gcc cc";;
 222 esac
 223
 224 AC_PROG_CC([$pgac_cc_list])
 225
 226 unset CFLAGS
 227
 228 #
 229 # Read the template
 230 #
 231 . "$srcdir/src/template/$template" || exit
 232
 233 # CFLAGS are selected so:
 234 # If the user specifies something in the environment, that is used.
 235 # else:  If the template file set something, that is used.
 236 # else:  If the compiler is GCC, then we use -O2.
 237 # else:  If the compiler is something else, then we use -0.
 238
 239 if test "$ac_env_CFLAGS_set" = set; then
 240   CFLAGS=$ac_env_CFLAGS_value
 241 elif test "${CFLAGS+set}" = set; then
 242   : # (keep what template set)
 243 elif test "$GCC" = yes; then
 244   CFLAGS="-O2"
 245 else
 246   # if the user selected debug mode, don't use -O
 247   if test "$enable_debug" != yes; then
 248     CFLAGS="-O"
 249   fi
 250 fi
 251
 252 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 253 PGAC_PROG_CC_NO_STRICT_ALIASING
 254
 255 # supply -g if --enable-debug
 256 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 257   CFLAGS="$CFLAGS -g"
 258 fi
 259
 260 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 261
 262 # We already have this in Makefile.win32, but configure needs it too
 263 if test "$PORTNAME" = "win32"; then
 264   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 265 fi
 266
 267 # Check if the compiler still works with the template settings
 268 AC_MSG_CHECKING([whether the C compiler still works])
 269 AC_TRY_LINK([], [return 0;],
 270   [AC_MSG_RESULT(yes)],
 271   [AC_MSG_RESULT(no)
 272    AC_MSG_ERROR([cannot proceed])])
 273
 274 # Defend against gcc -ffast-math
 275 if test "$GCC" = yes; then
 276 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 277 choke me
 278 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 279 fi
 280
 281 AC_PROG_CPP
 282 AC_SUBST(GCC)
 283
 284 # Create compiler version string
 285 if test x"$GCC" = x"yes" ; then
 286   cc_string="GCC `${CC} --version | sed q`"
 287 else
 288   cc_string=$CC
 289 fi
 290 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 291                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 292                    [A string containing the version number, platform, and C compiler])
 293
 294
 295 #
 296 # Set up TAS assembly code if needed; the template file has now had its
 297 # chance to request this.
 298 #
 299 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 300
 301 if test "$need_tas" = yes ; then
 302   TAS=tas.o
 303 else
 304   TAS=""
 305 fi
 306 AC_SUBST(TAS)
 307
 308
 309 #
 310 # Automatic dependency tracking
 311 #
 312 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 313               [autodepend=yes])
 314 AC_SUBST(autodepend)
 315
 316
 317 #
 318 # Enable assert checks
 319 #
 320 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 321               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 322                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 323
 324
 325 #
 326 # Include directories
 327 #
 328 ac_save_IFS=$IFS
 329 IFS="${IFS}:"
 330 # SRCH_INC comes from the template file
 331 for dir in $with_includes $SRCH_INC; do
 332   if test -d "$dir"; then
 333     INCLUDES="$INCLUDES -I$dir"
 334   else
 335     AC_MSG_WARN([*** Include directory $dir does not exist.])
 336   fi
 337 done
 338 IFS=$ac_save_IFS
 339 AC_SUBST(INCLUDES)
 340
 341
 342 #
 343 # Library directories
 344 #
 345 ac_save_IFS=$IFS
 346 IFS="${IFS}:"
 347 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 348 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 349   if test -d "$dir"; then
 350     LIBDIRS="$LIBDIRS -L$dir"
 351   else
 352     AC_MSG_WARN([*** Library directory $dir does not exist.])
 353   fi
 354 done
 355 IFS=$ac_save_IFS
 356
 357 #
 358 # Enable thread-safe client libraries
 359 #
 360 AC_MSG_CHECKING([allow thread-safe client libraries])
 361 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 362               [AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 363                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 364 AC_MSG_RESULT([$enable_thread_safety])
 365 AC_SUBST(enable_thread_safety)
 366
 367 #
 368 # Tcl/Tk
 369 #
 370 AC_MSG_CHECKING([whether to build with Tcl])
 371 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 372 AC_MSG_RESULT([$with_tcl])
 373 AC_SUBST([with_tcl])
 374
 375 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 376 AC_MSG_CHECKING([whether to build with Tk])
 377 if test "$with_tcl" = yes; then
 378   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 379 else
 380   with_tk=no
 381 fi
 382 AC_MSG_RESULT([$with_tk])
 383 AC_SUBST([with_tk])
 384
 385
 386 # We see if the path to the Tcl/Tk configuration scripts is specified.
 387 # This will override the use of tclsh to find the paths to search.
 388
 389 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 390
 391 # We see if the path to the Tk configuration scripts is specified.
 392 # This will override the use of tclsh to find the paths to search.
 393
 394 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 395
 396 #
 397 # Optionally build Perl modules (PL/Perl)
 398 #
 399 AC_MSG_CHECKING([whether to build Perl modules])
 400 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 401 AC_MSG_RESULT([$with_perl])
 402 AC_SUBST(with_perl)
 403
 404 #
 405 # Optionally build Python modules (PL/Python)
 406 #
 407 AC_MSG_CHECKING([whether to build Python modules])
 408 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 409 AC_MSG_RESULT([$with_python])
 410 AC_SUBST(with_python)
 411
 412 #
 413 # Kerberos 4
 414 #
 415 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 416 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 417 [
 418   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 419   krb_srvtab="/etc/srvtab"
 420 ])
 421 AC_MSG_RESULT([$with_krb4])
 422 AC_SUBST(with_krb4)
 423
 424
 425 #
 426 # Kerberos 5
 427 #
 428 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 429 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 430 [
 431   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 432   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 433 ])
 434 AC_MSG_RESULT([$with_krb5])
 435 AC_SUBST(with_krb5)
 436
 437
 438 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 439 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 440   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 441 fi
 442
 443 AC_SUBST(krb_srvtab)
 444
 445
 446 #
 447 # Kerberos configuration parameters
 448 #
 449 PGAC_ARG_REQ(with, krb-srvnam,
 450              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 451              [],
 452              [with_krb_srvnam="postgres"])
 453 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 454                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 455
 456
 457 #
 458 # PAM
 459 #
 460 AC_MSG_CHECKING([whether to build with PAM support])
 461 PGAC_ARG_BOOL(with, pam, no,
 462               [  --with-pam              build with PAM support],
 463               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 464 AC_MSG_RESULT([$with_pam])
 465 AC_SUBST(with_pam)
 466
 467
 468 #
 469 # Rendezvous
 470 #
 471 AC_MSG_CHECKING([whether to build with Rendezvous support])
 472 PGAC_ARG_BOOL(with, rendezvous, no,
 473               [  --with-rendezvous       build with Rendezvous support],
 474               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 475 AC_MSG_RESULT([$with_rendezvous])
 476 AC_SUBST(with_rendezvous)
 477
 478
 479 #
 480 # OpenSSL
 481 #
 482 AC_MSG_CHECKING([whether to build with OpenSSL support])
 483 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 484               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 485 AC_MSG_RESULT([$with_openssl])
 486 AC_SUBST(with_openssl)
 487
 488
 489 #
 490 # Readline
 491 #
 492 PGAC_ARG_BOOL(with, readline, yes,
 493               [  --without-readline      do not use Readline])
 494
 495 #
 496 # Zlib
 497 #
 498 PGAC_ARG_BOOL(with, zlib, yes,
 499               [  --without-zlib          do not use Zlib])
 500
 501 #
 502 # Elf
 503 #
 504
 505 # Assume system is ELF if it predefines __ELF__ as 1,
 506 # otherwise believe host_os based default.
 507 case $host_os in
 508     freebsd1*|freebsd2*) elf=no;;
 509     freebsd3*|freebsd4*) elf=yes;;
 510 esac
 511
 512 AC_EGREP_CPP(yes,
 513 [#if __ELF__
 514   yes
 515 #endif
 516 ],
 517 [ELF_SYS=true],
 518 [if test "X$elf" = "Xyes" ; then
 519   ELF_SYS=true
 520 else
 521   ELF_SYS=
 522 fi])
 523 AC_SUBST(ELF_SYS)
 524
 525 #
 526 # Assignments
 527 #
 528
 529 CPPFLAGS="$CPPFLAGS $INCLUDES"
 530 LDFLAGS="$LDFLAGS $LIBDIRS"
 531
 532 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 533 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 534
 535
 536 AC_PROG_AWK
 537 PGAC_PATH_FLEX
 538 AC_PROG_LN_S
 539 AC_PROG_LD
 540 AC_SUBST(LD)
 541 AC_SUBST(with_gnu_ld)
 542 case $host_os in sysv5*)
 543   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 544   [
 545     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 546     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 547     LDFLAGS=$pgac_save_LDFLAGS
 548   ])
 549   ld_R_works=$pgac_cv_prog_ld_R
 550   AC_SUBST(ld_R_works)
 551 esac
 552 AC_PROG_RANLIB
 553 AC_CHECK_PROGS(LORDER, lorder)
 554 AC_PATH_PROG(TAR, tar)
 555 PGAC_CHECK_STRIP
 556
 557 AC_CHECK_PROGS(YACC, ['bison -y'])
 558
 559 if test "$YACC"; then
 560   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 561     AC_MSG_WARN([
 562 *** If you are going to modify the grammar files or build from CVS, the installed
 563 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 564   fi
 565 fi
 566
 567 if test -z "$YACC"; then
 568   AC_MSG_WARN([
 569 *** Without Bison you will not be able to build PostgreSQL from CVS or
 570 *** change any of the parser definition files.  You can obtain Bison from
 571 *** a GNU mirror site.  (If you are using the official distribution of
 572 *** PostgreSQL then you do not need to worry about this because the Bison
 573 *** output is pre-generated.)  To use a different yacc program (possible,
 574 *** but not recommended), set the environment variable YACC before running
 575 *** 'configure'.])
 576 fi
 577 AC_SUBST(YFLAGS)
 578
 579 PGAC_PATH_PERL
 580 if test "$with_perl" = yes; then
 581   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 582   PGAC_CHECK_PERL_EMBED_LDFLAGS
 583 fi
 584
 585 if test "$with_python" = yes; then
 586   PGAC_PATH_PYTHON
 587   PGAC_CHECK_PYTHON_EMBED_SETUP
 588 fi
 589
 590
 591 ##
 592 ## Libraries
 593 ##
 594
 595 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 596 then
 597         AC_CHECK_LIB(bsd,      main)
 598 fi
 599 AC_CHECK_LIB(util,     setproctitle)
 600 AC_CHECK_LIB(m,        main)
 601 AC_CHECK_LIB(dl,       main)
 602 AC_CHECK_LIB(nsl,      main)
 603 AC_CHECK_LIB(socket,   main)
 604 AC_CHECK_LIB(ipc,      main)
 605 AC_CHECK_LIB(IPC,      main)
 606 AC_CHECK_LIB(lc,       main)
 607 AC_CHECK_LIB(dld,      main)
 608 AC_CHECK_LIB(ld,       main)
 609 AC_CHECK_LIB(compat,   main)
 610 AC_CHECK_LIB(BSD,      main)
 611 AC_CHECK_LIB(gen,      main)
 612 AC_CHECK_LIB(PW,       main)
 613 AC_CHECK_LIB(resolv,   main)
 614 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 615 # QNX:
 616 AC_CHECK_LIB(unix, main)
 617 AC_SEARCH_LIBS(crypt,  crypt)
 618 # BeOS:
 619 if test "$PORTNAME" = "beos"
 620 then
 621         AC_CHECK_LIB(bind, __inet_ntoa)
 622 fi
 623 # Solaris:
 624 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 625 # Cygwin:
 626 AC_CHECK_LIB(cygipc, shmget)
 627 # WIN32:
 628 if test "$PORTNAME" = "win32"
 629 then
 630         AC_CHECK_LIB(wsock32, main)
 631 fi
 632
 633 if test "$with_readline" = yes; then
 634   PGAC_CHECK_READLINE
 635   if test x"$pgac_cv_check_readline" = x"no"; then
 636     AC_MSG_ERROR([readline library not found
 637 If you have readline already installed, see config.log for details on the
 638 failure.  It is possible the compiler isn't looking in the proper directory.
 639 Use --without-readline to disable readline support.])
 640   fi
 641 fi
 642
 643 if test "$with_zlib" = yes; then
 644   AC_CHECK_LIB(z, inflate, [],
 645                [AC_MSG_ERROR([zlib library not found
 646 If you have zlib already installed, see config.log for details on the
 647 failure.  It is possible the compiler isn't looking in the proper directory.
 648 Use --without-zlib to disable zlib support.])])
 649 fi
 650
 651 if test "$enable_spinlocks" = yes; then
 652   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 653 else
 654   AC_MSG_WARN([
 655 *** Not using spinlocks will cause poor performance.])
 656 fi
 657
 658 if test "$with_krb4" = yes ; then
 659   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 660   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 661   AC_REPLACE_FUNCS([gethostname])
 662 fi
 663
 664 if test "$with_krb5" = yes ; then
 665   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 666                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 667   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 668                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 669   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 670                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 671 fi
 672
 673 if test "$with_openssl" = yes ; then
 674   dnl Order matters!
 675   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 676   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 677 fi
 678
 679 if test "$with_pam" = yes ; then
 680   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 681 fi
 682
 683
 684 ##
 685 ## Header files
 686 ##
 687
 688 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 689 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 690
 691 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 692 # netinet/in.h is included first.
 693 AC_CHECK_HEADERS(netinet/in.h)
 694 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 695 [AC_INCLUDES_DEFAULT
 696 #ifdef HAVE_NETINET_IN_H
 697 #include <netinet/in.h>
 698 #endif
 699 ])
 700
 701 if test "$with_readline" = yes; then
 702   AC_CHECK_HEADERS(readline/readline.h, [],
 703                    [AC_CHECK_HEADERS(editline/readline.h, [],
 704                          [AC_CHECK_HEADERS(readline.h, [],
 705                                      [AC_MSG_ERROR([readline header not found
 706 If you have readline already installed, see config.log for details on the
 707 failure.  It is possible the compiler isn't looking in the proper directory.
 708 Use --without-readline to disable readline support.])])])])
 709   AC_CHECK_HEADERS(readline/history.h, [],
 710                    [AC_CHECK_HEADERS(editline/history.h, [],
 711                          [AC_CHECK_HEADERS(history.h, [],
 712                                      [AC_MSG_ERROR([history header not found
 713 If you have readline already installed, see config.log for details on the
 714 failure.  It is possible the compiler isn't looking in the proper directory.
 715 Use --without-readline to disable readline support.])])])])
 716 fi
 717
 718 if test "$with_zlib" = yes; then
 719   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 720 If you have zlib already installed, see config.log for details on the
 721 failure.  It is possible the compiler isn't looking in the proper directory.
 722 Use --without-zlib to disable zlib support.])])
 723 fi
 724
 725 if test "$with_krb4" = yes ; then
 726   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 727 fi
 728
 729 if test "$with_krb5" = yes ; then
 730   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 731   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 732 fi
 733
 734 if test "$with_openssl" = yes ; then
 735   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 736   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 737 fi
 738
 739 if test "$with_pam" = yes ; then
 740   AC_CHECK_HEADERS(security/pam_appl.h, [],
 741                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 742                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 743 fi
 744
 745 if test "$with_rendezvous" = yes ; then
 746   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 747 fi
 748
 749
 750 ##
 751 ## Types, structures, compiler characteristics
 752 ##
 753
 754 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 755 AC_C_CONST
 756 AC_C_INLINE
 757 AC_C_STRINGIZE
 758 PGAC_C_SIGNED
 759 AC_C_VOLATILE
 760 PGAC_C_FUNCNAME_SUPPORT
 761 PGAC_STRUCT_TIMEZONE
 762 PGAC_UNION_SEMUN
 763 PGAC_STRUCT_SOCKADDR_UN
 764 PGAC_STRUCT_SOCKADDR_STORAGE
 765 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 766 PGAC_STRUCT_ADDRINFO
 767
 768 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 769 [#include <sys/param.h>
 770 #include <sys/types.h>
 771 #include <sys/socket.h>
 772 #include <sys/ucred.h>])
 773
 774 AC_CHECK_TYPES([struct option], [], [],
 775 [#ifdef HAVE_GETOPT_H
 776 #include <getopt.h>
 777 #endif])
 778
 779 if test "$with_zlib" = yes; then
 780   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 781   # did not).  While we could work around the lack of z_streamp, it
 782   # seems unwise to encourage people to use such old zlib versions...
 783   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 784 Use --without-zlib to disable zlib support.])],
 785                 [#include <zlib.h>])
 786 fi
 787
 788 if test "$with_krb5" = yes; then
 789 # Check for differences between MIT and Heimdal (KTH) releases
 790   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 791                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 792                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 793                                      [#include <krb5.h>])],
 794                    [#include <krb5.h>])
 795   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 796                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 797                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 798                                      [#include <krb5.h>])],
 799                    [#include <krb5.h>])
 800 fi
 801
 802
 803 ##
 804 ## Functions, global variables
 805 ##
 806
 807 PGAC_VAR_INT_TIMEZONE
 808 AC_FUNC_ACCEPT_ARGTYPES
 809 PGAC_FUNC_GETTIMEOFDAY_1ARG
 810
 811 # SunOS doesn't handle negative byte comparisons properly with +/- return
 812 AC_FUNC_MEMCMP
 813
 814 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 815
 816 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 817
 818 HAVE_IPV6=no
 819 AC_CHECK_TYPE([struct sockaddr_in6],
 820               [AC_CHECK_FUNC(inet_ntop,
 821                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 822                                                           HAVE_IPV6=yes])],
 823               [],
 824 [$ac_includes_default
 825 #include <netinet/in.h>])
 826 AC_SUBST(HAVE_IPV6)
 827
 828 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 829 [AC_TRY_LINK(
 830 [#include <machine/vmparam.h>
 831 #include <sys/exec.h>
 832 ],
 833 [PS_STRINGS->ps_nargvstr = 1;
 834 PS_STRINGS->ps_argvstr = "foo";],
 835 [pgac_cv_var_PS_STRINGS=yes],
 836 [pgac_cv_var_PS_STRINGS=no])])
 837 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 838   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 839 fi
 840
 841
 842 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 843 # is missing.  Yes, there are machines that have only one.  We may
 844 # also decide to use snprintf.c if snprintf() is present but does not
 845 # have working "long long int" support -- see below.
 846
 847 pgac_need_repl_snprintf=no
 848 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 849 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 850
 851
 852 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 853 # include/c.h will provide declarations.  Note this is a separate test
 854 # from whether the functions exist in the C library --- there are
 855 # systems that have the functions but don't bother to declare them :-(
 856
 857 AC_CHECK_DECLS([snprintf, vsnprintf])
 858
 859
 860 # do this one the hard way in case isinf() is a macro
 861 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 862 [AC_TRY_LINK(
 863 [#include <math.h>
 864 ],
 865 [double x = 0.0; int res = isinf(x);],
 866 [ac_cv_func_isinf=yes],
 867 [ac_cv_func_isinf=no])])
 868
 869 if test $ac_cv_func_isinf = yes ; then
 870   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 871 else
 872   AC_LIBOBJ(isinf)
 873   # Look for a way to implement a substitute for isinf()
 874   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 875 fi
 876
 877 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 878
 879 # system's version of getaddrinfo(), if any, may be used only if we found
 880 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 881 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 882   AC_REPLACE_FUNCS([getaddrinfo])
 883 else
 884   AC_LIBOBJ(getaddrinfo)
 885 fi
 886
 887 # similarly, use system's getopt_long() only if system provides struct option.
 888 if test x"$ac_cv_type_struct_option" = xyes ; then
 889   AC_REPLACE_FUNCS([getopt_long])
 890 else
 891   AC_LIBOBJ(getopt_long)
 892 fi
 893
 894 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 895 # We override the previous test that said fseeko/ftello didn't exist
 896 # OS tests are also done in include/c.h and port/fseeko.c
 897 case $host_os in bsdi*|netbsd*)
 898 ac_cv_func_fseeko=yes
 899 esac
 900
 901 # Solaris has a very slow qsort in certain cases, so we replace it.
 902 case $host_os in solaris*)
 903 AC_LIBOBJ(qsort) ;;
 904 esac
 905
 906 # Win32 support
 907 case $host_os in mingw*)
 908 AC_LIBOBJ(copydir)
 909 AC_LIBOBJ(gettimeofday)
 910 AC_LIBOBJ(open)
 911 AC_LIBOBJ(pipe)
 912 AC_LIBOBJ(rand) ;;
 913 esac
 914
 915 # Win32 can't to rename or unlink on an open file
 916 case $host_os in mingw*|cygwin*)
 917 AC_LIBOBJ(dirmod) ;;
 918 esac
 919
 920 if test "$with_readline" = yes; then
 921   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 922   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 923   AC_CHECK_FUNCS([replace_history_entry])
 924 fi
 925
 926
 927 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 928 AC_MSG_CHECKING(for finite)
 929 AC_TRY_LINK([#include <math.h>],
 930             [int dummy=finite(1.0);],
 931             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 932 AC_MSG_RESULT(yes)],
 933             [AC_MSG_RESULT(no)])
 934
 935 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 936 dnl (especially on GNU libc)
 937 dnl See also comments in c.h.
 938 AC_MSG_CHECKING(for sigsetjmp)
 939 AC_TRY_LINK([#include <setjmp.h>],
 940             [sigjmp_buf x; sigsetjmp(x, 1);],
 941             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 942 AC_MSG_RESULT(yes)],
 943             [AC_MSG_RESULT(no)])
 944
 945 AC_CHECK_FUNC(syslog,
 946               [AC_CHECK_HEADER(syslog.h,
 947                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 948
 949 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 950 [AC_TRY_LINK([#include <unistd.h>],
 951   [extern int optreset; optreset = 1;],
 952   [pgac_cv_var_int_optreset=yes],
 953   [pgac_cv_var_int_optreset=no])])
 954 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 955   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 956 fi
 957
 958 AC_CHECK_FUNCS([strtoll strtoq], [break])
 959 AC_CHECK_FUNCS([strtoull strtouq], [break])
 960
 961 # Check for one of atexit() or on_exit()
 962 AC_CHECK_FUNCS(atexit, [],
 963                [AC_CHECK_FUNCS(on_exit, [],
 964                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 965
 966 AC_FUNC_FSEEKO
 967
 968 #
 969 # Pthreads
 970 #
 971 # For each platform, we need to know about any special compile and link
 972 # libraries, and whether the normal C function names are thread-safe.
 973 # See the comment at the top of src/port/thread.c for more information.
 974 #
 975 if test "$enable_thread_safety" = yes; then
 976 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
 977
 978 if test "$THREAD_SUPPORT" != yes; then
 979 AC_MSG_ERROR([
 980 Cannot enable threads on your platform.
 981 Please report your platform threading info to the PostgreSQL mailing lists
 982 so it can be added to the next release.  Report all compile flags, link flags,
 983 functions, or libraries required for threading support.
 984 See the comment at the top of src/port/thread.c for more information.
 985 ])
 986 fi
 987
 988 #
 989 # Check for re-entrant versions of certain functions
 990 #
 991 # Include special flags if threads are enabled _and_ if required for
 992 # threading on this platform.  Some platforms have *_r functions but
 993 # their natively named funcs are thread-safe too.
 994 #
 995 # One trick here is that if we don't call AC_CHECK_FUNCS; the
 996 # functions are marked "not found", which is perfect.
 997 #
 998 if test "$enable_thread_safety" = yes -a "$STRERROR_THREADSAFE" = yes ; then
 999 AC_DEFINE(STRERROR_THREADSAFE, 1, [Define if strerror is not thread safe])
1000 fi
1001 if test "$enable_thread_safety" = yes -a "$GETPWUID_THREADSAFE" = yes ; then
1002 AC_DEFINE(GETPWUID_THREADSAFE, 1, [Define if getpwuid is not thread safe])
1003 fi
1004 if test "$enable_thread_safety" = yes -a "$GETHOSTBYNAME_THREADSAFE" = yes ; then
1005 AC_DEFINE(GETHOSTBYNAME_THREADSAFE, 1, [Define if gethostbyname is not thread safe])
1006 fi
1007
1008 # Check for *_r functions
1009 _CFLAGS="$CFLAGS"
1010 _LIBS="$LIBS"
1011 CFLAGS="$CFLAGS $THREAD_CPPFLAGS"
1012 LIBS="$LIBS $THREAD_LIBS"
1013 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1014 CFLAGS="$_CFLAGS"
1015 LIBS="$_LIBS"
1016
1017 PGAC_FUNC_GETPWUID_R_5ARG
1018
1019 else
1020 # do not use values from template file
1021 THREAD_CPPFLAGS=
1022 THREAD_LIBS=
1023 fi
1024
1025 AC_SUBST(THREAD_SUPPORT)
1026 AC_SUBST(THREAD_CPPFLAGS)
1027 AC_SUBST(THREAD_LIBS)
1028
1029
1030 # This test makes sure that run tests work at all.  Sometimes a shared
1031 # library is found by the linker, but the runtime linker can't find it.
1032 # This check should come after all modifications of compiler or linker
1033 # variables, and before any other run tests.
1034 AC_MSG_CHECKING([test program])
1035 AC_TRY_RUN([int main() { return 0; }],
1036 [AC_MSG_RESULT(ok)],
1037 [AC_MSG_RESULT(failed)
1038 AC_MSG_ERROR([[
1039 *** Could not execute a simple test program.  This may be a problem
1040 *** related to locating shared libraries.  Check the file 'config.log'
1041 *** for the exact reason.]])],
1042 [AC_MSG_RESULT([cross-compiling])])
1043
1044
1045 dnl Check to see if we have a working 64-bit integer type.
1046 dnl This breaks down into two steps:
1047 dnl (1) figure out if the compiler has a 64-bit int type with working
1048 dnl arithmetic, and if so
1049 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1050 dnl snprintf is the only library routine we really need for int8 support.)
1051 dnl It's entirely possible to have a compiler that handles a 64-bit type
1052 dnl when the C library doesn't; this is fairly likely when using gcc on
1053 dnl an older platform, for example.
1054 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1055 dnl we force our own version of snprintf() to be used instead.
1056 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1057
1058 PGAC_TYPE_64BIT_INT([long int])
1059
1060 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1061   PGAC_TYPE_64BIT_INT([long long int])
1062 fi
1063
1064
1065 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1066
1067 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1068   AC_TRY_COMPILE([
1069 #define INT64CONST(x)  x##LL
1070 long long int foo = INT64CONST(0x1234567890123456);
1071 ],
1072         [],
1073         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1074         [])
1075 fi
1076
1077
1078 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1079 # we found we need to use "long long int", better check.  We cope with
1080 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1081 # work, fall back to our own snprintf emulation (which we know uses %lld).
1082
1083 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1084   if test $pgac_need_repl_snprintf = no; then
1085     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1086     if test "$LONG_LONG_INT_FORMAT" = ""; then
1087       # Force usage of our own snprintf, since system snprintf is broken
1088       pgac_need_repl_snprintf=yes
1089       LONG_LONG_INT_FORMAT='%lld'
1090     fi
1091   else
1092     # Here if we previously decided we needed to use our own snprintf
1093     LONG_LONG_INT_FORMAT='%lld'
1094   fi
1095   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1096   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1097   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1098 else
1099   # Here if we are not using 'long long int' at all
1100   INT64_FORMAT='"%ld"'
1101   UINT64_FORMAT='"%lu"'
1102 fi
1103
1104 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1105                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1106
1107 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1108                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1109
1110 if test $pgac_need_repl_snprintf = yes; then
1111   AC_LIBOBJ(snprintf)
1112 fi
1113
1114 # Need a #define for the size of Datum (unsigned long)
1115 AC_CHECK_SIZEOF([unsigned long])
1116
1117 # Determine memory alignment requirements for the basic C data types.
1118
1119 PGAC_CHECK_ALIGNOF(short)
1120 PGAC_CHECK_ALIGNOF(int)
1121 PGAC_CHECK_ALIGNOF(long)
1122 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1123   PGAC_CHECK_ALIGNOF(long long int)
1124 fi
1125 PGAC_CHECK_ALIGNOF(double)
1126
1127 # Compute maximum alignment of any basic type.
1128 # We assume long's alignment is at least as strong as char, short, or int;
1129 # but we must check long long (if it exists) and double.
1130
1131 MAX_ALIGNOF=$pgac_cv_alignof_long
1132 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1133   MAX_ALIGNOF=$pgac_cv_alignof_double
1134 fi
1135 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1136   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1137 fi
1138 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1139
1140
1141 # Some platforms predefine the types int8, int16, etc.  Only check
1142 # a (hopefully) representative subset.
1143 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1144 [#include <stdio.h>
1145 #ifdef HAVE_SUPPORTDEFS_H
1146 #include <SupportDefs.h>
1147 #endif])
1148
1149 # We also check for sig_atomic_t, which *should* be defined per ANSI
1150 # C, but is missing on some old platforms.
1151 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1152
1153
1154 PGAC_FUNC_POSIX_SIGNALS
1155 if test $ac_cv_func_fseeko = yes; then
1156 AC_SYS_LARGEFILE
1157 fi
1158
1159
1160 # Select semaphore implementation type.
1161 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1162   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1163   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1164 else
1165   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1166     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1167     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1168   else
1169     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1170     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1171   fi
1172 fi
1173
1174
1175 # Select shared-memory implementation type.
1176 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1177 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1178
1179
1180 if test "$enable_nls" = yes ; then
1181   PGAC_CHECK_GETTEXT
1182 fi
1183
1184 # Check for Tcl configuration script tclConfig.sh
1185 if test "$with_tcl" = yes; then
1186     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1187     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1188                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1189     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1190 fi
1191
1192 # Check for Tk configuration script tkConfig.sh
1193 if test "$with_tk" = yes; then
1194     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1195     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1196 fi
1197
1198
1199 #
1200 # Check for DocBook and tools
1201 #
1202 PGAC_PROG_NSGMLS
1203 PGAC_PROG_JADE
1204 PGAC_CHECK_DOCBOOK(4.2)
1205 PGAC_PATH_DOCBOOK_STYLESHEETS
1206 PGAC_PATH_COLLATEINDEX
1207 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1208
1209
1210 # prepare build tree if outside source tree
1211 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1212 # Note 2: /bin/pwd might be better than shell's built-in at getting
1213 #         a symlink-free name.
1214 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1215   vpath_build=no
1216 else
1217   vpath_build=yes
1218   if test "$no_create" != yes; then
1219     _AS_ECHO_N([preparing build tree... ])
1220     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1221     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1222       || AC_MSG_ERROR(failed)
1223     AC_MSG_RESULT(done)
1224   fi
1225 fi
1226 AC_SUBST(vpath_build)
1227
1228
1229 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1230
1231 AC_CONFIG_LINKS([
1232   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1233   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1234   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1235   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1236   src/include/pg_config_os.h:src/include/port/${template}.h
1237   src/Makefile.port:src/makefiles/Makefile.${template}
1238 ])
1239
1240 AC_CONFIG_HEADERS([src/include/pg_config.h],
1241 [
1242 # Update timestamp for pg_config.h (see Makefile.global)
1243 echo >src/include/stamp-h
1244 ])
1245
1246 AC_OUTPUT