granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [10devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2017, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [AC_CHECK_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 AC_CHECK_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 AC_CHECK_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [AC_CHECK_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # WAL segment size
 348 #
 349 AC_MSG_CHECKING([for WAL segment size])
 350 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 351              [wal_segsize=$withval],
 352              [wal_segsize=16])
 353 case ${wal_segsize} in
 354   1) ;;
 355   2) ;;
 356   4) ;;
 357   8) ;;
 358  16) ;;
 359  32) ;;
 360  64) ;;
 361   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 362 esac
 363 AC_MSG_RESULT([${wal_segsize}MB])
 364
 365 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 366  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 367  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 368  XLOG_BLCKSZ).
 369
 370  Changing XLOG_SEG_SIZE requires an initdb.
 371 ])
 372
 373 #
 374 # C compiler
 375 #
 376
 377 # For historical reasons you can also use --with-CC to specify the C compiler
 378 # to use, although the standard way to do this is to set the CC environment
 379 # variable.
 380 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 381
 382 case $template in
 383   aix) pgac_cc_list="gcc xlc";;
 384     *) pgac_cc_list="gcc cc";;
 385 esac
 386
 387 AC_PROG_CC([$pgac_cc_list])
 388
 389 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 390 # but has idiosyncrasies of its own.  We assume icc will define
 391 # __INTEL_COMPILER regardless of CFLAGS.
 392 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 393 choke me
 394 @%:@endif])], [ICC=yes], [ICC=no])
 395
 396 # Check if it's Sun Studio compiler. We assume that
 397 # __SUNPRO_C will be defined for Sun Studio compilers
 398 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 399 choke me
 400 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 401
 402 AC_SUBST(SUN_STUDIO_CC)
 403
 404 unset CFLAGS
 405
 406 #
 407 # Read the template
 408 #
 409 . "$srcdir/src/template/$template" || exit
 410
 411 # CFLAGS are selected so:
 412 # If the user specifies something in the environment, that is used.
 413 # else:  If the template file set something, that is used.
 414 # else:  If coverage was enabled, don't set anything.
 415 # else:  If the compiler is GCC, then we use -O2.
 416 # else:  If the compiler is something else, then we use -O, unless debugging.
 417
 418 if test "$ac_env_CFLAGS_set" = set; then
 419   CFLAGS=$ac_env_CFLAGS_value
 420 elif test "${CFLAGS+set}" = set; then
 421   : # (keep what template set)
 422 elif test "$enable_coverage" = yes; then
 423   : # no optimization by default
 424 elif test "$GCC" = yes; then
 425   CFLAGS="-O2"
 426 else
 427   # if the user selected debug mode, don't use -O
 428   if test "$enable_debug" != yes; then
 429     CFLAGS="-O"
 430   fi
 431 fi
 432
 433 # CFLAGS we determined above will be added back at the end
 434 user_CFLAGS=$CFLAGS
 435 CFLAGS=""
 436
 437 # set CFLAGS_VECTOR from the environment, if available
 438 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 439   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 440 fi
 441
 442 # Some versions of GCC support some additional useful warning flags.
 443 # Check whether they are supported, and add them to CFLAGS if so.
 444 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 445 # but has its own.  Also check other compiler-specific flags here.
 446
 447 if test "$GCC" = yes -a "$ICC" = no; then
 448   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 449   # These work in some but not all gcc versions
 450   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 451   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 452   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 453   # This was included in -Wall/-Wformat in older GCC versions
 454   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 455   # Disable strict-aliasing rules; needed for gcc 3.3+
 456   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 457   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 458   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 459   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 460   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 461   # Optimization flags for specific files that benefit from vectorization
 462   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 463   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 464   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 465   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 466   # test for the positive form and if that works, add the negative form
 467   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 468   if test -n "$NOT_THE_CFLAGS"; then
 469     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 470   fi
 471 elif test "$ICC" = yes; then
 472   # Intel's compiler has a bug/misoptimization in checking for
 473   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 474   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 475   # Make sure strict aliasing is off (though this is said to be the default)
 476   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 477 elif test "$PORTNAME" = "aix"; then
 478   # AIX's xlc has to have strict aliasing turned off too
 479   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 480   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 481 elif test "$PORTNAME" = "hpux"; then
 482   # On some versions of HP-UX, libm functions do not set errno by default.
 483   # Fix that by using +Olibmerrno if the compiler recognizes it.
 484   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 485 fi
 486
 487 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 488
 489 # supply -g if --enable-debug
 490 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 491   CFLAGS="$CFLAGS -g"
 492 fi
 493
 494 # enable code coverage if --enable-coverage
 495 if test "$enable_coverage" = yes; then
 496   if test "$GCC" = yes; then
 497     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 498   else
 499     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 500   fi
 501 fi
 502
 503 # enable profiling if --enable-profiling
 504 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 505   if test "$GCC" = yes; then
 506     AC_DEFINE([PROFILE_PID_DIR], 1,
 507            [Define to 1 to allow profiling output to be saved separately for each process.])
 508     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 509   else
 510     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 511   fi
 512 fi
 513
 514 # We already have this in Makefile.win32, but configure needs it too
 515 if test "$PORTNAME" = "win32"; then
 516   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 517 fi
 518
 519 # Now that we're done automatically adding stuff to CFLAGS, put back the
 520 # user-specified flags (if any) at the end.  This lets users override
 521 # the automatic additions.
 522 CFLAGS="$CFLAGS $user_CFLAGS"
 523
 524 # Check if the compiler still works with the final flag settings
 525 AC_MSG_CHECKING([whether the C compiler still works])
 526 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 527   [AC_MSG_RESULT(yes)],
 528   [AC_MSG_RESULT(no)
 529    AC_MSG_ERROR([cannot proceed])])
 530
 531 # Defend against gcc -ffast-math
 532 if test "$GCC" = yes; then
 533 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 534 choke me
 535 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 536 fi
 537
 538 AC_PROG_CPP
 539 AC_SUBST(GCC)
 540
 541
 542 #
 543 # Set up TAS assembly code if needed; the template file has now had its
 544 # chance to request this.
 545 #
 546 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 547
 548 if test "$need_tas" = yes ; then
 549   TAS=tas.o
 550 else
 551   TAS=""
 552 fi
 553 AC_SUBST(TAS)
 554
 555
 556 #
 557 # Automatic dependency tracking
 558 #
 559 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 560               [autodepend=yes])
 561 AC_SUBST(autodepend)
 562
 563
 564 #
 565 # Enable assert checks
 566 #
 567 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 568               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 569                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 570
 571
 572 #
 573 # Include directories
 574 #
 575 ac_save_IFS=$IFS
 576 IFS="${IFS}${PATH_SEPARATOR}"
 577 # SRCH_INC comes from the template file
 578 for dir in $with_includes $SRCH_INC; do
 579   if test -d "$dir"; then
 580     INCLUDES="$INCLUDES -I$dir"
 581   else
 582     AC_MSG_WARN([*** Include directory $dir does not exist.])
 583   fi
 584 done
 585 IFS=$ac_save_IFS
 586 AC_SUBST(INCLUDES)
 587
 588
 589 #
 590 # Library directories
 591 #
 592 ac_save_IFS=$IFS
 593 IFS="${IFS}${PATH_SEPARATOR}"
 594 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 595 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 596   if test -d "$dir"; then
 597     LIBDIRS="$LIBDIRS -L$dir"
 598   else
 599     AC_MSG_WARN([*** Library directory $dir does not exist.])
 600   fi
 601 done
 602 IFS=$ac_save_IFS
 603
 604 #
 605 # Enable thread-safe client libraries
 606 #
 607 AC_MSG_CHECKING([allow thread-safe client libraries])
 608 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 609 if test "$enable_thread_safety" = yes; then
 610   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 611           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 612 fi
 613 AC_MSG_RESULT([$enable_thread_safety])
 614 AC_SUBST(enable_thread_safety)
 615
 616 #
 617 # Optionally build Tcl modules (PL/Tcl)
 618 #
 619 AC_MSG_CHECKING([whether to build with Tcl])
 620 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 621 AC_MSG_RESULT([$with_tcl])
 622 AC_SUBST([with_tcl])
 623
 624 # We see if the path to the Tcl/Tk configuration scripts is specified.
 625 # This will override the use of tclsh to find the paths to search.
 626
 627 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 628
 629 #
 630 # Optionally build Perl modules (PL/Perl)
 631 #
 632 AC_MSG_CHECKING([whether to build Perl modules])
 633 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 634 AC_MSG_RESULT([$with_perl])
 635 AC_SUBST(with_perl)
 636
 637 #
 638 # Optionally build Python modules (PL/Python)
 639 #
 640 AC_MSG_CHECKING([whether to build Python modules])
 641 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 642 AC_MSG_RESULT([$with_python])
 643 AC_SUBST(with_python)
 644
 645 #
 646 # GSSAPI
 647 #
 648 AC_MSG_CHECKING([whether to build with GSSAPI support])
 649 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 650 [
 651   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 652   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 653 ])
 654 AC_MSG_RESULT([$with_gssapi])
 655
 656
 657 AC_SUBST(krb_srvtab)
 658
 659
 660 #
 661 # Kerberos configuration parameters
 662 #
 663 PGAC_ARG_REQ(with, krb-srvnam,
 664              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 665              [],
 666              [with_krb_srvnam="postgres"])
 667 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 668                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 669
 670
 671 #
 672 # PAM
 673 #
 674 AC_MSG_CHECKING([whether to build with PAM support])
 675 PGAC_ARG_BOOL(with, pam, no,
 676               [build with PAM support],
 677               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 678 AC_MSG_RESULT([$with_pam])
 679
 680
 681 #
 682 # BSD AUTH
 683 #
 684 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 685 PGAC_ARG_BOOL(with, bsd-auth, no,
 686               [build with BSD Authentication support],
 687               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 688 AC_MSG_RESULT([$with_bsd_auth])
 689
 690
 691 #
 692 # LDAP
 693 #
 694 AC_MSG_CHECKING([whether to build with LDAP support])
 695 PGAC_ARG_BOOL(with, ldap, no,
 696               [build with LDAP support],
 697               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 698 AC_MSG_RESULT([$with_ldap])
 699
 700
 701 #
 702 # Bonjour
 703 #
 704 AC_MSG_CHECKING([whether to build with Bonjour support])
 705 PGAC_ARG_BOOL(with, bonjour, no,
 706               [build with Bonjour support],
 707               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 708 AC_MSG_RESULT([$with_bonjour])
 709
 710
 711 #
 712 # OpenSSL
 713 #
 714 AC_MSG_CHECKING([whether to build with OpenSSL support])
 715 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 716               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 717 AC_MSG_RESULT([$with_openssl])
 718 AC_SUBST(with_openssl)
 719
 720 #
 721 # SELinux
 722 #
 723 AC_MSG_CHECKING([whether to build with SELinux support])
 724 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 725 AC_SUBST(with_selinux)
 726 AC_MSG_RESULT([$with_selinux])
 727
 728 #
 729 # Systemd
 730 #
 731 AC_MSG_CHECKING([whether to build with systemd support])
 732 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 733               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 734 AC_SUBST(with_systemd)
 735 AC_MSG_RESULT([$with_systemd])
 736
 737 #
 738 # Readline
 739 #
 740 PGAC_ARG_BOOL(with, readline, yes,
 741               [do not use GNU Readline nor BSD Libedit for editing])
 742 # readline on MinGW has problems with backslashes in psql and other bugs.
 743 # This is particularly a problem with non-US code pages.
 744 # Therefore disable its use until we understand the cause. 2004-07-20
 745 if test "$PORTNAME" = "win32"; then
 746   if test "$with_readline" = yes; then
 747     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 748     with_readline=no
 749   fi
 750 fi
 751
 752
 753 #
 754 # Prefer libedit
 755 #
 756 PGAC_ARG_BOOL(with, libedit-preferred, no,
 757               [prefer BSD Libedit over GNU Readline])
 758
 759
 760 #
 761 # UUID library
 762 #
 763 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 764 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 765 # UUID library.  More than one of these might be present on a given platform,
 766 # so we make the user say which one she wants.
 767 #
 768 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 769 if test x"$with_uuid" = x"" ; then
 770   with_uuid=no
 771 fi
 772 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 773 if test "$with_ossp_uuid" = yes ; then
 774   with_uuid=ossp
 775 fi
 776
 777 if test "$with_uuid" = bsd ; then
 778   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 779   UUID_EXTRA_OBJS="md5.o sha1.o"
 780 elif test "$with_uuid" = e2fs ; then
 781   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 782   UUID_EXTRA_OBJS="md5.o sha1.o"
 783 elif test "$with_uuid" = ossp ; then
 784   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 785   UUID_EXTRA_OBJS=""
 786 elif test "$with_uuid" = no ; then
 787   UUID_EXTRA_OBJS=""
 788 else
 789   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 790 fi
 791 AC_SUBST(with_uuid)
 792 AC_SUBST(UUID_EXTRA_OBJS)
 793
 794
 795 #
 796 # XML
 797 #
 798 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 799               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 800
 801 if test "$with_libxml" = yes ; then
 802   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 803   if test -n "$XML2_CONFIG"; then
 804     for pgac_option in `$XML2_CONFIG --cflags`; do
 805       case $pgac_option in
 806         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 807       esac
 808     done
 809     for pgac_option in `$XML2_CONFIG --libs`; do
 810       case $pgac_option in
 811         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 812       esac
 813     done
 814   fi
 815 fi
 816
 817 AC_SUBST(with_libxml)
 818
 819 #
 820 # XSLT
 821 #
 822 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 823               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 824
 825
 826 AC_SUBST(with_libxslt)
 827
 828 #
 829 # tzdata
 830 #
 831 PGAC_ARG_REQ(with, system-tzdata,
 832              [DIR], [use system time zone data in DIR])
 833 AC_SUBST(with_system_tzdata)
 834
 835 #
 836 # Zlib
 837 #
 838 PGAC_ARG_BOOL(with, zlib, yes,
 839               [do not use Zlib])
 840 AC_SUBST(with_zlib)
 841
 842 #
 843 # Elf
 844 #
 845
 846 # Assume system is ELF if it predefines __ELF__ as 1,
 847 # otherwise believe host_os based default.
 848 case $host_os in
 849     freebsd1*|freebsd2*) elf=no;;
 850     freebsd3*|freebsd4*) elf=yes;;
 851 esac
 852
 853 AC_EGREP_CPP(yes,
 854 [#if __ELF__
 855   yes
 856 #endif
 857 ],
 858 [ELF_SYS=true],
 859 [if test "X$elf" = "Xyes" ; then
 860   ELF_SYS=true
 861 else
 862   ELF_SYS=
 863 fi])
 864 AC_SUBST(ELF_SYS)
 865
 866 #
 867 # Assignments
 868 #
 869
 870 CPPFLAGS="$CPPFLAGS $INCLUDES"
 871 LDFLAGS="$LDFLAGS $LIBDIRS"
 872
 873 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 874 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 875
 876 PGAC_PROG_LD
 877 AC_SUBST(LD)
 878 AC_SUBST(with_gnu_ld)
 879 AC_PROG_RANLIB
 880 PGAC_CHECK_STRIP
 881 AC_CHECK_TOOL(AR, ar, ar)
 882 if test "$PORTNAME" = "win32"; then
 883   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 884   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 885   AC_CHECK_TOOL(WINDRES, windres, windres)
 886 fi
 887
 888 AC_PROG_INSTALL
 889 # When Autoconf chooses install-sh as install program it tries to generate
 890 # a relative path to it in each makefile where it substitutes it. This clashes
 891 # with our Makefile.global concept. This workaround helps.
 892 case $INSTALL in
 893   *install-sh*) install_bin='';;
 894   *) install_bin=$INSTALL;;
 895 esac
 896 AC_SUBST(install_bin)
 897
 898 AC_PATH_PROG(TAR, tar)
 899 AC_PROG_LN_S
 900 AC_PROG_AWK
 901 AC_PROG_MKDIR_P
 902 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 903 # a relative path to it in each makefile where it substitutes it. This clashes
 904 # with our Makefile.global concept. This workaround helps.
 905 case $MKDIR_P in
 906   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 907 esac
 908
 909 PGAC_PATH_BISON
 910 PGAC_PATH_FLEX
 911
 912 PGAC_PATH_PERL
 913 if test "$with_perl" = yes; then
 914   if test -z "$PERL"; then
 915     AC_MSG_ERROR([Perl not found])
 916   fi
 917   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 918   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 919     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 920 You might have to rebuild your Perl installation.  Refer to the
 921 documentation for details.  Use --without-perl to disable building
 922 PL/Perl.])
 923   fi
 924   PGAC_CHECK_PERL_EMBED_LDFLAGS
 925 fi
 926
 927 if test "$with_python" = yes; then
 928   PGAC_PATH_PYTHON
 929   PGAC_CHECK_PYTHON_EMBED_SETUP
 930 fi
 931
 932 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 933   AC_PATH_PROG(ZIC, zic)
 934   if test -z "$ZIC"; then
 935     AC_MSG_ERROR([
 936 When cross-compiling, either use the option --with-system-tzdata to use
 937 existing time-zone data, or set the environment variable ZIC to a zic
 938 program to use during the build.])
 939   fi
 940 fi
 941
 942 #
 943 # Pthreads
 944 #
 945 # For each platform, we need to know about any special compile and link
 946 # libraries, and whether the normal C function names are thread-safe.
 947 # See the comment at the top of src/port/thread.c for more information.
 948 # WIN32 doesn't need the pthread tests;  it always uses threads
 949 #
 950 # These tests are run before the library-tests, because linking with the
 951 # other libraries can pull in the pthread functions as a side-effect.  We
 952 # want to use the -pthread or similar flags directly, and not rely on
 953 # the side-effects of linking with some other library.
 954 #
 955 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 956 # invocation below is the first one in the script, and autoconf generates
 957 # additional code for that, which must not be inside the if-block. AS_IF
 958 # knows how to do that.
 959 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 960 [ # then
 961 AX_PTHREAD      # set thread flags
 962
 963 # Some platforms use these, so just define them.  They can't hurt if they
 964 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 965 # enables 5-arg getpwuid_r, among other things.
 966 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 967
 968 # Check for *_r functions
 969 _CFLAGS="$CFLAGS"
 970 _LIBS="$LIBS"
 971 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 972 LIBS="$LIBS $PTHREAD_LIBS"
 973
 974 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 975 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 976
 977 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 978
 979 # Do test here with the proper thread flags
 980 PGAC_FUNC_STRERROR_R_INT
 981
 982 CFLAGS="$_CFLAGS"
 983 LIBS="$_LIBS"
 984
 985 ], [ # else
 986 # do not use values from template file
 987 PTHREAD_CFLAGS=
 988 PTHREAD_LIBS=
 989 ]) # fi
 990
 991 AC_SUBST(PTHREAD_CFLAGS)
 992 AC_SUBST(PTHREAD_LIBS)
 993
 994
 995 ##
 996 ## Libraries
 997 ##
 998 ## Most libraries are included only if they demonstrably provide a function
 999 ## we need, but libm is an exception: always include it, because there are
