granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 HTTPD_MMN=`$abs_srcdir/build/get-version.sh mmn $abs_srcdir/include/ap_mmn.h MODULE_MAGIC_NUMBER`
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please read the documentation.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/. Download and unpack the corresponding apr and apr-util packages to ./srclib/.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 if test "x${cache_file}" = "x/dev/null"; then
 210   # Likewise, ensure that CC and CPP are passed through to the pcre
 211   # configure script iff caching is disabled (the autoconf 2.5x default).
 212   export CC; export CPP
 213 fi
 214
 215 AC_ARG_WITH(pcre,
 216 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 217
 218 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 219 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 220    PCRE_CONFIG=$with_pcre/bin/pcre-config
 221 elif test -x "$with_pcre"; then
 222    PCRE_CONFIG=$with_pcre
 223 fi
 224
 225 if test "$PCRE_CONFIG" != "false"; then
 226   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 227     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 228   fi
 229   case `$PCRE_CONFIG --version` in
 230   [[1-5].*])
 231     AC_MSG_ERROR([Need at least pcre version 6.0])
 232     ;;
 233   esac
 234   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 235   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 236   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 237 else
 238   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 239 fi
 240 APACHE_SUBST(PCRE_LIBS)
 241
 242 AC_MSG_NOTICE([])
 243 AC_MSG_NOTICE([Configuring Apache httpd...])
 244 AC_MSG_NOTICE([])
 245
 246 dnl If the source dir is not equal to the build dir,
 247 dnl then we are running in VPATH mode.
 248
 249 APR_ADDTO(INCLUDES, [-I.])
 250
 251 if test "$abs_builddir" != "$abs_srcdir"; then
 252   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 253 fi
 254
 255 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 256
 257 # apr/apr-util --includes may pick up system paths for dependent
 258 # libraries, so ensure these are later in INCLUDES than local source
 259 # directories.
 260 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 261 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 262
 263 dnl Add in path to PCRE includes
 264 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 265
 266 AC_MSG_NOTICE([])
 267 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 268 AC_MSG_NOTICE([])
 269
 270 case $host in
 271   *os2*)
 272       # Use a custom made libtool replacement
 273       echo "using aplibtool"
 274       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 275       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 276       SH_LIBS="\$(ALL_LIBS)"
 277       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 278       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 279       MK_IMPLIB="emximp"
 280       other_targets="$other_targets os2core"
 281       INSTALL_PROG_FLAGS="-e .exe"
 282       SHLTCFLAGS=""
 283       LTCFLAGS=""
 284       ;;
 285   *)
 286       if test "x$LTFLAGS" = "x"; then
 287           LTFLAGS='--silent'
 288       fi
 289       my_libtool=`$apr_config --apr-libtool`
 290       LIBTOOL="$my_libtool \$(LTFLAGS)"
 291       libtoolversion=`$my_libtool --version`
 292       case $libtoolversion in
 293           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 294               SH_LIBTOOL='$(LIBTOOL)'
 295               SHLTCFLAGS="-prefer-pic"
 296               LTCFLAGS="-prefer-non-pic -static"
 297               ;;
 298           *)
 299               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 300               SHLTCFLAGS=""
 301               LTCFLAGS=""
 302               ;;
 303       esac
 304       ;;
 305 esac
 306 APACHE_SUBST(SHLTCFLAGS)
 307 APACHE_SUBST(LTCFLAGS)
 308
 309 case $host in
 310   *-apple-aux3*)
 311       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 312       ;;
 313   *os2-emx*)
 314       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 315       ;;
 316   *-linux-*)
 317       case `uname -r` in
 318         # Unserialized accept() was not recommended until Linux 2.2.
 319         [[01]].* | 2.[[01]]* )
 320             ;;
 321         * )
 322             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323             ;;
 324       esac
 325       ;;
 326   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 327       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 328       ;;
 329   *-solaris2*)
 330       dnl This is a hack -- we should be using AC_TRY_RUN instead
 331       ap_platform_runtime_link_flag="-R"
 332       dnl solaris 8 and above don't have a thundering herd
 333       dnl not sure about rev's before this one.
 334       case `uname -r` in
 335         5.[[567]]*)
 336             ;;
 337         * )
 338             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 339             ;;
 340       esac
 341       ;;
 342   *cygwin*)
 343       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 344       ;;
 345   *mingw32*)
 346       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 347       APR_SETIFNULL(ac_cv_func_times, [no])
 348       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 349       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 350       ;;
 351   *aix*)
 352       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 353       if test $aixver -ge 4320; then
 354         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 355       fi
 356       ;;
 357   *os390*)
 358       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 359       ;;
 360 esac
 361
 362 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 363
 364 dnl
 365 dnl Process command line arguments. This is done early in the process so the
 366 dnl user can get feedback quickly in case of an error.
 367 dnl
 368 dnl ### need to move some of the arguments "up here"
 369
 370 dnl ## Check for programs
 371
 372 AC_PATH_PROG(RM, rm)
 373 AC_PATH_PROG(PKGCONFIG, pkg-config)
 374 AC_PATH_PROG(RSYNC, rsync)
 375 AC_PROG_AWK
 376 AC_PROG_LN_S
 377 AC_CHECK_TOOL(RANLIB, ranlib, true)
 378 dnl AC_PATH_PROG(PERL_PATH, perl)
 379 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 380
 381 # Hard-coded install programs
 382 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 383 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 384 APACHE_SUBST(MKINSTALLDIRS)
 385 APACHE_SUBST(INSTALL)
 386
 387 dnl Various OS checks that apparently set required flags
 388 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 389 AC_USE_SYSTEM_EXTENSIONS
 390 ], [
 391 AC_AIX
 392 AC_MINIX
 393 ])
 394
 395 AC_ISC_POSIX
 396
 397 # Ensure that satisfactory versions of apr and apr-util are
 398 # found if external copies are configured.
 399 if test "${apr_found}" = "yes"; then
 400   # Require at least APR 1.3.x otherwise fail
 401   APACHE_CHECK_APxVER([apr], 1, 3)
 402 fi
 403
 404 if test "${apu_found}" = "yes"; then
 405   # Require at least APR-util 1.3.x otherwise fail
 406   if test "${apr_found}" = "yes"; then
 407     # we need to add the APR includes to CPPFLAGS
 408     apu_ckver_CPPFLAGS="$CPPFLAGS"
 409     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 410     APACHE_CHECK_APxVER([apu], 1, 3)
 411     CPPFLAGS="$apu_ckver_CPPFLAGS"
 412   else
 413     APACHE_CHECK_APxVER([apu], 1, 3)
 414   fi
 415 fi
 416
 417 dnl Check for what we can generate dependency files with
 418 APR_CHECK_DEPEND
 419
 420 dnl ## Check for libraries
 421
 422 dnl ## Check for header files
 423
 424 dnl I think these are just used all over the place, so just check for
 425 dnl them at the base of the tree. If some are specific to a single
 426 dnl directory, they should be moved (Comment #Spoon)
 427
 428 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 429 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 430 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 431
 432 AC_HEADER_STDC
 433 AC_CHECK_HEADERS( \
 434 string.h \
 435 limits.h \
 436 unistd.h \
 437 sys/socket.h \
 438 pwd.h \
 439 grp.h \
 440 strings.h \
 441 sys/prctl.h \
 442 sys/processor.h \
 443 sys/sem.h \
 444 sys/sdt.h \
 445 sys/loadavg.h
 446 )
 447 AC_HEADER_SYS_WAIT
 448
 449 dnl ## Check for typedefs, structures, and compiler characteristics.
 450
 451 AC_C_CONST
 452
 453 dnl ## Check for library functions
 454 dnl ## sqrt() only needed in support/ab.c
 455 saved_LIBS="$LIBS"
 456 LIBS=""
 457 AC_SEARCH_LIBS(sqrt, m)
 458 MATH_LIBS="$LIBS"
 459 APACHE_SUBST(MATH_LIBS)
 460 LIBS="$saved_LIBS"
 461
 462 saved_LIBS="$LIBS"
 463 LIBS=""
 464 AC_SEARCH_LIBS(crypt, crypt)
 465 CRYPT_LIBS="$LIBS"
 466 APACHE_SUBST(CRYPT_LIBS)
 467 LIBS="$saved_LIBS"
 468
 469 dnl See Comment #Spoon
 470
 471 AC_CHECK_FUNCS( \
 472 getpwnam \
 473 getgrnam \
 474 initgroups \
 475 bindprocessor \
 476 prctl \
 477 timegm \
 478 getpgid \
 479 fopen64 \
 480 getloadavg
 481 )
 482
 483 dnl confirm that a void pointer is large enough to store a long integer
 484 APACHE_CHECK_VOID_PTR_LEN
 485
 486 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 487 [AC_TRY_RUN(#define _GNU_SOURCE
 488 #include <unistd.h>
 489 #include <sys/syscall.h>
 490 #include <sys/types.h>
 491 int main(int argc, char **argv) {
 492 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 493 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 494 if test "$ac_cv_gettid" = "yes"; then
 495     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 496 fi
 497
 498 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 499 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 500 [AC_TRY_COMPILE([#include <sys/types.h>
 501 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 502   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 503 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 504     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 505 fi
 506
 507 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 508
 509 case $host in
 510     *aix*)
 511         # for 32-bit builds, increase MAXDATA to allow lots of threads
 512         if test x$OBJECT_MODE != x64; then
 513             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 514         fi
 515         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 516         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 517         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 518         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 519         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 520         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 521         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 522         ;;
 523     *os390*)
 524         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 525         ;;
 526     *)
 527         OS_SPECIFIC_VARS=""
 528 esac
 529
 530 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 531         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 532         [PORT=80])
 533
 534 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 535         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 536         [SSLPORT=443])
 537
 538 DTRACE=true
 539 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 540 [
 541   enable_dtrace=$enableval
 542   if test "$enableval" = "yes"; then
 543     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 544     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 545   fi
 546 ],
 547 [
 548   enable_dtrace=no
 549 ])
 550
 551 dnl Disabled dtrace build for now.
 552 enable_dtrace=no
 553
 554 case $host in
 555   *-solaris2*)
 556     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 557         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 558                   [Enable DTrace probes])
 559         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 560         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 561     fi
 562     ;;
 563 esac
 564
 565 APACHE_SUBST(DTRACE)
 566
 567 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 568 [
 569     if test "$enableval" = "yes"; then
 570         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 571                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 572         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 573     fi
 574 ])dnl
 575
 576 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 577 [
 578     if test "$enableval" = "yes"; then
 579         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 580                   [Allow modules to run hook after a fatal exception])
 581     fi
 582 ])dnl
 583
 584 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 585 [
 586   LOAD_ALL_MODULES=$enableval
 587   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 588 ],
 589 [
 590   LOAD_ALL_MODULES="no"
 591 ])
 592
 593 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 594 [
 595   if test "$enableval" = "yes"; then
 596     APR_ADDTO(NOTEST_CPPFLAGS, -DAP_DEBUG)
 597     if test "$GCC" = "yes"; then
 598       APACHE_ADD_GCC_CFLAG([-std=c89])
 599       APACHE_ADD_GCC_CFLAG([-Werror])
 600       APACHE_ADD_GCC_CFLAG([-Wall])
 601       APACHE_ADD_GCC_CFLAG([-Wstrict-prototypes])
 602       APACHE_ADD_GCC_CFLAG([-Wmissing-prototypes])
 603       APACHE_ADD_GCC_CFLAG([-Wmissing-declarations])
 604       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 605       APACHE_ADD_GCC_CFLAG([-Wpointer-arith])
 606       APACHE_ADD_GCC_CFLAG([-Wformat])
 607       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 608       APACHE_ADD_GCC_CFLAG([-Wunused])
 609     elif test "$AIX_XLC" = "yes"; then
 610       APR_ADDTO(NOTEST_CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 611     fi
 612     if test "x$enable_load_all_modules" = "x"; then
 613       LOAD_ALL_MODULES=yes
 614       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 615     fi
 616     if test "x$enable_bucketeer" = "x"; then
 617       enable_bucketeer=yes
 618       AC_MSG_NOTICE([Maintainer mode setting "enable_bucketeer" to yes])
 619     fi
 620   fi
 621 ])dnl
 622
 623 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 624 [
 625   if test "$enableval" = "yes"; then
 626     APR_ADDTO(NOTEST_CPPFLAGS, -DAP_DEBUG)
 627     if test "$GCC" = "yes"; then
 628       APACHE_ADD_GCC_CFLAG([-O0])
 629       APACHE_ADD_GCC_CFLAG([-Wall])
 630       APACHE_ADD_GCC_CFLAG([-Wstrict-prototypes])
 631       APACHE_ADD_GCC_CFLAG([-Wmissing-prototypes])
 632       APACHE_ADD_GCC_CFLAG([-Wmissing-declarations])
 633       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 634       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 635       APACHE_ADD_GCC_CFLAG([-Wpointer-arith])
 636       APACHE_ADD_GCC_CFLAG([-Wformat])
 637       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 638       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 639     elif test "$AIX_XLC" = "yes"; then
 640       APR_ADDTO(NOTEST_CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 641     fi
 642   fi
 643 ])dnl
 644
 645 dnl Conditionally enable PIE support for GNU toolchains.
 646 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 647 if test "$enable_pie" = "yes"; then
 648    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 649      save_CFLAGS=$CFLAGS
 650      save_LDFLAGS=$LDFLAGS
 651      CFLAGS="$CFLAGS -fPIE"
 652      LDFLAGS="$LDFLAGS -pie"
 653      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 654       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 655      CFLAGS=$save_CFLAGS
 656      LDFLAGS=$save_LDFLAGS
 657    ])
 658    if test "$ap_cv_cc_pie" = "yes"; then
 659      PICFLAGS="-fPIE"
 660      PILDFLAGS="-pie"
 661    else
 662      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 663    fi
 664 fi
 665 APACHE_SUBST(PICFLAGS)
 666 APACHE_SUBST(PILDFLAGS)
 667
 668 prefix="$orig_prefix"
 669 APACHE_ENABLE_MODULES
 670
 671 dnl reading config stubs
 672 esyscmd(./build/config-stubs .)
 673
 674 APACHE_SUBST(progname)
 675 APACHE_SUBST(OS)
 676 APACHE_SUBST(OS_DIR)
 677 APACHE_SUBST(BUILTIN_LIBS)
 678 APACHE_SUBST(SHLIBPATH_VAR)
 679 APACHE_SUBST(OS_SPECIFIC_VARS)
 680
 681 PRE_SHARED_CMDS='echo ""'
 682 POST_SHARED_CMDS='echo ""'
 683
 684 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 685
 686 if test "$apache_need_shared" = "yes"; then
 687   if test -f $ac_aux_dir/ltconfig; then
 688     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 689   fi
 690   shared_build="shared-build"
 691 fi
 692
 693 dnl enable_so tells us if *any* modules can be built as DSOs
 694
 695 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 696   case $host in
 697     *-ibm-aix*)
 698       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 699       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 700       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 701       ;;
 702     *os390)
 703       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 704       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 705   esac
 706   MOD_SO_ENABLED=yes
 707 fi
 708 AC_SUBST(MOD_SO_ENABLED)
 709
 710 APACHE_SUBST(PRE_SHARED_CMDS)
 711 APACHE_SUBST(POST_SHARED_CMDS)
 712 APACHE_SUBST(shared_build)
 713
 714 AC_ARG_WITH(program-name,
 715 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 716   progname="$withval" ], [
 717   progname="httpd"] )
 718
 719 # SuExec parameters
 720 AC_ARG_WITH(suexec-bin,
 721 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 722   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 723 ] )
 724
 725 AC_ARG_WITH(suexec-caller,
 726 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 727   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 728
 729 AC_ARG_WITH(suexec-userdir,
 730 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 731   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 732
 733 AC_ARG_WITH(suexec-docroot,
 734 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 735   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 736
 737 AC_ARG_WITH(suexec-uidmin,
 738 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 739   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 740
 741 AC_ARG_WITH(suexec-gidmin,
 742 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 743   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 744
 745 AC_ARG_WITH(suexec-logfile,
 746 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 747   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 748
 749 AC_ARG_WITH(suexec-safepath,
 750 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 751   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 752
 753 AC_ARG_WITH(suexec-umask,
 754 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 755   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 756
 757 dnl APR should go after the other libs, so the right symbols can be picked up
 758 if test x${apu_found} != xobsolete; then
 759   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 760 fi
 761 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 762 APACHE_SUBST(AP_LIBS)
 763 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 764 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 765
 766 AC_DEFINE(AP_USING_AUTOCONF, 1,
 767                 [Using autoconf to configure Apache])
 768
 769 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 770     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 771               [This platform doesn't suffer from the thundering herd problem])
 772 fi
 773
 774 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 775     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 776               [Listening sockets are non-blocking when there are more than 1])
 777 fi
 778
 779 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 780
 781 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 782 [
 783   v4mapped=$enableval
 784 ],
 785 [
 786     case $host in
 787     *freebsd[[1234]].*)
 788         v4mapped=yes
 789         ;;
 790     *freebsd*|*netbsd*|*openbsd*)
 791         v4mapped=no
 792         ;;
 793     *)
 794         v4mapped=yes
 795         ;;
 796     esac
 797     if ap_mpm_is_enabled winnt; then
 798         dnl WinNT MPM doesn't support this.
 799         v4mapped=no
 800     fi
 801 ])
 802
 803 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 804     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 805               [Allow IPv4 connections on IPv6 listening sockets])
 806 fi
 807
 808 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 809 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 810 APACHE_FAST_OUTPUT(support/Makefile)
 811
 812 if test -d ./test; then
 813     APACHE_FAST_OUTPUT(test/Makefile)
 814 fi
 815
 816 dnl ## Finalize the variables
 817 AC_MSG_NOTICE([])
 818 AC_MSG_NOTICE([Restore user-defined environment settings...])
 819 AC_MSG_NOTICE([])
 820
 821 APACHE_CONF_SEL_CC=${CC}
 822 APACHE_CONF_SEL_CFLAGS="${CFLAGS} ${EXTRA_CFLAGS} ${NOTEST_CFLAGS}"
 823 APACHE_CONF_SEL_CPPFLAGS="${CPPFLAGS} ${EXTRA_CPPFLAGS} ${NOTEST_CPPFLAGS}"
 824 APACHE_CONF_SEL_LDFLAGS="${LDFLAGS} ${EXTRA_LDFLAGS} ${NOTEST_LDFLAGS}"
 825 APACHE_CONF_SEL_LIBS="${LIBS} ${EXTRA_LIBS} ${NOTEST_LIBS}"
 826 APACHE_CONF_SEL_CPP=${CPP}
 827
 828 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 829 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 830 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 831 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 832 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 833 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 834
 835 AC_MSG_NOTICE([])
 836 AC_MSG_NOTICE([Construct makefiles and header files...])
 837 AC_MSG_NOTICE([])
 838
 839 APACHE_GEN_CONFIG_VARS
 840
 841 dnl ## Build modules.c
 842 rm -f modules.c
 843 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 844
 845 APR_EXPAND_VAR(ap_prefix, $prefix)
 846 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 847         [Root directory of the Apache install area])
 848 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 849         [Location of the config file, relative to the Apache root directory])
 850 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 851         [Location of the MIME types config file, relative to the Apache root directory])
 852
 853 perlbin=`$ac_aux_dir/PrintPath perl`
 854 if test "x$perlbin" = "x"; then
 855     perlbin="/replace/with/path/to/perl/interpreter"
 856 fi
 857 AC_SUBST(perlbin)
 858
 859 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 860
 861 BSD_MAKEFILE=no
 862 ap_make_include=include
 863 ap_make_delimiter=' '
 864 case $host in
 865 *bsdi*)
 866     # Check whether they've installed GNU make
 867     if make --version > /dev/null 2>&1; then
 868         true
 869     else
 870         BSD_MAKEFILE=yes
 871         ap_make_include=.include
 872         ap_make_delimiter='"'
 873     fi
 874     ;;
 875 esac
 876 AC_SUBST(ap_make_include)
 877 AC_SUBST(ap_make_delimiter)
 878
 879 dnl Ensure that docs/conf is created.
 880 test -d docs/conf||$mkdir_p docs/conf
 881
 882 AC_CONFIG_FILES(docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh)
 883 AC_CONFIG_COMMANDS([default], [true], [APACHE_GEN_MAKEFILES])
 884 AC_OUTPUT
 885 AC_MSG_NOTICE([summary of build options:
 886
 887     Server Version: ${HTTPD_VERSION}
 888     Install prefix: ${prefix}
 889     C compiler:     ${APACHE_CONF_SEL_CC}
 890     CFLAGS:         ${APACHE_CONF_SEL_CFLAGS}
 891     CPPFLAGS:       ${APACHE_CONF_SEL_CPPFLAGS}
 892     LDFLAGS:        ${APACHE_CONF_SEL_LDFLAGS}
 893     LIBS:           ${APACHE_CONF_SEL_LIBS}
 894     C preprocessor: ${APACHE_CONF_SEL_CPP}
 895 ])