granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.5devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2014, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sysv5*) template=unixware ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-bugs@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Add non-standard directories to the include path
 113 #
 114 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 115
 116
 117 #
 118 # Add non-standard directories to the library search path
 119 #
 120 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 121              [LIBRARY_DIRS=$withval])
 122
 123 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 124              [LIBRARY_DIRS=$withval])
 125
 126
 127 #
 128 # 64-bit integer date/time storage: enabled by default.
 129 #
 130 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 131 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 132               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 133                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 134 AC_MSG_RESULT([$enable_integer_datetimes])
 135
 136
 137 #
 138 # NLS
 139 #
 140 AC_MSG_CHECKING([whether NLS is wanted])
 141 PGAC_ARG_OPTARG(enable, nls,
 142                 [LANGUAGES], [enable Native Language Support],
 143                 [],
 144                 [WANTED_LANGUAGES=$enableval],
 145                 [AC_DEFINE(ENABLE_NLS, 1,
 146                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 147 AC_MSG_RESULT([$enable_nls])
 148 AC_SUBST(enable_nls)
 149 AC_SUBST(WANTED_LANGUAGES)
 150
 151 #
 152 # Default port number (--with-pgport), default 5432
 153 #
 154 AC_MSG_CHECKING([for default port number])
 155 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 156              [default_port=$withval],
 157              [default_port=5432])
 158 AC_MSG_RESULT([$default_port])
 159 # Need both of these because some places want an integer and some a string
 160 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 161 [Define to the default TCP port number on which the server listens and
 162 to which clients will try to connect.  This can be overridden at run-time,
 163 but it's convenient if your clients have the right default compiled in.
 164 (--with-pgport=PORTNUM)])
 165 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 166                    [Define to the default TCP port number as a string constant.])
 167 AC_SUBST(default_port)
 168
 169 #
 170 # '-rpath'-like feature can be disabled
 171 #
 172 PGAC_ARG_BOOL(enable, rpath, yes,
 173               [do not embed shared library search path in executables])
 174 AC_SUBST(enable_rpath)
 175
 176 #
 177 # Spinlocks
 178 #
 179 PGAC_ARG_BOOL(enable, spinlocks, yes,
 180               [do not use spinlocks])
 181
 182 #
 183 # --enable-debug adds -g to compiler flags
 184 #
 185 PGAC_ARG_BOOL(enable, debug, no,
 186               [build with debugging symbols (-g)])
 187 AC_SUBST(enable_debug)
 188
 189 #
 190 # --enable-profiling enables gcc profiling
 191 #
 192 PGAC_ARG_BOOL(enable, profiling, no,
 193               [build with profiling enabled ])
 194
 195 #
 196 # --enable-coverage enables generation of code coverage metrics with gcov
 197 #
 198 PGAC_ARG_BOOL(enable, coverage, no,
 199               [build with coverage testing instrumentation],
 200 [AC_CHECK_PROGS(GCOV, gcov)
 201 if test -z "$GCOV"; then
 202   AC_MSG_ERROR([gcov not found])
 203 fi
 204 AC_CHECK_PROGS(LCOV, lcov)
 205 if test -z "$LCOV"; then
 206   AC_MSG_ERROR([lcov not found])
 207 fi
 208 AC_CHECK_PROGS(GENHTML, genhtml)
 209 if test -z "$GENHTML"; then
 210   AC_MSG_ERROR([genhtml not found])
 211 fi])
 212 AC_SUBST(enable_coverage)
 213
 214 #
 215 # DTrace
 216 #
 217 PGAC_ARG_BOOL(enable, dtrace, no,
 218               [build with DTrace support],
 219 [AC_CHECK_PROGS(DTRACE, dtrace)
 220 if test -z "$DTRACE"; then
 221   AC_MSG_ERROR([dtrace not found])
 222 fi
 223 AC_SUBST(DTRACEFLAGS)])
 224 AC_SUBST(enable_dtrace)
 225
 226 #
 227 # Block size
 228 #
 229 AC_MSG_CHECKING([for block size])
 230 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 231              [blocksize=$withval],
 232              [blocksize=8])
 233 case ${blocksize} in
 234   1) BLCKSZ=1024;;
 235   2) BLCKSZ=2048;;
 236   4) BLCKSZ=4096;;
 237   8) BLCKSZ=8192;;
 238  16) BLCKSZ=16384;;
 239  32) BLCKSZ=32768;;
 240   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 241 esac
 242 AC_MSG_RESULT([${blocksize}kB])
 243
 244 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 245  Size of a disk block --- this also limits the size of a tuple.  You
 246  can set it bigger if you need bigger tuples (although TOAST should
 247  reduce the need to have large tuples, since fields can be spread
 248  across multiple tuples).
 249
 250  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 251  is currently 2^15 (32768).  This is determined by the 15-bit widths
 252  of the lp_off and lp_len fields in ItemIdData (see
 253  include/storage/itemid.h).
 254
 255  Changing BLCKSZ requires an initdb.
 256 ])
 257
 258 #
 259 # Relation segment size
 260 #
 261 AC_MSG_CHECKING([for segment size])
 262 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 263              [segsize=$withval],
 264              [segsize=1])
 265 # this expression is set up to avoid unnecessary integer overflow
 266 # blocksize is already guaranteed to be a factor of 1024
 267 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 268 test $? -eq 0 || exit 1
 269 AC_MSG_RESULT([${segsize}GB])
 270
 271 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 272  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 273  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 274  relations bigger than that are divided into multiple files.
 275
 276  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 277  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 278  have large file support enabled.  By default, we make the limit 1 GB
 279  to avoid any possible integer-overflow problems within the OS.
 280  A limit smaller than necessary only means we divide a large
 281  relation into more chunks than necessary, so it seems best to err
 282  in the direction of a small limit.
 283
 284  A power-of-2 value is recommended to save a few cycles in md.c,
 285  but is not absolutely required.
 286
 287  Changing RELSEG_SIZE requires an initdb.
 288 ])
 289
 290 #
 291 # WAL block size
 292 #
 293 AC_MSG_CHECKING([for WAL block size])
 294 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 295              [wal_blocksize=$withval],
 296              [wal_blocksize=8])
 297 case ${wal_blocksize} in
 298   1) XLOG_BLCKSZ=1024;;
 299   2) XLOG_BLCKSZ=2048;;
 300   4) XLOG_BLCKSZ=4096;;
 301   8) XLOG_BLCKSZ=8192;;
 302  16) XLOG_BLCKSZ=16384;;
 303  32) XLOG_BLCKSZ=32768;;
 304  64) XLOG_BLCKSZ=65536;;
 305   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 306 esac
 307 AC_MSG_RESULT([${wal_blocksize}kB])
 308
 309 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 310  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 311  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 312  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 313  buffers, else direct I/O may fail.
 314
 315  Changing XLOG_BLCKSZ requires an initdb.
 316 ])
 317
 318 #
 319 # WAL segment size
 320 #
 321 AC_MSG_CHECKING([for WAL segment size])
 322 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 323              [wal_segsize=$withval],
 324              [wal_segsize=16])
 325 case ${wal_segsize} in
 326   1) ;;
 327   2) ;;
 328   4) ;;
 329   8) ;;
 330  16) ;;
 331  32) ;;
 332  64) ;;
 333   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_segsize}MB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 338  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 339  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 340  XLOG_BLCKSZ).
 341
 342  Changing XLOG_SEG_SIZE requires an initdb.
 343 ])
 344
 345 #
 346 # C compiler
 347 #
 348
 349 # For historical reasons you can also use --with-CC to specify the C compiler
 350 # to use, although the standard way to do this is to set the CC environment
 351 # variable.
 352 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 353
 354 case $template in
 355   aix) pgac_cc_list="gcc xlc";;
 356     *) pgac_cc_list="gcc cc";;
 357 esac
 358
 359 AC_PROG_CC([$pgac_cc_list])
 360
 361 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 362 # but has idiosyncrasies of its own.  We assume icc will define
 363 # __INTEL_COMPILER regardless of CFLAGS.
 364 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 365 choke me
 366 @%:@endif], [ICC=[yes]], [ICC=[no]])
 367
 368 # Check if it's Sun Studio compiler. We assume that
 369 # __SUNPRO_C will be defined for Sun Studio compilers
 370 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 371 choke me
 372 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 373
 374 AC_SUBST(SUN_STUDIO_CC)
 375
 376 unset CFLAGS
 377
 378 #
 379 # Read the template
 380 #
 381 . "$srcdir/src/template/$template" || exit
 382
 383 # CFLAGS are selected so:
 384 # If the user specifies something in the environment, that is used.
 385 # else:  If the template file set something, that is used.
 386 # else:  If coverage was enabled, don't set anything.
 387 # else:  If the compiler is GCC, then we use -O2.
 388 # else:  If the compiler is something else, then we use -O, unless debugging.
 389
 390 if test "$ac_env_CFLAGS_set" = set; then
 391   CFLAGS=$ac_env_CFLAGS_value
 392 elif test "${CFLAGS+set}" = set; then
 393   : # (keep what template set)
 394 elif test "$enable_coverage" = yes; then
 395   : # no optimization by default
 396 elif test "$GCC" = yes; then
 397   CFLAGS="-O2"
 398 else
 399   # if the user selected debug mode, don't use -O
 400   if test "$enable_debug" != yes; then
 401     CFLAGS="-O"
 402   fi
 403 fi
 404
 405 # set CFLAGS_VECTOR from the environment, if available
 406 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 407   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 408 fi
 409
 410 # Some versions of GCC support some additional useful warning flags.
 411 # Check whether they are supported, and add them to CFLAGS if so.
 412 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 413 # but has its own.  Also check other compiler-specific flags here.
 414
 415 if test "$GCC" = yes -a "$ICC" = no; then
 416   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 417   # These work in some but not all gcc versions
 418   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 419   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 420   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 421   # This was included in -Wall/-Wformat in older GCC versions
 422   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 423   # Disable strict-aliasing rules; needed for gcc 3.3+
 424   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 425   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 426   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 427   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 428   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 429   # Optimization flags for specific files that benefit from vectorization
 430   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 431   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 432 elif test "$ICC" = yes; then
 433   # Intel's compiler has a bug/misoptimization in checking for
 434   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 435   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 436   # Make sure strict aliasing is off (though this is said to be the default)
 437   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 438 elif test "$PORTNAME" = "aix"; then
 439   # AIX's xlc has to have strict aliasing turned off too
 440   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 441 elif test "$PORTNAME" = "hpux"; then
 442   # On some versions of HP-UX, libm functions do not set errno by default.
 443   # Fix that by using +Olibmerrno if the compiler recognizes it.
 444   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 445 fi
 446
 447 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 448
 449 # supply -g if --enable-debug
 450 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 451   CFLAGS="$CFLAGS -g"
 452 fi
 453
 454 # enable code coverage if --enable-coverage
 455 if test "$enable_coverage" = yes; then
 456   if test "$GCC" = yes; then
 457     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 458   else
 459     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 460   fi
 461 fi
 462
 463 # enable profiling if --enable-profiling
 464 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 465   if test "$GCC" = yes; then
 466     AC_DEFINE([PROFILE_PID_DIR], 1,
 467            [Define to 1 to allow profiling output to be saved separately for each process.])
 468     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 469   else
 470     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 471   fi
 472 fi
 473
 474 # We already have this in Makefile.win32, but configure needs it too
 475 if test "$PORTNAME" = "win32"; then
 476   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 477 fi
 478
 479 # Check if the compiler still works with the template settings
 480 AC_MSG_CHECKING([whether the C compiler still works])
 481 AC_TRY_LINK([], [return 0;],
 482   [AC_MSG_RESULT(yes)],
 483   [AC_MSG_RESULT(no)
 484    AC_MSG_ERROR([cannot proceed])])
 485
 486 # Defend against gcc -ffast-math
 487 if test "$GCC" = yes; then
 488 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 489 choke me
 490 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 491 fi
 492
 493 AC_PROG_CPP
 494 AC_SUBST(GCC)
 495
 496
 497 #
 498 # Set up TAS assembly code if needed; the template file has now had its
 499 # chance to request this.
 500 #
 501 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 502
 503 if test "$need_tas" = yes ; then
 504   TAS=tas.o
 505 else
 506   TAS=""
 507 fi
 508 AC_SUBST(TAS)
 509
 510
 511 #
 512 # Automatic dependency tracking
 513 #
 514 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 515               [autodepend=yes])
 516 AC_SUBST(autodepend)
 517
 518
 519 #
 520 # Enable assert checks
 521 #
 522 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 523               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 524                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 525
 526
 527 #
 528 # Include directories
 529 #
 530 ac_save_IFS=$IFS
 531 IFS="${IFS}${PATH_SEPARATOR}"
 532 # SRCH_INC comes from the template file
 533 for dir in $with_includes $SRCH_INC; do
 534   if test -d "$dir"; then
 535     INCLUDES="$INCLUDES -I$dir"
 536   else
 537     AC_MSG_WARN([*** Include directory $dir does not exist.])
 538   fi
 539 done
 540 IFS=$ac_save_IFS
 541 AC_SUBST(INCLUDES)
 542
 543
 544 #
 545 # Library directories
 546 #
 547 ac_save_IFS=$IFS
 548 IFS="${IFS}${PATH_SEPARATOR}"
 549 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 550 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 551   if test -d "$dir"; then
 552     LIBDIRS="$LIBDIRS -L$dir"
 553   else
 554     AC_MSG_WARN([*** Library directory $dir does not exist.])
 555   fi
 556 done
 557 IFS=$ac_save_IFS
 558
 559 #
 560 # Enable thread-safe client libraries
 561 #
 562 AC_MSG_CHECKING([allow thread-safe client libraries])
 563 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 564 if test "$enable_thread_safety" = yes; then
 565   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 566           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 567 fi
 568 AC_MSG_RESULT([$enable_thread_safety])
 569 AC_SUBST(enable_thread_safety)
 570
 571 #
 572 # Optionally build Tcl modules (PL/Tcl)
 573 #
 574 AC_MSG_CHECKING([whether to build with Tcl])
 575 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 576 AC_MSG_RESULT([$with_tcl])
 577 AC_SUBST([with_tcl])
 578
 579 # We see if the path to the Tcl/Tk configuration scripts is specified.
 580 # This will override the use of tclsh to find the paths to search.
 581
 582 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 583
 584 #
 585 # Optionally build Perl modules (PL/Perl)
 586 #
 587 AC_MSG_CHECKING([whether to build Perl modules])
 588 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 589 AC_MSG_RESULT([$with_perl])
 590 AC_SUBST(with_perl)
 591
 592 #
 593 # Optionally build Python modules (PL/Python)
 594 #
 595 AC_MSG_CHECKING([whether to build Python modules])
 596 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 597 AC_MSG_RESULT([$with_python])
 598 AC_SUBST(with_python)
 599
 600 #
 601 # GSSAPI
 602 #
 603 AC_MSG_CHECKING([whether to build with GSSAPI support])
 604 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 605 [
 606   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 607   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 608 ])
 609 AC_MSG_RESULT([$with_gssapi])
 610
 611
 612 AC_SUBST(krb_srvtab)
 613
 614
 615 #
 616 # Kerberos configuration parameters
 617 #
 618 PGAC_ARG_REQ(with, krb-srvnam,
 619              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 620              [],
 621              [with_krb_srvnam="postgres"])
 622 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 623                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 624
 625
 626 #
 627 # PAM
 628 #
 629 AC_MSG_CHECKING([whether to build with PAM support])
 630 PGAC_ARG_BOOL(with, pam, no,
 631               [build with PAM support],
 632               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 633 AC_MSG_RESULT([$with_pam])
 634
 635
 636 #
 637 # LDAP
 638 #
 639 AC_MSG_CHECKING([whether to build with LDAP support])
 640 PGAC_ARG_BOOL(with, ldap, no,
 641               [build with LDAP support],
 642               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 643 AC_MSG_RESULT([$with_ldap])
 644
 645
 646 #
 647 # Bonjour
 648 #
 649 AC_MSG_CHECKING([whether to build with Bonjour support])
 650 PGAC_ARG_BOOL(with, bonjour, no,
 651               [build with Bonjour support],
 652               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 653 AC_MSG_RESULT([$with_bonjour])
 654
 655
 656 #
 657 # OpenSSL
 658 #
 659 AC_MSG_CHECKING([whether to build with OpenSSL support])
 660 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 661               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 662 AC_MSG_RESULT([$with_openssl])
 663 AC_SUBST(with_openssl)
 664
 665 #
 666 # SELinux
 667 #
 668 AC_MSG_CHECKING([whether to build with SELinux support])
 669 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 670 AC_SUBST(with_selinux)
 671 AC_MSG_RESULT([$with_selinux])
 672
 673 #
 674 # Readline
 675 #
 676 PGAC_ARG_BOOL(with, readline, yes,
 677               [do not use GNU Readline nor BSD Libedit for editing])
 678 # readline on MinGW has problems with backslashes in psql and other bugs.
 679 # This is particularly a problem with non-US code pages.
 680 # Therefore disable its use until we understand the cause. 2004-07-20
 681 if test "$PORTNAME" = "win32"; then
 682   if test "$with_readline" = yes; then
 683     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 684     with_readline=no
 685   fi
 686 fi
 687
 688
 689 #
 690 # Prefer libedit
 691 #
 692 PGAC_ARG_BOOL(with, libedit-preferred, no,
 693               [prefer BSD Libedit over GNU Readline])
 694
 695
 696 #
 697 # UUID library
 698 #
 699 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 700 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 701 # UUID library.  More than one of these might be present on a given platform,
 702 # so we make the user say which one she wants.
 703 #
 704 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 705 if test x"$with_uuid" = x"" ; then
 706   with_uuid=no
 707 fi
 708 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 709 if test "$with_ossp_uuid" = yes ; then
 710   with_uuid=ossp
 711 fi
 712
 713 if test "$with_uuid" = bsd ; then
 714   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 715   UUID_EXTRA_OBJS="md5.o sha1.o"
 716 elif test "$with_uuid" = e2fs ; then
 717   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 718   UUID_EXTRA_OBJS="md5.o sha1.o"
 719 elif test "$with_uuid" = ossp ; then
 720   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 721   UUID_EXTRA_OBJS=""
 722 elif test "$with_uuid" = no ; then
 723   UUID_EXTRA_OBJS=""
 724 else
 725   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 726 fi
 727 AC_SUBST(with_uuid)
 728 AC_SUBST(UUID_EXTRA_OBJS)
 729
 730
 731 #
 732 # XML
 733 #
 734 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 735               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 736
 737 if test "$with_libxml" = yes ; then
 738   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 739   if test -n "$XML2_CONFIG"; then
 740     for pgac_option in `$XML2_CONFIG --cflags`; do
 741       case $pgac_option in
 742         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 743       esac
 744     done
 745     for pgac_option in `$XML2_CONFIG --libs`; do
 746       case $pgac_option in
 747         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 748       esac
 749     done
 750   fi
 751 fi
 752
 753 AC_SUBST(with_libxml)
 754
 755 #
 756 # XSLT
 757 #
 758 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 759               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 760
 761
 762 AC_SUBST(with_libxslt)
 763
 764 #
 765 # tzdata
 766 #
 767 PGAC_ARG_REQ(with, system-tzdata,
 768              [DIR], [use system time zone data in DIR])
 769 AC_SUBST(with_system_tzdata)
 770
 771 #
 772 # Zlib
 773 #
 774 PGAC_ARG_BOOL(with, zlib, yes,
 775               [do not use Zlib])
 776 AC_SUBST(with_zlib)
 777
 778 #
 779 # Elf
 780 #
 781
 782 # Assume system is ELF if it predefines __ELF__ as 1,
 783 # otherwise believe host_os based default.
 784 case $host_os in
 785     freebsd1*|freebsd2*) elf=no;;
 786     freebsd3*|freebsd4*) elf=yes;;
 787 esac
 788
 789 AC_EGREP_CPP(yes,
 790 [#if __ELF__
 791   yes
 792 #endif
 793 ],
 794 [ELF_SYS=true],
 795 [if test "X$elf" = "Xyes" ; then
 796   ELF_SYS=true
 797 else
 798   ELF_SYS=
 799 fi])
 800 AC_SUBST(ELF_SYS)
 801
 802 #
 803 # Assignments
 804 #
 805
 806 CPPFLAGS="$CPPFLAGS $INCLUDES"
 807 LDFLAGS="$LDFLAGS $LIBDIRS"
 808
 809 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 810 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 811
 812 PGAC_PROG_LD
 813 AC_SUBST(LD)
 814 AC_SUBST(with_gnu_ld)
 815 case $host_os in sysv5*)
 816   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 817   [
 818     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 819     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 820     LDFLAGS=$pgac_save_LDFLAGS
 821   ])
 822   ld_R_works=$pgac_cv_prog_ld_R
 823   AC_SUBST(ld_R_works)
 824 esac
 825 AC_PROG_RANLIB
 826 PGAC_CHECK_STRIP
 827 AC_CHECK_TOOL(AR, ar, ar)
 828 if test "$PORTNAME" = "win32"; then
 829   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 830   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 831   AC_CHECK_TOOL(WINDRES, windres, windres)
 832 fi
 833
 834 AC_PROG_INSTALL
 835 # When Autoconf chooses install-sh as install program it tries to generate
 836 # a relative path to it in each makefile where it subsitutes it. This clashes
 837 # with our Makefile.global concept. This workaround helps.
 838 case $INSTALL in
 839   *install-sh*) install_bin='';;
 840   *) install_bin=$INSTALL;;
 841 esac
 842 AC_SUBST(install_bin)
 843
 844 AC_PATH_PROG(TAR, tar)
 845 AC_PROG_LN_S
 846 AC_PROG_AWK
 847 AC_PROG_MKDIR_P
 848 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 849 # a relative path to it in each makefile where it subsitutes it. This clashes
 850 # with our Makefile.global concept. This workaround helps.
 851 case $MKDIR_P in
 852   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 853 esac
 854
 855 PGAC_PATH_BISON
 856 PGAC_PATH_FLEX
 857
 858 PGAC_PATH_PERL
 859 if test "$with_perl" = yes; then
 860   if test -z "$PERL"; then
 861     AC_MSG_ERROR([Perl not found])
 862   fi
 863   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 864   PGAC_CHECK_PERL_EMBED_LDFLAGS
 865 fi
 866
 867 if test "$with_python" = yes; then
 868   PGAC_PATH_PYTHON
 869   PGAC_CHECK_PYTHON_EMBED_SETUP
 870 fi
 871
 872 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 873   AC_PATH_PROG(ZIC, zic)
 874   if test -z "$ZIC"; then
 875     AC_MSG_ERROR([
 876 When cross-compiling, either use the option --with-system-tzdata to use
 877 existing time-zone data, or set the environment variable ZIC to a zic
 878 program to use during the build.])
 879   fi
 880 fi
 881
 882
 883 ##
 884 ## Libraries
 885 ##
 886 ## Most libraries are included only if they demonstrably provide a function
 887 ## we need, but libm is an exception: always include it, because there are
 888 ## too many compilers that play cute optimization games that will break
 889 ## probes for standard functions such as pow().
 890 ##
 891
 892 AC_CHECK_LIB(m, main)
 893 AC_SEARCH_LIBS(setproctitle, util)
 894 AC_SEARCH_LIBS(dlopen, dl)
 895 AC_SEARCH_LIBS(socket, [socket wsock32])
 896 AC_SEARCH_LIBS(shl_load, dld)
 897 # We only use libld in port/dynloader/aix.c
 898 case $host_os in
 899      aix*)
 900         AC_SEARCH_LIBS(ldopen, ld)
 901         ;;
 902 esac
 903 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 904 AC_SEARCH_LIBS(crypt, crypt)
 905 AC_SEARCH_LIBS(shm_open, rt)
 906 AC_SEARCH_LIBS(shm_unlink, rt)
 907 # Solaris:
 908 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 909 # Required for thread_test.c on Solaris 2.5:
 910 # Other ports use it too (HP-UX) so test unconditionally
 911 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 912 # Cygwin:
 913 AC_SEARCH_LIBS(shmget, cygipc)
 914
 915 if test "$with_readline" = yes; then
 916   PGAC_CHECK_READLINE
 917   if test x"$pgac_cv_check_readline" = x"no"; then
 918     AC_MSG_ERROR([readline library not found
 919 If you have readline already installed, see config.log for details on the
 920 failure.  It is possible the compiler isn't looking in the proper directory.
 921 Use --without-readline to disable readline support.])
 922   fi
 923 fi
 924
 925 if test "$with_zlib" = yes; then
 926   AC_CHECK_LIB(z, inflate, [],
 927                [AC_MSG_ERROR([zlib library not found
 928 If you have zlib already installed, see config.log for details on the
 929 failure.  It is possible the compiler isn't looking in the proper directory.
 930 Use --without-zlib to disable zlib support.])])
 931 fi
 932
 933 if test "$enable_spinlocks" = yes; then
 934   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 935 else
 936   AC_MSG_WARN([
 937 *** Not using spinlocks will cause poor performance.])
 938 fi
 939
 940 if test "$with_gssapi" = yes ; then
 941   if test "$PORTNAME" != "win32"; then
 942     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 943                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 944   else
 945     LIBS="$LIBS -lgssapi32"
 946   fi
 947 fi
 948
 949 if test "$with_openssl" = yes ; then
 950   dnl Order matters!
 951   if test "$PORTNAME" != "win32"; then
 952      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 953      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 954   else
 955      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 956      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 957   fi
 958 fi
 959
 960 if test "$with_pam" = yes ; then
 961   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 962 fi
 963
 964 if test "$with_libxml" = yes ; then
 965   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 966 fi
 967
 968 if test "$with_libxslt" = yes ; then
 969   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 970 fi
 971
 972 # for contrib/sepgsql
 973 if test "$with_selinux" = yes; then
 974   AC_CHECK_LIB(selinux, security_compute_create_name, [],
 975                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
 976 fi
 977
 978 # for contrib/uuid-ossp
 979 if test "$with_uuid" = bsd ; then
 980   # On BSD, the UUID functions are in libc
 981   AC_CHECK_FUNC(uuid_to_string,
 982     [UUID_LIBS=""],
 983     [AC_MSG_ERROR([BSD UUID functions are not present])])
 984 elif test "$with_uuid" = e2fs ; then
 985   # On OS X, the UUID functions are in libc
 986   AC_CHECK_FUNC(uuid_generate,
 987     [UUID_LIBS=""],
 988     [AC_CHECK_LIB(uuid, uuid_generate,
 989       [UUID_LIBS="-luuid"],
 990       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
 991 elif test "$with_uuid" = ossp ; then
 992   AC_CHECK_LIB(ossp-uuid, uuid_export,
 993     [UUID_LIBS="-lossp-uuid"],
 994     [AC_CHECK_LIB(uuid, uuid_export,
 995       [UUID_LIBS="-luuid"],
 996       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
 997 fi
 998 AC_SUBST(UUID_LIBS)
 999
1000
1001 ##
1002 ## Header files
1003 ##
1004
1005 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
1006 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1007
1008 # On BSD, test for net/if.h will fail unless sys/socket.h
1009 # is included first.
1010 AC_CHECK_HEADERS(net/if.h, [], [],
1011 [AC_INCLUDES_DEFAULT
1012 #ifdef HAVE_SYS_SOCKET_H
1013 #include <sys/socket.h>
1014 #endif
1015 ])
1016
1017 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1018 # is included first.
1019 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1020 [AC_INCLUDES_DEFAULT
1021 #include <sys/param.h>
1022 ])
1023
1024 # At least on IRIX, test for netinet/tcp.h will fail unless
1025 # netinet/in.h is included first.
1026 AC_CHECK_HEADERS(netinet/in.h)
1027 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1028 [AC_INCLUDES_DEFAULT
1029 #ifdef HAVE_NETINET_IN_H
1030 #include <netinet/in.h>
1031 #endif
1032 ])
1033
1034 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1035   AC_CHECK_HEADERS(readline/readline.h, [],
1036         [AC_CHECK_HEADERS(readline.h, [],
1037                 [AC_MSG_ERROR([readline header not found
1038 If you have readline already installed, see config.log for details on the
1039 failure.  It is possible the compiler isn't looking in the proper directory.
1040 Use --without-readline to disable readline support.])])])
1041   AC_CHECK_HEADERS(readline/history.h, [],
1042         [AC_CHECK_HEADERS(history.h, [],
1043                 [AC_MSG_ERROR([history header not found
1044 If you have readline already installed, see config.log for details on the
1045 failure.  It is possible the compiler isn't looking in the proper directory.
1046 Use --without-readline to disable readline support.])])])
1047 fi
1048
1049 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1050 # Some installations of libedit usurp /usr/include/readline/, which seems
1051 # bad practice, since in combined installations readline will have its headers
1052 # there.  We might have to resort to AC_EGREP checks to make sure we found
1053 # the proper header...
1054   AC_CHECK_HEADERS(editline/readline.h, [],
1055         [AC_CHECK_HEADERS(readline.h, [],
1056                 [AC_CHECK_HEADERS(readline/readline.h, [],
1057                         [AC_MSG_ERROR([readline header not found
1058 If you have libedit already installed, see config.log for details on the
1059 failure.  It is possible the compiler isn't looking in the proper directory.
1060 Use --without-readline to disable libedit support.])])])])
1061 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1062 # not be there at all.  Hence, don't complain if not found.  We must check
1063 # though, since in yet other versions it is an independent header.
1064   AC_CHECK_HEADERS(editline/history.h, [],
1065         [AC_CHECK_HEADERS(history.h, [],
1066                 [AC_CHECK_HEADERS(readline/history.h)])])
1067 fi
1068
1069 if test "$with_zlib" = yes; then
1070   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1071 If you have zlib already installed, see config.log for details on the
1072 failure.  It is possible the compiler isn't looking in the proper directory.
1073 Use --without-zlib to disable zlib support.])])
1074 fi
1075
1076 if test "$with_gssapi" = yes ; then
1077   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1078         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1079 fi
1080
1081 if test "$with_openssl" = yes ; then
1082   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1083   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1084 fi
1085
1086 if test "$with_pam" = yes ; then
1087   AC_CHECK_HEADERS(security/pam_appl.h, [],
1088                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1089                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1090 fi
1091
1092 if test "$with_libxml" = yes ; then
1093   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1094 fi
1095
1096 if test "$with_libxslt" = yes ; then
1097   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1098 fi
1099
1100 if test "$with_ldap" = yes ; then
1101   if test "$PORTNAME" != "win32"; then
1102      AC_CHECK_HEADERS(ldap.h, [],
1103                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1104   else
1105      AC_CHECK_HEADERS(winldap.h, [],
1106                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1107                       [AC_INCLUDES_DEFAULT
1108 #include <windows.h>
1109                       ])
1110   fi
1111 fi
1112
1113 if test "$with_bonjour" = yes ; then
1114   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1115 fi
1116
1117 # for contrib/uuid-ossp
1118 if test "$with_uuid" = bsd ; then
1119   AC_CHECK_HEADERS(uuid.h,
1120     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1121       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1122     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1123 elif test "$with_uuid" = e2fs ; then
1124   AC_CHECK_HEADERS(uuid/uuid.h,
1125     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1126       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1127     [AC_CHECK_HEADERS(uuid.h,
1128       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1129         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1130       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1131 elif test "$with_uuid" = ossp ; then
1132   AC_CHECK_HEADERS(ossp/uuid.h,
1133     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1134       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1135     [AC_CHECK_HEADERS(uuid.h,
1136       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1137         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1138       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1139 fi
1140
1141 if test "$PORTNAME" = "win32" ; then
1142    AC_CHECK_HEADERS(crtdefs.h)
1143 fi
1144
1145 ##
1146 ## Types, structures, compiler characteristics
1147 ##
1148
1149 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1150 AC_C_BIGENDIAN
1151 PGAC_C_INLINE
1152 AC_C_FLEXIBLE_ARRAY_MEMBER
1153 PGAC_C_SIGNED
1154 PGAC_C_FUNCNAME_SUPPORT
1155 PGAC_C_STATIC_ASSERT
1156 PGAC_C_TYPES_COMPATIBLE
1157 PGAC_C_BUILTIN_CONSTANT_P
1158 PGAC_C_BUILTIN_UNREACHABLE
1159 PGAC_C_VA_ARGS
1160 PGAC_STRUCT_TIMEZONE
1161 PGAC_UNION_SEMUN
1162 PGAC_STRUCT_SOCKADDR_UN
1163 PGAC_STRUCT_SOCKADDR_STORAGE
1164 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1165 PGAC_STRUCT_ADDRINFO
1166 AC_TYPE_INTPTR_T
1167 AC_TYPE_UINTPTR_T
1168 AC_TYPE_LONG_LONG_INT
1169
1170 PGAC_TYPE_LOCALE_T
1171
1172 AC_CHECK_TYPES([struct cmsgcred], [], [],
1173 [#include <sys/socket.h>
1174 #include <sys/param.h>
1175 #ifdef HAVE_SYS_UCRED_H
1176 #include <sys/ucred.h>
1177 #endif])
1178
1179 AC_CHECK_TYPES([struct option], [], [],
1180 [#ifdef HAVE_GETOPT_H
1181 #include <getopt.h>
1182 #endif])
1183
1184 if test "$with_zlib" = yes; then
1185   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1186   # did not).  While we could work around the lack of z_streamp, it
1187   # seems unwise to encourage people to use such old zlib versions...
1188   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1189 Use --without-zlib to disable zlib support.])],
1190                 [#include <zlib.h>])
1191 fi
1192
1193 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1194 case $host_cpu in
1195   ppc*|powerpc*)
1196     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1197     AC_TRY_COMPILE([],
1198         [int a = 0; int *p = &a; int r;
1199          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1200         [pgac_cv_have_ppc_mutex_hint=yes],
1201         [pgac_cv_have_ppc_mutex_hint=no])
1202     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1203     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1204         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1205     fi
1206   ;;
1207 esac
1208
1209 # Check largefile support.  You might think this is a system service not a
1210 # compiler characteristic, but you'd be wrong.  We must check this before
1211 # probing existence of related functions such as fseeko, since the largefile
1212 # defines can affect what is generated for that.
1213 if test "$PORTNAME" != "win32"; then
1214    AC_SYS_LARGEFILE
1215    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1216    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on OS X 10.5 that activates a
1217    dnl bug that causes readdir() to sometimes return EINVAL.  On later OS X
1218    dnl versions where the feature actually works, it's on by default anyway.
1219    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1220 fi
1221
1222 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1223 AC_CHECK_SIZEOF([off_t])
1224
1225 # If we don't have largefile support, can't handle segsize >= 2GB.
1226 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1227    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1228 fi
1229
1230
1231 ##
1232 ## Functions, global variables
1233 ##
1234
1235 PGAC_VAR_INT_TIMEZONE
1236 AC_FUNC_ACCEPT_ARGTYPES
1237 PGAC_FUNC_GETTIMEOFDAY_1ARG
1238
1239 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1240 # symbols that that library has no business exposing to the world.  Pending
1241 # acquisition of a clue by those developers, ignore libedit (including its
1242 # possible alias of libreadline) while checking for everything else.
1243 LIBS_including_readline="$LIBS"
1244 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1245
1246 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid shm_open sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1247
1248 AC_REPLACE_FUNCS(fseeko)
1249 case $host_os in
1250         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1251         # Mingw uses macros to access Win32 API calls
1252         netbsd*|mingw*)
1253                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1254                 ac_cv_func_fseeko=yes;;
1255         *)
1256                 AC_FUNC_FSEEKO;;
1257 esac
1258
1259 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1260 # by calling it, 2009-04-02
1261 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1262 if test "$PORTNAME" != "solaris"; then
1263 AC_CHECK_FUNCS(posix_fadvise)
1264 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1265 fi
1266
1267 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1268 AC_CHECK_DECLS([strlcat, strlcpy])
1269 # This is probably only present on Darwin, but may as well check always
1270 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1271
1272 HAVE_IPV6=no
1273 AC_CHECK_TYPE([struct sockaddr_in6],
1274         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1275          HAVE_IPV6=yes],
1276         [],
1277 [$ac_includes_default
1278 #include <netinet/in.h>])
1279 AC_SUBST(HAVE_IPV6)
1280
1281 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1282 [AC_TRY_LINK(
1283 [#include <machine/vmparam.h>
1284 #include <sys/exec.h>
1285 ],
1286 [PS_STRINGS->ps_nargvstr = 1;
1287 PS_STRINGS->ps_argvstr = "foo";],
1288 [pgac_cv_var_PS_STRINGS=yes],
1289 [pgac_cv_var_PS_STRINGS=no])])
1290 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1291   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1292 fi
1293
1294
1295 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1296 # is missing.  Yes, there are machines that have only one.  We may
1297 # also decide to use snprintf.c if snprintf() is present but does not
1298 # have all the features we need --- see below.
1299
1300 if test "$PORTNAME" = "win32"; then
1301   # Win32 gets snprintf.c built unconditionally.
1302   #
1303   # To properly translate all NLS languages strings, we must support the
1304   # *printf() %$ format, which allows *printf() arguments to be selected
1305   # by position in the translated string.
1306   #
1307   # libintl versions < 0.13 use the native *printf() functions, and Win32
1308   # *printf() doesn't understand %$, so we must use our /port versions,
1309   # which do understand %$. libintl versions >= 0.13 include their own
1310   # *printf versions on Win32.  The libintl 0.13 release note text is:
1311   #
1312   #   C format strings with positions, as they arise when a translator
1313   #   needs to reorder a sentence, are now supported on all platforms.
1314   #   On those few platforms (NetBSD and Woe32) for which the native
1315   #   printf()/fprintf()/... functions don't support such format
1316   #   strings, replacements are provided through <libintl.h>.
1317   #
1318   # We could use libintl >= 0.13's *printf() if we were sure that we had
1319   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1320   # to guarantee that, it is best to just use our own, so we are sure to
1321   # get %$ support. In include/port.h we disable the *printf() macros
1322   # that might have been defined by libintl.
1323   #
1324   # We do this unconditionally whether NLS is used or not so we are sure
1325   # that all Win32 libraries and binaries behave the same.
1326   pgac_need_repl_snprintf=yes
1327 else
1328   pgac_need_repl_snprintf=no
1329   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1330   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1331 fi
1332
1333
1334 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1335 # include/c.h will provide declarations.  Note this is a separate test
1336 # from whether the functions exist in the C library --- there are
1337 # systems that have the functions but don't bother to declare them :-(
1338
1339 AC_CHECK_DECLS([snprintf, vsnprintf])
1340
1341
1342 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1343 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1344 [AC_TRY_LINK([
1345 #include <math.h>
1346 double glob_double;
1347 ],
1348 [return isinf(glob_double) ? 0 : 1;],
1349 [ac_cv_func_isinf=yes],
1350 [ac_cv_func_isinf=no])])
1351
1352 if test $ac_cv_func_isinf = yes ; then
1353   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1354 else
1355   AC_LIBOBJ(isinf)
1356   # Look for a way to implement a substitute for isinf()
1357   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1358 fi
1359
1360 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy])
1361
1362 case $host_os in
1363
1364         # Windows uses a specialised env handler
1365         # and doesn't need a replacement getpeereid because it doesn't use
1366         # Unix sockets.
1367         mingw*)
1368                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1369                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1370                 ac_cv_func_unsetenv=yes
1371                 ac_cv_func_getpeereid=yes;;
1372         *)
1373                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1374                 ;;
1375 esac
1376
1377 # System's version of getaddrinfo(), if any, may be used only if we found
1378 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1379 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1380 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1381 # because we want to use our own getaddrinfo.c on Windows anyway.)
1382 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1383   AC_REPLACE_FUNCS([getaddrinfo])
1384 else
1385   AC_LIBOBJ(getaddrinfo)
1386 fi
1387
1388 # Similarly, use system's getopt_long() only if system provides struct option.
1389 if test x"$ac_cv_type_struct_option" = xyes ; then
1390   AC_REPLACE_FUNCS([getopt_long])
1391 else
1392   AC_LIBOBJ(getopt_long)
1393 fi
1394
1395 # Solaris' getopt() doesn't do what we want for long options, so always use
1396 # our version on that platform.
1397 if test "$PORTNAME" = "solaris"; then
1398   AC_LIBOBJ(getopt)
1399 fi
1400
1401 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1402 # so always use our version on Windows.
1403 if test "$PORTNAME" = "win32"; then
1404   AC_LIBOBJ(getopt)
1405   AC_LIBOBJ(getopt_long)
1406 fi
1407
1408 # Win32 support
1409 if test "$PORTNAME" = "win32"; then
1410   AC_REPLACE_FUNCS(gettimeofday)
1411   AC_LIBOBJ(kill)
1412   AC_LIBOBJ(open)
1413   AC_LIBOBJ(system)
1414   AC_LIBOBJ(win32env)
1415   AC_LIBOBJ(win32error)
1416   AC_LIBOBJ(win32setlocale)
1417   AC_DEFINE([HAVE_SYMLINK], 1,
1418             [Define to 1 if you have the `symlink' function.])
1419   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1420 #define WIN32_LEAN_AND_MEAN
1421 #include <windows.h>
1422 #include <string.h>
1423 #include <dbghelp.h>])
1424 fi
1425 if test x"$pgac_minidump_type" = x"yes" ; then
1426   AC_SUBST(have_win32_dbghelp,yes)
1427 else
1428   AC_SUBST(have_win32_dbghelp,no)
1429 fi
1430
1431 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1432 dnl (especially on GNU libc)
1433 dnl See also comments in c.h.
1434 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1435 [AC_TRY_LINK([#include <setjmp.h>],
1436             [sigjmp_buf x; sigsetjmp(x, 1);],
1437             [pgac_cv_func_sigsetjmp=yes],
1438             [pgac_cv_func_sigsetjmp=no])])
1439 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1440   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1441 fi
1442
1443 AC_DECL_SYS_SIGLIST
1444
1445 AC_CHECK_FUNC(syslog,
1446               [AC_CHECK_HEADER(syslog.h,
1447                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1448
1449 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1450 [AC_TRY_LINK([#include <unistd.h>],
1451   [extern int opterr; opterr = 1;],
1452   [pgac_cv_var_int_opterr=yes],
1453   [pgac_cv_var_int_opterr=no])])
1454 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1455   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1456 fi
1457
1458 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1459 [AC_TRY_LINK([#include <unistd.h>],
1460   [extern int optreset; optreset = 1;],
1461   [pgac_cv_var_int_optreset=yes],
1462   [pgac_cv_var_int_optreset=no])])
1463 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1464   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1465 fi
1466
1467 AC_CHECK_FUNCS([strtoll strtoq], [break])
1468 AC_CHECK_FUNCS([strtoull strtouq], [break])
1469
1470 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1471 [AC_TRY_LINK([],
1472   [int lock = 0;
1473    __sync_lock_test_and_set(&lock, 1);
1474    __sync_lock_release(&lock);],
1475   [pgac_cv_gcc_int_atomics="yes"],
1476   [pgac_cv_gcc_int_atomics="no"])])
1477 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1478   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1479 fi
1480
1481 # Lastly, restore full LIBS list and check for readline/libedit symbols
1482 LIBS="$LIBS_including_readline"
1483
1484 if test "$with_readline" = yes; then
1485   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1486   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1487   AC_CHECK_FUNCS([append_history history_truncate_file])
1488 fi
1489
1490
1491 #
1492 # Pthreads
1493 #
1494 # For each platform, we need to know about any special compile and link
1495 # libraries, and whether the normal C function names are thread-safe.
1496 # See the comment at the top of src/port/thread.c for more information.
1497 # WIN32 doesn't need the pthread tests;  it always uses threads
1498 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1499 ACX_PTHREAD     # set thread flags
1500
1501 # Some platforms use these, so just define them.  They can't hurt if they
1502 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1503 # enables 5-arg getpwuid_r, among other things.
1504 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1505
1506
1507 # At this point, we don't want to muck with the compiler name for threading.
1508 # Let's see who fails, perhaps AIX.  2004-04-23
1509 if test "$PTHREAD_CC" != "$CC"; then
1510 AC_MSG_ERROR([
1511 PostgreSQL does not support platforms that require a special compiler
1512 for thread safety;  use --disable-thread-safety to disable thread safety.])
1513 fi
1514
1515 # Check for *_r functions
1516 _CFLAGS="$CFLAGS"
1517 _LIBS="$LIBS"
1518 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1519 LIBS="$LIBS $PTHREAD_LIBS"
1520
1521 if test "$PORTNAME" != "win32"; then
1522 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1523 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1524 fi
1525
1526 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1527
1528 # Do test here with the proper thread flags
1529 PGAC_FUNC_GETPWUID_R_5ARG
1530 PGAC_FUNC_STRERROR_R_INT
1531
1532 CFLAGS="$_CFLAGS"
1533 LIBS="$_LIBS"
1534
1535 else
1536 # do not use values from template file
1537 PTHREAD_CFLAGS=
1538 PTHREAD_LIBS=
1539 fi
1540
1541 AC_SUBST(PTHREAD_CFLAGS)
1542 AC_SUBST(PTHREAD_LIBS)
1543
1544
1545 # We can test for libldap_r only after we know PTHREAD_LIBS
1546 if test "$with_ldap" = yes ; then
1547   _LIBS="$LIBS"
1548   if test "$PORTNAME" != "win32"; then
1549     AC_CHECK_LIB(ldap, ldap_bind, [],
1550                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1551                  [$EXTRA_LDAP_LIBS])
1552     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1553     if test "$enable_thread_safety" = yes; then
1554       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1555       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1556                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1557                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1558       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1559     else
1560       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1561     fi
1562   else
1563     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1564     LDAP_LIBS_FE="-lwldap32"
1565     LDAP_LIBS_BE="-lwldap32"
1566   fi
1567   LIBS="$_LIBS"
1568 fi
1569 AC_SUBST(LDAP_LIBS_FE)
1570 AC_SUBST(LDAP_LIBS_BE)
1571
1572
1573 # This test makes sure that run tests work at all.  Sometimes a shared
1574 # library is found by the linker, but the runtime linker can't find it.
1575 # This check should come after all modifications of compiler or linker
1576 # variables, and before any other run tests.
1577 AC_MSG_CHECKING([test program])
1578 AC_TRY_RUN([int main() { return 0; }],
1579 [AC_MSG_RESULT(ok)],
1580 [AC_MSG_RESULT(failed)
1581 AC_MSG_ERROR([[
1582 Could not execute a simple test program.  This may be a problem
1583 related to locating shared libraries.  Check the file 'config.log'
1584 for the exact reason.]])],
1585 [AC_MSG_RESULT([cross-compiling])])
1586
1587 # --------------------
1588 # Run tests below here
1589 # --------------------
1590
1591 # Force use of our snprintf if system's doesn't do arg control
1592 # See comment above at snprintf test for details.
1593 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1594   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1595   if test $pgac_cv_snprintf_arg_control != yes ; then
1596     pgac_need_repl_snprintf=yes
1597   fi
1598 fi
1599
1600
1601 dnl Check to see if we have a working 64-bit integer type.
1602 dnl This breaks down into two steps:
1603 dnl (1) figure out if the compiler has a 64-bit int type with working
1604 dnl arithmetic, and if so
1605 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1606 dnl snprintf is the only library routine we really need for int8 support.)
1607 dnl It's entirely possible to have a compiler that handles a 64-bit type
1608 dnl when the C library doesn't; this is fairly likely when using gcc on
1609 dnl an older platform, for example.
1610 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1611 dnl we force our own version of snprintf() to be used instead.
1612 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1613
1614 dnl As of Postgres 8.4, we no longer support compilers without a working
1615 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1616
1617 PGAC_TYPE_64BIT_INT([long int])
1618
1619 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1620   pg_int64_type="long int"
1621 else
1622   PGAC_TYPE_64BIT_INT([long long int])
1623   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1624     pg_int64_type="long long int"
1625   else
1626     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1627   fi
1628 fi
1629
1630 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1631   [Define to the name of a signed 64-bit integer type.])
1632
1633 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1634
1635 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1636   AC_TRY_COMPILE([
1637 #define INT64CONST(x)  x##LL
1638 long long int foo = INT64CONST(0x1234567890123456);
1639 ],
1640         [],
1641         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1642         [])
1643 fi
1644
1645
1646 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1647 # we found we need to use "long long int", better check.  We cope with
1648 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1649 # work, fall back to our own snprintf emulation (which we know uses %lld).
1650
1651 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1652   if test $pgac_need_repl_snprintf = no; then
1653     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1654     if test "$LONG_LONG_INT_FORMAT" = ""; then
1655       # Force usage of our own snprintf, since system snprintf is broken
1656       pgac_need_repl_snprintf=yes
1657       LONG_LONG_INT_FORMAT='%lld'
1658     fi
1659   else
1660     # Here if we previously decided we needed to use our own snprintf
1661     LONG_LONG_INT_FORMAT='%lld'
1662   fi
1663   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1664   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1665   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1666 else
1667   # Here if we are not using 'long long int' at all
1668   INT64_FORMAT='"%ld"'
1669   UINT64_FORMAT='"%lu"'
1670 fi
1671
1672 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1673                    [Define to the appropriate snprintf format for 64-bit ints.])
1674
1675 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1676                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1677
1678 # Also force use of our snprintf if the system's doesn't support the %z flag.
1679 if test "$pgac_need_repl_snprintf" = no; then
1680   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1681   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1682     pgac_need_repl_snprintf=yes
1683   fi
1684 fi
1685
1686 # Now we have checked all the reasons to replace snprintf
1687 if test $pgac_need_repl_snprintf = yes; then
1688   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1689   AC_LIBOBJ(snprintf)
1690 fi
1691
1692 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1693 AC_CHECK_SIZEOF([void *])
1694 AC_CHECK_SIZEOF([size_t])
1695 AC_CHECK_SIZEOF([long])
1696
1697 # Decide whether float4 is passed by value: user-selectable, enabled by default
1698 AC_MSG_CHECKING([whether to build with float4 passed by value])
1699 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1700               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1701                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1702                float4passbyval=true],
1703               [float4passbyval=false])
1704 AC_MSG_RESULT([$enable_float4_byval])
1705 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1706
1707 # Decide whether float8 is passed by value.
1708 # Note: this setting also controls int8 and related types such as timestamp.
1709 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1710 # If not, trying to select it is an error.
1711 AC_MSG_CHECKING([whether to build with float8 passed by value])
1712 if test $ac_cv_sizeof_void_p -ge 8 ; then
1713   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1714 else
1715   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1716   if test "$enable_float8_byval" = yes ; then
1717     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1718   fi
1719 fi
1720 if test "$enable_float8_byval" = yes ; then
1721   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1722             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1723   float8passbyval=true
1724 else
1725   float8passbyval=false
1726 fi
1727 AC_MSG_RESULT([$enable_float8_byval])
1728 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1729
1730 # Determine memory alignment requirements for the basic C data types.
1731
1732 AC_CHECK_ALIGNOF(short)
1733 AC_CHECK_ALIGNOF(int)
1734 AC_CHECK_ALIGNOF(long)
1735 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1736   AC_CHECK_ALIGNOF(long long int)
1737 fi
1738 AC_CHECK_ALIGNOF(double)
1739
1740 # Compute maximum alignment of any basic type.
1741 # We assume long's alignment is at least as strong as char, short, or int;
1742 # but we must check long long (if it exists) and double.
1743
1744 MAX_ALIGNOF=$ac_cv_alignof_long
1745 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1746   MAX_ALIGNOF=$ac_cv_alignof_double
1747 fi
1748 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1749   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1750 fi
1751 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1752
1753
1754 # Some platforms predefine the types int8, int16, etc.  Only check
1755 # a (hopefully) representative subset.
1756 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1757 [#include <stdio.h>])
1758
1759 # We also check for sig_atomic_t, which *should* be defined per ANSI
1760 # C, but is missing on some old platforms.
1761 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1762
1763
1764 if test "$PORTNAME" != "win32"
1765 then
1766 PGAC_FUNC_POSIX_SIGNALS
1767 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1768   AC_MSG_ERROR([
1769 Thread-safety requires POSIX signals, which are not supported by this
1770 operating system;  use --disable-thread-safety to disable thread safety.])
1771 fi
1772 fi
1773
1774
1775 # Select semaphore implementation type.
1776 if test "$PORTNAME" != "win32"; then
1777   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1778     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1779     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1780   else
1781     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1782       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1783       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1784     else
1785       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1786       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1787     fi
1788   fi
1789 else
1790   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1791   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1792 fi
1793
1794
1795 # Select shared-memory implementation type.
1796 if test "$PORTNAME" != "win32"; then
1797   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1798   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1799 else
1800   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1801   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1802 fi
1803
1804 # Select latch implementation type.
1805 if test "$PORTNAME" != "win32"; then
1806   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1807 else
1808   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1809 fi
1810
1811 # If not set in template file, set bytes to use libc memset()
1812 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1813   MEMSET_LOOP_LIMIT=1024
1814 fi
1815 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1816
1817
1818 if test "$enable_nls" = yes ; then
1819   PGAC_CHECK_GETTEXT
1820 fi
1821
1822 # Check for Tcl configuration script tclConfig.sh
1823 if test "$with_tcl" = yes; then
1824     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1825     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1826                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1827     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1828     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1829     ac_save_CPPFLAGS=$CPPFLAGS
1830     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1831     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1832     CPPFLAGS=$ac_save_CPPFLAGS
1833 fi
1834
1835 # check for <perl.h>
1836 if test "$with_perl" = yes; then
1837   ac_save_CPPFLAGS=$CPPFLAGS
1838   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1839   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1840                   [#include <EXTERN.h>])
1841   # While we're at it, check that we can link to libperl.
1842   # On most platforms, if perl.h is there then libperl.so will be too, but at
1843   # this writing Debian packages them separately.  There is no known reason to
1844   # waste cycles on separate probes for the Tcl or Python libraries, though.
1845   pgac_save_LIBS=$LIBS
1846   LIBS="$perl_embed_ldflags"
1847   AC_MSG_CHECKING([for libperl])
1848   AC_TRY_LINK([
1849 #include <EXTERN.h>
1850 #include <perl.h>
1851 ],  [perl_alloc();],
1852     [AC_MSG_RESULT(yes)],
1853     [AC_MSG_RESULT(no)
1854      AC_MSG_ERROR([libperl library is required for Perl])])
1855   LIBS=$pgac_save_LIBS
1856   CPPFLAGS=$ac_save_CPPFLAGS
1857 fi
1858
1859 # check for <Python.h>
1860 if test "$with_python" = yes; then
1861   ac_save_CPPFLAGS=$CPPFLAGS
1862   CPPFLAGS="$python_includespec $CPPFLAGS"
1863   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1864   CPPFLAGS=$ac_save_CPPFLAGS
1865 fi
1866
1867 #
1868 # Check for DocBook and tools
1869 #
1870 PGAC_PROG_NSGMLS
1871 PGAC_PROG_JADE
1872 PGAC_CHECK_DOCBOOK(4.2)
1873 PGAC_PATH_DOCBOOK_STYLESHEETS
1874 PGAC_PATH_COLLATEINDEX
1875 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1876 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1877
1878 #
1879 # Check for test tools
1880 #
1881 AC_CHECK_PROGS(PROVE, prove)
1882
1883 # Thread testing
1884
1885 # We have to run the thread test near the end so we have all our symbols
1886 # defined.  Cross compiling throws a warning.
1887 #
1888 if test "$enable_thread_safety" = yes; then
1889 if test "$PORTNAME" != "win32"
1890 then
1891 AC_MSG_CHECKING([thread safety of required library functions])
1892
1893 _CFLAGS="$CFLAGS"
1894 _LIBS="$LIBS"
1895 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1896 LIBS="$LIBS $PTHREAD_LIBS"
1897 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1898   [AC_MSG_RESULT(yes)],
1899   [AC_MSG_RESULT(no)
1900   AC_MSG_ERROR([thread test program failed
1901 This platform is not thread-safe.  Check the file 'config.log' or compile
1902 and run src/test/thread/thread_test for the exact reason.
1903 Use --disable-thread-safety to disable thread safety.])],
1904   [AC_MSG_RESULT(maybe)
1905   AC_MSG_WARN([
1906 *** Skipping thread test program because of cross-compile build.
1907 *** Run the program in src/test/thread on the target machine.
1908 ])])
1909 CFLAGS="$_CFLAGS"
1910 LIBS="$_LIBS"
1911 else
1912 AC_MSG_WARN([*** skipping thread test on Win32])
1913 fi
1914 fi
1915
1916 # If compiler will take -Wl,--as-needed (or various platform-specific
1917 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1918 # trying to filter LIBS to the minimum for each executable.
1919 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1920 # libreadline; therefore we postpone testing it until we know what library
1921 # dependencies readline has.  The test code will try to link with $LIBS.
1922 if test "$with_readline" = yes; then
1923   link_test_func=readline
1924 else
1925   link_test_func=exit
1926 fi
1927
1928 if test "$PORTNAME" = "darwin"; then
1929   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1930 elif test "$PORTNAME" = "openbsd"; then
1931   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1932 else
1933   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1934 fi
1935
1936 # Create compiler version string
1937 if test x"$GCC" = x"yes" ; then
1938   cc_string=`${CC} --version | sed q`
1939   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1940 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1941   cc_string=`${CC} -V 2>&1 | sed q`
1942 else
1943   cc_string=$CC
1944 fi
1945
1946 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1947                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1948                    [A string containing the version number, platform, and C compiler])
1949
1950 # Supply a numeric version string for use by 3rd party add-ons
1951 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1952 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1953 tr '.' '        ' |
1954 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1955 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1956
1957
1958 # Begin output steps
1959
1960 AC_MSG_NOTICE([using compiler=$cc_string])
1961 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1962 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1963 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1964
1965 # prepare build tree if outside source tree
1966 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1967 # Note 2: /bin/pwd might be better than shell's built-in at getting
1968 #         a symlink-free name.
1969 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1970   vpath_build=no
1971 else
1972   vpath_build=yes
1973   if test "$no_create" != yes; then
1974     _AS_ECHO_N([preparing build tree... ])
1975     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1976     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1977       || AC_MSG_ERROR(failed)
1978     AC_MSG_RESULT(done)
1979   fi
1980 fi
1981 AC_SUBST(vpath_build)
1982
1983
1984 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1985
1986 AC_CONFIG_LINKS([
1987   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1988   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1989   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1990   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1991   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1992   src/include/pg_config_os.h:src/include/port/${template}.h
1993   src/Makefile.port:src/makefiles/Makefile.${template}
1994 ])
1995
1996 if test "$PORTNAME" = "win32"; then
1997 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1998 # Links sometimes fail undetected on Mingw -
1999 # so here we detect it and warn the user
2000 for FILE in $CONFIG_LINKS
2001  do
2002         # test -e works for symlinks in the MinGW console
2003         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2004  done
2005 ])
2006 fi
2007
2008 AC_CONFIG_HEADERS([src/include/pg_config.h],
2009 [
2010 # Update timestamp for pg_config.h (see Makefile.global)
2011 echo >src/include/stamp-h
2012 ])
2013
2014 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2015 [
2016 # Update timestamp for pg_config_ext.h (see Makefile.global)
2017 echo >src/include/stamp-ext-h
2018 ])
2019
2020 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2021                   [echo >src/interfaces/ecpg/include/stamp-h])
2022
2023 AC_OUTPUT