granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [11beta1], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CXX([$pgac_cxx_list])
 362
 363 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 364 # but has idiosyncrasies of its own.  We assume icc will define
 365 # __INTEL_COMPILER regardless of CFLAGS.
 366 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 367 choke me
 368 @%:@endif])], [ICC=yes], [ICC=no])
 369
 370 # Check if it's Sun Studio compiler. We assume that
 371 # __SUNPRO_C will be defined for Sun Studio compilers
 372 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 373 choke me
 374 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 375
 376 AC_SUBST(SUN_STUDIO_CC)
 377
 378
 379 #
 380 # LLVM
 381 #
 382 # Checked early because subsequent tests depend on it.
 383 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 384               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 385 AC_SUBST(with_llvm)
 386 if test "$with_llvm" = yes ; then
 387    PGAC_LLVM_SUPPORT()
 388 fi
 389
 390
 391 unset CFLAGS
 392 unset CXXFLAGS
 393
 394 #
 395 # Read the template
 396 #
 397 . "$srcdir/src/template/$template" || exit
 398
 399 # C[XX]FLAGS are selected so:
 400 # If the user specifies something in the environment, that is used.
 401 # else:  If the template file set something, that is used.
 402 # else:  If coverage was enabled, don't set anything.
 403 # else:  If the compiler is GCC, then we use -O2.
 404 # else:  If the compiler is something else, then we use -O, unless debugging.
 405
 406 if test "$ac_env_CFLAGS_set" = set; then
 407   CFLAGS=$ac_env_CFLAGS_value
 408 elif test "${CFLAGS+set}" = set; then
 409   : # (keep what template set)
 410 elif test "$enable_coverage" = yes; then
 411   : # no optimization by default
 412 elif test "$GCC" = yes; then
 413   CFLAGS="-O2"
 414 else
 415   # if the user selected debug mode, don't use -O
 416   if test "$enable_debug" != yes; then
 417     CFLAGS="-O"
 418   fi
 419 fi
 420
 421 if test "$ac_env_CXXFLAGS_set" = set; then
 422   CXXFLAGS=$ac_env_CXXFLAGS_value
 423 elif test "${CXXFLAGS+set}" = set; then
 424   : # (keep what template set)
 425 elif test "$enable_coverage" = yes; then
 426   : # no optimization by default
 427 elif test "$GCC" = yes; then
 428   CXXFLAGS="-O2"
 429 else
 430   # if the user selected debug mode, don't use -O
 431   if test "$enable_debug" != yes; then
 432     CXXFLAGS="-O"
 433   fi
 434 fi
 435
 436 # When generating bitcode (for inlining) we always want to use -O2
 437 # even when --enable-debug is specified. The bitcode it's not going to
 438 # be used for line-by-line debugging, and JIT inlining doesn't work
 439 # without at least -O1 (otherwise clang will emit 'noinline'
 440 # attributes everywhere), which is bad for testing.  Still allow the
 441 # environment to override if done explicitly.
 442 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 443   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 444 else
 445   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 446 fi
 447 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 448   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 449 else
 450   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 451 fi
 452
 453 # C[XX]FLAGS we determined above will be added back at the end
 454 user_CFLAGS=$CFLAGS
 455 CFLAGS=""
 456 user_CXXFLAGS=$CXXFLAGS
 457 CXXFLAGS=""
 458 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 459 BITCODE_CFLAGS=""
 460 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 461 BITCODE_CXXFLAGS=""
 462
 463 # set CFLAGS_VECTOR from the environment, if available
 464 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 465   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 466 fi
 467
 468 # Some versions of GCC support some additional useful warning flags.
 469 # Check whether they are supported, and add them to CFLAGS if so.
 470 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 471 # but has its own.  Also check other compiler-specific flags here.
 472
 473 if test "$GCC" = yes -a "$ICC" = no; then
 474   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 475   CXXFLAGS="-Wall -Wpointer-arith"
 476   # These work in some but not all gcc versions
 477   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 478   # -Wdeclaration-after-statement isn't applicable for C++
 479   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 480   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 481   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 482   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 483   # This was included in -Wall/-Wformat in older GCC versions
 484   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 485   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 486   # Disable strict-aliasing rules; needed for gcc 3.3+
 487   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 488   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 489   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 490   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 491   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 492   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 493   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 494   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 495   # Optimization flags for specific files that benefit from vectorization
 496   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 497   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 498   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 499   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 500   # test for the positive form and if that works, add the negative form
 501   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 502   if test -n "$NOT_THE_CFLAGS"; then
 503     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 504   fi
 505 elif test "$ICC" = yes; then
 506   # Intel's compiler has a bug/misoptimization in checking for
 507   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 508   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 509   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 510   # Make sure strict aliasing is off (though this is said to be the default)
 511   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 512   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 513 elif test "$PORTNAME" = "aix"; then
 514   # AIX's xlc has to have strict aliasing turned off too
 515   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 516   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 517   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 518   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 519 elif test "$PORTNAME" = "hpux"; then
 520   # On some versions of HP-UX, libm functions do not set errno by default.
 521   # Fix that by using +Olibmerrno if the compiler recognizes it.
 522   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 523   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 524 fi
 525
 526 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 527
 528 # Determine flags used to emit bitcode for JIT inlining. Need to test
 529 # for behaviour changing compiler flags, to keep compatibility with
 530 # compiler used for normal postgres code.
 531 if test "$with_llvm" = yes ; then
 532   CLANGXX="$CLANG -xc++"
 533
 534   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 535   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 536   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 537   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 538   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 539   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 540 fi
 541
 542 # supply -g if --enable-debug
 543 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 544   CFLAGS="$CFLAGS -g"
 545 fi
 546
 547 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 548   CXXFLAGS="$CXXFLAGS -g"
 549 fi
 550
 551 # enable code coverage if --enable-coverage
 552 if test "$enable_coverage" = yes; then
 553   if test "$GCC" = yes; then
 554     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 555     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 556   else
 557     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 558   fi
 559 fi
 560
 561 # enable profiling if --enable-profiling
 562 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 563   if test "$GCC" = yes; then
 564     AC_DEFINE([PROFILE_PID_DIR], 1,
 565            [Define to 1 to allow profiling output to be saved separately for each process.])
 566     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 567     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 568   else
 569     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 570   fi
 571 fi
 572
 573 # We already have this in Makefile.win32, but configure needs it too
 574 if test "$PORTNAME" = "win32"; then
 575   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 576 fi
 577
 578 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 579 # user-specified flags (if any) at the end.  This lets users override
 580 # the automatic additions.
 581 CFLAGS="$CFLAGS $user_CFLAGS"
 582 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 583 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 584 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 585
 586 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 587 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 588
 589 # Check if the compiler still works with the final flag settings
 590 # (note, we're not checking that for CXX, which is optional)
 591 AC_MSG_CHECKING([whether the C compiler still works])
 592 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 593   [AC_MSG_RESULT(yes)],
 594   [AC_MSG_RESULT(no)
 595    AC_MSG_ERROR([cannot proceed])])
 596
 597 # Defend against gcc -ffast-math
 598 if test "$GCC" = yes; then
 599 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 600 choke me
 601 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 602 fi
 603
 604 AC_PROG_CPP
 605 AC_SUBST(GCC)
 606
 607
 608 #
 609 # Set up TAS assembly code if needed; the template file has now had its
 610 # chance to request this.
 611 #
 612 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 613
 614 if test "$need_tas" = yes ; then
 615   TAS=tas.o
 616 else
 617   TAS=""
 618 fi
 619 AC_SUBST(TAS)
 620
 621
 622 #
 623 # Automatic dependency tracking
 624 #
 625 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 626               [autodepend=yes])
 627 AC_SUBST(autodepend)
 628
 629
 630 #
 631 # Enable assert checks
 632 #
 633 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 634               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 635                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 636
 637
 638 #
 639 # Include directories
 640 #
 641 ac_save_IFS=$IFS
 642 IFS="${IFS}${PATH_SEPARATOR}"
 643 # SRCH_INC comes from the template file
 644 for dir in $with_includes $SRCH_INC; do
 645   if test -d "$dir"; then
 646     INCLUDES="$INCLUDES -I$dir"
 647   else
 648     AC_MSG_WARN([*** Include directory $dir does not exist.])
 649   fi
 650 done
 651 IFS=$ac_save_IFS
 652 AC_SUBST(INCLUDES)
 653
 654
 655 #
 656 # Library directories
 657 #
 658 ac_save_IFS=$IFS
 659 IFS="${IFS}${PATH_SEPARATOR}"
 660 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 661 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 662   if test -d "$dir"; then
 663     LIBDIRS="$LIBDIRS -L$dir"
 664   else
 665     AC_MSG_WARN([*** Library directory $dir does not exist.])
 666   fi
 667 done
 668 IFS=$ac_save_IFS
 669
 670 #
 671 # Enable thread-safe client libraries
 672 #
 673 AC_MSG_CHECKING([allow thread-safe client libraries])
 674 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 675 if test "$enable_thread_safety" = yes; then
 676   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 677           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 678 fi
 679 AC_MSG_RESULT([$enable_thread_safety])
 680 AC_SUBST(enable_thread_safety)
 681
 682 #
 683 # ICU
 684 #
 685 AC_MSG_CHECKING([whether to build with ICU support])
 686 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 687               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 688 AC_MSG_RESULT([$with_icu])
 689 AC_SUBST(with_icu)
 690
 691 if test "$with_icu" = yes; then
 692   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 693 fi
 694
 695 #
 696 # Optionally build Tcl modules (PL/Tcl)
 697 #
 698 AC_MSG_CHECKING([whether to build with Tcl])
 699 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 700 AC_MSG_RESULT([$with_tcl])
 701 AC_SUBST([with_tcl])
 702
 703 # We see if the path to the Tcl/Tk configuration scripts is specified.
 704 # This will override the use of tclsh to find the paths to search.
 705
 706 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 707
 708 #
 709 # Optionally build Perl modules (PL/Perl)
 710 #
 711 AC_MSG_CHECKING([whether to build Perl modules])
 712 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 713 AC_MSG_RESULT([$with_perl])
 714 AC_SUBST(with_perl)
 715
 716 #
 717 # Optionally build Python modules (PL/Python)
 718 #
 719 AC_MSG_CHECKING([whether to build Python modules])
 720 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 721 AC_MSG_RESULT([$with_python])
 722 AC_SUBST(with_python)
 723
 724 #
 725 # GSSAPI
 726 #
 727 AC_MSG_CHECKING([whether to build with GSSAPI support])
 728 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 729 [
 730   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 731   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 732 ])
 733 AC_MSG_RESULT([$with_gssapi])
 734 AC_SUBST(with_gssapi)
 735
 736
 737 AC_SUBST(krb_srvtab)
 738
 739
 740 #
 741 # Kerberos configuration parameters
 742 #
 743 PGAC_ARG_REQ(with, krb-srvnam,
 744              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 745              [],
 746              [with_krb_srvnam="postgres"])
 747 AC_SUBST(with_krb_srvnam)
 748 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 749                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 750
 751
 752 #
 753 # PAM
 754 #
 755 AC_MSG_CHECKING([whether to build with PAM support])
 756 PGAC_ARG_BOOL(with, pam, no,
 757               [build with PAM support],
 758               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 759 AC_MSG_RESULT([$with_pam])
 760
 761
 762 #
 763 # BSD AUTH
 764 #
 765 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 766 PGAC_ARG_BOOL(with, bsd-auth, no,
 767               [build with BSD Authentication support],
 768               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 769 AC_MSG_RESULT([$with_bsd_auth])
 770
 771
 772 #
 773 # LDAP
 774 #
 775 AC_MSG_CHECKING([whether to build with LDAP support])
 776 PGAC_ARG_BOOL(with, ldap, no,
 777               [build with LDAP support],
 778               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 779 AC_MSG_RESULT([$with_ldap])
 780 AC_SUBST(with_ldap)
 781
 782
 783 #
 784 # Bonjour
 785 #
 786 AC_MSG_CHECKING([whether to build with Bonjour support])
 787 PGAC_ARG_BOOL(with, bonjour, no,
 788               [build with Bonjour support],
 789               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 790 AC_MSG_RESULT([$with_bonjour])
 791
 792
 793 #
 794 # OpenSSL
 795 #
 796 AC_MSG_CHECKING([whether to build with OpenSSL support])
 797 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 798               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 799 AC_MSG_RESULT([$with_openssl])
 800 AC_SUBST(with_openssl)
 801
 802 #
 803 # SELinux
 804 #
 805 AC_MSG_CHECKING([whether to build with SELinux support])
 806 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 807 AC_SUBST(with_selinux)
 808 AC_MSG_RESULT([$with_selinux])
 809
 810 #
 811 # Systemd
 812 #
 813 AC_MSG_CHECKING([whether to build with systemd support])
 814 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 815               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 816 AC_SUBST(with_systemd)
 817 AC_MSG_RESULT([$with_systemd])
 818
 819 #
 820 # Readline
 821 #
 822 PGAC_ARG_BOOL(with, readline, yes,
 823               [do not use GNU Readline nor BSD Libedit for editing])
 824 # readline on MinGW has problems with backslashes in psql and other bugs.
 825 # This is particularly a problem with non-US code pages.
 826 # Therefore disable its use until we understand the cause. 2004-07-20
 827 if test "$PORTNAME" = "win32"; then
 828   if test "$with_readline" = yes; then
 829     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 830     with_readline=no
 831   fi
 832 fi
 833
 834
 835 #
 836 # Prefer libedit
 837 #
 838 PGAC_ARG_BOOL(with, libedit-preferred, no,
 839               [prefer BSD Libedit over GNU Readline])
 840
 841
 842 #
 843 # UUID library
 844 #
 845 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 846 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 847 # UUID library.  More than one of these might be present on a given platform,
 848 # so we make the user say which one she wants.
 849 #
 850 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 851 if test x"$with_uuid" = x"" ; then
 852   with_uuid=no
 853 fi
 854 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 855 if test "$with_ossp_uuid" = yes ; then
 856   with_uuid=ossp
 857 fi
 858
 859 if test "$with_uuid" = bsd ; then
 860   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 861   UUID_EXTRA_OBJS="md5.o sha1.o"
 862 elif test "$with_uuid" = e2fs ; then
 863   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 864   UUID_EXTRA_OBJS="md5.o sha1.o"
 865 elif test "$with_uuid" = ossp ; then
 866   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 867   UUID_EXTRA_OBJS=""
 868 elif test "$with_uuid" = no ; then
 869   UUID_EXTRA_OBJS=""
 870 else
 871   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 872 fi
 873 AC_SUBST(with_uuid)
 874 AC_SUBST(UUID_EXTRA_OBJS)
 875
 876
 877 #
 878 # XML
 879 #
 880 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 881               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 882
 883 if test "$with_libxml" = yes ; then
 884   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 885   if test -n "$XML2_CONFIG"; then
 886     for pgac_option in `$XML2_CONFIG --cflags`; do
 887       case $pgac_option in
 888         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 889       esac
 890     done
 891     for pgac_option in `$XML2_CONFIG --libs`; do
 892       case $pgac_option in
 893         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 894       esac
 895     done
 896   fi
 897 fi
 898
 899 AC_SUBST(with_libxml)
 900
 901 #
 902 # XSLT
 903 #
 904 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 905               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 906
 907
 908 AC_SUBST(with_libxslt)
 909
 910 #
 911 # tzdata
 912 #
 913 PGAC_ARG_REQ(with, system-tzdata,
 914              [DIR], [use system time zone data in DIR])
 915 AC_SUBST(with_system_tzdata)
 916
 917 #
 918 # Zlib
 919 #
 920 PGAC_ARG_BOOL(with, zlib, yes,
 921               [do not use Zlib])
 922 AC_SUBST(with_zlib)
 923
 924 #
 925 # Elf
 926 #
 927
 928 # Assume system is ELF if it predefines __ELF__ as 1,
 929 # otherwise believe host_os based default.
 930 case $host_os in
 931     freebsd1*|freebsd2*) elf=no;;
 932     freebsd3*|freebsd4*) elf=yes;;
 933 esac
 934
 935 AC_EGREP_CPP(yes,
 936 [#if __ELF__
 937   yes
 938 #endif
 939 ],
 940 [ELF_SYS=true],
 941 [if test "X$elf" = "Xyes" ; then
 942   ELF_SYS=true
 943 else
 944   ELF_SYS=
 945 fi])
 946 AC_SUBST(ELF_SYS)
 947
 948 #
 949 # Assignments
 950 #
 951
 952 CPPFLAGS="$CPPFLAGS $INCLUDES"
 953 LDFLAGS="$LDFLAGS $LIBDIRS"
 954
 955 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 956 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 957
 958 PGAC_PROG_LD
 959 AC_SUBST(LD)
 960 AC_SUBST(with_gnu_ld)
 961 AC_PROG_RANLIB
 962 PGAC_CHECK_STRIP
 963 AC_CHECK_TOOL(AR, ar, ar)
 964 if test "$PORTNAME" = "win32"; then
 965   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 966   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 967   AC_CHECK_TOOL(WINDRES, windres, windres)
 968 fi
 969
 970 AC_PROG_INSTALL
 971 # When Autoconf chooses install-sh as install program it tries to generate
 972 # a relative path to it in each makefile where it substitutes it. This clashes
 973 # with our Makefile.global concept. This workaround helps.
 974 case $INSTALL in
 975   *install-sh*) install_bin='';;
 976   *) install_bin=$INSTALL;;
 977 esac
 978 AC_SUBST(install_bin)
 979
 980 PGAC_PATH_PROGS(TAR, tar)
 981 AC_PROG_LN_S
 982 AC_PROG_AWK
 983 AC_PROG_MKDIR_P
 984 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 985 # a relative path to it in each makefile where it substitutes it. This clashes
 986 # with our Makefile.global concept. This workaround helps.
 987 case $MKDIR_P in
 988   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 989 esac
 990
 991 PGAC_PATH_BISON
 992 PGAC_PATH_FLEX
 993
 994 PGAC_PATH_PERL
 995 if test "$with_perl" = yes; then
 996   if test -z "$PERL"; then
 997     AC_MSG_ERROR([Perl not found])
 998   fi
 999   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1000   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1001     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1002 You might have to rebuild your Perl installation.  Refer to the
