granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.418 2005/08/02 19:02:30 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.1devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2005, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60  linux*|gnu*|k*bsd*-gnu)
  61            template=linux ;;
  62    mingw*) template=win32 ;;
  63   netbsd*) template=netbsd ;;
  64 nextstep*) template=nextstep ;;
  65  openbsd*) template=openbsd ;;
  66      osf*) template=osf ;;
  67      qnx*) template=qnx4 ;;
  68      sco*) template=sco ;;
  69  solaris*) template=solaris ;;
  70    sunos*) template=sunos4 ;;
  71  sysv4.2*)
  72         case $host_vendor in
  73           univel) template=univel ;;
  74         esac ;;
  75    sysv4*) template=svr4 ;;
  76    sysv5*) template=unixware ;;
  77   ultrix*) template=ultrix4 ;;
  78 esac
  79
  80   if test x"$template" = x"" ; then
  81     AC_MSG_ERROR([[
  82 *******************************************************************
  83 PostgreSQL has apparently not been ported to your platform yet.
  84 To try a manual configuration, look into the src/template directory
  85 for a similar platform and use the '--with-template=' option.
  86
  87 Please also contact <pgsql-ports@postgresql.org> to see about
  88 rectifying this.  Include the above 'checking host system type...'
  89 line.
  90 *******************************************************************
  91 ]])
  92   fi
  93
  94 ])
  95
  96 AC_MSG_RESULT([$template])
  97
  98 PORTNAME=$template
  99 AC_SUBST(PORTNAME)
 100
 101 # Initialize default assumption that we do not need separate assembly code
 102 # for TAS (test-and-set).  This can be overridden by the template file
 103 # when it's executed.
 104 need_tas=no
 105 tas_file=dummy.s
 106
 107
 108
 109 ##
 110 ## Command line options
 111 ##
 112
 113 #
 114 # Installation directory for documentation
 115 #
 116 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 117   --without-docdir        do not install the documentation],
 118          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 119          [docdir=],
 120          [docdir=$withval],
 121          [docdir='${prefix}/doc'])
 122 AC_SUBST(docdir)
 123
 124
 125 #
 126 # Add non-standard directories to the include path
 127 #
 128 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 129
 130
 131 #
 132 # Add non-standard directories to the library search path
 133 #
 134 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 135              [LIBRARY_DIRS=$withval])
 136
 137 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 138              [LIBRARY_DIRS=$withval])
 139
 140
 141 #
 142 # 64-bit integer date/time storage (--enable-integer-datetimes)
 143 #
 144 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 145 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 146               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 147                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 148 AC_MSG_RESULT([$enable_integer_datetimes])
 149
 150
 151 #
 152 # NLS
 153 #
 154 AC_MSG_CHECKING([whether NLS is wanted])
 155 PGAC_ARG_OPTARG(enable, nls,
 156                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 157                 [],
 158                 [WANTED_LANGUAGES=$enableval],
 159                 [AC_DEFINE(ENABLE_NLS, 1,
 160                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 161 AC_MSG_RESULT([$enable_nls])
 162 AC_SUBST(enable_nls)
 163 AC_SUBST(WANTED_LANGUAGES)
 164
 165 #
 166 # Default port number (--with-pgport), default 5432
 167 #
 168 AC_MSG_CHECKING([for default port number])
 169 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 170              [default_port=$withval],
 171              [default_port=5432])
 172 AC_MSG_RESULT([$default_port])
 173 # Need both of these because some places want an integer and some a string
 174 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 175 [Define to the default TCP port number on which the server listens and
 176 to which clients will try to connect.  This can be overridden at run-time,
 177 but it's convenient if your clients have the right default compiled in.
 178 (--with-pgport=PORTNUM)])
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 180                    [Define to the default TCP port number as a string constant.])
 181 AC_SUBST(default_port)
 182
 183 #
 184 # Option to disable shared libraries
 185 #
 186 PGAC_ARG_BOOL(enable, shared, yes,
 187               [  --disable-shared        do not build shared libraries])
 188 AC_SUBST(enable_shared)
 189
 190 #
 191 # '-rpath'-like feature can be disabled
 192 #
 193 PGAC_ARG_BOOL(enable, rpath, yes,
 194               [  --disable-rpath         do not embed shared library search path in executables])
 195 AC_SUBST(enable_rpath)
 196
 197 #
 198 # Spinlocks
 199 #
 200 PGAC_ARG_BOOL(enable, spinlocks, yes,
 201               [  --disable-spinlocks     do not use spinlocks])
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 unset CFLAGS
 228
 229 #
 230 # Read the template
 231 #
 232 . "$srcdir/src/template/$template" || exit
 233
 234 # CFLAGS are selected so:
 235 # If the user specifies something in the environment, that is used.
 236 # else:  If the template file set something, that is used.
 237 # else:  If the compiler is GCC, then we use -O2.
 238 # else:  If the compiler is something else, then we use -0.
 239
 240 if test "$ac_env_CFLAGS_set" = set; then
 241   CFLAGS=$ac_env_CFLAGS_value
 242 elif test "${CFLAGS+set}" = set; then
 243   : # (keep what template set)
 244 elif test "$GCC" = yes; then
 245   CFLAGS="-O2"
 246 else
 247   # if the user selected debug mode, don't use -O
 248   if test "$enable_debug" != yes; then
 249     CFLAGS="-O"
 250   fi
 251 fi
 252
 253 if test "$GCC" = yes; then
 254   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 255
 256   # Some versions of GCC support some additional useful warning flags.
 257   # Check whether they are supported, and add them to CFLAGS if so.
 258   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 259   PGAC_PROG_CC_CFLAGS_OPT([-Wold-style-definition])
 260   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 261
 262   # Disable strict-aliasing rules; needed for gcc 3.3+
 263   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 264 fi
 265
 266 # supply -g if --enable-debug
 267 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 268   CFLAGS="$CFLAGS -g"
 269 fi
 270
 271 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 272
 273 # We already have this in Makefile.win32, but configure needs it too
 274 if test "$PORTNAME" = "win32"; then
 275   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 276 fi
 277
 278 # Check if the compiler still works with the template settings
 279 AC_MSG_CHECKING([whether the C compiler still works])
 280 AC_TRY_LINK([], [return 0;],
 281   [AC_MSG_RESULT(yes)],
 282   [AC_MSG_RESULT(no)
 283    AC_MSG_ERROR([cannot proceed])])
 284
 285 # Defend against gcc -ffast-math
 286 if test "$GCC" = yes; then
 287 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 288 choke me
 289 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 290 fi
 291
 292 AC_PROG_CPP
 293 AC_SUBST(GCC)
 294
 295 # Create compiler version string
 296 if test x"$GCC" = x"yes" ; then
 297   cc_string="GCC `${CC} --version | sed q`"
 298 else
 299   cc_string=$CC
 300 fi
 301 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 302                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 303                    [A string containing the version number, platform, and C compiler])
 304
 305
 306 #
 307 # Set up TAS assembly code if needed; the template file has now had its
 308 # chance to request this.
 309 #
 310 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 311
 312 if test "$need_tas" = yes ; then
 313   TAS=tas.o
 314 else
 315   TAS=""
 316 fi
 317 AC_SUBST(TAS)
 318
 319
 320 #
 321 # Automatic dependency tracking
 322 #
 323 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 324               [autodepend=yes])
 325 AC_SUBST(autodepend)
 326
 327
 328 #
 329 # Enable assert checks
 330 #
 331 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 332               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 333                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 334
 335
 336 #
 337 # Include directories
 338 #
 339 ac_save_IFS=$IFS
 340 IFS="${IFS}${PATH_SEPARATOR}"
 341 # SRCH_INC comes from the template file
 342 for dir in $with_includes $SRCH_INC; do
 343   if test -d "$dir"; then
 344     INCLUDES="$INCLUDES -I$dir"
 345   else
 346     AC_MSG_WARN([*** Include directory $dir does not exist.])
 347   fi
 348 done
 349 IFS=$ac_save_IFS
 350 AC_SUBST(INCLUDES)
 351
 352
 353 #
 354 # Library directories
 355 #
 356 ac_save_IFS=$IFS
 357 IFS="${IFS}${PATH_SEPARATOR}"
 358 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 359 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 360   if test -d "$dir"; then
 361     LIBDIRS="$LIBDIRS -L$dir"
 362   else
 363     AC_MSG_WARN([*** Library directory $dir does not exist.])
 364   fi
 365 done
 366 IFS=$ac_save_IFS
 367
 368 #
 369 # Enable thread-safe client libraries
 370 #
 371 AC_MSG_CHECKING([allow thread-safe client libraries])
 372 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 373 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 374 if test "$enable_thread_safety" = yes -o \
 375         "$enable_thread_safety_force" = yes; then
 376   enable_thread_safety="yes"    # for 'force'
 377   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 378           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 379 fi
 380 AC_MSG_RESULT([$enable_thread_safety])
 381 AC_SUBST(enable_thread_safety)
 382
 383 #
 384 # Optionally build Tcl modules (PL/Tcl)
 385 #
 386 AC_MSG_CHECKING([whether to build with Tcl])
 387 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 388 AC_MSG_RESULT([$with_tcl])
 389 AC_SUBST([with_tcl])
 390
 391 # We see if the path to the Tcl/Tk configuration scripts is specified.
 392 # This will override the use of tclsh to find the paths to search.
 393
 394 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 395
 396 #
 397 # Optionally build Perl modules (PL/Perl)
 398 #
 399 AC_MSG_CHECKING([whether to build Perl modules])
 400 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 401 AC_MSG_RESULT([$with_perl])
 402 AC_SUBST(with_perl)
 403
 404 #
 405 # Optionally build Python modules (PL/Python)
 406 #
 407 AC_MSG_CHECKING([whether to build Python modules])
 408 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 409 AC_MSG_RESULT([$with_python])
 410 AC_SUBST(with_python)
 411
 412 #
 413 # Kerberos 5
 414 #
 415 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 416 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 417 [
 418   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 419   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 420 ])
 421 AC_MSG_RESULT([$with_krb5])
 422 AC_SUBST(with_krb5)
 423
 424
 425 AC_SUBST(krb_srvtab)
 426
 427
 428 #
 429 # Kerberos configuration parameters
 430 #
 431 PGAC_ARG_REQ(with, krb-srvnam,
 432              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 433              [],
 434              [with_krb_srvnam="postgres"])
 435 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 436                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 437
 438
 439 #
 440 # PAM
 441 #
 442 AC_MSG_CHECKING([whether to build with PAM support])
 443 PGAC_ARG_BOOL(with, pam, no,
 444               [  --with-pam              build with PAM support],
 445               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 446 AC_MSG_RESULT([$with_pam])
 447 AC_SUBST(with_pam)
 448
 449
 450 #
 451 # Bonjour
 452 #
 453 AC_MSG_CHECKING([whether to build with Bonjour support])
 454 PGAC_ARG_BOOL(with, bonjour, no,
 455               [  --with-bonjour          build with Bonjour support],
 456               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 457 AC_MSG_RESULT([$with_bonjour])
 458 AC_SUBST(with_bonjour)
 459
 460
 461 #
 462 # OpenSSL
 463 #
 464 AC_MSG_CHECKING([whether to build with OpenSSL support])
 465 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 466               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 467 AC_MSG_RESULT([$with_openssl])
 468 AC_SUBST(with_openssl)
 469
 470
 471 #
 472 # Readline
 473 #
 474 PGAC_ARG_BOOL(with, readline, yes,
 475               [  --without-readline      do not use Readline])
 476 # readline on MinGW has problems with backslashes in psql and other bugs.
 477 # This is particularly a problem with non-US code pages.
 478 # Therefore disable its use until we understand the cause. 2004-07-20
 479 if test "$PORTNAME" = "win32"; then
 480   if test "$with_readline" = yes; then
 481     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 482     with_readline=no
 483   fi
 484 fi
 485
 486
 487 #
 488 # Zlib
 489 #
 490 PGAC_ARG_BOOL(with, zlib, yes,
 491               [  --without-zlib          do not use Zlib])
 492 AC_SUBST(with_zlib)
 493
 494 #
 495 # Elf
 496 #
 497
 498 # Assume system is ELF if it predefines __ELF__ as 1,
 499 # otherwise believe host_os based default.
 500 case $host_os in
 501     freebsd1*|freebsd2*) elf=no;;
 502     freebsd3*|freebsd4*) elf=yes;;
 503 esac
 504
 505 AC_EGREP_CPP(yes,
 506 [#if __ELF__
 507   yes
 508 #endif
 509 ],
 510 [ELF_SYS=true],
 511 [if test "X$elf" = "Xyes" ; then
 512   ELF_SYS=true
 513 else
 514   ELF_SYS=
 515 fi])
 516 AC_SUBST(ELF_SYS)
 517
 518 #
 519 # Assignments
 520 #
 521
 522 CPPFLAGS="$CPPFLAGS $INCLUDES"
 523 LDFLAGS="$LDFLAGS $LIBDIRS"
 524
 525 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 526 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 527
 528 AC_ARG_VAR(LDFLAGS_SL)
 529
 530 AC_PROG_AWK
 531 PGAC_PATH_FLEX
 532 AC_PROG_LN_S
 533 PGAC_PROG_LD
 534 AC_SUBST(LD)
 535 AC_SUBST(with_gnu_ld)
 536 case $host_os in sysv5*)
 537   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 538   [
 539     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 540     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 541     LDFLAGS=$pgac_save_LDFLAGS
 542   ])
 543   ld_R_works=$pgac_cv_prog_ld_R
 544   AC_SUBST(ld_R_works)
 545 esac
 546 AC_PROG_RANLIB
 547 AC_CHECK_PROGS(LORDER, lorder)
 548 AC_PATH_PROG(TAR, tar)
 549 PGAC_CHECK_STRIP
 550
 551 AC_CHECK_PROGS(YACC, ['bison -y'])
 552
 553 if test "$YACC"; then
 554   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 555     AC_MSG_WARN([
 556 *** If you are going to modify the grammar files or build from CVS, the installed
 557 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 558   fi
 559 fi
 560
 561 if test -z "$YACC"; then
 562   AC_MSG_WARN([
 563 *** Without Bison you will not be able to build PostgreSQL from CVS or
 564 *** change any of the parser definition files.  You can obtain Bison from
 565 *** a GNU mirror site.  (If you are using the official distribution of
 566 *** PostgreSQL then you do not need to worry about this because the Bison
 567 *** output is pre-generated.)  To use a different yacc program (possible,
 568 *** but not recommended), set the environment variable YACC before running
 569 *** 'configure'.])
 570 fi
 571 AC_SUBST(YFLAGS)
 572
 573 PGAC_PATH_PERL
 574 if test "$with_perl" = yes; then
 575   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 576   PGAC_CHECK_PERL_EMBED_LDFLAGS
 577 fi
 578
 579 if test "$with_python" = yes; then
 580   PGAC_PATH_PYTHON
 581   PGAC_CHECK_PYTHON_EMBED_SETUP
 582 fi
 583
 584
 585 ##
 586 ## Libraries
 587 ##
 588
 589 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 590 then
 591         AC_CHECK_LIB(bsd,      main)
 592 fi
 593 AC_CHECK_LIB(util,     setproctitle)
 594 AC_CHECK_LIB(m,        main)
 595 AC_CHECK_LIB(dl,       main)
 596 AC_CHECK_LIB(nsl,      main)
 597 AC_CHECK_LIB(socket,   main)
 598 AC_CHECK_LIB(ipc,      main)
 599 AC_CHECK_LIB(IPC,      main)
 600 AC_CHECK_LIB(lc,       main)
 601 AC_CHECK_LIB(dld,      main)
 602 AC_CHECK_LIB(ld,       main)
 603 AC_CHECK_LIB(compat,   main)
 604 AC_CHECK_LIB(BSD,      main)
 605 AC_CHECK_LIB(gen,      main)
 606 AC_CHECK_LIB(PW,       main)
 607 AC_CHECK_LIB(resolv,   main)
 608 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 609 # QNX:
 610 AC_CHECK_LIB(unix, main)
 611 AC_SEARCH_LIBS(crypt,  crypt)
 612 # BeOS:
 613 if test "$PORTNAME" = "beos"
 614 then
 615         AC_CHECK_LIB(bind, __inet_ntoa)
 616 fi
 617 # Solaris:
 618 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 619 # Cygwin:
 620 AC_CHECK_LIB(cygipc, shmget)
 621 # WIN32:
 622 if test "$PORTNAME" = "win32"
 623 then
 624         AC_CHECK_LIB(wsock32, main)
 625 fi
 626
 627 if test "$with_readline" = yes; then
 628   PGAC_CHECK_READLINE
 629   if test x"$pgac_cv_check_readline" = x"no"; then
 630     AC_MSG_ERROR([readline library not found
 631 If you have readline already installed, see config.log for details on the
 632 failure.  It is possible the compiler isn't looking in the proper directory.
 633 Use --without-readline to disable readline support.])
 634   fi
 635 fi
 636
 637 if test "$with_zlib" = yes; then
 638   AC_CHECK_LIB(z, inflate, [],
 639                [AC_MSG_ERROR([zlib library not found
 640 If you have zlib already installed, see config.log for details on the
 641 failure.  It is possible the compiler isn't looking in the proper directory.
 642 Use --without-zlib to disable zlib support.])])
 643 fi
 644
 645 if test "$enable_spinlocks" = yes; then
 646   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 647 else
 648   AC_MSG_WARN([
 649 *** Not using spinlocks will cause poor performance.])
 650 fi
 651
 652 if test "$with_krb5" = yes ; then
 653   if test "$PORTNAME" != "win32"; then
 654      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 655                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 656      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 657                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 658      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 659                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 660   else
 661      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 662                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 663   fi
 664 fi
 665
 666 if test "$with_openssl" = yes ; then
 667   dnl Order matters!
 668   if test "$PORTNAME" != "win32"; then
 669      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 670      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 671   else
 672      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 673      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 674   fi
 675 fi
 676
 677 if test "$with_pam" = yes ; then
 678   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 679 fi
 680
 681
 682 ##
 683 ## Header files
 684 ##
 685
 686 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 687 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 688
 689 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 690 # netinet/in.h is included first.
 691 AC_CHECK_HEADERS(netinet/in.h)
 692 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 693 [AC_INCLUDES_DEFAULT
 694 #ifdef HAVE_NETINET_IN_H
 695 #include <netinet/in.h>
 696 #endif
 697 ])
 698
 699 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 700   AC_CHECK_HEADERS(readline/readline.h, [],
 701         [AC_CHECK_HEADERS(readline.h, [],
 702                 [AC_MSG_ERROR([readline header not found
 703 If you have readline already installed, see config.log for details on the
 704 failure.  It is possible the compiler isn't looking in the proper directory.
 705 Use --without-readline to disable readline support.])])])
 706   AC_CHECK_HEADERS(readline/history.h, [],
 707         [AC_CHECK_HEADERS(history.h, [],
 708                 [AC_MSG_ERROR([history header not found
 709 If you have readline already installed, see config.log for details on the
 710 failure.  It is possible the compiler isn't looking in the proper directory.
 711 Use --without-readline to disable readline support.])])])
 712 fi
 713
 714 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 715 # Some installations of libedit usurp /usr/include/readline/, which seems
 716 # bad practice, since in combined installations readline will have its headers
 717 # there.  We might have to resort to AC_EGREP checks to make sure we found
 718 # the proper header...
 719   AC_CHECK_HEADERS(editline/readline.h, [],
 720         [AC_CHECK_HEADERS(readline.h, [],
 721                 [AC_CHECK_HEADERS(readline/readline.h, [],
 722                         [AC_MSG_ERROR([readline header not found
 723 If you have libedit already installed, see config.log for details on the
 724 failure.  It is possible the compiler isn't looking in the proper directory.
 725 Use --without-readline to disable libedit support.])])])])
 726   AC_CHECK_HEADERS(editline/history.h, [],
 727         [AC_CHECK_HEADERS(history.h, [],
 728                 [AC_CHECK_HEADERS(readline/history.h, [],
 729                         [AC_MSG_ERROR([history header not found
 730 If you have libedit already installed, see config.log for details on the
 731 failure.  It is possible the compiler isn't looking in the proper directory.
 732 Use --without-readline to disable libedit support.])])])])
 733 fi
 734
 735 if test "$with_zlib" = yes; then
 736   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 737 If you have zlib already installed, see config.log for details on the
 738 failure.  It is possible the compiler isn't looking in the proper directory.
 739 Use --without-zlib to disable zlib support.])])
 740 fi
 741
 742 if test "$with_krb5" = yes ; then
 743   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 744 fi
 745
 746 if test "$with_openssl" = yes ; then
 747   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 748   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 749 fi
 750
 751 if test "$with_pam" = yes ; then
 752   AC_CHECK_HEADERS(security/pam_appl.h, [],
 753                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 754                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 755 fi
 756
 757 if test "$with_bonjour" = yes ; then
 758   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 759 fi
 760
 761
 762 ##
 763 ## Types, structures, compiler characteristics
 764 ##
 765
 766 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 767 AC_C_CONST
 768 AC_C_INLINE
 769 AC_C_STRINGIZE
 770 PGAC_C_SIGNED
 771 AC_C_VOLATILE
 772 PGAC_C_FUNCNAME_SUPPORT
 773 PGAC_STRUCT_TIMEZONE
 774 PGAC_UNION_SEMUN
 775 PGAC_STRUCT_SOCKADDR_UN
 776 PGAC_STRUCT_SOCKADDR_STORAGE
 777 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 778 PGAC_STRUCT_ADDRINFO
 779
 780 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 781 [#include <sys/param.h>
 782 #include <sys/types.h>
 783 #include <sys/socket.h>
 784 #include <sys/ucred.h>])
 785
 786 AC_CHECK_TYPES([struct option], [], [],
 787 [#ifdef HAVE_GETOPT_H
 788 #include <getopt.h>
 789 #endif])
 790
 791 if test "$with_zlib" = yes; then
 792   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 793   # did not).  While we could work around the lack of z_streamp, it
 794   # seems unwise to encourage people to use such old zlib versions...
 795   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 796 Use --without-zlib to disable zlib support.])],
 797                 [#include <zlib.h>])
 798 fi
 799
 800 if test "$with_krb5" = yes; then
 801 # Check for differences between MIT and Heimdal (KTH) releases
 802   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 803                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 804                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 805                                      [#include <krb5.h>])],
 806                    [#include <krb5.h>])
 807   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 808                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 809                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 810                                      [#include <krb5.h>])],
 811                    [#include <krb5.h>])
 812 fi
 813
 814 ##
 815 ## Functions, global variables
 816 ##
 817
 818 PGAC_VAR_INT_TIMEZONE
 819 AC_FUNC_ACCEPT_ARGTYPES
 820 PGAC_FUNC_GETTIMEOFDAY_1ARG
 821
 822 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 823
 824 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 825
 826 HAVE_IPV6=no
 827 AC_CHECK_TYPE([struct sockaddr_in6],
 828               [AC_CHECK_FUNC(inet_ntop,
 829                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 830                                                           HAVE_IPV6=yes])],
 831               [],
 832 [$ac_includes_default
 833 #include <netinet/in.h>])
 834 AC_SUBST(HAVE_IPV6)
 835
 836 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 837 [AC_TRY_LINK(
 838 [#include <machine/vmparam.h>
 839 #include <sys/exec.h>
 840 ],
 841 [PS_STRINGS->ps_nargvstr = 1;
 842 PS_STRINGS->ps_argvstr = "foo";],
 843 [pgac_cv_var_PS_STRINGS=yes],
 844 [pgac_cv_var_PS_STRINGS=no])])
 845 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 846   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 847 fi
 848
 849
 850 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 851 # is missing.  Yes, there are machines that have only one.  We may
 852 # also decide to use snprintf.c if snprintf() is present but does not
 853 # have all the features we need --- see below.
 854
 855 pgac_need_repl_snprintf=no
 856 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 857 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 858
 859
 860 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 861 # include/c.h will provide declarations.  Note this is a separate test
 862 # from whether the functions exist in the C library --- there are
 863 # systems that have the functions but don't bother to declare them :-(
 864
 865 AC_CHECK_DECLS([snprintf, vsnprintf])
 866
 867
 868 # do this one the hard way in case isinf() is a macro
 869 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 870 [AC_TRY_LINK(
 871 [#include <math.h>
 872 ],
 873 [double x = 0.0; int res = isinf(x);],
 874 [ac_cv_func_isinf=yes],
 875 [ac_cv_func_isinf=no])])
 876
 877 if test $ac_cv_func_isinf = yes ; then
 878   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 879 else
 880   AC_LIBOBJ(isinf)
 881   # Look for a way to implement a substitute for isinf()
 882   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 883 fi
 884
 885 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 886
 887 # system's version of getaddrinfo(), if any, may be used only if we found
 888 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 889 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 890   AC_REPLACE_FUNCS([getaddrinfo])
 891 else
 892   AC_LIBOBJ(getaddrinfo)
 893 fi
 894
 895 # similarly, use system's getopt_long() only if system provides struct option.
 896 if test x"$ac_cv_type_struct_option" = xyes ; then
 897   AC_REPLACE_FUNCS([getopt_long])
 898 else
 899   AC_LIBOBJ(getopt_long)
 900 fi
 901
 902 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 903 # We override the previous test that said fseeko/ftello didn't exist
 904 # OS tests are also done in include/c.h and port/fseeko.c
 905 case $host_os in bsdi*|netbsd*)
 906 ac_cv_func_fseeko=yes
 907 esac
 908
 909 # Solaris has a very slow qsort in certain cases, so we replace it.
 910 if test "$PORTNAME" = "solaris"; then
 911 AC_LIBOBJ(qsort)
 912 fi
 913
 914 # Win32 support
 915 if test "$PORTNAME" = "win32"; then
 916 AC_LIBOBJ(gettimeofday)
 917 AC_LIBOBJ(kill)
 918 AC_LIBOBJ(open)
 919 AC_LIBOBJ(rand)
 920 AC_DEFINE([HAVE_SYMLINK], 1,
 921           [Define to 1 if you have the `symlink' function.])
 922 fi
 923
 924 if test "$with_readline" = yes; then
 925   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 926   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 927   AC_CHECK_FUNCS([replace_history_entry])
 928 fi
 929
 930
 931 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 932 AC_MSG_CHECKING(for finite)
 933 AC_TRY_LINK([#include <math.h>],
 934             [int dummy=finite(1.0);],
 935             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 936 AC_MSG_RESULT(yes)],
 937             [AC_MSG_RESULT(no)])
 938
 939 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 940 dnl (especially on GNU libc)
 941 dnl See also comments in c.h.
 942 AC_MSG_CHECKING(for sigsetjmp)
 943 AC_TRY_LINK([#include <setjmp.h>],
 944             [sigjmp_buf x; sigsetjmp(x, 1);],
 945             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 946 AC_MSG_RESULT(yes)],
 947             [AC_MSG_RESULT(no)])
 948
 949 AC_CHECK_FUNC(syslog,
 950               [AC_CHECK_HEADER(syslog.h,
 951                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 952
 953 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 954 [AC_TRY_LINK([#include <unistd.h>],
 955   [extern int optreset; optreset = 1;],
 956   [pgac_cv_var_int_optreset=yes],
 957   [pgac_cv_var_int_optreset=no])])
 958 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 959   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 960 fi
 961
 962 AC_CHECK_FUNCS([strtoll strtoq], [break])
 963 AC_CHECK_FUNCS([strtoull strtouq], [break])
 964
 965 # Check for one of atexit() or on_exit()
 966 AC_CHECK_FUNCS(atexit, [],
 967                [AC_CHECK_FUNCS(on_exit, [],
 968                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 969
 970 AC_FUNC_FSEEKO
 971
 972 #
 973 # Pthreads
 974 #
 975 # For each platform, we need to know about any special compile and link
 976 # libraries, and whether the normal C function names are thread-safe.
 977 # See the comment at the top of src/port/thread.c for more information.
 978 #
 979 if test "$enable_thread_safety" = yes; then
 980 ACX_PTHREAD     # set thread flags
 981
 982 # Some platforms use these, so just defineed them.  They can't hurt if they
 983 # are not supported.
 984 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 985
 986
 987 # At this point, we don't want to muck with the compiler name for threading.
 988 # Let's see who fails, perhaps AIX.  2004-04-23
 989 if test "$PTHREAD_CC" != "$CC"; then
 990 AC_MSG_ERROR([
 991 PostgreSQL does not support platforms that require a special
 992 compiler binary for thread-safety.
 993 ])
 994 fi
 995
 996 if test "$THREAD_SUPPORT" = no; then
 997 AC_MSG_ERROR([
 998 Cannot enable threads on your platform.
 999 Your platform is known to not support thread-safe programs.
1000 For details, compile and run src/bin/pg_thread_test.
1001 ])
1002 fi
1003
1004 # Check for *_r functions
1005 _CFLAGS="$CFLAGS"
1006 _LIBS="$LIBS"
1007 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1008 LIBS="$LIBS $PTHREAD_LIBS"
1009
1010 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1011
1012 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1013
1014 # Do test here with the proper thread flags
1015 PGAC_FUNC_GETPWUID_R_5ARG
1016 PGAC_FUNC_STRERROR_R_INT
1017
1018 CFLAGS="$_CFLAGS"
1019 LIBS="$_LIBS"
1020
1021 else
1022 # do not use values from template file
1023 PTHREAD_CFLAGS=
1024 PTHREAD_LIBS=
1025 fi
1026
1027 AC_SUBST(PTHREAD_CFLAGS)
1028 AC_SUBST(PTHREAD_LIBS)
1029
1030
1031 # This test makes sure that run tests work at all.  Sometimes a shared
1032 # library is found by the linker, but the runtime linker can't find it.
1033 # This check should come after all modifications of compiler or linker
1034 # variables, and before any other run tests.
1035 AC_MSG_CHECKING([test program])
1036 AC_TRY_RUN([int main() { return 0; }],
1037 [AC_MSG_RESULT(ok)],
1038 [AC_MSG_RESULT(failed)
1039 AC_MSG_ERROR([[
1040 *** Could not execute a simple test program.  This may be a problem
1041 *** related to locating shared libraries.  Check the file 'config.log'
1042 *** for the exact reason.]])],
1043 [AC_MSG_RESULT([cross-compiling])])
1044
1045
1046 # Force use of our snprintf if system's doesn't do arg control
1047 # This feature is used by NLS
1048 if test "$enable_nls" = yes &&
1049    test $pgac_need_repl_snprintf = no &&
1050 # On Win32, libintl replaces snprintf() with its own version that
1051 # understands arg control, so we don't need our own.  In fact, it
1052 # also uses macros that conflict with ours, so we _can't_ use
1053 # our own.
1054    test "$PORTNAME" != "win32"; then
1055   PGAC_FUNC_PRINTF_ARG_CONTROL
1056   if test $pgac_cv_printf_arg_control != yes ; then
1057     pgac_need_repl_snprintf=yes
1058   fi
1059 fi
1060
1061
1062 dnl Check to see if we have a working 64-bit integer type.
1063 dnl This breaks down into two steps:
1064 dnl (1) figure out if the compiler has a 64-bit int type with working
1065 dnl arithmetic, and if so
1066 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1067 dnl snprintf is the only library routine we really need for int8 support.)
1068 dnl It's entirely possible to have a compiler that handles a 64-bit type
1069 dnl when the C library doesn't; this is fairly likely when using gcc on
1070 dnl an older platform, for example.
1071 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1072 dnl we force our own version of snprintf() to be used instead.
1073 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1074
1075 PGAC_TYPE_64BIT_INT([long int])
1076
1077 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1078   PGAC_TYPE_64BIT_INT([long long int])
1079 fi
1080
1081
1082 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1083
1084 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1085   AC_TRY_COMPILE([
1086 #define INT64CONST(x)  x##LL
1087 long long int foo = INT64CONST(0x1234567890123456);
1088 ],
1089         [],
1090         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1091         [])
1092 fi
1093
1094
1095 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1096 # we found we need to use "long long int", better check.  We cope with
1097 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1098 # work, fall back to our own snprintf emulation (which we know uses %lld).
1099
1100 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1101   if test $pgac_need_repl_snprintf = no; then
1102     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1103     if test "$LONG_LONG_INT_FORMAT" = ""; then
1104       # Force usage of our own snprintf, since system snprintf is broken
1105       pgac_need_repl_snprintf=yes
1106       LONG_LONG_INT_FORMAT='%lld'
1107     fi
1108   else
1109     # Here if we previously decided we needed to use our own snprintf
1110     LONG_LONG_INT_FORMAT='%lld'
1111   fi
1112   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1113   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1114   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1115 else
1116   # Here if we are not using 'long long int' at all
1117   INT64_FORMAT='"%ld"'
1118   UINT64_FORMAT='"%lu"'
1119 fi
1120
1121 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1122                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1123
1124 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1125                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1126
1127 # Now we have checked all the reasons to replace snprintf
1128 if test $pgac_need_repl_snprintf = yes; then
1129   AC_DEFINE(USE_SNPRINTF, 1, [Use replacement snprintf() functions.])
1130   AC_LIBOBJ(snprintf)
1131 fi
1132
1133 # Need a #define for the size of Datum (unsigned long)
1134 AC_CHECK_SIZEOF([unsigned long])
1135
1136 # Determine memory alignment requirements for the basic C data types.
1137
1138 PGAC_CHECK_ALIGNOF(short)
1139 PGAC_CHECK_ALIGNOF(int)
1140 PGAC_CHECK_ALIGNOF(long)
1141 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1142   PGAC_CHECK_ALIGNOF(long long int)
1143 fi
1144 PGAC_CHECK_ALIGNOF(double)
1145
1146 # Compute maximum alignment of any basic type.
1147 # We assume long's alignment is at least as strong as char, short, or int;
1148 # but we must check long long (if it exists) and double.
1149
1150 MAX_ALIGNOF=$pgac_cv_alignof_long
1151 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1152   MAX_ALIGNOF=$pgac_cv_alignof_double
1153 fi
1154 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1155   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1156 fi
1157 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1158
1159
1160 # Some platforms predefine the types int8, int16, etc.  Only check
1161 # a (hopefully) representative subset.
1162 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1163 [#include <stdio.h>
1164 #ifdef HAVE_SUPPORTDEFS_H
1165 #include <SupportDefs.h>
1166 #endif])
1167
1168 # We also check for sig_atomic_t, which *should* be defined per ANSI
1169 # C, but is missing on some old platforms.
1170 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1171
1172
1173 PGAC_FUNC_POSIX_SIGNALS
1174 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1175   AC_MSG_ERROR([
1176 *** Thread-safety requires POSIX signals, which are not supported by your
1177 *** operating system.
1178 ])
1179 fi
1180
1181 if test $ac_cv_func_fseeko = yes; then
1182 AC_SYS_LARGEFILE
1183 fi
1184
1185 # SunOS doesn't handle negative byte comparisons properly with +/- return
1186 AC_FUNC_MEMCMP
1187
1188
1189 # Select semaphore implementation type.
1190 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1191   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1192   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1193 else
1194   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1195     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1196     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1197   else
1198     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1199     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1200   fi
1201 fi
1202
1203
1204 # Select shared-memory implementation type.
1205 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1206 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1207
1208
1209 if test "$enable_nls" = yes ; then
1210   PGAC_CHECK_GETTEXT
1211 fi
1212
1213 # Check for Tcl configuration script tclConfig.sh
1214 if test "$with_tcl" = yes; then
1215     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1216     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1217                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1218     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1219     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1220     ac_save_CPPFLAGS=$CPPFLAGS
1221     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1222     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1223     CPPFLAGS=$ac_save_CPPFLAGS
1224 fi
1225
1226 #
1227 # Check for DocBook and tools
1228 #
1229 PGAC_PROG_NSGMLS
1230 PGAC_PROG_JADE
1231 PGAC_CHECK_DOCBOOK(4.2)
1232 PGAC_PATH_DOCBOOK_STYLESHEETS
1233 PGAC_PATH_COLLATEINDEX
1234 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1235
1236 # Thread testing
1237
1238 # We have to run the thread test near the end so we have all our symbols
1239 # defined.  Cross compiling throws a warning.
1240 #
1241 if test "$enable_thread_safety_force" = yes; then
1242   AC_MSG_WARN([
1243 *** Skipping thread test program.  --enable-thread-safety-force was used.
1244 *** Run the program in src/tools/thread on the your machine and add
1245 proper locking function calls to your applications to guarantee thread
1246 safety.
1247 ])
1248 elif test "$enable_thread_safety" = yes; then
1249 AC_MSG_CHECKING([thread safety of required library functions])
1250
1251 _CFLAGS="$CFLAGS"
1252 _LIBS="$LIBS"
1253 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1254 LIBS="$LIBS $PTHREAD_LIBS"
1255 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1256   [AC_MSG_RESULT(yes)],
1257   [AC_MSG_RESULT(no)
1258   AC_MSG_ERROR([
1259 *** Thread test program failed.  Your platform is not thread-safe.
1260 *** Check the file 'config.log'for the exact reason.
1261 ***
1262 *** You can use the configure option --enable-thread-safety-force
1263 *** to force threads to be enabled.  However, you must then run
1264 *** the program in src/tools/thread and add locking function calls
1265 *** to your applications to guarantee thread safety.
1266 ])],
1267   [AC_MSG_RESULT(maybe)
1268   AC_MSG_WARN([
1269 *** Skipping thread test program because of cross-compile build.
1270 *** Run the program in src/tools/thread on the target machine.
1271 ])])
1272 CFLAGS="$_CFLAGS"
1273 LIBS="$_LIBS"
1274 fi
1275
1276 # prepare build tree if outside source tree
1277 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1278 # Note 2: /bin/pwd might be better than shell's built-in at getting
1279 #         a symlink-free name.
1280 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1281   vpath_build=no
1282 else
1283   vpath_build=yes
1284   if test "$no_create" != yes; then
1285     _AS_ECHO_N([preparing build tree... ])
1286     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1287     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1288       || AC_MSG_ERROR(failed)
1289     AC_MSG_RESULT(done)
1290   fi
1291 fi
1292 AC_SUBST(vpath_build)
1293
1294
1295 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1296
1297 AC_CONFIG_LINKS([
1298   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1299   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1300   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1301   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1302   src/include/pg_config_os.h:src/include/port/${template}.h
1303   src/Makefile.port:src/makefiles/Makefile.${template}
1304 ])
1305
1306 if test "$PORTNAME" = "win32"; then
1307 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1308 # Links sometimes fail undetected on Mingw -
1309 # so here we detect it and warn the user
1310 for FILE in $CONFIG_LINKS
1311  do
1312         # test -e works for symlinks in the MinGW console
1313         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1314  done
1315 ])
1316 fi
1317
1318 AC_CONFIG_HEADERS([src/include/pg_config.h],
1319 [
1320 # Update timestamp for pg_config.h (see Makefile.global)
1321 echo >src/include/stamp-h
1322 ])
1323
1324 AC_OUTPUT
1325