granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(build/find_ldap.m4)
  20 sinclude(acinclude.m4)
  21
  22 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  23 dnl configure script to emit at least warnings when it comes across unknown
  24 dnl command line options. These versions also have the macro
  25 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  26 dnl We want to have this turned off here since our configure calls can
  27 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  28 dnl So avoid confusing the user by turning this off. See also PR 45221.
  29 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  30
  31 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  32 dnl by configure until it is too late.  Is that how it should be or not?
  33 dnl Something seems broken here.
  34 AC_PREFIX_DEFAULT(/usr/local/apache2)
  35
  36 dnl Get the layout here, so we can pass the required variables to apr
  37 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  38
  39 dnl reparse the configure arguments.
  40 APR_PARSE_ARGUMENTS
  41
  42 dnl export expanded and relative configure argument variables
  43 APACHE_EXPORT_ARGUMENTS
  44
  45 dnl Save user-defined environment settings for later restoration
  46 dnl
  47 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  51 APR_SAVE_THE_ENVIRONMENT(LIBS)
  52 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  53
  54 dnl Generate ./config.nice for reproducing runs of configure
  55 dnl
  56 APR_CONFIG_NICE(config.nice)
  57
  58 nl='
  59 '
  60 dnl Check that mkdir -p works
  61 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  62
  63 dnl ## Run configure for packages Apache uses
  64
  65 dnl shared library support for these packages doesn't currently
  66 dnl work on some platforms
  67
  68 AC_CANONICAL_SYSTEM
  69
  70 orig_prefix="$prefix"
  71
  72 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  73
  74 AC_ARG_WITH(included-apr,
  75 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  76
  77 if test "x$with_included_apr" = "xyes"; then
  78    apr_found=reconfig
  79 else
  80    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2)
  81 fi
  82
  83 if test "$apr_found" = "no"; then
  84   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  85 fi
  86
  87 if test "$apr_found" = "reconfig"; then
  88   APR_SUBDIR_CONFIG(srclib/apr,
  89                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  90                     [--enable-layout=*|\'--enable-layout=*])
  91   dnl We must be the first to build and the last to be cleaned
  92   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  93   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  94
  95   dnl We have to find apr-N-config when we reconfigure APR.
  96   for majorver in 1 2; do
  97     test_apr_config="./srclib/apr/apr-${majorver}-config"
  98     if test -f "$test_apr_config"; then
  99       apr_config="$test_apr_config"
 100     fi
 101   done
 102 fi
 103
 104 APR_SETIFNULL(CC, `$apr_config --cc`)
 105 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 106 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 107 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 108 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 109 INTERNAL_CPPFLAGS=""
 110 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 111 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 112 APR_BINDIR=`$apr_config --bindir`
 113 APR_INCLUDEDIR=`$apr_config --includedir`
 114 APR_INCLUDES=`$apr_config --includes`
 115 APR_VERSION=`$apr_config --version`
 116 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 117 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 118
 119 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 120
 121 if test "x${apr_major_version}" = "x2"; then
 122    apu_found=obsolete
 123 elif test "x$with_included_apr" = "xyes"; then
 124    apu_found=reconfig
 125 else
 126    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 127    dnl isn't supported.
 128    ifdef([APR_FIND_APU], [
 129      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 130                   1, ${apr_major_version})
 131    ], [apu_found=no])
 132 fi
 133
 134 if test "$apu_found" = "no"; then
 135   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 136 fi
 137
 138 # Catch some misconfigurations:
 139 case ${apr_found}.${apu_found} in
 140 reconfig.yes)
 141   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 142   ;;
 143 yes.reconfig)
 144   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 145   ;;
 146 esac
 147
 148 if test "$apu_found" = "reconfig"; then
 149   APR_SUBDIR_CONFIG(srclib/apr-util,
 150                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 151                     [--enable-layout=*|\'--enable-layout=*])
 152   dnl We must be the last to build and the first to be cleaned
 153   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 154   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 155   dnl APR and APR-Util major versions must match
 156   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 157 fi
 158
 159 if test "$apu_found" = "obsolete"; then
 160   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 161 else
 162   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 163   APU_BINDIR=`$apu_config --bindir`
 164   APU_INCLUDEDIR=`$apu_config --includedir`
 165   APU_INCLUDES=`$apu_config --includes`
 166   APU_VERSION=`$apu_config --version`
 167   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 168 fi
 169
 170 dnl In case we picked up CC and CPP from APR, get that info into the
 171 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 172 dnl PCRE and for our config tests will be whatever PCRE determines.
 173 AC_PROG_CC
 174 AC_PROG_CPP
 175
 176 dnl Try to get c99 support for variadic macros
 177 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 178
 179 if test "x${cache_file}" = "x/dev/null"; then
 180   # Likewise, ensure that CC and CPP are passed through to the pcre
 181   # configure script iff caching is disabled (the autoconf 2.5x default).
 182   export CC; export CPP
 183 fi
 184
 185 dnl Absolute source/build directory
 186 abs_srcdir=`(cd $srcdir && pwd)`
 187 abs_builddir=`pwd`
 188
 189 AC_ARG_WITH(pcre,
 190 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 191
 192 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 193 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 194    PCRE_CONFIG=$with_pcre/bin/pcre-config
 195 elif test -x "$with_pcre"; then
 196    PCRE_CONFIG=$with_pcre
 197 fi
 198
 199 if test "$PCRE_CONFIG" != "false"; then
 200   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 201     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 202   fi
 203   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 204   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 205   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 206 else
 207   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 208 fi
 209 APACHE_SUBST(PCRE_LIBS)
 210 APR_ADDTO(AP_LIBS, [\$(PCRE_LIBS)])
 211
 212 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 213
 214 dnl If the source dir is not equal to the build dir,
 215 dnl then we are running in VPATH mode.
 216
 217 APR_ADDTO(INCLUDES, [-I.])
 218
 219 if test "$abs_builddir" != "$abs_srcdir"; then
 220   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 221 fi
 222
 223 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 224
 225 # apr/apr-util --includes may pick up system paths for dependent
 226 # libraries, so ensure these are later in INCLUDES than local source
 227 # directories.
 228 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 229 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 230
 231 dnl Add in path to PCRE includes
 232 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 233
 234 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 235
 236 case $host in
 237   *os2*)
 238       # Use a custom made libtool replacement
 239       echo "using aplibtool"
 240       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 241       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 242       SH_LIBS="\$(ALL_LIBS)"
 243       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 244       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 245       MK_IMPLIB="emximp"
 246       other_targets="$other_targets os2core"
 247       INSTALL_PROG_FLAGS="-e .exe"
 248       SHLTCFLAGS=""
 249       LTCFLAGS=""
 250       ;;
 251   *)
 252       if test "x$LTFLAGS" = "x"; then
 253           LTFLAGS='--silent'
 254       fi
 255       my_libtool=`$apr_config --apr-libtool`
 256       LIBTOOL="$my_libtool \$(LTFLAGS)"
 257       libtoolversion=`$my_libtool --version`
 258       case $libtoolversion in
 259           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 260               SH_LIBTOOL='$(LIBTOOL)'
 261               SHLTCFLAGS="-prefer-pic"
 262               LTCFLAGS="-prefer-non-pic -static"
 263               ;;
 264           *)
 265               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 266               SHLTCFLAGS=""
 267               LTCFLAGS=""
 268               ;;
 269       esac
 270       ;;
 271 esac
 272 APACHE_SUBST(SHLTCFLAGS)
 273 APACHE_SUBST(LTCFLAGS)
 274
 275 case $host in
 276   *-apple-aux3*)
 277       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 278       ;;
 279   *os2-emx*)
 280       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 281       ;;
 282   *-linux-*)
 283       case `uname -r` in
 284         2.[[2-9]]* )
 285             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 286             ;;
 287         * )
 288             ;;
 289       esac
 290       ;;
 291   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 292       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 293       ;;
 294   *-solaris2*)
 295       dnl This is a hack -- we should be using AC_TRY_RUN instead
 296       ap_platform_runtime_link_flag="-R"
 297       dnl solaris 8 and above don't have a thundering herd
 298       dnl not sure about rev's before this one.
 299       case `uname -r` in
 300         5.[567]*)
 301             ;;
 302         * )
 303             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 304             ;;
 305       esac
 306       ;;
 307   *cygwin*)
 308       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 309       ;;
 310   *mingw32*)
 311       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 312       APR_SETIFNULL(ac_cv_func_times, [no])
 313       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 314       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 315       ;;
 316   *aix*)
 317       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 318       if test $aixver -ge 4320; then
 319         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 320       fi
 321       ;;
 322   *os390*)
 323       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 324       ;;
 325 esac
 326
 327 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 328
 329 dnl
 330 dnl Process command line arguments. This is done early in the process so the
 331 dnl user can get feedback quickly in case of an error.
 332 dnl
 333 dnl ### need to move some of the arguments "up here"
 334
 335 dnl ## Check for programs
 336
 337 AC_PATH_PROG(RM, rm)
 338 AC_PATH_PROG(PKGCONFIG, pkg-config)
 339 AC_PATH_PROG(RSYNC, rsync)
 340 AC_PROG_AWK
 341 AC_PROG_LN_S
 342 AC_CHECK_TOOL(RANLIB, ranlib, true)
 343 dnl AC_PATH_PROG(PERL_PATH, perl)
 344 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 345
 346 # Hard-coded install programs
 347 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 348 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 349 APACHE_SUBST(MKINSTALLDIRS)
 350 APACHE_SUBST(INSTALL)
 351
 352 dnl Various OS checks that apparently set required flags
 353 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 354 AC_USE_SYSTEM_EXTENSIONS
 355 ], [
 356 AC_AIX
 357 AC_MINIX
 358 ])
 359
 360 AC_ISC_POSIX
 361
 362 # Ensure that satisfactory versions of apr and apr-util are
 363 # found if external copies are configured.
 364 if test "${apr_found}" = "yes"; then
 365   # Require at least APR 1.3.x otherwise fail
 366   APACHE_CHECK_APxVER([apr], 1, 3)
 367 fi
 368
 369 if test "${apu_found}" = "yes"; then
 370   # Require at least APR-util 1.3.x otherwise fail
 371   if test "${apr_found}" = "yes"; then
 372     # we need to add the APR includes to CPPFLAGS
 373     apu_ckver_CPPFLAGS="$CPPFLAGS"
 374     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 375     APACHE_CHECK_APxVER([apu], 1, 3)
 376     CPPFLAGS="$apu_ckver_CPPFLAGS"
 377   else
 378     APACHE_CHECK_APxVER([apu], 1, 3)
 379   fi
 380 fi
 381
 382 dnl Check for what we can generate dependency files with
 383 APR_CHECK_DEPEND
 384
 385 dnl ## Check for libraries
 386
 387 dnl ## Check for header files
 388
 389 dnl I think these are just used all over the place, so just check for
 390 dnl them at the base of the tree. If some are specific to a single
 391 dnl directory, they should be moved (Comment #Spoon)
 392
 393 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 394 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 395 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 396
 397 AC_HEADER_STDC
 398 AC_CHECK_HEADERS( \
 399 string.h \
 400 limits.h \
 401 unistd.h \
 402 sys/socket.h \
 403 pwd.h \
 404 grp.h \
 405 strings.h \
 406 sys/prctl.h \
 407 sys/processor.h \
 408 sys/sem.h \
 409 sys/sdt.h
 410 )
 411 AC_HEADER_SYS_WAIT
 412
 413 dnl ## Check for typedefs, structures, and compiler characteristics.
 414
 415 AC_C_CONST
 416
 417 dnl ## Check for library functions
 418 dnl ## sqrt() only needed in support/ab.c
 419 saved_LIBS="$LIBS"
 420 LIBS=""
 421 AC_SEARCH_LIBS(sqrt, m)
 422 MATH_LIBS="$LIBS"
 423 APACHE_SUBST(MATH_LIBS)
 424 LIBS="$saved_LIBS"
 425
 426 saved_LIBS="$LIBS"
 427 LIBS=""
 428 AC_SEARCH_LIBS(crypt, crypt)
 429 CRYPT_LIBS="$LIBS"
 430 APACHE_SUBST(CRYPT_LIBS)
 431 LIBS="$saved_LIBS"
 432
 433 dnl See Comment #Spoon
 434
 435 AC_CHECK_FUNCS( \
 436 getpwnam \
 437 getgrnam \
 438 initgroups \
 439 bindprocessor \
 440 prctl \
 441 timegm \
 442 getpgid \
 443 fopen64
 444 )
 445
 446 dnl confirm that a void pointer is large enough to store a long integer
 447 APACHE_CHECK_VOID_PTR_LEN
 448
 449 dnl check for LDAP support, needed by modules/aaa and modules/ldap
 450 AP_FIND_LDAP
 451
 452 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 453 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 454 [AC_TRY_COMPILE([#include <sys/types.h>
 455 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 456   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 457 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 458     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 459 fi
 460
 461 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 462
 463 case $host in
 464     *aix*)
 465         # for 32-bit builds, increase MAXDATA to allow lots of threads
 466         if test x$OBJECT_MODE != x64; then
 467             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 468         fi
 469         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 470         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 471         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 472         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 473         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 474         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 475         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 476         ;;
 477     *os390*)
 478         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 479         ;;
 480     *)
 481         OS_SPECIFIC_VARS=""
 482 esac
 483
 484 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 485         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 486         [PORT=80])
 487
 488 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 489         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 490         [SSLPORT=443])
 491
 492 DTRACE=true
 493 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 494 [
 495   enable_dtrace=$enableval
 496   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 497   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 498 ],
 499 [
 500   enable_dtrace=no
 501 ])
 502
 503 dnl Disabled dtrace build for now.
 504 enable_dtrace=no
 505
 506 case $host in
 507   *-solaris2*)
 508     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 509         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 510                   [Enable DTrace probes])
 511         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 512         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 513     fi
 514     ;;
 515 esac
 516
 517 APACHE_SUBST(DTRACE)
 518
 519 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 520 [
 521     AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 522         [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 523     APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 524 ])dnl
 525
 526 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 527 [
 528     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 529               [Allow modules to run hook after a fatal exception])
 530 ])dnl
 531
 532 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 533 [
 534   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 535   if test "$GCC" = "yes"; then
 536     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 537     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 538       save_CFLAGS=$CFLAGS
 539       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 540       AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo() { return 0; }])],
 541         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 542       CFLAGS=$save_CFLAGS
 543     ])
 544     if test "$ap_cv_cc_Wdas" = "yes"; then
 545       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 546     fi
 547   elif test "$AIX_XLC" = "yes"; then
 548     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 549   fi
 550 ])dnl
 551
 552 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 553 [
 554   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 555   if test "$GCC" = "yes"; then
 556     APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 557     AC_CACHE_CHECK([whether gcc accepts -Wdeclaration-after-statement], [ap_cv_cc_Wdas], [
 558       save_CFLAGS=$CFLAGS
 559       CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 560       AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo() { return 0; }])],
 561         [ap_cv_cc_Wdas=yes], [ap_cv_cc_Wdas=no])
 562       CFLAGS=$save_CFLAGS
 563     ])
 564     if test "$ap_cv_cc_Wdas" = "yes"; then
 565       APR_ADDTO(CFLAGS,[-Wdeclaration-after-statement])
 566     fi
 567   elif test "$AIX_XLC" = "yes"; then
 568     APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 569   fi
 570 ])dnl
 571
 572 dnl Conditionally enable PIE support for GNU toolchains.
 573 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 574 if test "$enable_pie" = "yes"; then
 575    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 576      save_CFLAGS=$CFLAGS
 577      save_LDFLAGS=$LDFLAGS
 578      CFLAGS="$CFLAGS -fPIE"
 579      LDFLAGS="$LDFLAGS -pie"
 580      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 581       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 582      CFLAGS=$save_CFLAGS
 583      LDFLAGS=$save_LDFLAGS
 584    ])
 585    if test "$ap_cv_cc_pie" = "yes"; then
 586      PICFLAGS="-fPIE"
 587      PILDFLAGS="-pie"
 588    else
 589      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 590    fi
 591 fi
 592 AC_SUBST(PICFLAGS)
 593 AC_SUBST(PILDFLAGS)
 594
 595 prefix="$orig_prefix"
 596 APACHE_ENABLE_MODULES
 597
 598 dnl reading config stubs
 599 esyscmd(./build/config-stubs .)
 600
 601 APACHE_SUBST(progname)
 602 APACHE_SUBST(OS)
 603 APACHE_SUBST(OS_DIR)
 604 APACHE_SUBST(BUILTIN_LIBS)
 605 APACHE_SUBST(SHLIBPATH_VAR)
 606 APACHE_SUBST(OS_SPECIFIC_VARS)
 607
 608 PRE_SHARED_CMDS='echo ""'
 609 POST_SHARED_CMDS='echo ""'
 610
 611 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 612
 613 if test "$apache_need_shared" = "yes"; then
 614   if test -f $ac_aux_dir/ltconfig; then
 615     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 616   fi
 617   shared_build="shared-build"
 618 fi
 619
 620 dnl enable_so tells us if *any* modules can be built as DSOs
 621
 622 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 623   case $host in
 624     *-ibm-aix*)
 625       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 626       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 627       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 628       ;;
 629     *os390)
 630       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 631       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 632   esac
 633   MOD_SO_ENABLED=yes
 634 fi
 635 AC_SUBST(MOD_SO_ENABLED)
 636
 637 APACHE_SUBST(PRE_SHARED_CMDS)
 638 APACHE_SUBST(POST_SHARED_CMDS)
 639 APACHE_SUBST(shared_build)
 640
 641 AC_ARG_WITH(program-name,
 642 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 643   progname="$withval" ], [
 644   progname="httpd"] )
 645
 646 # SuExec parameters
 647 AC_ARG_WITH(suexec-bin,
 648 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 649   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 650 ] )
 651
 652 AC_ARG_WITH(suexec-caller,
 653 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 654   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 655
 656 AC_ARG_WITH(suexec-userdir,
 657 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 658   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 659
 660 AC_ARG_WITH(suexec-docroot,
 661 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 662   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 663
 664 AC_ARG_WITH(suexec-uidmin,
 665 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 666   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 667
 668 AC_ARG_WITH(suexec-gidmin,
 669 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 670   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 671
 672 AC_ARG_WITH(suexec-logfile,
 673 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 674   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 675
 676 AC_ARG_WITH(suexec-safepath,
 677 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 678   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 679
 680 AC_ARG_WITH(suexec-umask,
 681 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 682   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 683
 684 dnl APR should go after the other libs, so the right symbols can be picked up
 685 if test x${apu_found} != xobsolete; then
 686   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 687 fi
 688 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 689 APACHE_SUBST(AP_LIBS)
 690 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 691 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 692
 693 AC_DEFINE(AP_USING_AUTOCONF, 1,
 694                 [Using autoconf to configure Apache])
 695
 696 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 697     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 698               [This platform doesn't suffer from the thundering herd problem])
 699 fi
 700
 701 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 702     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 703               [Listening sockets are non-blocking when there are more than 1])
 704 fi
 705
 706 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 707
 708 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 709 [
 710   v4mapped=$enableval
 711 ],
 712 [
 713     case $host in
 714     *freebsd5*|*netbsd*|*openbsd*)
 715         v4mapped=no
 716         ;;
 717     *)
 718         v4mapped=yes
 719         ;;
 720     esac
 721     if ap_mpm_is_enabled winnt; then
 722         dnl WinNT MPM doesn't support this.
 723         v4mapped=no
 724     fi
 725 ])
 726
 727 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 728     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 729               [Allow IPv4 connections on IPv6 listening sockets])
 730 fi
 731
 732 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 733 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 734 APACHE_FAST_OUTPUT(support/Makefile)
 735
 736 if test -d ./test; then
 737     APACHE_FAST_OUTPUT(test/Makefile)
 738 fi
 739
 740 dnl ## Finalize the variables
 741 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 742
 743 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 744 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 745 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 746 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 747 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 748 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 749
 750 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 751
 752 APACHE_GEN_CONFIG_VARS
 753
 754 dnl ## Build modules.c
 755 rm -f modules.c
 756 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 757
 758 APR_EXPAND_VAR(ap_prefix, $prefix)
 759 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 760         [Root directory of the Apache install area])
 761 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 762         [Location of the config file, relative to the Apache root directory])
 763 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 764         [Location of the MIME types config file, relative to the Apache root directory])
 765
 766 perlbin=`$ac_aux_dir/PrintPath perl`
 767 if test "x$perlbin" = "x"; then
 768     perlbin="/replace/with/path/to/perl/interpreter"
 769 fi
 770 AC_SUBST(perlbin)
 771
 772 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 773
 774 BSD_MAKEFILE=no
 775 ap_make_include=include
 776 ap_make_delimiter=' '
 777 case $host in
 778 *bsdi*)
 779     # Check whether they've installed GNU make
 780     if make --version > /dev/null 2>&1; then
 781         true
 782     else
 783         BSD_MAKEFILE=yes
 784         ap_make_include=.include
 785         ap_make_delimiter='"'
 786     fi
 787     ;;
 788 esac
 789 AC_SUBST(ap_make_include)
 790 AC_SUBST(ap_make_delimiter)
 791
 792 dnl Ensure that docs/conf is created.
 793 test -d docs/conf||$mkdir_p docs/conf
 794
 795 dnl Ensure that the httpd version is included
 796 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 797 AC_SUBST(HTTPD_VERSION)
 798
 799 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 800   APACHE_GEN_MAKEFILES
 801 ])