1000 ## too many compilers that play cute optimization games that will break
1001 ## probes for standard functions such as pow().
1002 ##
1003
1004 AC_CHECK_LIB(m, main)
1005 AC_SEARCH_LIBS(setproctitle, util)
1006 AC_SEARCH_LIBS(dlopen, dl)
1007 AC_SEARCH_LIBS(socket, [socket ws2_32])
1008 AC_SEARCH_LIBS(shl_load, dld)
1009 # We only use libld in port/dynloader/aix.c
1010 case $host_os in
1011      aix*)
1012         AC_SEARCH_LIBS(ldopen, ld)
1013         ;;
1014 esac
1015 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1016 AC_SEARCH_LIBS(crypt, crypt)
1017 AC_SEARCH_LIBS(shm_open, rt)
1018 AC_SEARCH_LIBS(shm_unlink, rt)
1019 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1020 # Solaris:
1021 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1022 # Required for thread_test.c on Solaris
1023 AC_SEARCH_LIBS(sched_yield, rt)
1024 # Required for thread_test.c on Solaris 2.5:
1025 # Other ports use it too (HP-UX) so test unconditionally
1026 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1027 # Cygwin:
1028 AC_SEARCH_LIBS(shmget, cygipc)
1029
1030 if test "$with_readline" = yes; then
1031   PGAC_CHECK_READLINE
1032   if test x"$pgac_cv_check_readline" = x"no"; then
1033     AC_MSG_ERROR([readline library not found
1034 If you have readline already installed, see config.log for details on the
1035 failure.  It is possible the compiler isn't looking in the proper directory.
1036 Use --without-readline to disable readline support.])
1037   fi
1038 fi
1039
1040 if test "$with_zlib" = yes; then
1041   AC_CHECK_LIB(z, inflate, [],
1042                [AC_MSG_ERROR([zlib library not found
1043 If you have zlib already installed, see config.log for details on the
1044 failure.  It is possible the compiler isn't looking in the proper directory.
1045 Use --without-zlib to disable zlib support.])])
1046 fi
1047
1048 if test "$enable_spinlocks" = yes; then
1049   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1050 else
1051   AC_MSG_WARN([
1052 *** Not using spinlocks will cause poor performance.])
1053 fi
1054
1055 if test "$enable_atomics" = yes; then
1056   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1057 else
1058   AC_MSG_WARN([
1059 *** Not using atomic operations will cause poor performance.])
1060 fi
1061
1062 if test "$with_gssapi" = yes ; then
1063   if test "$PORTNAME" != "win32"; then
1064     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1065                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1066   else
1067     LIBS="$LIBS -lgssapi32"
1068   fi
1069 fi
1070
1071 if test "$with_openssl" = yes ; then
1072   dnl Order matters!
1073   if test "$PORTNAME" != "win32"; then
1074      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1075      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1076   else
1077      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1078      AC_SEARCH_LIBS(SSL_new, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1079   fi
1080   AC_CHECK_FUNCS([SSL_get_current_compression])
1081   # Functions introduced in OpenSSL 1.1.0. We used to check for
1082   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1083   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1084   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1085   # functions.
1086   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1087   # OpenSSL versions before 1.1.0 required setting callback functions, for
1088   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1089   # function was removed.
1090   AC_CHECK_FUNCS([CRYPTO_lock])
1091 fi
1092
1093 if test "$with_pam" = yes ; then
1094   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1095 fi
1096
1097 if test "$with_libxml" = yes ; then
1098   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1099 fi
1100
1101 if test "$with_libxslt" = yes ; then
1102   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1103 fi
1104
1105 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1106 if test "$with_ldap" = yes ; then
1107   _LIBS="$LIBS"
1108   if test "$PORTNAME" != "win32"; then
1109     AC_CHECK_LIB(ldap, ldap_bind, [],
1110                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1111                  [$EXTRA_LDAP_LIBS])
1112     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1113     if test "$enable_thread_safety" = yes; then
1114       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1115       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1116                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1117                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1118       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1119     else
1120       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1121     fi
1122   else
1123     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1124     LDAP_LIBS_FE="-lwldap32"
1125     LDAP_LIBS_BE="-lwldap32"
1126   fi
1127   LIBS="$_LIBS"
1128 fi
1129 AC_SUBST(LDAP_LIBS_FE)
1130 AC_SUBST(LDAP_LIBS_BE)
1131
1132 # for contrib/sepgsql
1133 if test "$with_selinux" = yes; then
1134   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1135                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1136 fi
1137
1138 # for contrib/uuid-ossp
1139 if test "$with_uuid" = bsd ; then
1140   # On BSD, the UUID functions are in libc
1141   AC_CHECK_FUNC(uuid_to_string,
1142     [UUID_LIBS=""],
1143     [AC_MSG_ERROR([BSD UUID functions are not present])])
1144 elif test "$with_uuid" = e2fs ; then
1145   # On macOS, the UUID functions are in libc
1146   AC_CHECK_FUNC(uuid_generate,
1147     [UUID_LIBS=""],
1148     [AC_CHECK_LIB(uuid, uuid_generate,
1149       [UUID_LIBS="-luuid"],
1150       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1151 elif test "$with_uuid" = ossp ; then
1152   AC_CHECK_LIB(ossp-uuid, uuid_export,
1153     [UUID_LIBS="-lossp-uuid"],
1154     [AC_CHECK_LIB(uuid, uuid_export,
1155       [UUID_LIBS="-luuid"],
1156       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1157 fi
1158 AC_SUBST(UUID_LIBS)
1159
1160
1161 ##
1162 ## Header files
1163 ##
1164
1165 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1166
1167 # On BSD, test for net/if.h will fail unless sys/socket.h
1168 # is included first.
1169 AC_CHECK_HEADERS(net/if.h, [], [],
1170 [AC_INCLUDES_DEFAULT
1171 #include <sys/socket.h>
1172 ])
1173
1174 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1175 # is included first.
1176 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1177 [AC_INCLUDES_DEFAULT
1178 #include <sys/param.h>
1179 ])
1180
1181 # At least on IRIX, test for netinet/tcp.h will fail unless
1182 # netinet/in.h is included first.
1183 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1184 [AC_INCLUDES_DEFAULT
1185 #include <netinet/in.h>
1186 ])
1187
1188 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1189   AC_CHECK_HEADERS(readline/readline.h, [],
1190         [AC_CHECK_HEADERS(readline.h, [],
1191                 [AC_MSG_ERROR([readline header not found
1192 If you have readline already installed, see config.log for details on the
1193 failure.  It is possible the compiler isn't looking in the proper directory.
1194 Use --without-readline to disable readline support.])])])
1195   AC_CHECK_HEADERS(readline/history.h, [],
1196         [AC_CHECK_HEADERS(history.h, [],
1197                 [AC_MSG_ERROR([history header not found
1198 If you have readline already installed, see config.log for details on the
1199 failure.  It is possible the compiler isn't looking in the proper directory.
1200 Use --without-readline to disable readline support.])])])
1201 fi
1202
1203 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1204 # Some installations of libedit usurp /usr/include/readline/, which seems
1205 # bad practice, since in combined installations readline will have its headers
1206 # there.  We might have to resort to AC_EGREP checks to make sure we found
1207 # the proper header...
1208   AC_CHECK_HEADERS(editline/readline.h, [],
1209         [AC_CHECK_HEADERS(readline.h, [],
1210                 [AC_CHECK_HEADERS(readline/readline.h, [],
1211                         [AC_MSG_ERROR([readline header not found
1212 If you have libedit already installed, see config.log for details on the
1213 failure.  It is possible the compiler isn't looking in the proper directory.
1214 Use --without-readline to disable libedit support.])])])])
1215 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1216 # not be there at all.  Hence, don't complain if not found.  We must check
1217 # though, since in yet other versions it is an independent header.
1218   AC_CHECK_HEADERS(editline/history.h, [],
1219         [AC_CHECK_HEADERS(history.h, [],
1220                 [AC_CHECK_HEADERS(readline/history.h)])])
1221 fi
1222
1223 if test "$with_zlib" = yes; then
1224   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1225 If you have zlib already installed, see config.log for details on the
1226 failure.  It is possible the compiler isn't looking in the proper directory.
1227 Use --without-zlib to disable zlib support.])])
1228 fi
1229
1230 if test "$with_gssapi" = yes ; then
1231   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1232         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1233 fi
1234
1235 if test "$with_openssl" = yes ; then
1236   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1237   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1238 fi
1239
1240 if test "$with_pam" = yes ; then
1241   AC_CHECK_HEADERS(security/pam_appl.h, [],
1242                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1243                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1244 fi
1245
1246 if test "$with_bsd_auth" = yes ; then
1247   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1248 fi
1249
1250 if test "$with_systemd" = yes ; then
1251   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1252 fi
1253
1254 if test "$with_libxml" = yes ; then
1255   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1256 fi
1257
1258 if test "$with_libxslt" = yes ; then
1259   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1260 fi
1261
1262 if test "$with_ldap" = yes ; then
1263   if test "$PORTNAME" != "win32"; then
1264      AC_CHECK_HEADERS(ldap.h, [],
1265                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1266      PGAC_LDAP_SAFE
1267   else
1268      AC_CHECK_HEADERS(winldap.h, [],
1269                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1270                       [AC_INCLUDES_DEFAULT
1271 #include <windows.h>
1272                       ])
1273   fi
1274 fi
1275
1276 if test "$with_bonjour" = yes ; then
1277   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1278 fi
1279
1280 # for contrib/uuid-ossp
1281 if test "$with_uuid" = bsd ; then
1282   AC_CHECK_HEADERS(uuid.h,
1283     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1284       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1285     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1286 elif test "$with_uuid" = e2fs ; then
1287   AC_CHECK_HEADERS(uuid/uuid.h,
1288     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1289       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1290     [AC_CHECK_HEADERS(uuid.h,
1291       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1292         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1293       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1294 elif test "$with_uuid" = ossp ; then
1295   AC_CHECK_HEADERS(ossp/uuid.h,
1296     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1297       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1298     [AC_CHECK_HEADERS(uuid.h,
1299       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1300         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1301       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1302 fi
1303
1304 if test "$PORTNAME" = "win32" ; then
1305    AC_CHECK_HEADERS(crtdefs.h)
1306 fi
1307
1308 ##
1309 ## Types, structures, compiler characteristics
1310 ##
1311
1312 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1313 AC_C_BIGENDIAN
1314 AC_C_INLINE
1315 PGAC_PRINTF_ARCHETYPE
1316 AC_C_FLEXIBLE_ARRAY_MEMBER
1317 PGAC_C_SIGNED
1318 PGAC_C_FUNCNAME_SUPPORT
1319 PGAC_C_STATIC_ASSERT
1320 PGAC_C_TYPES_COMPATIBLE
1321 PGAC_C_BUILTIN_BSWAP32
1322 PGAC_C_BUILTIN_BSWAP64
1323 PGAC_C_BUILTIN_CONSTANT_P
1324 PGAC_C_BUILTIN_UNREACHABLE
1325 PGAC_C_COMPUTED_GOTO
1326 PGAC_C_VA_ARGS
1327 PGAC_STRUCT_TIMEZONE
1328 PGAC_UNION_SEMUN
1329 PGAC_STRUCT_SOCKADDR_UN
1330 PGAC_STRUCT_SOCKADDR_STORAGE
1331 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1332 PGAC_STRUCT_ADDRINFO
1333 AC_TYPE_INTPTR_T
1334 AC_TYPE_UINTPTR_T
1335 AC_TYPE_LONG_LONG_INT
1336
1337 PGAC_TYPE_LOCALE_T
1338
1339 AC_CHECK_TYPES([struct cmsgcred], [], [],
1340 [#include <sys/socket.h>
1341 #include <sys/param.h>
1342 #ifdef HAVE_SYS_UCRED_H
1343 #include <sys/ucred.h>
1344 #endif])
1345
1346 AC_CHECK_TYPES([struct option], [], [],
1347 [#ifdef HAVE_GETOPT_H
1348 #include <getopt.h>
1349 #endif])
1350
1351 if test "$with_zlib" = yes; then
1352   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1353   # did not).  While we could work around the lack of z_streamp, it
1354   # seems unwise to encourage people to use such old zlib versions...
1355   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1356 Use --without-zlib to disable zlib support.])],
1357                 [#include <zlib.h>])
1358 fi
1359
1360 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1361 case $host_cpu in
1362   ppc*|powerpc*)
1363     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1364     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1365         [int a = 0; int *p = &a; int r;
1366          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1367         [pgac_cv_have_ppc_mutex_hint=yes],
1368         [pgac_cv_have_ppc_mutex_hint=no])
1369     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1370     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1371         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1372     fi
1373   ;;
1374 esac
1375
1376 # Check largefile support.  You might think this is a system service not a
1377 # compiler characteristic, but you'd be wrong.  We must check this before
1378 # probing existence of related functions such as fseeko, since the largefile
1379 # defines can affect what is generated for that.
1380 if test "$PORTNAME" != "win32"; then
1381    AC_SYS_LARGEFILE
1382    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1383    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1384    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1385    dnl versions where the feature actually works, it's on by default anyway.
1386    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1387 fi
1388
1389 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1390 AC_CHECK_SIZEOF([off_t])
1391
1392 # If we don't have largefile support, can't handle segsize >= 2GB.
1393 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1394    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1395 fi
1396
1397
1398 ##
1399 ## Functions, global variables
1400 ##
1401
1402 PGAC_VAR_INT_TIMEZONE
1403 AC_FUNC_ACCEPT_ARGTYPES
1404 PGAC_FUNC_GETTIMEOFDAY_1ARG
1405 PGAC_FUNC_WCSTOMBS_L
1406
1407 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1408 # symbols that that library has no business exposing to the world.  Pending
1409 # acquisition of a clue by those developers, ignore libedit (including its
1410 # possible alias of libreadline) while checking for everything else.
1411 LIBS_including_readline="$LIBS"
1412 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1413
1414 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1415
1416 AC_REPLACE_FUNCS(fseeko)
1417 case $host_os in
1418         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1419         # Mingw uses macros to access Win32 API calls
1420         netbsd*|mingw*)
1421                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1422                 ac_cv_func_fseeko=yes;;
1423         *)
1424                 AC_FUNC_FSEEKO;;
1425 esac
1426
1427 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1428 # by calling it, 2009-04-02
1429 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1430 if test "$PORTNAME" != "solaris"; then
1431 AC_CHECK_FUNCS(posix_fadvise)
1432 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1433 fi
1434
1435 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1436 AC_CHECK_DECLS([strlcat, strlcpy])
1437 # This is probably only present on macOS, but may as well check always
1438 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1439
1440 HAVE_IPV6=no
1441 AC_CHECK_TYPE([struct sockaddr_in6],
1442         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1443          HAVE_IPV6=yes],
1444         [],
1445 [$ac_includes_default
1446 #include <netinet/in.h>])
1447 AC_SUBST(HAVE_IPV6)
1448
1449 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1450 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1451 [#include <machine/vmparam.h>
1452 #include <sys/exec.h>
1453 ],
1454 [PS_STRINGS->ps_nargvstr = 1;
1455 PS_STRINGS->ps_argvstr = "foo";])],
1456 [pgac_cv_var_PS_STRINGS=yes],
1457 [pgac_cv_var_PS_STRINGS=no])])
1458 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1459   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1460 fi
1461
1462
1463 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1464 # is missing.  Yes, there are machines that have only one.  We may
1465 # also decide to use snprintf.c if snprintf() is present but does not
1466 # have all the features we need --- see below.
1467
1468 if test "$PORTNAME" = "win32"; then
1469   # Win32 gets snprintf.c built unconditionally.
1470   #
1471   # To properly translate all NLS languages strings, we must support the
1472   # *printf() %$ format, which allows *printf() arguments to be selected
1473   # by position in the translated string.
1474   #
1475   # libintl versions < 0.13 use the native *printf() functions, and Win32
1476   # *printf() doesn't understand %$, so we must use our /port versions,
1477   # which do understand %$. libintl versions >= 0.13 include their own
1478   # *printf versions on Win32.  The libintl 0.13 release note text is:
1479   #
1480   #   C format strings with positions, as they arise when a translator
1481   #   needs to reorder a sentence, are now supported on all platforms.
1482   #   On those few platforms (NetBSD and Woe32) for which the native
1483   #   printf()/fprintf()/... functions don't support such format
1484   #   strings, replacements are provided through <libintl.h>.
1485   #
1486   # We could use libintl >= 0.13's *printf() if we were sure that we had
1487   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1488   # to guarantee that, it is best to just use our own, so we are sure to
1489   # get %$ support. In include/port.h we disable the *printf() macros
1490   # that might have been defined by libintl.
1491   #
1492   # We do this unconditionally whether NLS is used or not so we are sure
1493   # that all Win32 libraries and binaries behave the same.
1494   pgac_need_repl_snprintf=yes
1495 else
1496   pgac_need_repl_snprintf=no
1497   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1498   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1499 fi
1500
1501
1502 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1503 # include/c.h will provide declarations.  Note this is a separate test
1504 # from whether the functions exist in the C library --- there are
1505 # systems that have the functions but don't bother to declare them :-(
1506
1507 AC_CHECK_DECLS([snprintf, vsnprintf])
1508
1509
1510 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1511 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1512 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1513 #include <math.h>
1514 double glob_double;
1515 ],
1516 [return isinf(glob_double) ? 0 : 1;])],
1517 [ac_cv_func_isinf=yes],
1518 [ac_cv_func_isinf=no])])
1519
1520 if test $ac_cv_func_isinf = yes ; then
1521   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1522 else
1523   AC_LIBOBJ(isinf)
1524   # Look for a way to implement a substitute for isinf()
1525   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1526 fi
1527
1528 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1529
1530 case $host_os in
1531
1532         # Windows uses a specialised env handler
1533         # and doesn't need a replacement getpeereid because it doesn't use
1534         # Unix sockets.
1535         mingw*)
1536                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1537                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1538                 ac_cv_func_unsetenv=yes
1539                 ac_cv_func_getpeereid=yes;;
1540         *)
1541                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1542                 ;;
1543 esac
1544
1545 # System's version of getaddrinfo(), if any, may be used only if we found
1546 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1547 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1548 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1549    test "$PORTNAME" != "win32"; then
1550   AC_REPLACE_FUNCS([getaddrinfo])
1551 else
1552   AC_LIBOBJ(getaddrinfo)
1553 fi
1554
1555 # Similarly, use system's getopt_long() only if system provides struct option.
1556 if test x"$ac_cv_type_struct_option" = xyes ; then
1557   AC_REPLACE_FUNCS([getopt_long])
1558 else
1559   AC_LIBOBJ(getopt_long)
1560 fi
1561
1562 # Solaris' getopt() doesn't do what we want for long options, so always use
1563 # our version on that platform.
1564 if test "$PORTNAME" = "solaris"; then
1565   AC_LIBOBJ(getopt)
1566 fi
1567
1568 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1569 # so always use our version on Windows.
1570 if test "$PORTNAME" = "win32"; then
1571   AC_LIBOBJ(getopt)
1572   AC_LIBOBJ(getopt_long)
1573 fi
1574
1575 # Win32 (really MinGW) support
1576 if test "$PORTNAME" = "win32"; then
1577   AC_REPLACE_FUNCS(gettimeofday)
1578   AC_LIBOBJ(dirmod)
1579   AC_LIBOBJ(kill)
1580   AC_LIBOBJ(open)
1581   AC_LIBOBJ(system)
1582   AC_LIBOBJ(win32env)
1583   AC_LIBOBJ(win32error)
1584   AC_LIBOBJ(win32security)
1585   AC_LIBOBJ(win32setlocale)
1586   AC_DEFINE([HAVE_SYMLINK], 1,
1587             [Define to 1 if you have the `symlink' function.])
1588   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1589 #define WIN32_LEAN_AND_MEAN
1590 #include <windows.h>
1591 #include <string.h>
1592 #include <dbghelp.h>])
1593 fi
1594 if test x"$pgac_minidump_type" = x"yes" ; then
1595   AC_SUBST(have_win32_dbghelp,yes)
1596 else
1597   AC_SUBST(have_win32_dbghelp,no)
1598 fi
1599
1600 # Cygwin needs only a bit of that
1601 if test "$PORTNAME" = "cygwin"; then
1602   AC_LIBOBJ(dirmod)
1603 fi
1604
1605 AC_CHECK_DECLS([sys_siglist], [], [],
1606 [#include <signal.h>
1607 /* NetBSD declares sys_siglist in unistd.h.  */
1608 #ifdef HAVE_UNISTD_H
1609 # include <unistd.h>
1610 #endif
1611 ])
1612
1613 AC_CHECK_FUNC(syslog,
1614               [AC_CHECK_HEADER(syslog.h,
1615                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1616
1617 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1618 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1619   [extern int opterr; opterr = 1;])],
1620   [pgac_cv_var_int_opterr=yes],
1621   [pgac_cv_var_int_opterr=no])])
1622 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1623   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1624 fi
1625
1626 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1627 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1628   [extern int optreset; optreset = 1;])],
1629   [pgac_cv_var_int_optreset=yes],
1630   [pgac_cv_var_int_optreset=no])])
1631 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1632   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1633 fi
1634
1635 AC_CHECK_FUNCS([strtoll strtoq], [break])
1636 AC_CHECK_FUNCS([strtoull strtouq], [break])
1637
1638 # Lastly, restore full LIBS list and check for readline/libedit symbols
1639 LIBS="$LIBS_including_readline"
1640
1641 if test "$with_readline" = yes; then
1642   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1643   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1644   AC_CHECK_FUNCS([append_history history_truncate_file])
1645 fi
1646
1647
1648 # This test makes sure that run tests work at all.  Sometimes a shared
1649 # library is found by the linker, but the runtime linker can't find it.
1650 # This check should come after all modifications of compiler or linker
1651 # variables, and before any other run tests.
1652 AC_MSG_CHECKING([test program])
1653 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1654 [AC_MSG_RESULT(ok)],
1655 [AC_MSG_RESULT(failed)
1656 AC_MSG_ERROR([[
1657 Could not execute a simple test program.  This may be a problem
1658 related to locating shared libraries.  Check the file 'config.log'
1659 for the exact reason.]])],
1660 [AC_MSG_RESULT([cross-compiling])])
1661
1662 # --------------------
1663 # Run tests below here
1664 # --------------------
1665
1666 # Force use of our snprintf if system's doesn't do arg control
1667 # See comment above at snprintf test for details.
1668 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1669   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1670   if test $pgac_cv_snprintf_arg_control != yes ; then
1671     pgac_need_repl_snprintf=yes
1672   fi
1673 fi
1674
1675
1676 dnl Check to see if we have a working 64-bit integer type.
1677 dnl This breaks down into two steps:
1678 dnl (1) figure out if the compiler has a 64-bit int type with working
1679 dnl arithmetic, and if so
1680 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1681 dnl snprintf is the only library routine we really need for int8 support.)
1682 dnl It's entirely possible to have a compiler that handles a 64-bit type
1683 dnl when the C library doesn't; this is fairly likely when using gcc on
1684 dnl an older platform, for example.
1685 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1686 dnl we force our own version of snprintf() to be used instead.
1687 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1688
1689 dnl As of Postgres 8.4, we no longer support compilers without a working
1690 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1691
1692 PGAC_TYPE_64BIT_INT([long int])
1693
1694 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1695   pg_int64_type="long int"
1696 else
1697   PGAC_TYPE_64BIT_INT([long long int])
1698   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1699     pg_int64_type="long long int"
1700   else
1701     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1702   fi
1703 fi
1704
1705 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1706   [Define to the name of a signed 64-bit integer type.])
1707
1708 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1709
1710 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1711   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1712 #define INT64CONST(x)  x##LL
1713 long long int foo = INT64CONST(0x1234567890123456);
1714 ])],
1715         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1716         [])
1717 fi
1718
1719
1720 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1721 # we found we need to use "long long int", better check.  We cope with
1722 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1723 # work, fall back to our own snprintf emulation (which we know uses %lld).
1724
1725 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1726   if test $pgac_need_repl_snprintf = no; then
1727     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1728     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1729       # Force usage of our own snprintf, since system snprintf is broken
1730       pgac_need_repl_snprintf=yes
1731       LONG_LONG_INT_MODIFIER='ll'
1732     fi
1733   else
1734     # Here if we previously decided we needed to use our own snprintf
1735     LONG_LONG_INT_MODIFIER='ll'
1736   fi
1737 else
1738   # Here if we are not using 'long long int' at all
1739   LONG_LONG_INT_MODIFIER='l'
1740 fi
1741
1742 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1743
1744 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1745                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1746
1747 # Also force use of our snprintf if the system's doesn't support the %z flag.
1748 if test "$pgac_need_repl_snprintf" = no; then
1749   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1750   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1751     pgac_need_repl_snprintf=yes
1752   fi
1753 fi
1754
1755 # Now we have checked all the reasons to replace snprintf
1756 if test $pgac_need_repl_snprintf = yes; then
1757   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1758   AC_LIBOBJ(snprintf)
1759 fi
1760
1761 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1762 AC_CHECK_SIZEOF([void *])
1763 AC_CHECK_SIZEOF([size_t])
1764 AC_CHECK_SIZEOF([long])
1765
1766 # Decide whether float4 is passed by value: user-selectable, enabled by default
1767 AC_MSG_CHECKING([whether to build with float4 passed by value])
1768 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1769               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1770                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1771                float4passbyval=true],
1772               [float4passbyval=false])
1773 AC_MSG_RESULT([$enable_float4_byval])
1774 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1775
1776 # Decide whether float8 is passed by value.
1777 # Note: this setting also controls int8 and related types such as timestamp.
1778 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1779 # If not, trying to select it is an error.
1780 AC_MSG_CHECKING([whether to build with float8 passed by value])
1781 if test $ac_cv_sizeof_void_p -ge 8 ; then
1782   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1783 else
1784   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1785   if test "$enable_float8_byval" = yes ; then
1786     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1787   fi
1788 fi
1789 if test "$enable_float8_byval" = yes ; then
1790   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1791             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1792   float8passbyval=true
1793 else
1794   float8passbyval=false
1795 fi
1796 AC_MSG_RESULT([$enable_float8_byval])
1797 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1798
1799 # Determine memory alignment requirements for the basic C data types.
1800
1801 AC_CHECK_ALIGNOF(short)
1802 AC_CHECK_ALIGNOF(int)
1803 AC_CHECK_ALIGNOF(long)
1804 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1805   AC_CHECK_ALIGNOF(long long int)
1806 fi
1807 AC_CHECK_ALIGNOF(double)
1808
1809 # Compute maximum alignment of any basic type.
1810 # We assume long's alignment is at least as strong as char, short, or int;
1811 # but we must check long long (if it exists) and double.
1812
1813 MAX_ALIGNOF=$ac_cv_alignof_long
1814 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1815   MAX_ALIGNOF=$ac_cv_alignof_double
1816 fi
1817 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1818   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1819 fi
1820 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1821
1822
1823 # Some platforms predefine the types int8, int16, etc.  Only check
1824 # a (hopefully) representative subset.
1825 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1826 [#include <stdio.h>])
1827
1828 # Check for extensions offering the integer scalar type __int128.
1829 PGAC_TYPE_128BIT_INT
1830
1831 # Check for various atomic operations now that we have checked how to declare
1832 # 64bit integers.
1833 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1834 PGAC_HAVE_GCC__SYNC_INT32_TAS
1835 PGAC_HAVE_GCC__SYNC_INT32_CAS
1836 PGAC_HAVE_GCC__SYNC_INT64_CAS
1837 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1838 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1839
1840
1841 # Check for x86 cpuid instruction
1842 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1843 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1844   [[unsigned int exx[4] = {0, 0, 0, 0};
1845   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1846   ]])],
1847   [pgac_cv__get_cpuid="yes"],
1848   [pgac_cv__get_cpuid="no"])])
1849 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1850   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1851 fi
1852
1853 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1854 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1855   [[unsigned int exx[4] = {0, 0, 0, 0};
1856   __get_cpuid(exx[0], 1);
1857   ]])],
1858   [pgac_cv__cpuid="yes"],
1859   [pgac_cv__cpuid="no"])])
1860 if test x"$pgac_cv__cpuid" = x"yes"; then
1861   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1862 fi
1863
1864 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1865 #
1866 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1867 # with the default compiler flags. If not, check if adding the -msse4.2
1868 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1869 PGAC_SSE42_CRC32_INTRINSICS([])
1870 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1871   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1872 fi
1873 AC_SUBST(CFLAGS_SSE42)
1874
1875 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1876 # define __SSE4_2__ in that case.
1877 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1878 #ifndef __SSE4_2__
1879 #error __SSE4_2__ not defined
1880 #endif
1881 ])], [SSE4_2_TARGETED=1])
1882
1883 # Select CRC-32C implementation.
1884 #
1885 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1886 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1887 # a processor, but we can nevertheless produce code that uses the SSE
1888 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1889 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1890 # by the processor we're running on.
1891 #
1892 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1893 # in the template or configure command line.
1894 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1895   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1896     USE_SSE42_CRC32C=1
1897   else
1898     # the CPUID instruction is needed for the runtime check.
1899     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1900       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1901     else
1902       # fall back to slicing-by-8 algorithm which doesn't require any special
1903       # CPU support.
1904       USE_SLICING_BY_8_CRC32C=1
1905     fi
1906   fi
1907 fi
1908
1909 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1910 AC_MSG_CHECKING([which CRC-32C implementation to use])
1911 if test x"$USE_SSE42_CRC32C" = x"1"; then
1912   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1913   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1914   AC_MSG_RESULT(SSE 4.2)
1915 else
1916   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1917     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1918     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1919     AC_MSG_RESULT(SSE 4.2 with runtime check)
1920   else
1921     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1922     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1923     AC_MSG_RESULT(slicing-by-8)
1924   fi
1925 fi
1926 AC_SUBST(PG_CRC32C_OBJS)
1927
1928
1929 # Select semaphore implementation type.
1930 if test "$PORTNAME" != "win32"; then
1931   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1932     # Need sem_open for this
1933     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1934   fi
1935   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1936     # Need sem_init for this
1937     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1938   fi
1939   AC_MSG_CHECKING([which semaphore API to use])
1940   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1941     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1942     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1943     sematype="named POSIX"
1944   else
1945     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1946       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1947       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1948       sematype="unnamed POSIX"
1949     else
1950       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1951       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1952       sematype="System V"
1953     fi
1954   fi
1955   AC_MSG_RESULT([$sematype])
1956 else
1957   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1958   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1959 fi
1960
1961
1962 # Select shared-memory implementation type.
1963 if test "$PORTNAME" != "win32"; then
1964   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1965   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1966 else
1967   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1968   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1969 fi
1970
1971 # Select random number source
1972 #
1973 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
1974 # in the template or configure command line.
1975
1976 # If not selected manually, try to select a source automatically.
1977 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
1978   if test x"$with_openssl" = x"yes" ; then
1979     USE_OPENSSL_RANDOM=1
1980   elif test "$PORTNAME" = "win32" ; then
1981     USE_WIN32_RANDOM=1
1982   else
1983     AC_CHECK_FILE([/dev/urandom], [], [])
1984
1985     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
1986       USE_DEV_URANDOM=1
1987     fi
1988   fi
1989 fi
1990
1991 AC_MSG_CHECKING([which random number source to use])
1992 if test "$enable_strong_random" = yes ; then
1993   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
1994     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
1995     AC_MSG_RESULT([OpenSSL])
1996   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
1997     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
1998     AC_MSG_RESULT([Windows native])
1999   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2000     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2001     AC_MSG_RESULT([/dev/urandom])
2002   else
2003     AC_MSG_ERROR([
2004 no source of strong random numbers was found
2005 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2006 for authentication protocols. You can use --disable-strong-random to use a
2007 built-in pseudo random number generator, but that may be insecure.])
2008   fi
2009   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2010 else
2011     AC_MSG_RESULT([weak builtin PRNG])
2012     AC_MSG_WARN([
2013 *** Not using a strong random number source may be insecure.])
2014 fi
2015
2016 # If not set in template file, set bytes to use libc memset()
2017 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2018   MEMSET_LOOP_LIMIT=1024
2019 fi
2020 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2021
2022
2023 if test "$enable_nls" = yes ; then
2024   PGAC_CHECK_GETTEXT
2025 fi
2026
2027 # Check for Tcl configuration script tclConfig.sh
2028 if test "$with_tcl" = yes; then
2029     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2030     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2031                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2032     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2033     if test "$TCL_SHARED_BUILD" != 1; then
2034       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2035 Use --without-tcl to disable building PL/Tcl.])
2036     fi
2037     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2038     ac_save_CPPFLAGS=$CPPFLAGS
2039     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2040     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2041     CPPFLAGS=$ac_save_CPPFLAGS
2042 fi
2043
2044 # check for <perl.h>
2045 if test "$with_perl" = yes; then
2046   ac_save_CPPFLAGS=$CPPFLAGS
2047   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2048   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2049                   [#include <EXTERN.h>])
2050   # While we're at it, check that we can link to libperl.
2051   # On most platforms, if perl.h is there then libperl.so will be too, but at
2052   # this writing Debian packages them separately.  There is no known reason to
2053   # waste cycles on separate probes for the Tcl or Python libraries, though.
2054   pgac_save_LIBS=$LIBS
2055   LIBS="$perl_embed_ldflags"
2056   AC_MSG_CHECKING([for libperl])
2057   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2058 #include <EXTERN.h>
2059 #include <perl.h>
2060 ],  [perl_alloc();])],
2061     [AC_MSG_RESULT(yes)],
2062     [AC_MSG_RESULT(no)
2063      AC_MSG_ERROR([libperl library is required for Perl])])
2064   LIBS=$pgac_save_LIBS
2065   CPPFLAGS=$ac_save_CPPFLAGS
2066 fi
2067
2068 # check for <Python.h>
2069 if test "$with_python" = yes; then
2070   ac_save_CPPFLAGS=$CPPFLAGS
2071   CPPFLAGS="$python_includespec $CPPFLAGS"
2072   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2073   CPPFLAGS=$ac_save_CPPFLAGS
2074 fi
2075
2076 #
2077 # Check for DocBook and tools
2078 #
2079 PGAC_PROG_NSGMLS
2080 PGAC_PROG_JADE
2081 PGAC_CHECK_DOCBOOK(4.2)
2082 PGAC_PATH_DOCBOOK_STYLESHEETS
2083 PGAC_PATH_COLLATEINDEX
2084 AC_CHECK_PROGS(DBTOEPUB, dbtoepub)
2085 AC_CHECK_PROGS(XMLLINT, xmllint)
2086 AC_CHECK_PROGS(XSLTPROC, xsltproc)
2087 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
2088
2089 #
2090 # Check for test tools
2091 #
2092 if test "$enable_tap_tests" = yes; then
2093   AC_CHECK_PROGS(PROVE, prove)
2094   if test -z "$PROVE"; then
2095     AC_MSG_ERROR([prove not found])
2096   fi
2097   if test -z "$PERL"; then
2098     AC_MSG_ERROR([Perl not found])
2099   fi
2100 fi
2101
2102 # Thread testing
2103
2104 # We have to run the thread test near the end so we have all our symbols
2105 # defined.  Cross compiling throws a warning.
2106 #
2107 if test "$enable_thread_safety" = yes; then
2108 if test "$PORTNAME" != "win32"
2109 then
2110 AC_MSG_CHECKING([thread safety of required library functions])
2111
2112 _CFLAGS="$CFLAGS"
2113 _LIBS="$LIBS"
2114 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2115 LIBS="$LIBS $PTHREAD_LIBS"
2116 AC_RUN_IFELSE(
2117   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2118   [AC_MSG_RESULT(yes)],
2119   [AC_MSG_RESULT(no)
2120   AC_MSG_ERROR([thread test program failed
2121 This platform is not thread-safe.  Check the file 'config.log' or compile
2122 and run src/test/thread/thread_test for the exact reason.
2123 Use --disable-thread-safety to disable thread safety.])],
2124   [AC_MSG_RESULT(maybe)
2125   AC_MSG_WARN([
2126 *** Skipping thread test program because of cross-compile build.
2127 *** Run the program in src/test/thread on the target machine.
2128 ])])
2129 CFLAGS="$_CFLAGS"
2130 LIBS="$_LIBS"
2131 else
2132 AC_MSG_WARN([*** skipping thread test on Win32])
2133 fi
2134 fi
2135
2136 # If compiler will take -Wl,--as-needed (or various platform-specific
2137 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2138 # trying to filter LIBS to the minimum for each executable.
2139 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2140 # libreadline; therefore we postpone testing it until we know what library
2141 # dependencies readline has.  The test code will try to link with $LIBS.
2142 if test "$with_readline" = yes; then
2143   link_test_func=readline
2144 else
2145   link_test_func=exit
2146 fi
2147
2148 if test "$PORTNAME" = "darwin"; then
2149   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2150 elif test "$PORTNAME" = "openbsd"; then
2151   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2152 else
2153   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2154 fi
2155
2156 # Create compiler version string
2157 if test x"$GCC" = x"yes" ; then
2158   cc_string=`${CC} --version | sed q`
2159   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2160 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2161   cc_string=`${CC} -V 2>&1 | sed q`
2162 else
2163   cc_string=$CC
2164 fi
2165
2166 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2167                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2168                    [A string containing the version number, platform, and C compiler])
2169
2170 # Supply a numeric version string for use by 3rd party add-ons
2171 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2172 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2173 tr '.' '        ' |
2174 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
2175 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2176 AC_SUBST(PG_VERSION_NUM)
2177
2178
2179 # Begin output steps
2180
2181 AC_MSG_NOTICE([using compiler=$cc_string])
2182 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2183 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2184 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2185
2186 # prepare build tree if outside source tree
2187 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2188 # Note 2: /bin/pwd might be better than shell's built-in at getting
2189 #         a symlink-free name.
2190 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2191   vpath_build=no
2192 else
2193   vpath_build=yes
2194   if test "$no_create" != yes; then
2195     _AS_ECHO_N([preparing build tree... ])
2196     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2197     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2198       || AC_MSG_ERROR(failed)
2199     AC_MSG_RESULT(done)
2200   fi
2201 fi
2202 AC_SUBST(vpath_build)
2203
2204
2205 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2206
2207 AC_CONFIG_LINKS([
2208   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2209   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2210   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2211   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2212   src/include/pg_config_os.h:src/include/port/${template}.h
2213   src/Makefile.port:src/makefiles/Makefile.${template}
2214 ])
2215
2216 if test "$PORTNAME" = "win32"; then
2217 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2218 # Links sometimes fail undetected on Mingw -
2219 # so here we detect it and warn the user
2220 for FILE in $CONFIG_LINKS
2221  do
2222         # test -e works for symlinks in the MinGW console
2223         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2224  done
2225 ])
2226 fi
2227
2228 AC_CONFIG_HEADERS([src/include/pg_config.h],
2229 [
2230 # Update timestamp for pg_config.h (see Makefile.global)
2231 echo >src/include/stamp-h
2232 ])
2233
2234 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2235 [
2236 # Update timestamp for pg_config_ext.h (see Makefile.global)
2237 echo >src/include/stamp-ext-h
2238 ])
2239
2240 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2241                   [echo >src/interfaces/ecpg/include/stamp-h])
2242
2243 AC_OUTPUT