1003 documentation for details.  Use --without-perl to disable building
1004 PL/Perl.])
1005   fi
1006   PGAC_CHECK_PERL_EMBED_CCFLAGS
1007   PGAC_CHECK_PERL_EMBED_LDFLAGS
1008 fi
1009
1010 if test "$with_python" = yes; then
1011   PGAC_PATH_PYTHON
1012   PGAC_CHECK_PYTHON_EMBED_SETUP
1013 fi
1014
1015 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1016   PGAC_PATH_PROGS(ZIC, zic)
1017   if test -z "$ZIC"; then
1018     AC_MSG_ERROR([
1019 When cross-compiling, either use the option --with-system-tzdata to use
1020 existing time-zone data, or set the environment variable ZIC to a zic
1021 program to use during the build.])
1022   fi
1023 fi
1024
1025 #
1026 # Pthreads
1027 #
1028 # For each platform, we need to know about any special compile and link
1029 # libraries, and whether the normal C function names are thread-safe.
1030 # See the comment at the top of src/port/thread.c for more information.
1031 # WIN32 doesn't need the pthread tests;  it always uses threads
1032 #
1033 # These tests are run before the library-tests, because linking with the
1034 # other libraries can pull in the pthread functions as a side-effect.  We
1035 # want to use the -pthread or similar flags directly, and not rely on
1036 # the side-effects of linking with some other library.
1037 #
1038 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1039 # invocation below is the first one in the script, and autoconf generates
1040 # additional code for that, which must not be inside the if-block. AS_IF
1041 # knows how to do that.
1042 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1043 [ # then
1044 AX_PTHREAD      # set thread flags
1045
1046 # Some platforms use these, so just define them.  They can't hurt if they
1047 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1048 # enables 5-arg getpwuid_r, among other things.
1049 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1050
1051 # Check for *_r functions
1052 _CFLAGS="$CFLAGS"
1053 _LIBS="$LIBS"
1054 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1055 LIBS="$LIBS $PTHREAD_LIBS"
1056
1057 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1058 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1059
1060 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1061
1062 # Do test here with the proper thread flags
1063 PGAC_FUNC_STRERROR_R_INT
1064
1065 CFLAGS="$_CFLAGS"
1066 LIBS="$_LIBS"
1067
1068 ], [ # else
1069 # do not use values from template file
1070 PTHREAD_CFLAGS=
1071 PTHREAD_LIBS=
1072 ]) # fi
1073
1074 AC_SUBST(PTHREAD_CFLAGS)
1075 AC_SUBST(PTHREAD_LIBS)
1076
1077
1078 ##
1079 ## Libraries
1080 ##
1081 ## Most libraries are included only if they demonstrably provide a function
1082 ## we need, but libm is an exception: always include it, because there are
1083 ## too many compilers that play cute optimization games that will break
1084 ## probes for standard functions such as pow().
1085 ##
1086
1087 AC_CHECK_LIB(m, main)
1088 AC_SEARCH_LIBS(setproctitle, util)
1089 AC_SEARCH_LIBS(dlopen, dl)
1090 AC_SEARCH_LIBS(socket, [socket ws2_32])
1091 AC_SEARCH_LIBS(shl_load, dld)
1092 # We only use libld in port/dynloader/aix.c
1093 case $host_os in
1094      aix*)
1095         AC_SEARCH_LIBS(ldopen, ld)
1096         ;;
1097 esac
1098 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1099 AC_SEARCH_LIBS(crypt, crypt)
1100 AC_SEARCH_LIBS(shm_open, rt)
1101 AC_SEARCH_LIBS(shm_unlink, rt)
1102 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1103 # Solaris:
1104 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1105 # Required for thread_test.c on Solaris
1106 AC_SEARCH_LIBS(sched_yield, rt)
1107 # Required for thread_test.c on Solaris 2.5:
1108 # Other ports use it too (HP-UX) so test unconditionally
1109 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1110 # Cygwin:
1111 AC_SEARCH_LIBS(shmget, cygipc)
1112
1113 if test "$with_readline" = yes; then
1114   PGAC_CHECK_READLINE
1115   if test x"$pgac_cv_check_readline" = x"no"; then
1116     AC_MSG_ERROR([readline library not found
1117 If you have readline already installed, see config.log for details on the
1118 failure.  It is possible the compiler isn't looking in the proper directory.
1119 Use --without-readline to disable readline support.])
1120   fi
1121 fi
1122
1123 if test "$with_zlib" = yes; then
1124   AC_CHECK_LIB(z, inflate, [],
1125                [AC_MSG_ERROR([zlib library not found
1126 If you have zlib already installed, see config.log for details on the
1127 failure.  It is possible the compiler isn't looking in the proper directory.
1128 Use --without-zlib to disable zlib support.])])
1129 fi
1130
1131 if test "$enable_spinlocks" = yes; then
1132   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1133 else
1134   AC_MSG_WARN([
1135 *** Not using spinlocks will cause poor performance.])
1136 fi
1137
1138 if test "$enable_atomics" = yes; then
1139   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1140 else
1141   AC_MSG_WARN([
1142 *** Not using atomic operations will cause poor performance.])
1143 fi
1144
1145 if test "$with_gssapi" = yes ; then
1146   if test "$PORTNAME" != "win32"; then
1147     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1148                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1149   else
1150     LIBS="$LIBS -lgssapi32"
1151   fi
1152 fi
1153
1154 if test "$with_openssl" = yes ; then
1155   dnl Order matters!
1156   if test "$PORTNAME" != "win32"; then
1157      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1158      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1159   else
1160      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1161      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1162   fi
1163   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1164   # Functions introduced in OpenSSL 1.1.0. We used to check for
1165   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1166   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1167   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1168   # functions.
1169   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1170   # OpenSSL versions before 1.1.0 required setting callback functions, for
1171   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1172   # function was removed.
1173   AC_CHECK_FUNCS([CRYPTO_lock])
1174 fi
1175
1176 if test "$with_pam" = yes ; then
1177   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1178 fi
1179
1180 if test "$with_libxml" = yes ; then
1181   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1182 fi
1183
1184 if test "$with_libxslt" = yes ; then
1185   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1186 fi
1187
1188 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1189 if test "$with_ldap" = yes ; then
1190   _LIBS="$LIBS"
1191   if test "$PORTNAME" != "win32"; then
1192     AC_CHECK_LIB(ldap, ldap_bind, [],
1193                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1194                  [$EXTRA_LDAP_LIBS])
1195     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1196     if test "$enable_thread_safety" = yes; then
1197       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1198       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1199                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1200                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1201       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1202     else
1203       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1204     fi
1205     AC_CHECK_FUNCS([ldap_initialize])
1206   else
1207     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1208     LDAP_LIBS_FE="-lwldap32"
1209     LDAP_LIBS_BE="-lwldap32"
1210   fi
1211   LIBS="$_LIBS"
1212 fi
1213 AC_SUBST(LDAP_LIBS_FE)
1214 AC_SUBST(LDAP_LIBS_BE)
1215
1216 # for contrib/sepgsql
1217 if test "$with_selinux" = yes; then
1218   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1219                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1220 fi
1221
1222 # for contrib/uuid-ossp
1223 if test "$with_uuid" = bsd ; then
1224   # On BSD, the UUID functions are in libc
1225   AC_CHECK_FUNC(uuid_to_string,
1226     [UUID_LIBS=""],
1227     [AC_MSG_ERROR([BSD UUID functions are not present])])
1228 elif test "$with_uuid" = e2fs ; then
1229   # On macOS, the UUID functions are in libc
1230   AC_CHECK_FUNC(uuid_generate,
1231     [UUID_LIBS=""],
1232     [AC_CHECK_LIB(uuid, uuid_generate,
1233       [UUID_LIBS="-luuid"],
1234       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1235 elif test "$with_uuid" = ossp ; then
1236   AC_CHECK_LIB(ossp-uuid, uuid_export,
1237     [UUID_LIBS="-lossp-uuid"],
1238     [AC_CHECK_LIB(uuid, uuid_export,
1239       [UUID_LIBS="-luuid"],
1240       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1241 fi
1242 AC_SUBST(UUID_LIBS)
1243
1244
1245 ##
1246 ## Header files
1247 ##
1248
1249 AC_HEADER_STDBOOL
1250
1251 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1252
1253 # On BSD, test for net/if.h will fail unless sys/socket.h
1254 # is included first.
1255 AC_CHECK_HEADERS(net/if.h, [], [],
1256 [AC_INCLUDES_DEFAULT
1257 #include <sys/socket.h>
1258 ])
1259
1260 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1261 # is included first.
1262 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1263 [AC_INCLUDES_DEFAULT
1264 #include <sys/param.h>
1265 ])
1266
1267 # At least on IRIX, test for netinet/tcp.h will fail unless
1268 # netinet/in.h is included first.
1269 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1270 [AC_INCLUDES_DEFAULT
1271 #include <netinet/in.h>
1272 ])
1273
1274 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1275   AC_CHECK_HEADERS(readline/readline.h, [],
1276         [AC_CHECK_HEADERS(readline.h, [],
1277                 [AC_MSG_ERROR([readline header not found
1278 If you have readline already installed, see config.log for details on the
1279 failure.  It is possible the compiler isn't looking in the proper directory.
1280 Use --without-readline to disable readline support.])])])
1281   AC_CHECK_HEADERS(readline/history.h, [],
1282         [AC_CHECK_HEADERS(history.h, [],
1283                 [AC_MSG_ERROR([history header not found
1284 If you have readline already installed, see config.log for details on the
1285 failure.  It is possible the compiler isn't looking in the proper directory.
1286 Use --without-readline to disable readline support.])])])
1287 fi
1288
1289 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1290 # Some installations of libedit usurp /usr/include/readline/, which seems
1291 # bad practice, since in combined installations readline will have its headers
1292 # there.  We might have to resort to AC_EGREP checks to make sure we found
1293 # the proper header...
1294   AC_CHECK_HEADERS(editline/readline.h, [],
1295         [AC_CHECK_HEADERS(readline.h, [],
1296                 [AC_CHECK_HEADERS(readline/readline.h, [],
1297                         [AC_MSG_ERROR([readline header not found
1298 If you have libedit already installed, see config.log for details on the
1299 failure.  It is possible the compiler isn't looking in the proper directory.
1300 Use --without-readline to disable libedit support.])])])])
1301 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1302 # not be there at all.  Hence, don't complain if not found.  We must check
1303 # though, since in yet other versions it is an independent header.
1304   AC_CHECK_HEADERS(editline/history.h, [],
1305         [AC_CHECK_HEADERS(history.h, [],
1306                 [AC_CHECK_HEADERS(readline/history.h)])])
1307 fi
1308
1309 if test "$with_zlib" = yes; then
1310   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1311 If you have zlib already installed, see config.log for details on the
1312 failure.  It is possible the compiler isn't looking in the proper directory.
1313 Use --without-zlib to disable zlib support.])])
1314 fi
1315
1316 if test "$with_gssapi" = yes ; then
1317   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1318         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1319 fi
1320
1321 if test "$with_openssl" = yes ; then
1322   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1323   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1324 fi
1325
1326 if test "$with_pam" = yes ; then
1327   AC_CHECK_HEADERS(security/pam_appl.h, [],
1328                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1329                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1330 fi
1331
1332 if test "$with_bsd_auth" = yes ; then
1333   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1334 fi
1335
1336 if test "$with_systemd" = yes ; then
1337   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1338 fi
1339
1340 if test "$with_libxml" = yes ; then
1341   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1342 fi
1343
1344 if test "$with_libxslt" = yes ; then
1345   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1346 fi
1347
1348 if test "$with_ldap" = yes ; then
1349   if test "$PORTNAME" != "win32"; then
1350      AC_CHECK_HEADERS(ldap.h, [],
1351                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1352      PGAC_LDAP_SAFE
1353   else
1354      AC_CHECK_HEADERS(winldap.h, [],
1355                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1356                       [AC_INCLUDES_DEFAULT
1357 #include <windows.h>
1358                       ])
1359   fi
1360 fi
1361
1362 if test "$with_bonjour" = yes ; then
1363   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1364 dnl At some point we might add something like
1365 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1366 dnl but right now, what that would mainly accomplish is to encourage
1367 dnl people to try to use the avahi implementation, which does not work.
1368 dnl If you want to use Apple's own Bonjour code on another platform,
1369 dnl just add -ldns_sd to LIBS manually.
1370 fi
1371
1372 # for contrib/uuid-ossp
1373 if test "$with_uuid" = bsd ; then
1374   AC_CHECK_HEADERS(uuid.h,
1375     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1376       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1377     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1378 elif test "$with_uuid" = e2fs ; then
1379   AC_CHECK_HEADERS(uuid/uuid.h,
1380     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1381       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1382     [AC_CHECK_HEADERS(uuid.h,
1383       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1384         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1385       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1386 elif test "$with_uuid" = ossp ; then
1387   AC_CHECK_HEADERS(ossp/uuid.h,
1388     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1389       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1390     [AC_CHECK_HEADERS(uuid.h,
1391       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1392         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1393       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1394 fi
1395
1396 if test "$PORTNAME" = "win32" ; then
1397    AC_CHECK_HEADERS(crtdefs.h)
1398 fi
1399
1400 ##
1401 ## Types, structures, compiler characteristics
1402 ##
1403
1404 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1405 AC_C_BIGENDIAN
1406 AC_C_INLINE
1407 PGAC_PRINTF_ARCHETYPE
1408 AC_C_FLEXIBLE_ARRAY_MEMBER
1409 PGAC_C_SIGNED
1410 PGAC_C_FUNCNAME_SUPPORT
1411 PGAC_C_STATIC_ASSERT
1412 PGAC_C_TYPEOF
1413 PGAC_C_TYPES_COMPATIBLE
1414 PGAC_C_BUILTIN_BSWAP16
1415 PGAC_C_BUILTIN_BSWAP32
1416 PGAC_C_BUILTIN_BSWAP64
1417 PGAC_C_BUILTIN_CONSTANT_P
1418 PGAC_C_BUILTIN_UNREACHABLE
1419 PGAC_C_COMPUTED_GOTO
1420 PGAC_C_VA_ARGS
1421 PGAC_STRUCT_TIMEZONE
1422 PGAC_UNION_SEMUN
1423 PGAC_STRUCT_SOCKADDR_UN
1424 PGAC_STRUCT_SOCKADDR_STORAGE
1425 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1426 PGAC_STRUCT_ADDRINFO
1427 AC_TYPE_INTPTR_T
1428 AC_TYPE_UINTPTR_T
1429 AC_TYPE_LONG_LONG_INT
1430
1431 PGAC_TYPE_LOCALE_T
1432
1433 # MSVC doesn't cope well with defining restrict to __restrict, the
1434 # spelling it understands, because it conflicts with
1435 # __declspec(restrict). Therefore we define pg_restrict to the
1436 # appropriate definition, which presumably won't conflict.
1437 #
1438 # Allow platforms with buggy compilers to force restrict to not be
1439 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1440 # template.
1441 AC_C_RESTRICT
1442 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1443   pg_restrict=""
1444 else
1445   pg_restrict="$ac_cv_c_restrict"
1446 fi
1447 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1448 [Define to keyword to use for C99 restrict support, or to nothing if not
1449 supported])
1450
1451 AC_CHECK_TYPES([struct cmsgcred], [], [],
1452 [#include <sys/socket.h>
1453 #include <sys/param.h>
1454 #ifdef HAVE_SYS_UCRED_H
1455 #include <sys/ucred.h>
1456 #endif])
1457
1458 AC_CHECK_TYPES([struct option], [], [],
1459 [#ifdef HAVE_GETOPT_H
1460 #include <getopt.h>
1461 #endif])
1462
1463 if test "$with_zlib" = yes; then
1464   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1465   # did not).  While we could work around the lack of z_streamp, it
1466   # seems unwise to encourage people to use such old zlib versions...
1467   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1468 Use --without-zlib to disable zlib support.])],
1469                 [#include <zlib.h>])
1470 fi
1471
1472 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1473 case $host_cpu in
1474   ppc*|powerpc*)
1475     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1476     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1477         [int a = 0; int *p = &a; int r;
1478          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1479         [pgac_cv_have_ppc_mutex_hint=yes],
1480         [pgac_cv_have_ppc_mutex_hint=no])
1481     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1482     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1483         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1484     fi
1485   ;;
1486 esac
1487
1488 # Check largefile support.  You might think this is a system service not a
1489 # compiler characteristic, but you'd be wrong.  We must check this before
1490 # probing existence of related functions such as fseeko, since the largefile
1491 # defines can affect what is generated for that.
1492 if test "$PORTNAME" != "win32"; then
1493    AC_SYS_LARGEFILE
1494    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1495    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1496    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1497    dnl versions where the feature actually works, it's on by default anyway.
1498    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1499 fi
1500
1501 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1502 AC_CHECK_SIZEOF([off_t])
1503
1504 # If we don't have largefile support, can't handle segsize >= 2GB.
1505 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1506    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1507 fi
1508
1509 AC_CHECK_SIZEOF([bool], [],
1510 [#ifdef HAVE_STDBOOL_H
1511 #include <stdbool.h>
1512 #endif])
1513
1514
1515 ##
1516 ## Functions, global variables
1517 ##
1518
1519 PGAC_VAR_INT_TIMEZONE
1520 AC_FUNC_ACCEPT_ARGTYPES
1521 PGAC_FUNC_GETTIMEOFDAY_1ARG
1522 PGAC_FUNC_WCSTOMBS_L
1523
1524 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1525 # symbols that that library has no business exposing to the world.  Pending
1526 # acquisition of a clue by those developers, ignore libedit (including its
1527 # possible alias of libreadline) while checking for everything else.
1528 LIBS_including_readline="$LIBS"
1529 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1530
1531 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1532
1533 AC_REPLACE_FUNCS(fseeko)
1534 case $host_os in
1535         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1536         # Mingw uses macros to access Win32 API calls
1537         netbsd*|mingw*)
1538                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1539                 ac_cv_func_fseeko=yes;;
1540         *)
1541                 AC_FUNC_FSEEKO;;
1542 esac
1543
1544 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1545 # by calling it, 2009-04-02
1546 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1547 if test "$PORTNAME" != "solaris"; then
1548 AC_CHECK_FUNCS(posix_fadvise)
1549 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1550 fi
1551
1552 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1553 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1554 # This is probably only present on macOS, but may as well check always
1555 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1556
1557 HAVE_IPV6=no
1558 AC_CHECK_TYPE([struct sockaddr_in6],
1559         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1560          HAVE_IPV6=yes],
1561         [],
1562 [$ac_includes_default
1563 #include <netinet/in.h>])
1564 AC_SUBST(HAVE_IPV6)
1565
1566 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1567 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1568 [#include <machine/vmparam.h>
1569 #include <sys/exec.h>
1570 ],
1571 [PS_STRINGS->ps_nargvstr = 1;
1572 PS_STRINGS->ps_argvstr = "foo";])],
1573 [pgac_cv_var_PS_STRINGS=yes],
1574 [pgac_cv_var_PS_STRINGS=no])])
1575 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1576   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1577 fi
1578
1579
1580 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1581 # is missing.  Yes, there are machines that have only one.  We may
1582 # also decide to use snprintf.c if snprintf() is present but does not
1583 # have all the features we need --- see below.
1584
1585 if test "$PORTNAME" = "win32"; then
1586   # Win32 gets snprintf.c built unconditionally.
1587   #
1588   # To properly translate all NLS languages strings, we must support the
1589   # *printf() %$ format, which allows *printf() arguments to be selected
1590   # by position in the translated string.
1591   #
1592   # libintl versions < 0.13 use the native *printf() functions, and Win32
1593   # *printf() doesn't understand %$, so we must use our /port versions,
1594   # which do understand %$. libintl versions >= 0.13 include their own
1595   # *printf versions on Win32.  The libintl 0.13 release note text is:
1596   #
1597   #   C format strings with positions, as they arise when a translator
1598   #   needs to reorder a sentence, are now supported on all platforms.
1599   #   On those few platforms (NetBSD and Woe32) for which the native
1600   #   printf()/fprintf()/... functions don't support such format
1601   #   strings, replacements are provided through <libintl.h>.
1602   #
1603   # We could use libintl >= 0.13's *printf() if we were sure that we had
1604   # a libintl >= 0.13 at runtime, but seeing that there is no clean way
1605   # to guarantee that, it is best to just use our own, so we are sure to
1606   # get %$ support. In include/port.h we disable the *printf() macros
1607   # that might have been defined by libintl.
1608   #
1609   # We do this unconditionally whether NLS is used or not so we are sure
1610   # that all Win32 libraries and binaries behave the same.
1611   pgac_need_repl_snprintf=yes
1612 else
1613   pgac_need_repl_snprintf=no
1614   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1615   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1616 fi
1617
1618
1619 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1620 # include/c.h will provide declarations.  Note this is a separate test
1621 # from whether the functions exist in the C library --- there are
1622 # systems that have the functions but don't bother to declare them :-(
1623
1624 AC_CHECK_DECLS([snprintf, vsnprintf])
1625
1626
1627 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1628 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1629 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1630 #include <math.h>
1631 double glob_double;
1632 ],
1633 [return isinf(glob_double) ? 0 : 1;])],
1634 [ac_cv_func_isinf=yes],
1635 [ac_cv_func_isinf=no])])
1636
1637 if test $ac_cv_func_isinf = yes ; then
1638   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1639 else
1640   AC_LIBOBJ(isinf)
1641   # Look for a way to implement a substitute for isinf()
1642   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1643 fi
1644
1645 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1646
1647 case $host_os in
1648
1649         # Windows uses a specialised env handler
1650         # and doesn't need a replacement getpeereid because it doesn't use
1651         # Unix sockets.
1652         mingw*)
1653                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1654                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1655                 ac_cv_func_unsetenv=yes
1656                 ac_cv_func_getpeereid=yes;;
1657         *)
1658                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1659                 ;;
1660 esac
1661
1662 # System's version of getaddrinfo(), if any, may be used only if we found
1663 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1664 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1665 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1666    test "$PORTNAME" != "win32"; then
1667   AC_REPLACE_FUNCS([getaddrinfo])
1668 else
1669   AC_LIBOBJ(getaddrinfo)
1670 fi
1671
1672 # Similarly, use system's getopt_long() only if system provides struct option.
1673 if test x"$ac_cv_type_struct_option" = xyes ; then
1674   AC_REPLACE_FUNCS([getopt_long])
1675 else
1676   AC_LIBOBJ(getopt_long)
1677 fi
1678
1679 # Solaris' getopt() doesn't do what we want for long options, so always use
1680 # our version on that platform.
1681 if test "$PORTNAME" = "solaris"; then
1682   AC_LIBOBJ(getopt)
1683 fi
1684
1685 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1686 # so always use our version on Windows.
1687 if test "$PORTNAME" = "win32"; then
1688   AC_LIBOBJ(getopt)
1689   AC_LIBOBJ(getopt_long)
1690 fi
1691
1692 # Win32 (really MinGW) support
1693 if test "$PORTNAME" = "win32"; then
1694   AC_REPLACE_FUNCS(gettimeofday)
1695   AC_LIBOBJ(dirmod)
1696   AC_LIBOBJ(kill)
1697   AC_LIBOBJ(open)
1698   AC_LIBOBJ(system)
1699   AC_LIBOBJ(win32env)
1700   AC_LIBOBJ(win32error)
1701   AC_LIBOBJ(win32security)
1702   AC_LIBOBJ(win32setlocale)
1703   AC_DEFINE([HAVE_SYMLINK], 1,
1704             [Define to 1 if you have the `symlink' function.])
1705   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1706 #define WIN32_LEAN_AND_MEAN
1707 #include <windows.h>
1708 #include <string.h>
1709 #include <dbghelp.h>])
1710 fi
1711 if test x"$pgac_minidump_type" = x"yes" ; then
1712   AC_SUBST(have_win32_dbghelp,yes)
1713 else
1714   AC_SUBST(have_win32_dbghelp,no)
1715 fi
1716
1717 # Cygwin needs only a bit of that
1718 if test "$PORTNAME" = "cygwin"; then
1719   AC_LIBOBJ(dirmod)
1720 fi
1721
1722 AC_CHECK_DECLS([sys_siglist], [], [],
1723 [#include <signal.h>
1724 /* NetBSD declares sys_siglist in unistd.h.  */
1725 #ifdef HAVE_UNISTD_H
1726 # include <unistd.h>
1727 #endif
1728 ])
1729
1730 AC_CHECK_FUNC(syslog,
1731               [AC_CHECK_HEADER(syslog.h,
1732                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1733
1734 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1735 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1736   [extern int opterr; opterr = 1;])],
1737   [pgac_cv_var_int_opterr=yes],
1738   [pgac_cv_var_int_opterr=no])])
1739 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1740   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1741 fi
1742
1743 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1744 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1745   [extern int optreset; optreset = 1;])],
1746   [pgac_cv_var_int_optreset=yes],
1747   [pgac_cv_var_int_optreset=no])])
1748 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1749   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1750 fi
1751
1752 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1753 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1754 # strto[u]ll may exist but not be declared
1755 AC_CHECK_DECLS([strtoll, strtoull])
1756
1757 if test "$with_icu" = yes; then
1758   ac_save_CPPFLAGS=$CPPFLAGS
1759   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1760
1761   # Verify we have ICU's header files
1762   AC_CHECK_HEADER(unicode/ucol.h, [],
1763         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1764
1765   CPPFLAGS=$ac_save_CPPFLAGS
1766 fi
1767
1768 # Lastly, restore full LIBS list and check for readline/libedit symbols
1769 LIBS="$LIBS_including_readline"
1770
1771 if test "$with_readline" = yes; then
1772   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1773   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1774   AC_CHECK_FUNCS([append_history history_truncate_file])
1775 fi
1776
1777
1778 # This test makes sure that run tests work at all.  Sometimes a shared
1779 # library is found by the linker, but the runtime linker can't find it.
1780 # This check should come after all modifications of compiler or linker
1781 # variables, and before any other run tests.
1782 AC_MSG_CHECKING([test program])
1783 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1784 [AC_MSG_RESULT(ok)],
1785 [AC_MSG_RESULT(failed)
1786 AC_MSG_ERROR([[
1787 Could not execute a simple test program.  This may be a problem
1788 related to locating shared libraries.  Check the file 'config.log'
1789 for the exact reason.]])],
1790 [AC_MSG_RESULT([cross-compiling])])
1791
1792 # --------------------
1793 # Run tests below here
1794 # --------------------
1795
1796 # Force use of our snprintf if system's doesn't do arg control
1797 # See comment above at snprintf test for details.
1798 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1799   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1800   if test $pgac_cv_snprintf_arg_control != yes ; then
1801     pgac_need_repl_snprintf=yes
1802   fi
1803 fi
1804
1805
1806 dnl Check to see if we have a working 64-bit integer type.
1807 dnl Since Postgres 8.4, we no longer support compilers without a working
1808 dnl 64-bit type; but we have to determine whether that type is called
1809 dnl "long int" or "long long int".
1810
1811 PGAC_TYPE_64BIT_INT([long int])
1812
1813 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1814   pg_int64_type="long int"
1815 else
1816   PGAC_TYPE_64BIT_INT([long long int])
1817   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1818     pg_int64_type="long long int"
1819   else
1820     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1821   fi
1822 fi
1823
1824 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1825   [Define to the name of a signed 64-bit integer type.])
1826
1827 # Select the printf length modifier that goes with that, too.
1828 # (This used to be bound up with replacement-snprintf selection, but now
1829 # we assume that the native *printf functions use standard length modifiers.)
1830 if test x"$pg_int64_type" = x"long long int" ; then
1831   INT64_MODIFIER='"ll"'
1832 else
1833   INT64_MODIFIER='"l"'
1834 fi
1835
1836 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1837                    [Define to the appropriate printf length modifier for 64-bit ints.])
1838
1839 # Force use of our snprintf if the system's doesn't support the %z flag.
1840 # (Note this test uses PG_INT64_TYPE and INT64_MODIFIER.)
1841 if test "$pgac_need_repl_snprintf" = no; then
1842   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1843   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1844     pgac_need_repl_snprintf=yes
1845   fi
1846 fi
1847
1848 # Now we have checked all the reasons to replace snprintf
1849 if test $pgac_need_repl_snprintf = yes; then
1850   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1851   AC_LIBOBJ(snprintf)
1852 fi
1853
1854 # has to be down here, rather than with the other builtins, because
1855 # the test uses PG_INT64_TYPE.
1856 PGAC_C_BUILTIN_OP_OVERFLOW
1857
1858 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1859 AC_CHECK_SIZEOF([void *])
1860 AC_CHECK_SIZEOF([size_t])
1861 AC_CHECK_SIZEOF([long])
1862
1863 # Decide whether float4 is passed by value: user-selectable, enabled by default
1864 AC_MSG_CHECKING([whether to build with float4 passed by value])
1865 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1866               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1867                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1868                float4passbyval=true],
1869               [float4passbyval=false])
1870 AC_MSG_RESULT([$enable_float4_byval])
1871 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1872
1873 # Decide whether float8 is passed by value.
1874 # Note: this setting also controls int8 and related types such as timestamp.
1875 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1876 # If not, trying to select it is an error.
1877 AC_MSG_CHECKING([whether to build with float8 passed by value])
1878 if test $ac_cv_sizeof_void_p -ge 8 ; then
1879   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1880 else
1881   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1882   if test "$enable_float8_byval" = yes ; then
1883     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1884   fi
1885 fi
1886 if test "$enable_float8_byval" = yes ; then
1887   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1888             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1889   float8passbyval=true
1890 else
1891   float8passbyval=false
1892 fi
1893 AC_MSG_RESULT([$enable_float8_byval])
1894 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1895
1896 # Determine memory alignment requirements for the basic C data types.
1897
1898 AC_CHECK_ALIGNOF(short)
1899 AC_CHECK_ALIGNOF(int)
1900 AC_CHECK_ALIGNOF(long)
1901 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1902   AC_CHECK_ALIGNOF(long long int)
1903 fi
1904 AC_CHECK_ALIGNOF(double)
1905
1906 # Compute maximum alignment of any basic type.
1907 # We assume long's alignment is at least as strong as char, short, or int;
1908 # but we must check long long (if it is being used for int64) and double.
1909 # Note that we intentionally do not consider any types wider than 64 bits,
1910 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1911 # for disk and memory space.
1912
1913 MAX_ALIGNOF=$ac_cv_alignof_long
1914 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1915   MAX_ALIGNOF=$ac_cv_alignof_double
1916 fi
1917 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1918   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1919 fi
1920 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1921
1922
1923 # Some platforms predefine the types int8, int16, etc.  Only check
1924 # a (hopefully) representative subset.
1925 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1926 [#include <stdio.h>])
1927
1928 # Some compilers offer a 128-bit integer scalar type.
1929 PGAC_TYPE_128BIT_INT
1930
1931 # Check for various atomic operations now that we have checked how to declare
1932 # 64bit integers.
1933 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1934 PGAC_HAVE_GCC__SYNC_INT32_TAS
1935 PGAC_HAVE_GCC__SYNC_INT32_CAS
1936 PGAC_HAVE_GCC__SYNC_INT64_CAS
1937 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1938 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1939
1940
1941 # Check for x86 cpuid instruction
1942 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1943 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1944   [[unsigned int exx[4] = {0, 0, 0, 0};
1945   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1946   ]])],
1947   [pgac_cv__get_cpuid="yes"],
1948   [pgac_cv__get_cpuid="no"])])
1949 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1950   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1951 fi
1952
1953 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1954 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1955   [[unsigned int exx[4] = {0, 0, 0, 0};
1956   __get_cpuid(exx[0], 1);
1957   ]])],
1958   [pgac_cv__cpuid="yes"],
1959   [pgac_cv__cpuid="no"])])
1960 if test x"$pgac_cv__cpuid" = x"yes"; then
1961   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1962 fi
1963
1964 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1965 #
1966 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1967 # with the default compiler flags. If not, check if adding the -msse4.2
1968 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1969 PGAC_SSE42_CRC32_INTRINSICS([])
1970 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1971   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1972 fi
1973 AC_SUBST(CFLAGS_SSE42)
1974
1975 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1976 # define __SSE4_2__ in that case.
1977 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1978 #ifndef __SSE4_2__
1979 #error __SSE4_2__ not defined
1980 #endif
1981 ])], [SSE4_2_TARGETED=1])
1982
1983 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
1984 #
1985 # First check if __crc32c* intrinsics can be used with the default compiler
1986 # flags. If not, check if adding -march=armv8-a+crc flag helps.
1987 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
1988 PGAC_ARMV8_CRC32C_INTRINSICS([])
1989 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
1990   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
1991 fi
1992 AC_SUBST(CFLAGS_ARMV8_CRC32C)
1993
1994 # Select CRC-32C implementation.
1995 #
1996 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
1997 # use the special CRC instructions for calculating CRC-32C. If we're not
1998 # targeting such a processor, but we can nevertheless produce code that uses
1999 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2000 # implementations and select which one to use at runtime, depending on whether
2001 # SSE 4.2 is supported by the processor we're running on.
2002 #
2003 # Similarly, if we are targeting an ARM processor that has the CRC
2004 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2005 # we're not targeting such a processor, but can nevertheless produce code that
2006 # uses the CRC instructions, compile both, and select at runtime.
2007 #
2008 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2009 # in the template or configure command line.
2010 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2011   # Use Intel SSE 4.2 if available.
2012   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2013     USE_SSE42_CRC32C=1
2014   else
2015     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2016     # the runtime check.
2017     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2018       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2019     else
2020       # Use ARM CRC Extension if available.
2021       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2022         USE_ARMV8_CRC32C=1
2023       else
2024         # ARM CRC Extension, with runtime check?
2025         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2026           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2027         else
2028           # fall back to slicing-by-8 algorithm, which doesn't require any
2029           # special CPU support.
2030           USE_SLICING_BY_8_CRC32C=1
2031         fi
2032       fi
2033     fi
2034   fi
2035 fi
2036
2037 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2038 AC_MSG_CHECKING([which CRC-32C implementation to use])
2039 if test x"$USE_SSE42_CRC32C" = x"1"; then
2040   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2041   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2042   AC_MSG_RESULT(SSE 4.2)
2043 else
2044   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2045     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2046     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2047     AC_MSG_RESULT(SSE 4.2 with runtime check)
2048   else
2049     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2050       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2051       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2052       AC_MSG_RESULT(ARMv8 CRC instructions)
2053     else
2054       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2055         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2056         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2057         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2058       else
2059         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2060         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2061         AC_MSG_RESULT(slicing-by-8)
2062       fi
2063     fi
2064   fi
2065 fi
2066 AC_SUBST(PG_CRC32C_OBJS)
2067
2068
2069 # Select semaphore implementation type.
2070 if test "$PORTNAME" != "win32"; then
2071   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2072     # Need sem_open for this
2073     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2074   fi
2075   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2076     # Need sem_init for this
2077     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2078   fi
2079   AC_MSG_CHECKING([which semaphore API to use])
2080   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2081     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2082     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2083     sematype="named POSIX"
2084   else
2085     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2086       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2087       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2088       sematype="unnamed POSIX"
2089     else
2090       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2091       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2092       sematype="System V"
2093     fi
2094   fi
2095   AC_MSG_RESULT([$sematype])
2096 else
2097   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2098   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2099 fi
2100
2101
2102 # Select shared-memory implementation type.
2103 if test "$PORTNAME" != "win32"; then
2104   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2105   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2106 else
2107   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2108   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2109 fi
2110
2111 # Select random number source
2112 #
2113 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2114 # in the template or configure command line.
2115
2116 # If not selected manually, try to select a source automatically.
2117 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2118   if test x"$with_openssl" = x"yes" ; then
2119     USE_OPENSSL_RANDOM=1
2120   elif test "$PORTNAME" = "win32" ; then
2121     USE_WIN32_RANDOM=1
2122   else
2123     AC_CHECK_FILE([/dev/urandom], [], [])
2124
2125     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2126       USE_DEV_URANDOM=1
2127     fi
2128   fi
2129 fi
2130
2131 AC_MSG_CHECKING([which random number source to use])
2132 if test "$enable_strong_random" = yes ; then
2133   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2134     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2135     AC_MSG_RESULT([OpenSSL])
2136   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2137     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2138     AC_MSG_RESULT([Windows native])
2139   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2140     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2141     AC_MSG_RESULT([/dev/urandom])
2142   else
2143     AC_MSG_ERROR([
2144 no source of strong random numbers was found
2145 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2146 for authentication protocols. You can use --disable-strong-random to use a
2147 built-in pseudo random number generator, but that may be insecure.])
2148   fi
2149   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2150 else
2151     AC_MSG_RESULT([weak builtin PRNG])
2152     AC_MSG_WARN([
2153 *** Not using a strong random number source may be insecure.])
2154 fi
2155
2156 # If not set in template file, set bytes to use libc memset()
2157 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2158   MEMSET_LOOP_LIMIT=1024
2159 fi
2160 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2161
2162
2163 if test "$enable_nls" = yes ; then
2164   PGAC_CHECK_GETTEXT
2165 fi
2166
2167 # Check for Tcl configuration script tclConfig.sh
2168 if test "$with_tcl" = yes; then
2169     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2170     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2171                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2172     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2173     if test "$TCL_SHARED_BUILD" != 1; then
2174       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2175 Use --without-tcl to disable building PL/Tcl.])
2176     fi
2177     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2178     ac_save_CPPFLAGS=$CPPFLAGS
2179     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2180     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2181     CPPFLAGS=$ac_save_CPPFLAGS
2182 fi
2183
2184 # check for <perl.h>
2185 if test "$with_perl" = yes; then
2186   ac_save_CPPFLAGS=$CPPFLAGS
2187   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2188   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2189                   [#include <EXTERN.h>])
2190   # While we're at it, check that we can link to libperl.
2191   # On most platforms, if perl.h is there then libperl.so will be too, but at
2192   # this writing Debian packages them separately.  There is no known reason to
2193   # waste cycles on separate probes for the Tcl or Python libraries, though.
2194   pgac_save_LIBS=$LIBS
2195   LIBS="$perl_embed_ldflags"
2196   AC_MSG_CHECKING([for libperl])
2197   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2198 #include <EXTERN.h>
2199 #include <perl.h>
2200 ],  [perl_alloc();])],
2201     [AC_MSG_RESULT(yes)],
2202     [AC_MSG_RESULT(no)
2203      AC_MSG_ERROR([libperl library is required for Perl])])
2204   LIBS=$pgac_save_LIBS
2205   CPPFLAGS=$ac_save_CPPFLAGS
2206 fi
2207
2208 # check for <Python.h>
2209 if test "$with_python" = yes; then
2210   ac_save_CPPFLAGS=$CPPFLAGS
2211   CPPFLAGS="$python_includespec $CPPFLAGS"
2212   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2213   CPPFLAGS=$ac_save_CPPFLAGS
2214 fi
2215
2216 #
2217 # Check for DocBook and tools
2218 #
2219 PGAC_PATH_XMLLINT
2220 PGAC_CHECK_DOCBOOK(4.2)
2221 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2222 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2223 PGAC_PATH_PROGS(FOP, fop)
2224
2225 #
2226 # Check for test tools
2227 #
2228 if test "$enable_tap_tests" = yes; then
2229   # Check for necessary modules, unless user has specified the "prove" to use;
2230   # in that case it's her responsibility to have a working configuration.
2231   # (prove might be part of a different Perl installation than perl, eg on
2232   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2233   if test -z "$PROVE"; then
2234     # Test::More and Time::HiRes are supposed to be part of core Perl,
2235     # but some distros omit them in a minimal installation.
2236     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2237       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2238   fi
2239   # Now make sure we know where prove is
2240   PGAC_PATH_PROGS(PROVE, prove)
2241   if test -z "$PROVE"; then
2242     AC_MSG_ERROR([prove not found])
2243   fi
2244 fi
2245
2246 # Thread testing
2247
2248 # We have to run the thread test near the end so we have all our symbols
2249 # defined.  Cross compiling throws a warning.
2250 #
2251 if test "$enable_thread_safety" = yes; then
2252 if test "$PORTNAME" != "win32"
2253 then
2254 AC_MSG_CHECKING([thread safety of required library functions])
2255
2256 _CFLAGS="$CFLAGS"
2257 _LIBS="$LIBS"
2258 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2259 LIBS="$LIBS $PTHREAD_LIBS"
2260 AC_RUN_IFELSE(
2261   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2262   [AC_MSG_RESULT(yes)],
2263   [AC_MSG_RESULT(no)
2264   AC_MSG_ERROR([thread test program failed
2265 This platform is not thread-safe.  Check the file 'config.log' or compile
2266 and run src/test/thread/thread_test for the exact reason.
2267 Use --disable-thread-safety to disable thread safety.])],
2268   [AC_MSG_RESULT(maybe)
2269   AC_MSG_WARN([
2270 *** Skipping thread test program because of cross-compile build.
2271 *** Run the program in src/test/thread on the target machine.
2272 ])])
2273 CFLAGS="$_CFLAGS"
2274 LIBS="$_LIBS"
2275 else
2276 AC_MSG_WARN([*** skipping thread test on Win32])
2277 fi
2278 fi
2279
2280 # If compiler will take -Wl,--as-needed (or various platform-specific
2281 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2282 # trying to filter LIBS to the minimum for each executable.
2283 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2284 # libreadline; therefore we postpone testing it until we know what library
2285 # dependencies readline has.  The test code will try to link with $LIBS.
2286 if test "$with_readline" = yes; then
2287   link_test_func=readline
2288 else
2289   link_test_func=exit
2290 fi
2291
2292 if test "$PORTNAME" = "darwin"; then
2293   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2294 elif test "$PORTNAME" = "openbsd"; then
2295   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2296 else
2297   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2298 fi
2299
2300 # Create compiler version string
2301 if test x"$GCC" = x"yes" ; then
2302   cc_string=`${CC} --version | sed q`
2303   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2304 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2305   cc_string=`${CC} -V 2>&1 | sed q`
2306 else
2307   cc_string=$CC
2308 fi
2309
2310 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2311                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2312                    [A string containing the version number, platform, and C compiler])
2313
2314 # Supply a numeric version string for use by 3rd party add-ons
2315 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2316 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2317 tr '.' '        ' |
2318 $AWK '{printf "%d%04d", $1, $2}'`"]
2319 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2320 AC_SUBST(PG_VERSION_NUM)
2321
2322
2323 # Begin output steps
2324
2325 AC_MSG_NOTICE([using compiler=$cc_string])
2326 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2327 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2328 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2329 # Currently only used when LLVM is used
2330 if test "$with_llvm" = yes ; then
2331    AC_MSG_NOTICE([using CXX=$CXX])
2332    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2333    AC_MSG_NOTICE([using CLANG=$CLANG])
2334    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2335    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2336 fi
2337
2338 # prepare build tree if outside source tree
2339 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2340 # Note 2: /bin/pwd might be better than shell's built-in at getting
2341 #         a symlink-free name.
2342 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2343   vpath_build=no
2344 else
2345   vpath_build=yes
2346   if test "$no_create" != yes; then
2347     _AS_ECHO_N([preparing build tree... ])
2348     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2349     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2350       || AC_MSG_ERROR(failed)
2351     AC_MSG_RESULT(done)
2352   fi
2353 fi
2354 AC_SUBST(vpath_build)
2355
2356
2357 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2358
2359 AC_CONFIG_LINKS([
2360   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2361   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2362   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2363   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2364   src/include/pg_config_os.h:src/include/port/${template}.h
2365   src/Makefile.port:src/makefiles/Makefile.${template}
2366 ])
2367
2368 if test "$PORTNAME" = "win32"; then
2369 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2370 # Links sometimes fail undetected on Mingw -
2371 # so here we detect it and warn the user
2372 for FILE in $CONFIG_LINKS
2373  do
2374         # test -e works for symlinks in the MinGW console
2375         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2376  done
2377 ])
2378 fi
2379
2380 AC_CONFIG_HEADERS([src/include/pg_config.h],
2381 [
2382 # Update timestamp for pg_config.h (see Makefile.global)
2383 echo >src/include/stamp-h
2384 ])
2385
2386 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2387 [
2388 # Update timestamp for pg_config_ext.h (see Makefile.global)
2389 echo >src/include/stamp-ext-h
2390 ])
2391
2392 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2393                   [echo >src/interfaces/ecpg/include/stamp-h])
2394
2395 AC_OUTPUT