granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(srclib/apr/build/find_apr.m4)
  20 sinclude(srclib/apr-util/build/find_apu.m4)
  21 sinclude(acinclude.m4)
  22
  23 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  24 dnl by configure until it is too late.  Is that how it should be or not?
  25 dnl Something seems broken here.
  26 AC_PREFIX_DEFAULT(/usr/local/apache2)
  27
  28 dnl Get the layout here, so we can pass the required variables to apr
  29 APACHE_ENABLE_LAYOUT
  30
  31 dnl reparse the configure arguments.
  32 APACHE_PARSE_ARGUMENTS
  33
  34 dnl export expanded and relative configure argument variables
  35 APACHE_EXPORT_ARGUMENTS
  36
  37 dnl Save user-defined environment settings for later restoration
  38 dnl
  39 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  42 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  43 APR_SAVE_THE_ENVIRONMENT(LIBS)
  44 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  45
  46 dnl Generate ./config.nice for reproducing runs of configure
  47 dnl
  48 APR_CONFIG_NICE(config.nice)
  49
  50 nl='
  51 '
  52 dnl Check that mkdir -p works
  53 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  54
  55 dnl ## Run configure for packages Apache uses
  56
  57 dnl shared library support for these packages doesn't currently
  58 dnl work on some platforms
  59
  60 AC_CANONICAL_SYSTEM
  61
  62 orig_prefix="$prefix"
  63
  64 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  65
  66 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr")
  67
  68 if test "$apr_found" = "no"; then
  69   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  70 fi
  71
  72 if test "$apr_found" = "reconfig"; then
  73   APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  80 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  81 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  82 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  83 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  84
  85 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  86
  87 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util")
  88
  89 if test "$apu_found" = "no"; then
  90   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  91 fi
  92
  93 if test "$apu_found" = "reconfig"; then
  94   APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
  95   dnl We must be the last to build and the first to be cleaned
  96   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
  97   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
  98 fi
  99
 100 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 101 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 102
 103 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 104
 105 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
 106
 107 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 108
 109 dnl Absolute source/build directory
 110 abs_srcdir=`(cd $srcdir && pwd)`
 111 abs_builddir=`pwd`
 112
 113 dnl If the source dir is not equal to the build dir,
 114 dnl then we are running in VPATH mode.
 115
 116 if test "$abs_builddir" != "$abs_srcdir"; then
 117   USE_VPATH=1
 118   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/include -I\$(top_srcdir)/include])
 119 else
 120   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include])
 121 fi
 122
 123 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 124
 125 case $host in
 126   *os2*)
 127       # Use a custom made libtool replacement
 128       echo "using aplibtool"
 129       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 130       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 131       SH_LIBS="\$(ALL_LIBS)"
 132       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 133       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 134       MK_IMPLIB="emximp"
 135       other_targets="$other_targets os2core"
 136       INSTALL_PROG_FLAGS="-e .exe"
 137       SHLTCFLAGS=""
 138       LTCFLAGS=""
 139       ;;
 140   *)
 141       if test "x$LTFLAGS" = "x"; then
 142           LTFLAGS='--silent'
 143       fi
 144       my_libtool=`$apr_config --apr-libtool`
 145       LIBTOOL="$my_libtool \$(LTFLAGS)"
 146       libtoolversion=`$my_libtool --version`
 147       case $libtoolversion in
 148           *1.4*)
 149               SH_LIBTOOL='$(LIBTOOL)'
 150               SHLTCFLAGS="-prefer-pic"
 151               LTCFLAGS="-prefer-non-pic -static"
 152               ;;
 153           *)
 154               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 155               SHLTCFLAGS=""
 156               LTCFLAGS=""
 157               ;;
 158       esac
 159       ;;
 160 esac
 161 APACHE_SUBST(SHLTCFLAGS)
 162 APACHE_SUBST(LTCFLAGS)
 163
 164 AP_SIG_GRACEFUL=USR1
 165
 166 case $host in
 167   *-apple-aux3*)
 168       APR_SETVAR(APACHE_MPM, [prefork])
 169       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 170       ;;
 171   *-beos*)
 172       APR_SETVAR(APACHE_MPM, [beos])
 173       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 174       ;;
 175   *os2_emx*)
 176       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 177       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 178       ;;
 179   *-linux-*)
 180       case `uname -r` in
 181         2.0* )
 182             AP_SIG_GRACEFUL=WINCH
 183             ;;
 184         2.[[2-9]]* )
 185             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 186             ;;
 187         * )
 188             ;;
 189       esac
 190       ;;
 191   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 192       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 193       ;;
 194   *-solaris2*)
 195       dnl This is a hack -- we should be using AC_TRY_RUN instead
 196       ap_platform_runtime_link_flag="-R"
 197       dnl solaris 8 and above don't have a thundering herd
 198       dnl not sure about rev's before this one.
 199       case `uname -r` in
 200         5.[567]*)
 201             ;;
 202         * )
 203             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 204             ;;
 205       esac
 206       ;;
 207   *cygwin*)
 208       APR_SETVAR(APACHE_MPM, [prefork])
 209       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 210       ;;
 211 esac
 212
 213 dnl
 214 dnl Process command line arguments. This is done early in the process so the
 215 dnl user can get feedback quickly in case of an error.
 216 dnl
 217 dnl ### need to move some of the arguments "up here"
 218
 219 dnl ## Check for programs
 220
 221 AC_PATH_PROG(RM, rm)
 222 AC_PROG_AWK
 223 AC_PROG_CC
 224 AC_PROG_CPP
 225 AC_PROG_INSTALL
 226 AC_PROG_LN_S
 227 AC_CHECK_TOOL(RANLIB, ranlib, true)
 228 dnl AC_PATH_PROG(PERL_PATH, perl)
 229
 230 dnl various OS checks that apparently set required flags
 231 AC_AIX
 232 AC_ISC_POSIX
 233 AC_MINIX
 234
 235 dnl ## Check for libraries
 236
 237 dnl ## Check for header files
 238
 239 dnl I think these are just used all over the place, so just check for
 240 dnl them at the base of the tree. If some are specific to a single
 241 dnl directory, they should be moved (Comment #Spoon)
 242
 243 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 244 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 245 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 246
 247 AC_HEADER_STDC
 248 AC_CHECK_HEADERS( \
 249 string.h \
 250 limits.h \
 251 unistd.h \
 252 sys/socket.h \
 253 pwd.h \
 254 grp.h \
 255 strings.h \
 256 sys/processor.h \
 257 sys/sem.h
 258 )
 259 AC_HEADER_SYS_WAIT
 260
 261 dnl ## Check for typedefs, structures, and compiler characteristics.
 262
 263 AC_C_CONST
 264 if test "$ac_cv_prog_gcc" = "yes"; then
 265   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 266 fi
 267
 268 dnl ## Check for library functions
 269
 270 dnl See Comment #Spoon
 271
 272 AC_CHECK_FUNCS( \
 273 getpwnam \
 274 getgrnam \
 275 initgroups \
 276 bindprocessor \
 277 timegm \
 278 )
 279
 280 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 281 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 282 [AC_TRY_COMPILE([#include <sys/types.h>
 283 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 284   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 285 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 286     AC_DEFINE(HAVE_GMTOFF)
 287 fi
 288
 289 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 290
 291 case $host in
 292     *aix*)
 293         # for 32-bit builds, increase MAXDATA to allow lots of threads
 294         if test x$OBJECT_MODE != x64; then
 295             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 296         fi
 297         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 298         ;;
 299     *os390*)
 300         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 301         ;;
 302     *)
 303         OS_SPECIFIC_VARS=""
 304 esac
 305
 306 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 307         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 308         [PORT=80])
 309
 310 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 311 [
 312   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 313 ])dnl
 314
 315 prefix="$orig_prefix"
 316 APACHE_ENABLE_MODULES
 317
 318 dnl reading config stubs
 319 esyscmd(./build/config-stubs .)
 320
 321 APACHE_SUBST(progname)
 322 APACHE_SUBST(MPM_LIB)
 323 APACHE_SUBST(OS)
 324 APACHE_SUBST(OS_DIR)
 325 APACHE_SUBST(BUILTIN_LIBS)
 326 APACHE_SUBST(SHLIBPATH_VAR)
 327 APACHE_SUBST(OS_SPECIFIC_VARS)
 328
 329 PRE_SHARED_CMDS='echo ""'
 330 POST_SHARED_CMDS='echo ""'
 331
 332 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 333
 334 if test "$apache_need_shared" = "yes"; then
 335   if test -f $ac_aux_dir/ltconfig; then
 336     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 337   fi
 338   shared_build="shared-build"
 339 fi
 340
 341 dnl enable_so tells us if *any* modules can be built as DSOs
 342
 343 if test "$enable_so" = "yes"; then
 344   case $host in
 345     *-ibm-aix*)
 346       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 347       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 348       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 349       ;;
 350     *beos)
 351       SH_LDFLAGS='$(top_builddir)/_APP_'
 352       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 353       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 354       ;;
 355     *os390)
 356       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 357       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 358   esac
 359 fi
 360
 361 APACHE_SUBST(PRE_SHARED_CMDS)
 362 APACHE_SUBST(POST_SHARED_CMDS)
 363 APACHE_SUBST(shared_build)
 364
 365 AC_ARG_WITH(program-name,
 366 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 367   progname="$withval" ], [
 368   progname="httpd"] )
 369
 370 # SuExec parameters
 371 AC_ARG_WITH(suexec-bin,
 372 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 373   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 374 ] )
 375
 376 AC_ARG_WITH(suexec-caller,
 377 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 378   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 379
 380 AC_ARG_WITH(suexec-userdir,
 381 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 382   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 383
 384 AC_ARG_WITH(suexec-docroot,
 385 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 386   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 387
 388 AC_ARG_WITH(suexec-uidmin,
 389 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 390   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 391
 392 AC_ARG_WITH(suexec-gidmin,
 393 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 394   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 395
 396 AC_ARG_WITH(suexec-logfile,
 397 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 398   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 399
 400 AC_ARG_WITH(suexec-safepath,
 401 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 402   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 403
 404 AC_ARG_WITH(suexec-umask,
 405 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 406   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 407
 408 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 409 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 410
 411 dnl APR should go after the other libs, so the right symbols can be picked up
 412 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 413 APACHE_SUBST(AP_LIBS)
 414 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 415 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 416
 417 AC_DEFINE(AP_USING_AUTOCONF, 1,
 418                 [Using autoconf to configure Apache])
 419
 420 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 421     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 422               [This platform doesn't suffer from the thundering herd problem])
 423 fi
 424
 425 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 426 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 427 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 428 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 429 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 430 AC_SUBST(AP_SIG_GRACEFUL)
 431 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 432 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 433
 434 dnl check for endianness
 435 if test "$cross_compiling" = "no"; then
 436   AC_C_BIGENDIAN
 437 else
 438   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 439                 [byte order is unknown due to cross-compilation])
 440 fi
 441
 442 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 443 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 444 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 445 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 446
 447 if test -d ./test; then
 448     APACHE_FAST_OUTPUT(test/Makefile)
 449 fi
 450
 451 dnl ## Finalize the variables
 452 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 453
 454 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 455 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 456 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 457 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 458 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 459 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 460
 461 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 462
 463 APACHE_GEN_CONFIG_VARS
 464
 465 dnl ## Build modules.c
 466 rm -f modules.c
 467 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 468
 469 APR_EXPAND_VAR(ap_prefix, $prefix)
 470 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 471         [Root directory of the Apache install area])
 472 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 473         [Location of the config file, relative to the Apache root directory])
 474 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 475         [Location of the source for the current MPM])
 476
 477 perlbin=`$ac_aux_dir/PrintPath perl`
 478 if test "x$perlbin" = "x"; then
 479     perlbin="/replace/with/path/to/perl/interpreter"
 480 fi
 481 AC_SUBST(perlbin)
 482
 483 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 484
 485 BSD_MAKEFILE=no
 486 case $host in
 487 *bsdi*)
 488     # Check whether they've installed GNU make
 489     if make --version > /dev/null 2>&1; then
 490         true
 491     else
 492         BSD_MAKEFILE=yes
 493     fi
 494     ;;
 495 esac
 496
 497 dnl Ensure that docs/conf is created.
 498 test -d docs/conf||$mkdir_p docs/conf
 499
 500 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 501   APACHE_GEN_MAKEFILES
 502 ])
 503